ghc/compiler/basicTypes/MkId.lhs

   1 %
   2 % (c) The AQUA Project, Glasgow University, 1998
   3 %
   4 \section[StdIdInfo]{Standard unfoldings}
   5
   6 This module contains definitions for the IdInfo for things that
   7 have a standard form, namely:
   8
   9         * data constructors
  10         * record selectors
  11         * method and superclass selectors
  12         * primitive operations
  13
  14 \begin{code}
  15 module MkId (
  16         mkSpecPragmaId, mkWorkerId,
  17
  18         mkDictFunId, mkDefaultMethodId,
  19         mkDictSelId,
  20
  21         mkDataConId, mkDataConWrapId,
  22         mkRecordSelId,
  23         mkPrimOpId, mkCCallOpId,
  24
  25         -- And some particular Ids; see below for why they are wired in
  26         wiredInIds,
  27         unsafeCoerceId, realWorldPrimId,
  28         eRROR_ID, rEC_SEL_ERROR_ID, pAT_ERROR_ID, rEC_CON_ERROR_ID,
  29         rEC_UPD_ERROR_ID, iRREFUT_PAT_ERROR_ID, nON_EXHAUSTIVE_GUARDS_ERROR_ID,
  30         nO_METHOD_BINDING_ERROR_ID, aBSENT_ERROR_ID, pAR_ERROR_ID
  31     ) where
  32
  33 #include "HsVersions.h"
  34
  35
  36 import TysPrim          ( openAlphaTyVars, alphaTyVar, alphaTy,
  37                           intPrimTy, realWorldStatePrimTy
  38                         )
  39 import TysWiredIn       ( charTy, mkListTy )
  40 import PrelNames        ( pREL_ERR, pREL_GHC )
  41 import PrelRules        ( primOpRule )
  42 import Rules            ( addRule )
  43 import Type             ( Type, ThetaType, mkDictTy, mkDictTys, mkTyConApp, mkTyVarTys,
  44                           mkFunTys, mkFunTy, mkSigmaTy, splitSigmaTy,
  45                           isUnLiftedType, mkForAllTys, mkTyVarTy, tyVarsOfType,
  46                           splitFunTys, splitForAllTys, mkPredTy
  47                         )
  48 import Module           ( Module )
  49 import CoreUtils        ( exprType, mkInlineMe )
  50 import CoreUnfold       ( mkTopUnfolding, mkCompulsoryUnfolding, mkOtherCon )
  51 import Literal          ( Literal(..) )
  52 import TyCon            ( TyCon, isNewTyCon, tyConTyVars, tyConDataCons,
  53                           tyConTheta, isProductTyCon, isDataTyCon )
  54 import Class            ( Class, classTyCon, classTyVars, classSelIds )
  55 import Var              ( Id, TyVar )
  56 import VarSet           ( isEmptyVarSet )
  57 import Name             ( mkWiredInName, mkLocalName,
  58                           mkWorkerOcc, mkCCallName,
  59                           Name, NamedThing(..), getSrcLoc
  60                         )
  61 import OccName          ( mkVarOcc )
  62 import PrimOp           ( PrimOp(DataToTagOp, CCallOp),
  63                           primOpSig, mkPrimOpIdName,
  64                           CCall, pprCCallOp
  65                         )
  66 import Demand           ( wwStrict, wwPrim, mkStrictnessInfo )
  67 import DataCon          ( DataCon, StrictnessMark(..),
  68                           dataConFieldLabels, dataConRepArity, dataConTyCon,
  69                           dataConArgTys, dataConRepType, dataConRepStrictness,
  70                           dataConInstOrigArgTys,
  71                           dataConName, dataConTheta,
  72                           dataConSig, dataConStrictMarks, dataConId,
  73                           maybeMarkedUnboxed, splitProductType_maybe
  74                         )
  75 import Id               ( idType, mkId,
  76                           mkVanillaId, mkTemplateLocals, mkTemplateLocalsNum,
  77                           mkTemplateLocal, idCprInfo
  78                         )
  79 import IdInfo           ( IdInfo, constantIdInfo, mkIdInfo,
  80                           exactArity, setUnfoldingInfo, setCafInfo, setCprInfo,
  81                           setArityInfo, setSpecInfo, setTyGenInfo,
  82                           mkStrictnessInfo, setStrictnessInfo,
  83                           IdFlavour(..), CafInfo(..), CprInfo(..), TyGenInfo(..)
  84                         )
  85 import FieldLabel       ( mkFieldLabel, fieldLabelName,
  86                           firstFieldLabelTag, allFieldLabelTags, fieldLabelType
  87                         )
  88 import CoreSyn
  89 import Maybes
  90 import PrelNames
  91 import Maybe            ( isJust )
  92 import Outputable
  93 import ListSetOps       ( assoc, assocMaybe )
  94 import UnicodeUtil      ( stringToUtf8 )
  95 import Char             ( ord )
  96 \end{code}
  97
  98
  99 %************************************************************************
 100 %*                                                                      *
 101 \subsection{Wired in Ids}
 102 %*                                                                      *
 103 %************************************************************************
 104
 105 \begin{code}
 106 wiredInIds
 107   = [   -- These error-y things are wired in because we don't yet have
 108         -- a way to express in an interface file that the result type variable
 109         -- is 'open'; that is can be unified with an unboxed type
 110         --
 111         -- [The interface file format now carry such information, but there's
 112         -- no way yet of expressing at the definition site for these
 113         -- error-reporting
 114         -- functions that they have an 'open' result type. -- sof 1/99]
 115
 116       aBSENT_ERROR_ID
 117     , eRROR_ID
 118     , iRREFUT_PAT_ERROR_ID
 119     , nON_EXHAUSTIVE_GUARDS_ERROR_ID
 120     , nO_METHOD_BINDING_ERROR_ID
 121     , pAR_ERROR_ID
 122     , pAT_ERROR_ID
 123     , rEC_CON_ERROR_ID
 124     , rEC_UPD_ERROR_ID
 125
 126         -- These two can't be defined in Haskell
 127     , realWorldPrimId
 128     , unsafeCoerceId
 129     , getTagId
 130     ]
 131 \end{code}
 132
 133 %************************************************************************
 134 %*                                                                      *
 135 \subsection{Easy ones}
 136 %*                                                                      *
 137 %************************************************************************
 138
 139 \begin{code}
 140 mkSpecPragmaId occ uniq ty loc
 141   = mkId (mkLocalName uniq occ loc) ty (mkIdInfo SpecPragmaId NoCafRefs)
 142         -- Maybe a SysLocal?  But then we'd lose the location
 143
 144 mkDefaultMethodId dm_name rec_c ty
 145   = mkId dm_name ty info
 146   where
 147     info = constantIdInfo `setTyGenInfo` TyGenNever
 148              -- type is wired-in (see comment at TcClassDcl.tcClassSig), so
 149              -- do not generalise it
 150
 151 mkWorkerId :: Unique -> Id -> Type -> Id
 152 -- A worker gets a local name.  CoreTidy will globalise it if necessary.
 153 mkWorkerId uniq unwrkr ty
 154   = mkVanillaId wkr_name ty
 155   where
 156     wkr_name = mkLocalName uniq (mkWorkerOcc (getOccName unwrkr)) (getSrcLoc unwrkr)
 157 \end{code}
 158
 159 %************************************************************************
 160 %*                                                                      *
 161 \subsection{Data constructors}
 162 %*                                                                      *
 163 %************************************************************************
 164
 165 \begin{code}
 166 mkDataConId :: Name -> DataCon -> Id
 167         -- Makes the *worker* for the data constructor; that is, the function
 168         -- that takes the reprsentation arguments and builds the constructor.
 169 mkDataConId work_name data_con
 170   = mkId work_name (dataConRepType data_con) info
 171   where
 172     info = mkIdInfo (DataConId data_con) NoCafRefs
 173            `setArityInfo`       exactArity arity
 174            `setStrictnessInfo`  strict_info
 175            `setCprInfo`         cpr_info
 176
 177     arity = dataConRepArity data_con
 178
 179     strict_info = mkStrictnessInfo (dataConRepStrictness data_con, False)
 180
 181     tycon = dataConTyCon data_con
 182     cpr_info | isProductTyCon tycon &&
 183                isDataTyCon tycon    &&
 184                arity > 0                = ReturnsCPR
 185              | otherwise                = NoCPRInfo
 186         -- ReturnsCPR is only true for products that are real data types;
 187         -- that is, not unboxed tuples or newtypes
 188 \end{code}
 189
 190 The wrapper for a constructor is an ordinary top-level binding that evaluates
 191 any strict args, unboxes any args that are going to be flattened, and calls
 192 the worker.
 193
 194 We're going to build a constructor that looks like:
 195
 196         data (Data a, C b) =>  T a b = T1 !a !Int b
 197
 198         T1 = /\ a b ->
 199              \d1::Data a, d2::C b ->
 200              \p q r -> case p of { p ->
 201                        case q of { q ->
 202                        Con T1 [a,b] [p,q,r]}}
 203
 204 Notice that
 205
 206 * d2 is thrown away --- a context in a data decl is used to make sure
 207   one *could* construct dictionaries at the site the constructor
 208   is used, but the dictionary isn't actually used.
 209
 210 * We have to check that we can construct Data dictionaries for
 211   the types a and Int.  Once we've done that we can throw d1 away too.
 212
 213 * We use (case p of q -> ...) to evaluate p, rather than "seq" because
 214   all that matters is that the arguments are evaluated.  "seq" is
 215   very careful to preserve evaluation order, which we don't need
 216   to be here.
 217
 218   You might think that we could simply give constructors some strictness
 219   info, like PrimOps, and let CoreToStg do the let-to-case transformation.
 220   But we don't do that because in the case of primops and functions strictness
 221   is a *property* not a *requirement*.  In the case of constructors we need to
 222   do something active to evaluate the argument.
 223
 224   Making an explicit case expression allows the simplifier to eliminate
 225   it in the (common) case where the constructor arg is already evaluated.
 226
 227 \begin{code}
 228 mkDataConWrapId data_con
 229   = wrap_id
 230   where
 231     wrap_id = mkId (dataConName data_con) wrap_ty info
 232     work_id = dataConId data_con
 233
 234     info = mkIdInfo (DataConWrapId data_con) NoCafRefs
 235            `setUnfoldingInfo`   mkTopUnfolding (mkInlineMe wrap_rhs)
 236            `setCprInfo`         cpr_info
 237                 -- The Cpr info can be important inside INLINE rhss, where the
 238                 -- wrapper constructor isn't inlined
 239            `setArityInfo`       exactArity arity
 240                 -- It's important to specify the arity, so that partial
 241                 -- applications are treated as values
 242            `setTyGenInfo`     TyGenNever
 243                 -- No point generalising its type, since it gets eagerly inlined
 244                 -- away anyway
 245
 246     wrap_ty = mkForAllTys all_tyvars $
 247               mkFunTys all_arg_tys
 248               result_ty
 249
 250     cpr_info = idCprInfo work_id
 251
 252     wrap_rhs | isNewTyCon tycon
 253              = ASSERT( null ex_tyvars && null ex_dict_args && length orig_arg_tys == 1 )
 254                 -- No existentials on a newtype, but it can have a context
 255                 -- e.g.         newtype Eq a => T a = MkT (...)
 256
 257                mkLams tyvars $ mkLams dict_args $ Lam id_arg1 $
 258                Note (Coerce result_ty (head orig_arg_tys)) (Var id_arg1)
 259
 260              | null dict_args && all not_marked_strict strict_marks
 261              = Var work_id      -- The common case.  Not only is this efficient,
 262                                 -- but it also ensures that the wrapper is replaced
 263                                 -- by the worker even when there are no args.
 264                                 --              f (:) x
 265                                 -- becomes
 266                                 --              f $w: x
 267                                 -- This is really important in rule matching,
 268                                 -- (We could match on the wrappers,
 269                                 -- but that makes it less likely that rules will match
 270                                 -- when we bring bits of unfoldings together.)
 271                 --
 272                 -- NB:  because of this special case, (map (:) ys) turns into
 273                 --      (map $w: ys), and thence into (map (\x xs. $w: x xs) ys)
 274                 --      in core-to-stg.  The top-level defn for (:) is never used.
 275                 --      This is somewhat of a bore, but I'm currently leaving it
 276                 --      as is, so that there still is a top level curried (:) for
 277                 --      the interpreter to call.
 278
 279              | otherwise
 280              = mkLams all_tyvars $ mkLams dict_args $
 281                mkLams ex_dict_args $ mkLams id_args $
 282                foldr mk_case con_app
 283                      (zip (ex_dict_args++id_args) strict_marks) i3 []
 284
 285     con_app i rep_ids = mkApps (Var work_id)
 286                                (map varToCoreExpr (all_tyvars ++ reverse rep_ids))
 287
 288     (tyvars, theta, ex_tyvars, ex_theta, orig_arg_tys, tycon) = dataConSig data_con
 289     all_tyvars   = tyvars ++ ex_tyvars
 290
 291     dict_tys     = mkDictTys theta
 292     ex_dict_tys  = mkDictTys ex_theta
 293     all_arg_tys  = dict_tys ++ ex_dict_tys ++ orig_arg_tys
 294     result_ty    = mkTyConApp tycon (mkTyVarTys tyvars)
 295
 296     mkLocals i tys = (zipWith mkTemplateLocal [i..i+n-1] tys, i+n)
 297                    where
 298                      n = length tys
 299
 300     (dict_args, i1)    = mkLocals 1  dict_tys
 301     (ex_dict_args,i2)  = mkLocals i1 ex_dict_tys
 302     (id_args,i3)       = mkLocals i2 orig_arg_tys
 303     arity              = i3-1
 304     (id_arg1:_)   = id_args             -- Used for newtype only
 305
 306     strict_marks  = dataConStrictMarks data_con
 307     not_marked_strict NotMarkedStrict = True
 308     not_marked_strict other           = False
 309
 310
 311     mk_case
 312            :: (Id, StrictnessMark)      -- arg, strictness
 313            -> (Int -> [Id] -> CoreExpr) -- body
 314            -> Int                       -- next rep arg id
 315            -> [Id]                      -- rep args so far
 316            -> CoreExpr
 317     mk_case (arg,strict) body i rep_args
 318           = case strict of
 319                 NotMarkedStrict -> body i (arg:rep_args)
 320                 MarkedStrict
 321                    | isUnLiftedType (idType arg) -> body i (arg:rep_args)
 322                    | otherwise ->
 323                         Case (Var arg) arg [(DEFAULT,[], body i (arg:rep_args))]
 324
 325                 MarkedUnboxed con tys ->
 326                    Case (Var arg) arg [(DataAlt con, con_args,
 327                                         body i' (reverse con_args++rep_args))]
 328                    where
 329                         (con_args,i') = mkLocals i tys
 330 \end{code}
 331
 332
 333 %************************************************************************
 334 %*                                                                      *
 335 \subsection{Record selectors}
 336 %*                                                                      *
 337 %************************************************************************
 338
 339 We're going to build a record selector unfolding that looks like this:
 340
 341         data T a b c = T1 { ..., op :: a, ...}
 342                      | T2 { ..., op :: a, ...}
 343                      | T3
 344
 345         sel = /\ a b c -> \ d -> case d of
 346                                     T1 ... x ... -> x
 347                                     T2 ... x ... -> x
 348                                     other        -> error "..."
 349
 350 Similarly for newtypes
 351
 352         newtype N a = MkN { unN :: a->a }
 353
 354         unN :: N a -> a -> a
 355         unN n = coerce (a->a) n
 356
 357 We need to take a little care if the field has a polymorphic type:
 358
 359         data R = R { f :: forall a. a->a }
 360
 361 Then we want
 362
 363         f :: forall a. R -> a -> a
 364         f = /\ a \ r = case r of
 365                           R f -> f a
 366
 367 (not f :: R -> forall a. a->a, which gives the type inference mechanism
 368 problems at call sites)
 369
 370 Similarly for newtypes
 371
 372         newtype N = MkN { unN :: forall a. a->a }
 373
 374         unN :: forall a. N -> a -> a
 375         unN = /\a -> \n:N -> coerce (a->a) n
 376
 377 \begin{code}
 378 mkRecordSelId tycon field_label unpack_id unpackUtf8_id
 379         -- Assumes that all fields with the same field label have the same type
 380         --
 381         -- Annoyingly, we have to pass in the unpackCString# Id, because
 382         -- we can't conjure it up out of thin air
 383   = sel_id
 384   where
 385     sel_id     = mkId (fieldLabelName field_label) selector_ty info
 386
 387     field_ty   = fieldLabelType field_label
 388     data_cons  = tyConDataCons tycon
 389     tyvars     = tyConTyVars tycon      -- These scope over the types in
 390                                         -- the FieldLabels of constructors of this type
 391     data_ty   = mkTyConApp tycon tyvar_tys
 392     tyvar_tys = mkTyVarTys tyvars
 393
 394     tycon_theta = tyConTheta tycon      -- The context on the data decl
 395                                         --   eg data (Eq a, Ord b) => T a b = ...
 396     dict_tys  = [mkDictTy cls tys | (cls, tys) <- tycon_theta,
 397                                     needed_dict (cls, tys)]
 398     needed_dict pred = or [ pred `elem` (dataConTheta dc)
 399                           | (DataAlt dc, _, _) <- the_alts]
 400     n_dict_tys = length dict_tys
 401
 402     (field_tyvars,field_theta,field_tau) = splitSigmaTy field_ty
 403     field_dict_tys                       = map mkPredTy field_theta
 404     n_field_dict_tys                     = length field_dict_tys
 405         -- If the field has a universally quantified type we have to
 406         -- be a bit careful.  Suppose we have
 407         --      data R = R { op :: forall a => Foo a => a -> a }
 408         -- Then we can't give op the type
 409         --      op :: R -> forall a. Foo a => a -> a
 410         -- because the typechecker doesn't understand foralls to the
 411         -- right of an arrow.  The "right" type to give it is
 412         --      op :: forall a. Foo a => a -> a
 413         -- But then we must generat the right unfolding too:
 414         --      op = /\a -> \dfoo -> \ r ->
 415         --           case r of
 416         --              R op -> op a dfoo
 417         -- Note that this is exactly the type we'd infer from a user defn
 418         --      op (R op) = op
 419
 420         -- Very tiresomely, the selectors are (unnecessarily!) overloaded over
 421         -- just the dictionaries in the types of the constructors that contain
 422         -- the relevant field.  Urgh.
 423         -- NB: this code relies on the fact that DataCons are quantified over
 424         -- the identical type variables as their parent TyCon
 425
 426     selector_ty :: Type
 427     selector_ty  = mkForAllTys tyvars $ mkForAllTys field_tyvars $
 428                    mkFunTys dict_tys  $  mkFunTys field_dict_tys $
 429                    mkFunTy data_ty field_tau
 430
 431     arity = 1 + n_dict_tys + n_field_dict_tys
 432     info = mkIdInfo (RecordSelId field_label) NoCafRefs
 433            `setArityInfo`       exactArity arity
 434            `setUnfoldingInfo`   unfolding
 435            `setTyGenInfo`       TyGenNever
 436         -- ToDo: consider adding further IdInfo
 437
 438     unfolding = mkTopUnfolding sel_rhs
 439
 440         -- Allocate Ids.  We do it a funny way round because field_dict_tys is
 441         -- almost always empty
 442     dict_ids           = mkTemplateLocalsNum 1              dict_tys
 443     field_dict_ids     = mkTemplateLocalsNum (n_dict_tys+1) field_dict_tys
 444     data_id            = mkTemplateLocal     arity          data_ty
 445
 446     alts      = map mk_maybe_alt data_cons
 447     the_alts  = catMaybes alts
 448     default_alt | all isJust alts = []  -- No default needed
 449                 | otherwise       = [(DEFAULT, [], error_expr)]
 450
 451     sel_rhs = mkLams tyvars   $ mkLams field_tyvars $
 452               mkLams dict_ids $ mkLams field_dict_ids $
 453               Lam data_id     $ sel_body
 454
 455     sel_body | isNewTyCon tycon = Note (Coerce field_tau data_ty) (Var data_id)
 456              | otherwise        = Case (Var data_id) data_id (the_alts ++ default_alt)
 457
 458     mk_maybe_alt data_con
 459           = case maybe_the_arg_id of
 460                 Nothing         -> Nothing
 461                 Just the_arg_id -> Just (DataAlt data_con, real_args, expr)
 462                   where
 463                     body              = mkVarApps (mkVarApps (Var the_arg_id) field_tyvars) field_dict_ids
 464                     strict_marks      = dataConStrictMarks data_con
 465                     (expr, real_args) = rebuildConArgs data_con arg_ids strict_marks body
 466                                                        (length arg_ids + 1)
 467         where
 468             arg_ids = mkTemplateLocalsNum (arity+1) (dataConInstOrigArgTys data_con tyvar_tys)
 469                                 -- arity+1 avoids all shadowing
 470             maybe_the_arg_id  = assocMaybe (field_lbls `zip` arg_ids) field_label
 471             field_lbls        = dataConFieldLabels data_con
 472
 473     error_expr = mkApps (Var rEC_SEL_ERROR_ID) [Type field_tau, err_string]
 474     err_string
 475         | all safeChar full_msg
 476             = App (Var unpack_id) (Lit (MachStr (_PK_ full_msg)))
 477         | otherwise
 478             = App (Var unpackUtf8_id) (Lit (MachStr (_PK_ (stringToUtf8 (map ord full_msg)))))
 479         where
 480         safeChar c = c >= '\1' && c <= '\xFF'
 481         -- TODO: Putting this Unicode stuff here is ugly. Find a better
 482         -- generic place to make string literals. This logic is repeated
 483         -- in DsUtils.
 484     full_msg   = showSDoc (sep [text "No match in record selector", ppr sel_id])
 485
 486
 487 -- this rather ugly function converts the unpacked data con arguments back into
 488 -- their packed form.  It is almost the same as the version in DsUtils, except that
 489 -- we use template locals here rather than newDsId (ToDo: merge these).
 490
 491 rebuildConArgs
 492   :: DataCon                            -- the con we're matching on
 493   -> [Id]                               -- the source-level args
 494   -> [StrictnessMark]                   -- the strictness annotations (per-arg)
 495   -> CoreExpr                           -- the body
 496   -> Int                                -- template local
 497   -> (CoreExpr, [Id])
 498
 499 rebuildConArgs con [] stricts body i = (body, [])
 500 rebuildConArgs con (arg:args) stricts body i | isTyVar arg
 501   = let (body', args') = rebuildConArgs con args stricts body i
 502     in  (body',arg:args')
 503 rebuildConArgs con (arg:args) (str:stricts) body i
 504   = case maybeMarkedUnboxed str of
 505         Just (pack_con1, _) ->
 506             case splitProductType_maybe (idType arg) of
 507                 Just (_, tycon_args, pack_con, con_arg_tys) ->
 508                     ASSERT( pack_con == pack_con1 )
 509                     let unpacked_args = zipWith mkTemplateLocal [i..] con_arg_tys
 510                         (body', real_args) = rebuildConArgs con args stricts body
 511                                                 (i + length con_arg_tys)
 512                     in
 513                     (
 514                          Let (NonRec arg (mkConApp pack_con
 515                                                   (map Type tycon_args ++
 516                                                    map Var  unpacked_args))) body',
 517                          unpacked_args ++ real_args
 518                     )
 519
 520         _ -> let (body', args') = rebuildConArgs con args stricts body i
 521              in  (body', arg:args')
 522 \end{code}
 523
 524
 525 %************************************************************************
 526 %*                                                                      *
 527 \subsection{Dictionary selectors}
 528 %*                                                                      *
 529 %************************************************************************
 530
 531 Selecting a field for a dictionary.  If there is just one field, then
 532 there's nothing to do.
 533
 534 ToDo: unify with mkRecordSelId.
 535
 536 \begin{code}
 537 mkDictSelId :: Name -> Class -> Id
 538 mkDictSelId name clas
 539   = sel_id
 540   where
 541     ty        = exprType rhs
 542     sel_id    = mkId name ty info
 543     field_lbl = mkFieldLabel name tycon ty tag
 544     tag       = assoc "MkId.mkDictSelId" (classSelIds clas `zip` allFieldLabelTags) sel_id
 545
 546     info      = mkIdInfo (RecordSelId field_lbl) NoCafRefs
 547                 `setArityInfo`      exactArity 1
 548                 `setUnfoldingInfo`  unfolding
 549                 `setTyGenInfo`      TyGenNever
 550
 551         -- We no longer use 'must-inline' on record selectors.  They'll
 552         -- inline like crazy if they scrutinise a constructor
 553
 554     unfolding = mkTopUnfolding rhs
 555
 556     tyvars  = classTyVars clas
 557
 558     tycon      = classTyCon clas
 559     [data_con] = tyConDataCons tycon
 560     tyvar_tys  = mkTyVarTys tyvars
 561     arg_tys    = dataConArgTys data_con tyvar_tys
 562     the_arg_id = arg_ids !! (tag - firstFieldLabelTag)
 563
 564     dict_ty    = mkDictTy clas tyvar_tys
 565     (dict_id:arg_ids) = mkTemplateLocals (dict_ty : arg_tys)
 566
 567     rhs | isNewTyCon tycon = mkLams tyvars $ Lam dict_id $
 568                              Note (Coerce (head arg_tys) dict_ty) (Var dict_id)
 569         | otherwise        = mkLams tyvars $ Lam dict_id $
 570                              Case (Var dict_id) dict_id
 571                                   [(DataAlt data_con, arg_ids, Var the_arg_id)]
 572 \end{code}
 573
 574
 575 %************************************************************************
 576 %*                                                                      *
 577 \subsection{Primitive operations
 578 %*                                                                      *
 579 %************************************************************************
 580
 581 \begin{code}
 582 mkPrimOpId :: PrimOp -> Id
 583 mkPrimOpId prim_op
 584   = id
 585   where
 586     (tyvars,arg_tys,res_ty, arity, strict_info) = primOpSig prim_op
 587     ty   = mkForAllTys tyvars (mkFunTys arg_tys res_ty)
 588     name = mkPrimOpIdName prim_op
 589     id   = mkId name ty info
 590
 591     info = mkIdInfo (PrimOpId prim_op) NoCafRefs
 592            `setSpecInfo`        rules
 593            `setArityInfo`       exactArity arity
 594            `setStrictnessInfo`  strict_info
 595
 596     rules = addRule emptyCoreRules id (primOpRule prim_op)
 597
 598
 599 -- For each ccall we manufacture a separate CCallOpId, giving it
 600 -- a fresh unique, a type that is correct for this particular ccall,
 601 -- and a CCall structure that gives the correct details about calling
 602 -- convention etc.
 603 --
 604 -- The *name* of this Id is a local name whose OccName gives the full
 605 -- details of the ccall, type and all.  This means that the interface
 606 -- file reader can reconstruct a suitable Id
 607
 608 mkCCallOpId :: Unique -> CCall -> Type -> Id
 609 mkCCallOpId uniq ccall ty
 610   = ASSERT( isEmptyVarSet (tyVarsOfType ty) )
 611         -- A CCallOpId should have no free type variables;
 612         -- when doing substitutions won't substitute over it
 613     mkId name ty info
 614   where
 615     occ_str = showSDocIface (braces (pprCCallOp ccall <+> ppr ty))
 616         -- The "occurrence name" of a ccall is the full info about the
 617         -- ccall; it is encoded, but may have embedded spaces etc!
 618
 619     name    = mkCCallName uniq occ_str
 620     prim_op = CCallOp ccall
 621
 622     info = mkIdInfo (PrimOpId prim_op) NoCafRefs
 623            `setArityInfo`       exactArity arity
 624            `setStrictnessInfo`  strict_info
 625
 626     (_, tau)     = splitForAllTys ty
 627     (arg_tys, _) = splitFunTys tau
 628     arity        = length arg_tys
 629     strict_info  = mkStrictnessInfo (take arity (repeat wwPrim), False)
 630 \end{code}
 631
 632
 633 %************************************************************************
 634 %*                                                                      *
 635 \subsection{DictFuns}
 636 %*                                                                      *
 637 %************************************************************************
 638
 639 \begin{code}
 640 mkDictFunId :: Name             -- Name to use for the dict fun;
 641             -> Class
 642             -> [TyVar]
 643             -> [Type]
 644             -> ThetaType
 645             -> Id
 646
 647 mkDictFunId dfun_name clas inst_tyvars inst_tys dfun_theta
 648   = mkId dfun_name dfun_ty info
 649   where
 650     dfun_ty = mkSigmaTy inst_tyvars dfun_theta (mkDictTy clas inst_tys)
 651     info = mkIdInfo DictFunId MayHaveCafRefs
 652            `setTyGenInfo` TyGenNever
 653              -- type is wired-in (see comment at TcClassDcl.tcClassSig), so
 654              -- do not generalise it
 655         -- An imported dfun may refer to CAFs, so we assume the worst
 656
 657 {-  1 dec 99: disable the Mark Jones optimisation for the sake
 658     of compatibility with Hugs.
 659     See `types/InstEnv' for a discussion related to this.
 660
 661     (class_tyvars, sc_theta, _, _) = classBigSig clas
 662     not_const (clas, tys) = not (isEmptyVarSet (tyVarsOfTypes tys))
 663     sc_theta' = substClasses (mkTopTyVarSubst class_tyvars inst_tys) sc_theta
 664     dfun_theta = case inst_decl_theta of
 665                    []    -> []  -- If inst_decl_theta is empty, then we don't
 666                                 -- want to have any dict arguments, so that we can
 667                                 -- expose the constant methods.
 668
 669                    other -> nub (inst_decl_theta ++ filter not_const sc_theta')
 670                                 -- Otherwise we pass the superclass dictionaries to
 671                                 -- the dictionary function; the Mark Jones optimisation.
 672                                 --
 673                                 -- NOTE the "nub".  I got caught by this one:
 674                                 --   class Monad m => MonadT t m where ...
 675                                 --   instance Monad m => MonadT (EnvT env) m where ...
 676                                 -- Here, the inst_decl_theta has (Monad m); but so
 677                                 -- does the sc_theta'!
 678                                 --
 679                                 -- NOTE the "not_const".  I got caught by this one too:
 680                                 --   class Foo a => Baz a b where ...
 681                                 --   instance Wob b => Baz T b where..
 682                                 -- Now sc_theta' has Foo T
 683 -}
 684 \end{code}
 685
 686
 687 %************************************************************************
 688 %*                                                                      *
 689 \subsection{Un-definable}
 690 %*                                                                      *
 691 %************************************************************************
 692
 693 These two can't be defined in Haskell.
 694
 695 unsafeCoerce# isn't so much a PrimOp as a phantom identifier, that
 696 just gets expanded into a type coercion wherever it occurs.  Hence we
 697 add it as a built-in Id with an unfolding here.
 698
 699 The type variables we use here are "open" type variables: this means
 700 they can unify with both unlifted and lifted types.  Hence we provide
 701 another gun with which to shoot yourself in the foot.
 702
 703 \begin{code}
 704 unsafeCoerceId
 705   = pcMiscPrelId unsafeCoerceIdKey pREL_GHC SLIT("unsafeCoerce#") ty info
 706   where
 707     info = constantIdInfo `setUnfoldingInfo` mkCompulsoryUnfolding rhs
 708
 709
 710     ty  = mkForAllTys [openAlphaTyVar,openBetaTyVar]
 711                       (mkFunTy openAlphaTy openBetaTy)
 712     [x] = mkTemplateLocals [openAlphaTy]
 713     rhs = mkLams [openAlphaTyVar,openBetaTyVar,x] $
 714           Note (Coerce openBetaTy openAlphaTy) (Var x)
 715 \end{code}
 716
 717
 718 @getTag#@ is another function which can't be defined in Haskell.  It needs to
 719 evaluate its argument and call the dataToTag# primitive.
 720
 721 \begin{code}
 722 getTagId
 723   = pcMiscPrelId getTagIdKey pREL_GHC SLIT("getTag#") ty info
 724   where
 725     info = constantIdInfo
 726            `setUnfoldingInfo`   mkCompulsoryUnfolding rhs
 727         -- We don't provide a defn for this; you must inline it
 728
 729     ty = mkForAllTys [alphaTyVar] (mkFunTy alphaTy intPrimTy)
 730     [x,y] = mkTemplateLocals [alphaTy,alphaTy]
 731     rhs = mkLams [alphaTyVar,x] $
 732           Case (Var x) y [ (DEFAULT, [], mkApps (Var dataToTagId) [Type alphaTy, Var y]) ]
 733
 734 dataToTagId = mkPrimOpId DataToTagOp
 735 \end{code}
 736
 737 @realWorld#@ used to be a magic literal, \tr{void#}.  If things get
 738 nasty as-is, change it back to a literal (@Literal@).
 739
 740 \begin{code}
 741 realWorldPrimId -- :: State# RealWorld
 742   = pcMiscPrelId realWorldPrimIdKey pREL_GHC SLIT("realWorld#")
 743                  realWorldStatePrimTy
 744                  (noCafIdInfo `setUnfoldingInfo` mkOtherCon [])
 745         -- The mkOtherCon makes it look that realWorld# is evaluated
 746         -- which in turn makes Simplify.interestingArg return True,
 747         -- which in turn makes INLINE things applied to realWorld# likely
 748         -- to be inlined
 749 \end{code}
 750
 751
 752 %************************************************************************
 753 %*                                                                      *
 754 \subsection[PrelVals-error-related]{@error@ and friends; @trace@}
 755 %*                                                                      *
 756 %************************************************************************
 757
 758 GHC randomly injects these into the code.
 759
 760 @patError@ is just a version of @error@ for pattern-matching
 761 failures.  It knows various ``codes'' which expand to longer
 762 strings---this saves space!
 763
 764 @absentErr@ is a thing we put in for ``absent'' arguments.  They jolly
 765 well shouldn't be yanked on, but if one is, then you will get a
 766 friendly message from @absentErr@ (rather than a totally random
 767 crash).
 768
 769 @parError@ is a special version of @error@ which the compiler does
 770 not know to be a bottoming Id.  It is used in the @_par_@ and @_seq_@
 771 templates, but we don't ever expect to generate code for it.
 772
 773 \begin{code}
 774 eRROR_ID
 775   = pc_bottoming_Id errorIdKey pREL_ERR SLIT("error") errorTy
 776 pAT_ERROR_ID
 777   = generic_ERROR_ID patErrorIdKey SLIT("patError")
 778 rEC_SEL_ERROR_ID
 779   = generic_ERROR_ID recSelErrIdKey SLIT("recSelError")
 780 rEC_CON_ERROR_ID
 781   = generic_ERROR_ID recConErrorIdKey SLIT("recConError")
 782 rEC_UPD_ERROR_ID
 783   = generic_ERROR_ID recUpdErrorIdKey SLIT("recUpdError")
 784 iRREFUT_PAT_ERROR_ID
 785   = generic_ERROR_ID irrefutPatErrorIdKey SLIT("irrefutPatError")
 786 nON_EXHAUSTIVE_GUARDS_ERROR_ID
 787   = generic_ERROR_ID nonExhaustiveGuardsErrorIdKey SLIT("nonExhaustiveGuardsError")
 788 nO_METHOD_BINDING_ERROR_ID
 789   = generic_ERROR_ID noMethodBindingErrorIdKey SLIT("noMethodBindingError")
 790
 791 aBSENT_ERROR_ID
 792   = pc_bottoming_Id absentErrorIdKey pREL_ERR SLIT("absentErr")
 793         (mkSigmaTy [openAlphaTyVar] [] openAlphaTy)
 794
 795 pAR_ERROR_ID
 796   = pcMiscPrelId parErrorIdKey pREL_ERR SLIT("parError")
 797     (mkSigmaTy [openAlphaTyVar] [] openAlphaTy) noCafIdInfo
 798
 799 \end{code}
 800
 801
 802 %************************************************************************
 803 %*                                                                      *
 804 \subsection{Utilities}
 805 %*                                                                      *
 806 %************************************************************************
 807
 808 \begin{code}
 809 pcMiscPrelId :: Unique{-IdKey-} -> Module -> FAST_STRING -> Type -> IdInfo -> Id
 810 pcMiscPrelId key mod str ty info
 811   = let
 812         name = mkWiredInName mod (mkVarOcc str) key
 813         imp  = mkId name ty info -- the usual case...
 814     in
 815     imp
 816     -- We lie and say the thing is imported; otherwise, we get into
 817     -- a mess with dependency analysis; e.g., core2stg may heave in
 818     -- random calls to GHCbase.unpackPS__.  If GHCbase is the module
 819     -- being compiled, then it's just a matter of luck if the definition
 820     -- will be in "the right place" to be in scope.
 821
 822 pc_bottoming_Id key mod name ty
 823  = pcMiscPrelId key mod name ty bottoming_info
 824  where
 825     bottoming_info = noCafIdInfo
 826                      `setStrictnessInfo` mkStrictnessInfo ([wwStrict], True)
 827
 828         -- these "bottom" out, no matter what their arguments
 829
 830 generic_ERROR_ID u n = pc_bottoming_Id u pREL_ERR n errorTy
 831
 832 -- Very useful...
 833 noCafIdInfo = constantIdInfo `setCafInfo` NoCafRefs
 834
 835 (openAlphaTyVar:openBetaTyVar:_) = openAlphaTyVars
 836 openAlphaTy  = mkTyVarTy openAlphaTyVar
 837 openBetaTy   = mkTyVarTy openBetaTyVar
 838
 839 errorTy  :: Type
 840 errorTy  = mkSigmaTy [openAlphaTyVar] [] (mkFunTys [mkListTy charTy]
 841                                                    openAlphaTy)
 842     -- Notice the openAlphaTyVar.  It says that "error" can be applied
 843     -- to unboxed as well as boxed types.  This is OK because it never
 844     -- returns, so the return type is irrelevant.
 845 \end{code}
 846