ghc/compiler/basicTypes/MkId.lhs

   1 %
   2 % (c) The AQUA Project, Glasgow University, 1998
   3 %
   4 \section[StdIdInfo]{Standard unfoldings}
   5
   6 This module contains definitions for the IdInfo for things that
   7 have a standard form, namely:
   8
   9         * data constructors
  10         * record selectors
  11         * method and superclass selectors
  12         * primitive operations
  13
  14 \begin{code}
  15 module MkId (
  16         mkSpecPragmaId, mkWorkerId,
  17
  18         mkDictFunId, mkDefaultMethodId,
  19         mkDictSelId,
  20
  21         mkDataConId, mkDataConWrapId,
  22         mkRecordSelId,
  23         mkPrimOpId, mkCCallOpId,
  24
  25         -- And some particular Ids; see below for why they are wired in
  26         wiredInIds,
  27         unsafeCoerceId, realWorldPrimId,
  28         eRROR_ID, rEC_SEL_ERROR_ID, pAT_ERROR_ID, rEC_CON_ERROR_ID,
  29         rEC_UPD_ERROR_ID, iRREFUT_PAT_ERROR_ID, nON_EXHAUSTIVE_GUARDS_ERROR_ID,
  30         nO_METHOD_BINDING_ERROR_ID, aBSENT_ERROR_ID, pAR_ERROR_ID
  31     ) where
  32
  33 #include "HsVersions.h"
  34
  35
  36 import TysPrim          ( openAlphaTyVars, alphaTyVar, alphaTy,
  37                           intPrimTy, realWorldStatePrimTy
  38                         )
  39 import TysWiredIn       ( charTy, mkListTy )
  40 import PrelNames        ( pREL_ERR, pREL_GHC )
  41 import PrelRules        ( primOpRule )
  42 import Rules            ( addRule )
  43 import Type             ( Type, ThetaType, mkDictTy, mkDictTys, mkTyConApp, mkTyVarTys,
  44                           mkFunTys, mkFunTy, mkSigmaTy, splitSigmaTy,
  45                           isUnLiftedType, mkForAllTys, mkTyVarTy, tyVarsOfType,
  46                           splitFunTys, splitForAllTys, mkPredTy
  47                         )
  48 import Module           ( Module )
  49 import CoreUtils        ( exprType, mkInlineMe )
  50 import CoreUnfold       ( mkTopUnfolding, mkCompulsoryUnfolding, mkOtherCon )
  51 import Literal          ( Literal(..) )
  52 import TyCon            ( TyCon, isNewTyCon, tyConTyVars, tyConDataCons,
  53                           tyConTheta, isProductTyCon, isDataTyCon )
  54 import Class            ( Class, classTyCon, classTyVars, classSelIds )
  55 import Var              ( Id, TyVar )
  56 import VarSet           ( isEmptyVarSet )
  57 import Name             ( mkWiredInName, mkLocalName,
  58                           mkWorkerOcc, mkCCallName,
  59                           Name, NamedThing(..), getSrcLoc
  60                         )
  61 import OccName          ( mkVarOcc )
  62 import PrimOp           ( PrimOp(DataToTagOp, CCallOp),
  63                           primOpSig, mkPrimOpIdName,
  64                           CCall, pprCCallOp
  65                         )
  66 import Demand           ( wwStrict, wwPrim, mkStrictnessInfo )
  67 import DataCon          ( DataCon, StrictnessMark(..),
  68                           dataConFieldLabels, dataConRepArity, dataConTyCon,
  69                           dataConArgTys, dataConRepType, dataConRepStrictness,
  70                           dataConInstOrigArgTys,
  71                           dataConName, dataConTheta,
  72                           dataConSig, dataConStrictMarks, dataConId,
  73                           maybeMarkedUnboxed, splitProductType_maybe
  74                         )
  75 import Id               ( idType, mkId,
  76                           mkVanillaId, mkTemplateLocals, mkTemplateLocalsNum,
  77                           mkTemplateLocal, idCprInfo
  78                         )
  79 import IdInfo           ( IdInfo, constantIdInfo, mkIdInfo,
  80                           exactArity, setUnfoldingInfo, setCafInfo, setCprInfo,
  81                           setArityInfo, setSpecInfo, setTyGenInfo,
  82                           mkStrictnessInfo, setStrictnessInfo,
  83                           IdFlavour(..), CafInfo(..), CprInfo(..), TyGenInfo(..)
  84                         )
  85 import FieldLabel       ( mkFieldLabel, fieldLabelName,
  86                           firstFieldLabelTag, allFieldLabelTags, fieldLabelType
  87                         )
  88 import CoreSyn
  89 import Maybes
  90 import PrelNames
  91 import Maybe            ( isJust )
  92 import Outputable
  93 import ListSetOps       ( assoc, assocMaybe )
  94 import UnicodeUtil      ( stringToUtf8 )
  95 import Char             ( ord )
  96 \end{code}
  97
  98
  99 %************************************************************************
 100 %*                                                                      *
 101 \subsection{Wired in Ids}
 102 %*                                                                      *
 103 %************************************************************************
 104
 105 \begin{code}
 106 wiredInIds
 107   = [   -- These error-y things are wired in because we don't yet have
 108         -- a way to express in an interface file that the result type variable
 109         -- is 'open'; that is can be unified with an unboxed type
 110         --
 111         -- [The interface file format now carry such information, but there's
 112         -- no way yet of expressing at the definition site for these
 113         -- error-reporting
 114         -- functions that they have an 'open' result type. -- sof 1/99]
 115
 116       aBSENT_ERROR_ID
 117     , eRROR_ID
 118     , iRREFUT_PAT_ERROR_ID
 119     , nON_EXHAUSTIVE_GUARDS_ERROR_ID
 120     , nO_METHOD_BINDING_ERROR_ID
 121     , pAR_ERROR_ID
 122     , pAT_ERROR_ID
 123     , rEC_CON_ERROR_ID
 124     , rEC_UPD_ERROR_ID
 125
 126         -- These two can't be defined in Haskell
 127     , realWorldPrimId
 128     , unsafeCoerceId
 129     , getTagId
 130     ]
 131 \end{code}
 132
 133 %************************************************************************
 134 %*                                                                      *
 135 \subsection{Easy ones}
 136 %*                                                                      *
 137 %************************************************************************
 138
 139 \begin{code}
 140 mkSpecPragmaId occ uniq ty loc
 141   = mkId (mkLocalName uniq occ loc) ty (mkIdInfo SpecPragmaId NoCafRefs)
 142         -- Maybe a SysLocal?  But then we'd lose the location
 143
 144 mkDefaultMethodId dm_name rec_c ty
 145   = mkId dm_name ty info
 146   where
 147     info = constantIdInfo `setTyGenInfo` TyGenNever
 148              -- type is wired-in (see comment at TcClassDcl.tcClassSig), so
 149              -- do not generalise it
 150
 151 mkWorkerId :: Unique -> Id -> Type -> Id
 152 -- A worker gets a local name.  CoreTidy will globalise it if necessary.
 153 mkWorkerId uniq unwrkr ty
 154   = mkVanillaId wkr_name ty
 155   where
 156     wkr_name = mkLocalName uniq (mkWorkerOcc (getOccName unwrkr)) (getSrcLoc unwrkr)
 157 \end{code}
 158
 159 %************************************************************************
 160 %*                                                                      *
 161 \subsection{Data constructors}
 162 %*                                                                      *
 163 %************************************************************************
 164
 165 \begin{code}
 166 mkDataConId :: Name -> DataCon -> Id
 167         -- Makes the *worker* for the data constructor; that is, the function
 168         -- that takes the reprsentation arguments and builds the constructor.
 169 mkDataConId work_name data_con
 170   = mkId work_name (dataConRepType data_con) info
 171   where
 172     info = mkIdInfo (DataConId data_con) NoCafRefs
 173            `setArityInfo`       exactArity arity
 174            `setStrictnessInfo`  strict_info
 175            `setCprInfo`         cpr_info
 176
 177     arity = dataConRepArity data_con
 178
 179     strict_info = mkStrictnessInfo (dataConRepStrictness data_con, False)
 180
 181     tycon = dataConTyCon data_con
 182     cpr_info | isProductTyCon tycon &&
 183                isDataTyCon tycon    &&
 184                arity > 0                = ReturnsCPR
 185              | otherwise                = NoCPRInfo
 186         -- ReturnsCPR is only true for products that are real data types;
 187         -- that is, not unboxed tuples or newtypes
 188 \end{code}
 189
 190 The wrapper for a constructor is an ordinary top-level binding that evaluates
 191 any strict args, unboxes any args that are going to be flattened, and calls
 192 the worker.
 193
 194 We're going to build a constructor that looks like:
 195
 196         data (Data a, C b) =>  T a b = T1 !a !Int b
 197
 198         T1 = /\ a b ->
 199              \d1::Data a, d2::C b ->
 200              \p q r -> case p of { p ->
 201                        case q of { q ->
 202                        Con T1 [a,b] [p,q,r]}}
 203
 204 Notice that
 205
 206 * d2 is thrown away --- a context in a data decl is used to make sure
 207   one *could* construct dictionaries at the site the constructor
 208   is used, but the dictionary isn't actually used.
 209
 210 * We have to check that we can construct Data dictionaries for
 211   the types a and Int.  Once we've done that we can throw d1 away too.
 212
 213 * We use (case p of q -> ...) to evaluate p, rather than "seq" because
 214   all that matters is that the arguments are evaluated.  "seq" is
 215   very careful to preserve evaluation order, which we don't need
 216   to be here.
 217
 218   You might think that we could simply give constructors some strictness
 219   info, like PrimOps, and let CoreToStg do the let-to-case transformation.
 220   But we don't do that because in the case of primops and functions strictness
 221   is a *property* not a *requirement*.  In the case of constructors we need to
 222   do something active to evaluate the argument.
 223
 224   Making an explicit case expression allows the simplifier to eliminate
 225   it in the (common) case where the constructor arg is already evaluated.
 226
 227 \begin{code}
 228 mkDataConWrapId data_con
 229   = wrap_id
 230   where
 231     wrap_id = mkId (dataConName data_con) wrap_ty info
 232     work_id = dataConId data_con
 233
 234     info = mkIdInfo (DataConWrapId data_con) NoCafRefs
 235            `setUnfoldingInfo`   mkTopUnfolding (mkInlineMe wrap_rhs)
 236            `setCprInfo`         cpr_info
 237                 -- The Cpr info can be important inside INLINE rhss, where the
 238                 -- wrapper constructor isn't inlined
 239            `setArityInfo`       exactArity arity
 240                 -- It's important to specify the arity, so that partial
 241                 -- applications are treated as values
 242            `setTyGenInfo`     TyGenNever
 243                 -- No point generalising its type, since it gets eagerly inlined
 244                 -- away anyway
 245
 246     wrap_ty = mkForAllTys all_tyvars $
 247               mkFunTys all_arg_tys
 248               result_ty
 249
 250     cpr_info = idCprInfo work_id
 251
 252     wrap_rhs | isNewTyCon tycon
 253              = ASSERT( null ex_tyvars && null ex_dict_args && length orig_arg_tys == 1 )
 254                 -- No existentials on a newtype, but it can have a context
 255                 -- e.g.         newtype Eq a => T a = MkT (...)
 256
 257                mkLams tyvars $ mkLams dict_args $ Lam id_arg1 $
 258                Note (Coerce result_ty (head orig_arg_tys)) (Var id_arg1)
 259
 260              | null dict_args && all not_marked_strict strict_marks
 261              = Var work_id      -- The common case.  Not only is this efficient,
 262                                 -- but it also ensures that the wrapper is replaced
 263                                 -- by the worker even when there are no args.
 264                                 --              f (:) x
 265                                 -- becomes
 266                                 --              f $w: x
 267                                 -- This is really important in rule matching,
 268                                 -- (We could match on the wrappers,
 269                                 -- but that makes it less likely that rules will match
 270                                 -- when we bring bits of unfoldings together.)
 271                 --
 272                 -- NB:  because of this special case, (map (:) ys) turns into
 273                 --      (map $w: ys), and thence into (map (\x xs. $w: x xs) ys)
 274                 --      in core-to-stg.  The top-level defn for (:) is never used.
 275                 --      This is somewhat of a bore, but I'm currently leaving it
 276                 --      as is, so that there still is a top level curried (:) for
 277                 --      the interpreter to call.
 278
 279              | otherwise
 280              = mkLams all_tyvars $ mkLams dict_args $
 281                mkLams ex_dict_args $ mkLams id_args $
 282                foldr mk_case con_app
 283                      (zip (ex_dict_args++id_args) strict_marks) i3 []
 284
 285     con_app i rep_ids = mkApps (Var work_id)
 286                                (map varToCoreExpr (all_tyvars ++ reverse rep_ids))
 287
 288     (tyvars, theta, ex_tyvars, ex_theta, orig_arg_tys, tycon) = dataConSig data_con
 289     all_tyvars   = tyvars ++ ex_tyvars
 290
 291     dict_tys     = mkDictTys theta
 292     ex_dict_tys  = mkDictTys ex_theta
 293     all_arg_tys  = dict_tys ++ ex_dict_tys ++ orig_arg_tys
 294     result_ty    = mkTyConApp tycon (mkTyVarTys tyvars)
 295
 296     mkLocals i tys = (zipWith mkTemplateLocal [i..i+n-1] tys, i+n)
 297                    where
 298                      n = length tys
 299
 300     (dict_args, i1)    = mkLocals 1  dict_tys
 301     (ex_dict_args,i2)  = mkLocals i1 ex_dict_tys
 302     (id_args,i3)       = mkLocals i2 orig_arg_tys
 303     arity              = i3-1
 304     (id_arg1:_)   = id_args             -- Used for newtype only
 305
 306     strict_marks  = dataConStrictMarks data_con
 307     not_marked_strict NotMarkedStrict = True
 308     not_marked_strict other           = False
 309
 310
 311     mk_case
 312            :: (Id, StrictnessMark)      -- arg, strictness
 313            -> (Int -> [Id] -> CoreExpr) -- body
 314            -> Int                       -- next rep arg id
 315            -> [Id]                      -- rep args so far
 316            -> CoreExpr
 317     mk_case (arg,strict) body i rep_args
 318           = case strict of
 319                 NotMarkedStrict -> body i (arg:rep_args)
 320                 MarkedStrict
 321                    | isUnLiftedType (idType arg) -> body i (arg:rep_args)
 322                    | otherwise ->
 323                         Case (Var arg) arg [(DEFAULT,[], body i (arg:rep_args))]
 324
 325                 MarkedUnboxed con tys ->
 326                    Case (Var arg) arg [(DataAlt con, con_args,
 327                                         body i' (reverse con_args++rep_args))]
 328                    where
 329                         (con_args,i') = mkLocals i tys
 330 \end{code}
 331
 332
 333 %************************************************************************
 334 %*                                                                      *
 335 \subsection{Record selectors}
 336 %*                                                                      *
 337 %************************************************************************
 338
 339 We're going to build a record selector unfolding that looks like this:
 340
 341         data T a b c = T1 { ..., op :: a, ...}
 342                      | T2 { ..., op :: a, ...}
 343                      | T3
 344
 345         sel = /\ a b c -> \ d -> case d of
 346                                     T1 ... x ... -> x
 347                                     T2 ... x ... -> x
 348                                     other        -> error "..."
 349
 350 Similarly for newtypes
 351
 352         newtype N a = MkN { unN :: a->a }
 353
 354         unN :: N a -> a -> a
 355         unN n = coerce (a->a) n
 356
 357 We need to take a little care if the field has a polymorphic type:
 358
 359         data R = R { f :: forall a. a->a }
 360
 361 Then we want
 362
 363         f :: forall a. R -> a -> a
 364         f = /\ a \ r = case r of
 365                           R f -> f a
 366
 367 (not f :: R -> forall a. a->a, which gives the type inference mechanism
 368 problems at call sites)
 369
 370 Similarly for newtypes
 371
 372         newtype N = MkN { unN :: forall a. a->a }
 373
 374         unN :: forall a. N -> a -> a
 375         unN = /\a -> \n:N -> coerce (a->a) n
 376
 377 \begin{code}
 378 mkRecordSelId tycon field_label unpack_id unpackUtf8_id
 379         -- Assumes that all fields with the same field label have the same type
 380         --
 381         -- Annoyingly, we have to pass in the unpackCString# Id, because
 382         -- we can't conjure it up out of thin air
 383   = sel_id
 384   where
 385     sel_id     = mkId (fieldLabelName field_label) selector_ty info
 386
 387     field_ty   = fieldLabelType field_label
 388     data_cons  = tyConDataCons tycon
 389     tyvars     = tyConTyVars tycon      -- These scope over the types in
 390                                         -- the FieldLabels of constructors of this type
 391     data_ty   = mkTyConApp tycon tyvar_tys
 392     tyvar_tys = mkTyVarTys tyvars
 393
 394     tycon_theta = tyConTheta tycon      -- The context on the data decl
 395                                         --   eg data (Eq a, Ord b) => T a b = ...
 396     dict_tys  = [mkDictTy cls tys | (cls, tys) <- tycon_theta,
 397                                     needed_dict (cls, tys)]
 398     needed_dict pred = or [ pred `elem` (dataConTheta dc)
 399                           | (DataAlt dc, _, _) <- the_alts]
 400     n_dict_tys = length dict_tys
 401
 402     (field_tyvars,field_theta,field_tau) = splitSigmaTy field_ty
 403     field_dict_tys                       = map mkPredTy field_theta
 404     n_field_dict_tys                     = length field_dict_tys
 405         -- If the field has a universally quantified type we have to
 406         -- be a bit careful.  Suppose we have
 407         --      data R = R { op :: forall a. Foo a => a -> a }
 408         -- Then we can't give op the type
 409         --      op :: R -> forall a. Foo a => a -> a
 410         -- because the typechecker doesn't understand foralls to the
 411         -- right of an arrow.  The "right" type to give it is
 412         --      op :: forall a. Foo a => R -> a -> a
 413         -- But then we must generate the right unfolding too:
 414         --      op = /\a -> \dfoo -> \ r ->
 415         --           case r of
 416         --              R op -> op a dfoo
 417         -- Note that this is exactly the type we'd infer from a user defn
 418         --      op (R op) = op
 419
 420         -- Very tiresomely, the selectors are (unnecessarily!) overloaded over
 421         -- just the dictionaries in the types of the constructors that contain
 422         -- the relevant field.  Urgh.
 423         -- NB: this code relies on the fact that DataCons are quantified over
 424         -- the identical type variables as their parent TyCon
 425
 426     selector_ty :: Type
 427     selector_ty  = mkForAllTys tyvars $ mkForAllTys field_tyvars $
 428                    mkFunTys dict_tys  $  mkFunTys field_dict_tys $
 429                    mkFunTy data_ty field_tau
 430
 431     arity = 1 + n_dict_tys + n_field_dict_tys
 432     info = mkIdInfo (RecordSelId field_label) caf_info
 433            `setArityInfo`       exactArity arity
 434            `setUnfoldingInfo`   unfolding
 435            `setTyGenInfo`       TyGenNever
 436         -- ToDo: consider adding further IdInfo
 437
 438     unfolding = mkTopUnfolding sel_rhs
 439
 440         -- Allocate Ids.  We do it a funny way round because field_dict_tys is
 441         -- almost always empty
 442     dict_ids           = mkTemplateLocalsNum 1              dict_tys
 443     field_dict_ids     = mkTemplateLocalsNum (n_dict_tys+1) field_dict_tys
 444     data_id            = mkTemplateLocal     arity          data_ty
 445
 446     alts      = map mk_maybe_alt data_cons
 447     the_alts  = catMaybes alts
 448
 449     no_default = all isJust alts        -- No default needed
 450     default_alt | no_default = []
 451                 | otherwise  = [(DEFAULT, [], error_expr)]
 452
 453         -- the default branch may have CAF refs, because it calls recSelError etc.
 454     caf_info    | no_default = NoCafRefs
 455                 | otherwise  = MayHaveCafRefs
 456
 457     sel_rhs = mkLams tyvars   $ mkLams field_tyvars $
 458               mkLams dict_ids $ mkLams field_dict_ids $
 459               Lam data_id     $ sel_body
 460
 461     sel_body | isNewTyCon tycon = Note (Coerce field_tau data_ty) (Var data_id)
 462              | otherwise        = Case (Var data_id) data_id (the_alts ++ default_alt)
 463
 464     mk_maybe_alt data_con
 465           = case maybe_the_arg_id of
 466                 Nothing         -> Nothing
 467                 Just the_arg_id -> Just (DataAlt data_con, real_args, expr)
 468                   where
 469                     body              = mkVarApps (mkVarApps (Var the_arg_id) field_tyvars) field_dict_ids
 470                     strict_marks      = dataConStrictMarks data_con
 471                     (expr, real_args) = rebuildConArgs data_con arg_ids strict_marks body
 472                                                        (length arg_ids + 1)
 473         where
 474             arg_ids = mkTemplateLocalsNum (arity+1) (dataConInstOrigArgTys data_con tyvar_tys)
 475                                 -- arity+1 avoids all shadowing
 476             maybe_the_arg_id  = assocMaybe (field_lbls `zip` arg_ids) field_label
 477             field_lbls        = dataConFieldLabels data_con
 478
 479     error_expr = mkApps (Var rEC_SEL_ERROR_ID) [Type field_tau, err_string]
 480     err_string
 481         | all safeChar full_msg
 482             = App (Var unpack_id) (Lit (MachStr (_PK_ full_msg)))
 483         | otherwise
 484             = App (Var unpackUtf8_id) (Lit (MachStr (_PK_ (stringToUtf8 (map ord full_msg)))))
 485         where
 486         safeChar c = c >= '\1' && c <= '\xFF'
 487         -- TODO: Putting this Unicode stuff here is ugly. Find a better
 488         -- generic place to make string literals. This logic is repeated
 489         -- in DsUtils.
 490     full_msg   = showSDoc (sep [text "No match in record selector", ppr sel_id])
 491
 492
 493 -- this rather ugly function converts the unpacked data con arguments back into
 494 -- their packed form.  It is almost the same as the version in DsUtils, except that
 495 -- we use template locals here rather than newDsId (ToDo: merge these).
 496
 497 rebuildConArgs
 498   :: DataCon                            -- the con we're matching on
 499   -> [Id]                               -- the source-level args
 500   -> [StrictnessMark]                   -- the strictness annotations (per-arg)
 501   -> CoreExpr                           -- the body
 502   -> Int                                -- template local
 503   -> (CoreExpr, [Id])
 504
 505 rebuildConArgs con [] stricts body i = (body, [])
 506 rebuildConArgs con (arg:args) stricts body i | isTyVar arg
 507   = let (body', args') = rebuildConArgs con args stricts body i
 508     in  (body',arg:args')
 509 rebuildConArgs con (arg:args) (str:stricts) body i
 510   = case maybeMarkedUnboxed str of
 511         Just (pack_con1, _) ->
 512             case splitProductType_maybe (idType arg) of
 513                 Just (_, tycon_args, pack_con, con_arg_tys) ->
 514                     ASSERT( pack_con == pack_con1 )
 515                     let unpacked_args = zipWith mkTemplateLocal [i..] con_arg_tys
 516                         (body', real_args) = rebuildConArgs con args stricts body
 517                                                 (i + length con_arg_tys)
 518                     in
 519                     (
 520                          Let (NonRec arg (mkConApp pack_con
 521                                                   (map Type tycon_args ++
 522                                                    map Var  unpacked_args))) body',
 523                          unpacked_args ++ real_args
 524                     )
 525
 526         _ -> let (body', args') = rebuildConArgs con args stricts body i
 527              in  (body', arg:args')
 528 \end{code}
 529
 530
 531 %************************************************************************
 532 %*                                                                      *
 533 \subsection{Dictionary selectors}
 534 %*                                                                      *
 535 %************************************************************************
 536
 537 Selecting a field for a dictionary.  If there is just one field, then
 538 there's nothing to do.
 539
 540 ToDo: unify with mkRecordSelId.
 541
 542 \begin{code}
 543 mkDictSelId :: Name -> Class -> Id
 544 mkDictSelId name clas
 545   = sel_id
 546   where
 547     ty        = exprType rhs
 548     sel_id    = mkId name ty info
 549     field_lbl = mkFieldLabel name tycon ty tag
 550     tag       = assoc "MkId.mkDictSelId" (classSelIds clas `zip` allFieldLabelTags) sel_id
 551
 552     info      = mkIdInfo (RecordSelId field_lbl) NoCafRefs
 553                 `setArityInfo`      exactArity 1
 554                 `setUnfoldingInfo`  unfolding
 555                 `setTyGenInfo`      TyGenNever
 556
 557         -- We no longer use 'must-inline' on record selectors.  They'll
 558         -- inline like crazy if they scrutinise a constructor
 559
 560     unfolding = mkTopUnfolding rhs
 561
 562     tyvars  = classTyVars clas
 563
 564     tycon      = classTyCon clas
 565     [data_con] = tyConDataCons tycon
 566     tyvar_tys  = mkTyVarTys tyvars
 567     arg_tys    = dataConArgTys data_con tyvar_tys
 568     the_arg_id = arg_ids !! (tag - firstFieldLabelTag)
 569
 570     dict_ty    = mkDictTy clas tyvar_tys
 571     (dict_id:arg_ids) = mkTemplateLocals (dict_ty : arg_tys)
 572
 573     rhs | isNewTyCon tycon = mkLams tyvars $ Lam dict_id $
 574                              Note (Coerce (head arg_tys) dict_ty) (Var dict_id)
 575         | otherwise        = mkLams tyvars $ Lam dict_id $
 576                              Case (Var dict_id) dict_id
 577                                   [(DataAlt data_con, arg_ids, Var the_arg_id)]
 578 \end{code}
 579
 580
 581 %************************************************************************
 582 %*                                                                      *
 583 \subsection{Primitive operations
 584 %*                                                                      *
 585 %************************************************************************
 586
 587 \begin{code}
 588 mkPrimOpId :: PrimOp -> Id
 589 mkPrimOpId prim_op
 590   = id
 591   where
 592     (tyvars,arg_tys,res_ty, arity, strict_info) = primOpSig prim_op
 593     ty   = mkForAllTys tyvars (mkFunTys arg_tys res_ty)
 594     name = mkPrimOpIdName prim_op
 595     id   = mkId name ty info
 596
 597     info = mkIdInfo (PrimOpId prim_op) NoCafRefs
 598            `setSpecInfo`        rules
 599            `setArityInfo`       exactArity arity
 600            `setStrictnessInfo`  strict_info
 601
 602     rules = addRule emptyCoreRules id (primOpRule prim_op)
 603
 604
 605 -- For each ccall we manufacture a separate CCallOpId, giving it
 606 -- a fresh unique, a type that is correct for this particular ccall,
 607 -- and a CCall structure that gives the correct details about calling
 608 -- convention etc.
 609 --
 610 -- The *name* of this Id is a local name whose OccName gives the full
 611 -- details of the ccall, type and all.  This means that the interface
 612 -- file reader can reconstruct a suitable Id
 613
 614 mkCCallOpId :: Unique -> CCall -> Type -> Id
 615 mkCCallOpId uniq ccall ty
 616   = ASSERT( isEmptyVarSet (tyVarsOfType ty) )
 617         -- A CCallOpId should have no free type variables;
 618         -- when doing substitutions won't substitute over it
 619     mkId name ty info
 620   where
 621     occ_str = showSDocIface (braces (pprCCallOp ccall <+> ppr ty))
 622         -- The "occurrence name" of a ccall is the full info about the
 623         -- ccall; it is encoded, but may have embedded spaces etc!
 624
 625     name    = mkCCallName uniq occ_str
 626     prim_op = CCallOp ccall
 627
 628     info = mkIdInfo (PrimOpId prim_op) NoCafRefs
 629            `setArityInfo`       exactArity arity
 630            `setStrictnessInfo`  strict_info
 631
 632     (_, tau)     = splitForAllTys ty
 633     (arg_tys, _) = splitFunTys tau
 634     arity        = length arg_tys
 635     strict_info  = mkStrictnessInfo (take arity (repeat wwPrim), False)
 636 \end{code}
 637
 638
 639 %************************************************************************
 640 %*                                                                      *
 641 \subsection{DictFuns}
 642 %*                                                                      *
 643 %************************************************************************
 644
 645 \begin{code}
 646 mkDictFunId :: Name             -- Name to use for the dict fun;
 647             -> Class
 648             -> [TyVar]
 649             -> [Type]
 650             -> ThetaType
 651             -> Id
 652
 653 mkDictFunId dfun_name clas inst_tyvars inst_tys dfun_theta
 654   = mkId dfun_name dfun_ty info
 655   where
 656     dfun_ty = mkSigmaTy inst_tyvars dfun_theta (mkDictTy clas inst_tys)
 657     info = mkIdInfo DictFunId MayHaveCafRefs
 658            `setTyGenInfo` TyGenNever
 659              -- type is wired-in (see comment at TcClassDcl.tcClassSig), so
 660              -- do not generalise it
 661         -- An imported dfun may refer to CAFs, so we assume the worst
 662
 663 {-  1 dec 99: disable the Mark Jones optimisation for the sake
 664     of compatibility with Hugs.
 665     See `types/InstEnv' for a discussion related to this.
 666
 667     (class_tyvars, sc_theta, _, _) = classBigSig clas
 668     not_const (clas, tys) = not (isEmptyVarSet (tyVarsOfTypes tys))
 669     sc_theta' = substClasses (mkTopTyVarSubst class_tyvars inst_tys) sc_theta
 670     dfun_theta = case inst_decl_theta of
 671                    []    -> []  -- If inst_decl_theta is empty, then we don't
 672                                 -- want to have any dict arguments, so that we can
 673                                 -- expose the constant methods.
 674
 675                    other -> nub (inst_decl_theta ++ filter not_const sc_theta')
 676                                 -- Otherwise we pass the superclass dictionaries to
 677                                 -- the dictionary function; the Mark Jones optimisation.
 678                                 --
 679                                 -- NOTE the "nub".  I got caught by this one:
 680                                 --   class Monad m => MonadT t m where ...
 681                                 --   instance Monad m => MonadT (EnvT env) m where ...
 682                                 -- Here, the inst_decl_theta has (Monad m); but so
 683                                 -- does the sc_theta'!
 684                                 --
 685                                 -- NOTE the "not_const".  I got caught by this one too:
 686                                 --   class Foo a => Baz a b where ...
 687                                 --   instance Wob b => Baz T b where..
 688                                 -- Now sc_theta' has Foo T
 689 -}
 690 \end{code}
 691
 692
 693 %************************************************************************
 694 %*                                                                      *
 695 \subsection{Un-definable}
 696 %*                                                                      *
 697 %************************************************************************
 698
 699 These two can't be defined in Haskell.
 700
 701 unsafeCoerce# isn't so much a PrimOp as a phantom identifier, that
 702 just gets expanded into a type coercion wherever it occurs.  Hence we
 703 add it as a built-in Id with an unfolding here.
 704
 705 The type variables we use here are "open" type variables: this means
 706 they can unify with both unlifted and lifted types.  Hence we provide
 707 another gun with which to shoot yourself in the foot.
 708
 709 \begin{code}
 710 unsafeCoerceId
 711   = pcMiscPrelId unsafeCoerceIdKey pREL_GHC SLIT("unsafeCoerce#") ty info
 712   where
 713     info = constantIdInfo `setUnfoldingInfo` mkCompulsoryUnfolding rhs
 714
 715
 716     ty  = mkForAllTys [openAlphaTyVar,openBetaTyVar]
 717                       (mkFunTy openAlphaTy openBetaTy)
 718     [x] = mkTemplateLocals [openAlphaTy]
 719     rhs = mkLams [openAlphaTyVar,openBetaTyVar,x] $
 720           Note (Coerce openBetaTy openAlphaTy) (Var x)
 721 \end{code}
 722
 723
 724 @getTag#@ is another function which can't be defined in Haskell.  It needs to
 725 evaluate its argument and call the dataToTag# primitive.
 726
 727 \begin{code}
 728 getTagId
 729   = pcMiscPrelId getTagIdKey pREL_GHC SLIT("getTag#") ty info
 730   where
 731     info = constantIdInfo
 732            `setUnfoldingInfo`   mkCompulsoryUnfolding rhs
 733         -- We don't provide a defn for this; you must inline it
 734
 735     ty = mkForAllTys [alphaTyVar] (mkFunTy alphaTy intPrimTy)
 736     [x,y] = mkTemplateLocals [alphaTy,alphaTy]
 737     rhs = mkLams [alphaTyVar,x] $
 738           Case (Var x) y [ (DEFAULT, [], mkApps (Var dataToTagId) [Type alphaTy, Var y]) ]
 739
 740 dataToTagId = mkPrimOpId DataToTagOp
 741 \end{code}
 742
 743 @realWorld#@ used to be a magic literal, \tr{void#}.  If things get
 744 nasty as-is, change it back to a literal (@Literal@).
 745
 746 \begin{code}
 747 realWorldPrimId -- :: State# RealWorld
 748   = pcMiscPrelId realWorldPrimIdKey pREL_GHC SLIT("realWorld#")
 749                  realWorldStatePrimTy
 750                  (noCafIdInfo `setUnfoldingInfo` mkOtherCon [])
 751         -- The mkOtherCon makes it look that realWorld# is evaluated
 752         -- which in turn makes Simplify.interestingArg return True,
 753         -- which in turn makes INLINE things applied to realWorld# likely
 754         -- to be inlined
 755 \end{code}
 756
 757
 758 %************************************************************************
 759 %*                                                                      *
 760 \subsection[PrelVals-error-related]{@error@ and friends; @trace@}
 761 %*                                                                      *
 762 %************************************************************************
 763
 764 GHC randomly injects these into the code.
 765
 766 @patError@ is just a version of @error@ for pattern-matching
 767 failures.  It knows various ``codes'' which expand to longer
 768 strings---this saves space!
 769
 770 @absentErr@ is a thing we put in for ``absent'' arguments.  They jolly
 771 well shouldn't be yanked on, but if one is, then you will get a
 772 friendly message from @absentErr@ (rather than a totally random
 773 crash).
 774
 775 @parError@ is a special version of @error@ which the compiler does
 776 not know to be a bottoming Id.  It is used in the @_par_@ and @_seq_@
 777 templates, but we don't ever expect to generate code for it.
 778
 779 \begin{code}
 780 eRROR_ID
 781   = pc_bottoming_Id errorIdKey pREL_ERR SLIT("error") errorTy
 782 pAT_ERROR_ID
 783   = generic_ERROR_ID patErrorIdKey SLIT("patError")
 784 rEC_SEL_ERROR_ID
 785   = generic_ERROR_ID recSelErrIdKey SLIT("recSelError")
 786 rEC_CON_ERROR_ID
 787   = generic_ERROR_ID recConErrorIdKey SLIT("recConError")
 788 rEC_UPD_ERROR_ID
 789   = generic_ERROR_ID recUpdErrorIdKey SLIT("recUpdError")
 790 iRREFUT_PAT_ERROR_ID
 791   = generic_ERROR_ID irrefutPatErrorIdKey SLIT("irrefutPatError")
 792 nON_EXHAUSTIVE_GUARDS_ERROR_ID
 793   = generic_ERROR_ID nonExhaustiveGuardsErrorIdKey SLIT("nonExhaustiveGuardsError")
 794 nO_METHOD_BINDING_ERROR_ID
 795   = generic_ERROR_ID noMethodBindingErrorIdKey SLIT("noMethodBindingError")
 796
 797 aBSENT_ERROR_ID
 798   = pc_bottoming_Id absentErrorIdKey pREL_ERR SLIT("absentErr")
 799         (mkSigmaTy [openAlphaTyVar] [] openAlphaTy)
 800
 801 pAR_ERROR_ID
 802   = pcMiscPrelId parErrorIdKey pREL_ERR SLIT("parError")
 803     (mkSigmaTy [openAlphaTyVar] [] openAlphaTy) noCafIdInfo
 804
 805 \end{code}
 806
 807
 808 %************************************************************************
 809 %*                                                                      *
 810 \subsection{Utilities}
 811 %*                                                                      *
 812 %************************************************************************
 813
 814 \begin{code}
 815 pcMiscPrelId :: Unique{-IdKey-} -> Module -> FAST_STRING -> Type -> IdInfo -> Id
 816 pcMiscPrelId key mod str ty info
 817   = let
 818         name = mkWiredInName mod (mkVarOcc str) key
 819         imp  = mkId name ty info -- the usual case...
 820     in
 821     imp
 822     -- We lie and say the thing is imported; otherwise, we get into
 823     -- a mess with dependency analysis; e.g., core2stg may heave in
 824     -- random calls to GHCbase.unpackPS__.  If GHCbase is the module
 825     -- being compiled, then it's just a matter of luck if the definition
 826     -- will be in "the right place" to be in scope.
 827
 828 pc_bottoming_Id key mod name ty
 829  = pcMiscPrelId key mod name ty bottoming_info
 830  where
 831     bottoming_info = noCafIdInfo
 832                      `setStrictnessInfo` mkStrictnessInfo ([wwStrict], True)
 833
 834         -- these "bottom" out, no matter what their arguments
 835
 836 generic_ERROR_ID u n = pc_bottoming_Id u pREL_ERR n errorTy
 837
 838 -- Very useful...
 839 noCafIdInfo = constantIdInfo `setCafInfo` NoCafRefs
 840
 841 (openAlphaTyVar:openBetaTyVar:_) = openAlphaTyVars
 842 openAlphaTy  = mkTyVarTy openAlphaTyVar
 843 openBetaTy   = mkTyVarTy openBetaTyVar
 844
 845 errorTy  :: Type
 846 errorTy  = mkSigmaTy [openAlphaTyVar] [] (mkFunTys [mkListTy charTy]
 847                                                    openAlphaTy)
 848     -- Notice the openAlphaTyVar.  It says that "error" can be applied
 849     -- to unboxed as well as boxed types.  This is OK because it never
 850     -- returns, so the return type is irrelevant.
 851 \end{code}
 852