ghc/compiler/deSugar/DsExpr.lhs

   1 %
   2 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   3 %
   4 \section[DsExpr]{Matching expressions (Exprs)}
   5
   6 \begin{code}
   7 module DsExpr ( dsExpr, dsLExpr, dsLocalBinds, dsValBinds, dsLit ) where
   8
   9 #include "HsVersions.h"
  10
  11
  12 import Match            ( matchWrapper, matchSimply, matchSinglePat )
  13 import MatchLit         ( dsLit, dsOverLit )
  14 import DsBinds          ( dsLHsBinds )
  15 import DsGRHSs          ( dsGuarded )
  16 import DsListComp       ( dsListComp, dsPArrComp )
  17 import DsUtils          ( mkErrorAppDs, mkStringExpr, mkConsExpr, mkNilExpr,
  18                           extractMatchResult, cantFailMatchResult, matchCanFail,
  19                           mkCoreTupTy, selectSimpleMatchVarL, lookupEvidence )
  20 import DsArrows         ( dsProcExpr )
  21 import DsMonad
  22
  23 #ifdef GHCI
  24         -- Template Haskell stuff iff bootstrapped
  25 import DsMeta           ( dsBracket )
  26 #endif
  27
  28 import HsSyn
  29 import TcHsSyn          ( hsPatType )
  30
  31 -- NB: The desugarer, which straddles the source and Core worlds, sometimes
  32 --     needs to see source types (newtypes etc), and sometimes not
  33 --     So WATCH OUT; check each use of split*Ty functions.
  34 -- Sigh.  This is a pain.
  35
  36 import TcType           ( tcSplitAppTy, tcSplitFunTys, tcTyConAppTyCon,
  37                           tcTyConAppArgs, isUnLiftedType, Type, mkAppTy )
  38 import Type             ( funArgTy, splitFunTys, isUnboxedTupleType, mkFunTy )
  39 import CoreSyn
  40 import CoreUtils        ( exprType, mkIfThenElse, bindNonRec )
  41
  42 import CostCentre       ( mkUserCC )
  43 import Id               ( Id, idType, idName, idDataCon )
  44 import PrelInfo         ( rEC_CON_ERROR_ID, iRREFUT_PAT_ERROR_ID )
  45 import DataCon          ( DataCon, dataConWrapId, dataConFieldLabels, dataConInstOrigArgTys )
  46 import DataCon          ( isVanillaDataCon )
  47 import TyCon            ( FieldLabel, tyConDataCons )
  48 import TysWiredIn       ( tupleCon )
  49 import BasicTypes       ( RecFlag(..), Boxity(..), ipNameName )
  50 import PrelNames        ( toPName,
  51                           returnMName, bindMName, thenMName, failMName,
  52                           mfixName )
  53 import SrcLoc           ( Located(..), unLoc, getLoc, noLoc )
  54 import Util             ( zipEqual, zipWithEqual )
  55 import Bag              ( bagToList )
  56 import Outputable
  57 import FastString
  58 \end{code}
  59
  60
  61 %************************************************************************
  62 %*                                                                      *
  63 \subsection{dsLet}
  64 %*                                                                      *
  65 %************************************************************************
  66
  67 @dsLet@ is a match-result transformer, taking the @MatchResult@ for the body
  68 and transforming it into one for the let-bindings enclosing the body.
  69
  70 This may seem a bit odd, but (source) let bindings can contain unboxed
  71 binds like
  72 \begin{verbatim}
  73         C x# = e
  74 \end{verbatim}
  75 This must be transformed to a case expression and, if the type has
  76 more than one constructor, may fail.
  77
  78 \begin{code}
  79 dsLocalBinds :: HsLocalBinds Id -> CoreExpr -> DsM CoreExpr
  80 dsLocalBinds EmptyLocalBinds    body = return body
  81 dsLocalBinds (HsValBinds binds) body = dsValBinds binds body
  82 dsLocalBinds (HsIPBinds binds)  body = dsIPBinds  binds body
  83
  84 -------------------------
  85 dsValBinds :: HsValBinds Id -> CoreExpr -> DsM CoreExpr
  86 dsValBinds (ValBindsOut binds _) body = foldrDs ds_val_bind body binds
  87
  88 -------------------------
  89 dsIPBinds (IPBinds ip_binds dict_binds) body
  90   = do  { prs <- dsLHsBinds dict_binds
  91         ; let inner = foldr (\(x,r) e -> Let (NonRec x r) e) body prs
  92         ; foldrDs ds_ip_bind inner ip_binds }
  93   where
  94     ds_ip_bind (L _ (IPBind n e)) body
  95       = dsLExpr e       `thenDs` \ e' ->
  96         returnDs (Let (NonRec (ipNameName n) e') body)
  97
  98 -------------------------
  99 ds_val_bind :: (RecFlag, LHsBinds Id) -> CoreExpr -> DsM CoreExpr
 100 -- Special case for bindings which bind unlifted variables
 101 -- We need to do a case right away, rather than building
 102 -- a tuple and doing selections.
 103 -- Silently ignore INLINE and SPECIALISE pragmas...
 104 ds_val_bind (is_rec, hsbinds) body
 105   | [L _ (AbsBinds [] [] exports binds)] <- bagToList hsbinds,
 106     or [isUnLiftedType (idType g) | (_, g, _, _) <- exports]
 107   = ASSERT (case is_rec of {NonRecursive -> True; other -> False})
 108         -- Unlifted bindings are always non-recursive
 109         -- and are always a Fun or Pat monobind
 110         --
 111         -- ToDo: in some bizarre case it's conceivable that there
 112         --       could be dict binds in the 'binds'.  (See the notes
 113         --       below.  Then pattern-match would fail.  Urk.)
 114     let
 115       body_w_exports                  = foldr bind_export body exports
 116       bind_export (tvs, g, l, _) body = ASSERT( null tvs )
 117                                         bindNonRec g (Var l) body
 118
 119       mk_error_app pat = mkErrorAppDs iRREFUT_PAT_ERROR_ID
 120                                     (exprType body)
 121                                     (showSDoc (ppr pat))
 122     in
 123     case bagToList binds of
 124       [L loc (FunBind (L _ fun) _ matches _)]
 125         -> putSrcSpanDs loc                                     $
 126            matchWrapper (FunRhs (idName fun)) matches           `thenDs` \ (args, rhs) ->
 127            ASSERT( null args )  -- Functions aren't lifted
 128            returnDs (bindNonRec fun rhs body_w_exports)
 129
 130       [L loc (PatBind pat grhss ty _)]
 131         -> putSrcSpanDs loc                     $
 132            dsGuarded grhss ty                   `thenDs` \ rhs ->
 133            mk_error_app pat                     `thenDs` \ error_expr ->
 134            matchSimply rhs PatBindRhs pat body_w_exports error_expr
 135
 136       other -> pprPanic "dsLet: unlifted" (pprLHsBinds hsbinds $$ ppr body)
 137
 138 -- Ordinary case for bindings
 139 ds_val_bind (is_rec, binds) body
 140   = dsLHsBinds binds    `thenDs` \ prs ->
 141     returnDs (Let (Rec prs) body)
 142         -- Use a Rec regardless of is_rec.
 143         -- Why? Because it allows the binds to be all
 144         -- mixed up, which is what happens in one rare case
 145         -- Namely, for an AbsBind with no tyvars and no dicts,
 146         --         but which does have dictionary bindings.
 147         -- See notes with TcSimplify.inferLoop [NO TYVARS]
 148         -- It turned out that wrapping a Rec here was the easiest solution
 149         --
 150         -- NB The previous case dealt with unlifted bindings, so we
 151         --    only have to deal with lifted ones now; so Rec is ok
 152 \end{code}
 153
 154 %************************************************************************
 155 %*                                                                      *
 156 \subsection[DsExpr-vars-and-cons]{Variables, constructors, literals}
 157 %*                                                                      *
 158 %************************************************************************
 159
 160 \begin{code}
 161 dsLExpr :: LHsExpr Id -> DsM CoreExpr
 162 dsLExpr (L loc e) = putSrcSpanDs loc $ dsExpr e
 163
 164 dsExpr :: HsExpr Id -> DsM CoreExpr
 165
 166 dsExpr (HsPar e)              = dsLExpr e
 167 dsExpr (ExprWithTySigOut e _) = dsLExpr e
 168 dsExpr (HsVar var)            = returnDs (Var var)
 169 dsExpr (HsIPVar ip)           = returnDs (Var (ipNameName ip))
 170 dsExpr (HsLit lit)            = dsLit lit
 171 dsExpr (HsOverLit lit)        = dsOverLit lit
 172
 173 dsExpr (NegApp expr neg_expr)
 174   = do  { core_expr <- dsLExpr expr
 175         ; core_neg  <- dsExpr neg_expr
 176         ; return (core_neg `App` core_expr) }
 177
 178 dsExpr expr@(HsLam a_Match)
 179   = matchWrapper LambdaExpr a_Match     `thenDs` \ (binders, matching_code) ->
 180     returnDs (mkLams binders matching_code)
 181
 182 dsExpr expr@(HsApp fun arg)
 183   = dsLExpr fun         `thenDs` \ core_fun ->
 184     dsLExpr arg         `thenDs` \ core_arg ->
 185     returnDs (core_fun `App` core_arg)
 186 \end{code}
 187
 188 Operator sections.  At first it looks as if we can convert
 189 \begin{verbatim}
 190         (expr op)
 191 \end{verbatim}
 192 to
 193 \begin{verbatim}
 194         \x -> op expr x
 195 \end{verbatim}
 196
 197 But no!  expr might be a redex, and we can lose laziness badly this
 198 way.  Consider
 199 \begin{verbatim}
 200         map (expr op) xs
 201 \end{verbatim}
 202 for example.  So we convert instead to
 203 \begin{verbatim}
 204         let y = expr in \x -> op y x
 205 \end{verbatim}
 206 If \tr{expr} is actually just a variable, say, then the simplifier
 207 will sort it out.
 208
 209 \begin{code}
 210 dsExpr (OpApp e1 op _ e2)
 211   = dsLExpr op                                          `thenDs` \ core_op ->
 212     -- for the type of y, we need the type of op's 2nd argument
 213     dsLExpr e1                          `thenDs` \ x_core ->
 214     dsLExpr e2                          `thenDs` \ y_core ->
 215     returnDs (mkApps core_op [x_core, y_core])
 216
 217 dsExpr (SectionL expr op)
 218   = dsLExpr op                                          `thenDs` \ core_op ->
 219     -- for the type of y, we need the type of op's 2nd argument
 220     let
 221         (x_ty:y_ty:_, _) = splitFunTys (exprType core_op)
 222         -- Must look through an implicit-parameter type;
 223         -- newtype impossible; hence Type.splitFunTys
 224     in
 225     dsLExpr expr                                `thenDs` \ x_core ->
 226     newSysLocalDs x_ty                  `thenDs` \ x_id ->
 227     newSysLocalDs y_ty                  `thenDs` \ y_id ->
 228
 229     returnDs (bindNonRec x_id x_core $
 230               Lam y_id (mkApps core_op [Var x_id, Var y_id]))
 231
 232 -- dsLExpr (SectionR op expr)   -- \ x -> op x expr
 233 dsExpr (SectionR op expr)
 234   = dsLExpr op                  `thenDs` \ core_op ->
 235     -- for the type of x, we need the type of op's 2nd argument
 236     let
 237         (x_ty:y_ty:_, _) = splitFunTys (exprType core_op)
 238         -- See comment with SectionL
 239     in
 240     dsLExpr expr                                `thenDs` \ y_core ->
 241     newSysLocalDs x_ty                  `thenDs` \ x_id ->
 242     newSysLocalDs y_ty                  `thenDs` \ y_id ->
 243
 244     returnDs (bindNonRec y_id y_core $
 245               Lam x_id (mkApps core_op [Var x_id, Var y_id]))
 246
 247 dsExpr (HsSCC cc expr)
 248   = dsLExpr expr                        `thenDs` \ core_expr ->
 249     getModuleDs                 `thenDs` \ mod_name ->
 250     returnDs (Note (SCC (mkUserCC cc mod_name)) core_expr)
 251
 252
 253 -- hdaume: core annotation
 254
 255 dsExpr (HsCoreAnn fs expr)
 256   = dsLExpr expr        `thenDs` \ core_expr ->
 257     returnDs (Note (CoreNote $ unpackFS fs) core_expr)
 258
 259 -- Special case to handle unboxed tuple patterns; they can't appear nested
 260 -- The idea is that
 261 --      case e of (# p1, p2 #) -> rhs
 262 -- should desugar to
 263 --      case e of (# x1, x2 #) -> ... match p1, p2 ...
 264 -- NOT
 265 --      let x = e in case x of ....
 266 --
 267 -- But there may be a big
 268 --      let fail = ... in case e of ...
 269 -- wrapping the whole case, which complicates matters slightly
 270 -- It all seems a bit fragile.  Test is dsrun013.
 271
 272 dsExpr (HsCase discrim matches@(MatchGroup _ ty))
 273  | isUnboxedTupleType (funArgTy ty)
 274  =  dsLExpr discrim                     `thenDs` \ core_discrim ->
 275     matchWrapper CaseAlt matches        `thenDs` \ ([discrim_var], matching_code) ->
 276     let
 277         scrungle (Case (Var x) bndr ty alts)
 278                 | x == discrim_var = Case core_discrim bndr ty alts
 279         scrungle (Let binds body)  = Let binds (scrungle body)
 280         scrungle other = panic ("dsLExpr: tuple pattern:\n" ++ showSDoc (ppr other))
 281     in
 282     returnDs (scrungle matching_code)
 283
 284 dsExpr (HsCase discrim matches)
 285   = dsLExpr discrim                     `thenDs` \ core_discrim ->
 286     matchWrapper CaseAlt matches        `thenDs` \ ([discrim_var], matching_code) ->
 287     returnDs (bindNonRec discrim_var core_discrim matching_code)
 288
 289 dsExpr (HsLet binds body)
 290   = dsLExpr body                `thenDs` \ body' ->
 291     dsLocalBinds binds body'
 292
 293 -- We need the `ListComp' form to use `deListComp' (rather than the "do" form)
 294 -- because the interpretation of `stmts' depends on what sort of thing it is.
 295 --
 296 dsExpr (HsDo ListComp stmts body result_ty)
 297   =     -- Special case for list comprehensions
 298     dsListComp stmts body elt_ty
 299   where
 300     [elt_ty] = tcTyConAppArgs result_ty
 301
 302 dsExpr (HsDo DoExpr stmts body result_ty)
 303   = dsDo stmts body result_ty
 304
 305 dsExpr (HsDo (MDoExpr tbl) stmts body result_ty)
 306   = dsMDo tbl stmts body result_ty
 307
 308 dsExpr (HsDo PArrComp stmts body result_ty)
 309   =     -- Special case for array comprehensions
 310     dsPArrComp (map unLoc stmts) body elt_ty
 311   where
 312     [elt_ty] = tcTyConAppArgs result_ty
 313
 314 dsExpr (HsIf guard_expr then_expr else_expr)
 315   = dsLExpr guard_expr  `thenDs` \ core_guard ->
 316     dsLExpr then_expr   `thenDs` \ core_then ->
 317     dsLExpr else_expr   `thenDs` \ core_else ->
 318     returnDs (mkIfThenElse core_guard core_then core_else)
 319 \end{code}
 320
 321
 322 \noindent
 323 \underline{\bf Type lambda and application}
 324 %              ~~~~~~~~~~~~~~~~~~~~~~~~~~~
 325 \begin{code}
 326 dsExpr (TyLam tyvars expr)
 327   = dsLExpr expr `thenDs` \ core_expr ->
 328     returnDs (mkLams tyvars core_expr)
 329
 330 dsExpr (TyApp expr tys)
 331   = dsLExpr expr                `thenDs` \ core_expr ->
 332     returnDs (mkTyApps core_expr tys)
 333 \end{code}
 334
 335
 336 \noindent
 337 \underline{\bf Various data construction things}
 338 %              ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 339 \begin{code}
 340 dsExpr (ExplicitList ty xs)
 341   = go xs
 342   where
 343     go []     = returnDs (mkNilExpr ty)
 344     go (x:xs) = dsLExpr x                               `thenDs` \ core_x ->
 345                 go xs                                   `thenDs` \ core_xs ->
 346                 returnDs (mkConsExpr ty core_x core_xs)
 347
 348 -- we create a list from the array elements and convert them into a list using
 349 -- `PrelPArr.toP'
 350 --
 351 --  * the main disadvantage to this scheme is that `toP' traverses the list
 352 --   twice: once to determine the length and a second time to put to elements
 353 --   into the array; this inefficiency could be avoided by exposing some of
 354 --   the innards of `PrelPArr' to the compiler (ie, have a `PrelPArrBase') so
 355 --   that we can exploit the fact that we already know the length of the array
 356 --   here at compile time
 357 --
 358 dsExpr (ExplicitPArr ty xs)
 359   = dsLookupGlobalId toPName                            `thenDs` \toP      ->
 360     dsExpr (ExplicitList ty xs)                         `thenDs` \coreList ->
 361     returnDs (mkApps (Var toP) [Type ty, coreList])
 362
 363 dsExpr (ExplicitTuple expr_list boxity)
 364   = mappM dsLExpr expr_list       `thenDs` \ core_exprs  ->
 365     returnDs (mkConApp (tupleCon boxity (length expr_list))
 366                        (map (Type .  exprType) core_exprs ++ core_exprs))
 367
 368 dsExpr (ArithSeq expr (From from))
 369   = dsExpr expr           `thenDs` \ expr2 ->
 370     dsLExpr from          `thenDs` \ from2 ->
 371     returnDs (App expr2 from2)
 372
 373 dsExpr (ArithSeq expr (FromTo from two))
 374   = dsExpr expr           `thenDs` \ expr2 ->
 375     dsLExpr from          `thenDs` \ from2 ->
 376     dsLExpr two           `thenDs` \ two2 ->
 377     returnDs (mkApps expr2 [from2, two2])
 378
 379 dsExpr (ArithSeq expr (FromThen from thn))
 380   = dsExpr expr           `thenDs` \ expr2 ->
 381     dsLExpr from          `thenDs` \ from2 ->
 382     dsLExpr thn           `thenDs` \ thn2 ->
 383     returnDs (mkApps expr2 [from2, thn2])
 384
 385 dsExpr (ArithSeq expr (FromThenTo from thn two))
 386   = dsExpr expr           `thenDs` \ expr2 ->
 387     dsLExpr from          `thenDs` \ from2 ->
 388     dsLExpr thn           `thenDs` \ thn2 ->
 389     dsLExpr two           `thenDs` \ two2 ->
 390     returnDs (mkApps expr2 [from2, thn2, two2])
 391
 392 dsExpr (PArrSeq expr (FromTo from two))
 393   = dsExpr expr           `thenDs` \ expr2 ->
 394     dsLExpr from          `thenDs` \ from2 ->
 395     dsLExpr two           `thenDs` \ two2 ->
 396     returnDs (mkApps expr2 [from2, two2])
 397
 398 dsExpr (PArrSeq expr (FromThenTo from thn two))
 399   = dsExpr expr           `thenDs` \ expr2 ->
 400     dsLExpr from          `thenDs` \ from2 ->
 401     dsLExpr thn           `thenDs` \ thn2 ->
 402     dsLExpr two           `thenDs` \ two2 ->
 403     returnDs (mkApps expr2 [from2, thn2, two2])
 404
 405 dsExpr (PArrSeq expr _)
 406   = panic "DsExpr.dsExpr: Infinite parallel array!"
 407     -- the parser shouldn't have generated it and the renamer and typechecker
 408     -- shouldn't have let it through
 409 \end{code}
 410
 411 \noindent
 412 \underline{\bf Record construction and update}
 413 %              ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 414 For record construction we do this (assuming T has three arguments)
 415 \begin{verbatim}
 416         T { op2 = e }
 417 ==>
 418         let err = /\a -> recConErr a
 419         T (recConErr t1 "M.lhs/230/op1")
 420           e
 421           (recConErr t1 "M.lhs/230/op3")
 422 \end{verbatim}
 423 @recConErr@ then converts its arugment string into a proper message
 424 before printing it as
 425 \begin{verbatim}
 426         M.lhs, line 230: missing field op1 was evaluated
 427 \end{verbatim}
 428
 429 We also handle @C{}@ as valid construction syntax for an unlabelled
 430 constructor @C@, setting all of @C@'s fields to bottom.
 431
 432 \begin{code}
 433 dsExpr (RecordCon (L _ data_con_id) con_expr rbinds)
 434   = dsExpr con_expr     `thenDs` \ con_expr' ->
 435     let
 436         (arg_tys, _) = tcSplitFunTys (exprType con_expr')
 437         -- A newtype in the corner should be opaque;
 438         -- hence TcType.tcSplitFunTys
 439
 440         mk_arg (arg_ty, lbl)    -- Selector id has the field label as its name
 441           = case [rhs | (L _ sel_id, rhs) <- rbinds, lbl == idName sel_id] of
 442               (rhs:rhss) -> ASSERT( null rhss )
 443                             dsLExpr rhs
 444               []         -> mkErrorAppDs rEC_CON_ERROR_ID arg_ty (showSDoc (ppr lbl))
 445         unlabelled_bottom arg_ty = mkErrorAppDs rEC_CON_ERROR_ID arg_ty ""
 446
 447         labels = dataConFieldLabels (idDataCon data_con_id)
 448         -- The data_con_id is guaranteed to be the wrapper id of the constructor
 449     in
 450
 451     (if null labels
 452         then mappM unlabelled_bottom arg_tys
 453         else mappM mk_arg (zipEqual "dsExpr:RecordCon" arg_tys labels))
 454         `thenDs` \ con_args ->
 455
 456     returnDs (mkApps con_expr' con_args)
 457 \end{code}
 458
 459 Record update is a little harder. Suppose we have the decl:
 460 \begin{verbatim}
 461         data T = T1 {op1, op2, op3 :: Int}
 462                | T2 {op4, op2 :: Int}
 463                | T3
 464 \end{verbatim}
 465 Then we translate as follows:
 466 \begin{verbatim}
 467         r { op2 = e }
 468 ===>
 469         let op2 = e in
 470         case r of
 471           T1 op1 _ op3 -> T1 op1 op2 op3
 472           T2 op4 _     -> T2 op4 op2
 473           other        -> recUpdError "M.lhs/230"
 474 \end{verbatim}
 475 It's important that we use the constructor Ids for @T1@, @T2@ etc on the
 476 RHSs, and do not generate a Core constructor application directly, because the constructor
 477 might do some argument-evaluation first; and may have to throw away some
 478 dictionaries.
 479
 480 \begin{code}
 481 dsExpr (RecordUpd record_expr [] record_in_ty record_out_ty)
 482   = dsLExpr record_expr
 483
 484 dsExpr expr@(RecordUpd record_expr rbinds record_in_ty record_out_ty)
 485   = dsLExpr record_expr         `thenDs` \ record_expr' ->
 486
 487         -- Desugar the rbinds, and generate let-bindings if
 488         -- necessary so that we don't lose sharing
 489
 490     let
 491         in_inst_tys  = tcTyConAppArgs record_in_ty      -- Newtype opaque
 492         out_inst_tys = tcTyConAppArgs record_out_ty     -- Newtype opaque
 493         in_out_ty    = mkFunTy record_in_ty record_out_ty
 494
 495         mk_val_arg field old_arg_id
 496           = case [rhs | (L _ sel_id, rhs) <- rbinds, field == idName sel_id] of
 497               (rhs:rest) -> ASSERT(null rest) rhs
 498               []         -> nlHsVar old_arg_id
 499
 500         mk_alt con
 501           = newSysLocalsDs (dataConInstOrigArgTys con in_inst_tys) `thenDs` \ arg_ids ->
 502                 -- This call to dataConInstOrigArgTys won't work for existentials
 503                 -- but existentials don't have record types anyway
 504             let
 505                 val_args = zipWithEqual "dsExpr:RecordUpd" mk_val_arg
 506                                         (dataConFieldLabels con) arg_ids
 507                 rhs = foldl (\a b -> nlHsApp a b)
 508                         (noLoc $ TyApp (nlHsVar (dataConWrapId con))
 509                                 out_inst_tys)
 510                           val_args
 511             in
 512             returnDs (mkSimpleMatch [noLoc $ ConPatOut (noLoc con) [] [] emptyLHsBinds
 513                                                        (PrefixCon (map nlVarPat arg_ids)) record_in_ty]
 514                                     rhs)
 515     in
 516         -- Record stuff doesn't work for existentials
 517         -- The type checker checks for this, but we need
 518         -- worry only about the constructors that are to be updated
 519     ASSERT2( all isVanillaDataCon cons_to_upd, ppr expr )
 520
 521         -- It's important to generate the match with matchWrapper,
 522         -- and the right hand sides with applications of the wrapper Id
 523         -- so that everything works when we are doing fancy unboxing on the
 524         -- constructor aguments.
 525     mappM mk_alt cons_to_upd                            `thenDs` \ alts ->
 526     matchWrapper RecUpd (MatchGroup alts in_out_ty)     `thenDs` \ ([discrim_var], matching_code) ->
 527
 528     returnDs (bindNonRec discrim_var record_expr' matching_code)
 529
 530   where
 531     updated_fields :: [FieldLabel]
 532     updated_fields = [ idName sel_id | (L _ sel_id,_) <- rbinds]
 533
 534         -- Get the type constructor from the record_in_ty
 535         -- so that we are sure it'll have all its DataCons
 536         -- (In GHCI, it's possible that some TyCons may not have all
 537         --  their constructors, in a module-loop situation.)
 538     tycon       = tcTyConAppTyCon record_in_ty
 539     data_cons   = tyConDataCons tycon
 540     cons_to_upd = filter has_all_fields data_cons
 541
 542     has_all_fields :: DataCon -> Bool
 543     has_all_fields con_id
 544       = all (`elem` con_fields) updated_fields
 545       where
 546         con_fields = dataConFieldLabels con_id
 547 \end{code}
 548
 549
 550 \noindent
 551 \underline{\bf Dictionary lambda and application}
 552 %              ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 553 @DictLam@ and @DictApp@ turn into the regular old things.
 554 (OLD:) @DictFunApp@ also becomes a curried application, albeit slightly more
 555 complicated; reminiscent of fully-applied constructors.
 556 \begin{code}
 557 dsExpr (DictLam dictvars expr)
 558   = dsLExpr expr `thenDs` \ core_expr ->
 559     returnDs (mkLams dictvars core_expr)
 560
 561 ------------------
 562
 563 dsExpr (DictApp expr dicts)     -- becomes a curried application
 564   = dsLExpr expr                        `thenDs` \ core_expr ->
 565     returnDs (foldl (\f d -> f `App` (Var d)) core_expr dicts)
 566 \end{code}
 567
 568 Here is where we desugar the Template Haskell brackets and escapes
 569
 570 \begin{code}
 571 -- Template Haskell stuff
 572
 573 #ifdef GHCI     /* Only if bootstrapping */
 574 dsExpr (HsBracketOut x ps) = dsBracket x ps
 575 dsExpr (HsSpliceE s)       = pprPanic "dsExpr:splice" (ppr s)
 576 #endif
 577
 578 -- Arrow notation extension
 579 dsExpr (HsProc pat cmd) = dsProcExpr pat cmd
 580 \end{code}
 581
 582
 583 \begin{code}
 584
 585 #ifdef DEBUG
 586 -- HsSyn constructs that just shouldn't be here:
 587 dsExpr (ExprWithTySig _ _)  = panic "dsExpr:ExprWithTySig"
 588 #endif
 589
 590 \end{code}
 591
 592 %--------------------------------------------------------------------
 593
 594 Desugar 'do' and 'mdo' expressions (NOT list comprehensions, they're
 595 handled in DsListComp).  Basically does the translation given in the
 596 Haskell 98 report:
 597
 598 \begin{code}
 599 dsDo    :: [LStmt Id]
 600         -> LHsExpr Id
 601         -> Type                 -- Type of the whole expression
 602         -> DsM CoreExpr
 603
 604 dsDo stmts body result_ty
 605   = go (map unLoc stmts)
 606   where
 607     go [] = dsLExpr body
 608
 609     go (ExprStmt rhs then_expr _ : stmts)
 610       = do { rhs2 <- dsLExpr rhs
 611            ; then_expr2 <- dsExpr then_expr
 612            ; rest <- go stmts
 613            ; returnDs (mkApps then_expr2 [rhs2, rest]) }
 614
 615     go (LetStmt binds : stmts)
 616       = do { rest <- go stmts
 617            ; dsLocalBinds binds rest }
 618
 619     go (BindStmt pat rhs bind_op fail_op : stmts)
 620       = do { body  <- go stmts
 621            ; var   <- selectSimpleMatchVarL pat
 622            ; match <- matchSinglePat (Var var) (StmtCtxt DoExpr) pat
 623                                   result_ty (cantFailMatchResult body)
 624            ; match_code <- handle_failure pat match fail_op
 625            ; rhs'       <- dsLExpr rhs
 626            ; bind_op'   <- dsExpr bind_op
 627            ; returnDs (mkApps bind_op' [rhs', Lam var match_code]) }
 628
 629     -- In a do expression, pattern-match failure just calls
 630     -- the monadic 'fail' rather than throwing an exception
 631     handle_failure pat match fail_op
 632       | matchCanFail match
 633       = do { fail_op' <- dsExpr fail_op
 634            ; fail_msg <- mkStringExpr (mk_fail_msg pat)
 635            ; extractMatchResult match (App fail_op' fail_msg) }
 636       | otherwise
 637       = extractMatchResult match (error "It can't fail")
 638
 639 mk_fail_msg pat = "Pattern match failure in do expression at " ++
 640                   showSDoc (ppr (getLoc pat))
 641 \end{code}
 642
 643 Translation for RecStmt's:
 644 -----------------------------
 645 We turn (RecStmt [v1,..vn] stmts) into:
 646
 647   (v1,..,vn) <- mfix (\~(v1,..vn). do stmts
 648                                       return (v1,..vn))
 649
 650 \begin{code}
 651 dsMDo   :: PostTcTable
 652         -> [LStmt Id]
 653         -> LHsExpr Id
 654         -> Type                 -- Type of the whole expression
 655         -> DsM CoreExpr
 656
 657 dsMDo tbl stmts body result_ty
 658   = go (map unLoc stmts)
 659   where
 660     (m_ty, b_ty) = tcSplitAppTy result_ty       -- result_ty must be of the form (m b)
 661     mfix_id   = lookupEvidence tbl mfixName
 662     return_id = lookupEvidence tbl returnMName
 663     bind_id   = lookupEvidence tbl bindMName
 664     then_id   = lookupEvidence tbl thenMName
 665     fail_id   = lookupEvidence tbl failMName
 666     ctxt      = MDoExpr tbl
 667
 668     go [] = dsLExpr body
 669
 670     go (LetStmt binds : stmts)
 671       = do { rest <- go stmts
 672            ; dsLocalBinds binds rest }
 673
 674     go (ExprStmt rhs _ rhs_ty : stmts)
 675       = do { rhs2 <- dsLExpr rhs
 676            ; rest <- go stmts
 677            ; returnDs (mkApps (Var then_id) [Type rhs_ty, Type b_ty, rhs2, rest]) }
 678
 679     go (BindStmt pat rhs _ _ : stmts)
 680       = do { body  <- go stmts
 681            ; var   <- selectSimpleMatchVarL pat
 682            ; match <- matchSinglePat (Var var) (StmtCtxt ctxt) pat
 683                                   result_ty (cantFailMatchResult body)
 684            ; fail_msg   <- mkStringExpr (mk_fail_msg pat)
 685            ; let fail_expr = mkApps (Var fail_id) [Type b_ty, fail_msg]
 686            ; match_code <- extractMatchResult match fail_expr
 687
 688            ; rhs'       <- dsLExpr rhs
 689            ; returnDs (mkApps (Var bind_id) [Type (hsPatType pat), Type b_ty,
 690                                              rhs', Lam var match_code]) }
 691
 692     go (RecStmt rec_stmts later_ids rec_ids rec_rets binds : stmts)
 693       = ASSERT( length rec_ids > 0 )
 694         ASSERT( length rec_ids == length rec_rets )
 695         go (new_bind_stmt : let_stmt : stmts)
 696       where
 697         new_bind_stmt = mkBindStmt (mk_tup_pat later_pats) mfix_app
 698         let_stmt = LetStmt (HsValBinds (ValBindsOut [(Recursive, binds)] []))
 699
 700
 701                 -- Remove the later_ids that appear (without fancy coercions)
 702                 -- in rec_rets, because there's no need to knot-tie them separately
 703                 -- See Note [RecStmt] in HsExpr
 704         later_ids'   = filter (`notElem` mono_rec_ids) later_ids
 705         mono_rec_ids = [ id | HsVar id <- rec_rets ]
 706
 707         mfix_app = nlHsApp (noLoc $ TyApp (nlHsVar mfix_id) [tup_ty]) mfix_arg
 708         mfix_arg = noLoc $ HsLam (MatchGroup [mkSimpleMatch [mfix_pat] body]
 709                                              (mkFunTy tup_ty body_ty))
 710
 711         -- The rec_tup_pat must bind the rec_ids only; remember that the
 712         --      trimmed_laters may share the same Names
 713         -- Meanwhile, the later_pats must bind the later_vars
 714         rec_tup_pats = map mk_wild_pat later_ids' ++ map nlVarPat rec_ids
 715         later_pats   = map nlVarPat    later_ids' ++ map mk_later_pat rec_ids
 716         rets         = map nlHsVar     later_ids' ++ map noLoc rec_rets
 717
 718         mfix_pat = noLoc $ LazyPat $ mk_tup_pat rec_tup_pats
 719         body     = noLoc $ HsDo ctxt rec_stmts return_app body_ty
 720         body_ty = mkAppTy m_ty tup_ty
 721         tup_ty  = mkCoreTupTy (map idType (later_ids' ++ rec_ids))
 722                   -- mkCoreTupTy deals with singleton case
 723
 724         return_app  = nlHsApp (noLoc $ TyApp (nlHsVar return_id) [tup_ty])
 725                               (mk_ret_tup rets)
 726
 727         mk_wild_pat :: Id -> LPat Id
 728         mk_wild_pat v = noLoc $ WildPat $ idType v
 729
 730         mk_later_pat :: Id -> LPat Id
 731         mk_later_pat v | v `elem` later_ids' = mk_wild_pat v
 732                        | otherwise           = nlVarPat v
 733
 734         mk_tup_pat :: [LPat Id] -> LPat Id
 735         mk_tup_pat [p] = p
 736         mk_tup_pat ps  = noLoc $ TuplePat ps Boxed
 737
 738         mk_ret_tup :: [LHsExpr Id] -> LHsExpr Id
 739         mk_ret_tup [r] = r
 740         mk_ret_tup rs  = noLoc $ ExplicitTuple rs Boxed
 741 \end{code}