ghc/compiler/deSugar/Desugar.lhs

   1 %
   2 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   3 %
   4 \section[Desugar]{@deSugar@: the main function}
   5
   6 \begin{code}
   7 module Desugar ( deSugar, deSugarExpr ) where
   8
   9 #include "HsVersions.h"
  10
  11 import CmdLineOpts      ( DynFlag(..), dopt, opt_SccProfilingOn )
  12 import HscTypes         ( ModGuts(..), ModGuts, HscEnv(..), ExternalPackageState(..),
  13                           PersistentCompilerState(..),
  14                           lookupType, unQualInScope )
  15 import HsSyn            ( MonoBinds, RuleDecl(..), RuleBndr(..),
  16                           HsExpr(..), HsBinds(..), MonoBinds(..) )
  17 import TcHsSyn          ( TypecheckedRuleDecl, TypecheckedHsExpr )
  18 import TcRnTypes        ( TcGblEnv(..), ImportAvails(..) )
  19 import MkIface          ( mkUsageInfo )
  20 import Id               ( Id )
  21 import CoreSyn
  22 import PprCore          ( pprIdRules, pprCoreExpr )
  23 import Subst            ( substExpr, mkSubst, mkInScopeSet )
  24 import DsMonad
  25 import DsExpr           ( dsExpr )
  26 import DsBinds          ( dsMonoBinds, AutoScc(..) )
  27 import DsForeign        ( dsForeigns )
  28 import DsExpr           ()      -- Forces DsExpr to be compiled; DsBinds only
  29                                 -- depends on DsExpr.hi-boot.
  30 import Module           ( Module, moduleEnvElts )
  31 import Id               ( Id )
  32 import NameEnv          ( lookupNameEnv )
  33 import VarEnv
  34 import VarSet
  35 import Bag              ( isEmptyBag, mapBag )
  36 import CoreLint         ( showPass, endPass )
  37 import ErrUtils         ( doIfSet, dumpIfSet_dyn, pprBagOfWarnings, addShortWarnLocLine )
  38 import Outputable
  39 import qualified Pretty
  40 import UniqSupply       ( mkSplitUniqSupply )
  41 import SrcLoc           ( SrcLoc )
  42 import FastString
  43 import DATA_IOREF       ( readIORef )
  44 \end{code}
  45
  46 %************************************************************************
  47 %*                                                                      *
  48 %*              The main function: deSugar
  49 %*                                                                      *
  50 %************************************************************************
  51
  52 \begin{code}
  53 deSugar :: HscEnv -> PersistentCompilerState
  54         -> TcGblEnv -> IO ModGuts
  55
  56 deSugar hsc_env pcs
  57         (TcGblEnv { tcg_mod      = mod,
  58                     tcg_type_env = type_env,
  59                     tcg_usages   = usage_var,
  60                     tcg_imports  = imports,
  61                     tcg_exports  = exports,
  62                     tcg_rdr_env  = rdr_env,
  63                     tcg_fix_env  = fix_env,
  64                     tcg_deprecs  = deprecs,
  65                     tcg_insts    = insts,
  66                     tcg_binds    = binds,
  67                     tcg_fords    = fords,
  68                     tcg_rules    = rules })
  69   = do  { showPass dflags "Desugar"
  70         ; us <- mkSplitUniqSupply 'd'
  71         ; usages <- readIORef usage_var
  72
  73         -- Do desugaring
  74         ; let ((ds_binds, ds_rules, ds_fords), ds_warns)
  75                 = initDs dflags us lookup mod
  76                          (dsProgram binds rules fords)
  77
  78               warn_doc = pprBagOfWarnings (mapBag mk_warn ds_warns)
  79
  80         -- Display any warnings
  81         ; doIfSet (not (isEmptyBag ds_warns))
  82                   (printErrs warn_doc)
  83
  84         -- Lint result if necessary
  85         ; endPass dflags "Desugar" Opt_D_dump_ds ds_binds
  86
  87         -- Dump output
  88         ; doIfSet (dopt Opt_D_dump_ds dflags)
  89                   (printDump (ppr_ds_rules ds_rules))
  90
  91         ; let
  92              deps = (moduleEnvElts (dep_mods imports), dep_pkgs imports)
  93              mod_guts = ModGuts {
  94                 mg_module   = mod,
  95                 mg_exports  = exports,
  96                 mg_deps     = deps,
  97                 mg_usages   = mkUsageInfo hsc_env eps imports usages,
  98                 mg_dir_imps = [m | (m,_) <- moduleEnvElts (imp_mods imports)],
  99                 mg_rdr_env  = rdr_env,
 100                 mg_fix_env  = fix_env,
 101                 mg_deprecs  = deprecs,
 102                 mg_types    = type_env,
 103                 mg_insts    = insts,
 104                 mg_rules    = ds_rules,
 105                 mg_binds    = ds_binds,
 106                 mg_foreign  = ds_fords }
 107
 108         ; return mod_guts
 109         }
 110
 111   where
 112     dflags       = hsc_dflags hsc_env
 113     print_unqual = unQualInScope rdr_env
 114
 115         -- Desugarer warnings are SDocs; here we
 116         -- add the info about whether or not to print unqualified
 117     mk_warn :: (SrcLoc,SDoc) -> (SrcLoc, Pretty.Doc)
 118     mk_warn (loc, sdoc) = addShortWarnLocLine loc print_unqual sdoc
 119
 120         -- The lookup function passed to initDs is used for well-known Ids,
 121         -- such as fold, build, cons etc, so the chances are
 122         -- it'll be found in the package symbol table.  That's
 123         -- why we don't merge all these tables
 124     eps      = pcs_EPS pcs
 125     pte      = eps_PTE eps
 126     hpt      = hsc_HPT hsc_env
 127     lookup n = case lookupType hpt pte n of {
 128                  Just v -> v ;
 129                  other ->
 130                case lookupNameEnv type_env n of
 131                  Just v -> v ;
 132                  other         -> pprPanic "Desugar: lookup:" (ppr n)
 133                }
 134
 135 deSugarExpr :: HscEnv
 136             -> PersistentCompilerState
 137             -> Module -> PrintUnqualified
 138             -> TypecheckedHsExpr
 139             -> IO CoreExpr
 140 deSugarExpr hsc_env pcs mod_name unqual tc_expr
 141   = do  { showPass dflags "Desugar"
 142         ; us <- mkSplitUniqSupply 'd'
 143
 144         -- Do desugaring
 145         ; let (core_expr, ds_warns) = initDs dflags us lookup mod_name (dsExpr tc_expr)
 146               warn_doc = pprBagOfWarnings (mapBag mk_warn ds_warns)
 147               mk_warn :: (SrcLoc,SDoc) -> (SrcLoc, Pretty.Doc)
 148               mk_warn (loc,sdoc) = addShortWarnLocLine loc unqual sdoc
 149
 150         -- Display any warnings
 151         ; doIfSet (not (isEmptyBag ds_warns))
 152                   (printErrs warn_doc)
 153
 154         -- Dump output
 155         ; dumpIfSet_dyn dflags Opt_D_dump_ds "Desugared" (pprCoreExpr core_expr)
 156
 157         ; return core_expr
 158         }
 159   where
 160     dflags   = hsc_dflags hsc_env
 161     hpt      = hsc_HPT hsc_env
 162     pte      = eps_PTE (pcs_EPS pcs)
 163     lookup n = case lookupType hpt pte n of
 164                  Just v -> v
 165                  other  -> pprPanic "Desugar: lookup:" (ppr n)
 166
 167 dsProgram all_binds rules fo_decls
 168   = dsMonoBinds auto_scc all_binds []   `thenDs` \ core_prs ->
 169     dsForeigns fo_decls                 `thenDs` \ (ds_fords, foreign_binds) ->
 170     let
 171         ds_binds      = [Rec (foreign_binds ++ core_prs)]
 172         -- Notice that we put the whole lot in a big Rec, even the foreign binds
 173         -- When compiling PrelFloat, which defines data Float = F# Float#
 174         -- we want F# to be in scope in the foreign marshalling code!
 175         -- You might think it doesn't matter, but the simplifier brings all top-level
 176         -- things into the in-scope set before simplifying; so we get no unfolding for F#!
 177
 178         local_binders = mkVarSet (bindersOfBinds ds_binds)
 179     in
 180     mapDs (dsRule local_binders) rules  `thenDs` \ ds_rules ->
 181     returnDs (ds_binds, ds_rules, ds_fords)
 182   where
 183     auto_scc | opt_SccProfilingOn = TopLevel
 184              | otherwise          = NoSccs
 185
 186 ppr_ds_rules [] = empty
 187 ppr_ds_rules rules
 188   = text "" $$ text "-------------- DESUGARED RULES -----------------" $$
 189     pprIdRules rules
 190 \end{code}
 191
 192
 193
 194 %************************************************************************
 195 %*                                                                      *
 196 %*              Desugaring transformation rules
 197 %*                                                                      *
 198 %************************************************************************
 199
 200 \begin{code}
 201 dsRule :: IdSet -> TypecheckedRuleDecl -> DsM (Id, CoreRule)
 202 dsRule in_scope (IfaceRuleOut fun rule) -- Built-in rules come this way
 203   = returnDs (fun, rule)
 204
 205 dsRule in_scope (HsRule name act vars lhs rhs loc)
 206   = putSrcLocDs loc             $
 207     ds_lhs all_vars lhs         `thenDs` \ (fn, args) ->
 208     dsExpr rhs                  `thenDs` \ core_rhs ->
 209     returnDs (fn, Rule name act tpl_vars args core_rhs)
 210   where
 211     tpl_vars = [var | RuleBndr var <- vars]
 212     all_vars = mkInScopeSet (in_scope `unionVarSet` mkVarSet tpl_vars)
 213
 214 ds_lhs all_vars lhs
 215   = let
 216         (dict_binds, body) = case lhs of
 217                 (HsLet (MonoBind dict_binds _ _) body) -> (dict_binds, body)
 218                 other                                  -> (EmptyMonoBinds, lhs)
 219     in
 220     ds_dict_binds dict_binds    `thenDs` \ dict_binds' ->
 221     dsExpr body                 `thenDs` \ body' ->
 222
 223         -- Substitute the dict bindings eagerly,
 224         -- and take the body apart into a (f args) form
 225     let
 226         subst_env = mkSubstEnv [id                   | (id,rhs) <- dict_binds']
 227                                [ContEx subst_env rhs | (id,rhs) <- dict_binds']
 228                         -- Note recursion here... substitution won't terminate
 229                         -- if there is genuine recursion... which there isn't
 230
 231         subst = mkSubst all_vars subst_env
 232         body'' = substExpr subst body'
 233     in
 234
 235         -- Now unpack the resulting body
 236     let
 237         pair = case collectArgs body'' of
 238                         (Var fn, args) -> (fn, args)
 239                         other          -> pprPanic "dsRule" (ppr lhs)
 240     in
 241     returnDs pair
 242
 243 ds_dict_binds EmptyMonoBinds       = returnDs []
 244 ds_dict_binds (AndMonoBinds b1 b2) = ds_dict_binds b1   `thenDs` \ env1 ->
 245                                      ds_dict_binds b2   `thenDs` \ env2 ->
 246                                      returnDs (env1 ++ env2)
 247 ds_dict_binds (VarMonoBind id rhs) = dsExpr rhs         `thenDs` \ rhs' ->
 248                                      returnDs [(id,rhs')]
 249 \end{code}