ghc/compiler/deSugar/DsForeign.lhs

   1 %
   2 % (c) The AQUA Project, Glasgow University, 1998
   3 %
   4 \section[DsCCall]{Desugaring \tr{foreign} declarations}
   5
   6 Expanding out @foreign import@ and @foreign export@ declarations.
   7
   8 \begin{code}
   9 module DsForeign ( dsForeigns ) where
  10
  11 #include "HsVersions.h"
  12
  13 import CoreSyn
  14
  15 import DsCCall          ( dsCCall, mkCCall, boxResult, unboxArg )
  16 import DsMonad
  17 import DsUtils
  18
  19 import HsSyn            ( ExtName(..), ForeignDecl(..), isDynamicExtName, ForKind(..) )
  20 import HsDecls          ( extNameStatic )
  21 import CallConv
  22 import TcHsSyn          ( TypecheckedForeignDecl )
  23 import CoreUtils        ( exprType, mkInlineMe )
  24 import DataCon          ( DataCon, dataConWrapId )
  25 import Id               ( Id, idType, idName, mkWildId, mkVanillaId, mkSysLocal )
  26 import MkId             ( mkWorkerId )
  27 import Literal          ( Literal(..) )
  28 import Module           ( Module, moduleUserString )
  29 import Name             ( mkGlobalName, nameModule, nameOccName, getOccString,
  30                           mkForeignExportOcc, isLocalName,
  31                           NamedThing(..), Provenance(..), ExportFlag(..)
  32                         )
  33 import Type             ( unUsgTy,
  34                           splitTyConApp_maybe, splitFunTys, splitForAllTys,
  35                           Type, mkFunTys, mkForAllTys, mkTyConApp,
  36                           mkTyVarTy, mkFunTy, splitAppTy, applyTy, funResultTy
  37                         )
  38 import PprType          ( {- instance Outputable Type -} )
  39 import PrimOp           ( PrimOp(..), CCall(..), CCallTarget(..) )
  40 import Var              ( TyVar )
  41 import TysPrim          ( realWorldStatePrimTy, addrPrimTy )
  42 import TysWiredIn       ( unitTy, addrTy, stablePtrTyCon,
  43                           addrDataCon
  44                         )
  45 import Unique           ( Uniquable(..), hasKey,
  46                           ioTyConKey, deRefStablePtrIdKey, returnIOIdKey,
  47                           bindIOIdKey, makeStablePtrIdKey
  48                 )
  49 import Maybes           ( maybeToBool )
  50 import Outputable
  51 \end{code}
  52
  53 Desugaring of @foreign@ declarations is naturally split up into
  54 parts, an @import@ and an @export@  part. A @foreign import@
  55 declaration
  56 \begin{verbatim}
  57   foreign import cc nm f :: prim_args -> IO prim_res
  58 \end{verbatim}
  59 is the same as
  60 \begin{verbatim}
  61   f :: prim_args -> IO prim_res
  62   f a1 ... an = _ccall_ nm cc a1 ... an
  63 \end{verbatim}
  64 so we reuse the desugaring code in @DsCCall@ to deal with these.
  65
  66 \begin{code}
  67 dsForeigns :: Module
  68            -> [TypecheckedForeignDecl]
  69            -> DsM ( [CoreBind]        -- desugared foreign imports
  70                   , [CoreBind]        -- helper functions for foreign exports
  71                   , SDoc              -- Header file prototypes for
  72                                       -- "foreign exported" functions.
  73                   , SDoc              -- C stubs to use when calling
  74                                       -- "foreign exported" functions.
  75                   )
  76 dsForeigns mod_name fos = foldlDs combine ([],[],empty,empty) fos
  77  where
  78   combine (acc_fi, acc_fe, acc_h, acc_c) fo@(ForeignDecl i imp_exp _ ext_nm cconv _)
  79     | isForeignImport =   -- foreign import (dynamic)?
  80         dsFImport i (idType i) uns ext_nm cconv  `thenDs` \ bs ->
  81         returnDs (bs ++ acc_fi, acc_fe, acc_h, acc_c)
  82     | isForeignLabel =
  83         dsFLabel i ext_nm `thenDs` \ b ->
  84         returnDs (b:acc_fi, acc_fe, acc_h, acc_c)
  85     | isDynamicExtName ext_nm =
  86         dsFExportDynamic i (idType i) mod_name ext_nm cconv  `thenDs` \ (fi,fe,h,c) ->
  87         returnDs (fi:acc_fi, fe:acc_fe, h $$ acc_h, c $$ acc_c)
  88
  89     | otherwise        =  -- foreign export
  90         dsFExport i (idType i) mod_name ext_nm cconv False   `thenDs` \ (fe,h,c) ->
  91         returnDs (acc_fi, fe:acc_fe, h $$ acc_h, c $$ acc_c)
  92    where
  93     isForeignImport =
  94         case imp_exp of
  95           FoImport _ -> True
  96           _          -> False
  97
  98     isForeignLabel =
  99         case imp_exp of
 100           FoLabel -> True
 101           _       -> False
 102
 103     (FoImport uns)   = imp_exp
 104
 105 \end{code}
 106
 107 Desugaring foreign imports is just the matter of creating a binding
 108 that on its RHS unboxes its arguments, performs the external call
 109 (using the @CCallOp@ primop), before boxing the result up and returning it.
 110
 111 However, we create a worker/wrapper pair, thus:
 112
 113         foreign import f :: Int -> IO Int
 114 ==>
 115         f x = IO ( \s -> case x of { I# x# ->
 116                          case fw s x# of { (# s1, y# #) ->
 117                          (# s1, I# y# #)}})
 118
 119         fw s x# = ccall f s x#
 120
 121 The strictness/CPR analyser won't do this automatically because it doesn't look
 122 inside returned tuples; but inlining this wrapper is a Really Good Idea
 123 because it exposes the boxing to the call site.
 124
 125
 126 \begin{code}
 127 dsFImport :: Id
 128           -> Type               -- Type of foreign import.
 129           -> Bool               -- True <=> might cause Haskell GC
 130           -> ExtName
 131           -> CallConv
 132           -> DsM [CoreBind]
 133 dsFImport fn_id ty may_not_gc ext_name cconv
 134   = let
 135         (tvs, fun_ty)        = splitForAllTys ty
 136         (arg_tys, io_res_ty) = splitFunTys fun_ty
 137     in
 138     newSysLocalsDs arg_tys                      `thenDs` \ args ->
 139     mapAndUnzipDs unboxArg (map Var args)       `thenDs` \ (val_args, arg_wrappers) ->
 140     boxResult io_res_ty                         `thenDs` \ (ccall_result_ty, res_wrapper) ->
 141
 142     (case ext_name of
 143        Dynamic       -> getUniqueDs `thenDs` \ u ->
 144                         returnDs (DynamicTarget u)
 145        ExtName fs _  -> returnDs (StaticTarget fs))     `thenDs` \ lbl ->
 146
 147     getUniqueDs                                         `thenDs` \ ccall_uniq ->
 148     getUniqueDs                                         `thenDs` \ work_uniq ->
 149     let
 150         -- Build the worker
 151         work_arg_ids  = [v | Var v <- val_args]         -- All guaranteed to be vars
 152         worker_ty     = mkForAllTys tvs (mkFunTys (map idType work_arg_ids) ccall_result_ty)
 153         the_ccall     = CCall lbl False (not may_not_gc) cconv
 154         the_ccall_app = mkCCall ccall_uniq the_ccall val_args ccall_result_ty
 155         work_rhs      = mkLams tvs (mkLams work_arg_ids the_ccall_app)
 156         work_id       = mkSysLocal SLIT("$wccall") work_uniq worker_ty
 157
 158         -- Build the wrapper
 159         work_app     = mkApps (mkVarApps (Var work_id) tvs) val_args
 160         wrapper_body = foldr ($) (res_wrapper work_app) arg_wrappers
 161         wrap_rhs     = mkInlineMe (mkLams (tvs ++ args) wrapper_body)
 162     in
 163     returnDs [NonRec fn_id wrap_rhs, NonRec work_id work_rhs]
 164 \end{code}
 165
 166 Foreign labels
 167
 168 \begin{code}
 169 dsFLabel :: Id -> ExtName -> DsM CoreBind
 170 dsFLabel nm ext_name = returnDs (NonRec nm fo_rhs)
 171   where
 172    fo_rhs = mkConApp addrDataCon [mkLit (MachLitLit enm addrPrimTy)]
 173    enm    = extNameStatic ext_name
 174 \end{code}
 175
 176 The function that does most of the work for `@foreign export@' declarations.
 177 (see below for the boilerplate code a `@foreign export@' declaration expands
 178  into.)
 179
 180 For each `@foreign export foo@' in a module M we generate:
 181 \begin{itemize}
 182 \item a C function `@foo@', which calls
 183 \item a Haskell stub `@M.$ffoo@', which calls
 184 \end{itemize}
 185 the user-written Haskell function `@M.foo@'.
 186
 187 \begin{code}
 188 dsFExport :: Id
 189           -> Type               -- Type of foreign export.
 190           -> Module
 191           -> ExtName
 192           -> CallConv
 193           -> Bool               -- True => invoke IO action that's hanging off
 194                                 -- the first argument's stable pointer
 195           -> DsM ( CoreBind
 196                  , SDoc
 197                  , SDoc
 198                  )
 199 dsFExport fn_id ty mod_name ext_name cconv isDyn
 200   =     -- BUILD THE returnIO WRAPPER, if necessary
 201         -- Look at the result type of the exported function, orig_res_ty
 202         -- If it's IO t, return         (\x.x,          IO t, t)
 203         -- If it's plain t, return      (\x.returnIO x, IO t, t)
 204      (case splitTyConApp_maybe orig_res_ty of
 205         Just (ioTyCon, [res_ty])
 206               -> ASSERT( ioTyCon `hasKey` ioTyConKey )
 207                         -- The function already returns IO t
 208                  returnDs (\body -> body, orig_res_ty, res_ty)
 209
 210         other ->        -- The function returns t, so wrap the call in returnIO
 211                  dsLookupGlobalValue returnIOIdKey      `thenDs` \ retIOId ->
 212                  returnDs (\body -> mkApps (Var retIOId) [Type orig_res_ty, body],
 213                            funResultTy (applyTy (idType retIOId) orig_res_ty),
 214                                 -- We don't have ioTyCon conveniently to hand
 215                            orig_res_ty)
 216
 217      )          `thenDs` \ (return_io_wrapper,  -- Either identity or returnIO
 218                             io_res_ty,          -- IO t
 219                             res_ty) ->          -- t
 220
 221
 222         -- BUILD THE deRefStablePtr WRAPPER, if necessary
 223      (if isDyn then
 224         newSysLocalDs stbl_ptr_ty                       `thenDs` \ stbl_ptr ->
 225         newSysLocalDs stbl_ptr_to_ty                    `thenDs` \ stbl_value ->
 226         dsLookupGlobalValue deRefStablePtrIdKey         `thenDs` \ deRefStablePtrId ->
 227         dsLookupGlobalValue bindIOIdKey                 `thenDs` \ bindIOId ->
 228         let
 229          the_deref_app = mkApps (Var deRefStablePtrId)
 230                                 [ Type stbl_ptr_to_ty, Var stbl_ptr ]
 231
 232          stbl_app cont = mkApps (Var bindIOId)
 233                                 [ Type stbl_ptr_to_ty
 234                                 , Type res_ty
 235                                 , the_deref_app
 236                                 , mkLams [stbl_value] cont]
 237         in
 238         returnDs (stbl_value, stbl_app, stbl_ptr)
 239       else
 240         returnDs (fn_id,
 241                   \ body -> body,
 242                   panic "stbl_ptr"  -- should never be touched.
 243                   ))                    `thenDs` \ (i, getFun_wrapper, stbl_ptr) ->
 244
 245
 246         -- BUILD THE HELPER
 247      getModuleDs                        `thenDs` \ mod ->
 248      getUniqueDs                        `thenDs` \ uniq ->
 249      getSrcLocDs                        `thenDs` \ src_loc ->
 250      newSysLocalsDs fe_arg_tys          `thenDs` \ fe_args ->
 251      let
 252         wrapper_args | isDyn      = stbl_ptr:fe_args
 253                      | otherwise  = fe_args
 254
 255         wrapper_arg_tys | isDyn      = stbl_ptr_ty:fe_arg_tys
 256                         | otherwise  = fe_arg_tys
 257
 258         helper_ty =  mkForAllTys tvs $
 259                      mkFunTys wrapper_arg_tys io_res_ty
 260
 261         f_helper_glob = mkVanillaId helper_name helper_ty
 262                       where
 263                         name                = idName fn_id
 264                         mod
 265                          | isLocalName name = mod_name
 266                          | otherwise        = nameModule name
 267
 268                         occ                 = mkForeignExportOcc (nameOccName name)
 269                         prov                = LocalDef src_loc Exported
 270                         helper_name         = mkGlobalName uniq mod occ prov
 271
 272         the_app = getFun_wrapper (return_io_wrapper (mkVarApps (Var i) (tvs ++ fe_args)))
 273         the_body = mkLams (tvs ++ wrapper_args) the_app
 274         c_nm     = extNameStatic ext_name
 275
 276         (h_stub, c_stub) = fexportEntry (moduleUserString mod)
 277                                       c_nm f_helper_glob
 278                                       wrapper_arg_tys res_ty cconv isDyn
 279      in
 280      returnDs (NonRec f_helper_glob the_body, h_stub, c_stub)
 281
 282   where
 283    (tvs,sans_foralls)                   = splitForAllTys ty
 284    (fe_arg_tys', orig_res_ty)           = splitFunTys sans_foralls
 285
 286    (_, stbl_ptr_ty')                    = splitForAllTys stbl_ptr_ty
 287    (_, stbl_ptr_to_ty)                  = splitAppTy stbl_ptr_ty'
 288
 289    fe_arg_tys | isDyn     = tail fe_arg_tys'
 290               | otherwise = fe_arg_tys'
 291
 292    stbl_ptr_ty | isDyn     = head fe_arg_tys'
 293                | otherwise = error "stbl_ptr_ty"
 294 \end{code}
 295
 296 @foreign export dynamic@ lets you dress up Haskell IO actions
 297 of some fixed type behind an externally callable interface (i.e.,
 298 as a C function pointer). Useful for callbacks and stuff.
 299
 300 \begin{verbatim}
 301 foreign export stdcall f :: (Addr -> Int -> IO Int) -> IO Addr
 302
 303 -- Haskell-visible constructor, which is generated from the
 304 -- above:
 305
 306 f :: (Addr -> Int -> IO Int) -> IO Addr
 307 f cback = IO ( \ s1# ->
 308   case makeStablePtr# cback s1# of { StateAndStablePtr# s2# sp# ->
 309   case _ccall_ "mkAdjustor" sp# ``f_helper'' s2# of
 310     StateAndAddr# s3# a# ->
 311     case addr2Int# a# of
 312       0# -> IOfail s# err
 313       _  ->
 314          let
 315           a :: Addr
 316           a = A# a#
 317          in
 318          IOok s3# a)
 319
 320 foreign export "f_helper" f_helper :: StablePtr (Addr -> Int -> IO Int) -> Addr -> Int -> IO Int
 321 -- `special' foreign export that invokes the closure pointed to by the
 322 -- first argument.
 323 \end{verbatim}
 324
 325 \begin{code}
 326 dsFExportDynamic :: Id
 327                  -> Type                -- Type of foreign export.
 328                  -> Module
 329                  -> ExtName
 330                  -> CallConv
 331                  -> DsM (CoreBind, CoreBind, SDoc, SDoc)
 332 dsFExportDynamic i ty mod_name ext_name cconv =
 333      newSysLocalDs ty                                    `thenDs` \ fe_id ->
 334      let
 335         -- hack: need to get at the name of the C stub we're about to generate.
 336        fe_nm       = moduleUserString mod_name ++ "_" ++ toCName fe_id
 337        fe_ext_name = ExtName (_PK_ fe_nm) Nothing
 338      in
 339      dsFExport  i export_ty mod_name fe_ext_name cconv True
 340      `thenDs` \ (fe@(NonRec fe_helper fe_expr), h_code, c_code) ->
 341      newSysLocalDs arg_ty                       `thenDs` \ cback ->
 342      dsLookupGlobalValue makeStablePtrIdKey     `thenDs` \ makeStablePtrId ->
 343      let
 344         mk_stbl_ptr_app    = mkApps (Var makeStablePtrId) [ Type arg_ty, Var cback ]
 345      in
 346      dsLookupGlobalValue bindIOIdKey                    `thenDs` \ bindIOId ->
 347      newSysLocalDs (mkTyConApp stablePtrTyCon [arg_ty]) `thenDs` \ stbl_value ->
 348      let
 349       stbl_app cont ret_ty
 350         = mkApps (Var bindIOId)
 351                  [ Type (mkTyConApp stablePtrTyCon [arg_ty])
 352                  , Type ret_ty
 353                  , mk_stbl_ptr_app
 354                  , cont
 355                  ]
 356
 357        {-
 358         The arguments to the external function which will
 359         create a little bit of (template) code on the fly
 360         for allowing the (stable pointed) Haskell closure
 361         to be entered using an external calling convention
 362         (stdcall, ccall).
 363        -}
 364       adj_args      = [ mkIntLitInt (callConvToInt cconv)
 365                       , Var stbl_value
 366                       , mkLit (MachLitLit (_PK_ fe_nm) addrPrimTy)
 367                       ]
 368         -- name of external entry point providing these services.
 369         -- (probably in the RTS.)
 370       adjustor      = SLIT("createAdjustor")
 371      in
 372      dsCCall adjustor adj_args False False ioAddrTy `thenDs` \ ccall_adj ->
 373      let ccall_adj_ty = exprType ccall_adj
 374          ccall_io_adj = mkLams [stbl_value]                  $
 375                         Note (Coerce io_res_ty (unUsgTy ccall_adj_ty))
 376                              ccall_adj
 377      in
 378      let io_app = mkLams tvs     $
 379                   mkLams [cback] $
 380                   stbl_app ccall_io_adj addrTy
 381      in
 382      returnDs (NonRec i io_app, fe, h_code, c_code)
 383
 384  where
 385   (tvs,sans_foralls)               = splitForAllTys ty
 386   ([arg_ty], io_res_ty)            = splitFunTys sans_foralls
 387
 388   Just (ioTyCon, [res_ty])         = splitTyConApp_maybe io_res_ty
 389
 390   export_ty                        = mkFunTy (mkTyConApp stablePtrTyCon [arg_ty]) arg_ty
 391
 392   ioAddrTy :: Type      -- IO Addr
 393   ioAddrTy = mkTyConApp ioTyCon [addrTy]
 394
 395 toCName :: Id -> String
 396 toCName i = showSDoc (pprCode CStyle (ppr (idName i)))
 397 \end{code}
 398
 399 %*
 400 %
 401 \subsection{Generating @foreign export@ stubs}
 402 %
 403 %*
 404
 405 For each @foreign export@ function, a C stub function is generated.
 406 The C stub constructs the application of the exported Haskell function
 407 using the hugs/ghc rts invocation API.
 408
 409 \begin{code}
 410 fexportEntry :: String
 411              -> FAST_STRING
 412              -> Id
 413              -> [Type]
 414              -> Type
 415              -> CallConv
 416              -> Bool
 417              -> (SDoc, SDoc)
 418 fexportEntry mod_nm c_nm helper args res_ty cc isDyn = (header_bits, c_bits)
 419  where
 420    -- name of the (Haskell) helper function generated by the desugarer.
 421   h_nm      = ppr helper <> text "_closure"
 422    -- prototype for the exported function.
 423   header_bits = ptext SLIT("extern") <+> fun_proto <> semi
 424
 425   fun_proto = cResType <+> pprCconv <+> ptext c_nm <>
 426               parens (hsep (punctuate comma (zipWith (<+>) cParamTypes proto_args)))
 427
 428   c_bits =
 429     externDecl $$
 430     fun_proto  $$
 431     vcat
 432      [ lbrace
 433      ,   text "SchedulerStatus rc;"
 434      ,   declareResult
 435           -- create the application + perform it.
 436      ,   text "rc=rts_evalIO" <>
 437                   parens (foldl appArg (text "(StgClosure*)&" <> h_nm) (zip args c_args) <> comma <> text "&ret") <> semi
 438      ,   text "rts_checkSchedStatus" <> parens (doubleQuotes (ptext c_nm)
 439                                                 <> comma <> text "rc") <> semi
 440      ,   text "return" <> return_what <> semi
 441      , rbrace
 442      ]
 443
 444   appArg acc (a,c_a) =
 445      text "rts_apply" <> parens (acc <> comma <> mkHObj a <> parens c_a)
 446
 447   cParamTypes  = map showStgType real_args
 448
 449   res_ty_is_unit = res_ty == unitTy
 450
 451   cResType | res_ty_is_unit = text "void"
 452            | otherwise      = showStgType res_ty
 453
 454   pprCconv
 455    | cc == cCallConv = empty
 456    | otherwise       = pprCallConv cc
 457
 458   declareResult  = text "HaskellObj ret;"
 459
 460   externDecl     = mkExtern (text "HaskellObj") h_nm
 461
 462   mkExtern ty nm = text "extern" <+> ty <+> nm <> semi
 463
 464   return_what | res_ty_is_unit = empty
 465               | otherwise      = parens (unpackHObj res_ty <> parens (text "ret"))
 466
 467   c_args = mkCArgNames 0 args
 468
 469   {-
 470    If we're generating an entry point for a 'foreign export ccall dynamic',
 471    then we receive the return address of the C function that wants to
 472    invoke a Haskell function as any other C function, as second arg.
 473    This arg is unused within the body of the generated C stub, but
 474    needed by the Adjustor.c code to get the stack cleanup right.
 475   -}
 476   (proto_args, real_args)
 477     | cc == cCallConv && isDyn = ( text "a0" : text "a_" : mkCArgNames 1 (tail args)
 478                                 , head args : addrTy : tail args)
 479     | otherwise = (mkCArgNames 0 args, args)
 480
 481 mkCArgNames :: Int -> [a] -> [SDoc]
 482 mkCArgNames n as = zipWith (\ _ n -> text ('a':show n)) as [n..]
 483
 484 mkHObj :: Type -> SDoc
 485 mkHObj t = text "rts_mk" <> text (showFFIType t)
 486
 487 unpackHObj :: Type -> SDoc
 488 unpackHObj t = text "rts_get" <> text (showFFIType t)
 489
 490 showStgType :: Type -> SDoc
 491 showStgType t = text "Stg" <> text (showFFIType t)
 492
 493 showFFIType :: Type -> String
 494 showFFIType t = getOccString (getName tc)
 495  where
 496   tc = case splitTyConApp_maybe t of
 497             Just (tc,_) -> tc
 498             Nothing     -> pprPanic "showFFIType" (ppr t)
 499 \end{code}