ghc/compiler/compMan/CompManager.lhs

   1 %
   2 % (c) The University of Glasgow, 2000
   3 %
   4 \section[CompManager]{The Compilation Manager}
   5
   6 \begin{code}
   7 module CompManager (
   8     cmInit,       -- :: GhciMode -> IO CmState
   9
  10     cmLoadModule, -- :: CmState -> FilePath -> IO (CmState, [String])
  11
  12     cmUnload,     -- :: CmState -> DynFlags -> IO CmState
  13
  14     cmSetContext, -- :: CmState -> String -> IO CmState
  15
  16     cmGetContext, -- :: CmState -> IO String
  17
  18 #ifdef GHCI
  19     cmRunStmt,    --  :: CmState -> DynFlags -> String -> IO (CmState, [Name])
  20
  21     cmTypeOfExpr, --  :: CmState -> DynFlags -> String
  22                   --  -> IO (CmState, Maybe String)
  23
  24     cmTypeOfName, -- :: CmState -> Name -> IO (Maybe String)
  25
  26     cmCompileExpr,-- :: CmState -> DynFlags -> String
  27                   -- -> IO (CmState, Maybe HValue)#endif
  28 #endif
  29     CmState, emptyCmState  -- abstract
  30   )
  31 where
  32
  33 #include "HsVersions.h"
  34
  35 import CmLink
  36 import CmTypes
  37 import DriverPipeline
  38 import DriverFlags      ( getDynFlags )
  39 import DriverPhases
  40 import DriverUtil
  41 import Finder
  42 import HscMain          ( initPersistentCompilerState )
  43 import HscTypes
  44 import RnEnv            ( unQualInScope )
  45 import Id               ( idType, idName )
  46 import Name             ( Name, NamedThing(..), nameRdrName )
  47 import NameEnv
  48 import RdrName          ( lookupRdrEnv, emptyRdrEnv )
  49 import Module
  50 import GetImports
  51 import Type             ( tidyType )
  52 import VarEnv           ( emptyTidyEnv )
  53 import UniqFM
  54 import Unique           ( Uniquable )
  55 import Digraph          ( SCC(..), stronglyConnComp, flattenSCC )
  56 import ErrUtils         ( showPass )
  57 import SysTools         ( cleanTempFilesExcept )
  58 import Util
  59 import Outputable
  60 import Panic
  61 import CmdLineOpts      ( DynFlags(..) )
  62 import IOExts
  63
  64 #ifdef GHCI
  65 import Interpreter      ( HValue )
  66 import HscMain          ( hscStmt )
  67 import PrelGHC          ( unsafeCoerce# )
  68 #endif
  69
  70 -- lang
  71 import Exception        ( throwDyn )
  72
  73 -- std
  74 import Directory        ( getModificationTime, doesFileExist )
  75 import IO
  76 import Monad
  77 import List             ( nub )
  78 import Maybe
  79 \end{code}
  80
  81
  82 \begin{code}
  83 -- Persistent state for the entire system
  84 data CmState
  85    = CmState {
  86         hst   :: HomeSymbolTable,    -- home symbol table
  87         hit   :: HomeIfaceTable,     -- home interface table
  88         ui    :: UnlinkedImage,      -- the unlinked images
  89         mg    :: ModuleGraph,        -- the module graph
  90         gmode :: GhciMode,           -- NEVER CHANGES
  91         ic    :: InteractiveContext, -- command-line binding info
  92
  93         pcs    :: PersistentCompilerState, -- compile's persistent state
  94         pls    :: PersistentLinkerState    -- link's persistent state
  95      }
  96
  97 emptyCmState :: GhciMode -> Module -> IO CmState
  98 emptyCmState gmode mod
  99     = do pcs     <- initPersistentCompilerState
 100          pls     <- emptyPLS
 101          return (CmState { hst    = emptySymbolTable,
 102                            hit    = emptyIfaceTable,
 103                            ui     = emptyUI,
 104                            mg     = emptyMG,
 105                            gmode  = gmode,
 106                            ic     = emptyInteractiveContext mod,
 107                            pcs    = pcs,
 108                            pls    = pls })
 109
 110 emptyInteractiveContext mod
 111   = InteractiveContext { ic_module = mod,
 112                          ic_rn_env = emptyRdrEnv,
 113                          ic_type_env = emptyTypeEnv }
 114
 115 defaultCurrentModuleName = mkModuleName "Prelude"
 116 GLOBAL_VAR(defaultCurrentModule, error "no defaultCurrentModule", Module)
 117
 118 -- CM internal types
 119 type UnlinkedImage = [Linkable] -- the unlinked images (should be a set, really)
 120 emptyUI :: UnlinkedImage
 121 emptyUI = []
 122
 123 type ModuleGraph = [ModSummary]  -- the module graph, topologically sorted
 124 emptyMG :: ModuleGraph
 125 emptyMG = []
 126
 127 -----------------------------------------------------------------------------
 128 -- Produce an initial CmState.
 129
 130 cmInit :: GhciMode -> IO CmState
 131 cmInit mode = do
 132    prel <- moduleNameToModule defaultCurrentModuleName
 133    writeIORef defaultCurrentModule prel
 134    emptyCmState mode prel
 135
 136 -----------------------------------------------------------------------------
 137 -- Setting the context doesn't throw away any bindings; the bindings
 138 -- we've built up in the InteractiveContext simply move to the new
 139 -- module.  They always shadow anything in scope in the current context.
 140
 141 cmSetContext :: CmState -> String -> IO CmState
 142 cmSetContext cmstate str
 143    = do let mn = mkModuleName str
 144             modules_loaded = [ (name_of_summary s, ms_mod s)  | s <- mg cmstate ]
 145
 146         m <- case lookup mn modules_loaded of
 147                 Just m  -> return m
 148                 Nothing -> do
 149                    mod <- moduleNameToModule mn
 150                    if isHomeModule mod
 151                         then throwDyn (CmdLineError (showSDoc
 152                                 (quotes (ppr (moduleName mod))
 153                                   <+> text "is not currently loaded")))
 154                         else return mod
 155
 156         return cmstate{ ic = (ic cmstate){ic_module=m} }
 157
 158 cmGetContext :: CmState -> IO String
 159 cmGetContext cmstate = return (moduleUserString (ic_module (ic cmstate)))
 160
 161 moduleNameToModule :: ModuleName -> IO Module
 162 moduleNameToModule mn
 163  = do maybe_stuff <- findModule mn
 164       case maybe_stuff of
 165         Nothing -> throwDyn (CmdLineError ("can't find module `"
 166                                     ++ moduleNameUserString mn ++ "'"))
 167         Just (m,_) -> return m
 168
 169 -----------------------------------------------------------------------------
 170 -- cmRunStmt:  Run a statement/expr.
 171
 172 #ifdef GHCI
 173 cmRunStmt :: CmState -> DynFlags -> String
 174         -> IO (CmState,                 -- new state
 175                [Name])                  -- names bound by this evaluation
 176 cmRunStmt cmstate dflags expr
 177    = do
 178         let InteractiveContext {
 179                 ic_rn_env = rn_env,
 180                 ic_type_env = type_env,
 181                 ic_module   = this_mod } = icontext
 182
 183         (new_pcs, maybe_stuff)
 184             <- hscStmt dflags hst hit pcs icontext expr False{-stmt-}
 185
 186         case maybe_stuff of
 187            Nothing -> return (cmstate{ pcs=new_pcs }, [])
 188            Just (ids, _, bcos) -> do
 189
 190                 -- update the interactive context
 191                 let
 192                     names = map idName ids
 193
 194                     -- these names have just been shadowed
 195                     shadowed = [ n | r <- map nameRdrName names,
 196                                      Just n <- [lookupRdrEnv rn_env r] ]
 197
 198                     new_rn_env   = extendLocalRdrEnv rn_env names
 199
 200                     -- remove any shadowed bindings from the type_env
 201                     filtered_type_env = delListFromNameEnv type_env shadowed
 202
 203                     new_type_env = extendNameEnvList filtered_type_env
 204                                         [ (getName id, AnId id) | id <- ids]
 205
 206                     new_ic = icontext { ic_rn_env   = new_rn_env,
 207                                         ic_type_env = new_type_env }
 208
 209                 -- link it
 210                 hval <- linkExpr pls bcos
 211
 212                 -- run it!
 213                 let thing_to_run = unsafeCoerce# hval :: IO [HValue]
 214                 hvals <- thing_to_run
 215
 216                 -- Get the newly bound things, and bind them.  Don't forget
 217                 -- to delete any shadowed bindings from the closure_env, lest
 218                 -- we end up with a space leak.
 219                 pls <- delListFromClosureEnv pls shadowed
 220                 new_pls <- addListToClosureEnv pls (zip names hvals)
 221
 222                 return (cmstate{ pcs=new_pcs, pls=new_pls, ic=new_ic }, names)
 223    where
 224        CmState{ hst=hst, hit=hit, pcs=pcs, pls=pls, ic=icontext } = cmstate
 225 #endif
 226
 227 -----------------------------------------------------------------------------
 228 -- cmTypeOfExpr: returns a string representing the type of an expression
 229
 230 #ifdef GHCI
 231 cmTypeOfExpr :: CmState -> DynFlags -> String -> IO (CmState, Maybe String)
 232 cmTypeOfExpr cmstate dflags expr
 233    = do (new_pcs, maybe_stuff)
 234           <- hscStmt dflags hst hit pcs ic expr True{-just an expr-}
 235
 236         let new_cmstate = cmstate{pcs = new_pcs}
 237
 238         case maybe_stuff of
 239            Nothing -> return (new_cmstate, Nothing)
 240            Just (_, ty, _) ->
 241              let pit = pcs_PIT pcs
 242                  modname = moduleName (ic_module ic)
 243                  tidy_ty = tidyType emptyTidyEnv ty
 244                  str = case lookupIfaceByModName hit pit modname of
 245                           Nothing    -> showSDoc (ppr tidy_ty)
 246                           Just iface -> showSDocForUser unqual (ppr tidy_ty)
 247                              where unqual = unQualInScope (mi_globals iface)
 248              in return (new_cmstate, Just str)
 249    where
 250        CmState{ hst=hst, hit=hit, pcs=pcs, ic=ic } = cmstate
 251 #endif
 252
 253 -----------------------------------------------------------------------------
 254 -- cmTypeOfName: returns a string representing the type of a name.
 255
 256 #ifdef GHCI
 257 cmTypeOfName :: CmState -> Name -> IO (Maybe String)
 258 cmTypeOfName CmState{ hit=hit, pcs=pcs, ic=ic } name
 259  = case lookupNameEnv (ic_type_env ic) name of
 260         Nothing -> return Nothing
 261         Just (AnId id) ->
 262            let pit = pcs_PIT pcs
 263                modname = moduleName (ic_module ic)
 264                ty = tidyType emptyTidyEnv (idType id)
 265                str = case lookupIfaceByModName hit pit modname of
 266                         Nothing    -> showSDoc (ppr ty)
 267                         Just iface -> showSDocForUser unqual (ppr ty)
 268                            where unqual = unQualInScope (mi_globals iface)
 269            in return (Just str)
 270
 271         _ -> panic "cmTypeOfName"
 272 #endif
 273
 274 -----------------------------------------------------------------------------
 275 -- cmCompileExpr: compile an expression and deliver an HValue
 276
 277 #ifdef GHCI
 278 cmCompileExpr :: CmState -> DynFlags -> String -> IO (CmState, Maybe HValue)
 279 cmCompileExpr cmstate dflags expr
 280    = do
 281         let InteractiveContext {
 282                 ic_rn_env = rn_env,
 283                 ic_type_env = type_env,
 284                 ic_module   = this_mod } = icontext
 285
 286         (new_pcs, maybe_stuff)
 287             <- hscStmt dflags hst hit pcs icontext
 288                   ("let __cmCompileExpr = "++expr) False{-stmt-}
 289
 290         case maybe_stuff of
 291            Nothing -> return (cmstate{ pcs=new_pcs }, Nothing)
 292            Just (ids, _, bcos) -> do
 293
 294                 -- link it
 295                 hval <- linkExpr pls bcos
 296
 297                 -- run it!
 298                 let thing_to_run = unsafeCoerce# hval :: IO [HValue]
 299                 hvals <- thing_to_run
 300
 301                 case (ids,hvals) of
 302                   ([id],[hv]) -> return (cmstate{ pcs=new_pcs }, Just hv)
 303                   _ -> panic "cmCompileExpr"
 304
 305    where
 306        CmState{ hst=hst, hit=hit, pcs=pcs, pls=pls, ic=icontext } = cmstate
 307 #endif
 308
 309 -----------------------------------------------------------------------------
 310 -- cmInfo: return "info" about an expression.  The info might be:
 311 --
 312 --      * its type, for an expression,
 313 --      * the class definition, for a class
 314 --      * the datatype definition, for a tycon (or synonym)
 315 --      * the export list, for a module
 316 --
 317 -- Can be used to find the type of the last expression compiled, by looking
 318 -- for "it".
 319
 320 cmInfo :: CmState -> String -> IO (Maybe String)
 321 cmInfo cmstate str
 322  = do error "cmInfo not implemented yet"
 323
 324 -----------------------------------------------------------------------------
 325 -- Unload the compilation manager's state: everything it knows about the
 326 -- current collection of modules in the Home package.
 327
 328 cmUnload :: CmState -> DynFlags -> IO CmState
 329 cmUnload state@CmState{ gmode=mode, pls=pls, pcs=pcs } dflags
 330  = do -- Throw away the old home dir cache
 331       emptyHomeDirCache
 332
 333       -- Unload everything the linker knows about
 334       new_pls <- CmLink.unload mode dflags [] pls
 335
 336       -- Start with a fresh CmState, but keep the PersistentCompilerState
 337       new_state <- cmInit mode
 338       return new_state{ pcs=pcs, pls=new_pls }
 339
 340 -----------------------------------------------------------------------------
 341 -- The real business of the compilation manager: given a system state and
 342 -- a module name, try and bring the module up to date, probably changing
 343 -- the system state at the same time.
 344
 345 cmLoadModule :: CmState
 346              -> FilePath
 347              -> IO (CmState,            -- new state
 348                     Bool,               -- was successful
 349                     [String])           -- list of modules loaded
 350
 351 cmLoadModule cmstate1 rootname
 352    = do -- version 1's are the original, before downsweep
 353         let pls1      = pls    cmstate1
 354         let pcs1      = pcs    cmstate1
 355         let hst1      = hst    cmstate1
 356         let hit1      = hit    cmstate1
 357         -- similarly, ui1 is the (complete) set of linkables from
 358         -- the previous pass, if any.
 359         let ui1       = ui     cmstate1
 360         let mg1       = mg     cmstate1
 361         let ic1       = ic     cmstate1
 362
 363         let ghci_mode = gmode cmstate1 -- this never changes
 364
 365         -- Do the downsweep to reestablish the module graph
 366         dflags <- getDynFlags
 367         let verb = verbosity dflags
 368
 369         showPass dflags "Chasing dependencies"
 370         when (verb >= 1 && ghci_mode == Batch) $
 371            hPutStrLn stderr (progName ++ ": chasing modules from: " ++ rootname)
 372
 373         (mg2unsorted, a_root_is_Main) <- downsweep [rootname] mg1
 374         let mg2unsorted_names = map name_of_summary mg2unsorted
 375
 376         -- reachable_from follows source as well as normal imports
 377         let reachable_from :: ModuleName -> [ModuleName]
 378             reachable_from = downwards_closure_of_module mg2unsorted
 379
 380         -- should be cycle free; ignores 'import source's
 381         let mg2 = topological_sort False mg2unsorted
 382         -- ... whereas this takes them into account.  Used for
 383         -- backing out partially complete cycles following a failed
 384         -- upsweep, and for removing from hst/hit all the modules
 385         -- not in strict downwards closure, during calls to compile.
 386         let mg2_with_srcimps = topological_sort True mg2unsorted
 387
 388         -- Sort out which linkables we wish to keep in the unlinked image.
 389         -- See getValidLinkables below for details.
 390         valid_linkables <- getValidLinkables ui1 mg2unsorted_names
 391                                 mg2_with_srcimps
 392         -- when (verb >= 2) $
 393         --    putStrLn (showSDoc (text "Valid linkables:"
 394         --                       <+> ppr valid_linkables))
 395
 396         -- Figure out a stable set of modules which can be retained
 397         -- the top level envs, to avoid upsweeping them.  Goes to a
 398         -- bit of trouble to avoid upsweeping module cycles.
 399         --
 400         -- Construct a set S of stable modules like this:
 401         -- Travel upwards, over the sccified graph.  For each scc
 402         -- of modules ms, add ms to S only if:
 403         -- 1.  All home imports of ms are either in ms or S
 404         -- 2.  A valid linkable exists for each module in ms
 405
 406         stable_mods <- preUpsweep valid_linkables hit1
 407                                   mg2unsorted_names [] mg2_with_srcimps
 408
 409         let stable_summaries
 410                = concatMap (findInSummaries mg2unsorted) stable_mods
 411
 412             stable_linkables
 413                = filter (\m -> linkableModName m `elem` stable_mods)
 414                     valid_linkables
 415
 416         when (verb >= 2) $
 417            putStrLn (showSDoc (text "Stable modules:"
 418                                <+> sep (map (text.moduleNameUserString) stable_mods)))
 419
 420         -- unload any modules which aren't going to be re-linked this
 421         -- time around.
 422         pls2 <- unload ghci_mode dflags stable_linkables pls1
 423
 424         -- We could at this point detect cycles which aren't broken by
 425         -- a source-import, and complain immediately, but it seems better
 426         -- to let upsweep_mods do this, so at least some useful work gets
 427         -- done before the upsweep is abandoned.
 428         let upsweep_these
 429                = filter (\scc -> any (`notElem` stable_mods)
 430                                      (map name_of_summary (flattenSCC scc)))
 431                         mg2
 432
 433         --hPutStrLn stderr "after tsort:\n"
 434         --hPutStrLn stderr (showSDoc (vcat (map ppr mg2)))
 435
 436         -- Because we don't take into account source imports when doing
 437         -- the topological sort, there shouldn't be any cycles in mg2.
 438         -- If there is, we complain and give up -- the user needs to
 439         -- break the cycle using a boot file.
 440
 441         -- Now do the upsweep, calling compile for each module in
 442         -- turn.  Final result is version 3 of everything.
 443
 444         let threaded2 = CmThreaded pcs1 hst1 hit1
 445
 446         (upsweep_complete_success, threaded3, modsUpswept, newLis)
 447            <- upsweep_mods ghci_mode dflags valid_linkables reachable_from
 448                            threaded2 upsweep_these
 449
 450         let ui3 = add_to_ui valid_linkables newLis
 451         let (CmThreaded pcs3 hst3 hit3) = threaded3
 452
 453         -- At this point, modsUpswept and newLis should have the same
 454         -- length, so there is one new (or old) linkable for each
 455         -- mod which was processed (passed to compile).
 456
 457         -- Make modsDone be the summaries for each home module now
 458         -- available; this should equal the domains of hst3 and hit3.
 459         -- (NOT STRICTLY TRUE if an interactive session was started
 460         --  with some object on disk ???)
 461         -- Get in in a roughly top .. bottom order (hence reverse).
 462
 463         let modsDone = reverse modsUpswept ++ stable_summaries
 464
 465         -- Try and do linking in some form, depending on whether the
 466         -- upsweep was completely or only partially successful.
 467
 468         if upsweep_complete_success
 469
 470          then
 471            -- Easy; just relink it all.
 472            do when (verb >= 2) $
 473                  hPutStrLn stderr "Upsweep completely successful."
 474
 475               -- clean up after ourselves
 476               cleanTempFilesExcept verb (ppFilesFromSummaries modsDone)
 477
 478               -- link everything together
 479               linkresult <- link ghci_mode dflags a_root_is_Main ui3 pls2
 480
 481               cmLoadFinish True linkresult
 482                         hst3 hit3 ui3 modsDone ghci_mode pcs3
 483
 484          else
 485            -- Tricky.  We need to back out the effects of compiling any
 486            -- half-done cycles, both so as to clean up the top level envs
 487            -- and to avoid telling the interactive linker to link them.
 488            do when (verb >= 2) $
 489                 hPutStrLn stderr "Upsweep partially successful."
 490
 491               let modsDone_names
 492                      = map name_of_summary modsDone
 493               let mods_to_zap_names
 494                      = findPartiallyCompletedCycles modsDone_names
 495                           mg2_with_srcimps
 496               let mods_to_keep
 497                      = filter ((`notElem` mods_to_zap_names).name_of_summary)
 498                           modsDone
 499
 500               let (hst4, hit4, ui4)
 501                      = retainInTopLevelEnvs (map name_of_summary mods_to_keep)
 502                                             (hst3,hit3,ui3)
 503
 504               -- clean up after ourselves
 505               cleanTempFilesExcept verb (ppFilesFromSummaries mods_to_keep)
 506
 507               -- link everything together
 508               linkresult <- link ghci_mode dflags False ui4 pls2
 509
 510               cmLoadFinish False linkresult
 511                     hst4 hit4 ui4 mods_to_keep ghci_mode pcs3
 512
 513
 514 -- Finish up after a cmLoad.
 515 --
 516 -- Empty the interactive context and set the module context to the topmost
 517 -- newly loaded module, or the Prelude if none were loaded.
 518 cmLoadFinish ok linkresult hst hit ui mods ghci_mode pcs
 519   = do case linkresult of {
 520           LinkErrs _ _ -> panic "cmLoadModule: link failed (2)";
 521           LinkOK pls   -> do
 522
 523        def_mod <- readIORef defaultCurrentModule
 524        let current_mod = case mods of
 525                                 []    -> def_mod
 526                                 (x:_) -> ms_mod x
 527
 528            new_ic = emptyInteractiveContext current_mod
 529
 530            new_cmstate = CmState{ hst=hst, hit=hit,
 531                                   ui=ui, mg=mods,
 532                                   gmode=ghci_mode, pcs=pcs,
 533                                   pls=pls,
 534                                   ic = new_ic }
 535            mods_loaded = map (moduleNameUserString.name_of_summary) mods
 536
 537        return (new_cmstate, ok, mods_loaded)
 538     }
 539
 540 ppFilesFromSummaries summaries
 541   = [ fn | Just fn <- map (ml_hspp_file . ms_location) summaries ]
 542
 543 -----------------------------------------------------------------------------
 544 -- getValidLinkables
 545
 546 -- For each module (or SCC of modules), we take:
 547 --
 548 --      - an on-disk linkable, if this is the first time around and one
 549 --        is available.
 550 --
 551 --      - the old linkable, otherwise (and if one is available).
 552 --
 553 -- and we throw away the linkable if it is older than the source
 554 -- file.  We ignore the on-disk linkables unless all of the dependents
 555 -- of this SCC also have on-disk linkables.
 556 --
 557 -- If a module has a valid linkable, then it may be STABLE (see below),
 558 -- and it is classified as SOURCE UNCHANGED for the purposes of calling
 559 -- compile.
 560 --
 561 -- ToDo: this pass could be merged with the preUpsweep.
 562
 563 getValidLinkables
 564         :: [Linkable]           -- old linkables
 565         -> [ModuleName]         -- all home modules
 566         -> [SCC ModSummary]     -- all modules in the program, dependency order
 567         -> IO [Linkable]        -- still-valid linkables
 568
 569 getValidLinkables old_linkables all_home_mods module_graph
 570   = foldM (getValidLinkablesSCC old_linkables all_home_mods) [] module_graph
 571
 572 getValidLinkablesSCC old_linkables all_home_mods new_linkables scc0
 573    = let
 574           scc             = flattenSCC scc0
 575           scc_names       = map name_of_summary scc
 576           home_module m   = m `elem` all_home_mods && m `notElem` scc_names
 577           scc_allhomeimps = nub (filter home_module (concatMap ms_imps scc))
 578                 -- NOTE: ms_imps, not ms_allimps above.  We don't want to
 579                 -- force a module's SOURCE imports to be already compiled for
 580                 -- its object linkable to be valid.
 581
 582           has_object m = case findModuleLinkable_maybe new_linkables m of
 583                             Nothing -> False
 584                             Just l  -> isObjectLinkable l
 585
 586           objects_allowed = all has_object scc_allhomeimps
 587      in do
 588
 589      these_linkables
 590         <- foldM (getValidLinkable old_linkables objects_allowed) [] scc
 591
 592         -- since an scc can contain only all objects or no objects at all,
 593         -- we have to check whether we got all objects or not, and re-do
 594         -- the linkable check if not.
 595      adjusted_linkables
 596         <- if objects_allowed && not (all isObjectLinkable these_linkables)
 597               then foldM (getValidLinkable old_linkables False) [] scc
 598               else return these_linkables
 599
 600      return (adjusted_linkables ++ new_linkables)
 601
 602
 603 getValidLinkable :: [Linkable] -> Bool -> [Linkable] -> ModSummary
 604         -> IO [Linkable]
 605 getValidLinkable old_linkables objects_allowed new_linkables summary
 606   = do let mod_name = name_of_summary summary
 607
 608        maybe_disk_linkable
 609           <- if (not objects_allowed)
 610                 then return Nothing
 611                 else case ml_obj_file (ms_location summary) of
 612                         Just obj_fn -> maybe_getFileLinkable mod_name obj_fn
 613                         Nothing -> return Nothing
 614
 615        let old_linkable = findModuleLinkable_maybe old_linkables mod_name
 616            maybe_old_linkable =
 617                 case old_linkable of
 618                     Just l | not (isObjectLinkable l) || stillThere l
 619                                 -> old_linkable
 620                                 -- ToDo: emit a warning if not (stillThere l)
 621                     other -> Nothing
 622
 623            -- make sure that if we had an old disk linkable around, that it's
 624            -- still there on the disk (in case we need to re-link it).
 625            stillThere l =
 626                 case maybe_disk_linkable of
 627                    Nothing    -> False
 628                    Just l_disk -> linkableTime l == linkableTime l_disk
 629
 630            -- we only look for objects on disk the first time around;
 631            -- if the user compiles a module on the side during a GHCi session,
 632            -- it won't be picked up until the next ":load".  This is what the
 633            -- "null old_linkables" test below is.
 634            linkable | null old_linkables = maybeToList maybe_disk_linkable
 635                     | otherwise          = maybeToList maybe_old_linkable
 636
 637            -- only linkables newer than the source code are valid
 638            src_date = ms_hs_date summary
 639
 640            valid_linkable
 641               =  filter (\l -> linkableTime l > src_date) linkable
 642
 643        return (valid_linkable ++ new_linkables)
 644
 645
 646 maybe_getFileLinkable :: ModuleName -> FilePath -> IO (Maybe Linkable)
 647 maybe_getFileLinkable mod_name obj_fn
 648    = do obj_exist <- doesFileExist obj_fn
 649         if not obj_exist
 650          then return Nothing
 651          else
 652          do let stub_fn = case splitFilename3 obj_fn of
 653                              (dir, base, ext) -> dir ++ "/" ++ base ++ ".stub_o"
 654             stub_exist <- doesFileExist stub_fn
 655             obj_time <- getModificationTime obj_fn
 656             if stub_exist
 657              then return (Just (LM obj_time mod_name [DotO obj_fn, DotO stub_fn]))
 658              else return (Just (LM obj_time mod_name [DotO obj_fn]))
 659
 660
 661 -----------------------------------------------------------------------------
 662 -- Do a pre-upsweep without use of "compile", to establish a
 663 -- (downward-closed) set of stable modules for which we won't call compile.
 664
 665 -- a stable module:
 666 --      * has a valid linkable (see getValidLinkables above)
 667 --      * depends only on stable modules
 668 --      * has an interface in the HIT (interactive mode only)
 669
 670 preUpsweep :: [Linkable]        -- new valid linkables
 671            -> HomeIfaceTable
 672            -> [ModuleName]      -- names of all mods encountered in downsweep
 673            -> [ModuleName]      -- accumulating stable modules
 674            -> [SCC ModSummary]  -- scc-ified mod graph, including src imps
 675            -> IO [ModuleName]   -- stable modules
 676
 677 preUpsweep valid_lis hit all_home_mods stable []  = return stable
 678 preUpsweep valid_lis hit all_home_mods stable (scc0:sccs)
 679    = do let scc = flattenSCC scc0
 680             scc_allhomeimps :: [ModuleName]
 681             scc_allhomeimps
 682                = nub (filter (`elem` all_home_mods) (concatMap ms_allimps scc))
 683             all_imports_in_scc_or_stable
 684                = all in_stable_or_scc scc_allhomeimps
 685             scc_names
 686                = map name_of_summary scc
 687             in_stable_or_scc m
 688                = m `elem` scc_names || m `elem` stable
 689
 690             -- now we check for valid linkables: each module in the SCC must
 691             -- have a valid linkable (see getValidLinkables above).
 692             has_valid_linkable new_summary
 693               = isJust (findModuleLinkable_maybe valid_lis modname)
 694                where modname = name_of_summary new_summary
 695
 696             has_interface summary = ms_mod summary `elemUFM` hit
 697
 698             scc_is_stable = all_imports_in_scc_or_stable
 699                           && all has_valid_linkable scc
 700                           && all has_interface scc
 701
 702         if scc_is_stable
 703          then preUpsweep valid_lis hit all_home_mods (scc_names++stable) sccs
 704          else preUpsweep valid_lis hit all_home_mods stable sccs
 705
 706
 707 -- Helper for preUpsweep.  Assuming that new_summary's imports are all
 708 -- stable (in the sense of preUpsweep), determine if new_summary is itself
 709 -- stable, and, if so, in batch mode, return its linkable.
 710 findInSummaries :: [ModSummary] -> ModuleName -> [ModSummary]
 711 findInSummaries old_summaries mod_name
 712    = [s | s <- old_summaries, name_of_summary s == mod_name]
 713
 714 findModInSummaries :: [ModSummary] -> Module -> Maybe ModSummary
 715 findModInSummaries old_summaries mod
 716    = case [s | s <- old_summaries, ms_mod s == mod] of
 717          [] -> Nothing
 718          (s:_) -> Just s
 719
 720 -- Return (names of) all those in modsDone who are part of a cycle
 721 -- as defined by theGraph.
 722 findPartiallyCompletedCycles :: [ModuleName] -> [SCC ModSummary] -> [ModuleName]
 723 findPartiallyCompletedCycles modsDone theGraph
 724    = chew theGraph
 725      where
 726         chew [] = []
 727         chew ((AcyclicSCC v):rest) = chew rest    -- acyclic?  not interesting.
 728         chew ((CyclicSCC vs):rest)
 729            = let names_in_this_cycle = nub (map name_of_summary vs)
 730                  mods_in_this_cycle
 731                     = nub ([done | done <- modsDone,
 732                                    done `elem` names_in_this_cycle])
 733                  chewed_rest = chew rest
 734              in
 735              if   not (null mods_in_this_cycle)
 736                   && length mods_in_this_cycle < length names_in_this_cycle
 737              then mods_in_this_cycle ++ chewed_rest
 738              else chewed_rest
 739
 740
 741 -- Add the given (LM-form) Linkables to the UI, overwriting previous
 742 -- versions if they exist.
 743 add_to_ui :: UnlinkedImage -> [Linkable] -> UnlinkedImage
 744 add_to_ui ui lis
 745    = filter (not_in lis) ui ++ lis
 746      where
 747         not_in :: [Linkable] -> Linkable -> Bool
 748         not_in lis li
 749            = all (\l -> linkableModName l /= mod) lis
 750            where mod = linkableModName li
 751
 752
 753 data CmThreaded  -- stuff threaded through individual module compilations
 754    = CmThreaded PersistentCompilerState HomeSymbolTable HomeIfaceTable
 755
 756
 757 -- Compile multiple modules, stopping as soon as an error appears.
 758 -- There better had not be any cyclic groups here -- we check for them.
 759 upsweep_mods :: GhciMode
 760              -> DynFlags
 761              -> UnlinkedImage         -- valid linkables
 762              -> (ModuleName -> [ModuleName])  -- to construct downward closures
 763              -> CmThreaded            -- PCS & HST & HIT
 764              -> [SCC ModSummary]      -- mods to do (the worklist)
 765                                       -- ...... RETURNING ......
 766              -> IO (Bool{-complete success?-},
 767                     CmThreaded,
 768                     [ModSummary],     -- mods which succeeded
 769                     [Linkable])       -- new linkables
 770
 771 upsweep_mods ghci_mode dflags oldUI reachable_from threaded
 772      []
 773    = return (True, threaded, [], [])
 774
 775 upsweep_mods ghci_mode dflags oldUI reachable_from threaded
 776      ((CyclicSCC ms):_)
 777    = do hPutStrLn stderr ("Module imports form a cycle for modules:\n\t" ++
 778                           unwords (map (moduleNameUserString.name_of_summary) ms))
 779         return (False, threaded, [], [])
 780
 781 upsweep_mods ghci_mode dflags oldUI reachable_from threaded
 782      ((AcyclicSCC mod):mods)
 783    = do --case threaded of
 784         --   CmThreaded pcsz hstz hitz
 785         --      -> putStrLn ("UPSWEEP_MOD: hit = " ++ show (map (moduleNameUserString.moduleName.mi_module) (eltsUFM hitz)))
 786
 787         (threaded1, maybe_linkable)
 788            <- upsweep_mod ghci_mode dflags oldUI threaded mod
 789                           (reachable_from (name_of_summary mod))
 790         case maybe_linkable of
 791            Just linkable
 792               -> -- No errors; do the rest
 793                  do (restOK, threaded2, modOKs, linkables)
 794                        <- upsweep_mods ghci_mode dflags oldUI reachable_from
 795                                        threaded1 mods
 796                     return (restOK, threaded2, mod:modOKs, linkable:linkables)
 797            Nothing -- we got a compilation error; give up now
 798               -> return (False, threaded1, [], [])
 799
 800
 801 -- Compile a single module.  Always produce a Linkable for it if
 802 -- successful.  If no compilation happened, return the old Linkable.
 803 upsweep_mod :: GhciMode
 804             -> DynFlags
 805             -> UnlinkedImage
 806             -> CmThreaded
 807             -> ModSummary
 808             -> [ModuleName]
 809             -> IO (CmThreaded, Maybe Linkable)
 810
 811 upsweep_mod ghci_mode dflags oldUI threaded1 summary1 reachable_inc_me
 812    = do
 813         let mod_name = name_of_summary summary1
 814         let verb = verbosity dflags
 815
 816         let (CmThreaded pcs1 hst1 hit1) = threaded1
 817         let old_iface = lookupUFM hit1 mod_name
 818
 819         let maybe_old_linkable = findModuleLinkable_maybe oldUI mod_name
 820
 821             source_unchanged = isJust maybe_old_linkable
 822
 823             reachable_only = filter (/= (name_of_summary summary1))
 824                                 reachable_inc_me
 825
 826            -- in interactive mode, all home modules below us *must* have an
 827            -- interface in the HIT.  We never demand-load home interfaces in
 828            -- interactive mode.
 829             (hst1_strictDC, hit1_strictDC, [])
 830                = ASSERT(ghci_mode == Batch ||
 831                         all (`elemUFM` hit1) reachable_only)
 832                  retainInTopLevelEnvs reachable_only (hst1,hit1,[])
 833
 834             old_linkable
 835                = unJust "upsweep_mod:old_linkable" maybe_old_linkable
 836
 837             have_object
 838                | Just l <- maybe_old_linkable, isObjectLinkable l = True
 839                | otherwise = False
 840
 841         compresult <- compile ghci_mode summary1 source_unchanged
 842                          have_object old_iface hst1_strictDC hit1_strictDC pcs1
 843
 844         case compresult of
 845
 846            -- Compilation "succeeded", and may or may not have returned a new
 847            -- linkable (depending on whether compilation was actually performed
 848            -- or not).
 849            CompOK pcs2 new_details new_iface maybe_new_linkable
 850               -> do let hst2      = addToUFM hst1 mod_name new_details
 851                         hit2      = addToUFM hit1 mod_name new_iface
 852                         threaded2 = CmThreaded pcs2 hst2 hit2
 853
 854                     return (threaded2, if isJust maybe_new_linkable
 855                                           then maybe_new_linkable
 856                                           else Just old_linkable)
 857
 858            -- Compilation failed.  compile may still have updated
 859            -- the PCS, tho.
 860            CompErrs pcs2
 861               -> do let threaded2 = CmThreaded pcs2 hst1 hit1
 862                     return (threaded2, Nothing)
 863
 864 -- Filter modules in the top level envs (HST, HIT, UI).
 865 retainInTopLevelEnvs :: [ModuleName]
 866                         -> (HomeSymbolTable, HomeIfaceTable, UnlinkedImage)
 867                         -> (HomeSymbolTable, HomeIfaceTable, UnlinkedImage)
 868 retainInTopLevelEnvs keep_these (hst, hit, ui)
 869    = (retainInUFM hst keep_these,
 870       retainInUFM hit keep_these,
 871       filterModuleLinkables (`elem` keep_these) ui
 872      )
 873      where
 874         retainInUFM :: Uniquable key => UniqFM elt -> [key] -> UniqFM elt
 875         retainInUFM ufm keys_to_keep
 876            = listToUFM (concatMap (maybeLookupUFM ufm) keys_to_keep)
 877         maybeLookupUFM ufm u
 878            = case lookupUFM ufm u of Nothing -> []; Just val -> [(u, val)]
 879
 880 -- Needed to clean up HIT and HST so that we don't get duplicates in inst env
 881 downwards_closure_of_module :: [ModSummary] -> ModuleName -> [ModuleName]
 882 downwards_closure_of_module summaries root
 883    = let toEdge :: ModSummary -> (ModuleName,[ModuleName])
 884          toEdge summ = (name_of_summary summ,
 885                         filter (`elem` all_mods) (ms_allimps summ))
 886
 887          all_mods = map name_of_summary summaries
 888
 889          res = simple_transitive_closure (map toEdge summaries) [root]
 890      in
 891          --trace (showSDoc (text "DC of mod" <+> ppr root
 892          --                 <+> text "=" <+> ppr res)) (
 893          res
 894          --)
 895
 896 -- Calculate transitive closures from a set of roots given an adjacency list
 897 simple_transitive_closure :: Eq a => [(a,[a])] -> [a] -> [a]
 898 simple_transitive_closure graph set
 899    = let set2      = nub (concatMap dsts set ++ set)
 900          dsts node = fromMaybe [] (lookup node graph)
 901      in
 902          if   length set == length set2
 903          then set
 904          else simple_transitive_closure graph set2
 905
 906
 907 -- Calculate SCCs of the module graph, with or without taking into
 908 -- account source imports.
 909 topological_sort :: Bool -> [ModSummary] -> [SCC ModSummary]
 910 topological_sort include_source_imports summaries
 911    = let
 912          toEdge :: ModSummary -> (ModSummary,ModuleName,[ModuleName])
 913          toEdge summ
 914              = (summ, name_of_summary summ,
 915                       (if include_source_imports
 916                        then ms_srcimps summ else []) ++ ms_imps summ)
 917
 918          mash_edge :: (ModSummary,ModuleName,[ModuleName]) -> (ModSummary,Int,[Int])
 919          mash_edge (summ, m, m_imports)
 920             = case lookup m key_map of
 921                  Nothing -> panic "reverse_topological_sort"
 922                  Just mk -> (summ, mk,
 923                                 -- ignore imports not from the home package
 924                                 catMaybes (map (flip lookup key_map) m_imports))
 925
 926          edges     = map toEdge summaries
 927          key_map   = zip [nm | (s,nm,imps) <- edges] [1 ..] :: [(ModuleName,Int)]
 928          scc_input = map mash_edge edges
 929          sccs      = stronglyConnComp scc_input
 930      in
 931          sccs
 932
 933
 934 -- Chase downwards from the specified root set, returning summaries
 935 -- for all home modules encountered.  Only follow source-import
 936 -- links.  Also returns a Bool to indicate whether any of the roots
 937 -- are module Main.
 938 downsweep :: [FilePath] -> [ModSummary] -> IO ([ModSummary], Bool)
 939 downsweep rootNm old_summaries
 940    = do rootSummaries <- mapM getRootSummary rootNm
 941         let a_root_is_Main
 942                = any ((=="Main").moduleNameUserString.name_of_summary)
 943                      rootSummaries
 944         all_summaries
 945            <- loop (concat (map ms_imps rootSummaries))
 946                 (mkModuleEnv [ (mod, s) | s <- rootSummaries,
 947                                           let mod = ms_mod s, isHomeModule mod
 948                              ])
 949         return (all_summaries, a_root_is_Main)
 950      where
 951         getRootSummary :: FilePath -> IO ModSummary
 952         getRootSummary file
 953            | haskellish_src_file file
 954            = do exists <- doesFileExist file
 955                 if exists then summariseFile file else do
 956                 throwDyn (CmdLineError ("can't find file `" ++ file ++ "'"))
 957            | otherwise
 958            = do exists <- doesFileExist hs_file
 959                 if exists then summariseFile hs_file else do
 960                 exists <- doesFileExist lhs_file
 961                 if exists then summariseFile lhs_file else do
 962                 let mod_name = mkModuleName file
 963                 maybe_summary <- getSummary mod_name
 964                 case maybe_summary of
 965                    Nothing -> packageModErr mod_name
 966                    Just s  -> return s
 967            where
 968                  hs_file = file ++ ".hs"
 969                  lhs_file = file ++ ".lhs"
 970
 971         getSummary :: ModuleName -> IO (Maybe ModSummary)
 972         getSummary nm
 973            = do found <- findModule nm
 974                 case found of
 975                    Just (mod, location) -> do
 976                         let old_summary = findModInSummaries old_summaries mod
 977                         summarise mod location old_summary
 978
 979                    Nothing -> throwDyn (CmdLineError
 980                                    ("can't find module `"
 981                                      ++ showSDoc (ppr nm) ++ "'"))
 982
 983         -- loop invariant: env doesn't contain package modules
 984         loop :: [ModuleName] -> ModuleEnv ModSummary -> IO [ModSummary]
 985         loop [] env = return (moduleEnvElts env)
 986         loop imps env
 987            = do -- imports for modules we don't already have
 988                 let needed_imps = nub (filter (not . (`elemUFM` env)) imps)
 989
 990                 -- summarise them
 991                 needed_summaries <- mapM getSummary needed_imps
 992
 993                 -- get just the "home" modules
 994                 let new_home_summaries = [ s | Just s <- needed_summaries ]
 995
 996                 -- loop, checking the new imports
 997                 let new_imps = concat (map ms_imps new_home_summaries)
 998                 loop new_imps (extendModuleEnvList env
 999                                 [ (ms_mod s, s) | s <- new_home_summaries ])
1000
1001 -----------------------------------------------------------------------------
1002 -- Summarising modules
1003
1004 -- We have two types of summarisation:
1005 --
1006 --    * Summarise a file.  This is used for the root module passed to
1007 --      cmLoadModule.  The file is read, and used to determine the root
1008 --      module name.  The module name may differ from the filename.
1009 --
1010 --    * Summarise a module.  We are given a module name, and must provide
1011 --      a summary.  The finder is used to locate the file in which the module
1012 --      resides.
1013
1014 summariseFile :: FilePath -> IO ModSummary
1015 summariseFile file
1016    = do hspp_fn <- preprocess file
1017         (srcimps,imps,mod_name) <- getImportsFromFile hspp_fn
1018
1019         let (path, basename, ext) = splitFilename3 file
1020
1021         Just (mod, location)
1022            <- mkHomeModuleLocn mod_name (path ++ '/':basename) (Just file)
1023
1024         src_timestamp
1025            <- case ml_hs_file location of
1026                  Nothing     -> noHsFileErr mod_name
1027                  Just src_fn -> getModificationTime src_fn
1028
1029         return (ModSummary mod
1030                            location{ml_hspp_file=Just hspp_fn}
1031                            srcimps imps src_timestamp)
1032
1033 -- Summarise a module, and pick up source and timestamp.
1034 summarise :: Module -> ModuleLocation -> Maybe ModSummary
1035          -> IO (Maybe ModSummary)
1036 summarise mod location old_summary
1037    | not (isHomeModule mod) = return Nothing
1038    | otherwise
1039    = do let hs_fn = unJust "summarise" (ml_hs_file location)
1040
1041         case ml_hs_file location of {
1042            Nothing -> do {
1043                 dflags <- getDynFlags;
1044                 when (verbosity dflags >= 1) $
1045                     hPutStrLn stderr ("WARNING: module `" ++
1046                         moduleUserString mod ++ "' has no source file.");
1047                 return Nothing;
1048              };
1049
1050            Just src_fn -> do
1051
1052         src_timestamp <- getModificationTime src_fn
1053
1054         -- return the cached summary if the source didn't change
1055         case old_summary of {
1056            Just s | ms_hs_date s == src_timestamp -> return (Just s);
1057            _ -> do
1058
1059         hspp_fn <- preprocess hs_fn
1060         (srcimps,imps,mod_name) <- getImportsFromFile hspp_fn
1061
1062         when (mod_name /= moduleName mod) $
1063                 throwDyn (ProgramError
1064                    (showSDoc (text hs_fn
1065                               <>  text ": file name does not match module name"
1066                               <+> quotes (ppr (moduleName mod)))))
1067
1068         return (Just (ModSummary mod location{ml_hspp_file=Just hspp_fn}
1069                                  srcimps imps src_timestamp))
1070         }
1071       }
1072
1073
1074 noHsFileErr mod
1075   = throwDyn (CmdLineError (showSDoc (text "no source file for module" <+> quotes (ppr mod))))
1076
1077 packageModErr mod
1078   = throwDyn (CmdLineError (showSDoc (text "module" <+>
1079                                    quotes (ppr mod) <+>
1080                                    text "is a package module")))
1081 \end{code}