ghc/compiler/coreSyn/CoreTidy.lhs

   1 %
   2 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   3 %
   4 \section{Tidying up Core}
   5
   6 \begin{code}
   7 module CoreTidy (
   8         tidyCorePgm, tidyExpr,
   9         tidyBndr, tidyBndrs
  10     ) where
  11
  12 #include "HsVersions.h"
  13
  14 import CmdLineOpts      ( DynFlags, DynFlag(..), opt_UsageSPOn, dopt )
  15 import CoreSyn
  16 import CoreUnfold       ( noUnfolding )
  17 import CoreLint         ( beginPass, endPass )
  18 import UsageSPInf       ( doUsageSPInf )
  19 import VarEnv
  20 import VarSet
  21 import Var              ( Id, Var )
  22 import Id               ( idType, idInfo, idName,
  23                           mkVanillaId, mkId, exportWithOrigOccName,
  24                           idStrictness, setIdStrictness,
  25                           idDemandInfo, setIdDemandInfo,
  26                         )
  27 import IdInfo           ( specInfo, setSpecInfo,
  28                           setUnfoldingInfo, setDemandInfo,
  29                           workerInfo, setWorkerInfo, WorkerInfo(..)
  30                         )
  31 import Demand           ( wwLazy )
  32 import Name             ( getOccName, tidyTopName, mkLocalName )
  33 import OccName          ( initTidyOccEnv, tidyOccName )
  34 import Type             ( tidyTopType, tidyType, tidyTyVar )
  35 import Module           ( Module )
  36 import UniqSupply       ( mkSplitUniqSupply )
  37 import Unique           ( Uniquable(..) )
  38 import SrcLoc           ( noSrcLoc )
  39 import Util             ( mapAccumL )
  40 \end{code}
  41
  42
  43
  44 %************************************************************************
  45 %*                                                                      *
  46 \subsection{Tidying core}
  47 %*                                                                      *
  48 %************************************************************************
  49
  50 Several tasks are done by @tidyCorePgm@
  51
  52 1. If @opt_UsageSPOn@ then compute usage information (which is
  53    needed by Core2Stg).  ** NOTE _scc_ HERE **
  54    Do this first, because it may introduce new binders.
  55
  56 2.  Make certain top-level bindings into Globals. The point is that
  57     Global things get externally-visible labels at code generation
  58     time
  59
  60
  61 3. Give all binders a nice print-name.  Their uniques aren't changed;
  62    rather we give them lexically unique occ-names, so that we can
  63    safely print the OccNae only in the interface file.  [Bad idea to
  64    change the uniques, because the code generator makes global labels
  65    from the uniques for local thunks etc.]
  66
  67 \begin{code}
  68 tidyCorePgm :: DynFlags -> Module
  69             -> [CoreBind] -> [IdCoreRule]
  70             -> IO ([CoreBind], [IdCoreRule])
  71 tidyCorePgm dflags module_name binds_in orphans_in
  72   = do
  73         us <- mkSplitUniqSupply 'u'
  74
  75         beginPass dflags "Tidy Core"
  76
  77         binds_in1 <- if opt_UsageSPOn
  78                      then _scc_ "CoreUsageSPInf"
  79                                 doUsageSPInf dflags us binds_in
  80                      else return binds_in
  81
  82         let (tidy_env1, binds_out)  = mapAccumL (tidyBind (Just module_name))
  83                                                 init_tidy_env binds_in1
  84             orphans_out             = tidyIdRules tidy_env1 orphans_in
  85
  86         endPass dflags "Tidy Core" (dopt Opt_D_dump_simpl dflags ||
  87                                     dopt Opt_D_verbose_core2core dflags)
  88                 binds_out
  89
  90         return (binds_out, orphans_out)
  91   where
  92         -- We also make sure to avoid any exported binders.  Consider
  93         --      f{-u1-} = 1     -- Local decl
  94         --      ...
  95         --      f{-u2-} = 2     -- Exported decl
  96         --
  97         -- The second exported decl must 'get' the name 'f', so we
  98         -- have to put 'f' in the avoids list before we get to the first
  99         -- decl.  tidyTopId then does a no-op on exported binders.
 100     init_tidy_env = (initTidyOccEnv avoids, emptyVarEnv)
 101     avoids        = [getOccName bndr | bndr <- bindersOfBinds binds_in,
 102                                        exportWithOrigOccName bndr]
 103
 104 tidyBind :: Maybe Module                -- (Just m) for top level, Nothing for nested
 105          -> TidyEnv
 106          -> CoreBind
 107          -> (TidyEnv, CoreBind)
 108 tidyBind maybe_mod env (NonRec bndr rhs)
 109   = let
 110         (env', bndr') = tidy_bndr maybe_mod env' env bndr
 111         rhs'          = tidyExpr env' rhs
 112         -- We use env' when tidying the RHS even though it's not
 113         -- strictly necessary; it makes the code pretty hard to read
 114         -- if we don't!
 115     in
 116     (env', NonRec bndr' rhs')
 117
 118 tidyBind maybe_mod env (Rec pairs)
 119   = let
 120         -- We use env' when tidying the rhss
 121         -- When tidying the binder itself we may tidy it's
 122         -- specialisations; if any of these mention other binders
 123         -- in the group we should really feed env' to them too;
 124         -- but that seems (a) unlikely and (b) a bit tiresome.
 125         -- So I left it out for now
 126
 127         (bndrs, rhss)  = unzip pairs
 128         (env', bndrs') = mapAccumL (tidy_bndr maybe_mod env') env bndrs
 129         rhss'          = map (tidyExpr env') rhss
 130   in
 131   (env', Rec (zip bndrs' rhss'))
 132
 133 tidyExpr env (Type ty)       = Type (tidyType env ty)
 134 tidyExpr env (Lit lit)       = Lit lit
 135 tidyExpr env (App f a)       = App (tidyExpr env f) (tidyExpr env a)
 136 tidyExpr env (Note n e)      = Note (tidyNote env n) (tidyExpr env e)
 137
 138 tidyExpr env (Let b e)       = Let b' (tidyExpr env' e)
 139                              where
 140                                (env', b') = tidyBind Nothing env b
 141
 142 tidyExpr env (Case e b alts) = Case (tidyExpr env e) b' (map (tidyAlt env') alts)
 143                              where
 144                                (env', b') = tidyBndr env b
 145
 146 tidyExpr env (Var v)         = Var (tidyVarOcc env v)
 147
 148 tidyExpr env (Lam b e)       = Lam b' (tidyExpr env' e)
 149                              where
 150                                (env', b') = tidyBndr env b
 151
 152 tidyAlt env (con, vs, rhs)   = (con, vs', tidyExpr env' rhs)
 153                              where
 154                                (env', vs') = tidyBndrs env vs
 155
 156 tidyNote env (Coerce t1 t2)  = Coerce (tidyType env t1) (tidyType env t2)
 157
 158 tidyNote env note            = note
 159
 160 tidyVarOcc (_, var_env) v = case lookupVarEnv var_env v of
 161                                   Just v' -> v'
 162                                   Nothing -> v
 163 \end{code}
 164
 165 \begin{code}
 166 tidy_bndr (Just mod) env_idinfo env var = tidyTopId mod env env_idinfo var
 167 tidy_bndr Nothing    env_idinfo env var = tidyBndr      env            var
 168 \end{code}
 169
 170
 171
 172 %************************************************************************
 173 %*                                                                      *
 174 \subsection{Tidying up a binder}
 175 %*                                                                      *
 176 %************************************************************************
 177
 178 \begin{code}
 179 tidyBndr :: TidyEnv -> Var -> (TidyEnv, Var)
 180 tidyBndr env var | isTyVar var = tidyTyVar env var
 181                  | otherwise   = tidyId    env var
 182
 183 tidyBndrs :: TidyEnv -> [Var] -> (TidyEnv, [Var])
 184 tidyBndrs env vars = mapAccumL tidyBndr env vars
 185
 186 tidyId :: TidyEnv -> Id -> (TidyEnv, Id)
 187 tidyId env@(tidy_env, var_env) id
 188   =     -- Non-top-level variables
 189     let
 190         -- Give the Id a fresh print-name, *and* rename its type
 191         -- The SrcLoc isn't important now, though we could extract it from the Id
 192         name'             = mkLocalName (getUnique id) occ' noSrcLoc
 193         (tidy_env', occ') = tidyOccName tidy_env (getOccName id)
 194         ty'               = tidyType env (idType id)
 195         id'               = mkVanillaId name' ty'
 196                             `setIdStrictness` idStrictness id
 197                             `setIdDemandInfo` idDemandInfo id
 198                         -- NB: This throws away the IdInfo of the Id, which we
 199                         -- no longer need.  That means we don't need to
 200                         -- run over it with env, nor renumber it.
 201                         --
 202                         -- The exception is strictness and demand info, which
 203                         -- is used to decide whether to use let or case for
 204                         -- function arguments and let bindings
 205
 206         var_env'          = extendVarEnv var_env id id'
 207     in
 208     ((tidy_env', var_env'), id')
 209
 210 tidyTopId :: Module -> TidyEnv -> TidyEnv -> Id -> (TidyEnv, Id)
 211         -- The second env is the one to use for the IdInfo
 212         -- It's necessary because when we are dealing with a recursive
 213         -- group, a variable late in the group might be mentioned
 214         -- in the IdInfo of one early in the group
 215 tidyTopId mod env@(tidy_env, var_env) env_idinfo id
 216   =     -- Top level variables
 217     let
 218         (tidy_env', name') | exportWithOrigOccName id = (tidy_env, idName id)
 219                            | otherwise                = tidyTopName mod tidy_env (idName id)
 220         ty'                = tidyTopType (idType id)
 221         idinfo'            = tidyIdInfo env_idinfo (idInfo id)
 222         id'                = mkId name' ty' idinfo'
 223         var_env'           = extendVarEnv var_env id id'
 224     in
 225     ((tidy_env', var_env'), id')
 226 \end{code}
 227
 228 \begin{code}
 229 -- tidyIdInfo does these things:
 230 --      a) tidy the specialisation info and worker info (if any)
 231 --      b) zap the unfolding and demand info
 232 -- The latter two are to avoid space leaks
 233
 234 tidyIdInfo env info
 235   = info5
 236   where
 237     rules = specInfo info
 238
 239     info2 | isEmptyCoreRules rules = info
 240           | otherwise              = info `setSpecInfo` tidyRules env rules
 241
 242     info3 = info2 `setUnfoldingInfo` noUnfolding
 243     info4 = info3 `setDemandInfo`    wwLazy
 244
 245     info5 = case workerInfo info of
 246                 NoWorker -> info4
 247                 HasWorker w a  -> info4 `setWorkerInfo` HasWorker (tidyVarOcc env w) a
 248
 249 tidyIdRules :: TidyEnv -> [IdCoreRule] -> [IdCoreRule]
 250 tidyIdRules env rules
 251   = [ (tidyVarOcc env fn, tidyRule env rule) | (fn,rule) <- rules  ]
 252
 253 tidyRules :: TidyEnv -> CoreRules -> CoreRules
 254 tidyRules env (Rules rules fvs)
 255   = Rules (map (tidyRule env) rules)
 256           (foldVarSet tidy_set_elem emptyVarSet fvs)
 257   where
 258     tidy_set_elem var new_set = extendVarSet new_set (tidyVarOcc env var)
 259
 260 tidyRule :: TidyEnv -> CoreRule -> CoreRule
 261 tidyRule env rule@(BuiltinRule _) = rule
 262 tidyRule env (Rule name vars tpl_args rhs)
 263   = (Rule name vars' (map (tidyExpr env') tpl_args) (tidyExpr env' rhs))
 264   where
 265     (env', vars') = tidyBndrs env vars
 266 \end{code}