ghc/compiler/deSugar/DsBinds.lhs

   1 %
   2 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   3 %
   4 \section[DsBinds]{Pattern-matching bindings (HsBinds and MonoBinds)}
   5
   6 Handles @HsBinds@; those at the top level require different handling,
   7 in that the @Rec@/@NonRec@/etc structure is thrown away (whereas at
   8 lower levels it is preserved with @let@/@letrec@s).
   9
  10 \begin{code}
  11 module DsBinds ( dsMonoBinds, AutoScc(..) ) where
  12
  13 #include "HsVersions.h"
  14
  15
  16 import {-# SOURCE #-}   DsExpr( dsExpr )
  17
  18 import HsSyn            -- lots of things
  19 import CoreSyn          -- lots of things
  20 import CoreUtils        ( exprType, mkInlineMe, mkSCC )
  21 import TcHsSyn          ( TypecheckedMonoBinds )
  22 import DsMonad
  23 import DsGRHSs          ( dsGuarded )
  24 import DsUtils
  25 import Match            ( matchWrapper )
  26
  27 import CmdLineOpts      ( opt_AutoSccsOnAllToplevs, opt_AutoSccsOnExportedToplevs )
  28 import CostCentre       ( mkAutoCC, IsCafCC(..) )
  29 import Id               ( idType, idName, isExportedId, isSpecPragmaId, Id )
  30 import NameSet
  31 import VarSet
  32 import TcType           ( mkTyVarTy )
  33 import Subst            ( substTyWith )
  34 import TysWiredIn       ( voidTy )
  35 import Outputable
  36 import Maybe            ( isJust )
  37 \end{code}
  38
  39 %************************************************************************
  40 %*                                                                      *
  41 \subsection[dsMonoBinds]{Desugaring a @MonoBinds@}
  42 %*                                                                      *
  43 %************************************************************************
  44
  45 \begin{code}
  46 dsMonoBinds :: AutoScc                  -- scc annotation policy (see below)
  47             -> TypecheckedMonoBinds
  48             -> [(Id,CoreExpr)]          -- Put this on the end (avoid quadratic append)
  49             -> DsM [(Id,CoreExpr)]      -- Result
  50
  51 dsMonoBinds _ EmptyMonoBinds rest = returnDs rest
  52
  53 dsMonoBinds auto_scc (AndMonoBinds  binds_1 binds_2) rest
  54   = dsMonoBinds auto_scc binds_2 rest   `thenDs` \ rest' ->
  55     dsMonoBinds auto_scc binds_1 rest'
  56
  57 dsMonoBinds _ (CoreMonoBind var core_expr) rest
  58   = returnDs ((var, core_expr) : rest)
  59
  60 dsMonoBinds _ (VarMonoBind var expr) rest
  61   = dsExpr expr                 `thenDs` \ core_expr ->
  62
  63         -- Dictionary bindings are always VarMonoBinds, so
  64         -- we only need do this here
  65     addDictScc var core_expr    `thenDs` \ core_expr' ->
  66
  67     let
  68         -- Gross hack to prevent inlining into SpecPragmaId rhss
  69         -- Consider     fromIntegral = fromInteger . toInteger
  70         --              spec1 = fromIntegral Int Float
  71         -- Even though fromIntegral is small we don't want to inline
  72         -- it inside spec1, so that we collect the specialised call
  73         -- Solution: make spec1 an INLINE thing.
  74         core_expr'' = mkInline (isSpecPragmaId var) core_expr'
  75     in
  76
  77     returnDs ((var, core_expr'') : rest)
  78
  79 dsMonoBinds auto_scc (FunMonoBind fun _ matches locn) rest
  80   = putSrcLocDs locn    $
  81     matchWrapper (FunRhs fun) matches                   `thenDs` \ (args, body) ->
  82     addAutoScc auto_scc (fun, mkLams args body)         `thenDs` \ pair ->
  83     returnDs (pair : rest)
  84
  85 dsMonoBinds auto_scc (PatMonoBind pat grhss locn) rest
  86   = putSrcLocDs locn $
  87     dsGuarded grhss                             `thenDs` \ body_expr ->
  88     mkSelectorBinds pat body_expr               `thenDs` \ sel_binds ->
  89     mapDs (addAutoScc auto_scc) sel_binds       `thenDs` \ sel_binds ->
  90     returnDs (sel_binds ++ rest)
  91
  92         -- Common special case: no type or dictionary abstraction
  93 dsMonoBinds auto_scc (AbsBinds [] [] exports inlines binds) rest
  94   = dsMonoBinds (addSccs auto_scc exports) binds []`thenDs` \ core_prs ->
  95     let
  96         exports' = [(global, Var local) | (_, global, local) <- exports]
  97     in
  98     returnDs (addLocalInlines exports inlines core_prs ++ exports' ++ rest)
  99
 100         -- Another common case: one exported variable
 101         -- Non-recursive bindings come through this way
 102 dsMonoBinds auto_scc
 103      (AbsBinds all_tyvars dicts exps@[(tyvars, global, local)] inlines binds) rest
 104   = ASSERT( all (`elem` tyvars) all_tyvars )
 105     dsMonoBinds (addSccs auto_scc exps) binds []        `thenDs` \ core_prs ->
 106     let
 107         -- Always treat the binds as recursive, because the typechecker
 108         -- makes rather mixed-up dictionary bindings
 109         core_binds = [Rec core_prs]
 110         global'    = (global, mkInline (idName global `elemNameSet` inlines) $
 111                               mkLams tyvars $ mkLams dicts $
 112                               mkDsLets core_binds (Var local))
 113     in
 114     returnDs (global' : rest)
 115
 116 dsMonoBinds auto_scc (AbsBinds all_tyvars dicts exports inlines binds) rest
 117   = dsMonoBinds (addSccs auto_scc exports) binds []`thenDs` \ core_prs ->
 118     let
 119         core_binds = [Rec (addLocalInlines exports inlines core_prs)]
 120
 121         tup_expr      = mkTupleExpr locals
 122         tup_ty        = exprType tup_expr
 123         poly_tup_expr = mkLams all_tyvars $ mkLams dicts $
 124                         mkDsLets core_binds tup_expr
 125         locals        = [local | (_, _, local) <- exports]
 126         local_tys     = map idType locals
 127     in
 128     newSysLocalDs (exprType poly_tup_expr)              `thenDs` \ poly_tup_id ->
 129     let
 130         dict_args = map Var dicts
 131
 132         mk_bind (tyvars, global, local) n       -- locals !! n == local
 133           =     -- Need to make fresh locals to bind in the selector, because
 134                 -- some of the tyvars will be bound to voidTy
 135             newSysLocalsDs (map substitute local_tys)   `thenDs` \ locals' ->
 136             newSysLocalDs  (substitute tup_ty)          `thenDs` \ tup_id ->
 137             returnDs (global, mkLams tyvars $ mkLams dicts $
 138                               mkTupleSelector locals' (locals' !! n) tup_id $
 139                               mkApps (mkTyApps (Var poly_tup_id) ty_args) dict_args)
 140           where
 141             mk_ty_arg all_tyvar | all_tyvar `elem` tyvars = mkTyVarTy all_tyvar
 142                                 | otherwise               = voidTy
 143             ty_args    = map mk_ty_arg all_tyvars
 144             substitute = substTyWith all_tyvars ty_args
 145     in
 146     zipWithDs mk_bind exports [0..]             `thenDs` \ export_binds ->
 147      -- don't scc (auto-)annotate the tuple itself.
 148     returnDs ((poly_tup_id, poly_tup_expr) : (export_binds ++ rest))
 149 \end{code}
 150
 151
 152 %************************************************************************
 153 %*                                                                      *
 154 \subsection{Adding inline pragmas}
 155 %*                                                                      *
 156 %************************************************************************
 157
 158 \begin{code}
 159 mkInline :: Bool -> CoreExpr -> CoreExpr
 160 mkInline True  body = mkInlineMe body
 161 mkInline False body = body
 162
 163 addLocalInlines :: [(a, Id, Id)] -> NameSet -> [(Id,CoreExpr)] -> [(Id,CoreExpr)]
 164 addLocalInlines exports inlines pairs
 165   = [(bndr, mkInline (bndr `elemVarSet` local_inlines) rhs) | (bndr,rhs) <- pairs]
 166   where
 167     local_inlines = mkVarSet [l | (_,g,l) <- exports, idName g `elemNameSet` inlines]
 168 \end{code}
 169
 170
 171 %************************************************************************
 172 %*                                                                      *
 173 \subsection[addAutoScc]{Adding automatic sccs}
 174 %*                                                                      *
 175 %************************************************************************
 176
 177 \begin{code}
 178 data AutoScc
 179         = TopLevel
 180         | TopLevelAddSccs (Id -> Maybe Id)
 181         | NoSccs
 182
 183 addSccs :: AutoScc -> [(a,Id,Id)] -> AutoScc
 184 addSccs auto_scc@(TopLevelAddSccs _) exports = auto_scc
 185 addSccs NoSccs   exports = NoSccs
 186 addSccs TopLevel exports
 187   = TopLevelAddSccs (\id -> case [ exp | (_,exp,loc) <- exports, loc == id ] of
 188                                 (exp:_)  | opt_AutoSccsOnAllToplevs ||
 189                                             (isExportedId exp &&
 190                                              opt_AutoSccsOnExportedToplevs)
 191                                         -> Just exp
 192                                 _ -> Nothing)
 193
 194 addAutoScc :: AutoScc           -- if needs be, decorate toplevs?
 195            -> (Id, CoreExpr)
 196            -> DsM (Id, CoreExpr)
 197
 198 addAutoScc (TopLevelAddSccs auto_scc_fn) pair@(bndr, core_expr)
 199  | do_auto_scc
 200      = getModuleDs `thenDs` \ mod ->
 201        returnDs (bndr, mkSCC (mkAutoCC top_bndr mod NotCafCC) core_expr)
 202  where do_auto_scc = isJust maybe_auto_scc
 203        maybe_auto_scc = auto_scc_fn bndr
 204        (Just top_bndr) = maybe_auto_scc
 205
 206 addAutoScc _ pair
 207      = returnDs pair
 208 \end{code}
 209
 210 If profiling and dealing with a dict binding,
 211 wrap the dict in @_scc_ DICT <dict>@:
 212
 213 \begin{code}
 214 addDictScc var rhs = returnDs rhs
 215
 216 {- DISABLED for now (need to somehow make up a name for the scc) -- SDM
 217   | not ( opt_SccProfilingOn && opt_AutoSccsOnDicts)
 218     || not (isDictTy (idType var))
 219   = returnDs rhs                                -- That's easy: do nothing
 220
 221   | otherwise
 222   = getModuleAndGroupDs         `thenDs` \ (mod, grp) ->
 223         -- ToDo: do -dicts-all flag (mark dict things with individual CCs)
 224     returnDs (Note (SCC (mkAllDictsCC mod grp False)) rhs)
 225 -}
 226 \end{code}