ghc/compiler/deSugar/DsExpr.lhs

   1 %
   2 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   3 %
   4 \section[DsExpr]{Matching expressions (Exprs)}
   5
   6 \begin{code}
   7 module DsExpr ( dsExpr, dsLet, dsLit ) where
   8
   9 #include "HsVersions.h"
  10
  11
  12 import Match            ( matchWrapper, matchSimply )
  13 import MatchLit         ( dsLit )
  14 import DsBinds          ( dsMonoBinds, AutoScc(..) )
  15 import DsGRHSs          ( dsGuarded )
  16 import DsCCall          ( dsCCall )
  17 import DsListComp       ( dsListComp, dsPArrComp )
  18 import DsUtils          ( mkErrorAppDs, mkStringLit, mkConsExpr, mkNilExpr,
  19                           mkCoreTupTy, selectMatchVar,
  20                           dsReboundNames, lookupReboundName )
  21 import DsArrows         ( dsProcExpr )
  22 import DsMonad
  23
  24 #ifdef GHCI
  25         -- Template Haskell stuff iff bootstrapped
  26 import DsMeta           ( dsBracket, dsReify )
  27 #endif
  28
  29 import HsSyn            ( HsExpr(..), Pat(..), ArithSeqInfo(..),
  30                           Stmt(..), HsMatchContext(..), HsStmtContext(..),
  31                           Match(..), HsBinds(..), MonoBinds(..), HsConDetails(..),
  32                           ReboundNames,
  33                           mkSimpleMatch, isDoExpr
  34                         )
  35 import TcHsSyn          ( TypecheckedHsExpr, TypecheckedHsBinds, TypecheckedStmt, hsPatType )
  36
  37 -- NB: The desugarer, which straddles the source and Core worlds, sometimes
  38 --     needs to see source types (newtypes etc), and sometimes not
  39 --     So WATCH OUT; check each use of split*Ty functions.
  40 -- Sigh.  This is a pain.
  41
  42 import TcType           ( tcSplitAppTy, tcSplitFunTys, tcTyConAppArgs,
  43                           tcSplitTyConApp, isUnLiftedType, Type,
  44                           mkAppTy )
  45 import Type             ( splitFunTys )
  46 import CoreSyn
  47 import CoreUtils        ( exprType, mkIfThenElse, bindNonRec )
  48
  49 import FieldLabel       ( FieldLabel, fieldLabelTyCon )
  50 import CostCentre       ( mkUserCC )
  51 import Id               ( Id, idType, idName, recordSelectorFieldLabel )
  52 import PrelInfo         ( rEC_CON_ERROR_ID, iRREFUT_PAT_ERROR_ID )
  53 import DataCon          ( DataCon, dataConWrapId, dataConFieldLabels, dataConInstOrigArgTys )
  54 import DataCon          ( isExistentialDataCon )
  55 import Name             ( Name )
  56 import TyCon            ( tyConDataCons )
  57 import TysWiredIn       ( tupleCon )
  58 import BasicTypes       ( RecFlag(..), Boxity(..), ipNameName )
  59 import PrelNames        ( toPName,
  60                           returnMName, bindMName, thenMName, failMName,
  61                           mfixName )
  62 import SrcLoc           ( noSrcLoc )
  63 import Util             ( zipEqual, zipWithEqual )
  64 import Outputable
  65 import FastString
  66 \end{code}
  67
  68
  69 %************************************************************************
  70 %*                                                                      *
  71 \subsection{dsLet}
  72 %*                                                                      *
  73 %************************************************************************
  74
  75 @dsLet@ is a match-result transformer, taking the @MatchResult@ for the body
  76 and transforming it into one for the let-bindings enclosing the body.
  77
  78 This may seem a bit odd, but (source) let bindings can contain unboxed
  79 binds like
  80 \begin{verbatim}
  81         C x# = e
  82 \end{verbatim}
  83 This must be transformed to a case expression and, if the type has
  84 more than one constructor, may fail.
  85
  86 \begin{code}
  87 dsLet :: TypecheckedHsBinds -> CoreExpr -> DsM CoreExpr
  88
  89 dsLet EmptyBinds body
  90   = returnDs body
  91
  92 dsLet (ThenBinds b1 b2) body
  93   = dsLet b2 body       `thenDs` \ body' ->
  94     dsLet b1 body'
  95
  96 dsLet (IPBinds binds) body
  97   = foldlDs dsIPBind body binds
  98   where
  99     dsIPBind body (n, e)
 100         = dsExpr e      `thenDs` \ e' ->
 101           returnDs (Let (NonRec (ipNameName n) e') body)
 102
 103 -- Special case for bindings which bind unlifted variables
 104 -- We need to do a case right away, rather than building
 105 -- a tuple and doing selections.
 106 -- Silently ignore INLINE pragmas...
 107 dsLet bind@(MonoBind (AbsBinds [] [] exports inlines binds) sigs is_rec) body
 108   | or [isUnLiftedType (idType g) | (_, g, l) <- exports]
 109   = ASSERT (case is_rec of {NonRecursive -> True; other -> False})
 110         -- Unlifted bindings are always non-recursive
 111         -- and are always a Fun or Pat monobind
 112         --
 113         -- ToDo: in some bizarre case it's conceivable that there
 114         --       could be dict binds in the 'binds'.  (See the notes
 115         --       below.  Then pattern-match would fail.  Urk.)
 116     case binds of
 117       FunMonoBind fun _ matches loc
 118         -> putSrcLocDs loc                              $
 119            matchWrapper (FunRhs (idName fun)) matches   `thenDs` \ (args, rhs) ->
 120            ASSERT( null args )  -- Functions aren't lifted
 121            returnDs (bindNonRec fun rhs body_w_exports)
 122
 123       PatMonoBind pat grhss loc
 124         -> putSrcLocDs loc                      $
 125            dsGuarded grhss                      `thenDs` \ rhs ->
 126            mk_error_app pat                     `thenDs` \ error_expr ->
 127            matchSimply rhs PatBindRhs pat body_w_exports error_expr
 128
 129       other -> pprPanic "dsLet: unlifted" (ppr bind $$ ppr body)
 130   where
 131     body_w_exports               = foldr bind_export body exports
 132     bind_export (tvs, g, l) body = ASSERT( null tvs )
 133                                    bindNonRec g (Var l) body
 134
 135     mk_error_app pat = mkErrorAppDs iRREFUT_PAT_ERROR_ID
 136                                     (exprType body)
 137                                     (showSDoc (ppr pat))
 138
 139 -- Ordinary case for bindings
 140 dsLet (MonoBind binds sigs is_rec) body
 141   = dsMonoBinds NoSccs binds []  `thenDs` \ prs ->
 142     returnDs (Let (Rec prs) body)
 143         -- Use a Rec regardless of is_rec.
 144         -- Why? Because it allows the MonoBinds to be all
 145         -- mixed up, which is what happens in one rare case
 146         -- Namely, for an AbsBind with no tyvars and no dicts,
 147         --         but which does have dictionary bindings.
 148         -- See notes with TcSimplify.inferLoop [NO TYVARS]
 149         -- It turned out that wrapping a Rec here was the easiest solution
 150         --
 151         -- NB The previous case dealt with unlifted bindings, so we
 152         --    only have to deal with lifted ones now; so Rec is ok
 153 \end{code}
 154
 155 %************************************************************************
 156 %*                                                                      *
 157 \subsection[DsExpr-vars-and-cons]{Variables, constructors, literals}
 158 %*                                                                      *
 159 %************************************************************************
 160
 161 \begin{code}
 162 dsExpr :: TypecheckedHsExpr -> DsM CoreExpr
 163
 164 dsExpr (HsPar x) = dsExpr x
 165 dsExpr (HsVar var)  = returnDs (Var var)
 166 dsExpr (HsIPVar ip) = returnDs (Var (ipNameName ip))
 167 dsExpr (HsLit lit)  = dsLit lit
 168 -- HsOverLit has been gotten rid of by the type checker
 169
 170 dsExpr expr@(HsLam a_Match)
 171   = matchWrapper LambdaExpr [a_Match]   `thenDs` \ (binders, matching_code) ->
 172     returnDs (mkLams binders matching_code)
 173
 174 dsExpr expr@(HsApp fun arg)
 175   = dsExpr fun          `thenDs` \ core_fun ->
 176     dsExpr arg          `thenDs` \ core_arg ->
 177     returnDs (core_fun `App` core_arg)
 178 \end{code}
 179
 180 Operator sections.  At first it looks as if we can convert
 181 \begin{verbatim}
 182         (expr op)
 183 \end{verbatim}
 184 to
 185 \begin{verbatim}
 186         \x -> op expr x
 187 \end{verbatim}
 188
 189 But no!  expr might be a redex, and we can lose laziness badly this
 190 way.  Consider
 191 \begin{verbatim}
 192         map (expr op) xs
 193 \end{verbatim}
 194 for example.  So we convert instead to
 195 \begin{verbatim}
 196         let y = expr in \x -> op y x
 197 \end{verbatim}
 198 If \tr{expr} is actually just a variable, say, then the simplifier
 199 will sort it out.
 200
 201 \begin{code}
 202 dsExpr (OpApp e1 op _ e2)
 203   = dsExpr op                                           `thenDs` \ core_op ->
 204     -- for the type of y, we need the type of op's 2nd argument
 205     dsExpr e1                           `thenDs` \ x_core ->
 206     dsExpr e2                           `thenDs` \ y_core ->
 207     returnDs (mkApps core_op [x_core, y_core])
 208
 209 dsExpr (SectionL expr op)
 210   = dsExpr op                                           `thenDs` \ core_op ->
 211     -- for the type of y, we need the type of op's 2nd argument
 212     let
 213         (x_ty:y_ty:_, _) = splitFunTys (exprType core_op)
 214         -- Must look through an implicit-parameter type;
 215         -- newtype impossible; hence Type.splitFunTys
 216     in
 217     dsExpr expr                         `thenDs` \ x_core ->
 218     newSysLocalDs x_ty                  `thenDs` \ x_id ->
 219     newSysLocalDs y_ty                  `thenDs` \ y_id ->
 220
 221     returnDs (bindNonRec x_id x_core $
 222               Lam y_id (mkApps core_op [Var x_id, Var y_id]))
 223
 224 -- dsExpr (SectionR op expr)    -- \ x -> op x expr
 225 dsExpr (SectionR op expr)
 226   = dsExpr op                   `thenDs` \ core_op ->
 227     -- for the type of x, we need the type of op's 2nd argument
 228     let
 229         (x_ty:y_ty:_, _) = splitFunTys (exprType core_op)
 230         -- See comment with SectionL
 231     in
 232     dsExpr expr                         `thenDs` \ y_core ->
 233     newSysLocalDs x_ty                  `thenDs` \ x_id ->
 234     newSysLocalDs y_ty                  `thenDs` \ y_id ->
 235
 236     returnDs (bindNonRec y_id y_core $
 237               Lam x_id (mkApps core_op [Var x_id, Var y_id]))
 238
 239 dsExpr (HsSCC cc expr)
 240   = dsExpr expr                 `thenDs` \ core_expr ->
 241     getModuleDs                 `thenDs` \ mod_name ->
 242     returnDs (Note (SCC (mkUserCC cc mod_name)) core_expr)
 243
 244
 245 -- hdaume: core annotation
 246
 247 dsExpr (HsCoreAnn fs expr)
 248   = dsExpr expr        `thenDs` \ core_expr ->
 249     returnDs (Note (CoreNote $ unpackFS fs) core_expr)
 250
 251 -- special case to handle unboxed tuple patterns.
 252
 253 dsExpr (HsCase discrim matches src_loc)
 254  | all ubx_tuple_match matches
 255  =  putSrcLocDs src_loc $
 256     dsExpr discrim                      `thenDs` \ core_discrim ->
 257     matchWrapper CaseAlt matches        `thenDs` \ ([discrim_var], matching_code) ->
 258     case matching_code of
 259         Case (Var x) bndr alts | x == discrim_var ->
 260                 returnDs (Case core_discrim bndr alts)
 261         _ -> panic ("dsExpr: tuple pattern:\n" ++ showSDoc (ppr matching_code))
 262   where
 263     ubx_tuple_match (Match [TuplePat ps Unboxed] _ _) = True
 264     ubx_tuple_match _ = False
 265
 266 dsExpr (HsCase discrim matches src_loc)
 267   = putSrcLocDs src_loc $
 268     dsExpr discrim                      `thenDs` \ core_discrim ->
 269     matchWrapper CaseAlt matches        `thenDs` \ ([discrim_var], matching_code) ->
 270     returnDs (bindNonRec discrim_var core_discrim matching_code)
 271
 272 dsExpr (HsLet binds body)
 273   = dsExpr body         `thenDs` \ body' ->
 274     dsLet binds body'
 275
 276 -- We need the `ListComp' form to use `deListComp' (rather than the "do" form)
 277 -- because the interpretation of `stmts' depends on what sort of thing it is.
 278 --
 279 dsExpr (HsDo ListComp stmts _ result_ty src_loc)
 280   =     -- Special case for list comprehensions
 281     putSrcLocDs src_loc $
 282     dsListComp stmts elt_ty
 283   where
 284     (_, [elt_ty]) = tcSplitTyConApp result_ty
 285
 286 dsExpr (HsDo do_or_lc stmts ids result_ty src_loc)
 287   | isDoExpr do_or_lc
 288   = putSrcLocDs src_loc $
 289     dsDo do_or_lc stmts ids result_ty
 290
 291 dsExpr (HsDo PArrComp stmts _ result_ty src_loc)
 292   =     -- Special case for array comprehensions
 293     putSrcLocDs src_loc $
 294     dsPArrComp stmts elt_ty
 295   where
 296     (_, [elt_ty]) = tcSplitTyConApp result_ty
 297
 298 dsExpr (HsIf guard_expr then_expr else_expr src_loc)
 299   = putSrcLocDs src_loc $
 300     dsExpr guard_expr   `thenDs` \ core_guard ->
 301     dsExpr then_expr    `thenDs` \ core_then ->
 302     dsExpr else_expr    `thenDs` \ core_else ->
 303     returnDs (mkIfThenElse core_guard core_then core_else)
 304 \end{code}
 305
 306
 307 \noindent
 308 \underline{\bf Type lambda and application}
 309 %              ~~~~~~~~~~~~~~~~~~~~~~~~~~~
 310 \begin{code}
 311 dsExpr (TyLam tyvars expr)
 312   = dsExpr expr `thenDs` \ core_expr ->
 313     returnDs (mkLams tyvars core_expr)
 314
 315 dsExpr (TyApp expr tys)
 316   = dsExpr expr         `thenDs` \ core_expr ->
 317     returnDs (mkTyApps core_expr tys)
 318 \end{code}
 319
 320
 321 \noindent
 322 \underline{\bf Various data construction things}
 323 %              ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 324 \begin{code}
 325 dsExpr (ExplicitList ty xs)
 326   = go xs
 327   where
 328     go []     = returnDs (mkNilExpr ty)
 329     go (x:xs) = dsExpr x                                `thenDs` \ core_x ->
 330                 go xs                                   `thenDs` \ core_xs ->
 331                 returnDs (mkConsExpr ty core_x core_xs)
 332
 333 -- we create a list from the array elements and convert them into a list using
 334 -- `PrelPArr.toP'
 335 --
 336 -- * the main disadvantage to this scheme is that `toP' traverses the list
 337 --   twice: once to determine the length and a second time to put to elements
 338 --   into the array; this inefficiency could be avoided by exposing some of
 339 --   the innards of `PrelPArr' to the compiler (ie, have a `PrelPArrBase') so
 340 --   that we can exploit the fact that we already know the length of the array
 341 --   here at compile time
 342 --
 343 dsExpr (ExplicitPArr ty xs)
 344   = dsLookupGlobalId toPName                            `thenDs` \toP      ->
 345     dsExpr (ExplicitList ty xs)                         `thenDs` \coreList ->
 346     returnDs (mkApps (Var toP) [Type ty, coreList])
 347
 348 dsExpr (ExplicitTuple expr_list boxity)
 349   = mapDs dsExpr expr_list        `thenDs` \ core_exprs  ->
 350     returnDs (mkConApp (tupleCon boxity (length expr_list))
 351                        (map (Type .  exprType) core_exprs ++ core_exprs))
 352
 353 dsExpr (ArithSeqOut expr (From from))
 354   = dsExpr expr           `thenDs` \ expr2 ->
 355     dsExpr from           `thenDs` \ from2 ->
 356     returnDs (App expr2 from2)
 357
 358 dsExpr (ArithSeqOut expr (FromTo from two))
 359   = dsExpr expr           `thenDs` \ expr2 ->
 360     dsExpr from           `thenDs` \ from2 ->
 361     dsExpr two            `thenDs` \ two2 ->
 362     returnDs (mkApps expr2 [from2, two2])
 363
 364 dsExpr (ArithSeqOut expr (FromThen from thn))
 365   = dsExpr expr           `thenDs` \ expr2 ->
 366     dsExpr from           `thenDs` \ from2 ->
 367     dsExpr thn            `thenDs` \ thn2 ->
 368     returnDs (mkApps expr2 [from2, thn2])
 369
 370 dsExpr (ArithSeqOut expr (FromThenTo from thn two))
 371   = dsExpr expr           `thenDs` \ expr2 ->
 372     dsExpr from           `thenDs` \ from2 ->
 373     dsExpr thn            `thenDs` \ thn2 ->
 374     dsExpr two            `thenDs` \ two2 ->
 375     returnDs (mkApps expr2 [from2, thn2, two2])
 376
 377 dsExpr (PArrSeqOut expr (FromTo from two))
 378   = dsExpr expr           `thenDs` \ expr2 ->
 379     dsExpr from           `thenDs` \ from2 ->
 380     dsExpr two            `thenDs` \ two2 ->
 381     returnDs (mkApps expr2 [from2, two2])
 382
 383 dsExpr (PArrSeqOut expr (FromThenTo from thn two))
 384   = dsExpr expr           `thenDs` \ expr2 ->
 385     dsExpr from           `thenDs` \ from2 ->
 386     dsExpr thn            `thenDs` \ thn2 ->
 387     dsExpr two            `thenDs` \ two2 ->
 388     returnDs (mkApps expr2 [from2, thn2, two2])
 389
 390 dsExpr (PArrSeqOut expr _)
 391   = panic "DsExpr.dsExpr: Infinite parallel array!"
 392     -- the parser shouldn't have generated it and the renamer and typechecker
 393     -- shouldn't have let it through
 394 \end{code}
 395
 396 \noindent
 397 \underline{\bf Record construction and update}
 398 %              ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 399 For record construction we do this (assuming T has three arguments)
 400 \begin{verbatim}
 401         T { op2 = e }
 402 ==>
 403         let err = /\a -> recConErr a
 404         T (recConErr t1 "M.lhs/230/op1")
 405           e
 406           (recConErr t1 "M.lhs/230/op3")
 407 \end{verbatim}
 408 @recConErr@ then converts its arugment string into a proper message
 409 before printing it as
 410 \begin{verbatim}
 411         M.lhs, line 230: missing field op1 was evaluated
 412 \end{verbatim}
 413
 414 We also handle @C{}@ as valid construction syntax for an unlabelled
 415 constructor @C@, setting all of @C@'s fields to bottom.
 416
 417 \begin{code}
 418 dsExpr (RecordConOut data_con con_expr rbinds)
 419   = dsExpr con_expr     `thenDs` \ con_expr' ->
 420     let
 421         (arg_tys, _) = tcSplitFunTys (exprType con_expr')
 422         -- A newtype in the corner should be opaque;
 423         -- hence TcType.tcSplitFunTys
 424
 425         mk_arg (arg_ty, lbl)
 426           = case [rhs | (sel_id,rhs) <- rbinds,
 427                         lbl == recordSelectorFieldLabel sel_id] of
 428               (rhs:rhss) -> ASSERT( null rhss )
 429                             dsExpr rhs
 430               []         -> mkErrorAppDs rEC_CON_ERROR_ID arg_ty (showSDoc (ppr lbl))
 431         unlabelled_bottom arg_ty = mkErrorAppDs rEC_CON_ERROR_ID arg_ty ""
 432
 433         labels = dataConFieldLabels data_con
 434     in
 435
 436     (if null labels
 437         then mapDs unlabelled_bottom arg_tys
 438         else mapDs mk_arg (zipEqual "dsExpr:RecordCon" arg_tys labels))
 439         `thenDs` \ con_args ->
 440
 441     returnDs (mkApps con_expr' con_args)
 442 \end{code}
 443
 444 Record update is a little harder. Suppose we have the decl:
 445 \begin{verbatim}
 446         data T = T1 {op1, op2, op3 :: Int}
 447                | T2 {op4, op2 :: Int}
 448                | T3
 449 \end{verbatim}
 450 Then we translate as follows:
 451 \begin{verbatim}
 452         r { op2 = e }
 453 ===>
 454         let op2 = e in
 455         case r of
 456           T1 op1 _ op3 -> T1 op1 op2 op3
 457           T2 op4 _     -> T2 op4 op2
 458           other        -> recUpdError "M.lhs/230"
 459 \end{verbatim}
 460 It's important that we use the constructor Ids for @T1@, @T2@ etc on the
 461 RHSs, and do not generate a Core constructor application directly, because the constructor
 462 might do some argument-evaluation first; and may have to throw away some
 463 dictionaries.
 464
 465 \begin{code}
 466 dsExpr (RecordUpdOut record_expr record_in_ty record_out_ty [])
 467   = dsExpr record_expr
 468
 469 dsExpr expr@(RecordUpdOut record_expr record_in_ty record_out_ty rbinds)
 470   = getSrcLocDs                 `thenDs` \ src_loc ->
 471     dsExpr record_expr          `thenDs` \ record_expr' ->
 472
 473         -- Desugar the rbinds, and generate let-bindings if
 474         -- necessary so that we don't lose sharing
 475
 476     let
 477         in_inst_tys  = tcTyConAppArgs record_in_ty      -- Newtype opaque
 478         out_inst_tys = tcTyConAppArgs record_out_ty     -- Newtype opaque
 479
 480         mk_val_arg field old_arg_id
 481           = case [rhs | (sel_id, rhs) <- rbinds,
 482                         field == recordSelectorFieldLabel sel_id] of
 483               (rhs:rest) -> ASSERT(null rest) rhs
 484               []         -> HsVar old_arg_id
 485
 486         mk_alt con
 487           = newSysLocalsDs (dataConInstOrigArgTys con in_inst_tys) `thenDs` \ arg_ids ->
 488                 -- This call to dataConArgTys won't work for existentials
 489             let
 490                 val_args = zipWithEqual "dsExpr:RecordUpd" mk_val_arg
 491                                         (dataConFieldLabels con) arg_ids
 492                 rhs = foldl HsApp (TyApp (HsVar (dataConWrapId con)) out_inst_tys)
 493                                   val_args
 494             in
 495             returnDs (mkSimpleMatch [ConPatOut con (PrefixCon (map VarPat arg_ids)) record_in_ty [] []]
 496                                     rhs
 497                                     record_out_ty
 498                                     src_loc)
 499     in
 500         -- Record stuff doesn't work for existentials
 501         -- The type checker checks for this, but we need
 502         -- worry only about the constructors that are to be updated
 503     ASSERT2( all (not . isExistentialDataCon) cons_to_upd, ppr expr )
 504
 505         -- It's important to generate the match with matchWrapper,
 506         -- and the right hand sides with applications of the wrapper Id
 507         -- so that everything works when we are doing fancy unboxing on the
 508         -- constructor aguments.
 509     mapDs mk_alt cons_to_upd            `thenDs` \ alts ->
 510     matchWrapper RecUpd alts            `thenDs` \ ([discrim_var], matching_code) ->
 511
 512     returnDs (bindNonRec discrim_var record_expr' matching_code)
 513
 514   where
 515     updated_fields :: [FieldLabel]
 516     updated_fields = [recordSelectorFieldLabel sel_id | (sel_id,_) <- rbinds]
 517
 518         -- Get the type constructor from the first field label,
 519         -- so that we are sure it'll have all its DataCons
 520         -- (In GHCI, it's possible that some TyCons may not have all
 521         --  their constructors, in a module-loop situation.)
 522     tycon       = fieldLabelTyCon (head updated_fields)
 523     data_cons   = tyConDataCons tycon
 524     cons_to_upd = filter has_all_fields data_cons
 525
 526     has_all_fields :: DataCon -> Bool
 527     has_all_fields con_id
 528       = all (`elem` con_fields) updated_fields
 529       where
 530         con_fields = dataConFieldLabels con_id
 531 \end{code}
 532
 533
 534 \noindent
 535 \underline{\bf Dictionary lambda and application}
 536 %              ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 537 @DictLam@ and @DictApp@ turn into the regular old things.
 538 (OLD:) @DictFunApp@ also becomes a curried application, albeit slightly more
 539 complicated; reminiscent of fully-applied constructors.
 540 \begin{code}
 541 dsExpr (DictLam dictvars expr)
 542   = dsExpr expr `thenDs` \ core_expr ->
 543     returnDs (mkLams dictvars core_expr)
 544
 545 ------------------
 546
 547 dsExpr (DictApp expr dicts)     -- becomes a curried application
 548   = dsExpr expr                 `thenDs` \ core_expr ->
 549     returnDs (foldl (\f d -> f `App` (Var d)) core_expr dicts)
 550 \end{code}
 551
 552 Here is where we desugar the Template Haskell brackets and escapes
 553
 554 \begin{code}
 555 -- Template Haskell stuff
 556
 557 #ifdef GHCI     /* Only if bootstrapping */
 558 dsExpr (HsBracketOut x ps) = dsBracket x ps
 559 dsExpr (HsReify r)         = dsReify r
 560 dsExpr (HsSplice n e _)    = pprPanic "dsExpr:splice" (ppr e)
 561 #endif
 562
 563 -- Arrow notation extension
 564 dsExpr (HsProc pat cmd src_loc) = dsProcExpr pat cmd src_loc
 565 \end{code}
 566
 567
 568 \begin{code}
 569
 570 #ifdef DEBUG
 571 -- HsSyn constructs that just shouldn't be here:
 572 dsExpr (ExprWithTySig _ _)  = panic "dsExpr:ExprWithTySig"
 573 dsExpr (ArithSeqIn _)       = panic "dsExpr:ArithSeqIn"
 574 dsExpr (PArrSeqIn _)        = panic "dsExpr:PArrSeqIn"
 575 #endif
 576
 577 \end{code}
 578
 579 %--------------------------------------------------------------------
 580
 581 Basically does the translation given in the Haskell~1.3 report:
 582
 583 \begin{code}
 584 dsDo    :: HsStmtContext Name
 585         -> [TypecheckedStmt]
 586         -> ReboundNames Id      -- id for: [return,fail,>>=,>>] and possibly mfixName
 587         -> Type                 -- Element type; the whole expression has type (m t)
 588         -> DsM CoreExpr
 589
 590 dsDo do_or_lc stmts ids result_ty
 591   = dsReboundNames ids          `thenDs` \ (meth_binds, ds_meths) ->
 592     let
 593         return_id = lookupReboundName ds_meths returnMName
 594         fail_id   = lookupReboundName ds_meths failMName
 595         bind_id   = lookupReboundName ds_meths bindMName
 596         then_id   = lookupReboundName ds_meths thenMName
 597
 598         (m_ty, b_ty) = tcSplitAppTy result_ty   -- result_ty must be of the form (m b)
 599         is_do        = isDoExpr do_or_lc        -- True for both MDo and Do
 600
 601         -- For ExprStmt, see the comments near HsExpr.Stmt about
 602         -- exactly what ExprStmts mean!
 603         --
 604         -- In dsDo we can only see DoStmt and ListComp (no guards)
 605
 606         go [ResultStmt expr locn]
 607           | is_do     = do_expr expr locn
 608           | otherwise = do_expr expr locn       `thenDs` \ expr2 ->
 609                         returnDs (mkApps return_id [Type b_ty, expr2])
 610
 611         go (ExprStmt expr a_ty locn : stmts)
 612           | is_do       -- Do expression
 613           = do_expr expr locn           `thenDs` \ expr2 ->
 614             go stmts                    `thenDs` \ rest  ->
 615             returnDs (mkApps then_id [Type a_ty, Type b_ty, expr2, rest])
 616
 617            | otherwise  -- List comprehension
 618           = do_expr expr locn                   `thenDs` \ expr2 ->
 619             go stmts                            `thenDs` \ rest ->
 620             let
 621                 msg = "Pattern match failure in do expression, " ++ showSDoc (ppr locn)
 622             in
 623             mkStringLit msg                     `thenDs` \ core_msg ->
 624             returnDs (mkIfThenElse expr2 rest
 625                                    (App (App fail_id (Type b_ty)) core_msg))
 626
 627         go (LetStmt binds : stmts)
 628           = go stmts            `thenDs` \ rest   ->
 629             dsLet binds rest
 630
 631         go (BindStmt pat expr locn : stmts)
 632           = go stmts                    `thenDs` \ body ->
 633             putSrcLocDs locn            $       -- Rest is associated with this location
 634             dsExpr expr                 `thenDs` \ rhs ->
 635             mkStringLit (mk_msg locn)   `thenDs` \ core_msg ->
 636             let
 637                 -- In a do expression, pattern-match failure just calls
 638                 -- the monadic 'fail' rather than throwing an exception
 639                 fail_expr  = mkApps fail_id [Type b_ty, core_msg]
 640                 a_ty       = hsPatType pat
 641             in
 642             selectMatchVar pat                                  `thenDs` \ var ->
 643             matchSimply (Var var) (StmtCtxt do_or_lc) pat
 644                         body fail_expr                          `thenDs` \ match_code ->
 645             returnDs (mkApps bind_id [Type a_ty, Type b_ty, rhs, Lam var match_code])
 646
 647         go (RecStmt rec_stmts later_vars rec_vars rec_rets : stmts)
 648           = go (bind_stmt : stmts)
 649           where
 650             bind_stmt = dsRecStmt m_ty ds_meths rec_stmts later_vars rec_vars rec_rets
 651
 652     in
 653     go stmts                            `thenDs` \ stmts_code ->
 654     returnDs (foldr Let stmts_code meth_binds)
 655
 656   where
 657     do_expr expr locn = putSrcLocDs locn (dsExpr expr)
 658     mk_msg locn = "Pattern match failure in do expression at " ++ showSDoc (ppr locn)
 659 \end{code}
 660
 661 Translation for RecStmt's:
 662 -----------------------------
 663 We turn (RecStmt [v1,..vn] stmts) into:
 664
 665   (v1,..,vn) <- mfix (\~(v1,..vn). do stmts
 666                                       return (v1,..vn))
 667
 668 \begin{code}
 669 dsRecStmt :: Type               -- Monad type constructor :: * -> *
 670           -> [(Name,Id)]        -- Rebound Ids
 671           -> [TypecheckedStmt]
 672           -> [Id] -> [Id] -> [TypecheckedHsExpr]
 673           -> TypecheckedStmt
 674 dsRecStmt m_ty ds_meths stmts later_vars rec_vars rec_rets
 675   = ASSERT( length vars == length rets )
 676     BindStmt tup_pat mfix_app noSrcLoc
 677   where
 678         vars@(var1:rest) = later_vars           ++ rec_vars             -- Always at least one
 679         rets@(ret1:_)    = map HsVar later_vars ++ rec_rets
 680         one_var          = null rest
 681
 682         mfix_app = HsApp (TyApp (HsVar mfix_id) [tup_ty]) mfix_arg
 683         mfix_arg = HsLam (mkSimpleMatch [tup_pat] body tup_ty noSrcLoc)
 684
 685         tup_expr | one_var   = ret1
 686                  | otherwise = ExplicitTuple rets Boxed
 687         tup_ty               = mkCoreTupTy (map idType vars)
 688                                         -- Deals with singleton case
 689         tup_pat  | one_var   = VarPat var1
 690                  | otherwise = LazyPat (TuplePat (map VarPat vars) Boxed)
 691
 692         body = HsDo DoExpr (stmts ++ [return_stmt])
 693                            [(n, HsVar id) | (n,id) <- ds_meths] -- A bit of a hack
 694                            (mkAppTy m_ty tup_ty)
 695                            noSrcLoc
 696
 697         Var return_id = lookupReboundName ds_meths returnMName
 698         Var mfix_id   = lookupReboundName ds_meths mfixName
 699
 700         return_stmt = ResultStmt return_app noSrcLoc
 701         return_app  = HsApp (TyApp (HsVar return_id) [tup_ty]) tup_expr
 702 \end{code}