ghc/compiler/basicTypes/MkId.lhs

   1 %
   2 % (c) The AQUA Project, Glasgow University, 1998
   3 %
   4 \section[StdIdInfo]{Standard unfoldings}
   5
   6 This module contains definitions for the IdInfo for things that
   7 have a standard form, namely:
   8
   9         * data constructors
  10         * record selectors
  11         * method and superclass selectors
  12         * primitive operations
  13
  14 \begin{code}
  15 module MkId (
  16         mkSpecPragmaId, mkWorkerId,
  17
  18         mkDictFunId, mkDefaultMethodId,
  19         mkDictSelId,
  20
  21         mkDataConId, mkDataConWrapId,
  22         mkRecordSelId,
  23         mkPrimOpId, mkCCallOpId,
  24
  25         -- And some particular Ids; see below for why they are wired in
  26         wiredInIds,
  27         unsafeCoerceId, realWorldPrimId,
  28         eRROR_ID, rEC_SEL_ERROR_ID, pAT_ERROR_ID, rEC_CON_ERROR_ID,
  29         rEC_UPD_ERROR_ID, iRREFUT_PAT_ERROR_ID, nON_EXHAUSTIVE_GUARDS_ERROR_ID,
  30         nO_METHOD_BINDING_ERROR_ID, aBSENT_ERROR_ID, pAR_ERROR_ID
  31     ) where
  32
  33 #include "HsVersions.h"
  34
  35
  36 import TysPrim          ( openAlphaTyVars, alphaTyVar, alphaTy,
  37                           intPrimTy, realWorldStatePrimTy
  38                         )
  39 import TysWiredIn       ( boolTy, charTy, mkListTy )
  40 import PrelMods         ( pREL_ERR, pREL_GHC )
  41 import PrelRules        ( primOpRule )
  42 import Rules            ( addRule )
  43 import Type             ( Type, ClassContext, mkDictTy, mkDictTys, mkTyConApp, mkTyVarTys,
  44                           mkFunTys, mkFunTy, mkSigmaTy, classesToPreds,
  45                           isUnLiftedType, mkForAllTys, mkTyVarTy, tyVarsOfType, tyVarsOfTypes,
  46                           splitSigmaTy, splitFunTy_maybe,
  47                           splitFunTys, splitForAllTys, unUsgTy,
  48                           mkUsgTy, UsageAnn(..)
  49                         )
  50 import PprType          ( pprParendType )
  51 import Module           ( Module )
  52 import CoreUtils        ( mkInlineMe )
  53 import CoreUnfold       ( mkTopUnfolding, mkCompulsoryUnfolding, mkOtherCon )
  54 import Subst            ( mkTopTyVarSubst, substClasses )
  55 import TyCon            ( TyCon, isNewTyCon, tyConTyVars, tyConDataCons, isDataTyCon,
  56                           tyConTheta, isProductTyCon, isUnboxedTupleTyCon )
  57 import Class            ( Class, classBigSig, classTyCon, classTyVars, classSelIds )
  58 import Var              ( Id, TyVar )
  59 import VarSet           ( isEmptyVarSet )
  60 import Name             ( mkDerivedName, mkWiredInIdName, mkLocalName,
  61                           mkWorkerOcc, mkSuperDictSelOcc, mkCCallName,
  62                           Name, NamedThing(..),
  63                         )
  64 import OccName          ( mkSrcVarOcc )
  65 import PrimOp           ( PrimOp(DataToTagOp, CCallOp),
  66                           primOpSig, mkPrimOpIdName,
  67                           CCall, pprCCallOp
  68                         )
  69 import Demand           ( wwStrict, wwPrim )
  70 import DataCon          ( DataCon, StrictnessMark(..),
  71                           dataConFieldLabels, dataConRepArity, dataConTyCon,
  72                           dataConArgTys, dataConRepType, dataConRepStrictness,
  73                           dataConName, dataConTheta,
  74                           dataConSig, dataConStrictMarks, dataConId
  75                         )
  76 import Id               ( idType, mkId,
  77                           mkVanillaId, mkTemplateLocals,
  78                           mkTemplateLocal, setInlinePragma, idCprInfo
  79                         )
  80 import IdInfo           ( IdInfo, vanillaIdInfo, mkIdInfo,
  81                           exactArity, setUnfoldingInfo, setCafInfo, setCprInfo,
  82                           setArityInfo, setInlinePragInfo, setSpecInfo,
  83                           mkStrictnessInfo, setStrictnessInfo,
  84                           IdFlavour(..), InlinePragInfo(..), CafInfo(..), StrictnessInfo(..), CprInfo(..)
  85                         )
  86 import FieldLabel       ( FieldLabel, FieldLabelTag, mkFieldLabel, fieldLabelName,
  87                           firstFieldLabelTag, allFieldLabelTags, fieldLabelType
  88                         )
  89 import CoreSyn
  90 import Maybes
  91 import BasicTypes       ( Arity )
  92 import Unique
  93 import Maybe            ( isJust )
  94 import Outputable
  95 import Util             ( assoc )
  96 import List             ( nub )
  97 \end{code}
  98
  99
 100 %************************************************************************
 101 %*                                                                      *
 102 \subsection{Wired in Ids}
 103 %*                                                                      *
 104 %************************************************************************
 105
 106 \begin{code}
 107 wiredInIds
 108   = [   -- These error-y things are wired in because we don't yet have
 109         -- a way to express in an interface file that the result type variable
 110         -- is 'open'; that is can be unified with an unboxed type
 111         --
 112         -- [The interface file format now carry such information, but there's
 113         --  no way yet of expressing at the definition site for these error-reporting
 114         --  functions that they have an 'open' result type. -- sof 1/99]
 115
 116       aBSENT_ERROR_ID
 117     , eRROR_ID
 118     , iRREFUT_PAT_ERROR_ID
 119     , nON_EXHAUSTIVE_GUARDS_ERROR_ID
 120     , nO_METHOD_BINDING_ERROR_ID
 121     , pAR_ERROR_ID
 122     , pAT_ERROR_ID
 123     , rEC_CON_ERROR_ID
 124     , rEC_UPD_ERROR_ID
 125
 126         -- These two can't be defined in Haskell
 127     , realWorldPrimId
 128     , unsafeCoerceId
 129     , getTagId
 130     ]
 131 \end{code}
 132
 133 %************************************************************************
 134 %*                                                                      *
 135 \subsection{Easy ones}
 136 %*                                                                      *
 137 %************************************************************************
 138
 139 \begin{code}
 140 mkSpecPragmaId occ uniq ty loc
 141   = mkId (mkLocalName uniq occ loc) ty (mkIdInfo SpecPragmaId)
 142         -- Maybe a SysLocal?  But then we'd lose the location
 143
 144 mkDefaultMethodId dm_name rec_c ty
 145   = mkVanillaId dm_name ty
 146
 147 mkWorkerId uniq unwrkr ty
 148   = mkVanillaId (mkDerivedName mkWorkerOcc (getName unwrkr) uniq) ty
 149 \end{code}
 150
 151 %************************************************************************
 152 %*                                                                      *
 153 \subsection{Data constructors}
 154 %*                                                                      *
 155 %************************************************************************
 156
 157 \begin{code}
 158 mkDataConId :: Name -> DataCon -> Id
 159         -- Makes the *worker* for the data constructor; that is, the function
 160         -- that takes the reprsentation arguments and builds the constructor.
 161 mkDataConId work_name data_con
 162   = mkId work_name (dataConRepType data_con) info
 163   where
 164     info = mkIdInfo (DataConId data_con)
 165            `setArityInfo`       exactArity arity
 166            `setStrictnessInfo`  strict_info
 167            `setCprInfo`         cpr_info
 168
 169     arity = dataConRepArity data_con
 170
 171     strict_info = StrictnessInfo (dataConRepStrictness data_con) False
 172
 173     cpr_info | isProductTyCon tycon &&
 174                not (isUnboxedTupleTyCon tycon) &&
 175                arity > 0                        = ReturnsCPR
 176              | otherwise                        = NoCPRInfo
 177              where
 178                 tycon = dataConTyCon data_con
 179                 -- Newtypes don't have a worker at all
 180                 --
 181                 -- If we are a product with 0 args we must be void(like)
 182                 -- We can't create an unboxed tuple with 0 args for this
 183                 -- and since Void has only one, constant value it should
 184                 -- just mean returning a pointer to a pre-existing cell.
 185                 -- So we won't really gain from doing anything fancy
 186                 -- and we treat this case as Top.
 187 \end{code}
 188
 189 The wrapper for a constructor is an ordinary top-level binding that evaluates
 190 any strict args, unboxes any args that are going to be flattened, and calls
 191 the worker.
 192
 193 We're going to build a constructor that looks like:
 194
 195         data (Data a, C b) =>  T a b = T1 !a !Int b
 196
 197         T1 = /\ a b ->
 198              \d1::Data a, d2::C b ->
 199              \p q r -> case p of { p ->
 200                        case q of { q ->
 201                        Con T1 [a,b] [p,q,r]}}
 202
 203 Notice that
 204
 205 * d2 is thrown away --- a context in a data decl is used to make sure
 206   one *could* construct dictionaries at the site the constructor
 207   is used, but the dictionary isn't actually used.
 208
 209 * We have to check that we can construct Data dictionaries for
 210   the types a and Int.  Once we've done that we can throw d1 away too.
 211
 212 * We use (case p of q -> ...) to evaluate p, rather than "seq" because
 213   all that matters is that the arguments are evaluated.  "seq" is
 214   very careful to preserve evaluation order, which we don't need
 215   to be here.
 216
 217   You might think that we could simply give constructors some strictness
 218   info, like PrimOps, and let CoreToStg do the let-to-case transformation.
 219   But we don't do that because in the case of primops and functions strictness
 220   is a *property* not a *requirement*.  In the case of constructors we need to
 221   do something active to evaluate the argument.
 222
 223   Making an explicit case expression allows the simplifier to eliminate
 224   it in the (common) case where the constructor arg is already evaluated.
 225
 226 \begin{code}
 227 mkDataConWrapId data_con
 228   = wrap_id
 229   where
 230     wrap_id = mkId (dataConName data_con) wrap_ty info
 231     work_id = dataConId data_con
 232
 233     info = mkIdInfo (DataConWrapId data_con)
 234            `setUnfoldingInfo`   mkTopUnfolding (mkInlineMe wrap_rhs)
 235            `setCprInfo`         cpr_info
 236                 -- The Cpr info can be important inside INLINE rhss, where the
 237                 -- wrapper constructor isn't inlined
 238            `setArityInfo`       exactArity arity
 239                 -- It's important to specify the arity, so that partial
 240                 -- applications are treated as values
 241            `setCafInfo`       NoCafRefs
 242                 -- The wrapper Id ends up in STG code as an argument,
 243                 -- sometimes before its definition, so we want to
 244                 -- signal that it has no CAFs
 245
 246     wrap_ty = mkForAllTys all_tyvars $
 247               mkFunTys all_arg_tys
 248               result_ty
 249
 250     cpr_info = idCprInfo work_id
 251
 252     wrap_rhs | isNewTyCon tycon
 253              = ASSERT( null ex_tyvars && null ex_dict_args && length orig_arg_tys == 1 )
 254                 -- No existentials on a newtype, but it can have a contex
 255                 -- e.g.         newtype Eq a => T a = MkT (...)
 256
 257                mkLams tyvars $ mkLams dict_args $ Lam id_arg1 $
 258                Note (Coerce result_ty (head orig_arg_tys)) (Var id_arg1)
 259
 260 {-      I nuked this because map (:) xs would create a
 261         new local lambda for the (:) in core-to-stg.
 262         There isn't a defn for the worker!
 263
 264              | null dict_args && all not_marked_strict strict_marks
 265              = Var work_id      -- The common case.  Not only is this efficient,
 266                                 -- but it also ensures that the wrapper is replaced
 267                                 -- by the worker even when there are no args.
 268                                 --              f (:) x
 269                                 -- becomes
 270                                 --              f $w: x
 271                                 -- This is really important in rule matching,
 272                                 -- which is a bit sad.  (We could match on the wrappers,
 273                                 -- but that makes it less likely that rules will match
 274                                 -- when we bring bits of unfoldings together
 275 -}
 276
 277              | otherwise
 278              = mkLams all_tyvars $ mkLams dict_args $
 279                mkLams ex_dict_args $ mkLams id_args $
 280                foldr mk_case con_app
 281                      (zip (ex_dict_args++id_args) strict_marks) i3 []
 282
 283     con_app i rep_ids = mkApps (Var work_id)
 284                                (map varToCoreExpr (all_tyvars ++ reverse rep_ids))
 285
 286     (tyvars, theta, ex_tyvars, ex_theta, orig_arg_tys, tycon) = dataConSig data_con
 287     all_tyvars   = tyvars ++ ex_tyvars
 288
 289     dict_tys     = mkDictTys theta
 290     ex_dict_tys  = mkDictTys ex_theta
 291     all_arg_tys  = dict_tys ++ ex_dict_tys ++ orig_arg_tys
 292     result_ty    = mkTyConApp tycon (mkTyVarTys tyvars)
 293
 294     mkLocals i tys = (zipWith mkTemplateLocal [i..i+n-1] tys, i+n)
 295                    where
 296                      n = length tys
 297
 298     (dict_args, i1)    = mkLocals 1  dict_tys
 299     (ex_dict_args,i2)  = mkLocals i1 ex_dict_tys
 300     (id_args,i3)       = mkLocals i2 orig_arg_tys
 301     arity              = i3-1
 302     (id_arg1:_)   = id_args             -- Used for newtype only
 303
 304     strict_marks  = dataConStrictMarks data_con
 305     not_marked_strict NotMarkedStrict = True
 306     not_marked_strict other           = False
 307
 308
 309     mk_case
 310            :: (Id, StrictnessMark)      -- arg, strictness
 311            -> (Int -> [Id] -> CoreExpr) -- body
 312            -> Int                       -- next rep arg id
 313            -> [Id]                      -- rep args so far
 314            -> CoreExpr
 315     mk_case (arg,strict) body i rep_args
 316           = case strict of
 317                 NotMarkedStrict -> body i (arg:rep_args)
 318                 MarkedStrict
 319                    | isUnLiftedType (idType arg) -> body i (arg:rep_args)
 320                    | otherwise ->
 321                         Case (Var arg) arg [(DEFAULT,[], body i (arg:rep_args))]
 322
 323                 MarkedUnboxed con tys ->
 324                    Case (Var arg) arg [(DataAlt con, con_args,
 325                                         body i' (reverse con_args++rep_args))]
 326                    where n_tys = length tys
 327                          (con_args,i') = mkLocals i tys
 328 \end{code}
 329
 330
 331 %************************************************************************
 332 %*                                                                      *
 333 \subsection{Record selectors}
 334 %*                                                                      *
 335 %************************************************************************
 336
 337 We're going to build a record selector unfolding that looks like this:
 338
 339         data T a b c = T1 { ..., op :: a, ...}
 340                      | T2 { ..., op :: a, ...}
 341                      | T3
 342
 343         sel = /\ a b c -> \ d -> case d of
 344                                     T1 ... x ... -> x
 345                                     T2 ... x ... -> x
 346                                     other        -> error "..."
 347
 348 \begin{code}
 349 mkRecordSelId tycon field_label
 350         -- Assumes that all fields with the same field label
 351         -- have the same type
 352   = sel_id
 353   where
 354     sel_id     = mkId (fieldLabelName field_label) selector_ty info
 355
 356     field_ty   = fieldLabelType field_label
 357     field_name = fieldLabelName field_label
 358     data_cons  = tyConDataCons tycon
 359     tyvars     = tyConTyVars tycon      -- These scope over the types in
 360                                         -- the FieldLabels of constructors of this type
 361     tycon_theta = tyConTheta tycon      -- The context on the data decl
 362                                         --   eg data (Eq a, Ord b) => T a b = ...
 363
 364     data_ty   = mkTyConApp tycon (mkTyVarTys tyvars)
 365     tyvar_tys = mkTyVarTys tyvars
 366
 367         -- Very tiresomely, the selectors are (unnecessarily!) overloaded over
 368         -- just the dictionaries in the types of the constructors that contain
 369         -- the relevant field.  Urgh.
 370         -- NB: this code relies on the fact that DataCons are quantified over
 371         -- the identical type variables as their parent TyCon
 372     dict_tys  = [mkDictTy cls tys | (cls, tys) <- tycon_theta, needed_dict (cls, tys)]
 373     needed_dict pred = or [ pred `elem` (dataConTheta dc)
 374                           | (DataAlt dc, _, _) <- the_alts]
 375
 376     selector_ty :: Type
 377     selector_ty  = mkForAllTys tyvars $ mkFunTys dict_tys $
 378                    mkFunTy data_ty field_ty
 379
 380     info = mkIdInfo (RecordSelId field_label)
 381            `setArityInfo`       exactArity 1
 382            `setUnfoldingInfo`   unfolding
 383            `setCafInfo`         NoCafRefs
 384         -- ToDo: consider adding further IdInfo
 385
 386     unfolding = mkTopUnfolding sel_rhs
 387
 388
 389     (data_id:dict_ids) = mkTemplateLocals (data_ty:dict_tys)
 390     alts      = map mk_maybe_alt data_cons
 391     the_alts  = catMaybes alts
 392     default_alt | all isJust alts = []  -- No default needed
 393                 | otherwise       = [(DEFAULT, [], error_expr)]
 394
 395     sel_rhs | isNewTyCon tycon = new_sel_rhs
 396             | otherwise        = data_sel_rhs
 397
 398     data_sel_rhs = mkLams tyvars $ mkLams dict_ids $ Lam data_id $
 399                    Case (Var data_id) data_id (the_alts ++ default_alt)
 400
 401     new_sel_rhs  = mkLams tyvars $ Lam data_id $
 402                     Note (Coerce (unUsgTy field_ty) (unUsgTy data_ty)) (Var data_id)
 403
 404     mk_maybe_alt data_con
 405           = case maybe_the_arg_id of
 406                 Nothing         -> Nothing
 407                 Just the_arg_id -> Just (DataAlt data_con, arg_ids, Var the_arg_id)
 408           where
 409             arg_ids          = mkTemplateLocals (dataConArgTys data_con tyvar_tys)
 410                                     -- The first one will shadow data_id, but who cares
 411             field_lbls       = dataConFieldLabels data_con
 412             maybe_the_arg_id = assocMaybe (field_lbls `zip` arg_ids) field_label
 413
 414     error_expr = mkApps (Var rEC_SEL_ERROR_ID) [Type (unUsgTy field_ty), mkStringLit full_msg]
 415        -- preserves invariant that type args are *not* usage-annotated on top.  KSW 1999-04.
 416     full_msg   = showSDoc (sep [text "No match in record selector", ppr sel_id])
 417 \end{code}
 418
 419
 420 %************************************************************************
 421 %*                                                                      *
 422 \subsection{Dictionary selectors}
 423 %*                                                                      *
 424 %************************************************************************
 425
 426 Selecting a field for a dictionary.  If there is just one field, then
 427 there's nothing to do.
 428
 429 ToDo: unify with mkRecordSelId.
 430
 431 \begin{code}
 432 mkDictSelId name clas ty
 433   = sel_id
 434   where
 435     sel_id    = mkId name ty info
 436     field_lbl = mkFieldLabel name ty tag
 437     tag       = assoc "MkId.mkDictSelId" (classSelIds clas `zip` allFieldLabelTags) sel_id
 438
 439     info      = mkIdInfo (RecordSelId field_lbl)
 440                 `setArityInfo`      exactArity 1
 441                 `setUnfoldingInfo`  unfolding
 442                 `setCafInfo`        NoCafRefs
 443
 444         -- We no longer use 'must-inline' on record selectors.  They'll
 445         -- inline like crazy if they scrutinise a constructor
 446
 447     unfolding = mkTopUnfolding rhs
 448
 449     tyvars  = classTyVars clas
 450
 451     tycon      = classTyCon clas
 452     [data_con] = tyConDataCons tycon
 453     tyvar_tys  = mkTyVarTys tyvars
 454     arg_tys    = dataConArgTys data_con tyvar_tys
 455     the_arg_id = arg_ids !! (tag - firstFieldLabelTag)
 456
 457     dict_ty    = mkDictTy clas tyvar_tys
 458     (dict_id:arg_ids) = mkTemplateLocals (dict_ty : arg_tys)
 459
 460     rhs | isNewTyCon tycon = mkLams tyvars $ Lam dict_id $
 461                              Note (Coerce (head arg_tys) dict_ty) (Var dict_id)
 462         | otherwise        = mkLams tyvars $ Lam dict_id $
 463                              Case (Var dict_id) dict_id
 464                                   [(DataAlt data_con, arg_ids, Var the_arg_id)]
 465 \end{code}
 466
 467
 468 %************************************************************************
 469 %*                                                                      *
 470 \subsection{Primitive operations
 471 %*                                                                      *
 472 %************************************************************************
 473
 474 \begin{code}
 475 mkPrimOpId :: PrimOp -> Id
 476 mkPrimOpId prim_op
 477   = id
 478   where
 479     (tyvars,arg_tys,res_ty, arity, strict_info) = primOpSig prim_op
 480     ty   = mkForAllTys tyvars (mkFunTys arg_tys res_ty)
 481     name = mkPrimOpIdName prim_op id
 482     id   = mkId name ty info
 483
 484     info = mkIdInfo (PrimOpId prim_op)
 485            `setSpecInfo`        rules
 486            `setArityInfo`       exactArity arity
 487            `setStrictnessInfo`  strict_info
 488
 489     rules = addRule id emptyCoreRules (primOpRule prim_op)
 490
 491
 492 -- For each ccall we manufacture a separate CCallOpId, giving it
 493 -- a fresh unique, a type that is correct for this particular ccall,
 494 -- and a CCall structure that gives the correct details about calling
 495 -- convention etc.
 496 --
 497 -- The *name* of this Id is a local name whose OccName gives the full
 498 -- details of the ccall, type and all.  This means that the interface
 499 -- file reader can reconstruct a suitable Id
 500
 501 mkCCallOpId :: Unique -> CCall -> Type -> Id
 502 mkCCallOpId uniq ccall ty
 503   = ASSERT( isEmptyVarSet (tyVarsOfType ty) )
 504         -- A CCallOpId should have no free type variables;
 505         -- when doing substitutions won't substitute over it
 506     mkId name ty info
 507   where
 508     occ_str = showSDocIface (braces (pprCCallOp ccall <+> ppr ty))
 509         -- The "occurrence name" of a ccall is the full info about the
 510         -- ccall; it is encoded, but may have embedded spaces etc!
 511
 512     name    = mkCCallName uniq occ_str
 513     prim_op = CCallOp ccall
 514
 515     info = mkIdInfo (PrimOpId prim_op)
 516            `setArityInfo`       exactArity arity
 517            `setStrictnessInfo`  strict_info
 518
 519     (_, tau)     = splitForAllTys ty
 520     (arg_tys, _) = splitFunTys tau
 521     arity        = length arg_tys
 522     strict_info  = mkStrictnessInfo (take arity (repeat wwPrim), False)
 523 \end{code}
 524
 525
 526 %************************************************************************
 527 %*                                                                      *
 528 \subsection{DictFuns}
 529 %*                                                                      *
 530 %************************************************************************
 531
 532 \begin{code}
 533 mkDictFunId :: Name             -- Name to use for the dict fun;
 534             -> Class
 535             -> [TyVar]
 536             -> [Type]
 537             -> ClassContext
 538             -> Id
 539
 540 mkDictFunId dfun_name clas inst_tyvars inst_tys inst_decl_theta
 541   = mkVanillaId dfun_name dfun_ty
 542   where
 543     (class_tyvars, sc_theta, _, _) = classBigSig clas
 544     sc_theta' = substClasses (mkTopTyVarSubst class_tyvars inst_tys) sc_theta
 545
 546     dfun_theta = classesToPreds inst_decl_theta
 547
 548 {-  1 dec 99: disable the Mark Jones optimisation for the sake
 549     of compatibility with Hugs.
 550     See `types/InstEnv' for a discussion related to this.
 551
 552     dfun_theta = case inst_decl_theta of
 553                    []    -> []  -- If inst_decl_theta is empty, then we don't
 554                                 -- want to have any dict arguments, so that we can
 555                                 -- expose the constant methods.
 556
 557                    other -> nub (inst_decl_theta ++ filter not_const sc_theta')
 558                                 -- Otherwise we pass the superclass dictionaries to
 559                                 -- the dictionary function; the Mark Jones optimisation.
 560                                 --
 561                                 -- NOTE the "nub".  I got caught by this one:
 562                                 --   class Monad m => MonadT t m where ...
 563                                 --   instance Monad m => MonadT (EnvT env) m where ...
 564                                 -- Here, the inst_decl_theta has (Monad m); but so
 565                                 -- does the sc_theta'!
 566                                 --
 567                                 -- NOTE the "not_const".  I got caught by this one too:
 568                                 --   class Foo a => Baz a b where ...
 569                                 --   instance Wob b => Baz T b where..
 570                                 -- Now sc_theta' has Foo T
 571 -}
 572     dfun_ty = mkSigmaTy inst_tyvars dfun_theta (mkDictTy clas inst_tys)
 573
 574     not_const (clas, tys) = not (isEmptyVarSet (tyVarsOfTypes tys))
 575 \end{code}
 576
 577
 578 %************************************************************************
 579 %*                                                                      *
 580 \subsection{Un-definable}
 581 %*                                                                      *
 582 %************************************************************************
 583
 584 These two can't be defined in Haskell.
 585
 586 unsafeCoerce# isn't so much a PrimOp as a phantom identifier, that
 587 just gets expanded into a type coercion wherever it occurs.  Hence we
 588 add it as a built-in Id with an unfolding here.
 589
 590 The type variables we use here are "open" type variables: this means
 591 they can unify with both unlifted and lifted types.  Hence we provide
 592 another gun with which to shoot yourself in the foot.
 593
 594 \begin{code}
 595 unsafeCoerceId
 596   = pcMiscPrelId unsafeCoerceIdKey pREL_GHC SLIT("unsafeCoerce#") ty info
 597   where
 598     info = vanillaIdInfo
 599            `setUnfoldingInfo` mkCompulsoryUnfolding rhs
 600
 601
 602     ty  = mkForAllTys [openAlphaTyVar,openBetaTyVar]
 603                       (mkFunTy openAlphaTy openBetaTy)
 604     [x] = mkTemplateLocals [openAlphaTy]
 605     rhs = mkLams [openAlphaTyVar,openBetaTyVar,x] $
 606           Note (Coerce openBetaTy openAlphaTy) (Var x)
 607 \end{code}
 608
 609
 610 @getTag#@ is another function which can't be defined in Haskell.  It needs to
 611 evaluate its argument and call the dataToTag# primitive.
 612
 613 \begin{code}
 614 getTagId
 615   = pcMiscPrelId getTagIdKey pREL_GHC SLIT("getTag#") ty info
 616   where
 617     info = vanillaIdInfo
 618            `setUnfoldingInfo`   mkCompulsoryUnfolding rhs
 619         -- We don't provide a defn for this; you must inline it
 620
 621     ty = mkForAllTys [alphaTyVar] (mkFunTy alphaTy intPrimTy)
 622     [x,y] = mkTemplateLocals [alphaTy,alphaTy]
 623     rhs = mkLams [alphaTyVar,x] $
 624           Case (Var x) y [ (DEFAULT, [], mkApps (Var dataToTagId) [Type alphaTy, Var y]) ]
 625
 626 dataToTagId = mkPrimOpId DataToTagOp
 627 \end{code}
 628
 629 @realWorld#@ used to be a magic literal, \tr{void#}.  If things get
 630 nasty as-is, change it back to a literal (@Literal@).
 631
 632 \begin{code}
 633 realWorldPrimId -- :: State# RealWorld
 634   = pcMiscPrelId realWorldPrimIdKey pREL_GHC SLIT("realWorld#")
 635                  realWorldStatePrimTy
 636                  (noCafIdInfo `setUnfoldingInfo` mkOtherCon [])
 637         -- The mkOtherCon makes it look that realWorld# is evaluated
 638         -- which in turn makes Simplify.interestingArg return True,
 639         -- which in turn makes INLINE things applied to realWorld# likely
 640         -- to be inlined
 641 \end{code}
 642
 643
 644 %************************************************************************
 645 %*                                                                      *
 646 \subsection[PrelVals-error-related]{@error@ and friends; @trace@}
 647 %*                                                                      *
 648 %************************************************************************
 649
 650 GHC randomly injects these into the code.
 651
 652 @patError@ is just a version of @error@ for pattern-matching
 653 failures.  It knows various ``codes'' which expand to longer
 654 strings---this saves space!
 655
 656 @absentErr@ is a thing we put in for ``absent'' arguments.  They jolly
 657 well shouldn't be yanked on, but if one is, then you will get a
 658 friendly message from @absentErr@ (rather than a totally random
 659 crash).
 660
 661 @parError@ is a special version of @error@ which the compiler does
 662 not know to be a bottoming Id.  It is used in the @_par_@ and @_seq_@
 663 templates, but we don't ever expect to generate code for it.
 664
 665 \begin{code}
 666 eRROR_ID
 667   = pc_bottoming_Id errorIdKey pREL_ERR SLIT("error") errorTy
 668 rEC_SEL_ERROR_ID
 669   = generic_ERROR_ID recSelErrIdKey SLIT("patError")
 670 pAT_ERROR_ID
 671   = generic_ERROR_ID patErrorIdKey SLIT("patError")
 672 rEC_CON_ERROR_ID
 673   = generic_ERROR_ID recConErrorIdKey SLIT("recConError")
 674 rEC_UPD_ERROR_ID
 675   = generic_ERROR_ID recUpdErrorIdKey SLIT("recUpdError")
 676 iRREFUT_PAT_ERROR_ID
 677   = generic_ERROR_ID irrefutPatErrorIdKey SLIT("irrefutPatError")
 678 nON_EXHAUSTIVE_GUARDS_ERROR_ID
 679   = generic_ERROR_ID nonExhaustiveGuardsErrorIdKey SLIT("nonExhaustiveGuardsError")
 680 nO_METHOD_BINDING_ERROR_ID
 681   = generic_ERROR_ID noMethodBindingErrorIdKey SLIT("noMethodBindingError")
 682
 683 aBSENT_ERROR_ID
 684   = pc_bottoming_Id absentErrorIdKey pREL_ERR SLIT("absentErr")
 685         (mkSigmaTy [openAlphaTyVar] [] openAlphaTy)
 686
 687 pAR_ERROR_ID
 688   = pcMiscPrelId parErrorIdKey pREL_ERR SLIT("parError")
 689     (mkSigmaTy [openAlphaTyVar] [] openAlphaTy) noCafIdInfo
 690
 691 \end{code}
 692
 693
 694 %************************************************************************
 695 %*                                                                      *
 696 \subsection{Utilities}
 697 %*                                                                      *
 698 %************************************************************************
 699
 700 \begin{code}
 701 pcMiscPrelId :: Unique{-IdKey-} -> Module -> FAST_STRING -> Type -> IdInfo -> Id
 702 pcMiscPrelId key mod str ty info
 703   = let
 704         name = mkWiredInIdName key mod (mkSrcVarOcc str) imp
 705         imp  = mkId name ty info -- the usual case...
 706     in
 707     imp
 708     -- We lie and say the thing is imported; otherwise, we get into
 709     -- a mess with dependency analysis; e.g., core2stg may heave in
 710     -- random calls to GHCbase.unpackPS__.  If GHCbase is the module
 711     -- being compiled, then it's just a matter of luck if the definition
 712     -- will be in "the right place" to be in scope.
 713
 714 pc_bottoming_Id key mod name ty
 715  = pcMiscPrelId key mod name ty bottoming_info
 716  where
 717     bottoming_info = noCafIdInfo
 718                      `setStrictnessInfo` mkStrictnessInfo ([wwStrict], True)
 719
 720         -- these "bottom" out, no matter what their arguments
 721
 722 generic_ERROR_ID u n = pc_bottoming_Id u pREL_ERR n errorTy
 723
 724 -- Very useful...
 725 noCafIdInfo = vanillaIdInfo `setCafInfo` NoCafRefs
 726
 727 (openAlphaTyVar:openBetaTyVar:_) = openAlphaTyVars
 728 openAlphaTy  = mkTyVarTy openAlphaTyVar
 729 openBetaTy   = mkTyVarTy openBetaTyVar
 730
 731 errorTy  :: Type
 732 errorTy  = mkUsgTy UsMany $
 733            mkSigmaTy [openAlphaTyVar] [] (mkFunTys [mkUsgTy UsOnce (mkListTy charTy)]
 734                                                    (mkUsgTy UsMany openAlphaTy))
 735     -- Notice the openAlphaTyVar.  It says that "error" can be applied
 736     -- to unboxed as well as boxed types.  This is OK because it never
 737     -- returns, so the return type is irrelevant.
 738 \end{code}
 739