configure.in

   1 dnl == autoconf source for the Glasgow FP tools ==
   2 dnl (run "grep '^dnl \*' configure.in | sed -e 's/dnl / /g; s/\*\*/   +/g;'"
   3 dnl  (or some such) to see the outline of this file)
   4 dnl
   5 #
   6 # (c) The AQUA Project, Glasgow University, 1994-1998
   7 #
   8 # Configure script template for the Glasgow functional programming tools
   9 #
  10 # Process with 'autoconf' to get a working configure script.
  11 #
  12 # For the generated configure script, do "./configure --help" to
  13 # see what flags are available. (Better yet, read the documentation!)
  14 #
  15
  16 # First off, a distrib sanity check..
  17 AC_INIT(mk/config.mk.in)
  18
  19 dnl * Declare subdirectories that have a private configure script
  20 dnl
  21 dnl After the toplevel configuration is complete, the script will recurse into
  22 dnl these subdirectories (the use of cache values makes repeated checks cheap)
  23 dnl (We probably have to add hslibs/{OpenGL,GLUT} here later...)
  24 AC_CONFIG_SUBDIRS(ghc)
  25
  26 # -------------------------------------------------------------------------
  27 # Prepare to generate the following header files
  28 #
  29 #
  30 AC_CONFIG_HEADER(mk/config.h)
  31
  32 # No, semi-sadly, we don't do `--srcdir'...
  33 if test x"$srcdir" != 'x.' ; then
  34     echo "This configuration does not support the \`--srcdir' option.."
  35     exit 1
  36 fi
  37
  38 #
  39 # Remove common automounter nonsense + convert from UNC to DOS style paths
  40 # (UNC awareness isn't quite there yet for cygwin32-beta18 and consituent tools.)
  41 #
  42 hardtop=`pwd`
  43 hardtop=`echo $hardtop | sed 's|^/tmp_mnt.*\(/local/.*\)$|\1|' | sed 's|^/tmp_mnt/|/|' | sed 's|^/grasp_tmp|/local/grasp_tmp|' | sed 's|^//\(.\)/|\1:/|' `
  44
  45 echo ''
  46 echo "*** The top of your build tree is: $hardtop"
  47 AC_SUBST(hardtop)
  48
  49 dnl--------------------------------------------------------------------
  50 dnl * Choose host(/target/build) platform
  51 dnl--------------------------------------------------------------------
  52
  53 dnl Guess host/target/build platform(s) if necessary.
  54 AC_CANONICAL_SYSTEM
  55
  56 # "$host" defaults to "$target"
  57 if test "x$host" = xNONE ; then
  58     host=$target
  59 fi
  60
  61 dnl ** canonicalize platform names
  62 BuildPlatform=`/bin/sh $srcdir/config.sub $build` || exit 1
  63 HostPlatform=`/bin/sh $srcdir/config.sub $host` || exit 1
  64 TargetPlatform=`/bin/sh $srcdir/config.sub $target` || exit 1
  65
  66 if test x"$TargetPlatform" != x"$HostPlatform" ; then
  67     echo "GHC configuration does not support differing host/target (i.e., cross-compiling)"
  68     exit 1
  69 fi
  70
  71 exeext=''
  72 #
  73 # The following will be more difficult when we *are* cross-compiling.
  74 # Suitable names to slam in *_CPP are in platform.h.in.
  75 # We also record the architecture, vendor, and operating system (OS)
  76 # separately.
  77 case $HostPlatform in
  78 alpha-dec-osf[[12]]*)
  79         HostPlatform=alpha-dec-osf1   # canonicalise for our purposes
  80         TargetPlatform=alpha-dec-osf1 # this will work for now... (hack)
  81         BuildPlatform=alpha-dec-osf1  # hack
  82         HostPlatform_CPP='alpha_dec_osf1'
  83         HostArch_CPP='alpha'
  84         HostVendor_CPP='dec'
  85         HostOS_CPP='osf1'
  86         ;;
  87 alpha-dec-osf[[34]]*)
  88         HostPlatform=alpha-dec-osf3   # canonicalise for our purposes
  89         TargetPlatform=alpha-dec-osf3 # this will work for now... (hack)
  90         BuildPlatform=alpha-dec-osf3  # hack
  91         HostPlatform_CPP='alpha_dec_osf3'
  92         HostArch_CPP='alpha'
  93         HostVendor_CPP='dec'
  94         HostOS_CPP='osf3'
  95         ;;
  96 alpha-unknown-linux)
  97         HostPlatform=alpha-unknown-linux
  98         TargetPlatform=alpha-unknown-linux
  99         BuildPlatform=alpha-unknown-linux
 100         HostPlatform_CPP='alpha_unknown_linux'
 101         HostArch_CPP='alpha'
 102         HostVendor_CPP='unknown'
 103         HostOS_CPP='linux'
 104         ;;
 105 alpha-unknown-freebsd*)
 106         HostPlatform=alpha-unknown-freebsd
 107         TargetPlatform=alpha-unknown-freebsd
 108         BuildPlatform=alpha-unknown-freebsd
 109         HostPlatform_CPP='alpha_unknown_freebsd'
 110         HostArch_CPP='alpha'
 111         HostVendor_CPP='unknown'
 112         HostOS_CPP='freebsd'
 113         ;;
 114 hppa1.1-hp-hpux*)
 115         HostPlatform=hppa1.1-hp-hpux  # canonicalise for our purposes (hack)
 116         TargetPlatform=hppa1.1-hp-hpux
 117         BuildPlatform=hppa1.1-hp-hpux
 118         HostPlatform_CPP='hppa1_1_hp_hpux'
 119         HostArch_CPP='hppa1_1'
 120         HostVendor_CPP='hp'
 121         HostOS_CPP='hpux'
 122         ;;
 123 i[[3456]]86-*-linuxaout*)
 124         HostPlatform=i386-unknown-linuxaout   # hack again
 125         TargetPlatform=i386-unknown-linuxaout
 126         BuildPlatform=i386-unknown-linuxaout
 127         HostPlatform_CPP='i386_unknown_linuxaout'
 128         HostArch_CPP='i386'
 129         HostVendor_CPP='unknown'
 130         HostOS_CPP='linuxaout'
 131         ;;
 132 i[[3456]]86-*-linux*)
 133         HostPlatform=i386-unknown-linux # hack again
 134         TargetPlatform=i386-unknown-linux
 135         BuildPlatform=i386-unknown-linux
 136         HostPlatform_CPP='i386_unknown_linux'
 137         HostArch_CPP='i386'
 138         HostVendor_CPP='unknown'
 139         HostOS_CPP='linux'
 140         ;;
 141 i[[3456]]86-*-freebsd[[3-9]]*) # FreeBSD 3.0+ uses ELF
 142         HostPlatform=i386-unknown-freebsd # hack again
 143         TargetPlatform=i386-unknown-freebsd
 144         BuildPlatform=i386-unknown-freebsd
 145         HostPlatform_CPP='i386_unknown_freebsd'
 146         HostArch_CPP='i386'
 147         HostVendor_CPP='unknown'
 148         HostOS_CPP='freebsd'
 149         ;;
 150 i[[3456]]86-*-freebsd2*) # Older FreeBSDs are a.out
 151         HostPlatform=i386-unknown-freebsd2 # hack again
 152         TargetPlatform=i386-unknown-freebsd2
 153         BuildPlatform=i386-unknown-freebsd2
 154         HostPlatform_CPP='i386_unknown_freebsd2'
 155         HostArch_CPP='i386'
 156         HostVendor_CPP='unknown'
 157         HostOS_CPP='freebsd2'
 158         ;;
 159 i[[3456]]86-*-netbsd*)
 160         HostPlatform=i386-unknown-netbsd # hack again
 161         TargetPlatform=i386-unknown-netbsd
 162         BuildPlatform=i386-unknown-netbsd
 163         HostPlatform_CPP='i386_unknown_netbsd'
 164         HostArch_CPP='i386'
 165         HostVendor_CPP='unknown'
 166         HostOS_CPP='netbsd'
 167         ;;
 168 i[[3456]]86-*-openbsd*)
 169         HostPlatform=i386-unknown-openbsd # hack again
 170         TargetPlatform=i386-unknown-openbsd
 171         BuildPlatform=i386-unknown-openbsd
 172         HostPlatform_CPP='i386_unknown_openbsd'
 173         HostArch_CPP='i386'
 174         HostVendor_CPP='unknown'
 175         HostOS_CPP='openbsd'
 176         ;;
 177 i[[3456]]86-*-solaris2*)
 178         HostPlatform=i386-unknown-solaris2 # hack again
 179         TargetPlatform=i386-unknown-solaris2
 180         BuildPlatform=i386-unknown-solaris2
 181         HostPlatform_CPP='i386_unknown_solaris2'
 182         HostArch_CPP='i386'
 183         HostVendor_CPP='unknown'
 184         HostOS_CPP='solaris2'
 185         ;;
 186 i[[3456]]86-*-cygwin*)
 187         HostPlatform=i386-unknown-cygwin32 # hack again
 188         TargetPlatform=i386-unknown-cygwin32
 189         BuildPlatform=i386-unknown-cygwin32
 190         HostPlatform_CPP='i386_unknown_cygwin32'
 191         HostArch_CPP='i386'
 192         HostVendor_CPP='unknown'
 193         HostOS_CPP='cygwin32'
 194         exeext='.exe'
 195         ;;
 196 i[[3456]]86-*-mingw32*)
 197         HostPlatform=i386-unknown-mingw32 # hack again
 198         TargetPlatform=i386-unknown-mingw32
 199         BuildPlatform=i386-unknown-mingw32
 200         HostPlatform_CPP='i386_unknown_mingw32'
 201         HostArch_CPP='i386'
 202         HostVendor_CPP='unknown'
 203         HostOS_CPP='mingw32'
 204         exeext='.exe'
 205         ;;
 206 m68k-next-nextstep2)
 207         HostPlatform_CPP='m68k_next_nextstep2'
 208         HostArch_CPP='m68k'
 209         HostVendor_CPP='next'
 210         HostOS_CPP='nextstep2'
 211         ;;
 212 m68k-next-nextstep3)
 213         HostPlatform_CPP='m68k_next_nextstep3'
 214         HostArch_CPP='m68k'
 215         HostVendor_CPP='next'
 216         HostOS_CPP='nextstep3'
 217         ;;
 218 i[[3456]]86-next-nextstep3)
 219         HostPlatform=i386-next-nextstep3 # hack again
 220         TargetPlatform=i386-next-nextstep3
 221         BuildPlatform=i386-next-nextstep3
 222         HostPlatform_CPP='i386_next_nextstep3'
 223         HostArch_CPP='i386'
 224         HostVendor_CPP='next'
 225         HostOS_CPP='nextstep3'
 226         ;;
 227 m68k-sun-sunos4*)
 228         HostPlatform=m68k-sun-sunos4
 229         TargetPlatform=m68k-sun-sunos4 #hack
 230         BuildPlatform=m68k-sun-sunos4 #hack
 231         HostPlatform_CPP='m68k_sun_sunos4'
 232         HostArch_CPP='m68k'
 233         HostVendor_CPP='sun'
 234         HostOS_CPP='sunos4'
 235         ;;
 236 mips-dec-ultrix*)
 237         HostPlatform_CPP='mips_dec_ultrix'
 238         HostArch_CPP='mipsel'   # NB a little different
 239         HostVendor_CPP='dec'
 240         HostOS_CPP='ultrix'
 241         ;;
 242 mips-sgi-irix*)
 243         HostPlatform=mips-sgi-irix
 244         TargetPlatform=mips-sgi-irix #hack
 245         BuildPlatform=mips-sgi-irix #hack
 246         HostPlatform_CPP='mips_sgi_irix'
 247         HostArch_CPP='mipseb'   # NB a little different
 248         HostVendor_CPP='sgi'
 249         HostOS_CPP='irix'
 250         ;;
 251 rs6000-ibm-aix*)
 252         HostPlatform=rs6000-ibm-aix
 253         TargetPlatform=rs6000-ibm-aix #hack
 254         BuildPlatform=rs6000-ibm-aix #hack
 255         HostPlatform_CPP='rs6000_ibm_aix'
 256         HostArch_CPP='rs6000'
 257         HostVendor_CPP='ibm'
 258         HostOS_CPP='aix'
 259         ;;
 260 powerpc-ibm-aix*)
 261         HostPlatform=powerpc-ibm-aix
 262         TargetPlatform=powerpc-ibm-aix #hack
 263         BuildPlatform=powerpc-ibm-aix #hack
 264         HostPlatform_CPP='powerpc_ibm_aix'
 265         HostArch_CPP='powerpc'
 266         HostVendor_CPP='ibm'
 267         HostOS_CPP='aix'
 268         ;;
 269 powerpc-apple-macosx*)
 270       HostPlatform=powerpc-apple-macosx
 271       TargetPlatform=powerpc-apple-macosx #hack
 272       BuildPlatform=powerpc-apple-macosx #hack
 273         HostPlatform_CPP='powerpc_apple_macosx'
 274         HostArch_CPP='powerpc'
 275         HostVendor_CPP='apple'
 276         HostOS_CPP='macosx'
 277         ;;
 278 sparc-sun-sunos4*)
 279         HostPlatform=sparc-sun-sunos4
 280         TargetPlatform=sparc-sun-sunos4 #hack
 281         BuildPlatform=sparc-sun-sunos4 #hack
 282         HostPlatform_CPP='sparc_sun_sunos4'
 283         HostArch_CPP='sparc'
 284         HostVendor_CPP='sun'
 285         HostOS_CPP='sunos4'
 286         ;;
 287 sparc-sun-solaris2*)
 288         HostPlatform=sparc-sun-solaris2
 289         TargetPlatform=sparc-sun-solaris2 #hack
 290         BuildPlatform=sparc-sun-solaris2 #hack
 291         HostPlatform_CPP='sparc_sun_solaris2'
 292         HostArch_CPP='sparc'
 293         HostVendor_CPP='sun'
 294         HostOS_CPP='solaris2'
 295         ;;
 296 *)
 297         echo "Unrecognised platform: $HostPlatform"
 298         exit 1
 299         ;;
 300 esac
 301 echo "Canonicalised to: $HostPlatform"
 302 test  x"$HostPlatform" != x"$TargetPlatform" && echo "Target platform set to $TargetPlatform"
 303 test  x"$BuildPlatform" != x"$HostPlatform"  && echo "Build platform set to $BuildPlatform"
 304
 305 BuildPlatform_CPP=$HostPlatform_CPP
 306 TargetPlatform_CPP=$HostPlatform_CPP
 307 BuildArch_CPP=$HostArch_CPP
 308 TargetArch_CPP=$HostArch_CPP
 309 BuildOS_CPP=$HostOS_CPP
 310 HostOS_Full=$host_os
 311 TargetOS_CPP=$HostOS_CPP
 312 BuildVendor_CPP=$HostVendor_CPP
 313 TargetVendor_CPP=$HostVendor_CPP
 314
 315 dnl Cannot afford all these SUBSTs (because of braindead seds w/ 99 cmd limits)
 316 dnl AC_SUBST(BuildPlatform)
 317
 318 AC_SUBST(HostPlatform)
 319 AC_SUBST(TargetPlatform)
 320 AC_SUBST(HostPlatform_CPP)
 321 dnl AC_SUBST(BuildPlatform_CPP)
 322 dnl AC_SUBST(TargetPlatform_CPP)
 323
 324 AC_SUBST(HostArch_CPP)
 325 dnl AC_SUBST(BuildArch_CPP)
 326 dnl AC_SUBST(TargetArch_CPP)
 327
 328 AC_SUBST(HostOS_CPP)
 329 AC_SUBST(HostOS_Full)
 330 dnl AC_SUBST(BuildOS_CPP)
 331 dnl AC_SUBST(TargetOS_CPP)
 332
 333 AC_SUBST(HostVendor_CPP)
 334 dnl AC_SUBST(BuildVendor_CPP)
 335 dnl AC_SUBST(TargetVendor_CPP)
 336
 337 AC_SUBST(exeext)
 338
 339 dnl --------------------------------------------------------------
 340 dnl * Project specific configuration options
 341 dnl --------------------------------------------------------------
 342 dnl What follows is a bunch of options that can either be configured
 343 dnl through command line options to the configure script or by
 344 dnl supplying defns in the build tree's mk/build.mk. Having the option to
 345 dnl use either is considered a Feature.
 346
 347 dnl ** What command to use to compile compiler sources ?
 348 dnl --------------------------------------------------------------
 349 if test "$GHC" = ""; then
 350   AC_PATH_PROG(GHC,ghc)
 351 fi
 352
 353 AC_ARG_WITH(ghc,
 354 [  --with-ghc=<haskell compiler>
 355         Use a command different from 'ghc' to compile GHC-specific Haskell code
 356             (including GHC itself).
 357 ],
 358 [WithGhc="$withval"],
 359 [WithGhc=$GHC]
 360 )
 361 AC_SUBST(WithGhc)
 362
 363 AC_ARG_WITH(hc,
 364 [  --with-hc=<haskell compiler>
 365         Use a command different from 'ghc' to compile generic Haskell code.
 366 ],
 367 [WithHc="$withval"],
 368 [WithHc=$WithGhc]
 369 )
 370 AC_SUBST(WithHc)
 371
 372 if test "$WithGhc" != ""; then
 373   FPTOOLS_GHC_VERSION([GhcVersion], [GhcMajVersion], [GhcMinVersion], [GhcPatchLevel])dnl
 374   AC_SUBST(GhcVersion)dnl
 375   AC_SUBST(GhcMajVersion)dnl
 376   AC_SUBST(GhcMinVersion)dnl
 377   AC_SUBST(GhcPatchLevel)dnl
 378 fi
 379
 380 AC_PATH_PROGS(NHC,nhc nhc98)
 381 AC_PATH_PROG(HBC,hbc)
 382
 383 dnl ** Which gcc to use?
 384 dnl --------------------------------------------------------------
 385 AC_ARG_WITH(gcc,
 386 [  --with-gcc=<gcc command>
 387         Use a different command instead of 'gcc' for the GNU C compiler.
 388 ],
 389 [WhatGccIsCalled="$withval"
 390  CC="$withval"],
 391 [WhatGccIsCalled="gcc"]
 392 )
 393 AC_SUBST(WhatGccIsCalled)
 394
 395 dnl ** Booting from .hc files?
 396 dnl --------------------------------------------------------------
 397 AC_ARG_ENABLE(hc-boot,
 398 [  --enable-hc-boot
 399         Boot the Glasgow Haskell Compiler from intermediate .hc files.
 400         (This option is mostly of interest to porters.)
 401 ],
 402 [BootingFromHc=YES],
 403 [BootingFromHc=NO]
 404 )
 405 AC_SUBST(BootingFromHc)
 406
 407
 408 dnl ** Enable the construction of Win32 DLLs?
 409 dnl --------------------------------------------------------------
 410 AC_ARG_ENABLE(win32-dlls,
 411 [  --enable-win32-dlls
 412         If on a Win32 platform running mingw32/cygwin, enable the
 413         construction of DLLs containing ghc-compiled code.
 414 ],
 415 [
 416 case $HostOS_CPP in
 417 cygwin32) ;;
 418 mingw32)  ;;
 419 *)    echo "Unrecognised win32 platform: $HostPlatform"
 420       exit 1
 421       ;;
 422 esac
 423 EnableWin32DLLs=YES
 424 ],
 425 [EnableWin32DLLs=NO]
 426 )
 427 AC_SUBST(EnableWin32DLLs)
 428 if test x"$EnableWin32DLLs" = "xYES" ; then
 429  AC_DEFINE(HAVE_WIN32_DLL_SUPPORT)
 430 fi
 431
 432 dnl ** Enable the building of the OpenGL/GLUT binding in hslibs?
 433 dnl --------------------------------------------------------------
 434 AC_ARG_ENABLE(hopengl,
 435 [  --enable-hopengl
 436         Build HOpenGL, a Haskell binding for OpenGL/GLUT, too.
 437         (This option is only relevant when hslibs are built.)
 438 ],
 439 [GhcLibsWithHOpenGL=YES],
 440 [GhcLibsWithHOpenGL=NO]
 441 )
 442 AC_SUBST(GhcLibsWithHOpenGL)
 443
 444 dnl ** Use a specific version of the GLUT API
 445 dnl --------------------------------------------------------------
 446 AC_ARG_WITH(glut-api,
 447 [  --with-glut-api=<version>
 448         Use a specific version of the GLUT API when building HOpenGL.
 449 ])
 450 test -n "$with_glut_api"  && CPPFLAGS="$CPPFLAGS -DGLUT_API_VERSION=$with_glut_api"
 451
 452
 453 dnl ** Use a specific version of the GLUT API
 454 dnl --------------------------------------------------------------
 455 AC_ARG_WITH(glut-xlib,
 456 [  --with-glut-xlib=<version>
 457         Use a specific version of the GLUT Xlib implementation when building HOpenGL.
 458 ])
 459 test -n "$with_glut_xlib" && CPPFLAGS="$CPPFLAGS -DGLUT_XLIB_IMPLEMENTATION=$with_glut_xlib"
 460
 461
 462
 463
 464 dnl --------------------------------------------------------------
 465 dnl End of configure script option section
 466 dnl --------------------------------------------------------------
 467
 468
 469 dnl --------------------------------------------------------------
 470 dnl * General configuration checks
 471 dnl --------------------------------------------------------------
 472
 473 dnl ** does #! work?
 474 AC_SYS_INTERPRETER()
 475
 476 dnl ** look for `perl', but only in /bin on Windows
 477 case $HostOS_CPP in
 478 cygwin32|mingw32)
 479       AC_CHECK_PROG(PerlCmd,perl,/bin/perl,,/bin)
 480       if test -z "$PerlCmd"; then
 481          echo "You must install the version of Perl shipped with GHC"
 482          echo "(or a compatible one) in /bin."
 483          exit 1
 484       fi
 485    ;;
 486 *)
 487    AC_PATH_PROG(PerlCmd,perl)
 488    if test -z "$PerlCmd"; then
 489       echo "You must install perl before you can continue"
 490       echo "Perhaps it is already installed, but not in your PATH?"
 491       exit 1
 492    else
 493    FPTOOLS_CHECK_PERL_VERSION
 494    fi
 495    ;;
 496 esac
 497
 498 dnl ** does #! path/to/perl work? (sometimes it's too long...)
 499 FPTOOLS_SHEBANG_PERL
 500
 501 dnl ** look for GCC and find out which version
 502 dnl     Figure out which C compiler to use.  Gcc is preferred.
 503 dnl     If gcc, make sure it's at least 2.1
 504 dnl
 505 AC_PROG_CC
 506 FPTOOLS_HAVE_GCC
 507
 508 dnl ** figure out how to invoke cpp directly (gcc -E is no good)
 509 AC_PROG_CPP
 510
 511 dnl ** does the C compiler support the following options?
 512 FPTOOLS_CC_FLAG(-mwin32,CC_SUPPORTS_MWIN32)
 513 FPTOOLS_CC_FLAG(-mno-cygwin,CC_SUPPORTS_MNO_CYGWIN)
 514
 515 EXTRA_CC_OPTS="$CC_SUPPORTS_MNO_CYGWIN $CC_SUPPORTS_MWIN32"
 516 SRC_CC_OPTS="-O $EXTRA_CC_OPTS"
 517 CPPFLAGS="$EXTRA_CC_OPTS $CPPFLAGS"
 518 AC_SUBST(SRC_CC_OPTS)
 519
 520 dnl ** figure out how to do context diffs
 521 FPTOOLS_PROG_DIFF
 522
 523 dnl ** Find find command (for Win32's benefit)
 524 AC_PATH_PROG(FindCmd, find)
 525
 526 dnl ** look for a decent parser generator (bison preferred)
 527 dnl (FPTOOLS_PROG_YACCY is AC_PROG_YACC, but with some extra testing
 528 dnl  on the suitability of the 'yacc' returned.)
 529 FPTOOLS_PROG_YACCY
 530
 531 dnl ** Find lex command (lex or flex) - *doesn't* use autoconf's
 532 dnl    AC_PROG_LEX, since it doesn't actually check whether 'lex'
 533 dnl    exists if 'flex' doesn't.
 534 AC_PROG_LEX_STRICT
 535
 536 dnl ** figure out how to do a BSD-ish install
 537 AC_PROG_INSTALL
 538
 539 dnl If you can run configure, you certainly have /bin/sh
 540 AC_DEFINE(HAVE_BIN_SH)
 541
 542 dnl ** how to invoke `ar' and `ranlib'
 543 FPTOOLS_PROG_AR_AND_RANLIB
 544
 545
 546 dnl ** Check to see whether ln -s works
 547 AC_PROG_LN_S
 548
 549
 550 dnl ** Find the path to sed
 551 AC_PATH_PROG(SedCmd,sed)
 552
 553
 554 dnl ** check for time command
 555 AC_PATH_PROG(TimeCmd,time)
 556
 557
 558 dnl ** check for tar
 559 dnl   if GNU tar is named gtar, look for it first.
 560 AC_PATH_PROGS(TarCmd,gtar tar,tar)
 561
 562 dnl ** check for gzip/compress
 563 AC_PATH_PROGS(CompressCmd,gzip compress,gzip)
 564
 565 dnl ** check for jade/openjade & determine a working catalog
 566 AC_PATH_PROGS(JadeCmd,openjade jade,jade)
 567 FPTOOLS_DOCBOOK_CATALOG(Catalog, $JadeCmd, docs/fptools-both.dsl,
 568                         /etc/sgml/catalog /etc/sgml.catalog /usr/share/sgml/CATALOG.docbkdsl $hardtop/glafp-utils/docbook/CATALOG*)
 569 if test -z "$Catalog"; then
 570   AC_MSG_RESULT([Warning: You will not be able to build the documentation.])
 571 fi
 572 AC_SUBST(Catalog)
 573
 574 compress_nm=`basename $CompressCmd`
 575 if test x"$compress_nm" = xgzip; then
 576   CompressCmd="$CompressCmd -d"
 577   CompressSuffix="gz"
 578 else
 579   CompressSuffix="Z"
 580 fi
 581 AC_SUBST(CompressCmd)
 582 AC_SUBST(CompressSuffix)
 583
 584 dnl ** check for installed happy binary + version
 585 dnl    (don't do it if we're booting from .hc files though.)
 586 if test "$BootingFromHc" = "NO"; then
 587 FPTOOLS_HAPPY
 588 fi;
 589
 590 dnl --------------------------------------------------
 591 dnl ### program checking section ends here ###
 592 dnl --------------------------------------------------
 593
 594 dnl --------------------------------------------------
 595 dnl * Platform header file and syscall feature tests
 596 dnl ### checking the state of the local header files and syscalls ###
 597
 598 dnl ** check for full ANSI header (.h) files
 599 AC_HEADER_STDC
 600
 601 dnl ** check for specific header (.h) files that we are interested in
 602 AC_CHECK_HEADERS(Files.h arpa/inet.h assert.h console.h ctype.h dirent.h errno.h fcntl.h float.h ftw.h grp.h ieee754.h inttypes.h malloc.h memory.h nlist.h pascal.h pwd.h sgtty.h siginfo.h signal.h stat.h stdint.h stdlib.h stdarg.h string.h sys/fault.h sys/file.h sys/ioctl.h sys/limits.h sys/mman.h sys/param.h sys/procfs.h sys/resource.h sys/signal.h sys/socket.h netdb.h netinet/in.h netinet/tcp.h sys/stat.h sys/syscall.h sys/time.h sys/timeb.h sys/timers.h sys/times.h sys/types.h sys/un.h sys/utsname.h sys/vadvise.h sys/wait.h termio.h termios.h time.h types.h unistd.h utime.h values.h vfork.h bfd.h winsock.h)
 603
 604 AC_CHECK_HEADER(readline/readline.h, HaveReadlineReadlineH=YES, HaveReadlineReadlineH=NO)
 605 AC_CHECK_HEADER(readline/history.h, HaveReadlineHistoryH=YES, HaveReadlineHistoryH=NO)
 606
 607 if test $HaveReadlineReadlineH = YES && test $HaveReadlineHistoryH = YES ; then
 608   HaveReadlineHeaders=YES
 609   AC_DEFINE(HAVE_READLINE_HEADERS,1)
 610 else
 611   HaveReadlineHeaders=NO
 612   AC_DEFINE(HAVE_READLINE_HEADERS,0)
 613 fi
 614 AC_SUBST(HaveReadlineHeaders)
 615
 616 dnl ** check for DOS include files
 617 AC_CHECK_HEADERS(dos.h conio.h io.h std.h)
 618
 619 dnl ** check for Windows include files
 620 AC_CHECK_HEADERS(windows.h)
 621
 622 dnl ** check for OpenGL include files
 623 AC_CHECK_HEADERS(GL/gl.h)
 624
 625 dnl ** check if it is safe to include both <time.h> and <sys/time.h>
 626 AC_HEADER_TIME
 627
 628 dnl dynamic loading include files
 629 AC_CHECK_HEADERS(dlfcn.h dl.h)
 630
 631 dnl ** check for farcalloc (in bcc)
 632 AC_CHECK_HEADER(alloc.h,AC_CHECK_FUNCS(farcalloc))
 633
 634 dnl ** check for valloc (in sunos, solaris, mips, amiga, next, minix, ultrix)
 635 AC_CHECK_HEADER(malloc.h,AC_CHECK_FUNCS(valloc))
 636
 637 dnl ** how do we get a timezone name, and UTC offset ?
 638 AC_STRUCT_TIMEZONE
 639
 640 dnl ** what's the type of timezone?
 641 FPTOOLS_HAVE_TIMEZONE
 642 FPTOOLS_TYPE_TIMEZONE
 643
 644 dnl ** do we have altzone?
 645 FPTOOLS_ALTZONE
 646
 647 dnl ** does struct stat contain st_blksize?
 648 AC_STRUCT_ST_BLKSIZE
 649
 650 dnl ** do we have long longs?
 651 FPTOOLS_C_LONG_LONG
 652
 653 dnl ** what are the sizes of various types
 654 dnl    (these must come before GHC_CHECK_ALIGNMENT)
 655 AC_CHECK_SIZEOF(char,               1)
 656 AC_CHECK_SIZEOF(double,             8)
 657 AC_CHECK_SIZEOF(float,              4)
 658 AC_CHECK_SIZEOF(int,                4)
 659 AC_CHECK_SIZEOF(long,               4)
 660 if test "$fptools_cv_have_long_long" = yes; then
 661 AC_CHECK_SIZEOF(long long,          8)
 662 fi
 663 AC_CHECK_SIZEOF(short,              2)
 664 AC_CHECK_SIZEOF(unsigned char,      1)
 665 AC_CHECK_SIZEOF(unsigned int,       4)
 666 AC_CHECK_SIZEOF(unsigned long,      4)
 667 if test "$fptools_cv_have_long_long" = yes; then
 668 AC_CHECK_SIZEOF(unsigned long long, 8)
 669 fi
 670 AC_CHECK_SIZEOF(unsigned short,     2)
 671 AC_CHECK_SIZEOF(void *,             4)
 672
 673 dnl ** what are alignment constraints on various types
 674 FPTOOLS_CHECK_ALIGNMENT(char)
 675 FPTOOLS_CHECK_ALIGNMENT(double)
 676 FPTOOLS_CHECK_ALIGNMENT(float)
 677 FPTOOLS_CHECK_ALIGNMENT(int)
 678 FPTOOLS_CHECK_ALIGNMENT(long)
 679 if test "$fptools_cv_have_long_long" = yes; then
 680 FPTOOLS_CHECK_ALIGNMENT(long long)
 681 fi
 682 FPTOOLS_CHECK_ALIGNMENT(short)
 683 FPTOOLS_CHECK_ALIGNMENT(unsigned char)
 684 FPTOOLS_CHECK_ALIGNMENT(unsigned int)
 685 FPTOOLS_CHECK_ALIGNMENT(unsigned long)
 686 if test "$fptools_cv_have_long_long" = yes; then
 687 FPTOOLS_CHECK_ALIGNMENT(unsigned long long)
 688 fi
 689 FPTOOLS_CHECK_ALIGNMENT(unsigned short)
 690 FPTOOLS_CHECK_ALIGNMENT(void *)
 691
 692 dnl ** map standard C types and ISO types to Haskell types
 693 FPTOOLS_CHECK_HTYPE(char)
 694 FPTOOLS_CHECK_HTYPE(signed char)
 695 FPTOOLS_CHECK_HTYPE(unsigned char)
 696 FPTOOLS_CHECK_HTYPE(short)
 697 FPTOOLS_CHECK_HTYPE(unsigned short)
 698 FPTOOLS_CHECK_HTYPE(int)
 699 FPTOOLS_CHECK_HTYPE(unsigned int)
 700 FPTOOLS_CHECK_HTYPE(long)
 701 FPTOOLS_CHECK_HTYPE(unsigned long)
 702 if test "$fptools_cv_have_long_long" = yes; then
 703 FPTOOLS_CHECK_HTYPE(long long)
 704 FPTOOLS_CHECK_HTYPE(unsigned long long)
 705 fi
 706 FPTOOLS_CHECK_HTYPE(float)
 707 FPTOOLS_CHECK_HTYPE(double)
 708 FPTOOLS_CHECK_HTYPE(ptrdiff_t)
 709 FPTOOLS_CHECK_HTYPE(size_t)
 710 FPTOOLS_CHECK_HTYPE(wchar_t)
 711 dnl Int32 is a HACK for non-ISO C compilers
 712 FPTOOLS_CHECK_HTYPE(sig_atomic_t, Int32)
 713 FPTOOLS_CHECK_HTYPE(clock_t)
 714 FPTOOLS_CHECK_HTYPE(time_t)
 715
 716 dnl ** Map OpenGL data types to Haskell types
 717 if test $GhcLibsWithHOpenGL = YES ; then
 718 FPTOOLS_CHECK_HTYPE(GLboolean)
 719 FPTOOLS_CHECK_HTYPE(GLbyte)
 720 FPTOOLS_CHECK_HTYPE(GLubyte)
 721 FPTOOLS_CHECK_HTYPE(GLshort)
 722 FPTOOLS_CHECK_HTYPE(GLushort)
 723 FPTOOLS_CHECK_HTYPE(GLint)
 724 FPTOOLS_CHECK_HTYPE(GLuint)
 725 FPTOOLS_CHECK_HTYPE(GLsizei)
 726 FPTOOLS_CHECK_HTYPE(GLenum)
 727 FPTOOLS_CHECK_HTYPE(GLbitfield)
 728 FPTOOLS_CHECK_HTYPE(GLfloat)
 729 FPTOOLS_CHECK_HTYPE(GLclampf)
 730 FPTOOLS_CHECK_HTYPE(GLdouble)
 731 FPTOOLS_CHECK_HTYPE(GLclampd)
 732 fi
 733
 734 FPTOOLS_CHECK_CCONSTS(E2BIG EACCES EADDRINUSE EADDRNOTAVAIL EADV EAFNOSUPPORT EAGAIN EALREADY EBADF EBADMSG EBADRPC EBUSY ECHILD ECOMM ECONNABORTED ECONNREFUSED ECONNRESET EDEADLK EDESTADDRREQ EDIRTY EDOM EDQUOT EEXIST EFAULT EFBIG EFTYPE EHOSTDOWN EHOSTUNREACH EIDRM EILSEQ EINPROGRESS EINTR EINVAL EIO EISCONN EISDIR ELOOP EMFILE EMLINK EMSGSIZE EMULTIHOP ENAMETOOLONG ENETDOWN ENETRESET ENETUNREACH ENFILE ENOBUFS ENODATA ENODEV ENOENT ENOEXEC ENOLCK ENOLINK ENOMEM ENOMSG ENONET ENOPROTOOPT ENOSPC ENOSR ENOSTR ENOSYS ENOTBLK ENOTCONN ENOTDIR ENOTEMPTY ENOTSOCK ENOTTY ENXIO EOPNOTSUPP EPERM EPFNOSUPPORT EPIPE EPROCLIM EPROCUNAVAIL EPROGMISMATCH EPROGUNAVAIL EPROTO EPROTONOSUPPORT EPROTOTYPE ERANGE EREMCHG EREMOTE EROFS ERPCMISMATCH ERREMOTE ESHUTDOWN ESOCKTNOSUPPORT ESPIPE ESRCH ESRMNT ESTALE ETIME ETIMEDOUT ETOOMANYREFS ETXTBSY EUSERS EWOULDBLOCK EXDEV)
 735
 736 dnl ** can we open files in binary mode?
 737 FPTOOLS_O_BINARY
 738
 739 dnl ** check for GetModuleFileName and WinExec (windows only)
 740 dnl Old: AC_CHECK_FUNCS(WinExec GetModuleFileName)       dnl Windows
 741 dnl Doesn't work because the linker can't see the functions if
 742 dnl you omit the #include <windows.h>.  (I've no idea why not...)
 743
 744 FPTOOLS_TRY_LINK_NOWARN(,[
 745 #if HAVE_WINDOWS_H
 746 #include <windows.h>
 747 #endif
 748 main() {
 749   WinExec("",0);
 750   exit(0);
 751 }
 752 ],
 753 [have_winexec=1],
 754 [have_winexec=0])
 755 if test "$have_winexec" = "1"; then
 756 AC_DEFINE(HAVE_WINEXEC)
 757 fi
 758
 759 FPTOOLS_TRY_LINK_NOWARN(,[
 760 #if HAVE_WINDOWS_H
 761 #include <windows.h>
 762 #endif
 763 main() {
 764   char* dir;
 765   GetModuleFileName((HMODULE)0,dir,0);
 766   exit(0);
 767 }
 768 ],
 769 [have_getmodulefilename=1],
 770 [have_getmodulefilename=0])
 771 if test "$have_getmodulefilename" = "1"; then
 772 AC_DEFINE(HAVE_GETMODULEFILENAME)
 773 fi
 774
 775 dnl ** check return type of signal handlers
 776 dnl Foo: assumes we can use prototypes.
 777 dnl On BCC, signal handlers have type "int(void)", elsewhere its "void(int)".
 778 dnl AC_CACHE_CHECK([type of signal handlers], ac_cv_type_signal_handler,
 779 dnl [AC_TRY_COMPILE([#include <sys/types.h>
 780 dnl #include <signal.h>
 781 dnl #ifdef signal
 782 dnl #undef signal
 783 dnl #endif
 784 dnl void (*signal (int, void (*)(int)))(int);
 785 dnl ],
 786 dnl [int i;],
 787 dnl ac_cv_type_signal_handler=void_int,
 788 dnl ac_cv_type_signal_handler=int_void)])
 789 dnl if test "$ac_cv_type_signal_handler" = void_int; then
 790 dnl AC_DEFINE(VOID_INT_SIGNALS)
 791 dnl fi
 792
 793 dnl On BCC, signal handlers have type "int(void)", elsewhere its "void(int)".
 794 AC_TYPE_SIGNAL
 795 if test "$ac_cv_type_signal" = void; then
 796 AC_DEFINE(VOID_INT_SIGNALS)
 797 fi
 798
 799 dnl ** check for more functions
 800 AC_CHECK_FUNCS(strcasecmp _stricmp stricmp strcmpi)
 801 AC_CHECK_FUNCS(strcmp)
 802 AC_CHECK_FUNCS(realpath _fullpath)
 803 AC_CHECK_FUNCS(PBHSetVolSync macsystem)
 804 AC_CHECK_FUNCS(fgetpos fsetpos fseek ftell)
 805 AC_CHECK_FUNCS(vsnprintf _vsnprintf)
 806 AC_CHECK_FUNCS(snprintf  _snprintf )
 807 AC_CHECK_FUNCS(popen     _popen )
 808 AC_CHECK_FUNCS(pclose    _pclose )
 809
 810
 811 dnl ** check for specific library functions that we are interested in
 812 AC_CHECK_FUNCS(access ftime getclock getpagesize getrusage gettimeofday mktime mprotect readlink setitimer stat symlink sysconf timelocal times vadvise vfork)
 813
 814 dnl ** check whether this machine has gmp3 installed
 815 AC_CHECK_LIB(gmp,  __gmpz_fdiv_qr, HaveLibGmp=YES; LibGmp=gmp,
 816   AC_CHECK_LIB(gmp3, __gmpz_fdiv_qr,  HaveLibGmp=YES; LibGmp=gmp3,
 817     HaveLibGmp=No; LibGmp=not-installed))
 818 AC_SUBST(HaveLibGmp)
 819 AC_SUBST(LibGmp)
 820
 821 dnl ** check whether this machine has GNU regex in libc.
 822 FPTOOLS_REGEX_IN_LIBC
 823
 824 dnl ** check whether this machine has BFD and liberty installed (used for debugging)
 825 dnl    the order of these tests matters: bfd needs liberty
 826 AC_CHECK_LIB(iberty, xmalloc)
 827 AC_CHECK_LIB(bfd,    bfd_init)
 828
 829 dnl ** check for readline, for Hugs and hslibs' Readline
 830 dnl ncurses supersedes termcap and curses, but for compatibility,
 831 dnl we have to check for all...
 832 AC_CHECK_LIB(ncurses, tputs, HaveLibTermcap=YES; LibTermcap=ncurses,
 833   AC_CHECK_LIB(termcap, tputs, HaveLibTermcap=YES; LibTermcap=termcap,
 834     AC_CHECK_LIB(curses, tputs, HaveLibTermcap=YES; LibTermcap=curses,
 835       HaveLibTermcap=NO; LibTermcap=not-installed)))
 836
 837 if test $HaveLibTermcap = YES ; then
 838   LIBS="-l$LibTermcap $LIBS"
 839   AC_CHECK_LIB(readline, readline, HaveLibReadline=YES, HaveLibReadline=NO)
 840 fi
 841
 842 if test $HaveLibTermcap = YES && test x"$HaveLibReadline" = xYES ; then
 843   AC_DEFINE(HAVE_READLINE_LIBS,1)
 844   LibsReadline="readline $LibTermcap"
 845 else
 846   AC_DEFINE(HAVE_READLINE_LIBS,0)
 847   LibsReadline=
 848 fi
 849 AC_SUBST(LibsReadline)
 850
 851 if test "$HaveLibReadline"; then
 852   AC_CHECK_LIB(readline, rl_erase_empty_line,
 853     [AC_DEFINE(HAVE_READLINE_4, 1)],
 854     [AC_DEFINE(HAVE_READLINE_4, 0)])
 855   AC_CHECK_LIB(readline, rl_free_undo_list,
 856     [AC_DEFINE(HAVE_READLINE_4_2, 1)],
 857     [AC_DEFINE(HAVE_READLINE_4_2, 0)])
 858 else
 859   AC_DEFINE(HAVE_READLINE_4, 0)
 860   AC_DEFINE(HAVE_READLINE_4_2, 0)
 861 fi
 862
 863 dnl ** check for math library
 864 FPTOOLS_CHECK_LIBM()
 865 AC_SUBST(LIBM)
 866
 867 case $HostOS_CPP in
 868 cygwin32) ;;
 869 mingw32)  ;;
 870 *) AC_PATH_XTRA() ;;
 871 esac
 872
 873 dnl ################################################################
 874 dnl Check for libraries
 875 dnl ################################################################
 876
 877 AC_CHECK_LIB(dl, dlopen,
 878         [HaveLibDL=YES
 879          AC_DEFINE(HAVE_LIBDL)
 880          LIBS="$LIBS -ldl"],
 881         [HaveLibDL=NO])
 882 AC_CHECK_FUNCS(dlopen)
 883 AC_SUBST(HaveLibDL)
 884
 885 FPTOOLS_CHECK_LIB_NOWARN(m, atan)
 886
 887 dnl --------------------------------------------------
 888 dnl * test for GTK+
 889 dnl --------------------------------------------------
 890
 891 AC_PATH_PROGS(GTK_CONFIG, gtk-config gtk12-config)
 892 if test "$GTK_CONFIG" != ""; then
 893    AC_CACHE_CHECK([for version of GTK+], fptools_cv_gtk_version, [
 894         fptools_cv_gtk_version=`$GTK_CONFIG --version`
 895     ])
 896     GTK_VERSION=$fptools_cv_gtk_version
 897 else
 898     GTK_VERSION=
 899 fi
 900
 901 case $fptools_cv_gtk_version in
 902   1.[[23]].*) ;;
 903   *) AC_MSG_WARN([GTK+ not usable; need at least version 1.2])
 904      GTK_CONFIG=
 905      ;;
 906 esac
 907
 908 AC_SUBST(GTK_CONFIG)
 909 AC_SUBST(GTK_VERSION)
 910
 911 dnl --------------------------------------------------
 912 dnl * Miscellaneous feature tests
 913 dnl --------------------------------------------------
 914
 915 dnl ** can we get alloca?
 916 AC_FUNC_ALLOCA
 917
 918 dnl ** determine whether or not const works
 919 AC_C_CONST
 920
 921 dnl ** determine whether ANSI-function prototypes work?
 922 AC_C_PROTOTYPES
 923
 924 dnl ** are we big endian?
 925 AC_C_BIGENDIAN
 926 # Allay users' general fear of warnings of any kind.
 927 errprint((fptools configure script wizard sez: "don't worry, the above warning is harmless (to us.)")
 928 )
 929
 930 dnl ** check for leading underscores in symbol names
 931 FPTOOLS_UNDERSCORE
 932
 933 dnl ** how is the end of text section signalled?
 934 FPTOOLS_END_TEXT_SECTION
 935
 936 dnl ** how is the end of data section signalled?
 937 FPTOOLS_END_DATA_SECTION
 938
 939 dnl ** code before data?
 940 FPTOOLS_CODE_BEFORE_DATA
 941
 942
 943 AC_OUTPUT(mk/config.mk, echo timestamp > mk/stamp-h )