ghc/compiler/coreSyn/MkExternalCore.lhs

   1 %
   2 % (c) The University of Glasgow 2001
   3 %
   4 \begin{code}
   5
   6 module MkExternalCore (
   7         emitExternalCore
   8 ) where
   9
  10 #include "HsVersions.h"
  11
  12 import qualified ExternalCore as C
  13 import Char
  14 import Module
  15 import CoreSyn
  16 import HscTypes
  17 import TyCon
  18 import Class
  19 import TypeRep
  20 import Type
  21 import PprExternalCore  -- Instances
  22 import DataCon  ( DataCon, dataConExistentialTyVars, dataConRepArgTys,
  23                   dataConName, dataConWrapId_maybe )
  24 import CoreSyn
  25 import Var
  26 import IdInfo
  27 import Id       ( idUnfolding )
  28 import CoreTidy ( tidyExpr )
  29 import VarEnv   ( emptyTidyEnv )
  30 import Literal
  31 import Name
  32 import Outputable
  33 import ForeignCall
  34 import CmdLineOpts
  35 import Maybes   ( mapCatMaybes )
  36 import IO
  37 import FastString
  38
  39 emitExternalCore :: DynFlags -> ModGuts -> IO ()
  40 emitExternalCore dflags mod_impl
  41  | opt_EmitExternalCore
  42  = (do handle <- openFile corename WriteMode
  43        hPutStrLn handle (show (mkExternalCore mod_impl))
  44        hClose handle)
  45    `catch` (\err -> pprPanic "Failed to open or write external core output file"
  46                              (text corename))
  47    where corename = extCoreName dflags
  48 emitExternalCore _ _
  49  | otherwise
  50  = return ()
  51
  52
  53 mkExternalCore :: ModGuts -> C.Module
  54 -- The ModGuts has been tidied, but the implicit bindings have
  55 -- not been injected, so we have to add them manually here
  56 -- We don't include the strange data-con *workers* because they are
  57 -- implicit in the data type declaration itself
  58 mkExternalCore (ModGuts {mg_module=this_mod, mg_types = type_env, mg_binds = binds})
  59   = C.Module mname tdefs (map make_vdef all_binds)
  60   where
  61     mname  = make_mid this_mod
  62     tdefs  = foldr collect_tdefs [] tycons
  63
  64     all_binds  = implicit_con_wrappers ++ other_implicit_binds ++ binds
  65                 -- Put the constructor wrappers first, because
  66                 -- other implicit bindings (notably the fromT functions arising
  67                 -- from generics) use the constructor wrappers.
  68
  69     tycons = map classTyCon (typeEnvClasses type_env) ++ typeEnvTyCons type_env
  70
  71     implicit_con_wrappers = map get_defn (concatMap implicit_con_ids   (typeEnvElts type_env))
  72     other_implicit_binds  = map get_defn (concatMap other_implicit_ids (typeEnvElts type_env))
  73
  74 implicit_con_ids :: TyThing -> [Id]
  75 implicit_con_ids (ATyCon tc) | isAlgTyCon tc = mapCatMaybes dataConWrapId_maybe (tyConDataCons tc)
  76 implicit_con_ids other                       = []
  77
  78 other_implicit_ids :: TyThing -> [Id]
  79 other_implicit_ids (ATyCon tc) = tyConSelIds tc
  80 other_implicit_ids (AClass cl) = classSelIds cl
  81 other_implicit_ids other       = []
  82
  83 get_defn :: Id -> CoreBind
  84 get_defn id = NonRec id rhs
  85             where
  86               rhs  = tidyExpr emptyTidyEnv body
  87               body = unfoldingTemplate (idUnfolding id)
  88         -- Don't forget to tidy the body !  Otherwise you get silly things like
  89         --      \ tpl -> case tpl of tpl -> (tpl,tpl) -> tpl
  90         -- Maybe we should inject these bindings during CoreTidy?
  91
  92 collect_tdefs :: TyCon -> [C.Tdef] -> [C.Tdef]
  93 collect_tdefs tcon tdefs
  94   | isAlgTyCon tcon = tdef: tdefs
  95   where
  96     tdef | isNewTyCon tcon =
  97                 C.Newtype (make_con_qid (tyConName tcon)) (map make_tbind tyvars) repclause
  98          | null (tyConDataCons tcon) = error "MkExternalCore died: can't handle datatype declarations with no data constructors"
  99          | otherwise =
 100                 C.Data (make_con_qid (tyConName tcon)) (map make_tbind tyvars) (map make_cdef (tyConDataCons tcon))
 101          where repclause | isRecursiveTyCon tcon = Nothing
 102                          | otherwise = Just (make_ty rep)
 103                                            where (_, rep) = newTyConRep tcon
 104     tyvars = tyConTyVars tcon
 105
 106 collect_tdefs _ tdefs = tdefs
 107
 108
 109 make_cdef :: DataCon -> C.Cdef
 110 make_cdef dcon =  C.Constr dcon_name existentials tys
 111   where
 112     dcon_name    = make_var_id (dataConName dcon)
 113     existentials = map make_tbind ex_tyvars
 114     ex_tyvars    = dataConExistentialTyVars dcon
 115     tys          = map make_ty (dataConRepArgTys dcon)
 116
 117 make_tbind :: TyVar -> C.Tbind
 118 make_tbind tv = (make_var_id (tyVarName tv), make_kind (tyVarKind tv))
 119
 120 make_vbind :: Var -> C.Vbind
 121 make_vbind v = (make_var_id  (Var.varName v), make_ty (varType v))
 122
 123 make_vdef :: CoreBind -> C.Vdefg
 124 make_vdef b =
 125   case b of
 126     NonRec v e -> C.Nonrec (f (v,e))
 127     Rec ves -> C.Rec (map f ves)
 128   where f (v,e) = (make_var_id (Var.varName v), make_ty (varType v),make_exp e)
 129         -- Top level bindings are unqualified now
 130
 131 make_exp :: CoreExpr -> C.Exp
 132 make_exp (Var v) =
 133   case globalIdDetails v of
 134      -- a DataConId represents the Id of a worker, which is a varName. -- sof 4/02
 135 --    DataConId _ -> C.Dcon (make_con_qid (Var.varName v))
 136     FCallId (CCall (CCallSpec (StaticTarget nm) _ _)) -> C.External (unpackFS nm) (make_ty (varType v))
 137     FCallId _ -> error "MkExternalCore died: can't handle non-static-C foreign call"
 138     _ -> C.Var (make_var_qid (Var.varName v))
 139 make_exp (Lit (l@(MachLabel s _))) = error "MkExternalCore died: can't handle \"foreign label\" declarations"
 140 make_exp (Lit l) = C.Lit (make_lit l)
 141 make_exp (App e (Type t)) = C.Appt (make_exp e) (make_ty t)
 142 make_exp (App e1 e2) = C.App (make_exp e1) (make_exp e2)
 143 make_exp (Lam v e) | isTyVar v = C.Lam (C.Tb (make_tbind v)) (make_exp e)
 144 make_exp (Lam v e) | otherwise = C.Lam (C.Vb (make_vbind v)) (make_exp e)
 145 make_exp (Let b e) = C.Let (make_vdef b) (make_exp e)
 146 make_exp (Case e v alts) = C.Case (make_exp e) (make_vbind v) (map make_alt alts)
 147 make_exp (Note (SCC cc) e) = C.Note "SCC"  (make_exp e) -- temporary
 148 make_exp (Note (Coerce t_to t_from) e) = C.Coerce (make_ty t_to) (make_exp e)
 149 make_exp (Note InlineCall e) = C.Note "InlineCall" (make_exp e)
 150 make_exp (Note (CoreNote s) e) = C.Note s (make_exp e)  -- hdaume: core annotations
 151 make_exp (Note InlineMe e) = C.Note "InlineMe" (make_exp e)
 152 make_exp _ = error "MkExternalCore died: make_exp"
 153
 154 make_alt :: CoreAlt -> C.Alt
 155 make_alt (DataAlt dcon, vs, e) =
 156     C.Acon (make_con_qid (dataConName dcon))
 157            (map make_tbind tbs)
 158            (map make_vbind vbs)
 159            (make_exp e)
 160         where (tbs,vbs) = span isTyVar vs
 161 make_alt (LitAlt l,_,e) = C.Alit (make_lit l) (make_exp e)
 162 make_alt (DEFAULT,[],e) = C.Adefault (make_exp e)
 163
 164 make_lit :: Literal -> C.Lit
 165 make_lit l =
 166   case l of
 167     MachChar i -> C.Lchar i t
 168     MachStr s -> C.Lstring (unpackFS s) t
 169     MachNullAddr -> C.Lint 0 t
 170     MachInt i -> C.Lint i t
 171     MachInt64 i -> C.Lint i t
 172     MachWord i -> C.Lint i t
 173     MachWord64 i -> C.Lint i t
 174     MachFloat r -> C.Lrational r t
 175     MachDouble r -> C.Lrational r t
 176     _ -> error "MkExternalCore died: make_lit"
 177   where
 178     t = make_ty (literalType l)
 179
 180 make_ty :: Type -> C.Ty
 181 make_ty (TyVarTy tv)             = C.Tvar (make_var_id (tyVarName tv))
 182 make_ty (AppTy t1 t2)            = C.Tapp (make_ty t1) (make_ty t2)
 183 make_ty (FunTy t1 t2)            = make_ty (TyConApp funTyCon [t1,t2])
 184 make_ty (ForAllTy tv t)          = C.Tforall (make_tbind tv) (make_ty t)
 185 make_ty (TyConApp tc ts)         = foldl C.Tapp (C.Tcon (make_con_qid (tyConName tc)))
 186                                          (map make_ty ts)
 187 -- The special case for newtypes says "do not expand newtypes".
 188 -- Reason: predTypeRep does substitution and, while substitution deals
 189 --         correctly with name capture, it's only correct if you see the uniques!
 190 --         If you just see occurrence names, name capture may occur.
 191 -- Example: newtype A a = A (forall b. b -> a)
 192 --          test :: forall q b. q -> A b
 193 --          test _ = undefined
 194 --      Here the 'a' gets substituted by 'b', which is captured.
 195 -- Another solution would be to expand newtypes before tidying; but that would
 196 -- expose the representation in interface files, which definitely isn't right.
 197 -- Maybe CoreTidy should know whether to expand newtypes or not?
 198
 199 make_ty (NewTcApp tc ts) = foldl C.Tapp (C.Tcon (make_con_qid (tyConName tc)))
 200                                          (map make_ty ts)
 201
 202 make_ty (PredTy p)      = make_ty (predTypeRep p)
 203 make_ty (NoteTy _ t)    = make_ty t
 204
 205
 206
 207 make_kind :: Kind -> C.Kind
 208 make_kind (FunTy k1 k2) = C.Karrow (make_kind k1) (make_kind k2)
 209 make_kind k | k `eqKind` liftedTypeKind = C.Klifted
 210 make_kind k | k `eqKind` unliftedTypeKind = C.Kunlifted
 211 make_kind k | k `eqKind` openTypeKind = C.Kopen
 212 make_kind _ = error "MkExternalCore died: make_kind"
 213
 214 {- Id generation. -}
 215
 216 {- Use encoded strings.
 217    Also, adjust casing to work around some badly-chosen internal names. -}
 218 make_id :: Bool -> Name -> C.Id
 219 make_id is_var nm = (occNameString . nameOccName) nm
 220
 221 {-      SIMON thinks this stuff isn't necessary
 222 make_id is_var nm =
 223   case n of
 224     'Z':cs | is_var -> 'z':cs
 225     'z':cs | not is_var -> 'Z':cs
 226     c:cs | isUpper c && is_var -> 'z':'d':n
 227     c:cs | isLower c && (not is_var) -> 'Z':'d':n
 228     _ -> n
 229   where n = (occNameString . nameOccName) nm
 230 -}
 231
 232 make_var_id :: Name -> C.Id
 233 make_var_id = make_id True
 234
 235 make_mid :: Module -> C.Id
 236 make_mid = moduleNameString . moduleName
 237
 238 make_qid :: Bool -> Name -> C.Qual C.Id
 239 make_qid is_var n = (mname,make_id is_var n)
 240     where mname =
 241            case nameModule_maybe n of
 242             Just m -> make_mid m
 243             Nothing -> ""
 244
 245 make_var_qid :: Name -> C.Qual C.Id
 246 make_var_qid = make_qid True
 247
 248 make_con_qid :: Name -> C.Qual C.Id
 249 make_con_qid = make_qid False
 250
 251 \end{code}
 252
 253
 254
 255