ghc/Main.hs

   1 {-# OPTIONS -fno-warn-incomplete-patterns -optc-DNON_POSIX_SOURCE #-}
   2
   3 -----------------------------------------------------------------------------
   4 --
   5 -- GHC Driver program
   6 --
   7 -- (c) The University of Glasgow 2005
   8 --
   9 -----------------------------------------------------------------------------
  10
  11 module Main (main) where
  12
  13 -- The official GHC API
  14 import qualified GHC
  15 import GHC              ( -- DynFlags(..), HscTarget(..),
  16                           -- GhcMode(..), GhcLink(..),
  17                           Ghc, GhcMonad(..),
  18                           LoadHowMuch(..) )
  19 import CmdLineParser
  20
  21 -- Implementations of the various modes (--show-iface, mkdependHS. etc.)
  22 import LoadIface        ( showIface )
  23 import HscMain          ( newHscEnv )
  24 import DriverPipeline   ( oneShot, compileFile )
  25 import DriverMkDepend   ( doMkDependHS )
  26 #ifdef GHCI
  27 import InteractiveUI    ( interactiveUI, ghciWelcomeMsg )
  28 #endif
  29
  30
  31 -- Various other random stuff that we need
  32 import Config
  33 import HscTypes
  34 import Packages         ( dumpPackages )
  35 import DriverPhases     ( Phase(..), isSourceFilename, anyHsc,
  36                           startPhase, isHaskellSrcFilename )
  37 import BasicTypes       ( failed )
  38 import StaticFlags
  39 import StaticFlagParser
  40 import DynFlags
  41 import ErrUtils
  42 import FastString
  43 import Outputable
  44 import SrcLoc
  45 import Util
  46 import Panic
  47 import MonadUtils       ( liftIO )
  48
  49 -- Imports for --abi-hash
  50 import LoadIface           ( loadUserInterface )
  51 import Module              ( mkModuleName )
  52 import Finder              ( findImportedModule, cannotFindInterface )
  53 import TcRnMonad           ( initIfaceCheck )
  54 import Binary              ( openBinMem, put_, fingerprintBinMem )
  55
  56 -- Standard Haskell libraries
  57 import System.IO
  58 import System.Environment
  59 import System.Exit
  60 import System.FilePath
  61 import Control.Monad
  62 import Data.Char
  63 import Data.List
  64 import Data.Maybe
  65
  66 -----------------------------------------------------------------------------
  67 -- ToDo:
  68
  69 -- time commands when run with -v
  70 -- user ways
  71 -- Win32 support: proper signal handling
  72 -- reading the package configuration file is too slow
  73 -- -K<size>
  74
  75 -----------------------------------------------------------------------------
  76 -- GHC's command-line interface
  77
  78 main :: IO ()
  79 main = do
  80    hSetBuffering stdout NoBuffering
  81    GHC.defaultErrorHandler defaultDynFlags $ do
  82     -- 1. extract the -B flag from the args
  83     argv0 <- getArgs
  84
  85     let (minusB_args, argv1) = partition ("-B" `isPrefixOf`) argv0
  86         mbMinusB | null minusB_args = Nothing
  87                  | otherwise = Just (drop 2 (last minusB_args))
  88
  89     let argv1' = map (mkGeneralLocated "on the commandline") argv1
  90     (argv2, staticFlagWarnings) <- parseStaticFlags argv1'
  91
  92     -- 2. Parse the "mode" flags (--make, --interactive etc.)
  93     (mode, argv3, modeFlagWarnings) <- parseModeFlags argv2
  94
  95     let flagWarnings = staticFlagWarnings ++ modeFlagWarnings
  96
  97     -- If all we want to do is something like showing the version number
  98     -- then do it now, before we start a GHC session etc. This makes
  99     -- getting basic information much more resilient.
 100
 101     -- In particular, if we wait until later before giving the version
 102     -- number then bootstrapping gets confused, as it tries to find out
 103     -- what version of GHC it's using before package.conf exists, so
 104     -- starting the session fails.
 105     case mode of
 106         Left preStartupMode ->
 107             do case preStartupMode of
 108                    ShowSupportedExtensions -> showSupportedExtensions
 109                    ShowVersion             -> showVersion
 110                    ShowNumVersion          -> putStrLn cProjectVersion
 111                    Print str               -> putStrLn str
 112         Right postStartupMode ->
 113             -- start our GHC session
 114             GHC.runGhc mbMinusB $ do
 115
 116             dflags <- GHC.getSessionDynFlags
 117
 118             case postStartupMode of
 119                 Left preLoadMode ->
 120                     liftIO $ do
 121                         case preLoadMode of
 122                             ShowInfo               -> showInfo dflags
 123                             ShowGhcUsage           -> showGhcUsage  dflags
 124                             ShowGhciUsage          -> showGhciUsage dflags
 125                             PrintWithDynFlags f    -> putStrLn (f dflags)
 126                 Right postLoadMode ->
 127                     main' postLoadMode dflags argv3 flagWarnings
 128
 129 main' :: PostLoadMode -> DynFlags -> [Located String] -> [Located String]
 130       -> Ghc ()
 131 main' postLoadMode dflags0 args flagWarnings = do
 132   -- set the default GhcMode, HscTarget and GhcLink.  The HscTarget
 133   -- can be further adjusted on a module by module basis, using only
 134   -- the -fvia-C and -fasm flags.  If the default HscTarget is not
 135   -- HscC or HscAsm, -fvia-C and -fasm have no effect.
 136   let dflt_target = hscTarget dflags0
 137       (mode, lang, link)
 138          = case postLoadMode of
 139                DoInteractive   -> (CompManager, HscInterpreted, LinkInMemory)
 140                DoEval _        -> (CompManager, HscInterpreted, LinkInMemory)
 141                DoMake          -> (CompManager, dflt_target,    LinkBinary)
 142                DoMkDependHS    -> (MkDepend,    dflt_target,    LinkBinary)
 143                DoAbiHash       -> (OneShot,     dflt_target,    LinkBinary)
 144                _               -> (OneShot,     dflt_target,    LinkBinary)
 145
 146   let dflags1 = dflags0{ ghcMode   = mode,
 147                          hscTarget = lang,
 148                          ghcLink   = link,
 149                          -- leave out hscOutName for now
 150                          hscOutName = panic "Main.main:hscOutName not set",
 151                          verbosity = case postLoadMode of
 152                                          DoEval _ -> 0
 153                                          _other   -> 1
 154                         }
 155
 156       -- turn on -fimplicit-import-qualified for GHCi now, so that it
 157       -- can be overriden from the command-line
 158       dflags1a | DoInteractive <- postLoadMode = imp_qual_enabled
 159                | DoEval _      <- postLoadMode = imp_qual_enabled
 160                | otherwise                 = dflags1
 161         where imp_qual_enabled = dflags1 `dopt_set` Opt_ImplicitImportQualified
 162
 163         -- The rest of the arguments are "dynamic"
 164         -- Leftover ones are presumably files
 165   (dflags2, fileish_args, dynamicFlagWarnings) <- GHC.parseDynamicFlags dflags1a args
 166
 167   let flagWarnings' = flagWarnings ++ dynamicFlagWarnings
 168
 169   handleSourceError (\e -> do
 170        GHC.printException e
 171        liftIO $ exitWith (ExitFailure 1)) $ do
 172          liftIO $ handleFlagWarnings dflags2 flagWarnings'
 173
 174         -- make sure we clean up after ourselves
 175   GHC.defaultCleanupHandler dflags2 $ do
 176
 177   liftIO $ showBanner postLoadMode dflags2
 178
 179   -- we've finished manipulating the DynFlags, update the session
 180   _ <- GHC.setSessionDynFlags dflags2
 181   dflags3 <- GHC.getSessionDynFlags
 182   hsc_env <- GHC.getSession
 183
 184   let
 185      -- To simplify the handling of filepaths, we normalise all filepaths right
 186      -- away - e.g., for win32 platforms, backslashes are converted
 187      -- into forward slashes.
 188     normal_fileish_paths = map (normalise . unLoc) fileish_args
 189     (srcs, objs)         = partition_args normal_fileish_paths [] []
 190
 191   -- Note: have v_Ld_inputs maintain the order in which 'objs' occurred on
 192   --       the command-line.
 193   liftIO $ mapM_ (consIORef v_Ld_inputs) (reverse objs)
 194
 195         ---------------- Display configuration -----------
 196   when (verbosity dflags3 >= 4) $
 197         liftIO $ dumpPackages dflags3
 198
 199   when (verbosity dflags3 >= 3) $ do
 200         liftIO $ hPutStrLn stderr ("Hsc static flags: " ++ unwords staticFlags)
 201
 202         ---------------- Final sanity checking -----------
 203   liftIO $ checkOptions postLoadMode dflags3 srcs objs
 204
 205   ---------------- Do the business -----------
 206   handleSourceError (\e -> do
 207        GHC.printException e
 208        liftIO $ exitWith (ExitFailure 1)) $ do
 209     case postLoadMode of
 210        ShowInterface f        -> liftIO $ doShowIface dflags3 f
 211        DoMake                 -> doMake srcs
 212        DoMkDependHS           -> doMkDependHS (map fst srcs)
 213        StopBefore p           -> liftIO (oneShot hsc_env p srcs)
 214        DoInteractive          -> interactiveUI srcs Nothing
 215        DoEval exprs           -> interactiveUI srcs $ Just $ reverse exprs
 216        DoAbiHash              -> abiHash srcs
 217
 218   liftIO $ dumpFinalStats dflags3
 219
 220 #ifndef GHCI
 221 interactiveUI :: b -> c -> Ghc ()
 222 interactiveUI _ _ =
 223   ghcError (CmdLineError "not built for interactive use")
 224 #endif
 225
 226 -- -----------------------------------------------------------------------------
 227 -- Splitting arguments into source files and object files.  This is where we
 228 -- interpret the -x <suffix> option, and attach a (Maybe Phase) to each source
 229 -- file indicating the phase specified by the -x option in force, if any.
 230
 231 partition_args :: [String] -> [(String, Maybe Phase)] -> [String]
 232                -> ([(String, Maybe Phase)], [String])
 233 partition_args [] srcs objs = (reverse srcs, reverse objs)
 234 partition_args ("-x":suff:args) srcs objs
 235   | "none" <- suff      = partition_args args srcs objs
 236   | StopLn <- phase     = partition_args args srcs (slurp ++ objs)
 237   | otherwise           = partition_args rest (these_srcs ++ srcs) objs
 238         where phase = startPhase suff
 239               (slurp,rest) = break (== "-x") args
 240               these_srcs = zip slurp (repeat (Just phase))
 241 partition_args (arg:args) srcs objs
 242   | looks_like_an_input arg = partition_args args ((arg,Nothing):srcs) objs
 243   | otherwise               = partition_args args srcs (arg:objs)
 244
 245     {-
 246       We split out the object files (.o, .dll) and add them
 247       to v_Ld_inputs for use by the linker.
 248
 249       The following things should be considered compilation manager inputs:
 250
 251        - haskell source files (strings ending in .hs, .lhs or other
 252          haskellish extension),
 253
 254        - module names (not forgetting hierarchical module names),
 255
 256        - and finally we consider everything not containing a '.' to be
 257          a comp manager input, as shorthand for a .hs or .lhs filename.
 258
 259       Everything else is considered to be a linker object, and passed
 260       straight through to the linker.
 261     -}
 262 looks_like_an_input :: String -> Bool
 263 looks_like_an_input m =  isSourceFilename m
 264                       || looksLikeModuleName m
 265                       || '.' `notElem` m
 266
 267 -- -----------------------------------------------------------------------------
 268 -- Option sanity checks
 269
 270 -- | Ensure sanity of options.
 271 --
 272 -- Throws 'UsageError' or 'CmdLineError' if not.
 273 checkOptions :: PostLoadMode -> DynFlags -> [(String,Maybe Phase)] -> [String] -> IO ()
 274      -- Final sanity checking before kicking off a compilation (pipeline).
 275 checkOptions mode dflags srcs objs = do
 276      -- Complain about any unknown flags
 277    let unknown_opts = [ f | (f@('-':_), _) <- srcs ]
 278    when (notNull unknown_opts) (unknownFlagsErr unknown_opts)
 279
 280    when (notNull (filter isRTSWay (wayNames dflags))
 281          && isInterpretiveMode mode) $
 282         hPutStrLn stderr ("Warning: -debug, -threaded and -ticky are ignored by GHCi")
 283
 284         -- -prof and --interactive are not a good combination
 285    when (notNull (filter (not . isRTSWay) (wayNames dflags))
 286          && isInterpretiveMode mode) $
 287       do ghcError (UsageError
 288                    "--interactive can't be used with -prof or -unreg.")
 289         -- -ohi sanity check
 290    if (isJust (outputHi dflags) &&
 291       (isCompManagerMode mode || srcs `lengthExceeds` 1))
 292         then ghcError (UsageError "-ohi can only be used when compiling a single source file")
 293         else do
 294
 295         -- -o sanity checking
 296    if (srcs `lengthExceeds` 1 && isJust (outputFile dflags)
 297          && not (isLinkMode mode))
 298         then ghcError (UsageError "can't apply -o to multiple source files")
 299         else do
 300
 301    let not_linking = not (isLinkMode mode) || isNoLink (ghcLink dflags)
 302
 303    when (not_linking && not (null objs)) $
 304         hPutStrLn stderr ("Warning: the following files would be used as linker inputs, but linking is not being done: " ++ unwords objs)
 305
 306         -- Check that there are some input files
 307         -- (except in the interactive case)
 308    if null srcs && (null objs || not_linking) && needsInputsMode mode
 309         then ghcError (UsageError "no input files")
 310         else do
 311
 312      -- Verify that output files point somewhere sensible.
 313    verifyOutputFiles dflags
 314
 315
 316 -- Compiler output options
 317
 318 -- called to verify that the output files & directories
 319 -- point somewhere valid.
 320 --
 321 -- The assumption is that the directory portion of these output
 322 -- options will have to exist by the time 'verifyOutputFiles'
 323 -- is invoked.
 324 --
 325 verifyOutputFiles :: DynFlags -> IO ()
 326 verifyOutputFiles dflags = do
 327   -- not -odir: we create the directory for -odir if it doesn't exist (#2278).
 328   let ofile = outputFile dflags
 329   when (isJust ofile) $ do
 330      let fn = fromJust ofile
 331      flg <- doesDirNameExist fn
 332      when (not flg) (nonExistentDir "-o" fn)
 333   let ohi = outputHi dflags
 334   when (isJust ohi) $ do
 335      let hi = fromJust ohi
 336      flg <- doesDirNameExist hi
 337      when (not flg) (nonExistentDir "-ohi" hi)
 338  where
 339    nonExistentDir flg dir =
 340      ghcError (CmdLineError ("error: directory portion of " ++
 341                              show dir ++ " does not exist (used with " ++
 342                              show flg ++ " option.)"))
 343
 344 -----------------------------------------------------------------------------
 345 -- GHC modes of operation
 346
 347 type Mode = Either PreStartupMode PostStartupMode
 348 type PostStartupMode = Either PreLoadMode PostLoadMode
 349
 350 data PreStartupMode
 351   = ShowVersion             -- ghc -V/--version
 352   | ShowNumVersion          -- ghc --numeric-version
 353   | ShowSupportedExtensions -- ghc --supported-extensions
 354   | Print String            -- ghc --print-foo
 355
 356 showVersionMode, showNumVersionMode, showSupportedExtensionsMode :: Mode
 357 showVersionMode             = mkPreStartupMode ShowVersion
 358 showNumVersionMode          = mkPreStartupMode ShowNumVersion
 359 showSupportedExtensionsMode = mkPreStartupMode ShowSupportedExtensions
 360
 361 printMode :: String -> Mode
 362 printMode str              = mkPreStartupMode (Print str)
 363
 364 mkPreStartupMode :: PreStartupMode -> Mode
 365 mkPreStartupMode = Left
 366
 367 isShowVersionMode :: Mode -> Bool
 368 isShowVersionMode (Left ShowVersion) = True
 369 isShowVersionMode _ = False
 370
 371 isShowNumVersionMode :: Mode -> Bool
 372 isShowNumVersionMode (Left ShowNumVersion) = True
 373 isShowNumVersionMode _ = False
 374
 375 data PreLoadMode
 376   = ShowGhcUsage                           -- ghc -?
 377   | ShowGhciUsage                          -- ghci -?
 378   | ShowInfo                               -- ghc --info
 379   | PrintWithDynFlags (DynFlags -> String) -- ghc --print-foo
 380
 381 showGhcUsageMode, showGhciUsageMode, showInfoMode :: Mode
 382 showGhcUsageMode = mkPreLoadMode ShowGhcUsage
 383 showGhciUsageMode = mkPreLoadMode ShowGhciUsage
 384 showInfoMode = mkPreLoadMode ShowInfo
 385
 386 printWithDynFlagsMode :: (DynFlags -> String) -> Mode
 387 printWithDynFlagsMode f = mkPreLoadMode (PrintWithDynFlags f)
 388
 389 mkPreLoadMode :: PreLoadMode -> Mode
 390 mkPreLoadMode = Right . Left
 391
 392 isShowGhcUsageMode :: Mode -> Bool
 393 isShowGhcUsageMode (Right (Left ShowGhcUsage)) = True
 394 isShowGhcUsageMode _ = False
 395
 396 isShowGhciUsageMode :: Mode -> Bool
 397 isShowGhciUsageMode (Right (Left ShowGhciUsage)) = True
 398 isShowGhciUsageMode _ = False
 399
 400 data PostLoadMode
 401   = ShowInterface FilePath  -- ghc --show-iface
 402   | DoMkDependHS            -- ghc -M
 403   | StopBefore Phase        -- ghc -E | -C | -S
 404                             -- StopBefore StopLn is the default
 405   | DoMake                  -- ghc --make
 406   | DoInteractive           -- ghc --interactive
 407   | DoEval [String]         -- ghc -e foo -e bar => DoEval ["bar", "foo"]
 408   | DoAbiHash               -- ghc --abi-hash
 409
 410 doMkDependHSMode, doMakeMode, doInteractiveMode, doAbiHashMode :: Mode
 411 doMkDependHSMode = mkPostLoadMode DoMkDependHS
 412 doMakeMode = mkPostLoadMode DoMake
 413 doInteractiveMode = mkPostLoadMode DoInteractive
 414 doAbiHashMode = mkPostLoadMode DoAbiHash
 415
 416 showInterfaceMode :: FilePath -> Mode
 417 showInterfaceMode fp = mkPostLoadMode (ShowInterface fp)
 418
 419 stopBeforeMode :: Phase -> Mode
 420 stopBeforeMode phase = mkPostLoadMode (StopBefore phase)
 421
 422 doEvalMode :: String -> Mode
 423 doEvalMode str = mkPostLoadMode (DoEval [str])
 424
 425 mkPostLoadMode :: PostLoadMode -> Mode
 426 mkPostLoadMode = Right . Right
 427
 428 isDoInteractiveMode :: Mode -> Bool
 429 isDoInteractiveMode (Right (Right DoInteractive)) = True
 430 isDoInteractiveMode _ = False
 431
 432 isStopLnMode :: Mode -> Bool
 433 isStopLnMode (Right (Right (StopBefore StopLn))) = True
 434 isStopLnMode _ = False
 435
 436 isDoMakeMode :: Mode -> Bool
 437 isDoMakeMode (Right (Right DoMake)) = True
 438 isDoMakeMode _ = False
 439
 440 #ifdef GHCI
 441 isInteractiveMode :: PostLoadMode -> Bool
 442 isInteractiveMode DoInteractive = True
 443 isInteractiveMode _             = False
 444 #endif
 445
 446 -- isInterpretiveMode: byte-code compiler involved
 447 isInterpretiveMode :: PostLoadMode -> Bool
 448 isInterpretiveMode DoInteractive = True
 449 isInterpretiveMode (DoEval _)    = True
 450 isInterpretiveMode _             = False
 451
 452 needsInputsMode :: PostLoadMode -> Bool
 453 needsInputsMode DoMkDependHS    = True
 454 needsInputsMode (StopBefore _)  = True
 455 needsInputsMode DoMake          = True
 456 needsInputsMode _               = False
 457
 458 -- True if we are going to attempt to link in this mode.
 459 -- (we might not actually link, depending on the GhcLink flag)
 460 isLinkMode :: PostLoadMode -> Bool
 461 isLinkMode (StopBefore StopLn) = True
 462 isLinkMode DoMake              = True
 463 isLinkMode DoInteractive       = True
 464 isLinkMode (DoEval _)          = True
 465 isLinkMode _                   = False
 466
 467 isCompManagerMode :: PostLoadMode -> Bool
 468 isCompManagerMode DoMake        = True
 469 isCompManagerMode DoInteractive = True
 470 isCompManagerMode (DoEval _)    = True
 471 isCompManagerMode _             = False
 472
 473 -- -----------------------------------------------------------------------------
 474 -- Parsing the mode flag
 475
 476 parseModeFlags :: [Located String]
 477                -> IO (Mode,
 478                       [Located String],
 479                       [Located String])
 480 parseModeFlags args = do
 481   let ((leftover, errs1, warns), (mModeFlag, errs2, flags')) =
 482           runCmdLine (processArgs mode_flags args)
 483                      (Nothing, [], [])
 484       mode = case mModeFlag of
 485              Nothing     -> doMakeMode
 486              Just (m, _) -> m
 487       errs = errs1 ++ map (mkGeneralLocated "on the commandline") errs2
 488   when (not (null errs)) $ ghcError $ errorsToGhcException errs
 489   return (mode, flags' ++ leftover, warns)
 490
 491 type ModeM = CmdLineP (Maybe (Mode, String), [String], [Located String])
 492   -- mode flags sometimes give rise to new DynFlags (eg. -C, see below)
 493   -- so we collect the new ones and return them.
 494
 495 mode_flags :: [Flag ModeM]
 496 mode_flags =
 497   [  ------- help / version ----------------------------------------------
 498     Flag "?"                     (PassFlag (setMode showGhcUsageMode))
 499   , Flag "-help"                 (PassFlag (setMode showGhcUsageMode))
 500   , Flag "V"                     (PassFlag (setMode showVersionMode))
 501   , Flag "-version"              (PassFlag (setMode showVersionMode))
 502   , Flag "-numeric-version"      (PassFlag (setMode showNumVersionMode))
 503   , Flag "-info"                 (PassFlag (setMode showInfoMode))
 504   , Flag "-supported-languages"  (PassFlag (setMode showSupportedExtensionsMode))
 505   , Flag "-supported-extensions" (PassFlag (setMode showSupportedExtensionsMode))
 506   ] ++
 507   [ Flag k'                     (PassFlag (setMode mode))
 508   | (k, v) <- compilerInfo,
 509     let k' = "-print-" ++ map (replaceSpace . toLower) k
 510         replaceSpace ' ' = '-'
 511         replaceSpace c   = c
 512         mode = case v of
 513                String str -> printMode str
 514                FromDynFlags f -> printWithDynFlagsMode f
 515   ] ++
 516       ------- interfaces ----------------------------------------------------
 517   [ Flag "-show-iface"  (HasArg (\f -> setMode (showInterfaceMode f)
 518                                                "--show-iface"))
 519
 520       ------- primary modes ------------------------------------------------
 521   , Flag "c"            (PassFlag (\f -> do setMode (stopBeforeMode StopLn) f
 522                                             addFlag "-no-link" f))
 523   , Flag "M"            (PassFlag (setMode doMkDependHSMode))
 524   , Flag "E"            (PassFlag (setMode (stopBeforeMode anyHsc)))
 525   , Flag "C"            (PassFlag (\f -> do setMode (stopBeforeMode HCc) f
 526                                             addFlag "-fvia-C" f))
 527   , Flag "S"            (PassFlag (setMode (stopBeforeMode As)))
 528   , Flag "-make"        (PassFlag (setMode doMakeMode))
 529   , Flag "-interactive" (PassFlag (setMode doInteractiveMode))
 530   , Flag "-abi-hash"    (PassFlag (setMode doAbiHashMode))
 531   , Flag "e"            (SepArg   (\s -> setMode (doEvalMode s) "-e"))
 532   ]
 533
 534 setMode :: Mode -> String -> EwM ModeM ()
 535 setMode newMode newFlag = liftEwM $ do
 536     (mModeFlag, errs, flags') <- getCmdLineState
 537     let (modeFlag', errs') =
 538             case mModeFlag of
 539             Nothing -> ((newMode, newFlag), errs)
 540             Just (oldMode, oldFlag) ->
 541                 case (oldMode, newMode) of
 542                     -- -c/--make are allowed together, and mean --make -no-link
 543                     _ |  isStopLnMode oldMode && isDoMakeMode newMode
 544                       || isStopLnMode newMode && isDoMakeMode oldMode ->
 545                       ((doMakeMode, "--make"), [])
 546
 547                     -- If we have both --help and --interactive then we
 548                     -- want showGhciUsage
 549                     _ | isShowGhcUsageMode oldMode &&
 550                         isDoInteractiveMode newMode ->
 551                             ((showGhciUsageMode, oldFlag), [])
 552                       | isShowGhcUsageMode newMode &&
 553                         isDoInteractiveMode oldMode ->
 554                             ((showGhciUsageMode, newFlag), [])
 555                     -- Otherwise, --help/--version/--numeric-version always win
 556                       | isDominantFlag oldMode -> ((oldMode, oldFlag), [])
 557                       | isDominantFlag newMode -> ((newMode, newFlag), [])
 558                     -- We need to accumulate eval flags like "-e foo -e bar"
 559                     (Right (Right (DoEval esOld)),
 560                      Right (Right (DoEval [eNew]))) ->
 561                         ((Right (Right (DoEval (eNew : esOld))), oldFlag),
 562                          errs)
 563                     -- Saying e.g. --interactive --interactive is OK
 564                     _ | oldFlag == newFlag -> ((oldMode, oldFlag), errs)
 565                     -- Otherwise, complain
 566                     _ -> let err = flagMismatchErr oldFlag newFlag
 567                          in ((oldMode, oldFlag), err : errs)
 568     putCmdLineState (Just modeFlag', errs', flags')
 569   where isDominantFlag f = isShowGhcUsageMode   f ||
 570                            isShowGhciUsageMode  f ||
 571                            isShowVersionMode    f ||
 572                            isShowNumVersionMode f
 573
 574 flagMismatchErr :: String -> String -> String
 575 flagMismatchErr oldFlag newFlag
 576     = "cannot use `" ++ oldFlag ++  "' with `" ++ newFlag ++ "'"
 577
 578 addFlag :: String -> String -> EwM ModeM ()
 579 addFlag s flag = liftEwM $ do
 580   (m, e, flags') <- getCmdLineState
 581   putCmdLineState (m, e, mkGeneralLocated loc s : flags')
 582     where loc = "addFlag by " ++ flag ++ " on the commandline"
 583
 584 -- ----------------------------------------------------------------------------
 585 -- Run --make mode
 586
 587 doMake :: [(String,Maybe Phase)] -> Ghc ()
 588 doMake srcs  = do
 589     let (hs_srcs, non_hs_srcs) = partition haskellish srcs
 590
 591         haskellish (f,Nothing) =
 592           looksLikeModuleName f || isHaskellSrcFilename f || '.' `notElem` f
 593         haskellish (_,Just phase) =
 594           phase `notElem` [As, Cc, CmmCpp, Cmm, StopLn]
 595
 596     hsc_env <- GHC.getSession
 597
 598     -- if we have no haskell sources from which to do a dependency
 599     -- analysis, then just do one-shot compilation and/or linking.
 600     -- This means that "ghc Foo.o Bar.o -o baz" links the program as
 601     -- we expect.
 602     if (null hs_srcs)
 603        then liftIO (oneShot hsc_env StopLn srcs)
 604        else do
 605
 606     o_files <- mapM (\x -> liftIO $ compileFile hsc_env StopLn x)
 607                  non_hs_srcs
 608     liftIO $ mapM_ (consIORef v_Ld_inputs) (reverse o_files)
 609
 610     targets <- mapM (uncurry GHC.guessTarget) hs_srcs
 611     GHC.setTargets targets
 612     ok_flag <- GHC.load LoadAllTargets
 613
 614     when (failed ok_flag) (liftIO $ exitWith (ExitFailure 1))
 615     return ()
 616
 617
 618 -- ---------------------------------------------------------------------------
 619 -- --show-iface mode
 620
 621 doShowIface :: DynFlags -> FilePath -> IO ()
 622 doShowIface dflags file = do
 623   hsc_env <- newHscEnv dflags
 624   showIface hsc_env file
 625
 626 -- ---------------------------------------------------------------------------
 627 -- Various banners and verbosity output.
 628
 629 showBanner :: PostLoadMode -> DynFlags -> IO ()
 630 showBanner _postLoadMode dflags = do
 631    let verb = verbosity dflags
 632
 633 #ifdef GHCI
 634    -- Show the GHCi banner
 635    when (isInteractiveMode _postLoadMode && verb >= 1) $ putStrLn ghciWelcomeMsg
 636 #endif
 637
 638    -- Display details of the configuration in verbose mode
 639    when (verb >= 2) $
 640     do hPutStr stderr "Glasgow Haskell Compiler, Version "
 641        hPutStr stderr cProjectVersion
 642        hPutStr stderr ", for Haskell 98, stage "
 643        hPutStr stderr cStage
 644        hPutStr stderr " booted by GHC version "
 645        hPutStrLn stderr cBooterVersion
 646
 647 -- We print out a Read-friendly string, but a prettier one than the
 648 -- Show instance gives us
 649 showInfo :: DynFlags -> IO ()
 650 showInfo dflags = do
 651         let sq x = " [" ++ x ++ "\n ]"
 652         putStrLn $ sq $ concat $ intersperse "\n ," $ map (show . flatten) compilerInfo
 653     where flatten (k, String v)       = (k, v)
 654           flatten (k, FromDynFlags f) = (k, f dflags)
 655
 656 showSupportedExtensions :: IO ()
 657 showSupportedExtensions = mapM_ putStrLn supportedLanguagesAndExtensions
 658
 659 showVersion :: IO ()
 660 showVersion = putStrLn (cProjectName ++ ", version " ++ cProjectVersion)
 661
 662 showGhcUsage :: DynFlags -> IO ()
 663 showGhcUsage = showUsage False
 664
 665 showGhciUsage :: DynFlags -> IO ()
 666 showGhciUsage = showUsage True
 667
 668 showUsage :: Bool -> DynFlags -> IO ()
 669 showUsage ghci dflags = do
 670   let usage_path = if ghci then ghciUsagePath dflags
 671                            else ghcUsagePath dflags
 672   usage <- readFile usage_path
 673   dump usage
 674   where
 675      dump ""          = return ()
 676      dump ('$':'$':s) = putStr progName >> dump s
 677      dump (c:s)       = putChar c >> dump s
 678
 679 dumpFinalStats :: DynFlags -> IO ()
 680 dumpFinalStats dflags =
 681   when (dopt Opt_D_faststring_stats dflags) $ dumpFastStringStats dflags
 682
 683 dumpFastStringStats :: DynFlags -> IO ()
 684 dumpFastStringStats dflags = do
 685   buckets <- getFastStringTable
 686   let (entries, longest, is_z, has_z) = countFS 0 0 0 0 buckets
 687       msg = text "FastString stats:" $$
 688             nest 4 (vcat [text "size:           " <+> int (length buckets),
 689                           text "entries:        " <+> int entries,
 690                           text "longest chain:  " <+> int longest,
 691                           text "z-encoded:      " <+> (is_z `pcntOf` entries),
 692                           text "has z-encoding: " <+> (has_z `pcntOf` entries)
 693                          ])
 694         -- we usually get more "has z-encoding" than "z-encoded", because
 695         -- when we z-encode a string it might hash to the exact same string,
 696         -- which will is not counted as "z-encoded".  Only strings whose
 697         -- Z-encoding is different from the original string are counted in
 698         -- the "z-encoded" total.
 699   putMsg dflags msg
 700   where
 701    x `pcntOf` y = int ((x * 100) `quot` y) <> char '%'
 702
 703 countFS :: Int -> Int -> Int -> Int -> [[FastString]] -> (Int, Int, Int, Int)
 704 countFS entries longest is_z has_z [] = (entries, longest, is_z, has_z)
 705 countFS entries longest is_z has_z (b:bs) =
 706   let
 707         len = length b
 708         longest' = max len longest
 709         entries' = entries + len
 710         is_zs = length (filter isZEncoded b)
 711         has_zs = length (filter hasZEncoding b)
 712   in
 713         countFS entries' longest' (is_z + is_zs) (has_z + has_zs) bs
 714
 715 -- -----------------------------------------------------------------------------
 716 -- ABI hash support
 717
 718 {-
 719         ghc --abi-hash Data.Foo System.Bar
 720
 721 Generates a combined hash of the ABI for modules Data.Foo and
 722 System.Bar.  The modules must already be compiled, and appropriate -i
 723 options may be necessary in order to find the .hi files.
 724
 725 This is used by Cabal for generating the InstalledPackageId for a
 726 package.  The InstalledPackageId must change when the visible ABI of
 727 the package chagnes, so during registration Cabal calls ghc --abi-hash
 728 to get a hash of the package's ABI.
 729 -}
 730
 731 abiHash :: [(String, Maybe Phase)] -> Ghc ()
 732 abiHash strs = do
 733   hsc_env <- getSession
 734   let dflags = hsc_dflags hsc_env
 735
 736   liftIO $ do
 737
 738   let find_it str = do
 739          let modname = mkModuleName str
 740          r <- findImportedModule hsc_env modname Nothing
 741          case r of
 742            Found _ m -> return m
 743            _error    -> ghcError $ CmdLineError $ showSDoc $
 744                           cannotFindInterface dflags modname r
 745
 746   mods <- mapM find_it (map fst strs)
 747
 748   let get_iface modl = loadUserInterface False (text "abiHash") modl
 749   ifaces <- initIfaceCheck hsc_env $ mapM get_iface mods
 750
 751   bh <- openBinMem (3*1024) -- just less than a block
 752   mapM_ (put_ bh . mi_mod_hash) ifaces
 753   f <- fingerprintBinMem bh
 754
 755   putStrLn (showSDoc (ppr f))
 756
 757 -- -----------------------------------------------------------------------------
 758 -- Util
 759
 760 unknownFlagsErr :: [String] -> a
 761 unknownFlagsErr fs = ghcError (UsageError ("unrecognised flags: " ++ unwords fs))