ghc/compiler/basicTypes/OccName.lhs

   1 %
   2 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   3 %
   4
   5 \section[OccName]{@OccName@}
   6
   7 \begin{code}
   8 module OccName (
   9         -- The NameSpace type; abstact
  10         NameSpace, tcName, clsName, tcClsName, dataName, varName,
  11         tvName, nameSpaceString,
  12
  13         -- The OccName type
  14         OccName,        -- Abstract, instance of Outputable
  15         pprOccName,
  16
  17         mkOccFS, mkSysOcc, mkSysOccFS, mkFCallOcc, mkVarOcc, mkKindOccFS,
  18         mkSuperDictSelOcc, mkDFunOcc, mkForeignExportOcc,
  19         mkDictOcc, mkIPOcc, mkWorkerOcc, mkMethodOcc, mkDefaultMethodOcc,
  20         mkDerivedTyConOcc, mkClassTyConOcc, mkClassDataConOcc, mkSpecOcc,
  21         mkGenOcc1, mkGenOcc2,
  22
  23         isTvOcc, isDataOcc, isDataSymOcc, isSymOcc, isValOcc,
  24
  25         occNameFS, occNameString, occNameUserString, occNameSpace, occNameFlavour,
  26         setOccNameSpace,
  27
  28         -- Tidying up
  29         TidyOccEnv, emptyTidyOccEnv, tidyOccName, initTidyOccEnv,
  30
  31         -- Encoding
  32         EncodedString, EncodedFS, UserString, UserFS, encode, encodeFS, decode, pprEncodedFS,
  33
  34         -- The basic form of names
  35         isLexCon, isLexVar, isLexId, isLexSym,
  36         isLexConId, isLexConSym, isLexVarId, isLexVarSym,
  37         isLowerISO, isUpperISO
  38
  39     ) where
  40
  41 #include "HsVersions.h"
  42
  43 import Char     ( isDigit, isUpper, isLower, ISALPHANUM, ord, chr, digitToInt )
  44 import Util     ( thenCmp )
  45 import FiniteMap ( FiniteMap, emptyFM, lookupFM, addToFM, elemFM )
  46 import Outputable
  47 import GlaExts
  48 \end{code}
  49
  50 We hold both module names and identifier names in a 'Z-encoded' form
  51 that makes them acceptable both as a C identifier and as a Haskell
  52 (prefix) identifier.
  53
  54 They can always be decoded again when printing error messages
  55 or anything else for the user, but it does make sense for it
  56 to be represented here in encoded form, so that when generating
  57 code the encoding operation is not performed on each occurrence.
  58
  59 These type synonyms help documentation.
  60
  61 \begin{code}
  62 type UserFS    = FAST_STRING    -- As the user typed it
  63 type EncodedFS = FAST_STRING    -- Encoded form
  64
  65 type UserString = String        -- As the user typed it
  66 type EncodedString = String     -- Encoded form
  67
  68
  69 pprEncodedFS :: EncodedFS -> SDoc
  70 pprEncodedFS fs
  71   = getPprStyle         $ \ sty ->
  72     if userStyle sty
  73         -- ptext (decodeFS fs) would needlessly pack the string again
  74         then text (decode (_UNPK_ fs))
  75         else ptext fs
  76 \end{code}
  77
  78 %************************************************************************
  79 %*                                                                      *
  80 \subsection{Name space}
  81 %*                                                                      *
  82 %************************************************************************
  83
  84 \begin{code}
  85 data NameSpace = VarName        -- Variables
  86                | DataName       -- Data constructors
  87                | TvName         -- Type variables
  88                | TcClsName      -- Type constructors and classes; Haskell has them
  89                                 -- in the same name space for now.
  90                deriving( Eq, Ord )
  91
  92 -- Though type constructors and classes are in the same name space now,
  93 -- the NameSpace type is abstract, so we can easily separate them later
  94 tcName    = TcClsName           -- Type constructors
  95 clsName   = TcClsName           -- Classes
  96 tcClsName = TcClsName           -- Not sure which!
  97
  98 dataName = DataName
  99 tvName   = TvName
 100 varName  = VarName
 101
 102
 103 nameSpaceString :: NameSpace -> String
 104 nameSpaceString DataName  = "Data constructor"
 105 nameSpaceString VarName   = "Variable"
 106 nameSpaceString TvName    = "Type variable"
 107 nameSpaceString TcClsName = "Type constructor or class"
 108 \end{code}
 109
 110
 111 %************************************************************************
 112 %*                                                                      *
 113 \subsection[Name-pieces-datatypes]{The @OccName@ datatypes}
 114 %*                                                                      *
 115 %************************************************************************
 116
 117 \begin{code}
 118 data OccName = OccName
 119                         NameSpace
 120                         EncodedFS
 121 \end{code}
 122
 123
 124 \begin{code}
 125 instance Eq OccName where
 126     (OccName sp1 s1) == (OccName sp2 s2) = s1 == s2 && sp1 == sp2
 127
 128 instance Ord OccName where
 129     compare (OccName sp1 s1) (OccName sp2 s2) = (s1  `compare` s2) `thenCmp`
 130                                                 (sp1 `compare` sp2)
 131 \end{code}
 132
 133
 134 %************************************************************************
 135 %*                                                                      *
 136 \subsection{Printing}
 137 %*                                                                      *
 138 %************************************************************************
 139
 140 \begin{code}
 141 instance Outputable OccName where
 142     ppr = pprOccName
 143
 144 pprOccName :: OccName -> SDoc
 145 pprOccName (OccName sp occ) = pprEncodedFS occ
 146 \end{code}
 147
 148
 149 %************************************************************************
 150 %*                                                                      *
 151 \subsection{Construction}
 152 %*                                                                      *
 153 %************************************************************************
 154
 155 *Sys* things do no encoding; the caller should ensure that the thing is
 156 already encoded
 157
 158 \begin{code}
 159 mkSysOcc :: NameSpace -> EncodedString -> OccName
 160 mkSysOcc occ_sp str = ASSERT2( alreadyEncoded str, text str )
 161                       OccName occ_sp (_PK_ str)
 162
 163 mkSysOccFS :: NameSpace -> EncodedFS -> OccName
 164 mkSysOccFS occ_sp fs = ASSERT2( alreadyEncodedFS fs, ppr fs )
 165                        OccName occ_sp fs
 166
 167 mkFCallOcc :: EncodedString -> OccName
 168 -- This version of mkSysOcc doesn't check that the string is already encoded,
 169 -- because it will be something like "{__ccall f dyn Int# -> Int#}"
 170 -- This encodes a lot into something that then parses like an Id.
 171 -- But then alreadyEncoded complains about the braces!
 172 mkFCallOcc str = OccName varName (_PK_ str)
 173
 174 -- Kind constructors get a special function.  Uniquely, they are not encoded,
 175 -- so that they have names like '*'.  This means that *even in interface files*
 176 -- we'll get kinds like (* -> (* -> *)).  We can't use mkSysOcc because it
 177 -- has an ASSERT that doesn't hold.
 178 mkKindOccFS :: NameSpace -> EncodedFS -> OccName
 179 mkKindOccFS occ_sp fs = OccName occ_sp fs
 180 \end{code}
 181
 182 *Source-code* things are encoded.
 183
 184 \begin{code}
 185 mkOccFS :: NameSpace -> UserFS -> OccName
 186 mkOccFS occ_sp fs = mkSysOccFS occ_sp (encodeFS fs)
 187
 188 mkVarOcc :: UserFS -> OccName
 189 mkVarOcc fs = mkSysOccFS varName (encodeFS fs)
 190 \end{code}
 191
 192
 193
 194 %************************************************************************
 195 %*                                                                      *
 196 \subsection{Predicates and taking them apart}
 197 %*                                                                      *
 198 %************************************************************************
 199
 200 \begin{code}
 201 occNameFS :: OccName -> EncodedFS
 202 occNameFS (OccName _ s) = s
 203
 204 occNameString :: OccName -> EncodedString
 205 occNameString (OccName _ s) = _UNPK_ s
 206
 207 occNameUserString :: OccName -> UserString
 208 occNameUserString occ = decode (occNameString occ)
 209
 210 occNameSpace :: OccName -> NameSpace
 211 occNameSpace (OccName sp _) = sp
 212
 213 setOccNameSpace :: OccName -> NameSpace -> OccName
 214 setOccNameSpace (OccName _ occ) sp = OccName sp occ
 215
 216 -- occNameFlavour is used only to generate good error messages
 217 occNameFlavour :: OccName -> String
 218 occNameFlavour (OccName sp _) = nameSpaceString sp
 219 \end{code}
 220
 221 \begin{code}
 222 isTvOcc, isDataSymOcc, isSymOcc :: OccName -> Bool
 223
 224 isTvOcc (OccName TvName _) = True
 225 isTvOcc other              = False
 226
 227 isValOcc (OccName VarName  _) = True
 228 isValOcc (OccName DataName _) = True
 229 isValOcc other                = False
 230
 231 -- Data constructor operator (starts with ':', or '[]')
 232 -- Pretty inefficient!
 233 isDataSymOcc (OccName DataName s) = isLexConSym (decodeFS s)
 234 isDataSymOcc other                = False
 235
 236 isDataOcc (OccName DataName _) = True
 237 isDataOcc other                = False
 238
 239 -- Any operator (data constructor or variable)
 240 -- Pretty inefficient!
 241 isSymOcc (OccName DataName s) = isLexConSym (decodeFS s)
 242 isSymOcc (OccName VarName s)  = isLexSym (decodeFS s)
 243 \end{code}
 244
 245
 246 %************************************************************************
 247 %*                                                                      *
 248 \subsection{Making system names}
 249 %*                                                                      *
 250 %************************************************************************
 251
 252 Here's our convention for splitting up the interface file name space:
 253
 254         d...            dictionary identifiers
 255                         (local variables, so no name-clash worries)
 256
 257         $f...           dict-fun identifiers (from inst decls)
 258         $dm...          default methods
 259         $p...           superclass selectors
 260         $w...           workers
 261         $T...           compiler-generated tycons for dictionaries
 262         $D...           ...ditto data cons
 263         $sf..           specialised version of f
 264
 265         in encoded form these appear as Zdfxxx etc
 266
 267         :...            keywords (export:, letrec: etc.)
 268
 269 This knowledge is encoded in the following functions.
 270
 271
 272 @mk_deriv@ generates an @OccName@ from the one-char prefix and a string.
 273 NB: The string must already be encoded!
 274
 275 \begin{code}
 276 mk_deriv :: NameSpace
 277          -> String              -- Distinguishes one sort of derived name from another
 278          -> EncodedString       -- Must be already encoded!!  We don't want to encode it a
 279                                 -- second time because encoding isn't itempotent
 280          -> OccName
 281
 282 mk_deriv occ_sp sys_prefix str = mkSysOcc occ_sp (encode sys_prefix ++ str)
 283 \end{code}
 284
 285 \begin{code}
 286 mkDictOcc, mkIPOcc, mkWorkerOcc, mkDefaultMethodOcc,
 287            mkClassTyConOcc, mkClassDataConOcc, mkSpecOcc
 288    :: OccName -> OccName
 289
 290 -- These derived variables have a prefix that no Haskell value could have
 291 mkWorkerOcc        = mk_simple_deriv varName  "$w"
 292 mkDefaultMethodOcc = mk_simple_deriv varName  "$dm"
 293 mkDerivedTyConOcc  = mk_simple_deriv tcName   ":"       -- The : prefix makes sure it classifies
 294 mkClassTyConOcc    = mk_simple_deriv tcName   ":T"      -- as a tycon/datacon
 295 mkClassDataConOcc  = mk_simple_deriv dataName ":D"      --
 296 mkDictOcc          = mk_simple_deriv varName  "$d"
 297 mkIPOcc            = mk_simple_deriv varName  "$i"
 298 mkSpecOcc          = mk_simple_deriv varName  "$s"
 299 mkForeignExportOcc = mk_simple_deriv varName  "$f"
 300 mkGenOcc1           = mk_simple_deriv varName  "$gfrom"      -- Generics
 301 mkGenOcc2           = mk_simple_deriv varName  "$gto"        -- Generics
 302 mk_simple_deriv sp px occ = mk_deriv sp px (occNameString occ)
 303 \end{code}
 304
 305 \begin{code}
 306 mkSuperDictSelOcc :: Int        -- Index of superclass, eg 3
 307                   -> OccName    -- Class, eg "Ord"
 308                   -> OccName    -- eg "p3Ord"
 309 mkSuperDictSelOcc index cls_occ
 310   = mk_deriv varName "$p" (show index ++ occNameString cls_occ)
 311 \end{code}
 312
 313
 314 \begin{code}
 315 mkDFunOcc :: EncodedString      -- Typically the class and type glommed together e.g. "OrdMaybe"
 316           -> OccName            -- "$fOrdMaybe"
 317
 318 mkDFunOcc string = mk_deriv VarName "$f" string
 319 \end{code}
 320
 321 We used to add a '$m' to indicate a method, but that gives rise to bad
 322 error messages from the type checker when we print the function name or pattern
 323 of an instance-decl binding.  Why? Because the binding is zapped
 324 to use the method name in place of the selector name.
 325 (See TcClassDcl.tcMethodBind)
 326
 327 The way it is now, -ddump-xx output may look confusing, but
 328 you can always say -dppr-debug to get the uniques.
 329
 330 However, we *do* have to zap the first character to be lower case,
 331 because overloaded constructors (blarg) generate methods too.
 332 And convert to VarName space
 333
 334 e.g. a call to constructor MkFoo where
 335         data (Ord a) => Foo a = MkFoo a
 336
 337 If this is necessary, we do it by prefixing '$m'.  These
 338 guys never show up in error messages.  What a hack.
 339
 340 \begin{code}
 341 mkMethodOcc :: OccName -> OccName
 342 mkMethodOcc occ@(OccName VarName fs) = occ
 343 mkMethodOcc occ                      = mk_simple_deriv varName "$m" occ
 344 \end{code}
 345
 346
 347 %************************************************************************
 348 %*                                                                      *
 349 \subsection{Tidying them up}
 350 %*                                                                      *
 351 %************************************************************************
 352
 353 Before we print chunks of code we like to rename it so that
 354 we don't have to print lots of silly uniques in it.  But we mustn't
 355 accidentally introduce name clashes!  So the idea is that we leave the
 356 OccName alone unless it accidentally clashes with one that is already
 357 in scope; if so, we tack on '1' at the end and try again, then '2', and
 358 so on till we find a unique one.
 359
 360 There's a wrinkle for operators.  Consider '>>='.  We can't use '>>=1'
 361 because that isn't a single lexeme.  So we encode it to 'lle' and *then*
 362 tack on the '1', if necessary.
 363
 364 \begin{code}
 365 type TidyOccEnv = FiniteMap FAST_STRING Int     -- The in-scope OccNames
 366 emptyTidyOccEnv = emptyFM
 367
 368 initTidyOccEnv :: [OccName] -> TidyOccEnv       -- Initialise with names to avoid!
 369 initTidyOccEnv = foldl (\env (OccName _ fs) -> addToFM env fs 1) emptyTidyOccEnv
 370
 371 tidyOccName :: TidyOccEnv -> OccName -> (TidyOccEnv, OccName)
 372
 373 tidyOccName in_scope occ@(OccName occ_sp fs)
 374   | not (fs `elemFM` in_scope)
 375   = (addToFM in_scope fs 1, occ)        -- First occurrence
 376
 377   | otherwise                           -- Already occurs
 378   = go in_scope (_UNPK_ fs)
 379   where
 380
 381     go in_scope str = case lookupFM in_scope pk_str of
 382                         Just n  -> go (addToFM in_scope pk_str (n+1)) (str ++ show n)
 383                                 -- Need to go round again, just in case "t3" (say)
 384                                 -- clashes with a "t3" that's already in scope
 385
 386                         Nothing -> (addToFM in_scope pk_str 1, mkSysOccFS occ_sp pk_str)
 387                                 -- str is now unique
 388                     where
 389                       pk_str = _PK_ str
 390 \end{code}
 391
 392
 393 %************************************************************************
 394 %*                                                                      *
 395 \subsection{The 'Z' encoding}
 396 %*                                                                      *
 397 %************************************************************************
 398
 399 This is the main name-encoding and decoding function.  It encodes any
 400 string into a string that is acceptable as a C name.  This is the name
 401 by which things are known right through the compiler.
 402
 403 The basic encoding scheme is this.
 404
 405 * Tuples (,,,) are coded as Z3T
 406
 407 * Alphabetic characters (upper and lower) and digits
 408         all translate to themselves;
 409         except 'Z', which translates to 'ZZ'
 410         and    'z', which translates to 'zz'
 411   We need both so that we can preserve the variable/tycon distinction
 412
 413 * Most other printable characters translate to 'zx' or 'Zx' for some
 414         alphabetic character x
 415
 416 * The others translate as 'znnnU' where 'nnn' is the decimal number
 417         of the character
 418
 419         Before          After
 420         --------------------------
 421         Trak            Trak
 422         foo_wib         foozuwib
 423         >               zg
 424         >1              zg1
 425         foo#            foozh
 426         foo##           foozhzh
 427         foo##1          foozhzh1
 428         fooZ            fooZZ
 429         :+              Zczp
 430         ()              Z0T
 431         (,,,,)          Z4T     5-tuple
 432         (#,,,,#)        Z4H     unboxed 5-tuple
 433                 (NB: the number is one different to the number of
 434                 elements.  No real reason except that () is a zero-tuple,
 435                 while (,) is a 2-tuple.)
 436
 437 \begin{code}
 438 -- alreadyEncoded is used in ASSERTs to check for encoded
 439 -- strings.  It isn't fail-safe, of course, because, say 'zh' might
 440 -- be encoded or not.
 441 alreadyEncoded :: String -> Bool
 442 alreadyEncoded s = all ok s
 443                  where
 444                    ok ' ' = True
 445                         -- This is a bit of a lie; if we really wanted spaces
 446                         -- in names we'd have to encode them.  But we do put
 447                         -- spaces in ccall "occurrences", and we don't want to
 448                         -- reject them here
 449                    ok ch  = ISALPHANUM ch
 450
 451 alreadyEncodedFS :: FAST_STRING -> Bool
 452 alreadyEncodedFS fs = alreadyEncoded (_UNPK_ fs)
 453
 454 encode :: UserString -> EncodedString
 455 encode cs = case maybe_tuple cs of
 456                 Just n  -> n            -- Tuples go to Z2T etc
 457                 Nothing -> go cs
 458           where
 459                 go []     = []
 460                 go (c:cs) = encode_ch c ++ go cs
 461
 462 maybe_tuple ('(' : '#' : cs) = case count_commas (0::Int) cs of
 463                                  (n, '#' : ')' : cs) -> Just ('Z' : shows n "H")
 464                                  other               -> Nothing
 465 maybe_tuple ('(' : cs)       = case count_commas (0::Int) cs of
 466                                  (n, ')' : cs) -> Just ('Z' : shows n "T")
 467                                  other         -> Nothing
 468 maybe_tuple other            = Nothing
 469
 470 count_commas :: Int -> String -> (Int, String)
 471 count_commas n (',' : cs) = count_commas (n+1) cs
 472 count_commas n cs         = (n,cs)
 473
 474 encodeFS :: UserFS -> EncodedFS
 475 encodeFS fast_str  | all unencodedChar str = fast_str
 476                    | otherwise             = _PK_ (encode str)
 477                    where
 478                      str = _UNPK_ fast_str
 479
 480 unencodedChar :: Char -> Bool   -- True for chars that don't need encoding
 481 unencodedChar 'Z' = False
 482 unencodedChar 'z' = False
 483 unencodedChar c   = ISALPHANUM c
 484
 485 encode_ch :: Char -> EncodedString
 486 encode_ch c | unencodedChar c = [c]     -- Common case first
 487
 488 -- Constructors
 489 encode_ch '('  = "ZL"   -- Needed for things like (,), and (->)
 490 encode_ch ')'  = "ZR"   -- For symmetry with (
 491 encode_ch '['  = "ZM"
 492 encode_ch ']'  = "ZN"
 493 encode_ch ':'  = "ZC"
 494 encode_ch 'Z'  = "ZZ"
 495
 496 -- Variables
 497 encode_ch 'z'  = "zz"
 498 encode_ch '&'  = "za"
 499 encode_ch '|'  = "zb"
 500 encode_ch '^'  = "zc"
 501 encode_ch '$'  = "zd"
 502 encode_ch '='  = "ze"
 503 encode_ch '>'  = "zg"
 504 encode_ch '#'  = "zh"
 505 encode_ch '.'  = "zi"
 506 encode_ch '<'  = "zl"
 507 encode_ch '-'  = "zm"
 508 encode_ch '!'  = "zn"
 509 encode_ch '+'  = "zp"
 510 encode_ch '\'' = "zq"
 511 encode_ch '\\' = "zr"
 512 encode_ch '/'  = "zs"
 513 encode_ch '*'  = "zt"
 514 encode_ch '_'  = "zu"
 515 encode_ch '%'  = "zv"
 516 encode_ch c    = 'z' : shows (ord c) "U"
 517 \end{code}
 518
 519 Decode is used for user printing.
 520
 521 \begin{code}
 522 decodeFS :: FAST_STRING -> FAST_STRING
 523 decodeFS fs = _PK_ (decode (_UNPK_ fs))
 524
 525 decode :: EncodedString -> UserString
 526 decode [] = []
 527 decode ('Z' : rest) = decode_escape rest
 528 decode ('z' : rest) = decode_escape rest
 529 decode (c   : rest) = c : decode rest
 530
 531 decode_escape :: EncodedString -> UserString
 532
 533 decode_escape ('L' : rest) = '(' : decode rest
 534 decode_escape ('R' : rest) = ')' : decode rest
 535 decode_escape ('M' : rest) = '[' : decode rest
 536 decode_escape ('N' : rest) = ']' : decode rest
 537 decode_escape ('C' : rest) = ':' : decode rest
 538 decode_escape ('Z' : rest) = 'Z' : decode rest
 539
 540 decode_escape ('z' : rest) = 'z' : decode rest
 541 decode_escape ('a' : rest) = '&' : decode rest
 542 decode_escape ('b' : rest) = '|' : decode rest
 543 decode_escape ('c' : rest) = '^' : decode rest
 544 decode_escape ('d' : rest) = '$' : decode rest
 545 decode_escape ('e' : rest) = '=' : decode rest
 546 decode_escape ('g' : rest) = '>' : decode rest
 547 decode_escape ('h' : rest) = '#' : decode rest
 548 decode_escape ('i' : rest) = '.' : decode rest
 549 decode_escape ('l' : rest) = '<' : decode rest
 550 decode_escape ('m' : rest) = '-' : decode rest
 551 decode_escape ('n' : rest) = '!' : decode rest
 552 decode_escape ('p' : rest) = '+' : decode rest
 553 decode_escape ('q' : rest) = '\'' : decode rest
 554 decode_escape ('r' : rest) = '\\' : decode rest
 555 decode_escape ('s' : rest) = '/' : decode rest
 556 decode_escape ('t' : rest) = '*' : decode rest
 557 decode_escape ('u' : rest) = '_' : decode rest
 558 decode_escape ('v' : rest) = '%' : decode rest
 559
 560 -- Tuples are coded as Z23T
 561 -- Characters not having a specific code are coded as z224U
 562 decode_escape (c : rest)
 563   | isDigit c = go (digitToInt c) rest
 564   where
 565     go n (c : rest) | isDigit c = go (10*n + digitToInt c) rest
 566     go n ('T' : rest)           = '(' : replicate n ',' ++ ')' : decode rest
 567     go n ('H' : rest)           = '(' : '#' : replicate n ',' ++ '#' : ')' : decode rest
 568     go n ('U' : rest)           = chr n : decode rest
 569     go n other = pprPanic "decode_escape" (ppr n <+> text (c:rest))
 570
 571 decode_escape (c : rest) = pprTrace "decode_escape" (char c) (decode rest)
 572 \end{code}
 573
 574
 575 %************************************************************************
 576 %*                                                                      *
 577 n\subsection{Lexical categories}
 578 %*                                                                      *
 579 %************************************************************************
 580
 581 These functions test strings to see if they fit the lexical categories
 582 defined in the Haskell report.
 583
 584 \begin{code}
 585 isLexCon,   isLexVar,    isLexId,    isLexSym    :: FAST_STRING -> Bool
 586 isLexConId, isLexConSym, isLexVarId, isLexVarSym :: FAST_STRING -> Bool
 587
 588 isLexCon cs = isLexConId  cs || isLexConSym cs
 589 isLexVar cs = isLexVarId  cs || isLexVarSym cs
 590
 591 isLexId  cs = isLexConId  cs || isLexVarId  cs
 592 isLexSym cs = isLexConSym cs || isLexVarSym cs
 593
 594 -------------
 595
 596 isLexConId cs                           -- Prefix type or data constructors
 597   | _NULL_ cs        = False            --      e.g. "Foo", "[]", "(,)"
 598   | cs == SLIT("[]") = True
 599   | otherwise        = startsConId (_HEAD_ cs)
 600
 601 isLexVarId cs                           -- Ordinary prefix identifiers
 602   | _NULL_ cs    = False                --      e.g. "x", "_x"
 603   | otherwise    = startsVarId (_HEAD_ cs)
 604
 605 isLexConSym cs                          -- Infix type or data constructors
 606   | _NULL_ cs   = False                 --      e.g. ":-:", ":", "->"
 607   | cs == SLIT("->") = True
 608   | otherwise   = startsConSym (_HEAD_ cs)
 609
 610 isLexVarSym cs                          -- Infix identifiers
 611   | _NULL_ cs = False                   --      e.g. "+"
 612   | otherwise = startsVarSym (_HEAD_ cs)
 613
 614 -------------
 615 startsVarSym, startsVarId, startsConSym, startsConId :: Char -> Bool
 616 startsVarSym c = isSymbolASCII c || isSymbolISO c       -- Infix Ids
 617 startsConSym c = c == ':'                               -- Infix data constructors
 618 startsVarId c  = isLower c || isLowerISO c || c == '_'  -- Ordinary Ids
 619 startsConId c  = isUpper c || isUpperISO c || c == '('  -- Ordinary type constructors and data constructors
 620
 621
 622 isSymbolASCII c = c `elem` "!#$%&*+./<=>?@\\^|~-"
 623 isSymbolISO   c = ord c `elem` (0xd7 : 0xf7 : [0xa1 .. 0xbf])
 624 isUpperISO    (C# c#) = c# `geChar#` '\xc0'# && c# `leChar#` '\xde'# && c# `neChar#` '\xd7'#
 625         --0xc0 <= oc && oc <= 0xde && oc /= 0xd7 where oc = ord c
 626 isLowerISO    (C# c#) = c# `geChar#` '\xdf'# && c# `leChar#` '\xff'# && c# `neChar#` '\xf7'#
 627         --0xdf <= oc && oc <= 0xff && oc /= 0xf7 where oc = ord c
 628 \end{code}