ghc/compiler/deSugar/DsForeign.lhs

   1 %
   2 % (c) The AQUA Project, Glasgow University, 1998
   3 %
   4 \section[DsCCall]{Desugaring \tr{foreign} declarations}
   5
   6 Expanding out @foreign import@ and @foreign export@ declarations.
   7
   8 \begin{code}
   9 module DsForeign ( dsForeigns ) where
  10
  11 #include "HsVersions.h"
  12
  13 import CoreSyn
  14
  15 import DsCCall          ( dsCCall, mkCCall, boxResult, unboxArg, resultWrapper )
  16 import DsMonad
  17
  18 import HsSyn            ( ExtName(..), ForeignDecl(..), isDynamicExtName, ForKind(..) )
  19 import HsDecls          ( extNameStatic )
  20 import CallConv
  21 import TcHsSyn          ( TypecheckedForeignDecl )
  22 import CoreUtils        ( exprType, mkInlineMe )
  23 import Id               ( Id, idType, idName, mkVanillaId, mkSysLocal,
  24                           setInlinePragma )
  25 import IdInfo           ( neverInlinePrag )
  26 import Literal          ( Literal(..) )
  27 import Module           ( Module, moduleUserString )
  28 import Name             ( mkGlobalName, nameModule, nameOccName, getOccString,
  29                           mkForeignExportOcc, isLocalName,
  30                           NamedThing(..),
  31                         )
  32 import Type             ( unUsgTy, repType,
  33                           splitTyConApp_maybe, splitFunTys, splitForAllTys,
  34                           Type, mkFunTys, mkForAllTys, mkTyConApp,
  35                           mkTyVarTy, mkFunTy, splitAppTy, applyTy, funResultTy
  36                         )
  37 import PrimOp           ( PrimOp(..), CCall(..),
  38                           CCallTarget(..), dynamicTarget )
  39 import TysWiredIn       ( unitTy, addrTy, stablePtrTyCon,
  40                           addrDataCon
  41                         )
  42 import TysPrim          ( addrPrimTy )
  43 import PrelNames        ( Uniquable(..), hasKey,
  44                           ioTyConKey, deRefStablePtrName, returnIOIdKey,
  45                           bindIOName,
  46                           returnIOName, makeStablePtrName
  47                         )
  48 import Outputable
  49
  50 import Maybe            ( fromJust )
  51 \end{code}
  52
  53 Desugaring of @foreign@ declarations is naturally split up into
  54 parts, an @import@ and an @export@  part. A @foreign import@
  55 declaration
  56 \begin{verbatim}
  57   foreign import cc nm f :: prim_args -> IO prim_res
  58 \end{verbatim}
  59 is the same as
  60 \begin{verbatim}
  61   f :: prim_args -> IO prim_res
  62   f a1 ... an = _ccall_ nm cc a1 ... an
  63 \end{verbatim}
  64 so we reuse the desugaring code in @DsCCall@ to deal with these.
  65
  66 \begin{code}
  67 type Binding = (Id, CoreExpr)   -- No rec/nonrec structure;
  68                                 -- the occurrence analyser will sort it all out
  69
  70 dsForeigns :: Module
  71            -> [TypecheckedForeignDecl]
  72            -> DsM ( [Id]                -- Foreign-exported binders;
  73                                         -- we have to generate code to register these
  74                   , [Binding]
  75                   , SDoc              -- Header file prototypes for
  76                                       -- "foreign exported" functions.
  77                   , SDoc              -- C stubs to use when calling
  78                                       -- "foreign exported" functions.
  79                   )
  80 dsForeigns mod_name fos = foldlDs combine ([], [], empty, empty) fos
  81  where
  82   combine (acc_feb, acc_f, acc_h, acc_c) fo@(ForeignDecl i imp_exp _ ext_nm cconv _)
  83     | isForeignImport =   -- foreign import (dynamic)?
  84         dsFImport i (idType i) uns ext_nm cconv  `thenDs` \ bs ->
  85         returnDs (acc_feb, bs ++ acc_f, acc_h, acc_c)
  86     | isForeignLabel =
  87         dsFLabel i (idType i) ext_nm `thenDs` \ b ->
  88         returnDs (acc_feb, b:acc_f, acc_h, acc_c)
  89     | isDynamicExtName ext_nm =
  90         dsFExportDynamic i (idType i) mod_name ext_nm cconv  `thenDs` \ (feb,bs,h,c) ->
  91         returnDs (feb:acc_feb, bs ++ acc_f, h $$ acc_h, c $$ acc_c)
  92
  93     | otherwise        =  -- foreign export
  94         dsFExport i (idType i) mod_name ext_nm cconv False   `thenDs` \ (feb,fe,h,c) ->
  95         returnDs (feb:acc_feb, fe:acc_f, h $$ acc_h, c $$ acc_c)
  96    where
  97     isForeignImport =
  98         case imp_exp of
  99           FoImport _ -> True
 100           _          -> False
 101
 102     isForeignLabel =
 103         case imp_exp of
 104           FoLabel -> True
 105           _       -> False
 106
 107     (FoImport uns)   = imp_exp
 108
 109 \end{code}
 110
 111 Desugaring foreign imports is just the matter of creating a binding
 112 that on its RHS unboxes its arguments, performs the external call
 113 (using the @CCallOp@ primop), before boxing the result up and returning it.
 114
 115 However, we create a worker/wrapper pair, thus:
 116
 117         foreign import f :: Int -> IO Int
 118 ==>
 119         f x = IO ( \s -> case x of { I# x# ->
 120                          case fw s x# of { (# s1, y# #) ->
 121                          (# s1, I# y# #)}})
 122
 123         fw s x# = ccall f s x#
 124
 125 The strictness/CPR analyser won't do this automatically because it doesn't look
 126 inside returned tuples; but inlining this wrapper is a Really Good Idea
 127 because it exposes the boxing to the call site.
 128
 129
 130 \begin{code}
 131 dsFImport :: Id
 132           -> Type               -- Type of foreign import.
 133           -> Bool               -- True <=> might cause Haskell GC
 134           -> ExtName
 135           -> CallConv
 136           -> DsM [Binding]
 137 dsFImport fn_id ty may_not_gc ext_name cconv
 138   = let
 139         (tvs, fun_ty)        = splitForAllTys ty
 140         (arg_tys, io_res_ty) = splitFunTys fun_ty
 141     in
 142     newSysLocalsDs arg_tys                      `thenDs` \ args ->
 143     mapAndUnzipDs unboxArg (map Var args)       `thenDs` \ (val_args, arg_wrappers) ->
 144     boxResult io_res_ty                         `thenDs` \ (ccall_result_ty, res_wrapper) ->
 145
 146     getUniqueDs                                         `thenDs` \ ccall_uniq ->
 147     getUniqueDs                                         `thenDs` \ work_uniq ->
 148     let
 149         lbl = case ext_name of
 150                 Dynamic      -> dynamicTarget
 151                 ExtName fs _ -> StaticTarget fs
 152
 153         -- Build the worker
 154         work_arg_ids  = [v | Var v <- val_args]         -- All guaranteed to be vars
 155         worker_ty     = mkForAllTys tvs (mkFunTys (map idType work_arg_ids) ccall_result_ty)
 156         the_ccall     = CCall lbl False (not may_not_gc) cconv
 157         the_ccall_app = mkCCall ccall_uniq the_ccall val_args ccall_result_ty
 158         work_rhs      = mkLams tvs (mkLams work_arg_ids the_ccall_app)
 159         work_id       = mkSysLocal SLIT("$wccall") work_uniq worker_ty
 160
 161         -- Build the wrapper
 162         work_app     = mkApps (mkVarApps (Var work_id) tvs) val_args
 163         wrapper_body = foldr ($) (res_wrapper work_app) arg_wrappers
 164         wrap_rhs     = mkInlineMe (mkLams (tvs ++ args) wrapper_body)
 165     in
 166     returnDs [(work_id, work_rhs), (fn_id, wrap_rhs)]
 167 \end{code}
 168
 169 Foreign labels
 170
 171 \begin{code}
 172 dsFLabel :: Id -> Type -> ExtName -> DsM Binding
 173 dsFLabel nm ty ext_name =
 174    ASSERT(fromJust res_ty == addrPrimTy) -- typechecker ensures this
 175    returnDs (nm, fo_rhs (mkLit (MachLabel enm)))
 176   where
 177    (res_ty, fo_rhs) = resultWrapper ty
 178    enm    = extNameStatic ext_name
 179 \end{code}
 180
 181 The function that does most of the work for `@foreign export@' declarations.
 182 (see below for the boilerplate code a `@foreign export@' declaration expands
 183  into.)
 184
 185 For each `@foreign export foo@' in a module M we generate:
 186 \begin{itemize}
 187 \item a C function `@foo@', which calls
 188 \item a Haskell stub `@M.$ffoo@', which calls
 189 \end{itemize}
 190 the user-written Haskell function `@M.foo@'.
 191
 192 \begin{code}
 193 dsFExport :: Id
 194           -> Type               -- Type of foreign export.
 195           -> Module
 196           -> ExtName
 197           -> CallConv
 198           -> Bool               -- True => invoke IO action that's hanging off
 199                                 -- the first argument's stable pointer
 200           -> DsM ( Id           -- The foreign-exported Id
 201                  , Binding
 202                  , SDoc
 203                  , SDoc
 204                  )
 205 dsFExport fn_id ty mod_name ext_name cconv isDyn
 206   =     -- BUILD THE returnIO WRAPPER, if necessary
 207         -- Look at the result type of the exported function, orig_res_ty
 208         -- If it's IO t, return         (\x.x,          IO t, t)
 209         -- If it's plain t, return      (\x.returnIO x, IO t, t)
 210      (case splitTyConApp_maybe orig_res_ty of
 211         Just (ioTyCon, [res_ty])
 212               -> ASSERT( ioTyCon `hasKey` ioTyConKey )
 213                         -- The function already returns IO t
 214                  returnDs (\body -> body, orig_res_ty, res_ty)
 215
 216         other ->        -- The function returns t, so wrap the call in returnIO
 217                  dsLookupGlobalValue returnIOName       `thenDs` \ retIOId ->
 218                  returnDs (\body -> mkApps (Var retIOId) [Type orig_res_ty, body],
 219                            funResultTy (applyTy (idType retIOId) orig_res_ty),
 220                                 -- We don't have ioTyCon conveniently to hand
 221                            orig_res_ty)
 222
 223      )          `thenDs` \ (return_io_wrapper,  -- Either identity or returnIO
 224                             io_res_ty,          -- IO t
 225                             res_ty) ->          -- t
 226
 227
 228         -- BUILD THE deRefStablePtr WRAPPER, if necessary
 229      (if isDyn then
 230         newSysLocalDs stbl_ptr_ty                       `thenDs` \ stbl_ptr ->
 231         newSysLocalDs stbl_ptr_to_ty                    `thenDs` \ stbl_value ->
 232         dsLookupGlobalValue deRefStablePtrName          `thenDs` \ deRefStablePtrId ->
 233         dsLookupGlobalValue bindIOName                  `thenDs` \ bindIOId ->
 234         let
 235          the_deref_app = mkApps (Var deRefStablePtrId)
 236                                 [ Type stbl_ptr_to_ty, Var stbl_ptr ]
 237
 238          stbl_app cont = mkApps (Var bindIOId)
 239                                 [ Type stbl_ptr_to_ty
 240                                 , Type res_ty
 241                                 , the_deref_app
 242                                 , mkLams [stbl_value] cont]
 243         in
 244         returnDs (stbl_value, stbl_app, stbl_ptr)
 245       else
 246         returnDs (fn_id,
 247                   \ body -> body,
 248                   panic "stbl_ptr"  -- should never be touched.
 249                   ))                    `thenDs` \ (i, getFun_wrapper, stbl_ptr) ->
 250
 251
 252         -- BUILD THE HELPER
 253      getModuleDs                        `thenDs` \ mod ->
 254      getUniqueDs                        `thenDs` \ uniq ->
 255      getSrcLocDs                        `thenDs` \ src_loc ->
 256      newSysLocalsDs fe_arg_tys          `thenDs` \ fe_args ->
 257      let
 258         wrapper_args | isDyn      = stbl_ptr:fe_args
 259                      | otherwise  = fe_args
 260
 261         wrapper_arg_tys | isDyn      = stbl_ptr_ty:fe_arg_tys
 262                         | otherwise  = fe_arg_tys
 263
 264         helper_ty =  mkForAllTys tvs $
 265                      mkFunTys wrapper_arg_tys io_res_ty
 266
 267         f_helper_glob = mkVanillaId helper_name helper_ty
 268                       where
 269                         name                = idName fn_id
 270                         mod
 271                          | isLocalName name = mod_name
 272                          | otherwise        = nameModule name
 273
 274                         occ                 = mkForeignExportOcc (nameOccName name)
 275                         helper_name         = mkGlobalName uniq mod occ src_loc
 276
 277         the_app = getFun_wrapper (return_io_wrapper (mkVarApps (Var i) (tvs ++ fe_args)))
 278         the_body = mkLams (tvs ++ wrapper_args) the_app
 279         c_nm     = extNameStatic ext_name
 280
 281         (h_stub, c_stub) = fexportEntry (moduleUserString mod)
 282                                       c_nm f_helper_glob
 283                                       wrapper_arg_tys res_ty cconv isDyn
 284      in
 285      returnDs (f_helper_glob, (f_helper_glob, the_body), h_stub, c_stub)
 286
 287   where
 288    (tvs,sans_foralls)                   = splitForAllTys ty
 289    (fe_arg_tys', orig_res_ty)           = splitFunTys sans_foralls
 290
 291    (_, stbl_ptr_ty')                    = splitForAllTys stbl_ptr_ty
 292    (_, stbl_ptr_to_ty)                  = splitAppTy stbl_ptr_ty'
 293
 294    fe_arg_tys | isDyn     = tail fe_arg_tys'
 295               | otherwise = fe_arg_tys'
 296
 297    stbl_ptr_ty | isDyn     = head fe_arg_tys'
 298                | otherwise = error "stbl_ptr_ty"
 299 \end{code}
 300
 301 @foreign export dynamic@ lets you dress up Haskell IO actions
 302 of some fixed type behind an externally callable interface (i.e.,
 303 as a C function pointer). Useful for callbacks and stuff.
 304
 305 \begin{verbatim}
 306 foreign export dynamic f :: (Addr -> Int -> IO Int) -> IO Addr
 307
 308 -- Haskell-visible constructor, which is generated from the above:
 309 -- SUP: No check for NULL from createAdjustor anymore???
 310
 311 f :: (Addr -> Int -> IO Int) -> IO Addr
 312 f cback =
 313    bindIO (makeStablePtr cback)
 314           (\StablePtr sp# -> IO (\s1# ->
 315               case _ccall_ createAdjustor cconv sp# ``f_helper'' s1# of
 316                  (# s2#, a# #) -> (# s2#, A# a# #)))
 317
 318 foreign export "f_helper" f_helper :: StablePtr (Addr -> Int -> IO Int) -> Addr -> Int -> IO Int
 319 -- `special' foreign export that invokes the closure pointed to by the
 320 -- first argument.
 321 \end{verbatim}
 322
 323 \begin{code}
 324 dsFExportDynamic :: Id
 325                  -> Type                -- Type of foreign export.
 326                  -> Module
 327                  -> ExtName
 328                  -> CallConv
 329                  -> DsM (Id, [Binding], SDoc, SDoc)
 330 dsFExportDynamic i ty mod_name ext_name cconv =
 331      newSysLocalDs ty                                    `thenDs` \ fe_id ->
 332      let
 333         -- hack: need to get at the name of the C stub we're about to generate.
 334        fe_nm       = moduleUserString mod_name ++ "_" ++ toCName fe_id
 335        fe_ext_name = ExtName (_PK_ fe_nm) Nothing
 336      in
 337      dsFExport  i export_ty mod_name fe_ext_name cconv True
 338         `thenDs` \ (feb, fe, h_code, c_code) ->
 339      newSysLocalDs arg_ty                       `thenDs` \ cback ->
 340      dsLookupGlobalValue makeStablePtrName      `thenDs` \ makeStablePtrId ->
 341      let
 342         mk_stbl_ptr_app    = mkApps (Var makeStablePtrId) [ Type arg_ty, Var cback ]
 343      in
 344      dsLookupGlobalValue bindIOName                     `thenDs` \ bindIOId ->
 345      newSysLocalDs (mkTyConApp stablePtrTyCon [arg_ty]) `thenDs` \ stbl_value ->
 346      let
 347       stbl_app cont ret_ty
 348         = mkApps (Var bindIOId)
 349                  [ Type (mkTyConApp stablePtrTyCon [arg_ty])
 350                  , Type ret_ty
 351                  , mk_stbl_ptr_app
 352                  , cont
 353                  ]
 354
 355        {-
 356         The arguments to the external function which will
 357         create a little bit of (template) code on the fly
 358         for allowing the (stable pointed) Haskell closure
 359         to be entered using an external calling convention
 360         (stdcall, ccall).
 361        -}
 362       adj_args      = [ mkIntLitInt (callConvToInt cconv)
 363                       , Var stbl_value
 364                       , mkLit (MachLabel (_PK_ fe_nm))
 365                       ]
 366         -- name of external entry point providing these services.
 367         -- (probably in the RTS.)
 368       adjustor      = SLIT("createAdjustor")
 369      in
 370      dsCCall adjustor adj_args False False io_res_ty `thenDs` \ ccall_adj ->
 371      let ccall_adj_ty = exprType ccall_adj
 372          ccall_io_adj = mkLams [stbl_value]                  $
 373                         Note (Coerce io_res_ty (unUsgTy ccall_adj_ty))
 374                              ccall_adj
 375      in
 376      let io_app = mkLams tvs     $
 377                   mkLams [cback] $
 378                   stbl_app ccall_io_adj res_ty
 379          fed = (i `setInlinePragma` neverInlinePrag, io_app)
 380                 -- Never inline the f.e.d. function, because the litlit
 381                 -- might not be in scope in other modules.
 382      in
 383      returnDs (feb, [fed, fe], h_code, c_code)
 384
 385  where
 386   (tvs,sans_foralls)               = splitForAllTys ty
 387   ([arg_ty], io_res_ty)            = splitFunTys sans_foralls
 388
 389   Just (ioTyCon, [res_ty])         = splitTyConApp_maybe io_res_ty
 390
 391   export_ty                        = mkFunTy (mkTyConApp stablePtrTyCon [arg_ty]) arg_ty
 392
 393   ioAddrTy :: Type      -- IO Addr
 394   ioAddrTy = mkTyConApp ioTyCon [addrTy]
 395
 396 toCName :: Id -> String
 397 toCName i = showSDoc (pprCode CStyle (ppr (idName i)))
 398 \end{code}
 399
 400 %*
 401 %
 402 \subsection{Generating @foreign export@ stubs}
 403 %
 404 %*
 405
 406 For each @foreign export@ function, a C stub function is generated.
 407 The C stub constructs the application of the exported Haskell function
 408 using the hugs/ghc rts invocation API.
 409
 410 \begin{code}
 411 fexportEntry :: String
 412              -> FAST_STRING
 413              -> Id
 414              -> [Type]
 415              -> Type
 416              -> CallConv
 417              -> Bool
 418              -> (SDoc, SDoc)
 419 fexportEntry mod_nm c_nm helper args res_ty cc isDyn = (header_bits, c_bits)
 420  where
 421    -- name of the (Haskell) helper function generated by the desugarer.
 422   h_nm      = ppr helper <> text "_closure"
 423    -- prototype for the exported function.
 424   header_bits = ptext SLIT("extern") <+> fun_proto <> semi
 425
 426   fun_proto = cResType <+> pprCconv <+> ptext c_nm <>
 427               parens (hsep (punctuate comma (zipWith (<+>) cParamTypes proto_args)))
 428
 429   c_bits =
 430     externDecl $$
 431     fun_proto  $$
 432     vcat
 433      [ lbrace
 434      ,   text "SchedulerStatus rc;"
 435      ,   declareResult
 436           -- create the application + perform it.
 437      ,   text "rc=rts_evalIO" <>
 438                   parens (foldl appArg (text "(StgClosure*)&" <> h_nm) (zip args c_args) <> comma <> text "&ret") <> semi
 439      ,   text "rts_checkSchedStatus" <> parens (doubleQuotes (ptext c_nm)
 440                                                 <> comma <> text "rc") <> semi
 441      ,   text "return" <> return_what <> semi
 442      , rbrace
 443      ]
 444
 445   appArg acc (a,c_a) =
 446      text "rts_apply" <> parens (acc <> comma <> mkHObj a <> parens c_a)
 447
 448   cParamTypes  = map showStgType real_args
 449
 450   res_ty_is_unit = res_ty == unitTy
 451
 452   cResType | res_ty_is_unit = text "void"
 453            | otherwise      = showStgType res_ty
 454
 455   pprCconv
 456    | cc == cCallConv = empty
 457    | otherwise       = pprCallConv cc
 458
 459   declareResult  = text "HaskellObj ret;"
 460
 461   externDecl     = mkExtern (text "HaskellObj") h_nm
 462
 463   mkExtern ty nm = text "extern" <+> ty <+> nm <> semi
 464
 465   return_what | res_ty_is_unit = empty
 466               | otherwise      = parens (unpackHObj res_ty <> parens (text "ret"))
 467
 468   c_args = mkCArgNames 0 args
 469
 470   {-
 471    If we're generating an entry point for a 'foreign export ccall dynamic',
 472    then we receive the return address of the C function that wants to
 473    invoke a Haskell function as any other C function, as second arg.
 474    This arg is unused within the body of the generated C stub, but
 475    needed by the Adjustor.c code to get the stack cleanup right.
 476   -}
 477   (proto_args, real_args)
 478     | cc == cCallConv && isDyn = ( text "a0" : text "a_" : mkCArgNames 1 (tail args)
 479                                 , head args : addrTy : tail args)
 480     | otherwise = (mkCArgNames 0 args, args)
 481
 482 mkCArgNames :: Int -> [a] -> [SDoc]
 483 mkCArgNames n as = zipWith (\ _ n -> text ('a':show n)) as [n..]
 484
 485 mkHObj :: Type -> SDoc
 486 mkHObj t = text "rts_mk" <> text (showFFIType t)
 487
 488 unpackHObj :: Type -> SDoc
 489 unpackHObj t = text "rts_get" <> text (showFFIType t)
 490
 491 showStgType :: Type -> SDoc
 492 showStgType t = text "Stg" <> text (showFFIType t)
 493
 494 showFFIType :: Type -> String
 495 showFFIType t = getOccString (getName tc)
 496  where
 497   tc = case splitTyConApp_maybe (repType t) of
 498             Just (tc,_) -> tc
 499             Nothing     -> pprPanic "showFFIType" (ppr t)
 500 \end{code}