ghc/compiler/basicTypes/MkId.lhs

   1 %
   2 % (c) The AQUA Project, Glasgow University, 1998
   3 %
   4 \section[StdIdInfo]{Standard unfoldings}
   5
   6 This module contains definitions for the IdInfo for things that
   7 have a standard form, namely:
   8
   9         * data constructors
  10         * record selectors
  11         * method and superclass selectors
  12         * primitive operations
  13
  14 \begin{code}
  15 module MkId (
  16         mkSpecPragmaId, mkWorkerId,
  17
  18         mkDictFunId, mkDefaultMethodId,
  19         mkDictSelId,
  20
  21         mkDataConId, mkDataConWrapId,
  22         mkRecordSelId,
  23         mkPrimOpId, mkCCallOpId,
  24
  25         -- And some particular Ids; see below for why they are wired in
  26         wiredInIds,
  27         unsafeCoerceId, realWorldPrimId,
  28         eRROR_ID, rEC_SEL_ERROR_ID, pAT_ERROR_ID, rEC_CON_ERROR_ID,
  29         rEC_UPD_ERROR_ID, iRREFUT_PAT_ERROR_ID, nON_EXHAUSTIVE_GUARDS_ERROR_ID,
  30         nO_METHOD_BINDING_ERROR_ID, aBSENT_ERROR_ID, pAR_ERROR_ID
  31     ) where
  32
  33 #include "HsVersions.h"
  34
  35
  36 import TysPrim          ( openAlphaTyVars, alphaTyVar, alphaTy,
  37                           intPrimTy, realWorldStatePrimTy
  38                         )
  39 import TysWiredIn       ( boolTy, charTy, mkListTy )
  40 import PrelMods         ( pREL_ERR, pREL_GHC )
  41 import PrelRules        ( primOpRule )
  42 import Rules            ( addRule )
  43 import Type             ( Type, ClassContext, mkDictTy, mkDictTys, mkTyConApp, mkTyVarTys,
  44                           mkFunTys, mkFunTy, mkSigmaTy, classesToPreds,
  45                           isUnLiftedType, mkForAllTys, mkTyVarTy, tyVarsOfType, tyVarsOfTypes,
  46                           splitSigmaTy, splitFunTy_maybe,
  47                           splitFunTys, splitForAllTys, unUsgTy,
  48                           mkUsgTy, UsageAnn(..)
  49                         )
  50 import PprType          ( pprParendType )
  51 import Module           ( Module )
  52 import CoreUtils        ( exprType, mkInlineMe )
  53 import CoreUnfold       ( mkTopUnfolding, mkCompulsoryUnfolding, mkOtherCon )
  54 import Subst            ( mkTopTyVarSubst, substClasses )
  55 import TyCon            ( TyCon, isNewTyCon, tyConTyVars, tyConDataCons, isDataTyCon,
  56                           tyConTheta, isProductTyCon, isUnboxedTupleTyCon )
  57 import Class            ( Class, classBigSig, classTyCon, classTyVars, classSelIds )
  58 import Var              ( Id, TyVar )
  59 import VarSet           ( isEmptyVarSet )
  60 import Name             ( mkDerivedName, mkWiredInIdName, mkLocalName,
  61                           mkWorkerOcc, mkSuperDictSelOcc, mkCCallName,
  62                           Name, NamedThing(..),
  63                         )
  64 import OccName          ( mkSrcVarOcc )
  65 import PrimOp           ( PrimOp(DataToTagOp, CCallOp),
  66                           primOpSig, mkPrimOpIdName,
  67                           CCall, pprCCallOp
  68                         )
  69 import Demand           ( wwStrict, wwPrim )
  70 import DataCon          ( DataCon, StrictnessMark(..),
  71                           dataConFieldLabels, dataConRepArity, dataConTyCon,
  72                           dataConArgTys, dataConRepType, dataConRepStrictness,
  73                           dataConName, dataConTheta,
  74                           dataConSig, dataConStrictMarks, dataConId
  75                         )
  76 import Id               ( idType, mkId,
  77                           mkVanillaId, mkTemplateLocals,
  78                           mkTemplateLocal, setInlinePragma, idCprInfo
  79                         )
  80 import IdInfo           ( IdInfo, vanillaIdInfo, mkIdInfo,
  81                           exactArity, setUnfoldingInfo, setCafInfo, setCprInfo,
  82                           setArityInfo, setInlinePragInfo, setSpecInfo,
  83                           mkStrictnessInfo, setStrictnessInfo,
  84                           IdFlavour(..), InlinePragInfo(..), CafInfo(..), StrictnessInfo(..), CprInfo(..)
  85                         )
  86 import FieldLabel       ( FieldLabel, FieldLabelTag, mkFieldLabel, fieldLabelName,
  87                           firstFieldLabelTag, allFieldLabelTags, fieldLabelType
  88                         )
  89 import CoreSyn
  90 import Maybes
  91 import BasicTypes       ( Arity )
  92 import Unique
  93 import Maybe            ( isJust )
  94 import Outputable
  95 import Util             ( assoc )
  96 import List             ( nub )
  97 \end{code}
  98
  99
 100 %************************************************************************
 101 %*                                                                      *
 102 \subsection{Wired in Ids}
 103 %*                                                                      *
 104 %************************************************************************
 105
 106 \begin{code}
 107 wiredInIds
 108   = [   -- These error-y things are wired in because we don't yet have
 109         -- a way to express in an interface file that the result type variable
 110         -- is 'open'; that is can be unified with an unboxed type
 111         --
 112         -- [The interface file format now carry such information, but there's
 113         --  no way yet of expressing at the definition site for these error-reporting
 114         --  functions that they have an 'open' result type. -- sof 1/99]
 115
 116       aBSENT_ERROR_ID
 117     , eRROR_ID
 118     , iRREFUT_PAT_ERROR_ID
 119     , nON_EXHAUSTIVE_GUARDS_ERROR_ID
 120     , nO_METHOD_BINDING_ERROR_ID
 121     , pAR_ERROR_ID
 122     , pAT_ERROR_ID
 123     , rEC_CON_ERROR_ID
 124     , rEC_UPD_ERROR_ID
 125
 126         -- These two can't be defined in Haskell
 127     , realWorldPrimId
 128     , unsafeCoerceId
 129     , getTagId
 130     ]
 131 \end{code}
 132
 133 %************************************************************************
 134 %*                                                                      *
 135 \subsection{Easy ones}
 136 %*                                                                      *
 137 %************************************************************************
 138
 139 \begin{code}
 140 mkSpecPragmaId occ uniq ty loc
 141   = mkId (mkLocalName uniq occ loc) ty (mkIdInfo SpecPragmaId)
 142         -- Maybe a SysLocal?  But then we'd lose the location
 143
 144 mkDefaultMethodId dm_name rec_c ty
 145   = mkVanillaId dm_name ty
 146
 147 mkWorkerId uniq unwrkr ty
 148   = mkVanillaId (mkDerivedName mkWorkerOcc (getName unwrkr) uniq) ty
 149 \end{code}
 150
 151 %************************************************************************
 152 %*                                                                      *
 153 \subsection{Data constructors}
 154 %*                                                                      *
 155 %************************************************************************
 156
 157 \begin{code}
 158 mkDataConId :: Name -> DataCon -> Id
 159         -- Makes the *worker* for the data constructor; that is, the function
 160         -- that takes the reprsentation arguments and builds the constructor.
 161 mkDataConId work_name data_con
 162   = mkId work_name (dataConRepType data_con) info
 163   where
 164     info = mkIdInfo (DataConId data_con)
 165            `setArityInfo`       exactArity arity
 166            `setStrictnessInfo`  strict_info
 167            `setCprInfo`         cpr_info
 168
 169     arity = dataConRepArity data_con
 170
 171     strict_info = StrictnessInfo (dataConRepStrictness data_con) False
 172
 173     cpr_info | isProductTyCon tycon &&
 174                not (isUnboxedTupleTyCon tycon) &&
 175                arity > 0                        = ReturnsCPR
 176              | otherwise                        = NoCPRInfo
 177              where
 178                 tycon = dataConTyCon data_con
 179                 -- Newtypes don't have a worker at all
 180                 --
 181                 -- If we are a product with 0 args we must be void(like)
 182                 -- We can't create an unboxed tuple with 0 args for this
 183                 -- and since Void has only one, constant value it should
 184                 -- just mean returning a pointer to a pre-existing cell.
 185                 -- So we won't really gain from doing anything fancy
 186                 -- and we treat this case as Top.
 187 \end{code}
 188
 189 The wrapper for a constructor is an ordinary top-level binding that evaluates
 190 any strict args, unboxes any args that are going to be flattened, and calls
 191 the worker.
 192
 193 We're going to build a constructor that looks like:
 194
 195         data (Data a, C b) =>  T a b = T1 !a !Int b
 196
 197         T1 = /\ a b ->
 198              \d1::Data a, d2::C b ->
 199              \p q r -> case p of { p ->
 200                        case q of { q ->
 201                        Con T1 [a,b] [p,q,r]}}
 202
 203 Notice that
 204
 205 * d2 is thrown away --- a context in a data decl is used to make sure
 206   one *could* construct dictionaries at the site the constructor
 207   is used, but the dictionary isn't actually used.
 208
 209 * We have to check that we can construct Data dictionaries for
 210   the types a and Int.  Once we've done that we can throw d1 away too.
 211
 212 * We use (case p of q -> ...) to evaluate p, rather than "seq" because
 213   all that matters is that the arguments are evaluated.  "seq" is
 214   very careful to preserve evaluation order, which we don't need
 215   to be here.
 216
 217   You might think that we could simply give constructors some strictness
 218   info, like PrimOps, and let CoreToStg do the let-to-case transformation.
 219   But we don't do that because in the case of primops and functions strictness
 220   is a *property* not a *requirement*.  In the case of constructors we need to
 221   do something active to evaluate the argument.
 222
 223   Making an explicit case expression allows the simplifier to eliminate
 224   it in the (common) case where the constructor arg is already evaluated.
 225
 226 \begin{code}
 227 mkDataConWrapId data_con
 228   = wrap_id
 229   where
 230     wrap_id = mkId (dataConName data_con) wrap_ty info
 231     work_id = dataConId data_con
 232
 233     info = mkIdInfo (DataConWrapId data_con)
 234            `setUnfoldingInfo`   mkTopUnfolding (mkInlineMe wrap_rhs)
 235            `setCprInfo`         cpr_info
 236                 -- The Cpr info can be important inside INLINE rhss, where the
 237                 -- wrapper constructor isn't inlined
 238            `setArityInfo`       exactArity arity
 239                 -- It's important to specify the arity, so that partial
 240                 -- applications are treated as values
 241            `setCafInfo`       NoCafRefs
 242                 -- The wrapper Id ends up in STG code as an argument,
 243                 -- sometimes before its definition, so we want to
 244                 -- signal that it has no CAFs
 245
 246     wrap_ty = mkForAllTys all_tyvars $
 247               mkFunTys all_arg_tys
 248               result_ty
 249
 250     cpr_info = idCprInfo work_id
 251
 252     wrap_rhs | isNewTyCon tycon
 253              = ASSERT( null ex_tyvars && null ex_dict_args && length orig_arg_tys == 1 )
 254                 -- No existentials on a newtype, but it can have a contex
 255                 -- e.g.         newtype Eq a => T a = MkT (...)
 256
 257                mkLams tyvars $ mkLams dict_args $ Lam id_arg1 $
 258                Note (Coerce result_ty (head orig_arg_tys)) (Var id_arg1)
 259
 260 {-      I nuked this because map (:) xs would create a
 261         new local lambda for the (:) in core-to-stg.
 262         There isn't a defn for the worker!
 263
 264              | null dict_args && all not_marked_strict strict_marks
 265              = Var work_id      -- The common case.  Not only is this efficient,
 266                                 -- but it also ensures that the wrapper is replaced
 267                                 -- by the worker even when there are no args.
 268                                 --              f (:) x
 269                                 -- becomes
 270                                 --              f $w: x
 271                                 -- This is really important in rule matching,
 272                                 -- which is a bit sad.  (We could match on the wrappers,
 273                                 -- but that makes it less likely that rules will match
 274                                 -- when we bring bits of unfoldings together
 275 -}
 276
 277              | otherwise
 278              = mkLams all_tyvars $ mkLams dict_args $
 279                mkLams ex_dict_args $ mkLams id_args $
 280                foldr mk_case con_app
 281                      (zip (ex_dict_args++id_args) strict_marks) i3 []
 282
 283     con_app i rep_ids = mkApps (Var work_id)
 284                                (map varToCoreExpr (all_tyvars ++ reverse rep_ids))
 285
 286     (tyvars, theta, ex_tyvars, ex_theta, orig_arg_tys, tycon) = dataConSig data_con
 287     all_tyvars   = tyvars ++ ex_tyvars
 288
 289     dict_tys     = mkDictTys theta
 290     ex_dict_tys  = mkDictTys ex_theta
 291     all_arg_tys  = dict_tys ++ ex_dict_tys ++ orig_arg_tys
 292     result_ty    = mkTyConApp tycon (mkTyVarTys tyvars)
 293
 294     mkLocals i tys = (zipWith mkTemplateLocal [i..i+n-1] tys, i+n)
 295                    where
 296                      n = length tys
 297
 298     (dict_args, i1)    = mkLocals 1  dict_tys
 299     (ex_dict_args,i2)  = mkLocals i1 ex_dict_tys
 300     (id_args,i3)       = mkLocals i2 orig_arg_tys
 301     arity              = i3-1
 302     (id_arg1:_)   = id_args             -- Used for newtype only
 303
 304     strict_marks  = dataConStrictMarks data_con
 305     not_marked_strict NotMarkedStrict = True
 306     not_marked_strict other           = False
 307
 308
 309     mk_case
 310            :: (Id, StrictnessMark)      -- arg, strictness
 311            -> (Int -> [Id] -> CoreExpr) -- body
 312            -> Int                       -- next rep arg id
 313            -> [Id]                      -- rep args so far
 314            -> CoreExpr
 315     mk_case (arg,strict) body i rep_args
 316           = case strict of
 317                 NotMarkedStrict -> body i (arg:rep_args)
 318                 MarkedStrict
 319                    | isUnLiftedType (idType arg) -> body i (arg:rep_args)
 320                    | otherwise ->
 321                         Case (Var arg) arg [(DEFAULT,[], body i (arg:rep_args))]
 322
 323                 MarkedUnboxed con tys ->
 324                    Case (Var arg) arg [(DataAlt con, con_args,
 325                                         body i' (reverse con_args++rep_args))]
 326                    where n_tys = length tys
 327                          (con_args,i') = mkLocals i tys
 328 \end{code}
 329
 330
 331 %************************************************************************
 332 %*                                                                      *
 333 \subsection{Record selectors}
 334 %*                                                                      *
 335 %************************************************************************
 336
 337 We're going to build a record selector unfolding that looks like this:
 338
 339         data T a b c = T1 { ..., op :: a, ...}
 340                      | T2 { ..., op :: a, ...}
 341                      | T3
 342
 343         sel = /\ a b c -> \ d -> case d of
 344                                     T1 ... x ... -> x
 345                                     T2 ... x ... -> x
 346                                     other        -> error "..."
 347
 348 \begin{code}
 349 mkRecordSelId tycon field_label
 350         -- Assumes that all fields with the same field label
 351         -- have the same type
 352   = sel_id
 353   where
 354     sel_id     = mkId (fieldLabelName field_label) selector_ty info
 355
 356     field_ty   = fieldLabelType field_label
 357     field_name = fieldLabelName field_label
 358     data_cons  = tyConDataCons tycon
 359     tyvars     = tyConTyVars tycon      -- These scope over the types in
 360                                         -- the FieldLabels of constructors of this type
 361     tycon_theta = tyConTheta tycon      -- The context on the data decl
 362                                         --   eg data (Eq a, Ord b) => T a b = ...
 363
 364     data_ty   = mkTyConApp tycon (mkTyVarTys tyvars)
 365     tyvar_tys = mkTyVarTys tyvars
 366
 367         -- Very tiresomely, the selectors are (unnecessarily!) overloaded over
 368         -- just the dictionaries in the types of the constructors that contain
 369         -- the relevant field.  Urgh.
 370         -- NB: this code relies on the fact that DataCons are quantified over
 371         -- the identical type variables as their parent TyCon
 372     dict_tys  = [mkDictTy cls tys | (cls, tys) <- tycon_theta, needed_dict (cls, tys)]
 373     needed_dict pred = or [ pred `elem` (dataConTheta dc)
 374                           | (DataAlt dc, _, _) <- the_alts]
 375
 376     selector_ty :: Type
 377     selector_ty  = mkForAllTys tyvars $ mkFunTys dict_tys $
 378                    mkFunTy data_ty field_ty
 379
 380     info = mkIdInfo (RecordSelId field_label)
 381            `setArityInfo`       exactArity 1
 382            `setUnfoldingInfo`   unfolding
 383            `setCafInfo`         NoCafRefs
 384         -- ToDo: consider adding further IdInfo
 385
 386     unfolding = mkTopUnfolding sel_rhs
 387
 388
 389     (data_id:dict_ids) = mkTemplateLocals (data_ty:dict_tys)
 390     alts      = map mk_maybe_alt data_cons
 391     the_alts  = catMaybes alts
 392     default_alt | all isJust alts = []  -- No default needed
 393                 | otherwise       = [(DEFAULT, [], error_expr)]
 394
 395     sel_rhs | isNewTyCon tycon = new_sel_rhs
 396             | otherwise        = data_sel_rhs
 397
 398     data_sel_rhs = mkLams tyvars $ mkLams dict_ids $ Lam data_id $
 399                    Case (Var data_id) data_id (the_alts ++ default_alt)
 400
 401     new_sel_rhs  = mkLams tyvars $ Lam data_id $
 402                     Note (Coerce (unUsgTy field_ty) (unUsgTy data_ty)) (Var data_id)
 403
 404     mk_maybe_alt data_con
 405           = case maybe_the_arg_id of
 406                 Nothing         -> Nothing
 407                 Just the_arg_id -> Just (DataAlt data_con, arg_ids, Var the_arg_id)
 408           where
 409             arg_ids          = mkTemplateLocals (dataConArgTys data_con tyvar_tys)
 410                                     -- The first one will shadow data_id, but who cares
 411             field_lbls       = dataConFieldLabels data_con
 412             maybe_the_arg_id = assocMaybe (field_lbls `zip` arg_ids) field_label
 413
 414     error_expr = mkApps (Var rEC_SEL_ERROR_ID) [Type (unUsgTy field_ty), mkStringLit full_msg]
 415        -- preserves invariant that type args are *not* usage-annotated on top.  KSW 1999-04.
 416     full_msg   = showSDoc (sep [text "No match in record selector", ppr sel_id])
 417 \end{code}
 418
 419
 420 %************************************************************************
 421 %*                                                                      *
 422 \subsection{Dictionary selectors}
 423 %*                                                                      *
 424 %************************************************************************
 425
 426 Selecting a field for a dictionary.  If there is just one field, then
 427 there's nothing to do.
 428
 429 ToDo: unify with mkRecordSelId.
 430
 431 \begin{code}
 432 mkDictSelId name clas
 433   = sel_id
 434   where
 435     ty        = exprType rhs
 436     sel_id    = mkId name ty info
 437     field_lbl = mkFieldLabel name ty tag
 438     tag       = assoc "MkId.mkDictSelId" (classSelIds clas `zip` allFieldLabelTags) sel_id
 439
 440     info      = mkIdInfo (RecordSelId field_lbl)
 441                 `setArityInfo`      exactArity 1
 442                 `setUnfoldingInfo`  unfolding
 443                 `setCafInfo`        NoCafRefs
 444
 445         -- We no longer use 'must-inline' on record selectors.  They'll
 446         -- inline like crazy if they scrutinise a constructor
 447
 448     unfolding = mkTopUnfolding rhs
 449
 450     tyvars  = classTyVars clas
 451
 452     tycon      = classTyCon clas
 453     [data_con] = tyConDataCons tycon
 454     tyvar_tys  = mkTyVarTys tyvars
 455     arg_tys    = dataConArgTys data_con tyvar_tys
 456     the_arg_id = arg_ids !! (tag - firstFieldLabelTag)
 457
 458     dict_ty    = mkDictTy clas tyvar_tys
 459     (dict_id:arg_ids) = mkTemplateLocals (dict_ty : arg_tys)
 460
 461     rhs | isNewTyCon tycon = mkLams tyvars $ Lam dict_id $
 462                              Note (Coerce (head arg_tys) dict_ty) (Var dict_id)
 463         | otherwise        = mkLams tyvars $ Lam dict_id $
 464                              Case (Var dict_id) dict_id
 465                                   [(DataAlt data_con, arg_ids, Var the_arg_id)]
 466 \end{code}
 467
 468
 469 %************************************************************************
 470 %*                                                                      *
 471 \subsection{Primitive operations
 472 %*                                                                      *
 473 %************************************************************************
 474
 475 \begin{code}
 476 mkPrimOpId :: PrimOp -> Id
 477 mkPrimOpId prim_op
 478   = id
 479   where
 480     (tyvars,arg_tys,res_ty, arity, strict_info) = primOpSig prim_op
 481     ty   = mkForAllTys tyvars (mkFunTys arg_tys res_ty)
 482     name = mkPrimOpIdName prim_op id
 483     id   = mkId name ty info
 484
 485     info = mkIdInfo (PrimOpId prim_op)
 486            `setSpecInfo`        rules
 487            `setArityInfo`       exactArity arity
 488            `setStrictnessInfo`  strict_info
 489
 490     rules = addRule id emptyCoreRules (primOpRule prim_op)
 491
 492
 493 -- For each ccall we manufacture a separate CCallOpId, giving it
 494 -- a fresh unique, a type that is correct for this particular ccall,
 495 -- and a CCall structure that gives the correct details about calling
 496 -- convention etc.
 497 --
 498 -- The *name* of this Id is a local name whose OccName gives the full
 499 -- details of the ccall, type and all.  This means that the interface
 500 -- file reader can reconstruct a suitable Id
 501
 502 mkCCallOpId :: Unique -> CCall -> Type -> Id
 503 mkCCallOpId uniq ccall ty
 504   = ASSERT( isEmptyVarSet (tyVarsOfType ty) )
 505         -- A CCallOpId should have no free type variables;
 506         -- when doing substitutions won't substitute over it
 507     mkId name ty info
 508   where
 509     occ_str = showSDocIface (braces (pprCCallOp ccall <+> ppr ty))
 510         -- The "occurrence name" of a ccall is the full info about the
 511         -- ccall; it is encoded, but may have embedded spaces etc!
 512
 513     name    = mkCCallName uniq occ_str
 514     prim_op = CCallOp ccall
 515
 516     info = mkIdInfo (PrimOpId prim_op)
 517            `setArityInfo`       exactArity arity
 518            `setStrictnessInfo`  strict_info
 519
 520     (_, tau)     = splitForAllTys ty
 521     (arg_tys, _) = splitFunTys tau
 522     arity        = length arg_tys
 523     strict_info  = mkStrictnessInfo (take arity (repeat wwPrim), False)
 524 \end{code}
 525
 526
 527 %************************************************************************
 528 %*                                                                      *
 529 \subsection{DictFuns}
 530 %*                                                                      *
 531 %************************************************************************
 532
 533 \begin{code}
 534 mkDictFunId :: Name             -- Name to use for the dict fun;
 535             -> Class
 536             -> [TyVar]
 537             -> [Type]
 538             -> ClassContext
 539             -> Id
 540
 541 mkDictFunId dfun_name clas inst_tyvars inst_tys inst_decl_theta
 542   = mkVanillaId dfun_name dfun_ty
 543   where
 544     (class_tyvars, sc_theta, _, _) = classBigSig clas
 545     sc_theta' = substClasses (mkTopTyVarSubst class_tyvars inst_tys) sc_theta
 546
 547     dfun_theta = classesToPreds inst_decl_theta
 548
 549 {-  1 dec 99: disable the Mark Jones optimisation for the sake
 550     of compatibility with Hugs.
 551     See `types/InstEnv' for a discussion related to this.
 552
 553     dfun_theta = case inst_decl_theta of
 554                    []    -> []  -- If inst_decl_theta is empty, then we don't
 555                                 -- want to have any dict arguments, so that we can
 556                                 -- expose the constant methods.
 557
 558                    other -> nub (inst_decl_theta ++ filter not_const sc_theta')
 559                                 -- Otherwise we pass the superclass dictionaries to
 560                                 -- the dictionary function; the Mark Jones optimisation.
 561                                 --
 562                                 -- NOTE the "nub".  I got caught by this one:
 563                                 --   class Monad m => MonadT t m where ...
 564                                 --   instance Monad m => MonadT (EnvT env) m where ...
 565                                 -- Here, the inst_decl_theta has (Monad m); but so
 566                                 -- does the sc_theta'!
 567                                 --
 568                                 -- NOTE the "not_const".  I got caught by this one too:
 569                                 --   class Foo a => Baz a b where ...
 570                                 --   instance Wob b => Baz T b where..
 571                                 -- Now sc_theta' has Foo T
 572 -}
 573     dfun_ty = mkSigmaTy inst_tyvars dfun_theta (mkDictTy clas inst_tys)
 574
 575     not_const (clas, tys) = not (isEmptyVarSet (tyVarsOfTypes tys))
 576 \end{code}
 577
 578
 579 %************************************************************************
 580 %*                                                                      *
 581 \subsection{Un-definable}
 582 %*                                                                      *
 583 %************************************************************************
 584
 585 These two can't be defined in Haskell.
 586
 587 unsafeCoerce# isn't so much a PrimOp as a phantom identifier, that
 588 just gets expanded into a type coercion wherever it occurs.  Hence we
 589 add it as a built-in Id with an unfolding here.
 590
 591 The type variables we use here are "open" type variables: this means
 592 they can unify with both unlifted and lifted types.  Hence we provide
 593 another gun with which to shoot yourself in the foot.
 594
 595 \begin{code}
 596 unsafeCoerceId
 597   = pcMiscPrelId unsafeCoerceIdKey pREL_GHC SLIT("unsafeCoerce#") ty info
 598   where
 599     info = vanillaIdInfo
 600            `setUnfoldingInfo` mkCompulsoryUnfolding rhs
 601
 602
 603     ty  = mkForAllTys [openAlphaTyVar,openBetaTyVar]
 604                       (mkFunTy openAlphaTy openBetaTy)
 605     [x] = mkTemplateLocals [openAlphaTy]
 606     rhs = mkLams [openAlphaTyVar,openBetaTyVar,x] $
 607           Note (Coerce openBetaTy openAlphaTy) (Var x)
 608 \end{code}
 609
 610
 611 @getTag#@ is another function which can't be defined in Haskell.  It needs to
 612 evaluate its argument and call the dataToTag# primitive.
 613
 614 \begin{code}
 615 getTagId
 616   = pcMiscPrelId getTagIdKey pREL_GHC SLIT("getTag#") ty info
 617   where
 618     info = vanillaIdInfo
 619            `setUnfoldingInfo`   mkCompulsoryUnfolding rhs
 620         -- We don't provide a defn for this; you must inline it
 621
 622     ty = mkForAllTys [alphaTyVar] (mkFunTy alphaTy intPrimTy)
 623     [x,y] = mkTemplateLocals [alphaTy,alphaTy]
 624     rhs = mkLams [alphaTyVar,x] $
 625           Case (Var x) y [ (DEFAULT, [], mkApps (Var dataToTagId) [Type alphaTy, Var y]) ]
 626
 627 dataToTagId = mkPrimOpId DataToTagOp
 628 \end{code}
 629
 630 @realWorld#@ used to be a magic literal, \tr{void#}.  If things get
 631 nasty as-is, change it back to a literal (@Literal@).
 632
 633 \begin{code}
 634 realWorldPrimId -- :: State# RealWorld
 635   = pcMiscPrelId realWorldPrimIdKey pREL_GHC SLIT("realWorld#")
 636                  realWorldStatePrimTy
 637                  (noCafIdInfo `setUnfoldingInfo` mkOtherCon [])
 638         -- The mkOtherCon makes it look that realWorld# is evaluated
 639         -- which in turn makes Simplify.interestingArg return True,
 640         -- which in turn makes INLINE things applied to realWorld# likely
 641         -- to be inlined
 642 \end{code}
 643
 644
 645 %************************************************************************
 646 %*                                                                      *
 647 \subsection[PrelVals-error-related]{@error@ and friends; @trace@}
 648 %*                                                                      *
 649 %************************************************************************
 650
 651 GHC randomly injects these into the code.
 652
 653 @patError@ is just a version of @error@ for pattern-matching
 654 failures.  It knows various ``codes'' which expand to longer
 655 strings---this saves space!
 656
 657 @absentErr@ is a thing we put in for ``absent'' arguments.  They jolly
 658 well shouldn't be yanked on, but if one is, then you will get a
 659 friendly message from @absentErr@ (rather than a totally random
 660 crash).
 661
 662 @parError@ is a special version of @error@ which the compiler does
 663 not know to be a bottoming Id.  It is used in the @_par_@ and @_seq_@
 664 templates, but we don't ever expect to generate code for it.
 665
 666 \begin{code}
 667 eRROR_ID
 668   = pc_bottoming_Id errorIdKey pREL_ERR SLIT("error") errorTy
 669 rEC_SEL_ERROR_ID
 670   = generic_ERROR_ID recSelErrIdKey SLIT("patError")
 671 pAT_ERROR_ID
 672   = generic_ERROR_ID patErrorIdKey SLIT("patError")
 673 rEC_CON_ERROR_ID
 674   = generic_ERROR_ID recConErrorIdKey SLIT("recConError")
 675 rEC_UPD_ERROR_ID
 676   = generic_ERROR_ID recUpdErrorIdKey SLIT("recUpdError")
 677 iRREFUT_PAT_ERROR_ID
 678   = generic_ERROR_ID irrefutPatErrorIdKey SLIT("irrefutPatError")
 679 nON_EXHAUSTIVE_GUARDS_ERROR_ID
 680   = generic_ERROR_ID nonExhaustiveGuardsErrorIdKey SLIT("nonExhaustiveGuardsError")
 681 nO_METHOD_BINDING_ERROR_ID
 682   = generic_ERROR_ID noMethodBindingErrorIdKey SLIT("noMethodBindingError")
 683
 684 aBSENT_ERROR_ID
 685   = pc_bottoming_Id absentErrorIdKey pREL_ERR SLIT("absentErr")
 686         (mkSigmaTy [openAlphaTyVar] [] openAlphaTy)
 687
 688 pAR_ERROR_ID
 689   = pcMiscPrelId parErrorIdKey pREL_ERR SLIT("parError")
 690     (mkSigmaTy [openAlphaTyVar] [] openAlphaTy) noCafIdInfo
 691
 692 \end{code}
 693
 694
 695 %************************************************************************
 696 %*                                                                      *
 697 \subsection{Utilities}
 698 %*                                                                      *
 699 %************************************************************************
 700
 701 \begin{code}
 702 pcMiscPrelId :: Unique{-IdKey-} -> Module -> FAST_STRING -> Type -> IdInfo -> Id
 703 pcMiscPrelId key mod str ty info
 704   = let
 705         name = mkWiredInIdName key mod (mkSrcVarOcc str) imp
 706         imp  = mkId name ty info -- the usual case...
 707     in
 708     imp
 709     -- We lie and say the thing is imported; otherwise, we get into
 710     -- a mess with dependency analysis; e.g., core2stg may heave in
 711     -- random calls to GHCbase.unpackPS__.  If GHCbase is the module
 712     -- being compiled, then it's just a matter of luck if the definition
 713     -- will be in "the right place" to be in scope.
 714
 715 pc_bottoming_Id key mod name ty
 716  = pcMiscPrelId key mod name ty bottoming_info
 717  where
 718     bottoming_info = noCafIdInfo
 719                      `setStrictnessInfo` mkStrictnessInfo ([wwStrict], True)
 720
 721         -- these "bottom" out, no matter what their arguments
 722
 723 generic_ERROR_ID u n = pc_bottoming_Id u pREL_ERR n errorTy
 724
 725 -- Very useful...
 726 noCafIdInfo = vanillaIdInfo `setCafInfo` NoCafRefs
 727
 728 (openAlphaTyVar:openBetaTyVar:_) = openAlphaTyVars
 729 openAlphaTy  = mkTyVarTy openAlphaTyVar
 730 openBetaTy   = mkTyVarTy openBetaTyVar
 731
 732 errorTy  :: Type
 733 errorTy  = mkUsgTy UsMany $
 734            mkSigmaTy [openAlphaTyVar] [] (mkFunTys [mkUsgTy UsOnce (mkListTy charTy)]
 735                                                    (mkUsgTy UsMany openAlphaTy))
 736     -- Notice the openAlphaTyVar.  It says that "error" can be applied
 737     -- to unboxed as well as boxed types.  This is OK because it never
 738     -- returns, so the return type is irrelevant.
 739 \end{code}
 740