ghc/compiler/coreSyn/PprCore.lhs

   1 %
   2 % (c) The AQUA Project, Glasgow University, 1996-1998
   3 %
   4 %************************************************************************
   5 %*                                                                      *
   6 \section[PprCore]{Printing of Core syntax, including for interfaces}
   7 %*                                                                      *
   8 %************************************************************************
   9
  10 \begin{code}
  11 module PprCore (
  12         pprCoreExpr, pprParendExpr,
  13         pprCoreBinding, pprCoreBindings, pprCoreAlt,
  14         pprRules
  15     ) where
  16
  17 #include "HsVersions.h"
  18
  19 import CoreSyn
  20 import CostCentre       ( pprCostCentreCore )
  21 import Var              ( Var )
  22 import Id               ( Id, idType, isDataConWorkId_maybe, idArity,
  23                           idInfo, globalIdDetails, isGlobalId, isExportedId
  24                         )
  25 import Var              ( TyVar, isTyVar, tyVarKind )
  26 import IdInfo           ( IdInfo, megaSeqIdInfo,
  27                           inlinePragInfo, occInfo, newDemandInfo,
  28                           lbvarInfo, hasNoLBVarInfo,
  29                           arityInfo, ppArityInfo,
  30                           specInfo, pprNewStrictness,
  31                           workerInfo, ppWorkerInfo,
  32                           newStrictnessInfo, cafInfo, ppCafInfo, specInfoRules
  33                         )
  34 import NewDemand        ( isTop )
  35 #ifdef OLD_STRICTNESS
  36 import Id               ( idDemandInfo )
  37 import IdInfo           ( cprInfo, ppCprInfo, strictnessInfo, ppStrictnessInfo )
  38 #endif
  39
  40 import DataCon          ( dataConTyCon )
  41 import TyCon            ( tupleTyConBoxity, isTupleTyCon )
  42 import Type             ( pprParendType, pprType, pprParendKind )
  43 import BasicTypes       ( tupleParens, isNoOcc, isAlwaysActive )
  44 import Util             ( lengthIs )
  45 import Outputable
  46 import FastString       ( mkFastString )
  47 \end{code}
  48
  49 %************************************************************************
  50 %*                                                                      *
  51 \subsection{Public interfaces for Core printing (excluding instances)}
  52 %*                                                                      *
  53 %************************************************************************
  54
  55 @pprParendCoreExpr@ puts parens around non-atomic Core expressions.
  56
  57 \begin{code}
  58 pprCoreBindings :: OutputableBndr b => [Bind b] -> SDoc
  59 pprCoreBinding  :: OutputableBndr b => Bind b  -> SDoc
  60 pprCoreExpr     :: OutputableBndr b => Expr b  -> SDoc
  61 pprParendExpr   :: OutputableBndr b => Expr b  -> SDoc
  62
  63 pprCoreBindings = pprTopBinds
  64 pprCoreBinding  = pprTopBind
  65
  66 instance OutputableBndr b => Outputable (Bind b) where
  67     ppr bind = ppr_bind bind
  68
  69 instance OutputableBndr b => Outputable (Expr b) where
  70     ppr expr = pprCoreExpr expr
  71 \end{code}
  72
  73
  74 %************************************************************************
  75 %*                                                                      *
  76 \subsection{The guts}
  77 %*                                                                      *
  78 %************************************************************************
  79
  80 \begin{code}
  81 pprTopBinds binds = vcat (map pprTopBind binds)
  82
  83 pprTopBind (NonRec binder expr)
  84  = ppr_binding (binder,expr) $$ text ""
  85
  86 pprTopBind (Rec binds)
  87   = vcat [ptext SLIT("Rec {"),
  88           vcat (map ppr_binding binds),
  89           ptext SLIT("end Rec }"),
  90           text ""]
  91 \end{code}
  92
  93 \begin{code}
  94 ppr_bind :: OutputableBndr b => Bind b -> SDoc
  95
  96 ppr_bind (NonRec val_bdr expr) = ppr_binding (val_bdr, expr)
  97 ppr_bind (Rec binds)           = vcat (map pp binds)
  98                                where
  99                                  pp bind = ppr_binding bind <> semi
 100
 101 ppr_binding :: OutputableBndr b => (b, Expr b) -> SDoc
 102 ppr_binding (val_bdr, expr)
 103   = pprBndr LetBind val_bdr $$
 104     hang (ppr val_bdr <+> equals) 2 (pprCoreExpr expr)
 105 \end{code}
 106
 107 \begin{code}
 108 pprParendExpr   expr = ppr_expr parens expr
 109 pprCoreExpr expr = ppr_expr noParens expr
 110
 111 noParens :: SDoc -> SDoc
 112 noParens pp = pp
 113 \end{code}
 114
 115 \begin{code}
 116 ppr_expr :: OutputableBndr b => (SDoc -> SDoc) -> Expr b -> SDoc
 117         -- The function adds parens in context that need
 118         -- an atomic value (e.g. function args)
 119
 120 ppr_expr add_par (Type ty)  = add_par (ptext SLIT("TYPE") <+> ppr ty)   -- Wierd
 121
 122 ppr_expr add_par (Var name) = ppr name
 123 ppr_expr add_par (Lit lit)  = ppr lit
 124
 125 ppr_expr add_par expr@(Lam _ _)
 126   = let
 127         (bndrs, body) = collectBinders expr
 128     in
 129     add_par $
 130     hang (ptext SLIT("\\") <+> sep (map (pprBndr LambdaBind) bndrs) <+> arrow)
 131          2 (pprCoreExpr body)
 132
 133 ppr_expr add_par expr@(App fun arg)
 134   = case collectArgs expr of { (fun, args) ->
 135     let
 136         pp_args     = sep (map pprArg args)
 137         val_args    = dropWhile isTypeArg args   -- Drop the type arguments for tuples
 138         pp_tup_args = sep (punctuate comma (map pprArg val_args))
 139     in
 140     case fun of
 141         Var f -> case isDataConWorkId_maybe f of
 142                         -- Notice that we print the *worker*
 143                         -- for tuples in paren'd format.
 144                    Just dc | saturated && isTupleTyCon tc
 145                            -> tupleParens (tupleTyConBoxity tc) pp_tup_args
 146                            where
 147                              tc        = dataConTyCon dc
 148                              saturated = val_args `lengthIs` idArity f
 149
 150                    other -> add_par (hang (ppr f) 2 pp_args)
 151
 152         other -> add_par (hang (pprParendExpr fun) 2 pp_args)
 153     }
 154
 155 ppr_expr add_par (Case expr var ty [(con,args,rhs)])
 156   = add_par $
 157     sep [sep [ptext SLIT("case") <+> pprCoreExpr expr,
 158               ifPprDebug (braces (ppr ty)),
 159               hsep [ptext SLIT("of"),
 160                     ppr_bndr var,
 161                     char '{',
 162                     ppr_case_pat con args
 163           ]],
 164          pprCoreExpr rhs,
 165          char '}'
 166     ]
 167   where
 168     ppr_bndr = pprBndr CaseBind
 169
 170 ppr_expr add_par (Case expr var ty alts)
 171   = add_par $
 172     sep [sep [ptext SLIT("case")
 173                 <+> pprCoreExpr expr
 174                 <+> ifPprDebug (braces (ppr ty)),
 175               ptext SLIT("of") <+> ppr_bndr var <+> char '{'],
 176          nest 2 (sep (punctuate semi (map pprCoreAlt alts))),
 177          char '}'
 178     ]
 179   where
 180     ppr_bndr = pprBndr CaseBind
 181
 182
 183 -- special cases: let ... in let ...
 184 -- ("disgusting" SLPJ)
 185
 186 {-
 187 ppr_expr add_par (Let bind@(NonRec val_bdr rhs@(Let _ _)) body)
 188   = add_par $
 189     vcat [
 190       hsep [ptext SLIT("let {"), (pprBndr LetBind val_bdr $$ ppr val_bndr), equals],
 191       nest 2 (pprCoreExpr rhs),
 192       ptext SLIT("} in"),
 193       pprCoreExpr body ]
 194 -}
 195
 196 ppr_expr add_par (Let bind@(NonRec val_bdr rhs) expr@(Let _ _))
 197   = add_par
 198     (hang (ptext SLIT("let {"))
 199           2 (hsep [ppr_binding (val_bdr,rhs),
 200                    ptext SLIT("} in")])
 201      $$
 202      pprCoreExpr expr)
 203
 204 -- general case (recursive case, too)
 205 ppr_expr add_par (Let bind expr)
 206   = add_par $
 207     sep [hang (ptext keyword) 2 (ppr_bind bind),
 208          hang (ptext SLIT("} in ")) 2 (pprCoreExpr expr)]
 209   where
 210     keyword = case bind of
 211                 Rec _      -> SLIT("__letrec {")
 212                 NonRec _ _ -> SLIT("let {")
 213
 214 ppr_expr add_par (Note (SCC cc) expr)
 215   = add_par (sep [pprCostCentreCore cc, pprCoreExpr expr])
 216
 217 #ifdef DEBUG
 218 ppr_expr add_par (Note (Coerce to_ty from_ty) expr)
 219  = add_par $
 220    getPprStyle $ \ sty ->
 221    if debugStyle sty then
 222       sep [ptext SLIT("__coerce") <+>
 223                 sep [pprParendType to_ty, pprParendType from_ty],
 224            pprParendExpr expr]
 225    else
 226       sep [hsep [ptext SLIT("__coerce"), pprParendType to_ty],
 227                   pprParendExpr expr]
 228 #else
 229 ppr_expr add_par (Note (Coerce to_ty from_ty) expr)
 230   = add_par $
 231     sep [sep [ptext SLIT("__coerce"), nest 2 (pprParendType to_ty)],
 232          pprParendExpr expr]
 233 #endif
 234
 235 ppr_expr add_par (Note InlineCall expr)
 236   = add_par (ptext SLIT("__inline_call") <+> pprParendExpr expr)
 237
 238 ppr_expr add_par (Note InlineMe expr)
 239   = add_par $ ptext SLIT("__inline_me") <+> pprParendExpr expr
 240
 241 ppr_expr add_par (Note (CoreNote s) expr)
 242   = add_par $
 243     sep [sep [ptext SLIT("__core_note"), pprHsString (mkFastString s)],
 244          pprParendExpr expr]
 245
 246 pprCoreAlt (con, args, rhs)
 247   = hang (ppr_case_pat con args) 2 (pprCoreExpr rhs)
 248
 249 ppr_case_pat con@(DataAlt dc) args
 250   | isTupleTyCon tc
 251   = tupleParens (tupleTyConBoxity tc) (hsep (punctuate comma (map ppr_bndr args))) <+> arrow
 252   where
 253     ppr_bndr = pprBndr CaseBind
 254     tc = dataConTyCon dc
 255
 256 ppr_case_pat con args
 257   = ppr con <+> hsep (map ppr_bndr args) <+> arrow
 258   where
 259     ppr_bndr = pprBndr CaseBind
 260
 261 pprArg (Type ty) = ptext SLIT("@") <+> pprParendType ty
 262 pprArg expr      = pprParendExpr expr
 263 \end{code}
 264
 265 Other printing bits-and-bobs used with the general @pprCoreBinding@
 266 and @pprCoreExpr@ functions.
 267
 268 \begin{code}
 269 instance OutputableBndr Var where
 270   pprBndr = pprCoreBinder
 271
 272 pprCoreBinder :: BindingSite -> Var -> SDoc
 273 pprCoreBinder LetBind binder
 274   = vcat [sig, pprIdDetails binder, pragmas]
 275   where
 276     sig     = pprTypedBinder binder
 277     pragmas = ppIdInfo binder (idInfo binder)
 278
 279 -- Lambda bound type variables are preceded by "@"
 280 pprCoreBinder LambdaBind bndr = parens (pprTypedBinder bndr)
 281
 282 -- Case bound things don't get a signature or a herald
 283 pprCoreBinder CaseBind bndr = pprUntypedBinder bndr
 284
 285 pprUntypedBinder binder
 286   | isTyVar binder = ptext SLIT("@") <+> ppr binder     -- NB: don't print kind
 287   | otherwise      = pprIdBndr binder
 288
 289 pprTypedBinder binder
 290   | isTyVar binder  = ptext SLIT("@") <+> pprTyVarBndr binder
 291   | otherwise       = pprIdBndr binder <+> dcolon <+> pprType (idType binder)
 292
 293 pprTyVarBndr :: TyVar -> SDoc
 294 pprTyVarBndr tyvar
 295   = getPprStyle $ \ sty ->
 296     if debugStyle sty then
 297         hsep [ppr tyvar, dcolon, pprParendKind kind]
 298                 -- See comments with ppDcolon in PprCore.lhs
 299     else
 300         ppr tyvar
 301   where
 302     kind = tyVarKind tyvar
 303
 304 -- pprIdBndr does *not* print the type
 305 -- When printing any Id binder in debug mode, we print its inline pragma and one-shot-ness
 306 pprIdBndr id = ppr id <+> pprIdBndrInfo (idInfo id)
 307
 308 pprIdBndrInfo info
 309   = megaSeqIdInfo `seq` doc -- The seq is useful for poking on black holes
 310   where
 311     prag_info = inlinePragInfo info
 312     occ_info  = occInfo info
 313     dmd_info  = newDemandInfo info
 314     lbv_info  = lbvarInfo info
 315
 316     no_info = isAlwaysActive prag_info && isNoOcc occ_info &&
 317               (case dmd_info of { Nothing -> True; Just d -> isTop d }) &&
 318               hasNoLBVarInfo lbv_info
 319
 320     doc | no_info = empty
 321         | otherwise
 322         = brackets $ hcat [ppr prag_info, ppr occ_info,
 323                            ppr dmd_info, ppr lbv_info
 324 #ifdef OLD_STRICTNESS
 325                            , ppr (demandInfo id)
 326 #endif
 327                           ]
 328 \end{code}
 329
 330
 331 \begin{code}
 332 pprIdDetails :: Id -> SDoc
 333 pprIdDetails id | isGlobalId id     = ppr (globalIdDetails id)
 334                 | isExportedId id   = ptext SLIT("[Exported]")
 335                 | otherwise         = empty
 336
 337 ppIdInfo :: Id -> IdInfo -> SDoc
 338 ppIdInfo b info
 339   = brackets $
 340     vcat [  ppArityInfo a,
 341             ppWorkerInfo (workerInfo info),
 342             ppCafInfo (cafInfo info),
 343 #ifdef OLD_STRICTNESS
 344             ppStrictnessInfo s,
 345             ppCprInfo m,
 346 #endif
 347             pprNewStrictness (newStrictnessInfo info),
 348             if null rules then empty
 349             else ptext SLIT("RULES:") <+> vcat (map pprRule rules)
 350         -- Inline pragma, occ, demand, lbvar info
 351         -- printed out with all binders (when debug is on);
 352         -- see PprCore.pprIdBndr
 353         ]
 354   where
 355     a = arityInfo info
 356 #ifdef OLD_STRICTNESS
 357     s = strictnessInfo info
 358     m = cprInfo info
 359 #endif
 360     rules = specInfoRules (specInfo info)
 361 \end{code}
 362
 363
 364 \begin{code}
 365 instance Outputable CoreRule where
 366    ppr = pprRule
 367
 368 pprRules :: [CoreRule] -> SDoc
 369 pprRules rules = vcat (map pprRule rules)
 370
 371 pprRule :: CoreRule -> SDoc
 372 pprRule (BuiltinRule { ru_fn = fn, ru_name = name})
 373   = ptext SLIT("Built in rule for") <+> ppr fn <> colon <+> doubleQuotes (ftext name)
 374
 375 pprRule (Rule { ru_name = name, ru_act = act, ru_fn = fn,
 376                 ru_bndrs = tpl_vars, ru_args = tpl_args,
 377                 ru_rhs = rhs })
 378   = doubleQuotes (ftext name) <+> ppr act <+>
 379     sep [
 380           ptext SLIT("__forall") <+> braces (sep (map pprTypedBinder tpl_vars)),
 381           nest 2 (ppr fn <+> sep (map pprArg tpl_args)),
 382           nest 2 (ptext SLIT("=") <+> pprCoreExpr rhs)
 383     ] <+> semi
 384 \end{code}