configure.in

   1 dnl == autoconf source for the Glasgow FP tools ==
   2 dnl (run "grep '^dnl \*' configure.in | sed -e 's/dnl / /g; s/\*\*/   +/g;'"
   3 dnl  (or some such) to see the outline of this file)
   4 dnl
   5 #
   6 # (c) The AQUA Project, Glasgow University, 1994-1998
   7 #
   8 # Configure script template for the Glasgow functional programming tools
   9 #
  10 # Process with 'autoconf' to get a working configure script.
  11 #
  12 # For the generated configure script, do "./configure --help" to
  13 # see what flags are available. (Better yet, read the documentation!)
  14 #
  15
  16 # First off, a distrib sanity check..
  17 AC_INIT(mk/config.mk.in)
  18
  19 dnl * Declare subdirectories that have a private configure script
  20 dnl
  21 dnl After the toplevel configuration is complete, the script will recurse into
  22 dnl these subdirectories (the use of cache values makes repeated checks cheap)
  23 dnl (We probably have to add hslibs/{OpenGL,GLUT} here later...)
  24 AC_CONFIG_SUBDIRS(ghc)
  25
  26 # -------------------------------------------------------------------------
  27 # Prepare to generate the following header files
  28 #
  29 #
  30 AC_CONFIG_HEADER(mk/config.h)
  31
  32 # No, semi-sadly, we don't do `--srcdir'...
  33 if test x"$srcdir" != 'x.' ; then
  34     echo "This configuration does not support the \`--srcdir' option.."
  35     exit 1
  36 fi
  37
  38 #
  39 # Remove common automounter nonsense + convert from UNC to DOS style paths
  40 # (UNC awareness isn't quite there yet for cygwin32-beta18 and consituent tools.)
  41 #
  42 hardtop=`pwd`
  43 hardtop=`echo $hardtop | sed 's|^/tmp_mnt.*\(/local/.*\)$|\1|' | sed 's|^/tmp_mnt/|/|' | sed 's|^/grasp_tmp|/local/grasp_tmp|' | sed 's|^//\(.\)/|\1:/|' `
  44
  45 echo ''
  46 echo "*** The top of your build tree is: $hardtop"
  47 AC_SUBST(hardtop)
  48
  49 dnl--------------------------------------------------------------------
  50 dnl * Choose host(/target/build) platform
  51 dnl--------------------------------------------------------------------
  52
  53 dnl Guess host/target/build platform(s) if necessary.
  54 AC_CANONICAL_SYSTEM
  55
  56 # "$host" defaults to "$target"
  57 if test "x$host" = xNONE ; then
  58     host=$target
  59 fi
  60
  61 dnl ** canonicalize platform names
  62 BuildPlatform=`/bin/sh $srcdir/config.sub $build` || exit 1
  63 HostPlatform=`/bin/sh $srcdir/config.sub $host` || exit 1
  64 TargetPlatform=`/bin/sh $srcdir/config.sub $target` || exit 1
  65
  66 if test x"$TargetPlatform" != x"$HostPlatform" ; then
  67     echo "GHC configuration does not support differing host/target (i.e., cross-compiling)"
  68     exit 1
  69 fi
  70
  71 exeext=''
  72 #
  73 # The following will be more difficult when we *are* cross-compiling.
  74 # Suitable names to slam in *_CPP are in platform.h.in.
  75 # We also record the architecture, vendor, and operating system (OS)
  76 # separately.
  77 case $HostPlatform in
  78 alpha-dec-osf[[12]]*)
  79         HostPlatform=alpha-dec-osf1   # canonicalise for our purposes
  80         TargetPlatform=alpha-dec-osf1 # this will work for now... (hack)
  81         BuildPlatform=alpha-dec-osf1  # hack
  82         HostPlatform_CPP='alpha_dec_osf1'
  83         HostArch_CPP='alpha'
  84         HostVendor_CPP='dec'
  85         HostOS_CPP='osf1'
  86         ;;
  87 alpha-dec-osf[[34]]*)
  88         HostPlatform=alpha-dec-osf3   # canonicalise for our purposes
  89         TargetPlatform=alpha-dec-osf3 # this will work for now... (hack)
  90         BuildPlatform=alpha-dec-osf3  # hack
  91         HostPlatform_CPP='alpha_dec_osf3'
  92         HostArch_CPP='alpha'
  93         HostVendor_CPP='dec'
  94         HostOS_CPP='osf3'
  95         ;;
  96 alpha-unknown-linux)
  97         HostPlatform=alpha-unknown-linux
  98         TargetPlatform=alpha-unknown-linux
  99         BuildPlatform=alpha-unknown-linux
 100         HostPlatform_CPP='alpha_unknown_linux'
 101         HostArch_CPP='alpha'
 102         HostVendor_CPP='unknown'
 103         HostOS_CPP='linux'
 104         ;;
 105 alpha-unknown-freebsd*)
 106         HostPlatform=alpha-unknown-freebsd
 107         TargetPlatform=alpha-unknown-freebsd
 108         BuildPlatform=alpha-unknown-freebsd
 109         HostPlatform_CPP='alpha_unknown_freebsd'
 110         HostArch_CPP='alpha'
 111         HostVendor_CPP='unknown'
 112         HostOS_CPP='freebsd'
 113         ;;
 114 hppa1.1-hp-hpux*)
 115         HostPlatform=hppa1.1-hp-hpux  # canonicalise for our purposes (hack)
 116         TargetPlatform=hppa1.1-hp-hpux
 117         BuildPlatform=hppa1.1-hp-hpux
 118         HostPlatform_CPP='hppa1_1_hp_hpux'
 119         HostArch_CPP='hppa1_1'
 120         HostVendor_CPP='hp'
 121         HostOS_CPP='hpux'
 122         ;;
 123 i[[3456]]86-*-linuxaout*)
 124         HostPlatform=i386-unknown-linuxaout   # hack again
 125         TargetPlatform=i386-unknown-linuxaout
 126         BuildPlatform=i386-unknown-linuxaout
 127         HostPlatform_CPP='i386_unknown_linuxaout'
 128         HostArch_CPP='i386'
 129         HostVendor_CPP='unknown'
 130         HostOS_CPP='linuxaout'
 131         ;;
 132 i[[3456]]86-*-linux*)
 133         HostPlatform=i386-unknown-linux # hack again
 134         TargetPlatform=i386-unknown-linux
 135         BuildPlatform=i386-unknown-linux
 136         HostPlatform_CPP='i386_unknown_linux'
 137         HostArch_CPP='i386'
 138         HostVendor_CPP='unknown'
 139         HostOS_CPP='linux'
 140         ;;
 141 i[[3456]]86-*-freebsd[[3-9]]*) # FreeBSD 3.0+ uses ELF
 142         HostPlatform=i386-unknown-freebsd # hack again
 143         TargetPlatform=i386-unknown-freebsd
 144         BuildPlatform=i386-unknown-freebsd
 145         HostPlatform_CPP='i386_unknown_freebsd'
 146         HostArch_CPP='i386'
 147         HostVendor_CPP='unknown'
 148         HostOS_CPP='freebsd'
 149         ;;
 150 i[[3456]]86-*-freebsd2*) # Older FreeBSDs are a.out
 151         HostPlatform=i386-unknown-freebsd2 # hack again
 152         TargetPlatform=i386-unknown-freebsd2
 153         BuildPlatform=i386-unknown-freebsd2
 154         HostPlatform_CPP='i386_unknown_freebsd2'
 155         HostArch_CPP='i386'
 156         HostVendor_CPP='unknown'
 157         HostOS_CPP='freebsd2'
 158         ;;
 159 i[[3456]]86-*-netbsd*)
 160         HostPlatform=i386-unknown-netbsd # hack again
 161         TargetPlatform=i386-unknown-netbsd
 162         BuildPlatform=i386-unknown-netbsd
 163         HostPlatform_CPP='i386_unknown_netbsd'
 164         HostArch_CPP='i386'
 165         HostVendor_CPP='unknown'
 166         HostOS_CPP='netbsd'
 167         ;;
 168 i[[3456]]86-*-openbsd*)
 169         HostPlatform=i386-unknown-openbsd # hack again
 170         TargetPlatform=i386-unknown-openbsd
 171         BuildPlatform=i386-unknown-openbsd
 172         HostPlatform_CPP='i386_unknown_openbsd'
 173         HostArch_CPP='i386'
 174         HostVendor_CPP='unknown'
 175         HostOS_CPP='openbsd'
 176         ;;
 177 i[[3456]]86-*-solaris2*)
 178         HostPlatform=i386-unknown-solaris2 # hack again
 179         TargetPlatform=i386-unknown-solaris2
 180         BuildPlatform=i386-unknown-solaris2
 181         HostPlatform_CPP='i386_unknown_solaris2'
 182         HostArch_CPP='i386'
 183         HostVendor_CPP='unknown'
 184         HostOS_CPP='solaris2'
 185         ;;
 186 i[[3456]]86-*-cygwin*)
 187         HostPlatform=i386-unknown-cygwin32 # hack again
 188         TargetPlatform=i386-unknown-cygwin32
 189         BuildPlatform=i386-unknown-cygwin32
 190         HostPlatform_CPP='i386_unknown_cygwin32'
 191         HostArch_CPP='i386'
 192         HostVendor_CPP='unknown'
 193         HostOS_CPP='cygwin32'
 194         exeext='.exe'
 195         ;;
 196 i[[3456]]86-*-mingw32*)
 197         HostPlatform=i386-unknown-mingw32 # hack again
 198         TargetPlatform=i386-unknown-mingw32
 199         BuildPlatform=i386-unknown-mingw32
 200         HostPlatform_CPP='i386_unknown_mingw32'
 201         HostArch_CPP='i386'
 202         HostVendor_CPP='unknown'
 203         HostOS_CPP='mingw32'
 204         exeext='.exe'
 205         # We assume you're using mingw32 via the gcc that comes
 206         # with cygwin, and not the native port, so let's augment
 207         # the gcc command-line used here with -mno-cygwin to
 208         # arrange for good things to happen.
 209         CFLAGS="-mno-cygwin $CFLAGS"
 210         CPPFLAGS="-mno-cygwin $CPPFLAGS"
 211         ;;
 212 m68k-next-nextstep2)
 213         HostPlatform_CPP='m68k_next_nextstep2'
 214         HostArch_CPP='m68k'
 215         HostVendor_CPP='next'
 216         HostOS_CPP='nextstep2'
 217         ;;
 218 m68k-next-nextstep3)
 219         HostPlatform_CPP='m68k_next_nextstep3'
 220         HostArch_CPP='m68k'
 221         HostVendor_CPP='next'
 222         HostOS_CPP='nextstep3'
 223         ;;
 224 i[[3456]]86-next-nextstep3)
 225         HostPlatform=i386-next-nextstep3 # hack again
 226         TargetPlatform=i386-next-nextstep3
 227         BuildPlatform=i386-next-nextstep3
 228         HostPlatform_CPP='i386_next_nextstep3'
 229         HostArch_CPP='i386'
 230         HostVendor_CPP='next'
 231         HostOS_CPP='nextstep3'
 232         ;;
 233 m68k-sun-sunos4*)
 234         HostPlatform=m68k-sun-sunos4
 235         TargetPlatform=m68k-sun-sunos4 #hack
 236         BuildPlatform=m68k-sun-sunos4 #hack
 237         HostPlatform_CPP='m68k_sun_sunos4'
 238         HostArch_CPP='m68k'
 239         HostVendor_CPP='sun'
 240         HostOS_CPP='sunos4'
 241         ;;
 242 mips-dec-ultrix*)
 243         HostPlatform_CPP='mips_dec_ultrix'
 244         HostArch_CPP='mipsel'   # NB a little different
 245         HostVendor_CPP='dec'
 246         HostOS_CPP='ultrix'
 247         ;;
 248 mips-sgi-irix*)
 249         HostPlatform=mips-sgi-irix
 250         TargetPlatform=mips-sgi-irix #hack
 251         BuildPlatform=mips-sgi-irix #hack
 252         HostPlatform_CPP='mips_sgi_irix'
 253         HostArch_CPP='mipseb'   # NB a little different
 254         HostVendor_CPP='sgi'
 255         HostOS_CPP='irix'
 256         ;;
 257 rs6000-ibm-aix*)
 258         HostPlatform=rs6000-ibm-aix
 259         TargetPlatform=rs6000-ibm-aix #hack
 260         BuildPlatform=rs6000-ibm-aix #hack
 261         HostPlatform_CPP='rs6000_ibm_aix'
 262         HostArch_CPP='rs6000'
 263         HostVendor_CPP='ibm'
 264         HostOS_CPP='aix'
 265         ;;
 266 powerpc-ibm-aix*)
 267         HostPlatform=powerpc-ibm-aix
 268         TargetPlatform=powerpc-ibm-aix #hack
 269         BuildPlatform=powerpc-ibm-aix #hack
 270         HostPlatform_CPP='powerpc_ibm_aix'
 271         HostArch_CPP='powerpc'
 272         HostVendor_CPP='ibm'
 273         HostOS_CPP='aix'
 274         ;;
 275 powerpc-apple-macosx*)
 276       HostPlatform=powerpc-apple-macosx
 277       TargetPlatform=powerpc-apple-macosx #hack
 278       BuildPlatform=powerpc-apple-macosx #hack
 279         HostPlatform_CPP='powerpc_apple_macosx'
 280         HostArch_CPP='powerpc'
 281         HostVendor_CPP='apple'
 282         HostOS_CPP='macosx'
 283         ;;
 284 sparc-sun-sunos4*)
 285         HostPlatform=sparc-sun-sunos4
 286         TargetPlatform=sparc-sun-sunos4 #hack
 287         BuildPlatform=sparc-sun-sunos4 #hack
 288         HostPlatform_CPP='sparc_sun_sunos4'
 289         HostArch_CPP='sparc'
 290         HostVendor_CPP='sun'
 291         HostOS_CPP='sunos4'
 292         ;;
 293 sparc-sun-solaris2*)
 294         HostPlatform=sparc-sun-solaris2
 295         TargetPlatform=sparc-sun-solaris2 #hack
 296         BuildPlatform=sparc-sun-solaris2 #hack
 297         HostPlatform_CPP='sparc_sun_solaris2'
 298         HostArch_CPP='sparc'
 299         HostVendor_CPP='sun'
 300         HostOS_CPP='solaris2'
 301         ;;
 302 *)
 303         echo "Unrecognised platform: $HostPlatform"
 304         exit 1
 305         ;;
 306 esac
 307 echo "Canonicalised to: $HostPlatform"
 308 test  x"$HostPlatform" != x"$TargetPlatform" && echo "Target platform set to $TargetPlatform"
 309 test  x"$BuildPlatform" != x"$HostPlatform"  && echo "Build platform set to $BuildPlatform"
 310
 311 BuildPlatform_CPP=$HostPlatform_CPP
 312 TargetPlatform_CPP=$HostPlatform_CPP
 313 BuildArch_CPP=$HostArch_CPP
 314 TargetArch_CPP=$HostArch_CPP
 315 BuildOS_CPP=$HostOS_CPP
 316 HostOS_Full=$host_os
 317 TargetOS_CPP=$HostOS_CPP
 318 BuildVendor_CPP=$HostVendor_CPP
 319 TargetVendor_CPP=$HostVendor_CPP
 320
 321 dnl Cannot afford all these SUBSTs (because of braindead seds w/ 99 cmd limits)
 322 dnl AC_SUBST(BuildPlatform)
 323
 324 AC_SUBST(HostPlatform)
 325 AC_SUBST(TargetPlatform)
 326 AC_SUBST(HostPlatform_CPP)
 327 dnl AC_SUBST(BuildPlatform_CPP)
 328 dnl AC_SUBST(TargetPlatform_CPP)
 329
 330 AC_SUBST(HostArch_CPP)
 331 dnl AC_SUBST(BuildArch_CPP)
 332 dnl AC_SUBST(TargetArch_CPP)
 333
 334 AC_SUBST(HostOS_CPP)
 335 AC_SUBST(HostOS_Full)
 336 dnl AC_SUBST(BuildOS_CPP)
 337 dnl AC_SUBST(TargetOS_CPP)
 338
 339 AC_SUBST(HostVendor_CPP)
 340 dnl AC_SUBST(BuildVendor_CPP)
 341 dnl AC_SUBST(TargetVendor_CPP)
 342
 343 AC_SUBST(exeext)
 344
 345 dnl --------------------------------------------------------------
 346 dnl * Project specific configuration options
 347 dnl --------------------------------------------------------------
 348 dnl What follows is a bunch of options that can either be configured
 349 dnl through command line options to the configure script or by
 350 dnl supplying defns in the build tree's mk/build.mk. Having the option to
 351 dnl use either is considered a Feature.
 352
 353 dnl ** What command to use to compile compiler sources ?
 354 dnl --------------------------------------------------------------
 355 if test "$GHC" = ""; then
 356   AC_PATH_PROG(GHC,ghc)
 357 fi
 358
 359 AC_ARG_WITH(ghc,
 360 [  --with-ghc=<haskell compiler>
 361         Use a command different from 'ghc' to compile GHC-specific Haskell code
 362             (including GHC itself).
 363 ],
 364 [WithGhc="$withval"],
 365 [WithGhc=$GHC]
 366 )
 367 AC_SUBST(WithGhc)
 368
 369 AC_ARG_WITH(hc,
 370 [  --with-hc=<haskell compiler>
 371         Use a command different from 'ghc' to compile generic Haskell code.
 372 ],
 373 [WithHc="$withval"],
 374 [WithHc=$WithGhc]
 375 )
 376 AC_SUBST(WithHc)
 377
 378 if test "$WithGhc" != ""; then
 379   FPTOOLS_GHC_VERSION([GhcVersion], [GhcMajVersion], [GhcMinVersion], [GhcPatchLevel])dnl
 380   AC_SUBST(GhcVersion)dnl
 381   AC_SUBST(GhcMajVersion)dnl
 382   AC_SUBST(GhcMinVersion)dnl
 383   AC_SUBST(GhcPatchLevel)dnl
 384 fi
 385
 386 AC_PATH_PROGS(NHC,nhc nhc98)
 387 AC_PATH_PROG(HBC,hbc)
 388
 389 dnl ** Which gcc to use?
 390 dnl --------------------------------------------------------------
 391 AC_ARG_WITH(gcc,
 392 [  --with-gcc=<gcc command>
 393         Use a different command instead of 'gcc' for the GNU C compiler.
 394 ],
 395 [WhatGccIsCalled="$withval"],
 396 [WhatGccIsCalled="gcc"]
 397 )
 398 AC_SUBST(WhatGccIsCalled)
 399
 400 dnl ** Booting from .hc files?
 401 dnl --------------------------------------------------------------
 402 AC_ARG_ENABLE(hc-boot,
 403 [  --enable-hc-boot
 404         Boot the Glasgow Haskell Compiler from intermediate .hc files.
 405         (This option is mostly of interest to porters.)
 406 ],
 407 [BootingFromHc=YES],
 408 [BootingFromHc=NO]
 409 )
 410 AC_SUBST(BootingFromHc)
 411
 412
 413 dnl ** Enable the construction of Win32 DLLs?
 414 dnl --------------------------------------------------------------
 415 AC_ARG_ENABLE(win32-dlls,
 416 [  --enable-win32-dlls
 417         If on a Win32 platform running mingw32/cygwin, enable the
 418         construction of DLLs containing ghc-compiled code.
 419 ],
 420 [
 421 case $HostOS_CPP in
 422 cygwin32) ;;
 423 mingw32)  ;;
 424 *)    echo "Unrecognised win32 platform: $HostPlatform"
 425       exit 1
 426       ;;
 427 esac
 428 EnableWin32DLLs=YES
 429 ],
 430 [EnableWin32DLLs=NO]
 431 )
 432 AC_SUBST(EnableWin32DLLs)
 433 if test x"$EnableWin32DLLs" = "xYES" ; then
 434  AC_DEFINE(HAVE_WIN32_DLL_SUPPORT)
 435 fi
 436
 437 dnl ** Enable the building of the OpenGL/GLUT binding in hslibs?
 438 dnl --------------------------------------------------------------
 439 AC_ARG_ENABLE(hopengl,
 440 [  --enable-hopengl
 441         Build HOpenGL, a Haskell binding for OpenGL/GLUT, too.
 442         (This option is only relevant when hslibs are built.)
 443 ],
 444 [GhcLibsWithHOpenGL=YES],
 445 [GhcLibsWithHOpenGL=NO]
 446 )
 447 AC_SUBST(GhcLibsWithHOpenGL)
 448
 449 dnl ** Use a specific version of the GLUT API
 450 dnl --------------------------------------------------------------
 451 AC_ARG_WITH(glut-api,
 452 [  --with-glut-api=<version>
 453         Use a specific version of the GLUT API when building HOpenGL.
 454 ])
 455 test -n "$with_glut_api"  && CPPFLAGS="$CPPFLAGS -DGLUT_API_VERSION=$with_glut_api"
 456
 457
 458 dnl ** Use a specific version of the GLUT API
 459 dnl --------------------------------------------------------------
 460 AC_ARG_WITH(glut-xlib,
 461 [  --with-glut-xlib=<version>
 462         Use a specific version of the GLUT Xlib implementation when building HOpenGL.
 463 ])
 464 test -n "$with_glut_xlib" && CPPFLAGS="$CPPFLAGS -DGLUT_XLIB_IMPLEMENTATION=$with_glut_xlib"
 465
 466
 467 dnl --------------------------------------------------------------
 468 dnl End of configure script option section
 469 dnl --------------------------------------------------------------
 470
 471
 472 dnl --------------------------------------------------------------
 473 dnl * General configuration checks
 474 dnl --------------------------------------------------------------
 475
 476 dnl ** does #! work?
 477 AC_SYS_INTERPRETER()
 478
 479 dnl ** look for `perl', but only in /bin on Windows
 480 case $HostOS_CPP in
 481 cygwin32|mingw32)
 482    AC_CHECK_PROG(PerlCmd,perl,/bin/perl,,/bin)
 483    if test -z "$PerlCmd"; then
 484       echo "You must install the version of Perl shipped with GHC"
 485       echo "(or a compatible one) in /bin."
 486       exit 1
 487    fi
 488    ;;
 489 *)
 490    AC_PATH_PROG(PerlCmd,perl)
 491    if test -z "$PerlCmd"; then
 492       echo "You must install perl before you can continue"
 493       echo "Perhaps it is already installed, but not in your PATH?"
 494       exit 1
 495    else
 496    FPTOOLS_CHECK_PERL_VERSION
 497    fi
 498    ;;
 499 esac
 500
 501 dnl ** does #! path/to/perl work? (sometimes it's too long...)
 502 FPTOOLS_SHEBANG_PERL
 503
 504
 505 dnl ** look for GCC and find out which version
 506 dnl     Figure out which C compiler to use.  Gcc is preferred.
 507 dnl     If gcc, make sure it's at least 2.1
 508 dnl
 509 AC_PROG_CC
 510 FPTOOLS_HAVE_GCC
 511
 512 dnl ** figure out how to invoke cpp directly (gcc -E is no good)
 513 AC_PROG_CPP
 514
 515 dnl ** figure out how to do context diffs
 516 FPTOOLS_PROG_DIFF
 517
 518 dnl ** Find find command (for Win32's benefit)
 519 AC_PATH_PROG(FindCmd, find)
 520
 521 dnl ** look for a decent parser generator (bison preferred)
 522 dnl (FPTOOLS_PROG_YACCY is AC_PROG_YACC, but with some extra testing
 523 dnl  on the suitability of the 'yacc' returned.)
 524 FPTOOLS_PROG_YACCY
 525
 526 dnl ** Find lex command (lex or flex) and library (-ll or -lfl)
 527 dnl     ( not that we care about the latter, see mk/config.mk.in )
 528 AC_PROG_LEX
 529
 530
 531 dnl ** figure out how to do a BSD-ish install
 532 AC_PROG_INSTALL
 533
 534 dnl If you can run configure, you certainly have /bin/sh
 535 AC_DEFINE(HAVE_BIN_SH)
 536
 537 dnl ** how to invoke `ar' and `ranlib'
 538 FPTOOLS_PROG_AR_AND_RANLIB
 539
 540
 541 dnl ** Check to see whether ln -s works
 542 AC_PROG_LN_S
 543
 544
 545 dnl ** Find the path to sed
 546 AC_PATH_PROG(SedCmd,sed)
 547
 548
 549 dnl ** check for time command
 550 AC_PATH_PROG(TimeCmd,time)
 551
 552
 553 dnl ** check for tar
 554 dnl   if GNU tar is named gtar, look for it first.
 555 AC_PATH_PROGS(TarCmd,gtar tar,tar)
 556
 557 dnl ** check for gzip/compress
 558 AC_PATH_PROGS(CompressCmd,gzip compress,gzip)
 559
 560 dnl ** check for jade/openjade & determine a working catalog
 561 AC_PATH_PROGS(JadeCmd,openjade jade,jade)
 562 FPTOOLS_DOCBOOK_CATALOG(Catalog, $JadeCmd, docs/fptools-both.dsl,
 563                         /etc/sgml.catalog /usr/share/sgml/CATALOG.docbkdsl $hardtop/glafp-utils/docbook/CATALOG*)
 564 if test -z "$Catalog"; then
 565   AC_MSG_RESULT([Warning: You will not be able to build the documentation.])
 566 fi
 567 AC_SUBST(Catalog)
 568
 569 compress_nm=`basename $CompressCmd`
 570 if test x"$compress_nm" = xgzip; then
 571   CompressCmd="$CompressCmd -d"
 572   CompressSuffix="gz"
 573 else
 574   CompressSuffix="Z"
 575 fi
 576 AC_SUBST(CompressCmd)
 577 AC_SUBST(CompressSuffix)
 578
 579 dnl ** check for installed happy binary + version
 580 dnl    (don't do it if we're booting from .hc files though.)
 581 if (test "$BootingFromHc" = "NO"); then
 582 FPTOOLS_HAPPY
 583 fi;
 584
 585 dnl --------------------------------------------------
 586 dnl ### program checking section ends here ###
 587 dnl --------------------------------------------------
 588
 589 dnl --------------------------------------------------
 590 dnl * Platform header file and syscall feature tests
 591 dnl ### checking the state of the local header files and syscalls ###
 592
 593 dnl ** check for full ANSI header (.h) files
 594 AC_HEADER_STDC
 595
 596 dnl ** check for specific header (.h) files that we are interested in
 597 AC_CHECK_HEADERS(Files.h assert.h console.h ctype.h dirent.h errno.h fcntl.h float.h ftw.h grp.h ieee754.h inttypes.h malloc.h memory.h nlist.h pascal.h pwd.h sgtty.h siginfo.h signal.h stat.h stdint.h stdlib.h stdarg.h string.h sys/fault.h sys/file.h sys/ioctl.h sys/limits.h sys/mman.h sys/param.h sys/procfs.h sys/resource.h sys/signal.h sys/socket.h netinet/tcp.h sys/stat.h sys/syscall.h sys/time.h sys/timeb.h sys/timers.h sys/times.h sys/types.h sys/utsname.h sys/vadvise.h sys/wait.h termio.h termios.h time.h types.h unistd.h utime.h values.h vfork.h bfd.h winsock.h)
 598
 599 AC_CHECK_HEADER(readline/readline.h, HaveReadlineReadlineH=YES, HaveReadlineReadlineH=NO)
 600 AC_CHECK_HEADER(readline/history.h, HaveReadlineHistoryH=YES, HaveReadlineHistoryH=NO)
 601
 602 if test $HaveReadlineReadlineH = YES && test $HaveReadlineHistoryH = YES ; then
 603   HaveReadlineHeaders=YES
 604   AC_DEFINE(HAVE_READLINE_HEADERS,1)
 605 else
 606   HaveReadlineHeaders=NO
 607   AC_DEFINE(HAVE_READLINE_HEADERS,0)
 608 fi
 609 AC_SUBST(HaveReadlineHeaders)
 610
 611 dnl ** check for DOS include files
 612 AC_CHECK_HEADERS(dos.h conio.h io.h std.h)
 613
 614 dnl ** check for Windows include files
 615 AC_CHECK_HEADERS(windows.h)
 616
 617 dnl ** check for OpenGL include files
 618 AC_CHECK_HEADERS(GL/gl.h)
 619
 620 dnl ** check if it is safe to include both <time.h> and <sys/time.h>
 621 AC_HEADER_TIME
 622
 623 dnl dynamic loading include files
 624 AC_CHECK_HEADERS(dlfcn.h dl.h)
 625
 626 dnl ** check for farcalloc (in bcc)
 627 AC_CHECK_HEADER(alloc.h,AC_CHECK_FUNCS(farcalloc))
 628
 629 dnl ** check for valloc (in sunos, solaris, mips, amiga, next, minix, ultrix)
 630 AC_CHECK_HEADER(malloc.h,AC_CHECK_FUNCS(valloc))
 631
 632 dnl ** how do we get a timezone name, and UTC offset ?
 633 AC_STRUCT_TIMEZONE
 634
 635 dnl ** what's the type of timezone?
 636 FPTOOLS_HAVE_TIMEZONE
 637 FPTOOLS_TYPE_TIMEZONE
 638
 639 dnl ** do we have altzone?
 640 FPTOOLS_ALTZONE
 641
 642 dnl ** does struct stat contain st_blksize?
 643 AC_STRUCT_ST_BLKSIZE
 644
 645 dnl ** do we have long longs?
 646 FPTOOLS_C_LONG_LONG
 647
 648 dnl ** what are the sizes of various types
 649 dnl    (these must come before GHC_CHECK_ALIGNMENT)
 650 AC_CHECK_SIZEOF(char,               1)
 651 AC_CHECK_SIZEOF(double,             8)
 652 AC_CHECK_SIZEOF(float,              4)
 653 AC_CHECK_SIZEOF(int,                4)
 654 AC_CHECK_SIZEOF(long,               4)
 655 if test "$fptools_cv_have_long_long" = yes; then
 656 AC_CHECK_SIZEOF(long long,          8)
 657 fi
 658 AC_CHECK_SIZEOF(short,              2)
 659 AC_CHECK_SIZEOF(unsigned char,      1)
 660 AC_CHECK_SIZEOF(unsigned int,       4)
 661 AC_CHECK_SIZEOF(unsigned long,      4)
 662 if test "$fptools_cv_have_long_long" = yes; then
 663 AC_CHECK_SIZEOF(unsigned long long, 8)
 664 fi
 665 AC_CHECK_SIZEOF(unsigned short,     2)
 666 AC_CHECK_SIZEOF(void *,             4)
 667
 668 dnl ** what are alignment constraints on various types
 669 FPTOOLS_CHECK_ALIGNMENT(char)
 670 FPTOOLS_CHECK_ALIGNMENT(double)
 671 FPTOOLS_CHECK_ALIGNMENT(float)
 672 FPTOOLS_CHECK_ALIGNMENT(int)
 673 FPTOOLS_CHECK_ALIGNMENT(long)
 674 if test "$fptools_cv_have_long_long" = yes; then
 675 FPTOOLS_CHECK_ALIGNMENT(long long)
 676 fi
 677 FPTOOLS_CHECK_ALIGNMENT(short)
 678 FPTOOLS_CHECK_ALIGNMENT(unsigned char)
 679 FPTOOLS_CHECK_ALIGNMENT(unsigned int)
 680 FPTOOLS_CHECK_ALIGNMENT(unsigned long)
 681 if test "$fptools_cv_have_long_long" = yes; then
 682 FPTOOLS_CHECK_ALIGNMENT(unsigned long long)
 683 fi
 684 FPTOOLS_CHECK_ALIGNMENT(unsigned short)
 685 FPTOOLS_CHECK_ALIGNMENT(void *)
 686
 687 dnl ** map standard C types and ISO types to Haskell types
 688 FPTOOLS_CHECK_HTYPE(char)
 689 FPTOOLS_CHECK_HTYPE(signed char)
 690 FPTOOLS_CHECK_HTYPE(unsigned char)
 691 FPTOOLS_CHECK_HTYPE(short)
 692 FPTOOLS_CHECK_HTYPE(unsigned short)
 693 FPTOOLS_CHECK_HTYPE(int)
 694 FPTOOLS_CHECK_HTYPE(unsigned int)
 695 FPTOOLS_CHECK_HTYPE(long)
 696 FPTOOLS_CHECK_HTYPE(unsigned long)
 697 if test "$fptools_cv_have_long_long" = yes; then
 698 FPTOOLS_CHECK_HTYPE(long long)
 699 FPTOOLS_CHECK_HTYPE(unsigned long long)
 700 fi
 701 FPTOOLS_CHECK_HTYPE(float)
 702 FPTOOLS_CHECK_HTYPE(double)
 703 FPTOOLS_CHECK_HTYPE(ptrdiff_t)
 704 FPTOOLS_CHECK_HTYPE(size_t)
 705 FPTOOLS_CHECK_HTYPE(wchar_t)
 706 dnl Int32 is a HACK for non-ISO C compilers
 707 FPTOOLS_CHECK_HTYPE(sig_atomic_t, Int32)
 708 FPTOOLS_CHECK_HTYPE(clock_t)
 709 FPTOOLS_CHECK_HTYPE(time_t)
 710
 711 dnl ** Map OpenGL data types to Haskell types
 712 if test $GhcLibsWithHOpenGL = YES ; then
 713 FPTOOLS_CHECK_HTYPE(GLboolean)
 714 FPTOOLS_CHECK_HTYPE(GLbyte)
 715 FPTOOLS_CHECK_HTYPE(GLubyte)
 716 FPTOOLS_CHECK_HTYPE(GLshort)
 717 FPTOOLS_CHECK_HTYPE(GLushort)
 718 FPTOOLS_CHECK_HTYPE(GLint)
 719 FPTOOLS_CHECK_HTYPE(GLuint)
 720 FPTOOLS_CHECK_HTYPE(GLsizei)
 721 FPTOOLS_CHECK_HTYPE(GLenum)
 722 FPTOOLS_CHECK_HTYPE(GLbitfield)
 723 FPTOOLS_CHECK_HTYPE(GLfloat)
 724 FPTOOLS_CHECK_HTYPE(GLclampf)
 725 FPTOOLS_CHECK_HTYPE(GLdouble)
 726 FPTOOLS_CHECK_HTYPE(GLclampd)
 727 fi
 728
 729 FPTOOLS_CHECK_CCONSTS(E2BIG EACCES EADDRINUSE EADDRNOTAVAIL EADV EAFNOSUPPORT EAGAIN EALREADY EBADF EBADMSG EBADRPC EBUSY ECHILD ECOMM ECONNABORTED ECONNREFUSED ECONNRESET EDEADLK EDESTADDRREQ EDIRTY EDOM EDQUOT EEXIST EFAULT EFBIG EFTYPE EHOSTDOWN EHOSTUNREACH EIDRM EILSEQ EINPROGRESS EINTR EINVAL EIO EISCONN EISDIR ELOOP EMFILE EMLINK EMSGSIZE EMULTIHOP ENAMETOOLONG ENETDOWN ENETRESET ENETUNREACH ENFILE ENOBUFS ENODATA ENODEV ENOENT ENOEXEC ENOLCK ENOLINK ENOMEM ENOMSG ENONET ENOPROTOOPT ENOSPC ENOSR ENOSTR ENOSYS ENOTBLK ENOTCONN ENOTDIR ENOTEMPTY ENOTSOCK ENOTTY ENXIO EOPNOTSUPP EPERM EPFNOSUPPORT EPIPE EPROCLIM EPROCUNAVAIL EPROGMISMATCH EPROGUNAVAIL EPROTO EPROTONOSUPPORT EPROTOTYPE ERANGE EREMCHG EREMOTE EROFS ERPCMISMATCH ERREMOTE ESHUTDOWN ESOCKTNOSUPPORT ESPIPE ESRCH ESRMNT ESTALE ETIME ETIMEDOUT ETOOMANYREFS ETXTBSY EUSERS EWOULDBLOCK EXDEV)
 730
 731 dnl ** can we open files in binary mode?
 732 FPTOOLS_O_BINARY
 733
 734 dnl ** check for GetModuleFileName and WinExec (windows only)
 735 dnl Old: AC_CHECK_FUNCS(WinExec GetModuleFileName)       dnl Windows
 736 dnl Doesn't work because the linker can't see the functions if
 737 dnl you omit the #include <windows.h>.  (I've no idea why not...)
 738
 739 FPTOOLS_TRY_LINK_NOWARN(,[
 740 #if HAVE_WINDOWS_H
 741 #include <windows.h>
 742 #endif
 743 main() {
 744   WinExec("",0);
 745   exit(0);
 746 }
 747 ],
 748 [have_winexec=1],
 749 [have_winexec=0])
 750 if test "$have_winexec" = "1"; then
 751 AC_DEFINE(HAVE_WINEXEC)
 752 fi
 753
 754 FPTOOLS_TRY_LINK_NOWARN(,[
 755 #if HAVE_WINDOWS_H
 756 #include <windows.h>
 757 #endif
 758 main() {
 759   char* dir;
 760   GetModuleFileName((HMODULE)0,dir,0);
 761   exit(0);
 762 }
 763 ],
 764 [have_getmodulefilename=1],
 765 [have_getmodulefilename=0])
 766 if test "$have_getmodulefilename" = "1"; then
 767 AC_DEFINE(HAVE_GETMODULEFILENAME)
 768 fi
 769
 770 dnl ** check return type of signal handlers
 771 dnl Foo: assumes we can use prototypes.
 772 dnl On BCC, signal handlers have type "int(void)", elsewhere its "void(int)".
 773 dnl AC_CACHE_CHECK([type of signal handlers], ac_cv_type_signal_handler,
 774 dnl [AC_TRY_COMPILE([#include <sys/types.h>
 775 dnl #include <signal.h>
 776 dnl #ifdef signal
 777 dnl #undef signal
 778 dnl #endif
 779 dnl void (*signal (int, void (*)(int)))(int);
 780 dnl ],
 781 dnl [int i;],
 782 dnl ac_cv_type_signal_handler=void_int,
 783 dnl ac_cv_type_signal_handler=int_void)])
 784 dnl if test "$ac_cv_type_signal_handler" = void_int; then
 785 dnl AC_DEFINE(VOID_INT_SIGNALS)
 786 dnl fi
 787
 788 dnl On BCC, signal handlers have type "int(void)", elsewhere its "void(int)".
 789 AC_TYPE_SIGNAL
 790 if test "$ac_cv_type_signal" = void; then
 791 AC_DEFINE(VOID_INT_SIGNALS)
 792 fi
 793
 794 dnl ** check for more functions
 795 AC_CHECK_FUNCS(strcasecmp _stricmp stricmp strcmpi)
 796 AC_CHECK_FUNCS(strcmp)
 797 AC_CHECK_FUNCS(realpath _fullpath)
 798 AC_CHECK_FUNCS(PBHSetVolSync macsystem)
 799 AC_CHECK_FUNCS(fgetpos fsetpos fseek ftell)
 800 AC_CHECK_FUNCS(vsnprintf _vsnprintf)
 801 AC_CHECK_FUNCS(snprintf  _snprintf )
 802 AC_CHECK_FUNCS(popen     _popen )
 803 AC_CHECK_FUNCS(pclose    _pclose )
 804
 805
 806 dnl ** check for specific library functions that we are interested in
 807 AC_CHECK_FUNCS(access ftime getclock getpagesize getrusage gettimeofday mktime mprotect readlink setitimer stat symlink sysconf timelocal times vadvise vfork)
 808
 809 dnl ** check whether this machine has gmp3 installed
 810 AC_CHECK_LIB(gmp,  __gmpz_fdiv_qr, HaveLibGmp=YES; LibGmp=gmp,
 811   AC_CHECK_LIB(gmp3, __gmpz_fdiv_qr,  HaveLibGmp=YES; LibGmp=gmp3,
 812     HaveLibGmp=No; LibGmp=not-installed))
 813 AC_SUBST(HaveLibGmp)
 814 AC_SUBST(LibGmp)
 815
 816 dnl ** check whether this machine has GNU regex in libc.
 817 FPTOOLS_REGEX_IN_LIBC
 818
 819 dnl ** check whether this machine has BFD and liberty installed (used for debugging)
 820 dnl    the order of these tests matters: bfd needs liberty
 821 AC_CHECK_LIB(iberty, xmalloc)
 822 AC_CHECK_LIB(bfd,    bfd_init)
 823
 824 dnl ** check for readline, for Hugs and hslibs' Readline
 825 dnl ncurses supersedes termcap and curses, but for compatibility,
 826 dnl we have to check for all...
 827 AC_CHECK_LIB(ncurses, tputs, HaveLibTermcap=YES; LibTermcap=ncurses,
 828   AC_CHECK_LIB(termcap, tputs, HaveLibTermcap=YES; LibTermcap=termcap,
 829     AC_CHECK_LIB(curses, tputs, HaveLibTermcap=YES; LibTermcap=curses,
 830       HaveLibTermcap=NO; LibTermcap=not-installed)))
 831
 832 if test $HaveLibTermcap = YES ; then
 833   LIBS="-l$LibTermcap $LIBS"
 834   AC_CHECK_LIB(readline, readline, HaveLibReadline=YES, HaveLibReadline=NO)
 835 fi
 836
 837 if test $HaveLibTermcap = YES && test x"$HaveLibReadline" = xYES ; then
 838   AC_DEFINE(HAVE_READLINE_LIBS,1)
 839   LibsReadline="-lreadline -l$LibTermcap"
 840 else
 841   AC_DEFINE(HAVE_READLINE_LIBS,0)
 842   LibsReadline=
 843 fi
 844 AC_SUBST(LibsReadline)
 845
 846 dnl ** check for math library
 847 FPTOOLS_CHECK_LIBM()
 848 AC_SUBST(LIBM)
 849
 850 dnl ################################################################
 851 dnl Check for libraries
 852 dnl ################################################################
 853
 854 AC_CHECK_LIB(dl, dlopen,
 855         [HaveLibDL=YES
 856          AC_DEFINE(HAVE_LIBDL)
 857          LIBS="$LIBS -ldl"],
 858         [HaveLibDL=NO])
 859 AC_CHECK_FUNCS(dlopen)
 860 AC_SUBST(HaveLibDL)
 861
 862 FPTOOLS_CHECK_LIB_NOWARN(m, atan)
 863
 864 dnl --------------------------------------------------
 865 dnl * test for GTK+
 866 dnl --------------------------------------------------
 867
 868 AC_PATH_PROGS(GTK_CONFIG, gtk-config gtk12-config)
 869 if test "$GTK_CONFIG" != ""; then
 870    AC_CACHE_CHECK([for version of GTK+], fptools_cv_gtk_version, [
 871         fptools_cv_gtk_version=`$GTK_CONFIG --version`
 872     ])
 873     GTK_VERSION=$fptools_cv_gtk_version
 874 else
 875     GTK_VERSION=
 876 fi
 877
 878 case $fptools_cv_gtk_version in
 879   1.[[23]].*) ;;
 880   *) AC_MSG_WARN([GTK+ not usable; need at least version 1.2])
 881      GTK_CONFIG=
 882      ;;
 883 esac
 884
 885 AC_SUBST(GTK_CONFIG)
 886 AC_SUBST(GTK_VERSION)
 887
 888 dnl --------------------------------------------------
 889 dnl * Miscellaneous feature tests
 890 dnl --------------------------------------------------
 891
 892 dnl ** can we get alloca?
 893 AC_FUNC_ALLOCA
 894
 895 dnl ** determine whether or not const works
 896 AC_C_CONST
 897
 898 dnl ** determine whether ANSI-function prototypes work?
 899 AC_C_PROTOTYPES
 900
 901 dnl ** are we big endian?
 902 AC_C_BIGENDIAN
 903 # Allay users' general fear of warnings of any kind.
 904 errprint((fptools configure script wizard sez: "don't worry, the above warning is harmless (to us.)")
 905 )
 906
 907 dnl ** check for leading underscores in symbol names
 908 FPTOOLS_UNDERSCORE
 909
 910 dnl ** how is the end of text section signalled?
 911 FPTOOLS_END_TEXT_SECTION
 912
 913 dnl ** how is the end of data section signalled?
 914 FPTOOLS_END_DATA_SECTION
 915
 916 dnl ** code before data?
 917 FPTOOLS_CODE_BEFORE_DATA
 918
 919 AC_OUTPUT(mk/config.mk, echo timestamp > mk/stamp-h )