ghc/compiler/basicTypes/MkId.lhs

   1 %
   2 % (c) The AQUA Project, Glasgow University, 1998
   3 %
   4 \section[StdIdInfo]{Standard unfoldings}
   5
   6 This module contains definitions for the IdInfo for things that
   7 have a standard form, namely:
   8
   9         * data constructors
  10         * record selectors
  11         * method and superclass selectors
  12         * primitive operations
  13
  14 \begin{code}
  15 module MkId (
  16         mkSpecPragmaId, mkWorkerId,
  17
  18         mkDictFunId, mkDefaultMethodId,
  19         mkDictSelId,
  20
  21         mkDataConId, mkDataConWrapId,
  22         mkRecordSelId,
  23         mkPrimOpId, mkCCallOpId,
  24
  25         -- And some particular Ids; see below for why they are wired in
  26         wiredInIds,
  27         unsafeCoerceId, realWorldPrimId,
  28         eRROR_ID, rEC_SEL_ERROR_ID, pAT_ERROR_ID, rEC_CON_ERROR_ID,
  29         rEC_UPD_ERROR_ID, iRREFUT_PAT_ERROR_ID, nON_EXHAUSTIVE_GUARDS_ERROR_ID,
  30         nO_METHOD_BINDING_ERROR_ID, aBSENT_ERROR_ID, pAR_ERROR_ID
  31     ) where
  32
  33 #include "HsVersions.h"
  34
  35
  36 import TysPrim          ( openAlphaTyVars, alphaTyVar, alphaTy,
  37                           intPrimTy, realWorldStatePrimTy
  38                         )
  39 import TysWiredIn       ( boolTy, charTy, mkListTy )
  40 import PrelNames        ( pREL_ERR, pREL_GHC )
  41 import PrelRules        ( primOpRule )
  42 import Rules            ( addRule )
  43 import Type             ( Type, ClassContext, mkDictTy, mkDictTys, mkTyConApp, mkTyVarTys,
  44                           mkFunTys, mkFunTy, mkSigmaTy, classesToPreds,
  45                           isUnLiftedType, mkForAllTys, mkTyVarTy, tyVarsOfType, tyVarsOfTypes,
  46                           splitSigmaTy, splitFunTy_maybe,
  47                           splitFunTys, splitForAllTys, unUsgTy,
  48                           mkUsgTy, UsageAnn(..)
  49                         )
  50 import Module           ( Module )
  51 import CoreUtils        ( exprType, mkInlineMe )
  52 import CoreUnfold       ( mkTopUnfolding, mkCompulsoryUnfolding, mkOtherCon )
  53 import Literal          ( Literal(..) )
  54 import Subst            ( mkTopTyVarSubst, substClasses )
  55 import TyCon            ( TyCon, isNewTyCon, tyConTyVars, tyConDataCons, isDataTyCon,
  56                           tyConTheta, isProductTyCon, isUnboxedTupleTyCon )
  57 import Class            ( Class, classBigSig, classTyCon, classTyVars, classSelIds )
  58 import Var              ( Id, TyVar )
  59 import VarSet           ( isEmptyVarSet )
  60 import Name             ( mkDerivedName, mkWiredInIdName, mkLocalName,
  61                           mkWorkerOcc, mkSuperDictSelOcc, mkCCallName,
  62                           Name, NamedThing(..),
  63                         )
  64 import OccName          ( mkSrcVarOcc )
  65 import PrimOp           ( PrimOp(DataToTagOp, CCallOp),
  66                           primOpSig, mkPrimOpIdName,
  67                           CCall, pprCCallOp
  68                         )
  69 import Demand           ( wwStrict, wwPrim, mkStrictnessInfo )
  70 import DataCon          ( DataCon, StrictnessMark(..),
  71                           dataConFieldLabels, dataConRepArity, dataConTyCon,
  72                           dataConArgTys, dataConRepType, dataConRepStrictness,
  73                           dataConName, dataConTheta,
  74                           dataConSig, dataConStrictMarks, dataConId
  75                         )
  76 import Id               ( idType, mkId,
  77                           mkVanillaId, mkTemplateLocals,
  78                           mkTemplateLocal, setInlinePragma, idCprInfo
  79                         )
  80 import IdInfo           ( IdInfo, vanillaIdInfo, mkIdInfo,
  81                           exactArity, setUnfoldingInfo, setCafInfo, setCprInfo,
  82                           setArityInfo, setInlinePragInfo, setSpecInfo,
  83                           mkStrictnessInfo, setStrictnessInfo,
  84                           IdFlavour(..), InlinePragInfo(..), CafInfo(..), StrictnessInfo(..), CprInfo(..)
  85                         )
  86 import FieldLabel       ( FieldLabel, FieldLabelTag, mkFieldLabel, fieldLabelName,
  87                           firstFieldLabelTag, allFieldLabelTags, fieldLabelType
  88                         )
  89 import CoreSyn
  90 import Maybes
  91 import Unique
  92 import Maybe            ( isJust )
  93 import Outputable
  94 import Util             ( assoc )
  95 \end{code}
  96
  97
  98 %************************************************************************
  99 %*                                                                      *
 100 \subsection{Wired in Ids}
 101 %*                                                                      *
 102 %************************************************************************
 103
 104 \begin{code}
 105 wiredInIds
 106   = [   -- These error-y things are wired in because we don't yet have
 107         -- a way to express in an interface file that the result type variable
 108         -- is 'open'; that is can be unified with an unboxed type
 109         --
 110         -- [The interface file format now carry such information, but there's
 111         --  no way yet of expressing at the definition site for these error-reporting
 112         --  functions that they have an 'open' result type. -- sof 1/99]
 113
 114       aBSENT_ERROR_ID
 115     , eRROR_ID
 116     , iRREFUT_PAT_ERROR_ID
 117     , nON_EXHAUSTIVE_GUARDS_ERROR_ID
 118     , nO_METHOD_BINDING_ERROR_ID
 119     , pAR_ERROR_ID
 120     , pAT_ERROR_ID
 121     , rEC_CON_ERROR_ID
 122     , rEC_UPD_ERROR_ID
 123
 124         -- These two can't be defined in Haskell
 125     , realWorldPrimId
 126     , unsafeCoerceId
 127     , getTagId
 128     ]
 129 \end{code}
 130
 131 %************************************************************************
 132 %*                                                                      *
 133 \subsection{Easy ones}
 134 %*                                                                      *
 135 %************************************************************************
 136
 137 \begin{code}
 138 mkSpecPragmaId occ uniq ty loc
 139   = mkId (mkLocalName uniq occ loc) ty (mkIdInfo SpecPragmaId)
 140         -- Maybe a SysLocal?  But then we'd lose the location
 141
 142 mkDefaultMethodId dm_name rec_c ty
 143   = mkVanillaId dm_name ty
 144
 145 mkWorkerId uniq unwrkr ty
 146   = mkVanillaId (mkDerivedName mkWorkerOcc (getName unwrkr) uniq) ty
 147 \end{code}
 148
 149 %************************************************************************
 150 %*                                                                      *
 151 \subsection{Data constructors}
 152 %*                                                                      *
 153 %************************************************************************
 154
 155 \begin{code}
 156 mkDataConId :: Name -> DataCon -> Id
 157         -- Makes the *worker* for the data constructor; that is, the function
 158         -- that takes the reprsentation arguments and builds the constructor.
 159 mkDataConId work_name data_con
 160   = mkId work_name (dataConRepType data_con) info
 161   where
 162     info = mkIdInfo (DataConId data_con)
 163            `setArityInfo`       exactArity arity
 164            `setStrictnessInfo`  strict_info
 165            `setCprInfo`         cpr_info
 166
 167     arity = dataConRepArity data_con
 168
 169     strict_info = mkStrictnessInfo (dataConRepStrictness data_con, False)
 170
 171     cpr_info | isProductTyCon tycon &&
 172                not (isUnboxedTupleTyCon tycon) &&
 173                arity > 0                        = ReturnsCPR
 174              | otherwise                        = NoCPRInfo
 175              where
 176                 tycon = dataConTyCon data_con
 177                 -- Newtypes don't have a worker at all
 178                 --
 179                 -- If we are a product with 0 args we must be void(like)
 180                 -- We can't create an unboxed tuple with 0 args for this
 181                 -- and since Void has only one, constant value it should
 182                 -- just mean returning a pointer to a pre-existing cell.
 183                 -- So we won't really gain from doing anything fancy
 184                 -- and we treat this case as Top.
 185 \end{code}
 186
 187 The wrapper for a constructor is an ordinary top-level binding that evaluates
 188 any strict args, unboxes any args that are going to be flattened, and calls
 189 the worker.
 190
 191 We're going to build a constructor that looks like:
 192
 193         data (Data a, C b) =>  T a b = T1 !a !Int b
 194
 195         T1 = /\ a b ->
 196              \d1::Data a, d2::C b ->
 197              \p q r -> case p of { p ->
 198                        case q of { q ->
 199                        Con T1 [a,b] [p,q,r]}}
 200
 201 Notice that
 202
 203 * d2 is thrown away --- a context in a data decl is used to make sure
 204   one *could* construct dictionaries at the site the constructor
 205   is used, but the dictionary isn't actually used.
 206
 207 * We have to check that we can construct Data dictionaries for
 208   the types a and Int.  Once we've done that we can throw d1 away too.
 209
 210 * We use (case p of q -> ...) to evaluate p, rather than "seq" because
 211   all that matters is that the arguments are evaluated.  "seq" is
 212   very careful to preserve evaluation order, which we don't need
 213   to be here.
 214
 215   You might think that we could simply give constructors some strictness
 216   info, like PrimOps, and let CoreToStg do the let-to-case transformation.
 217   But we don't do that because in the case of primops and functions strictness
 218   is a *property* not a *requirement*.  In the case of constructors we need to
 219   do something active to evaluate the argument.
 220
 221   Making an explicit case expression allows the simplifier to eliminate
 222   it in the (common) case where the constructor arg is already evaluated.
 223
 224 \begin{code}
 225 mkDataConWrapId data_con
 226   = wrap_id
 227   where
 228     wrap_id = mkId (dataConName data_con) wrap_ty info
 229     work_id = dataConId data_con
 230
 231     info = mkIdInfo (DataConWrapId data_con)
 232            `setUnfoldingInfo`   mkTopUnfolding (mkInlineMe wrap_rhs)
 233            `setCprInfo`         cpr_info
 234                 -- The Cpr info can be important inside INLINE rhss, where the
 235                 -- wrapper constructor isn't inlined
 236            `setArityInfo`       exactArity arity
 237                 -- It's important to specify the arity, so that partial
 238                 -- applications are treated as values
 239            `setCafInfo`       NoCafRefs
 240                 -- The wrapper Id ends up in STG code as an argument,
 241                 -- sometimes before its definition, so we want to
 242                 -- signal that it has no CAFs
 243
 244     wrap_ty = mkForAllTys all_tyvars $
 245               mkFunTys all_arg_tys
 246               result_ty
 247
 248     cpr_info = idCprInfo work_id
 249
 250     wrap_rhs | isNewTyCon tycon
 251              = ASSERT( null ex_tyvars && null ex_dict_args && length orig_arg_tys == 1 )
 252                 -- No existentials on a newtype, but it can have a context
 253                 -- e.g.         newtype Eq a => T a = MkT (...)
 254
 255                mkLams tyvars $ mkLams dict_args $ Lam id_arg1 $
 256                Note (Coerce result_ty (head orig_arg_tys)) (Var id_arg1)
 257
 258 {-      I nuked this because map (:) xs would create a
 259         new local lambda for the (:) in core-to-stg.
 260         There isn't a defn for the worker!
 261
 262              | null dict_args && all not_marked_strict strict_marks
 263              = Var work_id      -- The common case.  Not only is this efficient,
 264                                 -- but it also ensures that the wrapper is replaced
 265                                 -- by the worker even when there are no args.
 266                                 --              f (:) x
 267                                 -- becomes
 268                                 --              f $w: x
 269                                 -- This is really important in rule matching,
 270                                 -- which is a bit sad.  (We could match on the wrappers,
 271                                 -- but that makes it less likely that rules will match
 272                                 -- when we bring bits of unfoldings together
 273 -}
 274
 275              | otherwise
 276              = mkLams all_tyvars $ mkLams dict_args $
 277                mkLams ex_dict_args $ mkLams id_args $
 278                foldr mk_case con_app
 279                      (zip (ex_dict_args++id_args) strict_marks) i3 []
 280
 281     con_app i rep_ids = mkApps (Var work_id)
 282                                (map varToCoreExpr (all_tyvars ++ reverse rep_ids))
 283
 284     (tyvars, theta, ex_tyvars, ex_theta, orig_arg_tys, tycon) = dataConSig data_con
 285     all_tyvars   = tyvars ++ ex_tyvars
 286
 287     dict_tys     = mkDictTys theta
 288     ex_dict_tys  = mkDictTys ex_theta
 289     all_arg_tys  = dict_tys ++ ex_dict_tys ++ orig_arg_tys
 290     result_ty    = mkTyConApp tycon (mkTyVarTys tyvars)
 291
 292     mkLocals i tys = (zipWith mkTemplateLocal [i..i+n-1] tys, i+n)
 293                    where
 294                      n = length tys
 295
 296     (dict_args, i1)    = mkLocals 1  dict_tys
 297     (ex_dict_args,i2)  = mkLocals i1 ex_dict_tys
 298     (id_args,i3)       = mkLocals i2 orig_arg_tys
 299     arity              = i3-1
 300     (id_arg1:_)   = id_args             -- Used for newtype only
 301
 302     strict_marks  = dataConStrictMarks data_con
 303     not_marked_strict NotMarkedStrict = True
 304     not_marked_strict other           = False
 305
 306
 307     mk_case
 308            :: (Id, StrictnessMark)      -- arg, strictness
 309            -> (Int -> [Id] -> CoreExpr) -- body
 310            -> Int                       -- next rep arg id
 311            -> [Id]                      -- rep args so far
 312            -> CoreExpr
 313     mk_case (arg,strict) body i rep_args
 314           = case strict of
 315                 NotMarkedStrict -> body i (arg:rep_args)
 316                 MarkedStrict
 317                    | isUnLiftedType (idType arg) -> body i (arg:rep_args)
 318                    | otherwise ->
 319                         Case (Var arg) arg [(DEFAULT,[], body i (arg:rep_args))]
 320
 321                 MarkedUnboxed con tys ->
 322                    Case (Var arg) arg [(DataAlt con, con_args,
 323                                         body i' (reverse con_args++rep_args))]
 324                    where n_tys = length tys
 325                          (con_args,i') = mkLocals i tys
 326 \end{code}
 327
 328
 329 %************************************************************************
 330 %*                                                                      *
 331 \subsection{Record selectors}
 332 %*                                                                      *
 333 %************************************************************************
 334
 335 We're going to build a record selector unfolding that looks like this:
 336
 337         data T a b c = T1 { ..., op :: a, ...}
 338                      | T2 { ..., op :: a, ...}
 339                      | T3
 340
 341         sel = /\ a b c -> \ d -> case d of
 342                                     T1 ... x ... -> x
 343                                     T2 ... x ... -> x
 344                                     other        -> error "..."
 345
 346 Similarly for newtypes
 347
 348         newtype N a = MkN { unN :: a->a }
 349
 350         unN :: N a -> a -> a
 351         unN n = coerce (a->a) n
 352
 353 We need to take a little care if the field has a polymorphic type:
 354
 355         data R = R { f :: forall a. a->a }
 356
 357 Then we want
 358
 359         f :: forall a. R -> a -> a
 360         f = /\ a \ r = case r of
 361                           R f -> f a
 362
 363 (not f :: R -> forall a. a->a, which gives the type inference mechanism
 364 problems at call sites)
 365
 366 Similarly for newtypes
 367
 368         newtype N = MkN { unN :: forall a. a->a }
 369
 370         unN :: forall a. N -> a -> a
 371         unN = /\a -> \n:N -> coerce (a->a) n
 372
 373 \begin{code}
 374 mkRecordSelId tycon field_label unpack_id
 375         -- Assumes that all fields with the same field label have the same type
 376         --
 377         -- Annoyingly, we have to pass in the unpackCString# Id, because
 378         -- we can't conjure it up out of thin air
 379   = sel_id
 380   where
 381     sel_id     = mkId (fieldLabelName field_label) selector_ty info
 382
 383     field_ty   = fieldLabelType field_label
 384     field_name = fieldLabelName field_label
 385     data_cons  = tyConDataCons tycon
 386     tyvars     = tyConTyVars tycon      -- These scope over the types in
 387                                         -- the FieldLabels of constructors of this type
 388     tycon_theta = tyConTheta tycon      -- The context on the data decl
 389                                         --   eg data (Eq a, Ord b) => T a b = ...
 390     (field_tyvars,field_tau) = splitForAllTys field_ty
 391
 392     data_ty   = mkTyConApp tycon tyvar_tys
 393     tyvar_tys = mkTyVarTys tyvars
 394
 395         -- Very tiresomely, the selectors are (unnecessarily!) overloaded over
 396         -- just the dictionaries in the types of the constructors that contain
 397         -- the relevant field.  Urgh.
 398         -- NB: this code relies on the fact that DataCons are quantified over
 399         -- the identical type variables as their parent TyCon
 400     dict_tys  = [mkDictTy cls tys | (cls, tys) <- tycon_theta, needed_dict (cls, tys)]
 401     needed_dict pred = or [ pred `elem` (dataConTheta dc)
 402                           | (DataAlt dc, _, _) <- the_alts]
 403
 404     selector_ty :: Type
 405     selector_ty  = mkForAllTys tyvars $ mkForAllTys field_tyvars $
 406                    mkFunTys dict_tys $  mkFunTy data_ty field_tau
 407
 408     info = mkIdInfo (RecordSelId field_label)
 409            `setArityInfo`       exactArity (1 + length dict_tys)
 410            `setUnfoldingInfo`   unfolding
 411            `setCafInfo`         NoCafRefs
 412         -- ToDo: consider adding further IdInfo
 413
 414     unfolding = mkTopUnfolding sel_rhs
 415
 416
 417     (data_id:dict_ids) = mkTemplateLocals (data_ty:dict_tys)
 418     alts      = map mk_maybe_alt data_cons
 419     the_alts  = catMaybes alts
 420     default_alt | all isJust alts = []  -- No default needed
 421                 | otherwise       = [(DEFAULT, [], error_expr)]
 422
 423     sel_rhs | isNewTyCon tycon = new_sel_rhs
 424             | otherwise        = data_sel_rhs
 425
 426     data_sel_rhs = mkLams tyvars $ mkLams field_tyvars $
 427                    mkLams dict_ids $ Lam data_id $
 428                    Case (Var data_id) data_id (the_alts ++ default_alt)
 429
 430     new_sel_rhs  = mkLams tyvars $ mkLams field_tyvars $ Lam data_id $
 431                     Note (Coerce (unUsgTy field_tau) (unUsgTy data_ty)) (Var data_id)
 432
 433     mk_maybe_alt data_con
 434           = case maybe_the_arg_id of
 435                 Nothing         -> Nothing
 436                 Just the_arg_id -> Just (DataAlt data_con, arg_ids,
 437                                          mkVarApps (Var the_arg_id) field_tyvars)
 438           where
 439             arg_ids          = mkTemplateLocals (dataConArgTys data_con tyvar_tys)
 440                                     -- The first one will shadow data_id, but who cares
 441             field_lbls       = dataConFieldLabels data_con
 442             maybe_the_arg_id = assocMaybe (field_lbls `zip` arg_ids) field_label
 443
 444     error_expr = mkApps (Var rEC_SEL_ERROR_ID) [Type (unUsgTy field_tau), err_string]
 445        -- preserves invariant that type args are *not* usage-annotated on top.  KSW 1999-04.
 446     err_string = App (Var unpack_id) (Lit (MachStr (_PK_ full_msg)))
 447     full_msg   = showSDoc (sep [text "No match in record selector", ppr sel_id])
 448 \end{code}
 449
 450
 451 %************************************************************************
 452 %*                                                                      *
 453 \subsection{Dictionary selectors}
 454 %*                                                                      *
 455 %************************************************************************
 456
 457 Selecting a field for a dictionary.  If there is just one field, then
 458 there's nothing to do.
 459
 460 ToDo: unify with mkRecordSelId.
 461
 462 \begin{code}
 463 mkDictSelId :: Name -> Class -> Id
 464 mkDictSelId name clas
 465   = sel_id
 466   where
 467     ty        = exprType rhs
 468     sel_id    = mkId name ty info
 469     field_lbl = mkFieldLabel name tycon ty tag
 470     tag       = assoc "MkId.mkDictSelId" (classSelIds clas `zip` allFieldLabelTags) sel_id
 471
 472     info      = mkIdInfo (RecordSelId field_lbl)
 473                 `setArityInfo`      exactArity 1
 474                 `setUnfoldingInfo`  unfolding
 475                 `setCafInfo`        NoCafRefs
 476
 477         -- We no longer use 'must-inline' on record selectors.  They'll
 478         -- inline like crazy if they scrutinise a constructor
 479
 480     unfolding = mkTopUnfolding rhs
 481
 482     tyvars  = classTyVars clas
 483
 484     tycon      = classTyCon clas
 485     [data_con] = tyConDataCons tycon
 486     tyvar_tys  = mkTyVarTys tyvars
 487     arg_tys    = dataConArgTys data_con tyvar_tys
 488     the_arg_id = arg_ids !! (tag - firstFieldLabelTag)
 489
 490     dict_ty    = mkDictTy clas tyvar_tys
 491     (dict_id:arg_ids) = mkTemplateLocals (dict_ty : arg_tys)
 492
 493     rhs | isNewTyCon tycon = mkLams tyvars $ Lam dict_id $
 494                              Note (Coerce (head arg_tys) dict_ty) (Var dict_id)
 495         | otherwise        = mkLams tyvars $ Lam dict_id $
 496                              Case (Var dict_id) dict_id
 497                                   [(DataAlt data_con, arg_ids, Var the_arg_id)]
 498 \end{code}
 499
 500
 501 %************************************************************************
 502 %*                                                                      *
 503 \subsection{Primitive operations
 504 %*                                                                      *
 505 %************************************************************************
 506
 507 \begin{code}
 508 mkPrimOpId :: PrimOp -> Id
 509 mkPrimOpId prim_op
 510   = id
 511   where
 512     (tyvars,arg_tys,res_ty, arity, strict_info) = primOpSig prim_op
 513     ty   = mkForAllTys tyvars (mkFunTys arg_tys res_ty)
 514     name = mkPrimOpIdName prim_op id
 515     id   = mkId name ty info
 516
 517     info = mkIdInfo (PrimOpId prim_op)
 518            `setSpecInfo`        rules
 519            `setArityInfo`       exactArity arity
 520            `setStrictnessInfo`  strict_info
 521
 522     rules = addRule id emptyCoreRules (primOpRule prim_op)
 523
 524
 525 -- For each ccall we manufacture a separate CCallOpId, giving it
 526 -- a fresh unique, a type that is correct for this particular ccall,
 527 -- and a CCall structure that gives the correct details about calling
 528 -- convention etc.
 529 --
 530 -- The *name* of this Id is a local name whose OccName gives the full
 531 -- details of the ccall, type and all.  This means that the interface
 532 -- file reader can reconstruct a suitable Id
 533
 534 mkCCallOpId :: Unique -> CCall -> Type -> Id
 535 mkCCallOpId uniq ccall ty
 536   = ASSERT( isEmptyVarSet (tyVarsOfType ty) )
 537         -- A CCallOpId should have no free type variables;
 538         -- when doing substitutions won't substitute over it
 539     mkId name ty info
 540   where
 541     occ_str = showSDocIface (braces (pprCCallOp ccall <+> ppr ty))
 542         -- The "occurrence name" of a ccall is the full info about the
 543         -- ccall; it is encoded, but may have embedded spaces etc!
 544
 545     name    = mkCCallName uniq occ_str
 546     prim_op = CCallOp ccall
 547
 548     info = mkIdInfo (PrimOpId prim_op)
 549            `setArityInfo`       exactArity arity
 550            `setStrictnessInfo`  strict_info
 551
 552     (_, tau)     = splitForAllTys ty
 553     (arg_tys, _) = splitFunTys tau
 554     arity        = length arg_tys
 555     strict_info  = mkStrictnessInfo (take arity (repeat wwPrim), False)
 556 \end{code}
 557
 558
 559 %************************************************************************
 560 %*                                                                      *
 561 \subsection{DictFuns}
 562 %*                                                                      *
 563 %************************************************************************
 564
 565 \begin{code}
 566 mkDictFunId :: Name             -- Name to use for the dict fun;
 567             -> Class
 568             -> [TyVar]
 569             -> [Type]
 570             -> ClassContext
 571             -> Id
 572
 573 mkDictFunId dfun_name clas inst_tyvars inst_tys inst_decl_theta
 574   = mkVanillaId dfun_name dfun_ty
 575   where
 576     (class_tyvars, sc_theta, _, _) = classBigSig clas
 577     sc_theta' = substClasses (mkTopTyVarSubst class_tyvars inst_tys) sc_theta
 578
 579     dfun_theta = classesToPreds inst_decl_theta
 580
 581 {-  1 dec 99: disable the Mark Jones optimisation for the sake
 582     of compatibility with Hugs.
 583     See `types/InstEnv' for a discussion related to this.
 584
 585     dfun_theta = case inst_decl_theta of
 586                    []    -> []  -- If inst_decl_theta is empty, then we don't
 587                                 -- want to have any dict arguments, so that we can
 588                                 -- expose the constant methods.
 589
 590                    other -> nub (inst_decl_theta ++ filter not_const sc_theta')
 591                                 -- Otherwise we pass the superclass dictionaries to
 592                                 -- the dictionary function; the Mark Jones optimisation.
 593                                 --
 594                                 -- NOTE the "nub".  I got caught by this one:
 595                                 --   class Monad m => MonadT t m where ...
 596                                 --   instance Monad m => MonadT (EnvT env) m where ...
 597                                 -- Here, the inst_decl_theta has (Monad m); but so
 598                                 -- does the sc_theta'!
 599                                 --
 600                                 -- NOTE the "not_const".  I got caught by this one too:
 601                                 --   class Foo a => Baz a b where ...
 602                                 --   instance Wob b => Baz T b where..
 603                                 -- Now sc_theta' has Foo T
 604 -}
 605     dfun_ty = mkSigmaTy inst_tyvars dfun_theta (mkDictTy clas inst_tys)
 606
 607     not_const (clas, tys) = not (isEmptyVarSet (tyVarsOfTypes tys))
 608 \end{code}
 609
 610
 611 %************************************************************************
 612 %*                                                                      *
 613 \subsection{Un-definable}
 614 %*                                                                      *
 615 %************************************************************************
 616
 617 These two can't be defined in Haskell.
 618
 619 unsafeCoerce# isn't so much a PrimOp as a phantom identifier, that
 620 just gets expanded into a type coercion wherever it occurs.  Hence we
 621 add it as a built-in Id with an unfolding here.
 622
 623 The type variables we use here are "open" type variables: this means
 624 they can unify with both unlifted and lifted types.  Hence we provide
 625 another gun with which to shoot yourself in the foot.
 626
 627 \begin{code}
 628 unsafeCoerceId
 629   = pcMiscPrelId unsafeCoerceIdKey pREL_GHC SLIT("unsafeCoerce#") ty info
 630   where
 631     info = vanillaIdInfo
 632            `setUnfoldingInfo` mkCompulsoryUnfolding rhs
 633
 634
 635     ty  = mkForAllTys [openAlphaTyVar,openBetaTyVar]
 636                       (mkFunTy openAlphaTy openBetaTy)
 637     [x] = mkTemplateLocals [openAlphaTy]
 638     rhs = mkLams [openAlphaTyVar,openBetaTyVar,x] $
 639           Note (Coerce openBetaTy openAlphaTy) (Var x)
 640 \end{code}
 641
 642
 643 @getTag#@ is another function which can't be defined in Haskell.  It needs to
 644 evaluate its argument and call the dataToTag# primitive.
 645
 646 \begin{code}
 647 getTagId
 648   = pcMiscPrelId getTagIdKey pREL_GHC SLIT("getTag#") ty info
 649   where
 650     info = vanillaIdInfo
 651            `setUnfoldingInfo`   mkCompulsoryUnfolding rhs
 652         -- We don't provide a defn for this; you must inline it
 653
 654     ty = mkForAllTys [alphaTyVar] (mkFunTy alphaTy intPrimTy)
 655     [x,y] = mkTemplateLocals [alphaTy,alphaTy]
 656     rhs = mkLams [alphaTyVar,x] $
 657           Case (Var x) y [ (DEFAULT, [], mkApps (Var dataToTagId) [Type alphaTy, Var y]) ]
 658
 659 dataToTagId = mkPrimOpId DataToTagOp
 660 \end{code}
 661
 662 @realWorld#@ used to be a magic literal, \tr{void#}.  If things get
 663 nasty as-is, change it back to a literal (@Literal@).
 664
 665 \begin{code}
 666 realWorldPrimId -- :: State# RealWorld
 667   = pcMiscPrelId realWorldPrimIdKey pREL_GHC SLIT("realWorld#")
 668                  realWorldStatePrimTy
 669                  (noCafIdInfo `setUnfoldingInfo` mkOtherCon [])
 670         -- The mkOtherCon makes it look that realWorld# is evaluated
 671         -- which in turn makes Simplify.interestingArg return True,
 672         -- which in turn makes INLINE things applied to realWorld# likely
 673         -- to be inlined
 674 \end{code}
 675
 676
 677 %************************************************************************
 678 %*                                                                      *
 679 \subsection[PrelVals-error-related]{@error@ and friends; @trace@}
 680 %*                                                                      *
 681 %************************************************************************
 682
 683 GHC randomly injects these into the code.
 684
 685 @patError@ is just a version of @error@ for pattern-matching
 686 failures.  It knows various ``codes'' which expand to longer
 687 strings---this saves space!
 688
 689 @absentErr@ is a thing we put in for ``absent'' arguments.  They jolly
 690 well shouldn't be yanked on, but if one is, then you will get a
 691 friendly message from @absentErr@ (rather than a totally random
 692 crash).
 693
 694 @parError@ is a special version of @error@ which the compiler does
 695 not know to be a bottoming Id.  It is used in the @_par_@ and @_seq_@
 696 templates, but we don't ever expect to generate code for it.
 697
 698 \begin{code}
 699 eRROR_ID
 700   = pc_bottoming_Id errorIdKey pREL_ERR SLIT("error") errorTy
 701 pAT_ERROR_ID
 702   = generic_ERROR_ID patErrorIdKey SLIT("patError")
 703 rEC_SEL_ERROR_ID
 704   = generic_ERROR_ID recSelErrIdKey SLIT("recSelError")
 705 rEC_CON_ERROR_ID
 706   = generic_ERROR_ID recConErrorIdKey SLIT("recConError")
 707 rEC_UPD_ERROR_ID
 708   = generic_ERROR_ID recUpdErrorIdKey SLIT("recUpdError")
 709 iRREFUT_PAT_ERROR_ID
 710   = generic_ERROR_ID irrefutPatErrorIdKey SLIT("irrefutPatError")
 711 nON_EXHAUSTIVE_GUARDS_ERROR_ID
 712   = generic_ERROR_ID nonExhaustiveGuardsErrorIdKey SLIT("nonExhaustiveGuardsError")
 713 nO_METHOD_BINDING_ERROR_ID
 714   = generic_ERROR_ID noMethodBindingErrorIdKey SLIT("noMethodBindingError")
 715
 716 aBSENT_ERROR_ID
 717   = pc_bottoming_Id absentErrorIdKey pREL_ERR SLIT("absentErr")
 718         (mkSigmaTy [openAlphaTyVar] [] openAlphaTy)
 719
 720 pAR_ERROR_ID
 721   = pcMiscPrelId parErrorIdKey pREL_ERR SLIT("parError")
 722     (mkSigmaTy [openAlphaTyVar] [] openAlphaTy) noCafIdInfo
 723
 724 \end{code}
 725
 726
 727 %************************************************************************
 728 %*                                                                      *
 729 \subsection{Utilities}
 730 %*                                                                      *
 731 %************************************************************************
 732
 733 \begin{code}
 734 pcMiscPrelId :: Unique{-IdKey-} -> Module -> FAST_STRING -> Type -> IdInfo -> Id
 735 pcMiscPrelId key mod str ty info
 736   = let
 737         name = mkWiredInIdName key mod (mkSrcVarOcc str) imp
 738         imp  = mkId name ty info -- the usual case...
 739     in
 740     imp
 741     -- We lie and say the thing is imported; otherwise, we get into
 742     -- a mess with dependency analysis; e.g., core2stg may heave in
 743     -- random calls to GHCbase.unpackPS__.  If GHCbase is the module
 744     -- being compiled, then it's just a matter of luck if the definition
 745     -- will be in "the right place" to be in scope.
 746
 747 pc_bottoming_Id key mod name ty
 748  = pcMiscPrelId key mod name ty bottoming_info
 749  where
 750     bottoming_info = noCafIdInfo
 751                      `setStrictnessInfo` mkStrictnessInfo ([wwStrict], True)
 752
 753         -- these "bottom" out, no matter what their arguments
 754
 755 generic_ERROR_ID u n = pc_bottoming_Id u pREL_ERR n errorTy
 756
 757 -- Very useful...
 758 noCafIdInfo = vanillaIdInfo `setCafInfo` NoCafRefs
 759
 760 (openAlphaTyVar:openBetaTyVar:_) = openAlphaTyVars
 761 openAlphaTy  = mkTyVarTy openAlphaTyVar
 762 openBetaTy   = mkTyVarTy openBetaTyVar
 763
 764 errorTy  :: Type
 765 errorTy  = mkUsgTy UsMany $
 766            mkSigmaTy [openAlphaTyVar] [] (mkFunTys [mkUsgTy UsOnce (mkListTy charTy)]
 767                                                    (mkUsgTy UsMany openAlphaTy))
 768     -- Notice the openAlphaTyVar.  It says that "error" can be applied
 769     -- to unboxed as well as boxed types.  This is OK because it never
 770     -- returns, so the return type is irrelevant.
 771 \end{code}
 772