ghc/compiler/cmm/CmmParse.y

   1 -----------------------------------------------------------------------------
   2 --
   3 -- (c) The University of Glasgow, 2004
   4 --
   5 -- Parser for concrete Cmm.
   6 --
   7 -----------------------------------------------------------------------------
   8
   9 {
  10 module CmmParse ( parseCmmFile ) where
  11
  12 import CgMonad
  13 import CgHeapery
  14 import CgUtils
  15 import CgProf
  16 import CgTicky
  17 import CgInfoTbls
  18 import CgForeignCall
  19 import CgTailCall       ( pushUnboxedTuple )
  20 import CgStackery       ( emitPushUpdateFrame )
  21 import ClosureInfo      ( C_SRT(..) )
  22 import CgCallConv       ( smallLiveness )
  23 import CgClosure        ( emitBlackHoleCode )
  24 import CostCentre       ( dontCareCCS )
  25
  26 import Cmm
  27 import PprCmm
  28 import CmmUtils         ( mkIntCLit )
  29 import CmmLex
  30 import CLabel
  31 import MachOp
  32 import SMRep            ( fixedHdrSize, CgRep(..) )
  33 import Lexer
  34
  35 import ForeignCall      ( CCallConv(..), Safety(..) )
  36 import Literal          ( mkMachInt )
  37 import Unique
  38 import UniqFM
  39 import SrcLoc
  40 import DynFlags         ( DynFlags, DynFlag(..) )
  41 import Packages         ( HomeModules )
  42 import StaticFlags      ( opt_SccProfilingOn )
  43 import ErrUtils         ( printError, dumpIfSet_dyn, showPass )
  44 import StringBuffer     ( hGetStringBuffer )
  45 import FastString
  46 import Panic            ( panic )
  47 import Constants        ( wORD_SIZE )
  48 import Outputable
  49
  50 import Monad            ( when )
  51 import Data.Char        ( ord )
  52
  53 #include "HsVersions.h"
  54 }
  55
  56 %token
  57         ':'     { L _ (CmmT_SpecChar ':') }
  58         ';'     { L _ (CmmT_SpecChar ';') }
  59         '{'     { L _ (CmmT_SpecChar '{') }
  60         '}'     { L _ (CmmT_SpecChar '}') }
  61         '['     { L _ (CmmT_SpecChar '[') }
  62         ']'     { L _ (CmmT_SpecChar ']') }
  63         '('     { L _ (CmmT_SpecChar '(') }
  64         ')'     { L _ (CmmT_SpecChar ')') }
  65         '='     { L _ (CmmT_SpecChar '=') }
  66         '`'     { L _ (CmmT_SpecChar '`') }
  67         '~'     { L _ (CmmT_SpecChar '~') }
  68         '/'     { L _ (CmmT_SpecChar '/') }
  69         '*'     { L _ (CmmT_SpecChar '*') }
  70         '%'     { L _ (CmmT_SpecChar '%') }
  71         '-'     { L _ (CmmT_SpecChar '-') }
  72         '+'     { L _ (CmmT_SpecChar '+') }
  73         '&'     { L _ (CmmT_SpecChar '&') }
  74         '^'     { L _ (CmmT_SpecChar '^') }
  75         '|'     { L _ (CmmT_SpecChar '|') }
  76         '>'     { L _ (CmmT_SpecChar '>') }
  77         '<'     { L _ (CmmT_SpecChar '<') }
  78         ','     { L _ (CmmT_SpecChar ',') }
  79         '!'     { L _ (CmmT_SpecChar '!') }
  80
  81         '..'    { L _ (CmmT_DotDot) }
  82         '::'    { L _ (CmmT_DoubleColon) }
  83         '>>'    { L _ (CmmT_Shr) }
  84         '<<'    { L _ (CmmT_Shl) }
  85         '>='    { L _ (CmmT_Ge) }
  86         '<='    { L _ (CmmT_Le) }
  87         '=='    { L _ (CmmT_Eq) }
  88         '!='    { L _ (CmmT_Ne) }
  89         '&&'    { L _ (CmmT_BoolAnd) }
  90         '||'    { L _ (CmmT_BoolOr) }
  91
  92         'CLOSURE'       { L _ (CmmT_CLOSURE) }
  93         'INFO_TABLE'    { L _ (CmmT_INFO_TABLE) }
  94         'INFO_TABLE_RET'{ L _ (CmmT_INFO_TABLE_RET) }
  95         'INFO_TABLE_FUN'{ L _ (CmmT_INFO_TABLE_FUN) }
  96         'INFO_TABLE_CONSTR'{ L _ (CmmT_INFO_TABLE_CONSTR) }
  97         'INFO_TABLE_SELECTOR'{ L _ (CmmT_INFO_TABLE_SELECTOR) }
  98         'else'          { L _ (CmmT_else) }
  99         'export'        { L _ (CmmT_export) }
 100         'section'       { L _ (CmmT_section) }
 101         'align'         { L _ (CmmT_align) }
 102         'goto'          { L _ (CmmT_goto) }
 103         'if'            { L _ (CmmT_if) }
 104         'jump'          { L _ (CmmT_jump) }
 105         'foreign'       { L _ (CmmT_foreign) }
 106         'import'        { L _ (CmmT_import) }
 107         'switch'        { L _ (CmmT_switch) }
 108         'case'          { L _ (CmmT_case) }
 109         'default'       { L _ (CmmT_default) }
 110         'bits8'         { L _ (CmmT_bits8) }
 111         'bits16'        { L _ (CmmT_bits16) }
 112         'bits32'        { L _ (CmmT_bits32) }
 113         'bits64'        { L _ (CmmT_bits64) }
 114         'float32'       { L _ (CmmT_float32) }
 115         'float64'       { L _ (CmmT_float64) }
 116
 117         GLOBALREG       { L _ (CmmT_GlobalReg   $$) }
 118         NAME            { L _ (CmmT_Name        $$) }
 119         STRING          { L _ (CmmT_String      $$) }
 120         INT             { L _ (CmmT_Int         $$) }
 121         FLOAT           { L _ (CmmT_Float       $$) }
 122
 123 %monad { P } { >>= } { return }
 124 %lexer { cmmlex } { L _ CmmT_EOF }
 125 %name cmmParse cmm
 126 %tokentype { Located CmmToken }
 127
 128 -- C-- operator precedences, taken from the C-- spec
 129 %right '||'     -- non-std extension, called %disjoin in C--
 130 %right '&&'     -- non-std extension, called %conjoin in C--
 131 %right '!'
 132 %nonassoc '>=' '>' '<=' '<' '!=' '=='
 133 %left '|'
 134 %left '^'
 135 %left '&'
 136 %left '>>' '<<'
 137 %left '-' '+'
 138 %left '/' '*' '%'
 139 %right '~'
 140
 141 %%
 142
 143 cmm     :: { ExtCode }
 144         : {- empty -}                   { return () }
 145         | cmmtop cmm                    { do $1; $2 }
 146
 147 cmmtop  :: { ExtCode }
 148         : cmmproc                       { $1 }
 149         | cmmdata                       { $1 }
 150         | decl                          { $1 }
 151         | 'CLOSURE' '(' NAME ',' NAME lits ')' ';'
 152                 { do lits <- sequence $6;
 153                      staticClosure $3 $5 (map getLit lits) }
 154
 155 -- The only static closures in the RTS are dummy closures like
 156 -- stg_END_TSO_QUEUE_closure and stg_dummy_ret.  We don't need
 157 -- to provide the full generality of static closures here.
 158 -- In particular:
 159 --      * CCS can always be CCS_DONT_CARE
 160 --      * closure is always extern
 161 --      * payload is always empty
 162 --      * we can derive closure and info table labels from a single NAME
 163
 164 cmmdata :: { ExtCode }
 165         : 'section' STRING '{' statics '}'
 166                 { do ss <- sequence $4;
 167                      code (emitData (section $2) (concat ss)) }
 168
 169 statics :: { [ExtFCode [CmmStatic]] }
 170         : {- empty -}                   { [] }
 171         | static statics                { $1 : $2 }
 172
 173 -- Strings aren't used much in the RTS HC code, so it doesn't seem
 174 -- worth allowing inline strings.  C-- doesn't allow them anyway.
 175 static  :: { ExtFCode [CmmStatic] }
 176         : NAME ':'      { return [CmmDataLabel (mkRtsDataLabelFS $1)] }
 177         | type expr ';' { do e <- $2;
 178                              return [CmmStaticLit (getLit e)] }
 179         | type ';'                      { return [CmmUninitialised
 180                                                         (machRepByteWidth $1)] }
 181         | 'bits8' '[' ']' STRING ';'    { return [mkString $4] }
 182         | 'bits8' '[' INT ']' ';'       { return [CmmUninitialised
 183                                                         (fromIntegral $3)] }
 184         | typenot8 '[' INT ']' ';'      { return [CmmUninitialised
 185                                                 (machRepByteWidth $1 *
 186                                                         fromIntegral $3)] }
 187         | 'align' INT ';'               { return [CmmAlign (fromIntegral $2)] }
 188         | 'CLOSURE' '(' NAME lits ')'
 189                 { do lits <- sequence $4;
 190                      return $ map CmmStaticLit $
 191                        mkStaticClosure (mkRtsInfoLabelFS $3)
 192                          dontCareCCS (map getLit lits) [] [] [] }
 193         -- arrays of closures required for the CHARLIKE & INTLIKE arrays
 194
 195 lits    :: { [ExtFCode CmmExpr] }
 196         : {- empty -}           { [] }
 197         | ',' expr lits         { $2 : $3 }
 198
 199 cmmproc :: { ExtCode }
 200         : info '{' body '}'
 201                 { do  (info_lbl, info1, info2) <- $1;
 202                       stmts <- getCgStmtsEC (loopDecls $3)
 203                       blks <- code (cgStmtsToBlocks stmts)
 204                       code (emitInfoTableAndCode info_lbl info1 info2 [] blks) }
 205
 206         | info ';'
 207                 { do (info_lbl, info1, info2) <- $1;
 208                      code (emitInfoTableAndCode info_lbl info1 info2 [] []) }
 209
 210         | NAME '{' body '}'
 211                 { do stmts <- getCgStmtsEC (loopDecls $3);
 212                      blks <- code (cgStmtsToBlocks stmts)
 213                      code (emitProc [] (mkRtsCodeLabelFS $1) [] blks) }
 214
 215 info    :: { ExtFCode (CLabel, [CmmLit],[CmmLit]) }
 216         : 'INFO_TABLE' '(' NAME ',' INT ',' INT ',' INT ',' STRING ',' STRING ')'
 217                 -- ptrs, nptrs, closure type, description, type
 218                 { stdInfo $3 $5 $7 0 $9 $11 $13 }
 219
 220         | 'INFO_TABLE_FUN' '(' NAME ',' INT ',' INT ',' INT ',' STRING ',' STRING ',' INT ')'
 221                 -- ptrs, nptrs, closure type, description, type, fun type
 222                 { funInfo $3 $5 $7 $9 $11 $13 $15 }
 223
 224         | 'INFO_TABLE_CONSTR' '(' NAME ',' INT ',' INT ',' INT ',' INT ',' STRING ',' STRING ')'
 225                 -- ptrs, nptrs, tag, closure type, description, type
 226                 { stdInfo $3 $5 $7 $9 $11 $13 $15 }
 227
 228         | 'INFO_TABLE_SELECTOR' '(' NAME ',' INT ',' INT ',' STRING ',' STRING ')'
 229                 -- selector, closure type, description, type
 230                 { basicInfo $3 (mkIntCLit (fromIntegral $5)) 0 $7 $9 $11 }
 231
 232         | 'INFO_TABLE_RET' '(' NAME ',' INT ',' INT ',' INT maybe_vec ')'
 233                 { retInfo $3 $5 $7 $9 $10 }
 234
 235 maybe_vec :: { [CmmLit] }
 236         : {- empty -}                   { [] }
 237         | ',' NAME maybe_vec            { CmmLabel (mkRtsCodeLabelFS $2) : $3 }
 238
 239 body    :: { ExtCode }
 240         : {- empty -}                   { return () }
 241         | decl body                     { do $1; $2 }
 242         | stmt body                     { do $1; $2 }
 243
 244 decl    :: { ExtCode }
 245         : type names ';'                { mapM_ (newLocal $1) $2 }
 246         | 'import' names ';'            { return () }  -- ignore imports
 247         | 'export' names ';'            { return () }  -- ignore exports
 248
 249 names   :: { [FastString] }
 250         : NAME                  { [$1] }
 251         | NAME ',' names        { $1 : $3 }
 252
 253 stmt    :: { ExtCode }
 254         : ';'                                   { nopEC }
 255
 256         | block_id ':'                          { code (labelC $1) }
 257
 258         | lreg '=' expr ';'
 259                 { do reg <- $1; e <- $3; stmtEC (CmmAssign reg e) }
 260         | type '[' expr ']' '=' expr ';'
 261                 { doStore $1 $3 $6 }
 262         | 'foreign' STRING expr '(' hint_exprs0 ')' vols ';'
 263                 {% foreignCall $2 [] $3 $5 $7 }
 264         | lreg '=' 'foreign' STRING expr '(' hint_exprs0 ')' vols ';'
 265                 {% let result = do r <- $1; return (r,NoHint) in
 266                    foreignCall $4 [result] $5 $7 $9 }
 267         | STRING lreg '=' 'foreign' STRING expr '(' hint_exprs0 ')' vols ';'
 268                 {% do h <- parseHint $1;
 269                       let result = do r <- $2; return (r,h) in
 270                       foreignCall $5 [result] $6 $8 $10 }
 271         -- stmt-level macros, stealing syntax from ordinary C-- function calls.
 272         -- Perhaps we ought to use the %%-form?
 273         | NAME '(' exprs0 ')' ';'
 274                 {% stmtMacro $1 $3  }
 275         | 'switch' maybe_range expr '{' arms default '}'
 276                 { doSwitch $2 $3 $5 $6 }
 277         | 'goto' block_id ';'
 278                 { stmtEC (CmmBranch $2) }
 279         | 'jump' expr {-maybe_actuals-} ';'
 280                 { do e <- $2; stmtEC (CmmJump e []) }
 281         | 'if' bool_expr '{' body '}' else
 282                 { ifThenElse $2 $4 $6 }
 283
 284 bool_expr :: { ExtFCode BoolExpr }
 285         : bool_op                       { $1 }
 286         | expr                          { do e <- $1; return (BoolTest e) }
 287
 288 bool_op :: { ExtFCode BoolExpr }
 289         : bool_expr '&&' bool_expr      { do e1 <- $1; e2 <- $3;
 290                                           return (BoolAnd e1 e2) }
 291         | bool_expr '||' bool_expr      { do e1 <- $1; e2 <- $3;
 292                                           return (BoolOr e1 e2)  }
 293         | '!' bool_expr                 { do e <- $2; return (BoolNot e) }
 294         | '(' bool_op ')'               { $2 }
 295
 296 -- This is not C-- syntax.  What to do?
 297 vols    :: { Maybe [GlobalReg] }
 298         : {- empty -}                   { Nothing }
 299         | '[' ']'                       { Just [] }
 300         | '[' globals ']'               { Just $2 }
 301
 302 globals :: { [GlobalReg] }
 303         : GLOBALREG                     { [$1] }
 304         | GLOBALREG ',' globals         { $1 : $3 }
 305
 306 maybe_range :: { Maybe (Int,Int) }
 307         : '[' INT '..' INT ']'  { Just (fromIntegral $2, fromIntegral $4) }
 308         | {- empty -}           { Nothing }
 309
 310 arms    :: { [([Int],ExtCode)] }
 311         : {- empty -}                   { [] }
 312         | arm arms                      { $1 : $2 }
 313
 314 arm     :: { ([Int],ExtCode) }
 315         : 'case' ints ':' '{' body '}'  { ($2, $5) }
 316
 317 ints    :: { [Int] }
 318         : INT                           { [ fromIntegral $1 ] }
 319         | INT ',' ints                  { fromIntegral $1 : $3 }
 320
 321 default :: { Maybe ExtCode }
 322         : 'default' ':' '{' body '}'    { Just $4 }
 323         -- taking a few liberties with the C-- syntax here; C-- doesn't have
 324         -- 'default' branches
 325         | {- empty -}                   { Nothing }
 326
 327 else    :: { ExtCode }
 328         : {- empty -}                   { nopEC }
 329         | 'else' '{' body '}'           { $3 }
 330
 331 -- we have to write this out longhand so that Happy's precedence rules
 332 -- can kick in.
 333 expr    :: { ExtFCode CmmExpr }
 334         : expr '/' expr                 { mkMachOp MO_U_Quot [$1,$3] }
 335         | expr '*' expr                 { mkMachOp MO_Mul [$1,$3] }
 336         | expr '%' expr                 { mkMachOp MO_U_Rem [$1,$3] }
 337         | expr '-' expr                 { mkMachOp MO_Sub [$1,$3] }
 338         | expr '+' expr                 { mkMachOp MO_Add [$1,$3] }
 339         | expr '>>' expr                { mkMachOp MO_U_Shr [$1,$3] }
 340         | expr '<<' expr                { mkMachOp MO_Shl [$1,$3] }
 341         | expr '&' expr                 { mkMachOp MO_And [$1,$3] }
 342         | expr '^' expr                 { mkMachOp MO_Xor [$1,$3] }
 343         | expr '|' expr                 { mkMachOp MO_Or [$1,$3] }
 344         | expr '>=' expr                { mkMachOp MO_U_Ge [$1,$3] }
 345         | expr '>' expr                 { mkMachOp MO_U_Gt [$1,$3] }
 346         | expr '<=' expr                { mkMachOp MO_U_Le [$1,$3] }
 347         | expr '<' expr                 { mkMachOp MO_U_Lt [$1,$3] }
 348         | expr '!=' expr                { mkMachOp MO_Ne [$1,$3] }
 349         | expr '==' expr                { mkMachOp MO_Eq [$1,$3] }
 350         | '~' expr                      { mkMachOp MO_Not [$2] }
 351         | '-' expr                      { mkMachOp MO_S_Neg [$2] }
 352         | expr0 '`' NAME '`' expr0      {% do { mo <- nameToMachOp $3 ;
 353                                                 return (mkMachOp mo [$1,$5]) } }
 354         | expr0                         { $1 }
 355
 356 expr0   :: { ExtFCode CmmExpr }
 357         : INT   maybe_ty         { return (CmmLit (CmmInt $1 $2)) }
 358         | FLOAT maybe_ty         { return (CmmLit (CmmFloat $1 $2)) }
 359         | STRING                 { do s <- code (mkStringCLit $1);
 360                                       return (CmmLit s) }
 361         | reg                    { $1 }
 362         | type '[' expr ']'      { do e <- $3; return (CmmLoad e $1) }
 363         | '%' NAME '(' exprs0 ')' {% exprOp $2 $4 }
 364         | '(' expr ')'           { $2 }
 365
 366
 367 -- leaving out the type of a literal gives you the native word size in C--
 368 maybe_ty :: { MachRep }
 369         : {- empty -}                   { wordRep }
 370         | '::' type                     { $2 }
 371
 372 hint_exprs0 :: { [ExtFCode (CmmExpr, MachHint)] }
 373         : {- empty -}                   { [] }
 374         | hint_exprs                    { $1 }
 375
 376 hint_exprs :: { [ExtFCode (CmmExpr, MachHint)] }
 377         : hint_expr                     { [$1] }
 378         | hint_expr ',' hint_exprs      { $1 : $3 }
 379
 380 hint_expr :: { ExtFCode (CmmExpr, MachHint) }
 381         : expr                          { do e <- $1; return (e, inferHint e) }
 382         | expr STRING                   {% do h <- parseHint $2;
 383                                               return $ do
 384                                                 e <- $1; return (e,h) }
 385
 386 exprs0  :: { [ExtFCode CmmExpr] }
 387         : {- empty -}                   { [] }
 388         | exprs                         { $1 }
 389
 390 exprs   :: { [ExtFCode CmmExpr] }
 391         : expr                          { [ $1 ] }
 392         | expr ',' exprs                { $1 : $3 }
 393
 394 reg     :: { ExtFCode CmmExpr }
 395         : NAME                  { lookupName $1 }
 396         | GLOBALREG             { return (CmmReg (CmmGlobal $1)) }
 397
 398 lreg    :: { ExtFCode CmmReg }
 399         : NAME                  { do e <- lookupName $1;
 400                                      return $
 401                                        case e of
 402                                         CmmReg r -> r
 403                                         other -> pprPanic "CmmParse:" (ftext $1 <> text " not a register") }
 404         | GLOBALREG             { return (CmmGlobal $1) }
 405
 406 block_id :: { BlockId }
 407         : NAME                  { BlockId (newTagUnique (getUnique $1) 'L') }
 408                         -- TODO: ugh.  The unique of a FastString has a null
 409                         -- tag, so we have to put our own tag on.  We should
 410                         -- really make a new unique for every label, and keep
 411                         -- them in an environment.
 412
 413 type    :: { MachRep }
 414         : 'bits8'               { I8 }
 415         | typenot8              { $1 }
 416
 417 typenot8 :: { MachRep }
 418         : 'bits16'              { I16 }
 419         | 'bits32'              { I32 }
 420         | 'bits64'              { I64 }
 421         | 'float32'             { F32 }
 422         | 'float64'             { F64 }
 423 {
 424 section :: String -> Section
 425 section "text"   = Text
 426 section "data"   = Data
 427 section "rodata" = ReadOnlyData
 428 section "bss"    = UninitialisedData
 429 section s        = OtherSection s
 430
 431 mkString :: String -> CmmStatic
 432 mkString s = CmmString (map (fromIntegral.ord) s)
 433
 434 -- mkMachOp infers the type of the MachOp from the type of its first
 435 -- argument.  We assume that this is correct: for MachOps that don't have
 436 -- symmetrical args (e.g. shift ops), the first arg determines the type of
 437 -- the op.
 438 mkMachOp :: (MachRep -> MachOp) -> [ExtFCode CmmExpr] -> ExtFCode CmmExpr
 439 mkMachOp fn args = do
 440   arg_exprs <- sequence args
 441   return (CmmMachOp (fn (cmmExprRep (head arg_exprs))) arg_exprs)
 442
 443 getLit :: CmmExpr -> CmmLit
 444 getLit (CmmLit l) = l
 445 getLit (CmmMachOp (MO_S_Neg _) [CmmLit (CmmInt i r)])  = CmmInt (negate i) r
 446 getLit _ = panic "invalid literal" -- TODO messy failure
 447
 448 nameToMachOp :: FastString -> P (MachRep -> MachOp)
 449 nameToMachOp name =
 450   case lookupUFM machOps name of
 451         Nothing -> fail ("unknown primitive " ++ unpackFS name)
 452         Just m  -> return m
 453
 454 exprOp :: FastString -> [ExtFCode CmmExpr] -> P (ExtFCode CmmExpr)
 455 exprOp name args_code =
 456   case lookupUFM exprMacros name of
 457      Just f  -> return $ do
 458         args <- sequence args_code
 459         return (f args)
 460      Nothing -> do
 461         mo <- nameToMachOp name
 462         return $ mkMachOp mo args_code
 463
 464 exprMacros :: UniqFM ([CmmExpr] -> CmmExpr)
 465 exprMacros = listToUFM [
 466   ( FSLIT("ENTRY_CODE"),   \ [x] -> entryCode x ),
 467   ( FSLIT("GET_ENTRY"),    \ [x] -> entryCode (closureInfoPtr x) ),
 468   ( FSLIT("STD_INFO"),     \ [x] -> infoTable x ),
 469   ( FSLIT("GET_STD_INFO"), \ [x] -> infoTable (closureInfoPtr x) ),
 470   ( FSLIT("GET_FUN_INFO"), \ [x] -> funInfoTable (closureInfoPtr x) ),
 471   ( FSLIT("INFO_TYPE"),    \ [x] -> infoTableClosureType x ),
 472   ( FSLIT("INFO_PTRS"),    \ [x] -> infoTablePtrs x ),
 473   ( FSLIT("INFO_NPTRS"),   \ [x] -> infoTableNonPtrs x ),
 474   ( FSLIT("RET_VEC"),      \ [info, conZ] -> retVec info conZ )
 475   ]
 476
 477 -- we understand a subset of C-- primitives:
 478 machOps = listToUFM $
 479         map (\(x, y) -> (mkFastString x, y)) [
 480         ( "add",        MO_Add ),
 481         ( "sub",        MO_Sub ),
 482         ( "eq",         MO_Eq ),
 483         ( "ne",         MO_Ne ),
 484         ( "mul",        MO_Mul ),
 485         ( "neg",        MO_S_Neg ),
 486         ( "quot",       MO_S_Quot ),
 487         ( "rem",        MO_S_Rem ),
 488         ( "divu",       MO_U_Quot ),
 489         ( "modu",       MO_U_Rem ),
 490
 491         ( "ge",         MO_S_Ge ),
 492         ( "le",         MO_S_Le ),
 493         ( "gt",         MO_S_Gt ),
 494         ( "lt",         MO_S_Lt ),
 495
 496         ( "geu",        MO_U_Ge ),
 497         ( "leu",        MO_U_Le ),
 498         ( "gtu",        MO_U_Gt ),
 499         ( "ltu",        MO_U_Lt ),
 500
 501         ( "flt",        MO_S_Lt ),
 502         ( "fle",        MO_S_Le ),
 503         ( "feq",        MO_Eq ),
 504         ( "fne",        MO_Ne ),
 505         ( "fgt",        MO_S_Gt ),
 506         ( "fge",        MO_S_Ge ),
 507         ( "fneg",       MO_S_Neg ),
 508
 509         ( "and",        MO_And ),
 510         ( "or",         MO_Or ),
 511         ( "xor",        MO_Xor ),
 512         ( "com",        MO_Not ),
 513         ( "shl",        MO_Shl ),
 514         ( "shrl",       MO_U_Shr ),
 515         ( "shra",       MO_S_Shr ),
 516
 517         ( "lobits8",  flip MO_U_Conv I8  ),
 518         ( "lobits16", flip MO_U_Conv I16 ),
 519         ( "lobits32", flip MO_U_Conv I32 ),
 520         ( "lobits64", flip MO_U_Conv I64 ),
 521         ( "sx16",     flip MO_S_Conv I16 ),
 522         ( "sx32",     flip MO_S_Conv I32 ),
 523         ( "sx64",     flip MO_S_Conv I64 ),
 524         ( "zx16",     flip MO_U_Conv I16 ),
 525         ( "zx32",     flip MO_U_Conv I32 ),
 526         ( "zx64",     flip MO_U_Conv I64 ),
 527         ( "f2f32",    flip MO_S_Conv F32 ),  -- TODO; rounding mode
 528         ( "f2f64",    flip MO_S_Conv F64 ),  -- TODO; rounding mode
 529         ( "f2i8",     flip MO_S_Conv I8 ),
 530         ( "f2i16",    flip MO_S_Conv I8 ),
 531         ( "f2i32",    flip MO_S_Conv I8 ),
 532         ( "f2i64",    flip MO_S_Conv I8 ),
 533         ( "i2f32",    flip MO_S_Conv F32 ),
 534         ( "i2f64",    flip MO_S_Conv F64 )
 535         ]
 536
 537 parseHint :: String -> P MachHint
 538 parseHint "ptr"    = return PtrHint
 539 parseHint "signed" = return SignedHint
 540 parseHint "float"  = return FloatHint
 541 parseHint str      = fail ("unrecognised hint: " ++ str)
 542
 543 -- labels are always pointers, so we might as well infer the hint
 544 inferHint :: CmmExpr -> MachHint
 545 inferHint (CmmLit (CmmLabel _)) = PtrHint
 546 inferHint (CmmReg (CmmGlobal g)) | isPtrGlobalReg g = PtrHint
 547 inferHint _ = NoHint
 548
 549 isPtrGlobalReg Sp               = True
 550 isPtrGlobalReg SpLim            = True
 551 isPtrGlobalReg Hp               = True
 552 isPtrGlobalReg HpLim            = True
 553 isPtrGlobalReg CurrentTSO       = True
 554 isPtrGlobalReg CurrentNursery   = True
 555 isPtrGlobalReg _                = False
 556
 557 happyError :: P a
 558 happyError = srcParseFail
 559
 560 -- -----------------------------------------------------------------------------
 561 -- Statement-level macros
 562
 563 stmtMacro :: FastString -> [ExtFCode CmmExpr] -> P ExtCode
 564 stmtMacro fun args_code = do
 565   case lookupUFM stmtMacros fun of
 566     Nothing -> fail ("unknown macro: " ++ unpackFS fun)
 567     Just fcode -> return $ do
 568         args <- sequence args_code
 569         code (fcode args)
 570
 571 stmtMacros :: UniqFM ([CmmExpr] -> Code)
 572 stmtMacros = listToUFM [
 573   ( FSLIT("CCS_ALLOC"),            \[words,ccs]  -> profAlloc words ccs ),
 574   ( FSLIT("CLOSE_NURSERY"),        \[]  -> emitCloseNursery ),
 575   ( FSLIT("ENTER_CCS_PAP_CL"),     \[e] -> enterCostCentrePAP e ),
 576   ( FSLIT("ENTER_CCS_THUNK"),      \[e] -> enterCostCentreThunk e ),
 577   ( FSLIT("HP_CHK_GEN"),           \[words,liveness,reentry] ->
 578                                       hpChkGen words liveness reentry ),
 579   ( FSLIT("HP_CHK_NP_ASSIGN_SP0"), \[e,f] -> hpChkNodePointsAssignSp0 e f ),
 580   ( FSLIT("LOAD_THREAD_STATE"),    \[] -> emitLoadThreadState ),
 581   ( FSLIT("LDV_ENTER"),            \[e] -> ldvEnter e ),
 582   ( FSLIT("LDV_RECORD_CREATE"),    \[e] -> ldvRecordCreate e ),
 583   ( FSLIT("OPEN_NURSERY"),         \[]  -> emitOpenNursery ),
 584   ( FSLIT("PUSH_UPD_FRAME"),       \[sp,e] -> emitPushUpdateFrame sp e ),
 585   ( FSLIT("SAVE_THREAD_STATE"),    \[] -> emitSaveThreadState ),
 586   ( FSLIT("SET_HDR"),              \[ptr,info,ccs] ->
 587                                         emitSetDynHdr ptr info ccs ),
 588   ( FSLIT("STK_CHK_GEN"),          \[words,liveness,reentry] ->
 589                                       stkChkGen words liveness reentry ),
 590   ( FSLIT("STK_CHK_NP"),           \[e] -> stkChkNodePoints e ),
 591   ( FSLIT("TICK_ALLOC_PRIM"),      \[hdr,goods,slop] ->
 592                                         tickyAllocPrim hdr goods slop ),
 593   ( FSLIT("TICK_ALLOC_PAP"),       \[goods,slop] ->
 594                                         tickyAllocPAP goods slop ),
 595   ( FSLIT("TICK_ALLOC_UP_THK"),    \[goods,slop] ->
 596                                         tickyAllocThunk goods slop ),
 597   ( FSLIT("UPD_BH_UPDATABLE"),       \[] -> emitBlackHoleCode False ),
 598   ( FSLIT("UPD_BH_SINGLE_ENTRY"),    \[] -> emitBlackHoleCode True ),
 599
 600   ( FSLIT("RET_P"),     \[a] ->       emitRetUT [(PtrArg,a)]),
 601   ( FSLIT("RET_N"),     \[a] ->       emitRetUT [(NonPtrArg,a)]),
 602   ( FSLIT("RET_PP"),    \[a,b] ->     emitRetUT [(PtrArg,a),(PtrArg,b)]),
 603   ( FSLIT("RET_NN"),    \[a,b] ->     emitRetUT [(NonPtrArg,a),(NonPtrArg,b)]),
 604   ( FSLIT("RET_NP"),    \[a,b] ->     emitRetUT [(NonPtrArg,a),(PtrArg,b)]),
 605   ( FSLIT("RET_PPP"),   \[a,b,c] ->   emitRetUT [(PtrArg,a),(PtrArg,b),(PtrArg,c)]),
 606   ( FSLIT("RET_NNP"),   \[a,b,c] ->   emitRetUT [(NonPtrArg,a),(NonPtrArg,b),(PtrArg,c)]),
 607   ( FSLIT("RET_NNNP"),  \[a,b,c,d] -> emitRetUT [(NonPtrArg,a),(NonPtrArg,b),(NonPtrArg,c),(PtrArg,d)]),
 608   ( FSLIT("RET_NPNP"),  \[a,b,c,d] -> emitRetUT [(NonPtrArg,a),(PtrArg,b),(NonPtrArg,c),(PtrArg,d)])
 609
 610  ]
 611
 612 -- -----------------------------------------------------------------------------
 613 -- Our extended FCode monad.
 614
 615 -- We add a mapping from names to CmmExpr, to support local variable names in
 616 -- the concrete C-- code.  The unique supply of the underlying FCode monad
 617 -- is used to grab a new unique for each local variable.
 618
 619 -- In C--, a local variable can be declared anywhere within a proc,
 620 -- and it scopes from the beginning of the proc to the end.  Hence, we have
 621 -- to collect declarations as we parse the proc, and feed the environment
 622 -- back in circularly (to avoid a two-pass algorithm).
 623
 624 type Decls = [(FastString,CmmExpr)]
 625 type Env   = UniqFM CmmExpr
 626
 627 newtype ExtFCode a = EC { unEC :: Env -> Decls -> FCode (Decls, a) }
 628
 629 type ExtCode = ExtFCode ()
 630
 631 returnExtFC a = EC $ \e s -> return (s, a)
 632 thenExtFC (EC m) k = EC $ \e s -> do (s',r) <- m e s; unEC (k r) e s'
 633
 634 instance Monad ExtFCode where
 635   (>>=) = thenExtFC
 636   return = returnExtFC
 637
 638 -- This function takes the variable decarations and imports and makes
 639 -- an environment, which is looped back into the computation.  In this
 640 -- way, we can have embedded declarations that scope over the whole
 641 -- procedure, and imports that scope over the entire module.
 642 loopDecls :: ExtFCode a -> ExtFCode a
 643 loopDecls (EC fcode) =
 644    EC $ \e s -> fixC (\ ~(decls,a) -> fcode (addListToUFM e decls) [])
 645
 646 getEnv :: ExtFCode Env
 647 getEnv = EC $ \e s -> return (s, e)
 648
 649 addVarDecl :: FastString -> CmmExpr -> ExtCode
 650 addVarDecl var expr = EC $ \e s -> return ((var,expr):s, ())
 651
 652 newLocal :: MachRep -> FastString -> ExtCode
 653 newLocal ty name  = do
 654    u <- code newUnique
 655    addVarDecl name (CmmReg (CmmLocal (LocalReg u ty)))
 656
 657 -- Unknown names are treated as if they had been 'import'ed.
 658 -- This saves us a lot of bother in the RTS sources, at the expense of
 659 -- deferring some errors to link time.
 660 lookupName :: FastString -> ExtFCode CmmExpr
 661 lookupName name = do
 662   env <- getEnv
 663   return $
 664      case lookupUFM env name of
 665         Nothing -> CmmLit (CmmLabel (mkRtsCodeLabelFS name))
 666         Just e  -> e
 667
 668 -- Lifting FCode computations into the ExtFCode monad:
 669 code :: FCode a -> ExtFCode a
 670 code fc = EC $ \e s -> do r <- fc; return (s, r)
 671
 672 code2 :: (FCode (Decls,b) -> FCode ((Decls,b),c))
 673          -> ExtFCode b -> ExtFCode c
 674 code2 f (EC ec) = EC $ \e s -> do ((s',b),c) <- f (ec e s); return (s',c)
 675
 676 nopEC = code nopC
 677 stmtEC stmt = code (stmtC stmt)
 678 stmtsEC stmts = code (stmtsC stmts)
 679 getCgStmtsEC = code2 getCgStmts'
 680
 681 forkLabelledCodeEC ec = do
 682   stmts <- getCgStmtsEC ec
 683   code (forkCgStmts stmts)
 684
 685 retInfo name size live_bits cl_type vector = do
 686   let liveness = smallLiveness (fromIntegral size) (fromIntegral live_bits)
 687       info_lbl = mkRtsRetInfoLabelFS name
 688       (info1,info2) = mkRetInfoTable info_lbl liveness NoC_SRT
 689                                 (fromIntegral cl_type) vector
 690   return (info_lbl, info1, info2)
 691
 692 stdInfo name ptrs nptrs srt_bitmap cl_type desc_str ty_str =
 693   basicInfo name (packHalfWordsCLit ptrs nptrs)
 694         srt_bitmap cl_type desc_str ty_str
 695
 696 basicInfo name layout srt_bitmap cl_type desc_str ty_str = do
 697   lit1 <- if opt_SccProfilingOn
 698                    then code $ mkStringCLit desc_str
 699                    else return (mkIntCLit 0)
 700   lit2 <- if opt_SccProfilingOn
 701                    then code $ mkStringCLit ty_str
 702                    else return (mkIntCLit 0)
 703   let info1 = mkStdInfoTable lit1 lit2 (fromIntegral cl_type)
 704                         (fromIntegral srt_bitmap)
 705                         layout
 706   return (mkRtsInfoLabelFS name, info1, [])
 707
 708 funInfo name ptrs nptrs cl_type desc_str ty_str fun_type = do
 709   (label,info1,_) <- stdInfo name ptrs nptrs 0{-srt_bitmap-}
 710                          cl_type desc_str ty_str
 711   let info2 = mkFunGenInfoExtraBits (fromIntegral fun_type) 0 zero zero zero
 712                 -- we leave most of the fields zero here.  This is only used
 713                 -- to generate the BCO info table in the RTS at the moment.
 714   return (label,info1,info2)
 715  where
 716    zero = mkIntCLit 0
 717
 718
 719 staticClosure :: FastString -> FastString -> [CmmLit] -> ExtCode
 720 staticClosure cl_label info payload
 721   = code $ emitDataLits (mkRtsDataLabelFS cl_label) lits
 722   where  lits = mkStaticClosure (mkRtsInfoLabelFS info) dontCareCCS payload [] [] []
 723
 724 foreignCall
 725         :: String
 726         -> [ExtFCode (CmmReg,MachHint)]
 727         -> ExtFCode CmmExpr
 728         -> [ExtFCode (CmmExpr,MachHint)]
 729         -> Maybe [GlobalReg] -> P ExtCode
 730 foreignCall "C" results_code expr_code args_code vols
 731   = return $ do
 732         results <- sequence results_code
 733         expr <- expr_code
 734         args <- sequence args_code
 735         code (emitForeignCall' PlayRisky results
 736                  (CmmForeignCall expr CCallConv) args vols)
 737 foreignCall conv _ _ _ _
 738   = fail ("unknown calling convention: " ++ conv)
 739
 740 doStore :: MachRep -> ExtFCode CmmExpr  -> ExtFCode CmmExpr -> ExtCode
 741 doStore rep addr_code val_code
 742   = do addr <- addr_code
 743        val <- val_code
 744         -- if the specified store type does not match the type of the expr
 745         -- on the rhs, then we insert a coercion that will cause the type
 746         -- mismatch to be flagged by cmm-lint.  If we don't do this, then
 747         -- the store will happen at the wrong type, and the error will not
 748         -- be noticed.
 749        let coerce_val
 750                 | cmmExprRep val /= rep = CmmMachOp (MO_U_Conv rep rep) [val]
 751                 | otherwise             = val
 752        stmtEC (CmmStore addr coerce_val)
 753
 754 -- Return an unboxed tuple.
 755 emitRetUT :: [(CgRep,CmmExpr)] -> Code
 756 emitRetUT args = do
 757   tickyUnboxedTupleReturn (length args)  -- TICK
 758   (sp, stmts) <- pushUnboxedTuple 0 args
 759   emitStmts stmts
 760   when (sp /= 0) $ stmtC (CmmAssign spReg (cmmRegOffW spReg (-sp)))
 761   stmtC (CmmJump (entryCode (CmmLoad (cmmRegOffW spReg sp) wordRep)) [])
 762
 763 -- -----------------------------------------------------------------------------
 764 -- If-then-else and boolean expressions
 765
 766 data BoolExpr
 767   = BoolExpr `BoolAnd` BoolExpr
 768   | BoolExpr `BoolOr`  BoolExpr
 769   | BoolNot BoolExpr
 770   | BoolTest CmmExpr
 771
 772 -- ToDo: smart constructors which simplify the boolean expression.
 773
 774 ifThenElse cond then_part else_part = do
 775      then_id <- code newLabelC
 776      join_id <- code newLabelC
 777      c <- cond
 778      emitCond c then_id
 779      else_part
 780      stmtEC (CmmBranch join_id)
 781      code (labelC then_id)
 782      then_part
 783      -- fall through to join
 784      code (labelC join_id)
 785
 786 -- 'emitCond cond true_id'  emits code to test whether the cond is true,
 787 -- branching to true_id if so, and falling through otherwise.
 788 emitCond (BoolTest e) then_id = do
 789   stmtEC (CmmCondBranch e then_id)
 790 emitCond (BoolNot (BoolTest (CmmMachOp op args))) then_id
 791   | Just op' <- maybeInvertComparison op
 792   = emitCond (BoolTest (CmmMachOp op' args)) then_id
 793 emitCond (BoolNot e) then_id = do
 794   else_id <- code newLabelC
 795   emitCond e else_id
 796   stmtEC (CmmBranch then_id)
 797   code (labelC else_id)
 798 emitCond (e1 `BoolOr` e2) then_id = do
 799   emitCond e1 then_id
 800   emitCond e2 then_id
 801 emitCond (e1 `BoolAnd` e2) then_id = do
 802         -- we'd like to invert one of the conditionals here to avoid an
 803         -- extra branch instruction, but we can't use maybeInvertComparison
 804         -- here because we can't look too closely at the expression since
 805         -- we're in a loop.
 806   and_id <- code newLabelC
 807   else_id <- code newLabelC
 808   emitCond e1 and_id
 809   stmtEC (CmmBranch else_id)
 810   code (labelC and_id)
 811   emitCond e2 then_id
 812   code (labelC else_id)
 813
 814
 815 -- -----------------------------------------------------------------------------
 816 -- Table jumps
 817
 818 -- We use a simplified form of C-- switch statements for now.  A
 819 -- switch statement always compiles to a table jump.  Each arm can
 820 -- specify a list of values (not ranges), and there can be a single
 821 -- default branch.  The range of the table is given either by the
 822 -- optional range on the switch (eg. switch [0..7] {...}), or by
 823 -- the minimum/maximum values from the branches.
 824
 825 doSwitch :: Maybe (Int,Int) -> ExtFCode CmmExpr -> [([Int],ExtCode)]
 826          -> Maybe ExtCode -> ExtCode
 827 doSwitch mb_range scrut arms deflt
 828    = do
 829         -- Compile code for the default branch
 830         dflt_entry <-
 831                 case deflt of
 832                   Nothing -> return Nothing
 833                   Just e  -> do b <- forkLabelledCodeEC e; return (Just b)
 834
 835         -- Compile each case branch
 836         table_entries <- mapM emitArm arms
 837
 838         -- Construct the table
 839         let
 840             all_entries = concat table_entries
 841             ixs = map fst all_entries
 842             (min,max)
 843                 | Just (l,u) <- mb_range = (l,u)
 844                 | otherwise              = (minimum ixs, maximum ixs)
 845
 846             entries = elems (accumArray (\_ a -> Just a) dflt_entry (min,max)
 847                                 all_entries)
 848         expr <- scrut
 849         -- ToDo: check for out of range and jump to default if necessary
 850         stmtEC (CmmSwitch expr entries)
 851    where
 852         emitArm :: ([Int],ExtCode) -> ExtFCode [(Int,BlockId)]
 853         emitArm (ints,code) = do
 854            blockid <- forkLabelledCodeEC code
 855            return [ (i,blockid) | i <- ints ]
 856
 857
 858 -- -----------------------------------------------------------------------------
 859 -- Putting it all together
 860
 861 -- The initial environment: we define some constants that the compiler
 862 -- knows about here.
 863 initEnv :: Env
 864 initEnv = listToUFM [
 865   ( FSLIT("SIZEOF_StgHeader"),
 866         CmmLit (CmmInt (fromIntegral (fixedHdrSize * wORD_SIZE)) wordRep) ),
 867   ( FSLIT("SIZEOF_StgInfoTable"),
 868         CmmLit (CmmInt (fromIntegral stdInfoTableSizeB) wordRep) )
 869   ]
 870
 871 parseCmmFile :: DynFlags -> HomeModules -> FilePath -> IO (Maybe Cmm)
 872 parseCmmFile dflags hmods filename = do
 873   showPass dflags "ParseCmm"
 874   buf <- hGetStringBuffer filename
 875   let
 876         init_loc = mkSrcLoc (mkFastString filename) 1 0
 877         init_state = (mkPState buf init_loc dflags) { lex_state = [0] }
 878                 -- reset the lex_state: the Lexer monad leaves some stuff
 879                 -- in there we don't want.
 880   case unP cmmParse init_state of
 881     PFailed span err -> do printError span err; return Nothing
 882     POk _ code -> do
 883         cmm <- initC dflags hmods no_module (getCmm (unEC code initEnv [] >> return ()))
 884         dumpIfSet_dyn dflags Opt_D_dump_cmm "Cmm" (pprCmms [cmm])
 885         return (Just cmm)
 886   where
 887         no_module = panic "parseCmmFile: no module"
 888 }