ghc/compiler/coreSyn/MkExternalCore.lhs

   1 %
   2 % (c) The University of Glasgow 2001
   3 %
   4 \begin{code}
   5
   6 module MkExternalCore (
   7         emitExternalCore
   8 ) where
   9
  10 #include "HsVersions.h"
  11
  12 import qualified ExternalCore as C
  13 import Char
  14 import Module
  15 import CoreSyn
  16 import HscTypes
  17 import TyCon
  18 import Class
  19 import TypeRep
  20 import Type
  21 import DataCon  ( DataCon, dataConExistentialTyVars, dataConRepArgTys,
  22                   dataConName, dataConWrapId_maybe )
  23 import CoreSyn
  24 import Var
  25 import IdInfo
  26 import Id       ( idUnfolding )
  27 import CoreTidy ( tidyExpr )
  28 import VarEnv   ( emptyTidyEnv )
  29 import TysPrim  ( intPrimTy )
  30 import Literal
  31 import Name
  32 import CostCentre
  33 import Outputable
  34 import ForeignCall
  35 import PprExternalCore
  36 import CmdLineOpts
  37 import Maybes   ( orElse, catMaybes )
  38 import IO
  39 import FastString
  40
  41 emitExternalCore :: DynFlags -> ModGuts -> IO ()
  42 emitExternalCore dflags mod_impl
  43  | opt_EmitExternalCore
  44  = (do handle <- openFile corename WriteMode
  45        hPutStrLn handle (show (mkExternalCore mod_impl))
  46        hClose handle)
  47    `catch` (\err -> pprPanic "Failed to open or write external core output file"
  48                              (text corename))
  49    where corename = extCoreName dflags
  50 emitExternalCore _ _
  51  | otherwise
  52  = return ()
  53
  54
  55 mkExternalCore :: ModGuts -> C.Module
  56 -- The ModGuts has been tidied, but the implicit bindings have
  57 -- not been injected, so we have to add them manually here
  58 -- We don't include the strange data-con *workers* because they are
  59 -- implicit in the data type declaration itself
  60 mkExternalCore (ModGuts {mg_module=this_mod, mg_types = type_env, mg_binds = binds})
  61   = C.Module mname tdefs (map make_vdef all_binds)
  62   where
  63     mname  = make_mid this_mod
  64     tdefs  = foldr collect_tdefs [] tycons
  65
  66     all_binds  = implicit_con_wrappers ++ other_implicit_binds ++ binds
  67                 -- Put the constructor wrappers first, because
  68                 -- other implicit bindings (notably the fromT functions arising
  69                 -- from generics) use the constructor wrappers.
  70
  71     tycons = map classTyCon (typeEnvClasses type_env) ++ typeEnvTyCons type_env
  72
  73     implicit_con_wrappers = map get_defn (concatMap implicit_con_ids   (typeEnvElts type_env))
  74     other_implicit_binds  = map get_defn (concatMap other_implicit_ids (typeEnvElts type_env))
  75
  76 implicit_con_ids :: TyThing -> [Id]
  77 implicit_con_ids (ATyCon tc) | isAlgTyCon tc = catMaybes (map dataConWrapId_maybe (tyConDataCons tc))
  78 implicit_con_ids other                       = []
  79
  80 other_implicit_ids :: TyThing -> [Id]
  81 other_implicit_ids (ATyCon tc) = tyConSelIds tc ++ tyConGenIds tc
  82 other_implicit_ids (AClass cl) = classSelIds cl
  83 other_implicit_ids other       = []
  84
  85 get_defn :: Id -> CoreBind
  86 get_defn id = NonRec id rhs
  87             where
  88               rhs  = tidyExpr emptyTidyEnv body
  89               body = unfoldingTemplate (idUnfolding id)
  90         -- Don't forget to tidy the body !  Otherwise you get silly things like
  91         --      \ tpl -> case tpl of tpl -> (tpl,tpl) -> tpl
  92         -- Maybe we should inject these bindings during CoreTidy?
  93
  94 collect_tdefs :: TyCon -> [C.Tdef] -> [C.Tdef]
  95 collect_tdefs tcon tdefs
  96   | isAlgTyCon tcon = tdef: tdefs
  97   where
  98     tdef | isNewTyCon tcon =
  99                 C.Newtype (make_con_qid (tyConName tcon)) (map make_tbind tyvars) repclause
 100          | otherwise =
 101                 C.Data (make_con_qid (tyConName tcon)) (map make_tbind tyvars) (map make_cdef (tyConDataCons tcon))
 102          where repclause | isRecursiveTyCon tcon = Nothing
 103                          | otherwise = Just (make_ty rep)
 104                                            where (_, rep) = newTyConRep tcon
 105     tyvars = tyConTyVars tcon
 106
 107 collect_tdefs _ tdefs = tdefs
 108
 109
 110 make_cdef :: DataCon -> C.Cdef
 111 make_cdef dcon =  C.Constr dcon_name existentials tys
 112   where
 113     dcon_name    = make_con_qid (dataConName dcon)
 114     existentials = map make_tbind ex_tyvars
 115     ex_tyvars    = dataConExistentialTyVars dcon
 116     tys          = map make_ty (dataConRepArgTys dcon)
 117
 118 make_tbind :: TyVar -> C.Tbind
 119 make_tbind tv = (make_var_id (tyVarName tv), make_kind (tyVarKind tv))
 120
 121 make_vbind :: Var -> C.Vbind
 122 make_vbind v = (make_var_id  (Var.varName v), make_ty (varType v))
 123
 124 make_vdef :: CoreBind -> C.Vdefg
 125 make_vdef b =
 126   case b of
 127     NonRec v e -> C.Nonrec (f (v,e))
 128     Rec ves -> C.Rec (map f ves)
 129   where f (v,e) = (make_var_qid (Var.varName v), make_ty (varType v),make_exp e)
 130
 131 make_exp :: CoreExpr -> C.Exp
 132 make_exp (Var v) =
 133   case globalIdDetails v of
 134      -- a DataConId represents the Id of a worker, which is a varName. -- sof 4/02
 135 --    DataConId _ -> C.Dcon (make_con_qid (Var.varName v))
 136     FCallId (CCall (CCallSpec (StaticTarget nm) _ _)) -> C.External (unpackFS nm) (make_ty (varType v))
 137     FCallId _ -> error "MkExternalCore died: can't handle non-static-C foreign call"
 138     _ -> C.Var (make_var_qid (Var.varName v))
 139 make_exp (Lit (l@(MachLabel s _))) = C.External (unpackFS s) (make_ty (literalType l))
 140 make_exp (Lit l) = C.Lit (make_lit l)
 141 make_exp (App e (Type t)) = C.Appt (make_exp e) (make_ty t)
 142 make_exp (App e1 e2) = C.App (make_exp e1) (make_exp e2)
 143 make_exp (Lam v e) | isTyVar v = C.Lam (C.Tb (make_tbind v)) (make_exp e)
 144 make_exp (Lam v e) | otherwise = C.Lam (C.Vb (make_vbind v)) (make_exp e)
 145 make_exp (Let b e) = C.Let (make_vdef b) (make_exp e)
 146 make_exp (Case e v alts) = C.Case (make_exp e) (make_vbind v) (map make_alt alts)
 147 make_exp (Note (SCC cc) e) = C.Note "SCC"  (make_exp e) -- temporary
 148 make_exp (Note (Coerce t_to t_from) e) = C.Coerce (make_ty t_to) (make_exp e)
 149 make_exp (Note InlineCall e) = C.Note "InlineCall" (make_exp e)
 150 make_exp (Note (CoreNote s) e) = C.Note s (make_exp e)  -- hdaume: core annotations
 151 make_exp (Note InlineMe e) = C.Note "InlineMe" (make_exp e)
 152 make_exp _ = error "MkExternalCore died: make_exp"
 153
 154 make_alt :: CoreAlt -> C.Alt
 155 make_alt (DataAlt dcon, vs, e) =
 156     C.Acon (make_con_qid (dataConName dcon))
 157            (map make_tbind tbs)
 158            (map make_vbind vbs)
 159            (make_exp e)
 160         where (tbs,vbs) = span isTyVar vs
 161 make_alt (LitAlt l,_,e) = C.Alit (make_lit l) (make_exp e)
 162 make_alt (DEFAULT,[],e) = C.Adefault (make_exp e)
 163
 164 make_lit :: Literal -> C.Lit
 165 make_lit l =
 166   case l of
 167     MachChar i | i <= 0xff -> C.Lchar (chr i) t
 168     MachChar i | otherwise -> C.Lint (toEnum i) (make_ty intPrimTy)
 169         -- For 'big' characters, use an integer
 170     MachStr s -> C.Lstring (unpackFS s) t
 171     MachNullAddr -> C.Lint 0 t
 172     MachInt i -> C.Lint i t
 173     MachInt64 i -> C.Lint i t
 174     MachWord i -> C.Lint i t
 175     MachWord64 i -> C.Lint i t
 176     MachFloat r -> C.Lrational r t
 177     MachDouble r -> C.Lrational r t
 178     _ -> error "MkExternalCore died: make_lit"
 179   where
 180     t = make_ty (literalType l)
 181
 182 make_ty :: Type -> C.Ty
 183 make_ty (TyVarTy tv)             = C.Tvar (make_var_id (tyVarName tv))
 184 make_ty (AppTy t1 t2)            = C.Tapp (make_ty t1) (make_ty t2)
 185 make_ty (FunTy t1 t2)            = make_ty (TyConApp funTyCon [t1,t2])
 186 make_ty (ForAllTy tv t)          = C.Tforall (make_tbind tv) (make_ty t)
 187 make_ty (TyConApp tc ts)         = foldl C.Tapp (C.Tcon (make_con_qid (tyConName tc)))
 188                                          (map make_ty ts)
 189 -- The special case for newtypes says "do not expand newtypes".
 190 -- Reason: sourceTypeRep does substitution and, while substitution deals
 191 --         correctly with name capture, it's only correct if you see the uniques!
 192 --         If you just see occurrence names, name capture may occur.
 193 -- Example: newtype A a = A (forall b. b -> a)
 194 --          test :: forall q b. q -> A b
 195 --          test _ = undefined
 196 --      Here the 'a' gets substituted by 'b', which is captured.
 197 -- Another solution would be to expand newtypes before tidying; but that would
 198 -- expose the representation in interface files, which definitely isn't right.
 199 -- Maybe CoreTidy should know whether to expand newtypes or not?
 200
 201 make_ty (SourceTy (NType tc ts)) = foldl C.Tapp (C.Tcon (make_con_qid (tyConName tc)))
 202                                          (map make_ty ts)
 203
 204 make_ty (SourceTy p)             = make_ty (sourceTypeRep p)
 205 make_ty (NoteTy _ t)             = make_ty t
 206
 207
 208
 209 make_kind :: Kind -> C.Kind
 210 make_kind (FunTy k1 k2) = C.Karrow (make_kind k1) (make_kind k2)
 211 make_kind k | k `eqKind` liftedTypeKind = C.Klifted
 212 make_kind k | k `eqKind` unliftedTypeKind = C.Kunlifted
 213 make_kind k | k `eqKind` openTypeKind = C.Kopen
 214 make_kind _ = error "MkExternalCore died: make_kind"
 215
 216 {- Id generation. -}
 217
 218 {- Use encoded strings.
 219    Also, adjust casing to work around some badly-chosen internal names. -}
 220 make_id :: Bool -> Name -> C.Id
 221 make_id is_var nm = (occNameString . nameOccName) nm
 222
 223 {-      SIMON thinks this stuff isn't necessary
 224 make_id is_var nm =
 225   case n of
 226     'Z':cs | is_var -> 'z':cs
 227     'z':cs | not is_var -> 'Z':cs
 228     c:cs | isUpper c && is_var -> 'z':'d':n
 229     c:cs | isLower c && (not is_var) -> 'Z':'d':n
 230     _ -> n
 231   where n = (occNameString . nameOccName) nm
 232 -}
 233
 234 make_var_id :: Name -> C.Id
 235 make_var_id = make_id True
 236
 237 make_mid :: Module -> C.Id
 238 make_mid = moduleNameString . moduleName
 239
 240 make_qid :: Bool -> Name -> C.Qual C.Id
 241 make_qid is_var n = (mname,make_id is_var n)
 242     where mname =
 243            case nameModule_maybe n of
 244             Just m -> make_mid m
 245             Nothing -> ""
 246
 247 make_var_qid :: Name -> C.Qual C.Id
 248 make_var_qid = make_qid True
 249
 250 make_con_qid :: Name -> C.Qual C.Id
 251 make_con_qid = make_qid False
 252
 253 \end{code}
 254
 255
 256
 257