ghc/compiler/compMan/CompManager.lhs

   1 %
   2 % (c) The University of Glasgow, 2000
   3 %
   4 \section[CompManager]{The Compilation Manager}
   5
   6 \begin{code}
   7 module CompManager (
   8     cmInit,       -- :: GhciMode -> IO CmState
   9
  10     cmLoadModule, -- :: CmState -> FilePath -> IO (CmState, [String])
  11
  12     cmUnload,     -- :: CmState -> DynFlags -> IO CmState
  13
  14     cmSetContext, -- :: CmState -> String -> IO CmState
  15
  16     cmGetContext, -- :: CmState -> IO String
  17
  18 #ifdef GHCI
  19     cmRunStmt,    --  :: CmState -> DynFlags -> String -> IO (CmState, [Name])
  20
  21     cmTypeOfExpr, --  :: CmState -> DynFlags -> String
  22                   --  -> IO (CmState, Maybe String)
  23
  24     cmTypeOfName, -- :: CmState -> Name -> IO (Maybe String)
  25
  26     cmCompileExpr,-- :: CmState -> DynFlags -> String
  27                   -- -> IO (CmState, Maybe HValue)#endif
  28 #endif
  29     CmState, emptyCmState  -- abstract
  30   )
  31 where
  32
  33 #include "HsVersions.h"
  34
  35 import CmLink
  36 import CmTypes
  37 import DriverPipeline
  38 import DriverFlags      ( getDynFlags )
  39 import DriverPhases
  40 import DriverUtil
  41 import Finder
  42 import HscMain          ( initPersistentCompilerState )
  43 import HscTypes
  44 import RnEnv            ( unQualInScope )
  45 import Id               ( idType, idName )
  46 import Name             ( Name, NamedThing(..), nameRdrName )
  47 import NameEnv
  48 import RdrName          ( lookupRdrEnv, emptyRdrEnv )
  49 import Module
  50 import GetImports
  51 import Type             ( tidyType )
  52 import VarEnv           ( emptyTidyEnv )
  53 import UniqFM
  54 import Unique           ( Uniquable )
  55 import Digraph          ( SCC(..), stronglyConnComp, flattenSCC )
  56 import ErrUtils         ( showPass )
  57 import SysTools         ( cleanTempFilesExcept )
  58 import Util
  59 import Outputable
  60 import Panic
  61 import CmdLineOpts      ( DynFlags(..) )
  62 import IOExts
  63
  64 #ifdef GHCI
  65 import Interpreter      ( HValue )
  66 import HscMain          ( hscStmt )
  67 import PrelGHC          ( unsafeCoerce# )
  68 #endif
  69
  70 -- lang
  71 import Exception        ( throwDyn )
  72
  73 -- std
  74 import Directory        ( getModificationTime, doesFileExist )
  75 import IO
  76 import Monad
  77 import List             ( nub )
  78 import Maybe
  79 \end{code}
  80
  81
  82 \begin{code}
  83 -- Persistent state for the entire system
  84 data CmState
  85    = CmState {
  86         hst   :: HomeSymbolTable,    -- home symbol table
  87         hit   :: HomeIfaceTable,     -- home interface table
  88         ui    :: UnlinkedImage,      -- the unlinked images
  89         mg    :: ModuleGraph,        -- the module graph
  90         gmode :: GhciMode,           -- NEVER CHANGES
  91         ic    :: InteractiveContext, -- command-line binding info
  92
  93         pcs    :: PersistentCompilerState, -- compile's persistent state
  94         pls    :: PersistentLinkerState    -- link's persistent state
  95      }
  96
  97 emptyCmState :: GhciMode -> Module -> IO CmState
  98 emptyCmState gmode mod
  99     = do pcs     <- initPersistentCompilerState
 100          pls     <- emptyPLS
 101          return (CmState { hst    = emptySymbolTable,
 102                            hit    = emptyIfaceTable,
 103                            ui     = emptyUI,
 104                            mg     = emptyMG,
 105                            gmode  = gmode,
 106                            ic     = emptyInteractiveContext mod,
 107                            pcs    = pcs,
 108                            pls    = pls })
 109
 110 emptyInteractiveContext mod
 111   = InteractiveContext { ic_module = mod,
 112                          ic_rn_env = emptyRdrEnv,
 113                          ic_type_env = emptyTypeEnv }
 114
 115 defaultCurrentModuleName = mkModuleName "Prelude"
 116 GLOBAL_VAR(defaultCurrentModule, error "no defaultCurrentModule", Module)
 117
 118 -- CM internal types
 119 type UnlinkedImage = [Linkable] -- the unlinked images (should be a set, really)
 120 emptyUI :: UnlinkedImage
 121 emptyUI = []
 122
 123 type ModuleGraph = [ModSummary]  -- the module graph, topologically sorted
 124 emptyMG :: ModuleGraph
 125 emptyMG = []
 126
 127 -----------------------------------------------------------------------------
 128 -- Produce an initial CmState.
 129
 130 cmInit :: GhciMode -> IO CmState
 131 cmInit mode = do
 132    prel <- moduleNameToModule defaultCurrentModuleName
 133    writeIORef defaultCurrentModule prel
 134    emptyCmState mode prel
 135
 136 -----------------------------------------------------------------------------
 137 -- Setting the context doesn't throw away any bindings; the bindings
 138 -- we've built up in the InteractiveContext simply move to the new
 139 -- module.  They always shadow anything in scope in the current context.
 140
 141 cmSetContext :: CmState -> String -> IO CmState
 142 cmSetContext cmstate str
 143    = do let mn = mkModuleName str
 144             modules_loaded = [ (name_of_summary s, ms_mod s)  | s <- mg cmstate ]
 145
 146         m <- case lookup mn modules_loaded of
 147                 Just m  -> return m
 148                 Nothing -> do
 149                    mod <- moduleNameToModule mn
 150                    if isHomeModule mod
 151                         then throwDyn (CmdLineError (showSDoc
 152                                 (quotes (ppr (moduleName mod))
 153                                   <+> text "is not currently loaded")))
 154                         else return mod
 155
 156         return cmstate{ ic = (ic cmstate){ic_module=m} }
 157
 158 cmGetContext :: CmState -> IO String
 159 cmGetContext cmstate = return (moduleUserString (ic_module (ic cmstate)))
 160
 161 moduleNameToModule :: ModuleName -> IO Module
 162 moduleNameToModule mn
 163  = do maybe_stuff <- findModule mn
 164       case maybe_stuff of
 165         Nothing -> throwDyn (CmdLineError ("can't find module `"
 166                                     ++ moduleNameUserString mn ++ "'"))
 167         Just (m,_) -> return m
 168
 169 -----------------------------------------------------------------------------
 170 -- cmRunStmt:  Run a statement/expr.
 171
 172 #ifdef GHCI
 173 cmRunStmt :: CmState -> DynFlags -> String
 174         -> IO (CmState,                 -- new state
 175                [Name])                  -- names bound by this evaluation
 176 cmRunStmt cmstate dflags expr
 177    = do
 178         let InteractiveContext {
 179                 ic_rn_env = rn_env,
 180                 ic_type_env = type_env,
 181                 ic_module   = this_mod } = icontext
 182
 183         (new_pcs, maybe_stuff)
 184             <- hscStmt dflags hst hit pcs icontext expr False{-stmt-}
 185
 186         case maybe_stuff of
 187            Nothing -> return (cmstate{ pcs=new_pcs }, [])
 188            Just (ids, _, bcos) -> do
 189
 190                 -- update the interactive context
 191                 let
 192                     names = map idName ids
 193
 194                     -- these names have just been shadowed
 195                     shadowed = [ n | r <- map nameRdrName names,
 196                                      Just n <- [lookupRdrEnv rn_env r] ]
 197
 198                     new_rn_env   = extendLocalRdrEnv rn_env names
 199
 200                     -- remove any shadowed bindings from the type_env
 201                     filtered_type_env = delListFromNameEnv type_env shadowed
 202
 203                     new_type_env = extendNameEnvList filtered_type_env
 204                                         [ (getName id, AnId id) | id <- ids]
 205
 206                     new_ic = icontext { ic_rn_env   = new_rn_env,
 207                                         ic_type_env = new_type_env }
 208
 209                 -- link it
 210                 hval <- linkExpr pls bcos
 211
 212                 -- run it!
 213                 let thing_to_run = unsafeCoerce# hval :: IO [HValue]
 214                 hvals <- thing_to_run
 215
 216                 -- Get the newly bound things, and bind them.  Don't forget
 217                 -- to delete any shadowed bindings from the closure_env, lest
 218                 -- we end up with a space leak.
 219                 pls <- delListFromClosureEnv pls shadowed
 220                 new_pls <- addListToClosureEnv pls (zip names hvals)
 221
 222                 return (cmstate{ pcs=new_pcs, pls=new_pls, ic=new_ic }, names)
 223    where
 224        CmState{ hst=hst, hit=hit, pcs=pcs, pls=pls, ic=icontext } = cmstate
 225 #endif
 226
 227 -----------------------------------------------------------------------------
 228 -- cmTypeOfExpr: returns a string representing the type of an expression
 229
 230 #ifdef GHCI
 231 cmTypeOfExpr :: CmState -> DynFlags -> String -> IO (CmState, Maybe String)
 232 cmTypeOfExpr cmstate dflags expr
 233    = do (new_pcs, maybe_stuff)
 234           <- hscStmt dflags hst hit pcs ic expr True{-just an expr-}
 235
 236         let new_cmstate = cmstate{pcs = new_pcs}
 237
 238         case maybe_stuff of
 239            Nothing -> return (new_cmstate, Nothing)
 240            Just (_, ty, _) ->
 241              let pit = pcs_PIT pcs
 242                  modname = moduleName (ic_module ic)
 243                  tidy_ty = tidyType emptyTidyEnv ty
 244                  str = case lookupIfaceByModName hit pit modname of
 245                           Nothing    -> showSDoc (ppr tidy_ty)
 246                           Just iface -> showSDocForUser unqual (ppr tidy_ty)
 247                              where unqual = unQualInScope (mi_globals iface)
 248              in return (new_cmstate, Just str)
 249    where
 250        CmState{ hst=hst, hit=hit, pcs=pcs, ic=ic } = cmstate
 251 #endif
 252
 253 -----------------------------------------------------------------------------
 254 -- cmTypeOfName: returns a string representing the type of a name.
 255
 256 #ifdef GHCI
 257 cmTypeOfName :: CmState -> Name -> IO (Maybe String)
 258 cmTypeOfName CmState{ hit=hit, pcs=pcs, ic=ic } name
 259  = case lookupNameEnv (ic_type_env ic) name of
 260         Nothing -> return Nothing
 261         Just (AnId id) ->
 262            let pit = pcs_PIT pcs
 263                modname = moduleName (ic_module ic)
 264                ty = tidyType emptyTidyEnv (idType id)
 265                str = case lookupIfaceByModName hit pit modname of
 266                         Nothing    -> showSDoc (ppr ty)
 267                         Just iface -> showSDocForUser unqual (ppr ty)
 268                            where unqual = unQualInScope (mi_globals iface)
 269            in return (Just str)
 270
 271         _ -> panic "cmTypeOfName"
 272 #endif
 273
 274 -----------------------------------------------------------------------------
 275 -- cmCompileExpr: compile an expression and deliver an HValue
 276
 277 #ifdef GHCI
 278 cmCompileExpr :: CmState -> DynFlags -> String -> IO (CmState, Maybe HValue)
 279 cmCompileExpr cmstate dflags expr
 280    = do
 281         let InteractiveContext {
 282                 ic_rn_env = rn_env,
 283                 ic_type_env = type_env,
 284                 ic_module   = this_mod } = icontext
 285
 286         (new_pcs, maybe_stuff)
 287             <- hscStmt dflags hst hit pcs icontext
 288                   ("let __cmCompileExpr = "++expr) False{-stmt-}
 289
 290         case maybe_stuff of
 291            Nothing -> return (cmstate{ pcs=new_pcs }, Nothing)
 292            Just (ids, _, bcos) -> do
 293
 294                 -- link it
 295                 hval <- linkExpr pls bcos
 296
 297                 -- run it!
 298                 let thing_to_run = unsafeCoerce# hval :: IO [HValue]
 299                 hvals <- thing_to_run
 300
 301                 case (ids,hvals) of
 302                   ([id],[hv]) -> return (cmstate{ pcs=new_pcs }, Just hv)
 303                   _ -> panic "cmCompileExpr"
 304
 305    where
 306        CmState{ hst=hst, hit=hit, pcs=pcs, pls=pls, ic=icontext } = cmstate
 307 #endif
 308
 309 -----------------------------------------------------------------------------
 310 -- cmInfo: return "info" about an expression.  The info might be:
 311 --
 312 --      * its type, for an expression,
 313 --      * the class definition, for a class
 314 --      * the datatype definition, for a tycon (or synonym)
 315 --      * the export list, for a module
 316 --
 317 -- Can be used to find the type of the last expression compiled, by looking
 318 -- for "it".
 319
 320 cmInfo :: CmState -> String -> IO (Maybe String)
 321 cmInfo cmstate str
 322  = do error "cmInfo not implemented yet"
 323
 324 -----------------------------------------------------------------------------
 325 -- Unload the compilation manager's state: everything it knows about the
 326 -- current collection of modules in the Home package.
 327
 328 cmUnload :: CmState -> DynFlags -> IO CmState
 329 cmUnload state@CmState{ gmode=mode, pls=pls, pcs=pcs } dflags
 330  = do -- Throw away the old home dir cache
 331       emptyHomeDirCache
 332
 333       -- Unload everything the linker knows about
 334       new_pls <- CmLink.unload mode dflags [] pls
 335
 336       -- Start with a fresh CmState, but keep the PersistentCompilerState
 337       new_state <- cmInit mode
 338       return new_state{ pcs=pcs, pls=new_pls }
 339
 340 -----------------------------------------------------------------------------
 341 -- The real business of the compilation manager: given a system state and
 342 -- a module name, try and bring the module up to date, probably changing
 343 -- the system state at the same time.
 344
 345 cmLoadModule :: CmState
 346              -> [FilePath]
 347              -> IO (CmState,            -- new state
 348                     Bool,               -- was successful
 349                     [String])           -- list of modules loaded
 350
 351 cmLoadModule cmstate1 rootnames
 352    = do -- version 1's are the original, before downsweep
 353         let pls1      = pls    cmstate1
 354         let pcs1      = pcs    cmstate1
 355         let hst1      = hst    cmstate1
 356         let hit1      = hit    cmstate1
 357         -- similarly, ui1 is the (complete) set of linkables from
 358         -- the previous pass, if any.
 359         let ui1       = ui     cmstate1
 360         let mg1       = mg     cmstate1
 361         let ic1       = ic     cmstate1
 362
 363         let ghci_mode = gmode cmstate1 -- this never changes
 364
 365         -- Do the downsweep to reestablish the module graph
 366         dflags <- getDynFlags
 367         let verb = verbosity dflags
 368
 369         showPass dflags "Chasing dependencies"
 370         when (verb >= 1 && ghci_mode == Batch) $
 371            hPutStrLn stderr (showSDoc (hcat [
 372              text progName, text ": chasing modules from: ",
 373              hcat (punctuate comma (map text rootnames))]))
 374
 375         (mg2unsorted, a_root_is_Main) <- downsweep rootnames mg1
 376         let mg2unsorted_names = map name_of_summary mg2unsorted
 377
 378         -- reachable_from follows source as well as normal imports
 379         let reachable_from :: ModuleName -> [ModuleName]
 380             reachable_from = downwards_closure_of_module mg2unsorted
 381
 382         -- should be cycle free; ignores 'import source's
 383         let mg2 = topological_sort False mg2unsorted
 384         -- ... whereas this takes them into account.  Used for
 385         -- backing out partially complete cycles following a failed
 386         -- upsweep, and for removing from hst/hit all the modules
 387         -- not in strict downwards closure, during calls to compile.
 388         let mg2_with_srcimps = topological_sort True mg2unsorted
 389
 390         -- Sort out which linkables we wish to keep in the unlinked image.
 391         -- See getValidLinkables below for details.
 392         valid_linkables <- getValidLinkables ui1 mg2unsorted_names
 393                                 mg2_with_srcimps
 394         -- when (verb >= 2) $
 395         --    putStrLn (showSDoc (text "Valid linkables:"
 396         --                       <+> ppr valid_linkables))
 397
 398         -- Figure out a stable set of modules which can be retained
 399         -- the top level envs, to avoid upsweeping them.  Goes to a
 400         -- bit of trouble to avoid upsweeping module cycles.
 401         --
 402         -- Construct a set S of stable modules like this:
 403         -- Travel upwards, over the sccified graph.  For each scc
 404         -- of modules ms, add ms to S only if:
 405         -- 1.  All home imports of ms are either in ms or S
 406         -- 2.  A valid linkable exists for each module in ms
 407
 408         stable_mods <- preUpsweep valid_linkables hit1
 409                                   mg2unsorted_names [] mg2_with_srcimps
 410
 411         let stable_summaries
 412                = concatMap (findInSummaries mg2unsorted) stable_mods
 413
 414             stable_linkables
 415                = filter (\m -> linkableModName m `elem` stable_mods)
 416                     valid_linkables
 417
 418         when (verb >= 2) $
 419            putStrLn (showSDoc (text "Stable modules:"
 420                                <+> sep (map (text.moduleNameUserString) stable_mods)))
 421
 422         -- unload any modules which aren't going to be re-linked this
 423         -- time around.
 424         pls2 <- unload ghci_mode dflags stable_linkables pls1
 425
 426         -- We could at this point detect cycles which aren't broken by
 427         -- a source-import, and complain immediately, but it seems better
 428         -- to let upsweep_mods do this, so at least some useful work gets
 429         -- done before the upsweep is abandoned.
 430         let upsweep_these
 431                = filter (\scc -> any (`notElem` stable_mods)
 432                                      (map name_of_summary (flattenSCC scc)))
 433                         mg2
 434
 435         --hPutStrLn stderr "after tsort:\n"
 436         --hPutStrLn stderr (showSDoc (vcat (map ppr mg2)))
 437
 438         -- Because we don't take into account source imports when doing
 439         -- the topological sort, there shouldn't be any cycles in mg2.
 440         -- If there is, we complain and give up -- the user needs to
 441         -- break the cycle using a boot file.
 442
 443         -- Now do the upsweep, calling compile for each module in
 444         -- turn.  Final result is version 3 of everything.
 445
 446         let threaded2 = CmThreaded pcs1 hst1 hit1
 447
 448         (upsweep_complete_success, threaded3, modsUpswept, newLis)
 449            <- upsweep_mods ghci_mode dflags valid_linkables reachable_from
 450                            threaded2 upsweep_these
 451
 452         let ui3 = add_to_ui valid_linkables newLis
 453         let (CmThreaded pcs3 hst3 hit3) = threaded3
 454
 455         -- At this point, modsUpswept and newLis should have the same
 456         -- length, so there is one new (or old) linkable for each
 457         -- mod which was processed (passed to compile).
 458
 459         -- Make modsDone be the summaries for each home module now
 460         -- available; this should equal the domains of hst3 and hit3.
 461         -- (NOT STRICTLY TRUE if an interactive session was started
 462         --  with some object on disk ???)
 463         -- Get in in a roughly top .. bottom order (hence reverse).
 464
 465         let modsDone = reverse modsUpswept ++ stable_summaries
 466
 467         -- Try and do linking in some form, depending on whether the
 468         -- upsweep was completely or only partially successful.
 469
 470         if upsweep_complete_success
 471
 472          then
 473            -- Easy; just relink it all.
 474            do when (verb >= 2) $
 475                  hPutStrLn stderr "Upsweep completely successful."
 476
 477               -- clean up after ourselves
 478               cleanTempFilesExcept verb (ppFilesFromSummaries modsDone)
 479
 480               -- link everything together
 481               linkresult <- link ghci_mode dflags a_root_is_Main ui3 pls2
 482
 483               cmLoadFinish True linkresult
 484                         hst3 hit3 ui3 modsDone ghci_mode pcs3
 485
 486          else
 487            -- Tricky.  We need to back out the effects of compiling any
 488            -- half-done cycles, both so as to clean up the top level envs
 489            -- and to avoid telling the interactive linker to link them.
 490            do when (verb >= 2) $
 491                 hPutStrLn stderr "Upsweep partially successful."
 492
 493               let modsDone_names
 494                      = map name_of_summary modsDone
 495               let mods_to_zap_names
 496                      = findPartiallyCompletedCycles modsDone_names
 497                           mg2_with_srcimps
 498               let mods_to_keep
 499                      = filter ((`notElem` mods_to_zap_names).name_of_summary)
 500                           modsDone
 501
 502               let (hst4, hit4, ui4)
 503                      = retainInTopLevelEnvs (map name_of_summary mods_to_keep)
 504                                             (hst3,hit3,ui3)
 505
 506               -- clean up after ourselves
 507               cleanTempFilesExcept verb (ppFilesFromSummaries mods_to_keep)
 508
 509               -- link everything together
 510               linkresult <- link ghci_mode dflags False ui4 pls2
 511
 512               cmLoadFinish False linkresult
 513                     hst4 hit4 ui4 mods_to_keep ghci_mode pcs3
 514
 515
 516 -- Finish up after a cmLoad.
 517 --
 518 -- Empty the interactive context and set the module context to the topmost
 519 -- newly loaded module, or the Prelude if none were loaded.
 520 cmLoadFinish ok linkresult hst hit ui mods ghci_mode pcs
 521   = do case linkresult of {
 522           LinkErrs _ _ -> panic "cmLoadModule: link failed (2)";
 523           LinkOK pls   -> do
 524
 525        def_mod <- readIORef defaultCurrentModule
 526        let current_mod = case mods of
 527                                 []    -> def_mod
 528                                 (x:_) -> ms_mod x
 529
 530            new_ic = emptyInteractiveContext current_mod
 531
 532            new_cmstate = CmState{ hst=hst, hit=hit,
 533                                   ui=ui, mg=mods,
 534                                   gmode=ghci_mode, pcs=pcs,
 535                                   pls=pls,
 536                                   ic = new_ic }
 537            mods_loaded = map (moduleNameUserString.name_of_summary) mods
 538
 539        return (new_cmstate, ok, mods_loaded)
 540     }
 541
 542 ppFilesFromSummaries summaries
 543   = [ fn | Just fn <- map (ml_hspp_file . ms_location) summaries ]
 544
 545 -----------------------------------------------------------------------------
 546 -- getValidLinkables
 547
 548 -- For each module (or SCC of modules), we take:
 549 --
 550 --      - an on-disk linkable, if this is the first time around and one
 551 --        is available.
 552 --
 553 --      - the old linkable, otherwise (and if one is available).
 554 --
 555 -- and we throw away the linkable if it is older than the source
 556 -- file.  We ignore the on-disk linkables unless all of the dependents
 557 -- of this SCC also have on-disk linkables.
 558 --
 559 -- If a module has a valid linkable, then it may be STABLE (see below),
 560 -- and it is classified as SOURCE UNCHANGED for the purposes of calling
 561 -- compile.
 562 --
 563 -- ToDo: this pass could be merged with the preUpsweep.
 564
 565 getValidLinkables
 566         :: [Linkable]           -- old linkables
 567         -> [ModuleName]         -- all home modules
 568         -> [SCC ModSummary]     -- all modules in the program, dependency order
 569         -> IO [Linkable]        -- still-valid linkables
 570
 571 getValidLinkables old_linkables all_home_mods module_graph
 572   = foldM (getValidLinkablesSCC old_linkables all_home_mods) [] module_graph
 573
 574 getValidLinkablesSCC old_linkables all_home_mods new_linkables scc0
 575    = let
 576           scc             = flattenSCC scc0
 577           scc_names       = map name_of_summary scc
 578           home_module m   = m `elem` all_home_mods && m `notElem` scc_names
 579           scc_allhomeimps = nub (filter home_module (concatMap ms_imps scc))
 580                 -- NOTE: ms_imps, not ms_allimps above.  We don't want to
 581                 -- force a module's SOURCE imports to be already compiled for
 582                 -- its object linkable to be valid.
 583
 584           has_object m = case findModuleLinkable_maybe new_linkables m of
 585                             Nothing -> False
 586                             Just l  -> isObjectLinkable l
 587
 588           objects_allowed = all has_object scc_allhomeimps
 589      in do
 590
 591      these_linkables
 592         <- foldM (getValidLinkable old_linkables objects_allowed) [] scc
 593
 594         -- since an scc can contain only all objects or no objects at all,
 595         -- we have to check whether we got all objects or not, and re-do
 596         -- the linkable check if not.
 597      adjusted_linkables
 598         <- if objects_allowed && not (all isObjectLinkable these_linkables)
 599               then foldM (getValidLinkable old_linkables False) [] scc
 600               else return these_linkables
 601
 602      return (adjusted_linkables ++ new_linkables)
 603
 604
 605 getValidLinkable :: [Linkable] -> Bool -> [Linkable] -> ModSummary
 606         -> IO [Linkable]
 607 getValidLinkable old_linkables objects_allowed new_linkables summary
 608   = do let mod_name = name_of_summary summary
 609
 610        maybe_disk_linkable
 611           <- if (not objects_allowed)
 612                 then return Nothing
 613                 else case ml_obj_file (ms_location summary) of
 614                         Just obj_fn -> maybe_getFileLinkable mod_name obj_fn
 615                         Nothing -> return Nothing
 616
 617        let old_linkable = findModuleLinkable_maybe old_linkables mod_name
 618            maybe_old_linkable =
 619                 case old_linkable of
 620                     Just l | not (isObjectLinkable l) || stillThere l
 621                                 -> old_linkable
 622                                 -- ToDo: emit a warning if not (stillThere l)
 623                     other -> Nothing
 624
 625            -- make sure that if we had an old disk linkable around, that it's
 626            -- still there on the disk (in case we need to re-link it).
 627            stillThere l =
 628                 case maybe_disk_linkable of
 629                    Nothing    -> False
 630                    Just l_disk -> linkableTime l == linkableTime l_disk
 631
 632            -- we only look for objects on disk the first time around;
 633            -- if the user compiles a module on the side during a GHCi session,
 634            -- it won't be picked up until the next ":load".  This is what the
 635            -- "null old_linkables" test below is.
 636            linkable | null old_linkables = maybeToList maybe_disk_linkable
 637                     | otherwise          = maybeToList maybe_old_linkable
 638
 639            -- only linkables newer than the source code are valid
 640            src_date = ms_hs_date summary
 641
 642            valid_linkable
 643               =  filter (\l -> linkableTime l > src_date) linkable
 644
 645        return (valid_linkable ++ new_linkables)
 646
 647
 648 maybe_getFileLinkable :: ModuleName -> FilePath -> IO (Maybe Linkable)
 649 maybe_getFileLinkable mod_name obj_fn
 650    = do obj_exist <- doesFileExist obj_fn
 651         if not obj_exist
 652          then return Nothing
 653          else
 654          do let stub_fn = case splitFilename3 obj_fn of
 655                              (dir, base, ext) -> dir ++ "/" ++ base ++ ".stub_o"
 656             stub_exist <- doesFileExist stub_fn
 657             obj_time <- getModificationTime obj_fn
 658             if stub_exist
 659              then return (Just (LM obj_time mod_name [DotO obj_fn, DotO stub_fn]))
 660              else return (Just (LM obj_time mod_name [DotO obj_fn]))
 661
 662
 663 -----------------------------------------------------------------------------
 664 -- Do a pre-upsweep without use of "compile", to establish a
 665 -- (downward-closed) set of stable modules for which we won't call compile.
 666
 667 -- a stable module:
 668 --      * has a valid linkable (see getValidLinkables above)
 669 --      * depends only on stable modules
 670 --      * has an interface in the HIT (interactive mode only)
 671
 672 preUpsweep :: [Linkable]        -- new valid linkables
 673            -> HomeIfaceTable
 674            -> [ModuleName]      -- names of all mods encountered in downsweep
 675            -> [ModuleName]      -- accumulating stable modules
 676            -> [SCC ModSummary]  -- scc-ified mod graph, including src imps
 677            -> IO [ModuleName]   -- stable modules
 678
 679 preUpsweep valid_lis hit all_home_mods stable []  = return stable
 680 preUpsweep valid_lis hit all_home_mods stable (scc0:sccs)
 681    = do let scc = flattenSCC scc0
 682             scc_allhomeimps :: [ModuleName]
 683             scc_allhomeimps
 684                = nub (filter (`elem` all_home_mods) (concatMap ms_allimps scc))
 685             all_imports_in_scc_or_stable
 686                = all in_stable_or_scc scc_allhomeimps
 687             scc_names
 688                = map name_of_summary scc
 689             in_stable_or_scc m
 690                = m `elem` scc_names || m `elem` stable
 691
 692             -- now we check for valid linkables: each module in the SCC must
 693             -- have a valid linkable (see getValidLinkables above).
 694             has_valid_linkable new_summary
 695               = isJust (findModuleLinkable_maybe valid_lis modname)
 696                where modname = name_of_summary new_summary
 697
 698             has_interface summary = ms_mod summary `elemUFM` hit
 699
 700             scc_is_stable = all_imports_in_scc_or_stable
 701                           && all has_valid_linkable scc
 702                           && all has_interface scc
 703
 704         if scc_is_stable
 705          then preUpsweep valid_lis hit all_home_mods (scc_names++stable) sccs
 706          else preUpsweep valid_lis hit all_home_mods stable sccs
 707
 708
 709 -- Helper for preUpsweep.  Assuming that new_summary's imports are all
 710 -- stable (in the sense of preUpsweep), determine if new_summary is itself
 711 -- stable, and, if so, in batch mode, return its linkable.
 712 findInSummaries :: [ModSummary] -> ModuleName -> [ModSummary]
 713 findInSummaries old_summaries mod_name
 714    = [s | s <- old_summaries, name_of_summary s == mod_name]
 715
 716 findModInSummaries :: [ModSummary] -> Module -> Maybe ModSummary
 717 findModInSummaries old_summaries mod
 718    = case [s | s <- old_summaries, ms_mod s == mod] of
 719          [] -> Nothing
 720          (s:_) -> Just s
 721
 722 -- Return (names of) all those in modsDone who are part of a cycle
 723 -- as defined by theGraph.
 724 findPartiallyCompletedCycles :: [ModuleName] -> [SCC ModSummary] -> [ModuleName]
 725 findPartiallyCompletedCycles modsDone theGraph
 726    = chew theGraph
 727      where
 728         chew [] = []
 729         chew ((AcyclicSCC v):rest) = chew rest    -- acyclic?  not interesting.
 730         chew ((CyclicSCC vs):rest)
 731            = let names_in_this_cycle = nub (map name_of_summary vs)
 732                  mods_in_this_cycle
 733                     = nub ([done | done <- modsDone,
 734                                    done `elem` names_in_this_cycle])
 735                  chewed_rest = chew rest
 736              in
 737              if   not (null mods_in_this_cycle)
 738                   && length mods_in_this_cycle < length names_in_this_cycle
 739              then mods_in_this_cycle ++ chewed_rest
 740              else chewed_rest
 741
 742
 743 -- Add the given (LM-form) Linkables to the UI, overwriting previous
 744 -- versions if they exist.
 745 add_to_ui :: UnlinkedImage -> [Linkable] -> UnlinkedImage
 746 add_to_ui ui lis
 747    = filter (not_in lis) ui ++ lis
 748      where
 749         not_in :: [Linkable] -> Linkable -> Bool
 750         not_in lis li
 751            = all (\l -> linkableModName l /= mod) lis
 752            where mod = linkableModName li
 753
 754
 755 data CmThreaded  -- stuff threaded through individual module compilations
 756    = CmThreaded PersistentCompilerState HomeSymbolTable HomeIfaceTable
 757
 758
 759 -- Compile multiple modules, stopping as soon as an error appears.
 760 -- There better had not be any cyclic groups here -- we check for them.
 761 upsweep_mods :: GhciMode
 762              -> DynFlags
 763              -> UnlinkedImage         -- valid linkables
 764              -> (ModuleName -> [ModuleName])  -- to construct downward closures
 765              -> CmThreaded            -- PCS & HST & HIT
 766              -> [SCC ModSummary]      -- mods to do (the worklist)
 767                                       -- ...... RETURNING ......
 768              -> IO (Bool{-complete success?-},
 769                     CmThreaded,
 770                     [ModSummary],     -- mods which succeeded
 771                     [Linkable])       -- new linkables
 772
 773 upsweep_mods ghci_mode dflags oldUI reachable_from threaded
 774      []
 775    = return (True, threaded, [], [])
 776
 777 upsweep_mods ghci_mode dflags oldUI reachable_from threaded
 778      ((CyclicSCC ms):_)
 779    = do hPutStrLn stderr ("Module imports form a cycle for modules:\n\t" ++
 780                           unwords (map (moduleNameUserString.name_of_summary) ms))
 781         return (False, threaded, [], [])
 782
 783 upsweep_mods ghci_mode dflags oldUI reachable_from threaded
 784      ((AcyclicSCC mod):mods)
 785    = do --case threaded of
 786         --   CmThreaded pcsz hstz hitz
 787         --      -> putStrLn ("UPSWEEP_MOD: hit = " ++ show (map (moduleNameUserString.moduleName.mi_module) (eltsUFM hitz)))
 788
 789         (threaded1, maybe_linkable)
 790            <- upsweep_mod ghci_mode dflags oldUI threaded mod
 791                           (reachable_from (name_of_summary mod))
 792         case maybe_linkable of
 793            Just linkable
 794               -> -- No errors; do the rest
 795                  do (restOK, threaded2, modOKs, linkables)
 796                        <- upsweep_mods ghci_mode dflags oldUI reachable_from
 797                                        threaded1 mods
 798                     return (restOK, threaded2, mod:modOKs, linkable:linkables)
 799            Nothing -- we got a compilation error; give up now
 800               -> return (False, threaded1, [], [])
 801
 802
 803 -- Compile a single module.  Always produce a Linkable for it if
 804 -- successful.  If no compilation happened, return the old Linkable.
 805 upsweep_mod :: GhciMode
 806             -> DynFlags
 807             -> UnlinkedImage
 808             -> CmThreaded
 809             -> ModSummary
 810             -> [ModuleName]
 811             -> IO (CmThreaded, Maybe Linkable)
 812
 813 upsweep_mod ghci_mode dflags oldUI threaded1 summary1 reachable_inc_me
 814    = do
 815         let mod_name = name_of_summary summary1
 816         let verb = verbosity dflags
 817
 818         let (CmThreaded pcs1 hst1 hit1) = threaded1
 819         let old_iface = lookupUFM hit1 mod_name
 820
 821         let maybe_old_linkable = findModuleLinkable_maybe oldUI mod_name
 822
 823             source_unchanged = isJust maybe_old_linkable
 824
 825             reachable_only = filter (/= (name_of_summary summary1))
 826                                 reachable_inc_me
 827
 828            -- in interactive mode, all home modules below us *must* have an
 829            -- interface in the HIT.  We never demand-load home interfaces in
 830            -- interactive mode.
 831             (hst1_strictDC, hit1_strictDC, [])
 832                = ASSERT(ghci_mode == Batch ||
 833                         all (`elemUFM` hit1) reachable_only)
 834                  retainInTopLevelEnvs reachable_only (hst1,hit1,[])
 835
 836             old_linkable
 837                = unJust "upsweep_mod:old_linkable" maybe_old_linkable
 838
 839             have_object
 840                | Just l <- maybe_old_linkable, isObjectLinkable l = True
 841                | otherwise = False
 842
 843         compresult <- compile ghci_mode summary1 source_unchanged
 844                          have_object old_iface hst1_strictDC hit1_strictDC pcs1
 845
 846         case compresult of
 847
 848            -- Compilation "succeeded", and may or may not have returned a new
 849            -- linkable (depending on whether compilation was actually performed
 850            -- or not).
 851            CompOK pcs2 new_details new_iface maybe_new_linkable
 852               -> do let hst2      = addToUFM hst1 mod_name new_details
 853                         hit2      = addToUFM hit1 mod_name new_iface
 854                         threaded2 = CmThreaded pcs2 hst2 hit2
 855
 856                     return (threaded2, if isJust maybe_new_linkable
 857                                           then maybe_new_linkable
 858                                           else Just old_linkable)
 859
 860            -- Compilation failed.  compile may still have updated
 861            -- the PCS, tho.
 862            CompErrs pcs2
 863               -> do let threaded2 = CmThreaded pcs2 hst1 hit1
 864                     return (threaded2, Nothing)
 865
 866 -- Filter modules in the top level envs (HST, HIT, UI).
 867 retainInTopLevelEnvs :: [ModuleName]
 868                         -> (HomeSymbolTable, HomeIfaceTable, UnlinkedImage)
 869                         -> (HomeSymbolTable, HomeIfaceTable, UnlinkedImage)
 870 retainInTopLevelEnvs keep_these (hst, hit, ui)
 871    = (retainInUFM hst keep_these,
 872       retainInUFM hit keep_these,
 873       filterModuleLinkables (`elem` keep_these) ui
 874      )
 875      where
 876         retainInUFM :: Uniquable key => UniqFM elt -> [key] -> UniqFM elt
 877         retainInUFM ufm keys_to_keep
 878            = listToUFM (concatMap (maybeLookupUFM ufm) keys_to_keep)
 879         maybeLookupUFM ufm u
 880            = case lookupUFM ufm u of Nothing -> []; Just val -> [(u, val)]
 881
 882 -- Needed to clean up HIT and HST so that we don't get duplicates in inst env
 883 downwards_closure_of_module :: [ModSummary] -> ModuleName -> [ModuleName]
 884 downwards_closure_of_module summaries root
 885    = let toEdge :: ModSummary -> (ModuleName,[ModuleName])
 886          toEdge summ = (name_of_summary summ,
 887                         filter (`elem` all_mods) (ms_allimps summ))
 888
 889          all_mods = map name_of_summary summaries
 890
 891          res = simple_transitive_closure (map toEdge summaries) [root]
 892      in
 893 --         trace (showSDoc (text "DC of mod" <+> ppr root
 894 --                          <+> text "=" <+> ppr res)) $
 895          res
 896
 897 -- Calculate transitive closures from a set of roots given an adjacency list
 898 simple_transitive_closure :: Eq a => [(a,[a])] -> [a] -> [a]
 899 simple_transitive_closure graph set
 900    = let set2      = nub (concatMap dsts set ++ set)
 901          dsts node = fromMaybe [] (lookup node graph)
 902      in
 903          if   length set == length set2
 904          then set
 905          else simple_transitive_closure graph set2
 906
 907
 908 -- Calculate SCCs of the module graph, with or without taking into
 909 -- account source imports.
 910 topological_sort :: Bool -> [ModSummary] -> [SCC ModSummary]
 911 topological_sort include_source_imports summaries
 912    = let
 913          toEdge :: ModSummary -> (ModSummary,ModuleName,[ModuleName])
 914          toEdge summ
 915              = (summ, name_of_summary summ,
 916                       (if include_source_imports
 917                        then ms_srcimps summ else []) ++ ms_imps summ)
 918
 919          mash_edge :: (ModSummary,ModuleName,[ModuleName]) -> (ModSummary,Int,[Int])
 920          mash_edge (summ, m, m_imports)
 921             = case lookup m key_map of
 922                  Nothing -> panic "reverse_topological_sort"
 923                  Just mk -> (summ, mk,
 924                                 -- ignore imports not from the home package
 925                                 catMaybes (map (flip lookup key_map) m_imports))
 926
 927          edges     = map toEdge summaries
 928          key_map   = zip [nm | (s,nm,imps) <- edges] [1 ..] :: [(ModuleName,Int)]
 929          scc_input = map mash_edge edges
 930          sccs      = stronglyConnComp scc_input
 931      in
 932          sccs
 933
 934
 935 -- Chase downwards from the specified root set, returning summaries
 936 -- for all home modules encountered.  Only follow source-import
 937 -- links.  Also returns a Bool to indicate whether any of the roots
 938 -- are module Main.
 939 downsweep :: [FilePath] -> [ModSummary] -> IO ([ModSummary], Bool)
 940 downsweep rootNm old_summaries
 941    = do rootSummaries <- mapM getRootSummary rootNm
 942         let a_root_is_Main
 943                = any ((=="Main").moduleNameUserString.name_of_summary)
 944                      rootSummaries
 945         all_summaries
 946            <- loop (concat (map ms_imps rootSummaries))
 947                 (mkModuleEnv [ (mod, s) | s <- rootSummaries,
 948                                           let mod = ms_mod s, isHomeModule mod
 949                              ])
 950         return (all_summaries, a_root_is_Main)
 951      where
 952         getRootSummary :: FilePath -> IO ModSummary
 953         getRootSummary file
 954            | haskellish_src_file file
 955            = do exists <- doesFileExist file
 956                 if exists then summariseFile file else do
 957                 throwDyn (CmdLineError ("can't find file `" ++ file ++ "'"))
 958            | otherwise
 959            = do exists <- doesFileExist hs_file
 960                 if exists then summariseFile hs_file else do
 961                 exists <- doesFileExist lhs_file
 962                 if exists then summariseFile lhs_file else do
 963                 let mod_name = mkModuleName file
 964                 maybe_summary <- getSummary mod_name
 965                 case maybe_summary of
 966                    Nothing -> packageModErr mod_name
 967                    Just s  -> return s
 968            where
 969                  hs_file = file ++ ".hs"
 970                  lhs_file = file ++ ".lhs"
 971
 972         getSummary :: ModuleName -> IO (Maybe ModSummary)
 973         getSummary nm
 974            = do found <- findModule nm
 975                 case found of
 976                    Just (mod, location) -> do
 977                         let old_summary = findModInSummaries old_summaries mod
 978                         summarise mod location old_summary
 979
 980                    Nothing -> throwDyn (CmdLineError
 981                                    ("can't find module `"
 982                                      ++ showSDoc (ppr nm) ++ "'"))
 983
 984         -- loop invariant: env doesn't contain package modules
 985         loop :: [ModuleName] -> ModuleEnv ModSummary -> IO [ModSummary]
 986         loop [] env = return (moduleEnvElts env)
 987         loop imps env
 988            = do -- imports for modules we don't already have
 989                 let needed_imps = nub (filter (not . (`elemUFM` env)) imps)
 990
 991                 -- summarise them
 992                 needed_summaries <- mapM getSummary needed_imps
 993
 994                 -- get just the "home" modules
 995                 let new_home_summaries = [ s | Just s <- needed_summaries ]
 996
 997                 -- loop, checking the new imports
 998                 let new_imps = concat (map ms_imps new_home_summaries)
 999                 loop new_imps (extendModuleEnvList env
1000                                 [ (ms_mod s, s) | s <- new_home_summaries ])
1001
1002 -----------------------------------------------------------------------------
1003 -- Summarising modules
1004
1005 -- We have two types of summarisation:
1006 --
1007 --    * Summarise a file.  This is used for the root module passed to
1008 --      cmLoadModule.  The file is read, and used to determine the root
1009 --      module name.  The module name may differ from the filename.
1010 --
1011 --    * Summarise a module.  We are given a module name, and must provide
1012 --      a summary.  The finder is used to locate the file in which the module
1013 --      resides.
1014
1015 summariseFile :: FilePath -> IO ModSummary
1016 summariseFile file
1017    = do hspp_fn <- preprocess file
1018         (srcimps,imps,mod_name) <- getImportsFromFile hspp_fn
1019
1020         let (path, basename, ext) = splitFilename3 file
1021
1022         Just (mod, location)
1023            <- mkHomeModuleLocn mod_name (path ++ '/':basename) (Just file)
1024
1025         src_timestamp
1026            <- case ml_hs_file location of
1027                  Nothing     -> noHsFileErr mod_name
1028                  Just src_fn -> getModificationTime src_fn
1029
1030         return (ModSummary mod
1031                            location{ml_hspp_file=Just hspp_fn}
1032                            srcimps imps src_timestamp)
1033
1034 -- Summarise a module, and pick up source and timestamp.
1035 summarise :: Module -> ModuleLocation -> Maybe ModSummary
1036          -> IO (Maybe ModSummary)
1037 summarise mod location old_summary
1038    | not (isHomeModule mod) = return Nothing
1039    | otherwise
1040    = do let hs_fn = unJust "summarise" (ml_hs_file location)
1041
1042         case ml_hs_file location of {
1043            Nothing -> do {
1044                 dflags <- getDynFlags;
1045                 when (verbosity dflags >= 1) $
1046                     hPutStrLn stderr ("WARNING: module `" ++
1047                         moduleUserString mod ++ "' has no source file.");
1048                 return Nothing;
1049              };
1050
1051            Just src_fn -> do
1052
1053         src_timestamp <- getModificationTime src_fn
1054
1055         -- return the cached summary if the source didn't change
1056         case old_summary of {
1057            Just s | ms_hs_date s == src_timestamp -> return (Just s);
1058            _ -> do
1059
1060         hspp_fn <- preprocess hs_fn
1061         (srcimps,imps,mod_name) <- getImportsFromFile hspp_fn
1062
1063         when (mod_name /= moduleName mod) $
1064                 throwDyn (ProgramError
1065                    (showSDoc (text hs_fn
1066                               <>  text ": file name does not match module name"
1067                               <+> quotes (ppr (moduleName mod)))))
1068
1069         return (Just (ModSummary mod location{ml_hspp_file=Just hspp_fn}
1070                                  srcimps imps src_timestamp))
1071         }
1072       }
1073
1074
1075 noHsFileErr mod
1076   = throwDyn (CmdLineError (showSDoc (text "no source file for module" <+> quotes (ppr mod))))
1077
1078 packageModErr mod
1079   = throwDyn (CmdLineError (showSDoc (text "module" <+>
1080                                    quotes (ppr mod) <+>
1081                                    text "is a package module")))
1082 \end{code}