ghc/compiler/basicTypes/Module.lhs

   1 %
   2 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   3 %
   4 \section[Module]{The @Module@ module.}
   5
   6 Representing modules and their flavours.
   7
   8 \begin{code}
   9 module Module
  10     (
  11       Module                -- abstract, instance of Eq, Ord, Outputable
  12     , ModuleName
  13
  14     , moduleNameString          -- :: ModuleName -> EncodedString
  15     , moduleNameUserString      -- :: ModuleName -> UserString
  16
  17     , moduleString          -- :: Module -> EncodedString
  18     , moduleUserString      -- :: Module -> UserString
  19     , moduleName            -- :: Module -> ModuleName
  20
  21     , mkVanillaModule       -- :: ModuleName -> Module
  22     , mkThisModule          -- :: ModuleName -> Module
  23     , mkPrelModule          -- :: UserString -> Module
  24
  25     , isDynamicModule       -- :: Module -> Bool
  26     , isLibModule
  27
  28     , mkSrcModule
  29
  30     , mkSrcModuleFS         -- :: UserFS    -> ModuleName
  31     , mkSysModuleFS         -- :: EncodedFS -> ModuleName
  32
  33     , pprModule, pprModuleName
  34
  35         -- DllFlavour
  36     , DllFlavour, dll, notDll
  37
  38         -- ModFlavour
  39     , ModFlavour, libMod, userMod
  40
  41         -- Where to find a .hi file
  42     , WhereFrom(..), SearchPath, mkSearchPath
  43     , ModuleHiMap, mkModuleHiMaps
  44
  45     ) where
  46
  47 #include "HsVersions.h"
  48 import OccName
  49 import Outputable
  50 import FiniteMap
  51 import CmdLineOpts      ( opt_Static, opt_CompilingPrelude, opt_WarnHiShadows )
  52 import Constants        ( interfaceFileFormatVersion )
  53 import Maybes           ( seqMaybe )
  54 import Maybe            ( fromMaybe )
  55 import Directory        ( doesFileExist )
  56 import DirUtils         ( getDirectoryContents )
  57 import List             ( intersperse )
  58 import Monad            ( foldM )
  59 import IO               ( hPutStrLn, stderr, isDoesNotExistError )
  60 \end{code}
  61
  62
  63 %************************************************************************
  64 %*                                                                      *
  65 \subsection{Interface file flavour}
  66 %*                                                                      *
  67 %************************************************************************
  68
  69 A further twist to the tale is the support for dynamically linked libraries under
  70 Win32. Here, dealing with the use of global variables that's residing in a DLL
  71 requires special handling at the point of use (there's an extra level of indirection,
  72 i.e., (**v) to get at v's value, rather than just (*v) .) When slurping in an
  73 interface file we then record whether it's coming from a .hi corresponding to a
  74 module that's packaged up in a DLL or not, so that we later can emit the
  75 appropriate code.
  76
  77 The logic for how an interface file is marked as corresponding to a module that's
  78 hiding in a DLL is explained elsewhere (ToDo: give renamer href here.)
  79
  80 \begin{code}
  81 data DllFlavour = NotDll        -- Ordinary module
  82                 | Dll           -- The module's object code lives in a DLL.
  83                 deriving( Eq )
  84
  85 dll    = Dll
  86 notDll = NotDll
  87
  88 instance Text DllFlavour where  -- Just used in debug prints of lex tokens
  89   showsPrec n NotDll s = s
  90   showsPrec n Dll    s = "dll " ++ s
  91 \end{code}
  92
  93
  94 %************************************************************************
  95 %*                                                                      *
  96 \subsection{System/user module}
  97 %*                                                                      *
  98 %************************************************************************
  99
 100 We also track whether an imported module is from a 'system-ish' place.  In this case
 101 we don't record the fact that this module depends on it, nor usages of things
 102 inside it.
 103
 104 \begin{code}
 105 data ModFlavour = LibMod        -- A library-ish module
 106                 | UserMod       -- Not library-ish
 107
 108 libMod  = LibMod
 109 userMod = UserMod
 110 \end{code}
 111
 112
 113 %************************************************************************
 114 %*                                                                      *
 115 \subsection{Where from}
 116 %*                                                                      *
 117 %************************************************************************
 118
 119 The @WhereFrom@ type controls where the renamer looks for an interface file
 120
 121 \begin{code}
 122 data WhereFrom = ImportByUser           -- Ordinary user import: look for M.hi
 123                | ImportByUserSource     -- User {- SOURCE -}: look for M.hi-boot
 124                | ImportBySystem         -- Non user import.  Look for M.hi if M is in
 125                                         -- the module this module depends on, or is a system-ish module;
 126                                         -- M.hi-boot otherwise
 127
 128 instance Outputable WhereFrom where
 129   ppr ImportByUser       = empty
 130   ppr ImportByUserSource = ptext SLIT("{- SOURCE -}")
 131   ppr ImportBySystem     = ptext SLIT("{- SYSTEM IMPORT -}")
 132 \end{code}
 133
 134
 135 %************************************************************************
 136 %*                                                                      *
 137 \subsection{The name of a module}
 138 %*                                                                      *
 139 %************************************************************************
 140
 141 \begin{code}
 142 type ModuleName = EncodedFS
 143         -- Haskell module names can include the quote character ',
 144         -- so the module names have the z-encoding applied to them
 145
 146
 147 pprModuleName :: ModuleName -> SDoc
 148 pprModuleName nm = pprEncodedFS nm
 149
 150 moduleNameString :: ModuleName -> EncodedString
 151 moduleNameString mod = _UNPK_ mod
 152
 153 moduleNameUserString :: ModuleName -> UserString
 154 moduleNameUserString mod = decode (_UNPK_ mod)
 155
 156 mkSrcModule :: UserString -> ModuleName
 157 mkSrcModule s = _PK_ (encode s)
 158
 159 mkSrcModuleFS :: UserFS -> ModuleName
 160 mkSrcModuleFS s = encodeFS s
 161
 162 mkSysModuleFS :: EncodedFS -> ModuleName
 163 mkSysModuleFS s = s
 164 \end{code}
 165
 166 \begin{code}
 167 data Module = Module
 168                 ModuleName
 169                 ModFlavour
 170                 DllFlavour
 171 \end{code}
 172
 173 \begin{code}
 174 instance Outputable Module where
 175   ppr = pprModule
 176
 177 instance Eq Module where
 178   (Module m1 _  _) == (Module m2 _ _) = m1 == m2
 179
 180 instance Ord Module where
 181   (Module m1 _ _) `compare` (Module m2 _ _) = m1 `compare` m2
 182 \end{code}
 183
 184
 185 \begin{code}
 186 pprModule :: Module -> SDoc
 187 pprModule (Module mod _ _) = pprEncodedFS mod
 188 \end{code}
 189
 190
 191 \begin{code}
 192 mkModule = Module
 193
 194 mkVanillaModule :: ModuleName -> Module
 195 mkVanillaModule name = Module name UserMod NotDll
 196
 197 mkThisModule :: ModuleName -> Module    -- The module being comiled
 198 mkThisModule name = Module name UserMod NotDll  -- ToDo: correct Dll flag?
 199
 200 mkPrelModule :: ModuleName -> Module
 201 mkPrelModule name = Module name sys dll
 202  where
 203   sys | opt_CompilingPrelude = UserMod
 204       | otherwise            = LibMod
 205
 206   dll | opt_Static || opt_CompilingPrelude = NotDll
 207       | otherwise                          = Dll
 208
 209 moduleString :: Module -> EncodedString
 210 moduleString (Module mod _ _) = _UNPK_ mod
 211
 212 moduleName :: Module -> ModuleName
 213 moduleName (Module mod _ _) = mod
 214
 215 moduleUserString :: Module -> UserString
 216 moduleUserString (Module mod _ _) = moduleNameUserString mod
 217 \end{code}
 218
 219 \begin{code}
 220 isDynamicModule :: Module -> Bool
 221 isDynamicModule (Module _ _ Dll)  = True
 222 isDynamicModule _                 = False
 223
 224 isLibModule :: Module -> Bool
 225 isLibModule (Module _ LibMod _) = True
 226 isLibModule _                   = False
 227 \end{code}
 228
 229
 230 %************************************************************************
 231 %*                                                                      *
 232 \subsection{Finding modules in the file system
 233 %*                                                                      *
 234 %************************************************************************
 235
 236 \begin{code}
 237 type ModuleHiMap = FiniteMap ModuleName (String, Module)
 238   -- Mapping from module name to
 239   --    * the file path of its corresponding interface file,
 240   --    * the Module, decorated with it's properties
 241 \end{code}
 242
 243 (We allege that) it is quicker to build up a mapping from module names
 244 to the paths to their corresponding interface files once, than to search
 245 along the import part every time we slurp in a new module (which we
 246 do quite a lot of.)
 247
 248 \begin{code}
 249 type SearchPath = [(String,String)]     -- List of (directory,suffix) pairs to search
 250                                         -- for interface files.
 251
 252 mkModuleHiMaps :: SearchPath -> IO (ModuleHiMap, ModuleHiMap)
 253 mkModuleHiMaps dirs = foldM (getAllFilesMatching dirs) (env,env) dirs
 254  where
 255   env = emptyFM
 256
 257 {- A pseudo file, currently "dLL_ifs.hi",
 258    signals that the interface files
 259    contained in a particular directory have got their
 260    corresponding object codes stashed away in a DLL
 261
 262    This stuff is only needed to deal with Win32 DLLs,
 263    and conceivably we conditionally compile in support
 264    for handling it. (ToDo?)
 265 -}
 266 dir_contain_dll_his = "dLL_ifs.hi"
 267
 268 getAllFilesMatching :: SearchPath
 269                     -> (ModuleHiMap, ModuleHiMap)
 270                     -> (FilePath, String)
 271                     -> IO (ModuleHiMap, ModuleHiMap)
 272 getAllFilesMatching dirs hims (dir_path, suffix) = ( do
 273     -- fpaths entries do not have dir_path prepended
 274   fpaths  <- getDirectoryContents dir_path
 275   is_dll <- catch
 276                 (if opt_Static || dir_path == "." then
 277                      return NotDll
 278                  else
 279                      do  exists <- doesFileExist (dir_path ++ '/': dir_contain_dll_his)
 280                          return (if exists then Dll else NotDll)
 281                 )
 282                 (\ _ {-don't care-} -> return NotDll)
 283   return (foldl (addModules is_dll) hims fpaths)
 284   )  -- soft failure
 285       `catch`
 286         (\ err -> do
 287               hPutStrLn stderr
 288                      ("Import path element `" ++ dir_path ++
 289                       if (isDoesNotExistError err) then
 290                          "' does not exist, ignoring."
 291                       else
 292                         "' couldn't read, ignoring.")
 293
 294               return hims
 295         )
 296  where
 297
 298         -- Dreadfully crude.  We want a better way to distinguish
 299         -- "library-ish" modules.
 300    is_sys | head dir_path == '/' = LibMod
 301           | otherwise            = UserMod
 302
 303    xiffus        = reverse dotted_suffix
 304    dotted_suffix = case suffix of
 305                       []       -> []
 306                       ('.':xs) -> suffix
 307                       ls       -> '.':ls
 308
 309    hi_boot_version_xiffus =
 310       reverse (show interfaceFileFormatVersion) ++ '-':hi_boot_xiffus
 311    hi_boot_xiffus = "toob-ih." -- .hi-boot reversed!
 312
 313    addModules is_dll his@(hi_env, hib_env) filename = fromMaybe his $
 314         FMAP add_hi   (go xiffus                 rev_fname)     `seqMaybe`
 315
 316         FMAP add_vhib (go hi_boot_version_xiffus rev_fname)     `seqMaybe`
 317                 -- If there's a Foo.hi-boot-N file then override any Foo.hi-boot
 318
 319         FMAP add_hib  (go hi_boot_xiffus         rev_fname)
 320      where
 321         rev_fname = reverse filename
 322         path      = dir_path ++ '/':filename
 323
 324           -- In these functions file_nm is the base of the filename,
 325           -- with the path and suffix both stripped off.  The filename
 326           -- is the *unencoded* module name (else 'make' gets confused).
 327           -- But the domain of the HiMaps is ModuleName which is encoded.
 328         add_hi    file_nm = (add_to_map addNewOne hi_env file_nm,   hib_env)
 329         add_vhib  file_nm = (hi_env, add_to_map overrideNew hib_env file_nm)
 330         add_hib   file_nm = (hi_env, add_to_map addNewOne   hib_env file_nm)
 331
 332         add_to_map combiner env file_nm
 333           = addToFM_C combiner env mod_nm (path, mkModule mod_nm is_sys is_dll)
 334           where
 335             mod_nm = mkSrcModuleFS file_nm
 336
 337    -- go prefix (prefix ++ stuff) == Just (reverse stuff)
 338    go [] xs                     = Just (_PK_ (reverse xs))
 339    go _  []                     = Nothing
 340    go (x:xs) (y:ys) | x == y    = go xs ys
 341                     | otherwise = Nothing
 342
 343    addNewOne | opt_WarnHiShadows = conflict
 344              | otherwise         = stickWithOld
 345
 346    stickWithOld old new = old
 347    overrideNew  old new = new
 348
 349    conflict (old_path,mod) (new_path,_)
 350     | old_path /= new_path =
 351         pprTrace "Warning: " (text "Identically named interface files present on the import path, " $$
 352                               text (show old_path) <+> text "shadows" $$
 353                               text (show new_path) $$
 354                               text "on the import path: " <+>
 355                               text (concat (intersperse ":" (map fst dirs))))
 356         (old_path,mod)
 357     | otherwise = (old_path,mod)  -- don't warn about innocous shadowings.
 358 \end{code}
 359
 360
 361 %*********************************************************
 362 %*                                                       *
 363 \subsection{Making a search path}
 364 %*                                                       *
 365 %*********************************************************
 366
 367 @mkSearchPath@ takes a string consisting of a colon-separated list
 368 of directories and corresponding suffixes, and turns it into a list
 369 of (directory, suffix) pairs.  For example:
 370
 371 \begin{verbatim}
 372  mkSearchPath "foo%.hi:.%.p_hi:baz%.mc_hi"
 373    = [("foo",".hi"),( ".", ".p_hi"), ("baz",".mc_hi")]
 374 \begin{verbatim}
 375
 376 \begin{code}
 377 mkSearchPath :: Maybe String -> SearchPath
 378 mkSearchPath Nothing = [(".",".hi")]  -- ToDo: default should be to look in
 379                                       -- the directory the module we're compiling
 380                                       -- lives.
 381 mkSearchPath (Just s) = go s
 382   where
 383     go "" = []
 384     go s  =
 385       case span (/= '%') s of
 386        (dir,'%':rs) ->
 387          case span (/= ':') rs of
 388           (hisuf,_:rest) -> (dir,hisuf):go rest
 389           (hisuf,[])     -> [(dir,hisuf)]
 390 \end{code}
 391