ghc/compiler/basicTypes/UniqSupply.lhs

   1 %
   2 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   3 %
   4 \section[UniqSupply]{The @UniqueSupply@ data type and a (monadic) supply thereof}
   5
   6 \begin{code}
   7 module UniqSupply (
   8
   9         UniqSupply,             -- Abstractly
  10
  11         uniqFromSupply, uniqsFromSupply,        -- basic ops
  12
  13         UniqSM,         -- type: unique supply monad
  14         initUs, initUs_, thenUs, thenUs_, returnUs, fixUs, getUs, withUs,
  15         getUniqueUs, getUniquesUs,
  16         mapUs, mapAndUnzipUs, mapAndUnzip3Us,
  17         thenMaybeUs, mapAccumLUs,
  18         lazyThenUs, lazyMapUs,
  19
  20         mkSplitUniqSupply,
  21         splitUniqSupply
  22   ) where
  23
  24 #include "HsVersions.h"
  25
  26 import Unique
  27
  28 import GLAEXTS
  29 import UNSAFE_IO        ( unsafeInterleaveIO )
  30
  31 w2i x = word2Int# x
  32 i2w x = int2Word# x
  33 i2w_s x = (x :: Int#)
  34 \end{code}
  35
  36
  37 %************************************************************************
  38 %*                                                                      *
  39 \subsection{Splittable Unique supply: @UniqSupply@}
  40 %*                                                                      *
  41 %************************************************************************
  42
  43 A value of type @UniqSupply@ is unique, and it can
  44 supply {\em one} distinct @Unique@.  Also, from the supply, one can
  45 also manufacture an arbitrary number of further @UniqueSupplies@,
  46 which will be distinct from the first and from all others.
  47
  48 \begin{code}
  49 data UniqSupply
  50   = MkSplitUniqSupply Int       -- make the Unique with this
  51                    UniqSupply UniqSupply
  52                                 -- when split => these two supplies
  53 \end{code}
  54
  55 \begin{code}
  56 mkSplitUniqSupply :: Char -> IO UniqSupply
  57
  58 splitUniqSupply :: UniqSupply -> (UniqSupply, UniqSupply)
  59 uniqFromSupply  :: UniqSupply -> Unique
  60 uniqsFromSupply :: UniqSupply -> [Unique]       -- Infinite
  61 \end{code}
  62
  63 \begin{code}
  64 mkSplitUniqSupply (C# c#)
  65   = let
  66 #if __GLASGOW_HASKELL__ >= 503
  67         mask# = (i2w (ord# c#)) `uncheckedShiftL#` (i2w_s 24#)
  68 #else
  69         mask# = (i2w (ord# c#)) `shiftL#` (i2w_s 24#)
  70 #endif
  71         -- here comes THE MAGIC:
  72
  73         -- This is one of the most hammered bits in the whole compiler
  74         mk_supply#
  75           = unsafeInterleaveIO (
  76                 mk_unique   >>= \ uniq ->
  77                 mk_supply#  >>= \ s1 ->
  78                 mk_supply#  >>= \ s2 ->
  79                 return (MkSplitUniqSupply uniq s1 s2)
  80             )
  81
  82         mk_unique = _ccall_ genSymZh            >>= \ (W# u#) ->
  83                     return (I# (w2i (mask# `or#` u#)))
  84     in
  85     mk_supply#
  86
  87 splitUniqSupply (MkSplitUniqSupply _ s1 s2) = (s1, s2)
  88 \end{code}
  89
  90 \begin{code}
  91 uniqFromSupply  (MkSplitUniqSupply (I# n) _ _)  = mkUniqueGrimily n
  92 uniqsFromSupply (MkSplitUniqSupply (I# n) _ s2) = mkUniqueGrimily n : uniqsFromSupply s2
  93 \end{code}
  94
  95 %************************************************************************
  96 %*                                                                      *
  97 \subsubsection[UniqSupply-monad]{@UniqSupply@ monad: @UniqSM@}
  98 %*                                                                      *
  99 %************************************************************************
 100
 101 \begin{code}
 102 type UniqSM result = UniqSupply -> (result, UniqSupply)
 103
 104 -- the initUs function also returns the final UniqSupply; initUs_ drops it
 105 initUs :: UniqSupply -> UniqSM a -> (a,UniqSupply)
 106 initUs init_us m = case m init_us of { (r,us) -> (r,us) }
 107
 108 initUs_ :: UniqSupply -> UniqSM a -> a
 109 initUs_ init_us m = case m init_us of { (r,us) -> r }
 110
 111 {-# INLINE thenUs #-}
 112 {-# INLINE lazyThenUs #-}
 113 {-# INLINE returnUs #-}
 114 {-# INLINE splitUniqSupply #-}
 115 \end{code}
 116
 117 @thenUs@ is where we split the @UniqSupply@.
 118 \begin{code}
 119 fixUs :: (a -> UniqSM a) -> UniqSM a
 120 fixUs m us
 121   = (r,us')  where  (r,us') = m r us
 122
 123 thenUs :: UniqSM a -> (a -> UniqSM b) -> UniqSM b
 124 thenUs expr cont us
 125   = case (expr us) of { (result, us') -> cont result us' }
 126
 127 lazyThenUs :: UniqSM a -> (a -> UniqSM b) -> UniqSM b
 128 lazyThenUs expr cont us
 129   = let (result, us') = expr us in cont result us'
 130
 131 thenUs_ :: UniqSM a -> UniqSM b -> UniqSM b
 132 thenUs_ expr cont us
 133   = case (expr us) of { (_, us') -> cont us' }
 134
 135
 136 returnUs :: a -> UniqSM a
 137 returnUs result us = (result, us)
 138
 139 withUs :: (UniqSupply -> (a, UniqSupply)) -> UniqSM a
 140 withUs f us = f us      -- Ha ha!
 141
 142 getUs :: UniqSM UniqSupply
 143 getUs us = splitUniqSupply us
 144
 145 getUniqueUs :: UniqSM Unique
 146 getUniqueUs us = case splitUniqSupply us of
 147                    (us1,us2) -> (uniqFromSupply us1, us2)
 148
 149 getUniquesUs :: UniqSM [Unique]
 150 getUniquesUs us = case splitUniqSupply us of
 151                       (us1,us2) -> (uniqsFromSupply us1, us2)
 152 \end{code}
 153
 154 \begin{code}
 155 mapUs :: (a -> UniqSM b) -> [a] -> UniqSM [b]
 156 mapUs f []     = returnUs []
 157 mapUs f (x:xs)
 158   = f x         `thenUs` \ r  ->
 159     mapUs f xs  `thenUs` \ rs ->
 160     returnUs (r:rs)
 161
 162 lazyMapUs :: (a -> UniqSM b) -> [a] -> UniqSM [b]
 163 lazyMapUs f []     = returnUs []
 164 lazyMapUs f (x:xs)
 165   = f x             `lazyThenUs` \ r  ->
 166     lazyMapUs f xs  `lazyThenUs` \ rs ->
 167     returnUs (r:rs)
 168
 169 mapAndUnzipUs  :: (a -> UniqSM (b,c))   -> [a] -> UniqSM ([b],[c])
 170 mapAndUnzip3Us :: (a -> UniqSM (b,c,d)) -> [a] -> UniqSM ([b],[c],[d])
 171
 172 mapAndUnzipUs f [] = returnUs ([],[])
 173 mapAndUnzipUs f (x:xs)
 174   = f x                 `thenUs` \ (r1,  r2)  ->
 175     mapAndUnzipUs f xs  `thenUs` \ (rs1, rs2) ->
 176     returnUs (r1:rs1, r2:rs2)
 177
 178 mapAndUnzip3Us f [] = returnUs ([],[],[])
 179 mapAndUnzip3Us f (x:xs)
 180   = f x                 `thenUs` \ (r1,  r2,  r3)  ->
 181     mapAndUnzip3Us f xs `thenUs` \ (rs1, rs2, rs3) ->
 182     returnUs (r1:rs1, r2:rs2, r3:rs3)
 183
 184 thenMaybeUs :: UniqSM (Maybe a) -> (a -> UniqSM (Maybe b)) -> UniqSM (Maybe b)
 185 thenMaybeUs m k
 186   = m   `thenUs` \ result ->
 187     case result of
 188       Nothing -> returnUs Nothing
 189       Just x  -> k x
 190
 191 mapAccumLUs :: (acc -> x -> UniqSM (acc, y))
 192             -> acc
 193             -> [x]
 194             -> UniqSM (acc, [y])
 195
 196 mapAccumLUs f b []     = returnUs (b, [])
 197 mapAccumLUs f b (x:xs)
 198   = f b x                           `thenUs` \ (b__2, x__2) ->
 199     mapAccumLUs f b__2 xs           `thenUs` \ (b__3, xs__2) ->
 200     returnUs (b__3, x__2:xs__2)
 201 \end{code}