ghc/Main.hs

   1 {-# OPTIONS -fno-warn-incomplete-patterns -optc-DNON_POSIX_SOURCE #-}
   2
   3 -----------------------------------------------------------------------------
   4 --
   5 -- GHC Driver program
   6 --
   7 -- (c) The University of Glasgow 2005
   8 --
   9 -----------------------------------------------------------------------------
  10
  11 module Main (main) where
  12
  13 -- The official GHC API
  14 import qualified GHC
  15 import GHC              ( -- DynFlags(..), HscTarget(..),
  16                           -- GhcMode(..), GhcLink(..),
  17                           LoadHowMuch(..), -- dopt, DynFlag(..),
  18                           defaultCallbacks )
  19 import CmdLineParser
  20
  21 -- Implementations of the various modes (--show-iface, mkdependHS. etc.)
  22 import LoadIface        ( showIface )
  23 import HscMain          ( newHscEnv )
  24 import DriverPipeline   ( oneShot, compileFile )
  25 import DriverMkDepend   ( doMkDependHS )
  26 #ifdef GHCI
  27 import InteractiveUI    ( interactiveUI, ghciWelcomeMsg )
  28 #endif
  29
  30
  31 -- Various other random stuff that we need
  32 import Config
  33 import HscTypes
  34 import Packages         ( dumpPackages )
  35 import DriverPhases     ( Phase(..), isSourceFilename, anyHsc,
  36                           startPhase, isHaskellSrcFilename )
  37 import BasicTypes       ( failed )
  38 import StaticFlags
  39 import StaticFlagParser
  40 import DynFlags
  41 import ErrUtils
  42 import FastString
  43 import Outputable
  44 import SrcLoc
  45 import Util
  46 import Panic
  47 -- import MonadUtils       ( liftIO )
  48
  49 -- Imports for --abi-hash
  50 import LoadIface           ( loadUserInterface )
  51 import Module              ( mkModuleName )
  52 import Finder              ( findImportedModule, cannotFindInterface )
  53 import TcRnMonad           ( initIfaceCheck )
  54 import Binary              ( openBinMem, put_, fingerprintBinMem )
  55
  56 -- Standard Haskell libraries
  57 import System.IO
  58 import System.Environment
  59 import System.Exit
  60 import System.FilePath
  61 import Control.Monad
  62 import Data.Char
  63 import Data.List
  64 import Data.Maybe
  65
  66 -----------------------------------------------------------------------------
  67 -- ToDo:
  68
  69 -- time commands when run with -v
  70 -- user ways
  71 -- Win32 support: proper signal handling
  72 -- reading the package configuration file is too slow
  73 -- -K<size>
  74
  75 -----------------------------------------------------------------------------
  76 -- GHC's command-line interface
  77
  78 main :: IO ()
  79 main =
  80     GHC.defaultErrorHandler defaultDynFlags $ do
  81     -- 1. extract the -B flag from the args
  82     argv0 <- getArgs
  83
  84     let (minusB_args, argv1) = partition ("-B" `isPrefixOf`) argv0
  85         mbMinusB | null minusB_args = Nothing
  86                  | otherwise = Just (drop 2 (last minusB_args))
  87
  88     let argv1' = map (mkGeneralLocated "on the commandline") argv1
  89     (argv2, staticFlagWarnings) <- parseStaticFlags argv1'
  90
  91     -- 2. Parse the "mode" flags (--make, --interactive etc.)
  92     (mode, argv3, modeFlagWarnings) <- parseModeFlags argv2
  93
  94     let flagWarnings = staticFlagWarnings ++ modeFlagWarnings
  95
  96     -- If all we want to do is something like showing the version number
  97     -- then do it now, before we start a GHC session etc. This makes
  98     -- getting basic information much more resilient.
  99
 100     -- In particular, if we wait until later before giving the version
 101     -- number then bootstrapping gets confused, as it tries to find out
 102     -- what version of GHC it's using before package.conf exists, so
 103     -- starting the session fails.
 104     case mode of
 105         Left preStartupMode ->
 106             do case preStartupMode of
 107                    ShowSupportedLanguages  -> showSupportedLanguages
 108                    ShowVersion             -> showVersion
 109                    ShowNumVersion          -> putStrLn cProjectVersion
 110                    Print str               -> putStrLn str
 111         Right postStartupMode ->
 112             -- start our GHC session
 113             GHC.runGhc mbMinusB $ do
 114
 115             dflags <- GHC.getSessionDynFlags
 116
 117             case postStartupMode of
 118                 Left preLoadMode ->
 119                     liftIO $ do
 120                         case preLoadMode of
 121                             ShowInfo               -> showInfo dflags
 122                             ShowGhcUsage           -> showGhcUsage  dflags
 123                             ShowGhciUsage          -> showGhciUsage dflags
 124                             PrintWithDynFlags f    -> putStrLn (f dflags)
 125                 Right postLoadMode ->
 126                     main' postLoadMode dflags argv3 flagWarnings
 127
 128 main' :: PostLoadMode -> DynFlags -> [Located String] -> [Located String]
 129       -> Ghc ()
 130 main' postLoadMode dflags0 args flagWarnings = do
 131   -- set the default GhcMode, HscTarget and GhcLink.  The HscTarget
 132   -- can be further adjusted on a module by module basis, using only
 133   -- the -fvia-C and -fasm flags.  If the default HscTarget is not
 134   -- HscC or HscAsm, -fvia-C and -fasm have no effect.
 135   let dflt_target = hscTarget dflags0
 136       (mode, lang, link)
 137          = case postLoadMode of
 138                DoInteractive   -> (CompManager, HscInterpreted, LinkInMemory)
 139                DoEval _        -> (CompManager, HscInterpreted, LinkInMemory)
 140                DoMake          -> (CompManager, dflt_target,    LinkBinary)
 141                DoMkDependHS    -> (MkDepend,    dflt_target,    LinkBinary)
 142                DoAbiHash       -> (OneShot,     dflt_target,    LinkBinary)
 143                _               -> (OneShot,     dflt_target,    LinkBinary)
 144
 145   let dflags1 = dflags0{ ghcMode   = mode,
 146                          hscTarget = lang,
 147                          ghcLink   = link,
 148                          -- leave out hscOutName for now
 149                          hscOutName = panic "Main.main:hscOutName not set",
 150                          verbosity = case postLoadMode of
 151                                          DoEval _ -> 0
 152                                          _other   -> 1
 153                         }
 154
 155       -- turn on -fimplicit-import-qualified for GHCi now, so that it
 156       -- can be overriden from the command-line
 157       dflags1a | DoInteractive <- postLoadMode = imp_qual_enabled
 158                | DoEval _      <- postLoadMode = imp_qual_enabled
 159                | otherwise                 = dflags1
 160         where imp_qual_enabled = dflags1 `dopt_set` Opt_ImplicitImportQualified
 161
 162         -- The rest of the arguments are "dynamic"
 163         -- Leftover ones are presumably files
 164   (dflags2, fileish_args, dynamicFlagWarnings) <- GHC.parseDynamicFlags dflags1a args
 165
 166   let flagWarnings' = flagWarnings ++ dynamicFlagWarnings
 167
 168   handleSourceError (\e -> do
 169        GHC.printExceptionAndWarnings e
 170        liftIO $ exitWith (ExitFailure 1)) $
 171     handleFlagWarnings dflags2 flagWarnings'
 172
 173         -- make sure we clean up after ourselves
 174   GHC.defaultCleanupHandler dflags2 $ do
 175
 176   liftIO $ showBanner postLoadMode dflags2
 177
 178   -- we've finished manipulating the DynFlags, update the session
 179   _ <- GHC.setSessionDynFlags dflags2
 180   dflags3 <- GHC.getSessionDynFlags
 181   hsc_env <- GHC.getSession
 182
 183   let
 184      -- To simplify the handling of filepaths, we normalise all filepaths right
 185      -- away - e.g., for win32 platforms, backslashes are converted
 186      -- into forward slashes.
 187     normal_fileish_paths = map (normalise . unLoc) fileish_args
 188     (srcs, objs)         = partition_args normal_fileish_paths [] []
 189
 190   -- Note: have v_Ld_inputs maintain the order in which 'objs' occurred on
 191   --       the command-line.
 192   liftIO $ mapM_ (consIORef v_Ld_inputs) (reverse objs)
 193
 194         ---------------- Display configuration -----------
 195   when (verbosity dflags3 >= 4) $
 196         liftIO $ dumpPackages dflags3
 197
 198   when (verbosity dflags3 >= 3) $ do
 199         liftIO $ hPutStrLn stderr ("Hsc static flags: " ++ unwords staticFlags)
 200
 201         ---------------- Final sanity checking -----------
 202   liftIO $ checkOptions postLoadMode dflags3 srcs objs
 203
 204   ---------------- Do the business -----------
 205   handleSourceError (\e -> do
 206        GHC.printExceptionAndWarnings e
 207        liftIO $ exitWith (ExitFailure 1)) $ do
 208     case postLoadMode of
 209        ShowInterface f        -> liftIO $ doShowIface dflags3 f
 210        DoMake                 -> doMake srcs
 211        DoMkDependHS           -> do doMkDependHS (map fst srcs)
 212                                     GHC.printWarnings
 213        StopBefore p           -> oneShot hsc_env p srcs >> GHC.printWarnings
 214        DoInteractive          -> interactiveUI srcs Nothing
 215        DoEval exprs           -> interactiveUI srcs $ Just $ reverse exprs
 216        DoAbiHash              -> abiHash srcs
 217
 218   liftIO $ dumpFinalStats dflags3
 219
 220 #ifndef GHCI
 221 interactiveUI :: b -> c -> Ghc ()
 222 interactiveUI _ _ =
 223   ghcError (CmdLineError "not built for interactive use")
 224 #endif
 225
 226 -- -----------------------------------------------------------------------------
 227 -- Splitting arguments into source files and object files.  This is where we
 228 -- interpret the -x <suffix> option, and attach a (Maybe Phase) to each source
 229 -- file indicating the phase specified by the -x option in force, if any.
 230
 231 partition_args :: [String] -> [(String, Maybe Phase)] -> [String]
 232                -> ([(String, Maybe Phase)], [String])
 233 partition_args [] srcs objs = (reverse srcs, reverse objs)
 234 partition_args ("-x":suff:args) srcs objs
 235   | "none" <- suff      = partition_args args srcs objs
 236   | StopLn <- phase     = partition_args args srcs (slurp ++ objs)
 237   | otherwise           = partition_args rest (these_srcs ++ srcs) objs
 238         where phase = startPhase suff
 239               (slurp,rest) = break (== "-x") args
 240               these_srcs = zip slurp (repeat (Just phase))
 241 partition_args (arg:args) srcs objs
 242   | looks_like_an_input arg = partition_args args ((arg,Nothing):srcs) objs
 243   | otherwise               = partition_args args srcs (arg:objs)
 244
 245     {-
 246       We split out the object files (.o, .dll) and add them
 247       to v_Ld_inputs for use by the linker.
 248
 249       The following things should be considered compilation manager inputs:
 250
 251        - haskell source files (strings ending in .hs, .lhs or other
 252          haskellish extension),
 253
 254        - module names (not forgetting hierarchical module names),
 255
 256        - and finally we consider everything not containing a '.' to be
 257          a comp manager input, as shorthand for a .hs or .lhs filename.
 258
 259       Everything else is considered to be a linker object, and passed
 260       straight through to the linker.
 261     -}
 262 looks_like_an_input :: String -> Bool
 263 looks_like_an_input m =  isSourceFilename m
 264                       || looksLikeModuleName m
 265                       || '.' `notElem` m
 266
 267 -- -----------------------------------------------------------------------------
 268 -- Option sanity checks
 269
 270 -- | Ensure sanity of options.
 271 --
 272 -- Throws 'UsageError' or 'CmdLineError' if not.
 273 checkOptions :: PostLoadMode -> DynFlags -> [(String,Maybe Phase)] -> [String] -> IO ()
 274      -- Final sanity checking before kicking off a compilation (pipeline).
 275 checkOptions mode dflags srcs objs = do
 276      -- Complain about any unknown flags
 277    let unknown_opts = [ f | (f@('-':_), _) <- srcs ]
 278    when (notNull unknown_opts) (unknownFlagsErr unknown_opts)
 279
 280    when (notNull (filter isRTSWay (wayNames dflags))
 281          && isInterpretiveMode mode) $
 282         hPutStrLn stderr ("Warning: -debug, -threaded and -ticky are ignored by GHCi")
 283
 284         -- -prof and --interactive are not a good combination
 285    when (notNull (filter (not . isRTSWay) (wayNames dflags))
 286          && isInterpretiveMode mode) $
 287       do ghcError (UsageError
 288                    "--interactive can't be used with -prof or -unreg.")
 289         -- -ohi sanity check
 290    if (isJust (outputHi dflags) &&
 291       (isCompManagerMode mode || srcs `lengthExceeds` 1))
 292         then ghcError (UsageError "-ohi can only be used when compiling a single source file")
 293         else do
 294
 295         -- -o sanity checking
 296    if (srcs `lengthExceeds` 1 && isJust (outputFile dflags)
 297          && not (isLinkMode mode))
 298         then ghcError (UsageError "can't apply -o to multiple source files")
 299         else do
 300
 301    let not_linking = not (isLinkMode mode) || isNoLink (ghcLink dflags)
 302
 303    when (not_linking && not (null objs)) $
 304         hPutStrLn stderr ("Warning: the following files would be used as linker inputs, but linking is not being done: " ++ unwords objs)
 305
 306         -- Check that there are some input files
 307         -- (except in the interactive case)
 308    if null srcs && (null objs || not_linking) && needsInputsMode mode
 309         then ghcError (UsageError "no input files")
 310         else do
 311
 312      -- Verify that output files point somewhere sensible.
 313    verifyOutputFiles dflags
 314
 315
 316 -- Compiler output options
 317
 318 -- called to verify that the output files & directories
 319 -- point somewhere valid.
 320 --
 321 -- The assumption is that the directory portion of these output
 322 -- options will have to exist by the time 'verifyOutputFiles'
 323 -- is invoked.
 324 --
 325 verifyOutputFiles :: DynFlags -> IO ()
 326 verifyOutputFiles dflags = do
 327   -- not -odir: we create the directory for -odir if it doesn't exist (#2278).
 328   let ofile = outputFile dflags
 329   when (isJust ofile) $ do
 330      let fn = fromJust ofile
 331      flg <- doesDirNameExist fn
 332      when (not flg) (nonExistentDir "-o" fn)
 333   let ohi = outputHi dflags
 334   when (isJust ohi) $ do
 335      let hi = fromJust ohi
 336      flg <- doesDirNameExist hi
 337      when (not flg) (nonExistentDir "-ohi" hi)
 338  where
 339    nonExistentDir flg dir =
 340      ghcError (CmdLineError ("error: directory portion of " ++
 341                              show dir ++ " does not exist (used with " ++
 342                              show flg ++ " option.)"))
 343
 344 -----------------------------------------------------------------------------
 345 -- GHC modes of operation
 346
 347 type Mode = Either PreStartupMode PostStartupMode
 348 type PostStartupMode = Either PreLoadMode PostLoadMode
 349
 350 data PreStartupMode
 351   = ShowVersion             -- ghc -V/--version
 352   | ShowNumVersion          -- ghc --numeric-version
 353   | ShowSupportedLanguages  -- ghc --supported-languages
 354   | Print String            -- ghc --print-foo
 355
 356 showVersionMode, showNumVersionMode, showSupportedLanguagesMode :: Mode
 357 showVersionMode            = mkPreStartupMode ShowVersion
 358 showNumVersionMode         = mkPreStartupMode ShowNumVersion
 359 showSupportedLanguagesMode = mkPreStartupMode ShowSupportedLanguages
 360
 361 printMode :: String -> Mode
 362 printMode str              = mkPreStartupMode (Print str)
 363
 364 mkPreStartupMode :: PreStartupMode -> Mode
 365 mkPreStartupMode = Left
 366
 367 isShowVersionMode :: Mode -> Bool
 368 isShowVersionMode (Left ShowVersion) = True
 369 isShowVersionMode _ = False
 370
 371 isShowNumVersionMode :: Mode -> Bool
 372 isShowNumVersionMode (Left ShowNumVersion) = True
 373 isShowNumVersionMode _ = False
 374
 375 data PreLoadMode
 376   = ShowGhcUsage                           -- ghc -?
 377   | ShowGhciUsage                          -- ghci -?
 378   | ShowInfo                               -- ghc --info
 379   | PrintWithDynFlags (DynFlags -> String) -- ghc --print-foo
 380
 381 showGhcUsageMode, showGhciUsageMode, showInfoMode :: Mode
 382 showGhcUsageMode = mkPreLoadMode ShowGhcUsage
 383 showGhciUsageMode = mkPreLoadMode ShowGhciUsage
 384 showInfoMode = mkPreLoadMode ShowInfo
 385
 386 printWithDynFlagsMode :: (DynFlags -> String) -> Mode
 387 printWithDynFlagsMode f = mkPreLoadMode (PrintWithDynFlags f)
 388
 389 mkPreLoadMode :: PreLoadMode -> Mode
 390 mkPreLoadMode = Right . Left
 391
 392 isShowGhcUsageMode :: Mode -> Bool
 393 isShowGhcUsageMode (Right (Left ShowGhcUsage)) = True
 394 isShowGhcUsageMode _ = False
 395
 396 isShowGhciUsageMode :: Mode -> Bool
 397 isShowGhciUsageMode (Right (Left ShowGhciUsage)) = True
 398 isShowGhciUsageMode _ = False
 399
 400 data PostLoadMode
 401   = ShowInterface FilePath  -- ghc --show-iface
 402   | DoMkDependHS            -- ghc -M
 403   | StopBefore Phase        -- ghc -E | -C | -S
 404                             -- StopBefore StopLn is the default
 405   | DoMake                  -- ghc --make
 406   | DoInteractive           -- ghc --interactive
 407   | DoEval [String]         -- ghc -e foo -e bar => DoEval ["bar", "foo"]
 408   | DoAbiHash               -- ghc --abi-hash
 409
 410 doMkDependHSMode, doMakeMode, doInteractiveMode, doAbiHashMode :: Mode
 411 doMkDependHSMode = mkPostLoadMode DoMkDependHS
 412 doMakeMode = mkPostLoadMode DoMake
 413 doInteractiveMode = mkPostLoadMode DoInteractive
 414 doAbiHashMode = mkPostLoadMode DoAbiHash
 415
 416 showInterfaceMode :: FilePath -> Mode
 417 showInterfaceMode fp = mkPostLoadMode (ShowInterface fp)
 418
 419 stopBeforeMode :: Phase -> Mode
 420 stopBeforeMode phase = mkPostLoadMode (StopBefore phase)
 421
 422 doEvalMode :: String -> Mode
 423 doEvalMode str = mkPostLoadMode (DoEval [str])
 424
 425 mkPostLoadMode :: PostLoadMode -> Mode
 426 mkPostLoadMode = Right . Right
 427
 428 isDoInteractiveMode :: Mode -> Bool
 429 isDoInteractiveMode (Right (Right DoInteractive)) = True
 430 isDoInteractiveMode _ = False
 431
 432 #ifdef GHCI
 433 isInteractiveMode :: PostLoadMode -> Bool
 434 isInteractiveMode DoInteractive = True
 435 isInteractiveMode _             = False
 436 #endif
 437
 438 -- isInterpretiveMode: byte-code compiler involved
 439 isInterpretiveMode :: PostLoadMode -> Bool
 440 isInterpretiveMode DoInteractive = True
 441 isInterpretiveMode (DoEval _)    = True
 442 isInterpretiveMode _             = False
 443
 444 needsInputsMode :: PostLoadMode -> Bool
 445 needsInputsMode DoMkDependHS    = True
 446 needsInputsMode (StopBefore _)  = True
 447 needsInputsMode DoMake          = True
 448 needsInputsMode _               = False
 449
 450 -- True if we are going to attempt to link in this mode.
 451 -- (we might not actually link, depending on the GhcLink flag)
 452 isLinkMode :: PostLoadMode -> Bool
 453 isLinkMode (StopBefore StopLn) = True
 454 isLinkMode DoMake              = True
 455 isLinkMode DoInteractive       = True
 456 isLinkMode (DoEval _)          = True
 457 isLinkMode _                   = False
 458
 459 isCompManagerMode :: PostLoadMode -> Bool
 460 isCompManagerMode DoMake        = True
 461 isCompManagerMode DoInteractive = True
 462 isCompManagerMode (DoEval _)    = True
 463 isCompManagerMode _             = False
 464
 465
 466 -- -----------------------------------------------------------------------------
 467 -- Parsing the mode flag
 468
 469 parseModeFlags :: [Located String]
 470                -> IO (Mode,
 471                       [Located String],
 472                       [Located String])
 473 parseModeFlags args = do
 474   let ((leftover, errs1, warns), (mModeFlag, errs2, flags')) =
 475           runCmdLine (processArgs mode_flags args)
 476                      (Nothing, [], [])
 477       mode = case mModeFlag of
 478              Nothing -> stopBeforeMode StopLn
 479              Just (m, _) -> m
 480       errs = errs1 ++ map (mkGeneralLocated "on the commandline") errs2
 481   when (not (null errs)) $ ghcError $ errorsToGhcException errs
 482   return (mode, flags' ++ leftover, warns)
 483
 484 type ModeM = CmdLineP (Maybe (Mode, String), [String], [Located String])
 485   -- mode flags sometimes give rise to new DynFlags (eg. -C, see below)
 486   -- so we collect the new ones and return them.
 487
 488 mode_flags :: [Flag ModeM]
 489 mode_flags =
 490   [  ------- help / version ----------------------------------------------
 491     Flag "?"                    (PassFlag (setMode showGhcUsageMode))
 492          Supported
 493   , Flag "-help"                (PassFlag (setMode showGhcUsageMode))
 494          Supported
 495   , Flag "V"                    (PassFlag (setMode showVersionMode))
 496          Supported
 497   , Flag "-version"             (PassFlag (setMode showVersionMode))
 498          Supported
 499   , Flag "-numeric-version"     (PassFlag (setMode showNumVersionMode))
 500          Supported
 501   , Flag "-info"                (PassFlag (setMode showInfoMode))
 502          Supported
 503   , Flag "-supported-languages" (PassFlag (setMode showSupportedLanguagesMode))
 504          Supported
 505   ] ++
 506   [ Flag k'                     (PassFlag (setMode mode))
 507          Supported
 508   | (k, v) <- compilerInfo,
 509     let k' = "-print-" ++ map (replaceSpace . toLower) k
 510         replaceSpace ' ' = '-'
 511         replaceSpace c   = c
 512         mode = case v of
 513                String str -> printMode str
 514                FromDynFlags f -> printWithDynFlagsMode f
 515   ] ++
 516       ------- interfaces ----------------------------------------------------
 517   [ Flag "-show-iface"  (HasArg (\f -> setMode (showInterfaceMode f)
 518                                                "--show-iface"))
 519          Supported
 520
 521       ------- primary modes ------------------------------------------------
 522   , Flag "M"            (PassFlag (setMode doMkDependHSMode))
 523          Supported
 524   , Flag "E"            (PassFlag (setMode (stopBeforeMode anyHsc)))
 525          Supported
 526   , Flag "C"            (PassFlag (\f -> do setMode (stopBeforeMode HCc) f
 527                                             addFlag "-fvia-C" f))
 528          Supported
 529   , Flag "S"            (PassFlag (setMode (stopBeforeMode As)))
 530          Supported
 531   , Flag "-make"        (PassFlag (setMode doMakeMode))
 532          Supported
 533   , Flag "-interactive" (PassFlag (setMode doInteractiveMode))
 534          Supported
 535   , Flag "-abi-hash"    (PassFlag (setMode doAbiHashMode))
 536          Supported
 537   , Flag "e"            (HasArg   (\s -> setMode (doEvalMode s) "-e"))
 538          Supported
 539
 540        -- -fno-code says to stop after Hsc but don't generate any code.
 541   , Flag "fno-code"     (PassFlag (\f -> do setMode (stopBeforeMode HCc) f
 542                                             addFlag "-fno-code" f
 543                                             addFlag "-fforce-recomp" f))
 544          Supported
 545   ]
 546
 547 setMode :: Mode -> String -> ModeM ()
 548 setMode newMode newFlag = do
 549     (mModeFlag, errs, flags') <- getCmdLineState
 550     let (modeFlag', errs') =
 551             case mModeFlag of
 552             Nothing -> ((newMode, newFlag), errs)
 553             Just (oldMode, oldFlag) ->
 554                 case (oldMode, newMode) of
 555                     -- If we have both --help and --interactive then we
 556                     -- want showGhciUsage
 557                     _ | isShowGhcUsageMode oldMode &&
 558                         isDoInteractiveMode newMode ->
 559                             ((showGhciUsageMode, oldFlag), [])
 560                       | isShowGhcUsageMode newMode &&
 561                         isDoInteractiveMode oldMode ->
 562                             ((showGhciUsageMode, newFlag), [])
 563                     -- Otherwise, --help/--version/--numeric-version always win
 564                       | isDominantFlag oldMode -> ((oldMode, oldFlag), [])
 565                       | isDominantFlag newMode -> ((newMode, newFlag), [])
 566                     -- We need to accumulate eval flags like "-e foo -e bar"
 567                     (Right (Right (DoEval esOld)),
 568                      Right (Right (DoEval [eNew]))) ->
 569                         ((Right (Right (DoEval (eNew : esOld))), oldFlag),
 570                          errs)
 571                     -- Saying e.g. --interactive --interactive is OK
 572                     _ | oldFlag == newFlag -> ((oldMode, oldFlag), errs)
 573                     -- Otherwise, complain
 574                     _ -> let err = flagMismatchErr oldFlag newFlag
 575                          in ((oldMode, oldFlag), err : errs)
 576     putCmdLineState (Just modeFlag', errs', flags')
 577   where isDominantFlag f = isShowGhcUsageMode   f ||
 578                            isShowGhciUsageMode  f ||
 579                            isShowVersionMode    f ||
 580                            isShowNumVersionMode f
 581
 582 flagMismatchErr :: String -> String -> String
 583 flagMismatchErr oldFlag newFlag
 584     = "cannot use `" ++ oldFlag ++  "' with `" ++ newFlag ++ "'"
 585
 586 addFlag :: String -> String -> ModeM ()
 587 addFlag s flag = do
 588   (m, e, flags') <- getCmdLineState
 589   putCmdLineState (m, e, mkGeneralLocated loc s : flags')
 590     where loc = "addFlag by " ++ flag ++ " on the commandline"
 591
 592 -- ----------------------------------------------------------------------------
 593 -- Run --make mode
 594
 595 doMake :: [(String,Maybe Phase)] -> Ghc ()
 596 doMake []    = ghcError (UsageError "no input files")
 597 doMake srcs  = do
 598     let (hs_srcs, non_hs_srcs) = partition haskellish srcs
 599
 600         haskellish (f,Nothing) =
 601           looksLikeModuleName f || isHaskellSrcFilename f || '.' `notElem` f
 602         haskellish (_,Just phase) =
 603           phase `notElem` [As, Cc, CmmCpp, Cmm, StopLn]
 604
 605     hsc_env <- GHC.getSession
 606     o_files <- mapM (\x -> do
 607                         f <- compileFile hsc_env StopLn x
 608                         GHC.printWarnings
 609                         return f)
 610                  non_hs_srcs
 611     liftIO $ mapM_ (consIORef v_Ld_inputs) (reverse o_files)
 612
 613     targets <- mapM (uncurry GHC.guessTarget) hs_srcs
 614     GHC.setTargets targets
 615     ok_flag <- GHC.load LoadAllTargets
 616
 617     when (failed ok_flag) (liftIO $ exitWith (ExitFailure 1))
 618     return ()
 619
 620
 621 -- ---------------------------------------------------------------------------
 622 -- --show-iface mode
 623
 624 doShowIface :: DynFlags -> FilePath -> IO ()
 625 doShowIface dflags file = do
 626   hsc_env <- newHscEnv defaultCallbacks dflags
 627   showIface hsc_env file
 628
 629 -- ---------------------------------------------------------------------------
 630 -- Various banners and verbosity output.
 631
 632 showBanner :: PostLoadMode -> DynFlags -> IO ()
 633 showBanner _postLoadMode dflags = do
 634    let verb = verbosity dflags
 635
 636 #ifdef GHCI
 637    -- Show the GHCi banner
 638    when (isInteractiveMode _postLoadMode && verb >= 1) $ putStrLn ghciWelcomeMsg
 639 #endif
 640
 641    -- Display details of the configuration in verbose mode
 642    when (verb >= 2) $
 643     do hPutStr stderr "Glasgow Haskell Compiler, Version "
 644        hPutStr stderr cProjectVersion
 645        hPutStr stderr ", for Haskell 98, stage "
 646        hPutStr stderr cStage
 647        hPutStr stderr " booted by GHC version "
 648        hPutStrLn stderr cBooterVersion
 649
 650 -- We print out a Read-friendly string, but a prettier one than the
 651 -- Show instance gives us
 652 showInfo :: DynFlags -> IO ()
 653 showInfo dflags = do
 654         let sq x = " [" ++ x ++ "\n ]"
 655         putStrLn $ sq $ concat $ intersperse "\n ," $ map (show . flatten) compilerInfo
 656     where flatten (k, String v)       = (k, v)
 657           flatten (k, FromDynFlags f) = (k, f dflags)
 658
 659 showSupportedLanguages :: IO ()
 660 showSupportedLanguages = mapM_ putStrLn supportedLanguages
 661
 662 showVersion :: IO ()
 663 showVersion = putStrLn (cProjectName ++ ", version " ++ cProjectVersion)
 664
 665 showGhcUsage :: DynFlags -> IO ()
 666 showGhcUsage = showUsage False
 667
 668 showGhciUsage :: DynFlags -> IO ()
 669 showGhciUsage = showUsage True
 670
 671 showUsage :: Bool -> DynFlags -> IO ()
 672 showUsage ghci dflags = do
 673   let usage_path = if ghci then ghciUsagePath dflags
 674                            else ghcUsagePath dflags
 675   usage <- readFile usage_path
 676   dump usage
 677   where
 678      dump ""          = return ()
 679      dump ('$':'$':s) = putStr progName >> dump s
 680      dump (c:s)       = putChar c >> dump s
 681
 682 dumpFinalStats :: DynFlags -> IO ()
 683 dumpFinalStats dflags =
 684   when (dopt Opt_D_faststring_stats dflags) $ dumpFastStringStats dflags
 685
 686 dumpFastStringStats :: DynFlags -> IO ()
 687 dumpFastStringStats dflags = do
 688   buckets <- getFastStringTable
 689   let (entries, longest, is_z, has_z) = countFS 0 0 0 0 buckets
 690       msg = text "FastString stats:" $$
 691             nest 4 (vcat [text "size:           " <+> int (length buckets),
 692                           text "entries:        " <+> int entries,
 693                           text "longest chain:  " <+> int longest,
 694                           text "z-encoded:      " <+> (is_z `pcntOf` entries),
 695                           text "has z-encoding: " <+> (has_z `pcntOf` entries)
 696                          ])
 697         -- we usually get more "has z-encoding" than "z-encoded", because
 698         -- when we z-encode a string it might hash to the exact same string,
 699         -- which will is not counted as "z-encoded".  Only strings whose
 700         -- Z-encoding is different from the original string are counted in
 701         -- the "z-encoded" total.
 702   putMsg dflags msg
 703   where
 704    x `pcntOf` y = int ((x * 100) `quot` y) <> char '%'
 705
 706 countFS :: Int -> Int -> Int -> Int -> [[FastString]] -> (Int, Int, Int, Int)
 707 countFS entries longest is_z has_z [] = (entries, longest, is_z, has_z)
 708 countFS entries longest is_z has_z (b:bs) =
 709   let
 710         len = length b
 711         longest' = max len longest
 712         entries' = entries + len
 713         is_zs = length (filter isZEncoded b)
 714         has_zs = length (filter hasZEncoding b)
 715   in
 716         countFS entries' longest' (is_z + is_zs) (has_z + has_zs) bs
 717
 718 -- -----------------------------------------------------------------------------
 719 -- ABI hash support
 720
 721 {-
 722         ghc --abi-hash Data.Foo System.Bar
 723
 724 Generates a combined hash of the ABI for modules Data.Foo and
 725 System.Bar.  The modules must already be compiled, and appropriate -i
 726 options may be necessary in order to find the .hi files.
 727
 728 This is used by Cabal for generating the InstalledPackageId for a
 729 package.  The InstalledPackageId must change when the visible ABI of
 730 the package chagnes, so during registration Cabal calls ghc --abi-hash
 731 to get a hash of the package's ABI.
 732 -}
 733
 734 abiHash :: [(String, Maybe Phase)] -> Ghc ()
 735 abiHash strs = do
 736   hsc_env <- getSession
 737   let dflags = hsc_dflags hsc_env
 738
 739   liftIO $ do
 740
 741   let find_it str = do
 742          let modname = mkModuleName str
 743          r <- findImportedModule hsc_env modname Nothing
 744          case r of
 745            Found _ m -> return m
 746            _error    -> ghcError $ CmdLineError $ showSDoc $
 747                           cannotFindInterface dflags modname r
 748
 749   mods <- mapM find_it (map fst strs)
 750
 751   let get_iface modl = loadUserInterface False (text "abiHash") modl
 752   ifaces <- initIfaceCheck hsc_env $ mapM get_iface mods
 753
 754   bh <- openBinMem (3*1024) -- just less than a block
 755   mapM_ (put_ bh . mi_mod_hash) ifaces
 756   f <- fingerprintBinMem bh
 757
 758   putStrLn (showSDoc (ppr f))
 759
 760 -- -----------------------------------------------------------------------------
 761 -- Util
 762
 763 unknownFlagsErr :: [String] -> a
 764 unknownFlagsErr fs = ghcError (UsageError ("unrecognised flags: " ++ unwords fs))