ghc/compiler/deSugar/DsForeign.lhs

   1 %
   2 % (c) The AQUA Project, Glasgow University, 1998
   3 %
   4 \section[DsCCall]{Desugaring \tr{foreign} declarations}
   5
   6 Expanding out @foreign import@ and @foreign export@ declarations.
   7
   8 \begin{code}
   9 module DsForeign ( dsForeigns ) where
  10
  11 #include "HsVersions.h"
  12
  13 import CoreSyn
  14
  15 import DsCCall          ( dsCCall, mkFCall, boxResult, unboxArg, resultWrapper )
  16 import DsMonad
  17
  18 import HsSyn            ( ForeignDecl(..), ForeignExport(..),
  19                           ForeignImport(..), CImportSpec(..) )
  20 import TcHsSyn          ( TypecheckedForeignDecl )
  21 import CoreUtils        ( exprType, mkInlineMe )
  22 import Id               ( Id, idType, idName, mkVanillaGlobal, mkSysLocal,
  23                           setInlinePragma )
  24 import IdInfo           ( vanillaIdInfo )
  25 import Literal          ( Literal(..) )
  26 import Module           ( Module, moduleUserString )
  27 import Name             ( mkGlobalName, nameModule, nameOccName, getOccString,
  28                           mkForeignExportOcc, isLocalName,
  29                           NamedThing(..),
  30                         )
  31 import Type             ( repType, eqType )
  32 import TcType           ( Type, mkFunTys, mkForAllTys, mkTyConApp,
  33                           mkFunTy, applyTy,
  34                           tcSplitForAllTys, tcSplitFunTys, tcTyConAppArgs,
  35                           tcSplitTyConApp_maybe, tcSplitAppTy,
  36                           tcFunResultTy
  37                         )
  38
  39 import ForeignCall      ( ForeignCall(..), CCallSpec(..),
  40                           Safety(..), playSafe,
  41                           CExportSpec(..),
  42                           CCallConv(..), ccallConvToInt,
  43                           ccallConvAttribute
  44                         )
  45 import CStrings         ( CLabelString )
  46 import TysWiredIn       ( addrTy, unitTy, stablePtrTyCon )
  47 import TysPrim          ( addrPrimTy )
  48 import PrelNames        ( hasKey, ioTyConKey, deRefStablePtrName, newStablePtrName,
  49                           bindIOName, returnIOName
  50                         )
  51 import BasicTypes       ( Activation( NeverActive ) )
  52 import ErrUtils         ( addShortWarnLocLine )
  53 import Outputable
  54 import Maybe            ( fromJust )
  55 \end{code}
  56
  57 Desugaring of @foreign@ declarations is naturally split up into
  58 parts, an @import@ and an @export@  part. A @foreign import@
  59 declaration
  60 \begin{verbatim}
  61   foreign import cc nm f :: prim_args -> IO prim_res
  62 \end{verbatim}
  63 is the same as
  64 \begin{verbatim}
  65   f :: prim_args -> IO prim_res
  66   f a1 ... an = _ccall_ nm cc a1 ... an
  67 \end{verbatim}
  68 so we reuse the desugaring code in @DsCCall@ to deal with these.
  69
  70 \begin{code}
  71 type Binding = (Id, CoreExpr)   -- No rec/nonrec structure;
  72                                 -- the occurrence analyser will sort it all out
  73
  74 dsForeigns :: Module
  75            -> [TypecheckedForeignDecl]
  76            -> DsM ( [Id]                -- Foreign-exported binders;
  77                                         -- we have to generate code to register these
  78                   , [Binding]
  79                   , SDoc              -- Header file prototypes for
  80                                       -- "foreign exported" functions.
  81                   , SDoc              -- C stubs to use when calling
  82                                       -- "foreign exported" functions.
  83                   , [FAST_STRING]     -- headers that need to be included
  84                                       -- into C code generated for this module
  85                   )
  86 dsForeigns mod_name fos
  87   = foldlDs combine ([], [], empty, empty, []) fos
  88  where
  89   combine (acc_feb, acc_f, acc_h, acc_c, acc_header)
  90           (ForeignImport id _ spec depr loc)
  91     = dsFImport mod_name id spec                   `thenDs` \(bs, h, c, hd) ->
  92       warnDepr depr loc                            `thenDs` \_              ->
  93       returnDs (acc_feb, bs ++ acc_f, h $$ acc_h, c $$ acc_c, hd ++ acc_header)
  94
  95   combine (acc_feb, acc_f, acc_h, acc_c, acc_header)
  96           (ForeignExport id _ (CExport (CExportStatic ext_nm cconv)) depr loc)
  97     = dsFExport mod_name id (idType id)
  98                 ext_nm cconv False                 `thenDs` \(feb, b, h, c) ->
  99       warnDepr depr loc                            `thenDs` \_              ->
 100       returnDs (feb:acc_feb, b:acc_f, h $$ acc_h, c $$ acc_c, acc_header)
 101
 102   warnDepr False _   = returnDs ()
 103   warnDepr True  loc = dsWarn (addShortWarnLocLine loc msg)
 104    where
 105     msg = ptext SLIT("foreign declaration uses deprecated non-standard syntax")
 106 \end{code}
 107
 108
 109 %************************************************************************
 110 %*                                                                      *
 111 \subsection{Foreign import}
 112 %*                                                                      *
 113 %************************************************************************
 114
 115 Desugaring foreign imports is just the matter of creating a binding
 116 that on its RHS unboxes its arguments, performs the external call
 117 (using the @CCallOp@ primop), before boxing the result up and returning it.
 118
 119 However, we create a worker/wrapper pair, thus:
 120
 121         foreign import f :: Int -> IO Int
 122 ==>
 123         f x = IO ( \s -> case x of { I# x# ->
 124                          case fw s x# of { (# s1, y# #) ->
 125                          (# s1, I# y# #)}})
 126
 127         fw s x# = ccall f s x#
 128
 129 The strictness/CPR analyser won't do this automatically because it doesn't look
 130 inside returned tuples; but inlining this wrapper is a Really Good Idea
 131 because it exposes the boxing to the call site.
 132
 133 \begin{code}
 134 dsFImport :: Module
 135           -> Id
 136           -> ForeignImport
 137           -> DsM ([Binding], SDoc, SDoc, [FAST_STRING])
 138 dsFImport modName id (CImport cconv safety header lib spec)
 139   = dsCImport modName id spec cconv safety        `thenDs` \(ids, h, c) ->
 140     returnDs (ids, h, c, if _NULL_ header then [] else [header])
 141   -- FIXME: the `lib' field is needed for .NET ILX generation when invoking
 142   --        routines that are external to the .NET runtime, but GHC doesn't
 143   --        support such calls yet; if `_NULL_ lib', the value was not given
 144 dsFImport modName id (DNImport spec)
 145   = dsFCall modName id (DNCall spec)              `thenDs` \(ids, h, c) ->
 146     returnDs (ids, h, c, [])
 147
 148 dsCImport :: Module
 149           -> Id
 150           -> CImportSpec
 151           -> CCallConv
 152           -> Safety
 153           -> DsM ([Binding], SDoc, SDoc)
 154 dsCImport modName id (CLabel cid)       _     _
 155  = ASSERT(fromJust resTy `eqType` addrPrimTy)    -- typechecker ensures this
 156    returnDs ([(id, rhs)], empty, empty)
 157  where
 158    (resTy, foRhs) = resultWrapper (idType id)
 159    rhs            = foRhs (mkLit (MachLabel cid))
 160 dsCImport modName id (CFunction target) cconv safety
 161   = dsFCall modName id (CCall (CCallSpec target cconv safety))
 162 dsCImport modName id CWrapper           cconv _
 163   = dsFExportDynamic modName id cconv
 164 \end{code}
 165
 166
 167 %************************************************************************
 168 %*                                                                      *
 169 \subsection{Foreign calls}
 170 %*                                                                      *
 171 %************************************************************************
 172
 173 \begin{code}
 174 dsFCall mod_Name fn_id fcall
 175   = let
 176         ty                   = idType fn_id
 177         (tvs, fun_ty)        = tcSplitForAllTys ty
 178         (arg_tys, io_res_ty) = tcSplitFunTys fun_ty
 179                 -- Must use tcSplit* functions because we want to
 180                 -- see that (IO t) in the corner
 181     in
 182     newSysLocalsDs arg_tys                      `thenDs` \ args ->
 183     mapAndUnzipDs unboxArg (map Var args)       `thenDs` \ (val_args, arg_wrappers) ->
 184
 185     let
 186         work_arg_ids  = [v | Var v <- val_args] -- All guaranteed to be vars
 187
 188         -- These are the ids we pass to boxResult, which are used to decide
 189         -- whether to touch# an argument after the call (used to keep
 190         -- ForeignObj#s live across a 'safe' foreign import).
 191         maybe_arg_ids | unsafe_call fcall = work_arg_ids
 192                       | otherwise         = []
 193     in
 194     boxResult maybe_arg_ids io_res_ty           `thenDs` \ (ccall_result_ty, res_wrapper) ->
 195
 196     getUniqueDs                                 `thenDs` \ ccall_uniq ->
 197     getUniqueDs                                 `thenDs` \ work_uniq ->
 198     let
 199         -- Build the worker
 200         worker_ty     = mkForAllTys tvs (mkFunTys (map idType work_arg_ids) ccall_result_ty)
 201         the_ccall_app = mkFCall ccall_uniq fcall val_args ccall_result_ty
 202         work_rhs      = mkLams tvs (mkLams work_arg_ids the_ccall_app)
 203         work_id       = mkSysLocal SLIT("$wccall") work_uniq worker_ty
 204
 205         -- Build the wrapper
 206         work_app     = mkApps (mkVarApps (Var work_id) tvs) val_args
 207         wrapper_body = foldr ($) (res_wrapper work_app) arg_wrappers
 208         wrap_rhs     = mkInlineMe (mkLams (tvs ++ args) wrapper_body)
 209     in
 210     returnDs ([(work_id, work_rhs), (fn_id, wrap_rhs)], empty, empty)
 211
 212 unsafe_call (CCall (CCallSpec _ _ safety)) = playSafe safety
 213 unsafe_call (DNCall _)                     = False
 214 \end{code}
 215
 216
 217 %************************************************************************
 218 %*                                                                      *
 219 \subsection{Foreign export}
 220 %*                                                                      *
 221 %************************************************************************
 222
 223 The function that does most of the work for `@foreign export@' declarations.
 224 (see below for the boilerplate code a `@foreign export@' declaration expands
 225  into.)
 226
 227 For each `@foreign export foo@' in a module M we generate:
 228 \begin{itemize}
 229 \item a C function `@foo@', which calls
 230 \item a Haskell stub `@M.$ffoo@', which calls
 231 \end{itemize}
 232 the user-written Haskell function `@M.foo@'.
 233
 234 \begin{code}
 235 dsFExport :: Module
 236           -> Id                 -- Either the exported Id,
 237                                 -- or the foreign-export-dynamic constructor
 238           -> Type               -- The type of the thing callable from C
 239           -> CLabelString       -- The name to export to C land
 240           -> CCallConv
 241           -> Bool               -- True => foreign export dynamic
 242                                 --         so invoke IO action that's hanging off
 243                                 --         the first argument's stable pointer
 244           -> DsM ( Id           -- The foreign-exported Id
 245                  , Binding
 246                  , SDoc
 247                  , SDoc
 248                  )
 249 dsFExport mod_name fn_id ty ext_name cconv isDyn
 250   =     -- BUILD THE returnIO WRAPPER, if necessary
 251         -- Look at the result type of the exported function, orig_res_ty
 252         -- If it's IO t, return         (\x.x,          IO t, t)
 253         -- If it's plain t, return      (\x.returnIO x, IO t, t)
 254      (case tcSplitTyConApp_maybe orig_res_ty of
 255         -- We must use tcSplit here so that we see the (IO t) in
 256         -- the type.  [IO t is transparent to plain splitTyConApp.]
 257
 258         Just (ioTyCon, [res_ty])
 259               -> ASSERT( ioTyCon `hasKey` ioTyConKey )
 260                         -- The function already returns IO t
 261                  returnDs (\body -> body, orig_res_ty, res_ty)
 262
 263         other ->        -- The function returns t, so wrap the call in returnIO
 264                  dsLookupGlobalValue returnIOName       `thenDs` \ retIOId ->
 265                  returnDs (\body -> mkApps (Var retIOId) [Type orig_res_ty, body],
 266                            tcFunResultTy (applyTy (idType retIOId) orig_res_ty),
 267                                 -- We don't have ioTyCon conveniently to hand
 268                            orig_res_ty)
 269
 270      )          `thenDs` \ (return_io_wrapper,  -- Either identity or returnIO
 271                             io_res_ty,          -- IO t
 272                             res_ty) ->          -- t
 273
 274
 275         -- BUILD THE deRefStablePtr WRAPPER, if necessary
 276      (if isDyn then
 277         newSysLocalDs stbl_ptr_ty                       `thenDs` \ stbl_ptr ->
 278         newSysLocalDs stbl_ptr_to_ty                    `thenDs` \ stbl_value ->
 279         dsLookupGlobalValue deRefStablePtrName          `thenDs` \ deRefStablePtrId ->
 280         dsLookupGlobalValue bindIOName                  `thenDs` \ bindIOId ->
 281         let
 282          the_deref_app = mkApps (Var deRefStablePtrId)
 283                                 [ Type stbl_ptr_to_ty, Var stbl_ptr ]
 284
 285          stbl_app cont = mkApps (Var bindIOId)
 286                                 [ Type stbl_ptr_to_ty
 287                                 , Type res_ty
 288                                 , the_deref_app
 289                                 , mkLams [stbl_value] cont]
 290         in
 291         returnDs (stbl_value, stbl_app, stbl_ptr)
 292       else
 293         returnDs (fn_id,
 294                   \ body -> body,
 295                   panic "stbl_ptr"  -- should never be touched.
 296                   ))                    `thenDs` \ (i, getFun_wrapper, stbl_ptr) ->
 297
 298
 299         -- BUILD THE HELPER
 300      getModuleDs                        `thenDs` \ mod ->
 301      getUniqueDs                        `thenDs` \ uniq ->
 302      getSrcLocDs                        `thenDs` \ src_loc ->
 303      newSysLocalsDs fe_arg_tys          `thenDs` \ fe_args ->
 304      let
 305         wrapper_args | isDyn      = stbl_ptr:fe_args
 306                      | otherwise  = fe_args
 307
 308         wrapper_arg_tys | isDyn      = stbl_ptr_ty:fe_arg_tys
 309                         | otherwise  = fe_arg_tys
 310
 311         helper_ty =  mkForAllTys tvs $
 312                      mkFunTys wrapper_arg_tys io_res_ty
 313
 314         f_helper_glob = mkVanillaGlobal helper_name helper_ty vanillaIdInfo
 315                       where
 316                         name                = idName fn_id
 317                         mod
 318                          | isLocalName name = mod_name
 319                          | otherwise        = nameModule name
 320
 321                         occ                 = mkForeignExportOcc (nameOccName name)
 322                         helper_name         = mkGlobalName uniq mod occ src_loc
 323
 324         the_app = getFun_wrapper (return_io_wrapper (mkVarApps (Var i) (tvs ++ fe_args)))
 325         the_body = mkLams (tvs ++ wrapper_args) the_app
 326
 327         (h_stub, c_stub) = fexportEntry (moduleUserString mod)
 328                                         ext_name
 329                                         (if isDyn then Nothing else Just f_helper_glob)
 330                                         fe_arg_tys res_ty cconv
 331      in
 332      returnDs (f_helper_glob, (f_helper_glob, the_body), h_stub, c_stub)
 333
 334   where
 335    (tvs,sans_foralls)           = tcSplitForAllTys ty
 336    (fe_arg_tys', orig_res_ty)   = tcSplitFunTys sans_foralls
 337         -- We must use tcSplits here, because we want to see
 338         -- the (IO t) in the corner of the type!
 339
 340    fe_arg_tys | isDyn     = tail fe_arg_tys'
 341               | otherwise = fe_arg_tys'
 342
 343    stbl_ptr_ty | isDyn     = head fe_arg_tys'
 344                | otherwise = error "stbl_ptr_ty"
 345
 346    (_, stbl_ptr_ty')            = tcSplitForAllTys stbl_ptr_ty
 347    (_, stbl_ptr_to_ty)          = tcSplitAppTy stbl_ptr_ty'
 348         -- Again, stable pointers are just newtypes,
 349         -- so we must see them!  Hence tcSplit*
 350 \end{code}
 351
 352 @foreign export dynamic@ lets you dress up Haskell IO actions
 353 of some fixed type behind an externally callable interface (i.e.,
 354 as a C function pointer). Useful for callbacks and stuff.
 355
 356 \begin{verbatim}
 357 foreign export dynamic f :: (Addr -> Int -> IO Int) -> IO Addr
 358
 359 -- Haskell-visible constructor, which is generated from the above:
 360 -- SUP: No check for NULL from createAdjustor anymore???
 361
 362 f :: (Addr -> Int -> IO Int) -> IO Addr
 363 f cback =
 364    bindIO (newStablePtr cback)
 365           (\StablePtr sp# -> IO (\s1# ->
 366               case _ccall_ createAdjustor cconv sp# ``f_helper'' s1# of
 367                  (# s2#, a# #) -> (# s2#, A# a# #)))
 368
 369 foreign export "f_helper" f_helper :: StablePtr (Addr -> Int -> IO Int) -> Addr -> Int -> IO Int
 370 -- `special' foreign export that invokes the closure pointed to by the
 371 -- first argument.
 372 \end{verbatim}
 373
 374 \begin{code}
 375 dsFExportDynamic :: Module
 376                  -> Id
 377                  -> CCallConv
 378                  -> DsM ([Binding], SDoc, SDoc)
 379 dsFExportDynamic mod_name id cconv
 380   =  newSysLocalDs ty                                    `thenDs` \ fe_id ->
 381      let
 382         -- hack: need to get at the name of the C stub we're about to generate.
 383        fe_nm       = _PK_ (moduleUserString mod_name ++ "_" ++ toCName fe_id)
 384      in
 385      dsFExport mod_name id export_ty fe_nm cconv True   `thenDs` \ ({-feb-}_, {-fe-}_, h_code, c_code) ->
 386      newSysLocalDs arg_ty                               `thenDs` \ cback ->
 387      dsLookupGlobalValue newStablePtrName               `thenDs` \ newStablePtrId ->
 388      let
 389         mk_stbl_ptr_app    = mkApps (Var newStablePtrId) [ Type arg_ty, Var cback ]
 390      in
 391      dsLookupGlobalValue bindIOName                     `thenDs` \ bindIOId ->
 392      newSysLocalDs (mkTyConApp stablePtrTyCon [arg_ty]) `thenDs` \ stbl_value ->
 393      let
 394       stbl_app cont ret_ty
 395         = mkApps (Var bindIOId)
 396                  [ Type (mkTyConApp stablePtrTyCon [arg_ty])
 397                  , Type ret_ty
 398                  , mk_stbl_ptr_app
 399                  , cont
 400                  ]
 401
 402        {-
 403         The arguments to the external function which will
 404         create a little bit of (template) code on the fly
 405         for allowing the (stable pointed) Haskell closure
 406         to be entered using an external calling convention
 407         (stdcall, ccall).
 408        -}
 409       adj_args      = [ mkIntLitInt (ccallConvToInt cconv)
 410                       , Var stbl_value
 411                       , mkLit (MachLabel fe_nm)
 412                       ]
 413         -- name of external entry point providing these services.
 414         -- (probably in the RTS.)
 415       adjustor      = SLIT("createAdjustor")
 416      in
 417      dsCCall adjustor adj_args PlayRisky False io_res_ty        `thenDs` \ ccall_adj ->
 418         -- PlayRisky: the adjustor doesn't allocate in the Haskell heap or do a callback
 419      let ccall_adj_ty = exprType ccall_adj
 420          ccall_io_adj = mkLams [stbl_value]                  $
 421                         Note (Coerce io_res_ty ccall_adj_ty)
 422                              ccall_adj
 423          io_app = mkLams tvs     $
 424                   mkLams [cback] $
 425                   stbl_app ccall_io_adj res_ty
 426          fed = (id `setInlinePragma` NeverActive, io_app)
 427                 -- Never inline the f.e.d. function, because the litlit
 428                 -- might not be in scope in other modules.
 429      in
 430      returnDs ([fed] {-[fed, fe]-}, h_code, c_code)
 431
 432  where
 433   ty                    = idType id
 434   (tvs,sans_foralls)    = tcSplitForAllTys ty
 435   ([arg_ty], io_res_ty) = tcSplitFunTys sans_foralls
 436   [res_ty]              = tcTyConAppArgs io_res_ty
 437         -- Must use tcSplit* to see the (IO t), which is a newtype
 438   export_ty             = mkFunTy (mkTyConApp stablePtrTyCon [arg_ty]) arg_ty
 439
 440 toCName :: Id -> String
 441 toCName i = showSDoc (pprCode CStyle (ppr (idName i)))
 442 \end{code}
 443
 444 %*
 445 %
 446 \subsection{Generating @foreign export@ stubs}
 447 %
 448 %*
 449
 450 For each @foreign export@ function, a C stub function is generated.
 451 The C stub constructs the application of the exported Haskell function
 452 using the hugs/ghc rts invocation API.
 453
 454 \begin{code}
 455 fexportEntry :: String
 456              -> FAST_STRING
 457              -> Maybe Id        -- Just==static, Nothing==dynamic
 458              -> [Type]
 459              -> Type
 460              -> CCallConv
 461              -> (SDoc, SDoc)
 462 fexportEntry mod_nm c_nm maybe_target arg_htys res_hty cc = (header_bits, c_bits)
 463  where
 464   -- Create up types and names for the real args
 465   arg_cnames, arg_ctys :: [SDoc]
 466   arg_cnames = mkCArgNames 1 arg_htys
 467   arg_ctys   = map showStgType arg_htys
 468
 469   -- and also for auxiliary ones; the stable ptr in the dynamic case, and
 470   -- a slot for the dummy return address in the dynamic + ccall case
 471   extra_cnames_and_ctys
 472      = case maybe_target of
 473           Nothing -> [(text "the_stableptr", text "StgStablePtr")]
 474           other   -> []
 475        ++
 476        case (maybe_target, cc) of
 477           (Nothing, CCallConv) -> [(text "original_return_addr", text "void*")]
 478           other                -> []
 479
 480   all_cnames_and_ctys :: [(SDoc, SDoc)]
 481   all_cnames_and_ctys
 482      = extra_cnames_and_ctys ++ zip arg_cnames arg_ctys
 483
 484   -- stuff to do with the return type of the C function
 485   res_hty_is_unit = res_hty `eqType` unitTy     -- Look through any newtypes
 486
 487   cResType | res_hty_is_unit = text "void"
 488            | otherwise       = showStgType res_hty
 489
 490   -- Now we can cook up the prototype for the exported function.
 491   pprCconv = case cc of
 492                 CCallConv   -> empty
 493                 StdCallConv -> text (ccallConvAttribute cc)
 494
 495   header_bits = ptext SLIT("extern") <+> fun_proto <> semi
 496
 497   fun_proto = cResType <+> pprCconv <+> ptext c_nm <>
 498               parens (hsep (punctuate comma (map (\(nm,ty) -> ty <+> nm)
 499                                                  all_cnames_and_ctys)))
 500
 501   -- the target which will form the root of what we ask rts_evalIO to run
 502   the_cfun
 503      = case maybe_target of
 504           Nothing    -> text "(StgClosure*)deRefStablePtr(the_stableptr)"
 505           Just hs_fn -> ppr hs_fn <> text "_closure"
 506
 507   -- the expression we give to rts_evalIO
 508   expr_to_run
 509      = foldl appArg the_cfun (zip arg_cnames arg_htys)
 510        where
 511           appArg acc (arg_cname, arg_hty)
 512              = text "rts_apply"
 513                <> parens (acc <> comma <> mkHObj arg_hty <> parens arg_cname)
 514
 515   -- various other bits for inside the fn
 516   declareResult = text "HaskellObj ret;"
 517
 518   return_what | res_hty_is_unit = empty
 519               | otherwise       = parens (unpackHObj res_hty <> parens (text "ret"))
 520
 521   -- an extern decl for the fn being called
 522   extern_decl
 523      = case maybe_target of
 524           Nothing -> empty
 525           Just hs_fn -> text "extern StgClosure* " <> ppr hs_fn <> text "_closure" <> semi
 526
 527   -- finally, the whole darn thing
 528   c_bits =
 529     extern_decl $$
 530     fun_proto  $$
 531     vcat
 532      [ lbrace
 533      ,   text "SchedulerStatus rc;"
 534      ,   declareResult
 535           -- create the application + perform it.
 536      ,   text "rc=rts_evalIO"
 537          <> parens (expr_to_run <+> comma <> text "&ret")
 538          <> semi
 539      ,   text "rts_checkSchedStatus" <> parens (doubleQuotes (ptext c_nm)
 540                                                 <> comma <> text "rc") <> semi
 541      ,   text "return" <> return_what <> semi
 542      , rbrace
 543      ]
 544
 545
 546 mkCArgNames :: Int -> [a] -> [SDoc]
 547 mkCArgNames n as = zipWith (\ _ n -> text ('a':show n)) as [n..]
 548
 549 mkHObj :: Type -> SDoc
 550 mkHObj t = text "rts_mk" <> text (showFFIType t)
 551
 552 unpackHObj :: Type -> SDoc
 553 unpackHObj t = text "rts_get" <> text (showFFIType t)
 554
 555 showStgType :: Type -> SDoc
 556 showStgType t = text "Hs" <> text (showFFIType t)
 557
 558 showFFIType :: Type -> String
 559 showFFIType t = getOccString (getName tc)
 560  where
 561   tc = case tcSplitTyConApp_maybe (repType t) of
 562             Just (tc,_) -> tc
 563             Nothing     -> pprPanic "showFFIType" (ppr t)
 564 \end{code}