ghc/compiler/deSugar/DsUtils.lhs

   1 %
   2 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   3 %
   4 \section[DsUtils]{Utilities for desugaring}
   5
   6 This module exports some utility functions of no great interest.
   7
   8 \begin{code}
   9 module DsUtils (
  10         EquationInfo(..),
  11         firstPat, shiftEqns,
  12
  13         mkDsLet, mkDsLets,
  14
  15         MatchResult(..), CanItFail(..),
  16         cantFailMatchResult, alwaysFailMatchResult,
  17         extractMatchResult, combineMatchResults,
  18         adjustMatchResult,  adjustMatchResultDs,
  19         mkCoLetMatchResult, mkGuardedMatchResult,
  20         matchCanFail,
  21         mkCoPrimCaseMatchResult, mkCoAlgCaseMatchResult,
  22         wrapBind, wrapBinds,
  23
  24         mkErrorAppDs, mkNilExpr, mkConsExpr, mkListExpr,
  25         mkIntExpr, mkCharExpr,
  26         mkStringExpr, mkStringExprFS, mkIntegerExpr,
  27
  28         mkSelectorBinds, mkTupleExpr, mkTupleSelector,
  29         mkTupleType, mkTupleCase, mkBigCoreTup,
  30         mkCoreTup, mkCoreTupTy,
  31
  32         dsSyntaxTable, lookupEvidence,
  33
  34         selectSimpleMatchVarL, selectMatchVars
  35     ) where
  36
  37 #include "HsVersions.h"
  38
  39 import {-# SOURCE #-}   Match ( matchSimply )
  40 import {-# SOURCE #-}   DsExpr( dsExpr )
  41
  42 import HsSyn
  43 import TcHsSyn          ( hsPatType )
  44 import CoreSyn
  45 import Constants        ( mAX_TUPLE_SIZE )
  46 import DsMonad
  47
  48 import CoreUtils        ( exprType, mkIfThenElse, mkCoerce, bindNonRec )
  49 import MkId             ( iRREFUT_PAT_ERROR_ID, mkReboxingAlt, mkNewTypeBody )
  50 import Id               ( idType, Id, mkWildId, mkTemplateLocals, mkSysLocal )
  51 import Var              ( Var )
  52 import Name             ( Name )
  53 import Literal          ( Literal(..), mkStringLit, inIntRange, tARGET_MAX_INT )
  54 import TyCon            ( isNewTyCon, tyConDataCons )
  55 import DataCon          ( DataCon, dataConSourceArity, dataConTyCon, dataConTag )
  56 import Type             ( mkFunTy, isUnLiftedType, Type, splitTyConApp, mkTyVarTy )
  57 import TcType           ( tcEqType )
  58 import TysPrim          ( intPrimTy )
  59 import TysWiredIn       ( nilDataCon, consDataCon,
  60                           tupleCon, mkTupleTy,
  61                           unitDataConId, unitTy,
  62                           charTy, charDataCon,
  63                           intTy, intDataCon,
  64                           isPArrFakeCon )
  65 import BasicTypes       ( Boxity(..) )
  66 import UniqSet          ( mkUniqSet, minusUniqSet, isEmptyUniqSet )
  67 import UniqSupply       ( splitUniqSupply, uniqFromSupply, uniqsFromSupply )
  68 import PrelNames        ( unpackCStringName, unpackCStringUtf8Name,
  69                           plusIntegerName, timesIntegerName, smallIntegerDataConName,
  70                           lengthPName, indexPName )
  71 import Outputable
  72 import SrcLoc           ( Located(..), unLoc )
  73 import Util             ( isSingleton, zipEqual, sortWith )
  74 import ListSetOps       ( assocDefault )
  75 import FastString
  76 import Data.Char        ( ord )
  77
  78 #ifdef DEBUG
  79 import Util             ( notNull )     -- Used in an assertion
  80 #endif
  81 \end{code}
  82
  83
  84
  85 %************************************************************************
  86 %*                                                                      *
  87                 Rebindable syntax
  88 %*                                                                      *
  89 %************************************************************************
  90
  91 \begin{code}
  92 dsSyntaxTable :: SyntaxTable Id
  93                -> DsM ([CoreBind],      -- Auxiliary bindings
  94                        [(Name,Id)])     -- Maps the standard name to its value
  95
  96 dsSyntaxTable rebound_ids
  97   = mapAndUnzipDs mk_bind rebound_ids   `thenDs` \ (binds_s, prs) ->
  98     return (concat binds_s, prs)
  99   where
 100         -- The cheapo special case can happen when we
 101         -- make an intermediate HsDo when desugaring a RecStmt
 102     mk_bind (std_name, HsVar id) = return ([], (std_name, id))
 103     mk_bind (std_name, expr)
 104          = dsExpr expr                          `thenDs` \ rhs ->
 105            newSysLocalDs (exprType rhs)         `thenDs` \ id ->
 106            return ([NonRec id rhs], (std_name, id))
 107
 108 lookupEvidence :: [(Name, Id)] -> Name -> Id
 109 lookupEvidence prs std_name
 110   = assocDefault (mk_panic std_name) prs std_name
 111   where
 112     mk_panic std_name = pprPanic "dsSyntaxTable" (ptext SLIT("Not found:") <+> ppr std_name)
 113 \end{code}
 114
 115
 116 %************************************************************************
 117 %*                                                                      *
 118 \subsection{Building lets}
 119 %*                                                                      *
 120 %************************************************************************
 121
 122 Use case, not let for unlifted types.  The simplifier will turn some
 123 back again.
 124
 125 \begin{code}
 126 mkDsLet :: CoreBind -> CoreExpr -> CoreExpr
 127 mkDsLet (NonRec bndr rhs) body
 128   | isUnLiftedType (idType bndr)
 129   = Case rhs bndr (exprType body) [(DEFAULT,[],body)]
 130 mkDsLet bind body
 131   = Let bind body
 132
 133 mkDsLets :: [CoreBind] -> CoreExpr -> CoreExpr
 134 mkDsLets binds body = foldr mkDsLet body binds
 135 \end{code}
 136
 137
 138 %************************************************************************
 139 %*                                                                      *
 140 \subsection{ Selecting match variables}
 141 %*                                                                      *
 142 %************************************************************************
 143
 144 We're about to match against some patterns.  We want to make some
 145 @Ids@ to use as match variables.  If a pattern has an @Id@ readily at
 146 hand, which should indeed be bound to the pattern as a whole, then use it;
 147 otherwise, make one up.
 148
 149 \begin{code}
 150 selectSimpleMatchVarL :: LPat Id -> DsM Id
 151 selectSimpleMatchVarL pat = selectMatchVar (unLoc pat) (hsPatType pat)
 152
 153 -- (selectMatchVars ps tys) chooses variables of type tys
 154 -- to use for matching ps against.  If the pattern is a variable,
 155 -- we try to use that, to save inventing lots of fresh variables.
 156 -- But even if it is a variable, its type might not match.  Consider
 157 --      data T a where
 158 --        T1 :: Int -> T Int
 159 --        T2 :: a   -> T a
 160 --
 161 --      f :: T a -> a -> Int
 162 --      f (T1 i) (x::Int) = x
 163 --      f (T2 i) (y::a)   = 0
 164 -- Then we must not choose (x::Int) as the matching variable!
 165
 166 selectMatchVars :: [Pat Id] -> [Type] -> DsM [Id]
 167 selectMatchVars []     []       = return []
 168 selectMatchVars (p:ps) (ty:tys) = do { v  <- selectMatchVar  p  ty
 169                                      ; vs <- selectMatchVars ps tys
 170                                      ; return (v:vs) }
 171
 172 selectMatchVar (LazyPat pat)   pat_ty  = selectMatchVar (unLoc pat) pat_ty
 173 selectMatchVar (VarPat var)    pat_ty  = try_for var         pat_ty
 174 selectMatchVar (AsPat var pat) pat_ty  = try_for (unLoc var) pat_ty
 175 selectMatchVar other_pat       pat_ty  = newSysLocalDs pat_ty   -- OK, better make up one...
 176
 177 try_for var pat_ty
 178   | idType var `tcEqType` pat_ty = returnDs var
 179   | otherwise                    = newSysLocalDs pat_ty
 180 \end{code}
 181
 182
 183 %************************************************************************
 184 %*                                                                      *
 185 %* type synonym EquationInfo and access functions for its pieces        *
 186 %*                                                                      *
 187 %************************************************************************
 188 \subsection[EquationInfo-synonym]{@EquationInfo@: a useful synonym}
 189
 190 The ``equation info'' used by @match@ is relatively complicated and
 191 worthy of a type synonym and a few handy functions.
 192
 193 \begin{code}
 194 firstPat :: EquationInfo -> Pat Id
 195 firstPat eqn = head (eqn_pats eqn)
 196
 197 shiftEqns :: [EquationInfo] -> [EquationInfo]
 198 -- Drop the first pattern in each equation
 199 shiftEqns eqns = [ eqn { eqn_pats = tail (eqn_pats eqn) } | eqn <- eqns ]
 200 \end{code}
 201
 202 Functions on MatchResults
 203
 204 \begin{code}
 205 matchCanFail :: MatchResult -> Bool
 206 matchCanFail (MatchResult CanFail _)  = True
 207 matchCanFail (MatchResult CantFail _) = False
 208
 209 alwaysFailMatchResult :: MatchResult
 210 alwaysFailMatchResult = MatchResult CanFail (\fail -> returnDs fail)
 211
 212 cantFailMatchResult :: CoreExpr -> MatchResult
 213 cantFailMatchResult expr = MatchResult CantFail (\ ignore -> returnDs expr)
 214
 215 extractMatchResult :: MatchResult -> CoreExpr -> DsM CoreExpr
 216 extractMatchResult (MatchResult CantFail match_fn) fail_expr
 217   = match_fn (error "It can't fail!")
 218
 219 extractMatchResult (MatchResult CanFail match_fn) fail_expr
 220   = mkFailurePair fail_expr             `thenDs` \ (fail_bind, if_it_fails) ->
 221     match_fn if_it_fails                `thenDs` \ body ->
 222     returnDs (mkDsLet fail_bind body)
 223
 224
 225 combineMatchResults :: MatchResult -> MatchResult -> MatchResult
 226 combineMatchResults (MatchResult CanFail      body_fn1)
 227                     (MatchResult can_it_fail2 body_fn2)
 228   = MatchResult can_it_fail2 body_fn
 229   where
 230     body_fn fail = body_fn2 fail                        `thenDs` \ body2 ->
 231                    mkFailurePair body2                  `thenDs` \ (fail_bind, duplicatable_expr) ->
 232                    body_fn1 duplicatable_expr           `thenDs` \ body1 ->
 233                    returnDs (Let fail_bind body1)
 234
 235 combineMatchResults match_result1@(MatchResult CantFail body_fn1) match_result2
 236   = match_result1
 237
 238 adjustMatchResult :: (CoreExpr -> CoreExpr) -> MatchResult -> MatchResult
 239 adjustMatchResult encl_fn (MatchResult can_it_fail body_fn)
 240   = MatchResult can_it_fail (\fail -> body_fn fail      `thenDs` \ body ->
 241                                       returnDs (encl_fn body))
 242
 243 adjustMatchResultDs :: (CoreExpr -> DsM CoreExpr) -> MatchResult -> MatchResult
 244 adjustMatchResultDs encl_fn (MatchResult can_it_fail body_fn)
 245   = MatchResult can_it_fail (\fail -> body_fn fail      `thenDs` \ body ->
 246                                       encl_fn body)
 247
 248 wrapBinds :: [(Var,Var)] -> CoreExpr -> CoreExpr
 249 wrapBinds [] e = e
 250 wrapBinds ((new,old):prs) e = wrapBind new old (wrapBinds prs e)
 251
 252 wrapBind :: Var -> Var -> CoreExpr -> CoreExpr
 253 wrapBind new old body
 254   | new==old    = body
 255   | isTyVar new = App (Lam new body) (Type (mkTyVarTy old))
 256   | otherwise   = Let (NonRec new (Var old)) body
 257
 258 mkCoLetMatchResult :: CoreBind -> MatchResult -> MatchResult
 259 mkCoLetMatchResult bind match_result
 260   = adjustMatchResult (mkDsLet bind) match_result
 261
 262 mkGuardedMatchResult :: CoreExpr -> MatchResult -> MatchResult
 263 mkGuardedMatchResult pred_expr (MatchResult can_it_fail body_fn)
 264   = MatchResult CanFail (\fail -> body_fn fail  `thenDs` \ body ->
 265                                   returnDs (mkIfThenElse pred_expr body fail))
 266
 267 mkCoPrimCaseMatchResult :: Id                           -- Scrutinee
 268                     -> Type                             -- Type of the case
 269                     -> [(Literal, MatchResult)]         -- Alternatives
 270                     -> MatchResult
 271 mkCoPrimCaseMatchResult var ty match_alts
 272   = MatchResult CanFail mk_case
 273   where
 274     mk_case fail
 275       = mappM (mk_alt fail) sorted_alts         `thenDs` \ alts ->
 276         returnDs (Case (Var var) var ty ((DEFAULT, [], fail) : alts))
 277
 278     sorted_alts = sortWith fst match_alts       -- Right order for a Case
 279     mk_alt fail (lit, MatchResult _ body_fn) = body_fn fail     `thenDs` \ body ->
 280                                                returnDs (LitAlt lit, [], body)
 281
 282
 283 mkCoAlgCaseMatchResult :: Id                                    -- Scrutinee
 284                     -> Type                                     -- Type of exp
 285                     -> [(DataCon, [CoreBndr], MatchResult)]     -- Alternatives
 286                     -> MatchResult
 287 mkCoAlgCaseMatchResult var ty match_alts
 288   | isNewTyCon tycon            -- Newtype case; use a let
 289   = ASSERT( null (tail match_alts) && null (tail arg_ids1) )
 290     mkCoLetMatchResult (NonRec arg_id1 newtype_rhs) match_result1
 291
 292   | isPArrFakeAlts match_alts   -- Sugared parallel array; use a literal case
 293   = MatchResult CanFail mk_parrCase
 294
 295   | otherwise                   -- Datatype case; use a case
 296   = MatchResult fail_flag mk_case
 297   where
 298     tycon = dataConTyCon con1
 299         -- [Interesting: becuase of GADTs, we can't rely on the type of
 300         --  the scrutinised Id to be sufficiently refined to have a TyCon in it]
 301
 302         -- Stuff for newtype
 303     (con1, arg_ids1, match_result1) = head match_alts
 304     arg_id1     = head arg_ids1
 305     newtype_rhs = mkNewTypeBody tycon (idType arg_id1) (Var var)
 306
 307         -- Stuff for data types
 308     data_cons      = tyConDataCons tycon
 309     match_results  = [match_result | (_,_,match_result) <- match_alts]
 310
 311     fail_flag | exhaustive_case
 312               = foldr1 orFail [can_it_fail | MatchResult can_it_fail _ <- match_results]
 313               | otherwise
 314               = CanFail
 315
 316     wild_var = mkWildId (idType var)
 317     sorted_alts  = sortWith get_tag match_alts
 318     get_tag (con, _, _) = dataConTag con
 319     mk_case fail = mappM (mk_alt fail) sorted_alts      `thenDs` \ alts ->
 320                    returnDs (Case (Var var) wild_var ty (mk_default fail ++ alts))
 321
 322     mk_alt fail (con, args, MatchResult _ body_fn)
 323         = body_fn fail                          `thenDs` \ body ->
 324           newUniqueSupply                       `thenDs` \ us ->
 325           returnDs (mkReboxingAlt (uniqsFromSupply us) con args body)
 326
 327     mk_default fail | exhaustive_case = []
 328                     | otherwise       = [(DEFAULT, [], fail)]
 329
 330     un_mentioned_constructors
 331         = mkUniqSet data_cons `minusUniqSet` mkUniqSet [ con | (con, _, _) <- match_alts]
 332     exhaustive_case = isEmptyUniqSet un_mentioned_constructors
 333
 334         -- Stuff for parallel arrays
 335         --
 336         --  * the following is to desugar cases over fake constructors for
 337         --   parallel arrays, which are introduced by `tidy1' in the `PArrPat'
 338         --   case
 339         --
 340         -- Concerning `isPArrFakeAlts':
 341         --
 342         --  * it is *not* sufficient to just check the type of the type
 343         --   constructor, as we have to be careful not to confuse the real
 344         --   representation of parallel arrays with the fake constructors;
 345         --   moreover, a list of alternatives must not mix fake and real
 346         --   constructors (this is checked earlier on)
 347         --
 348         -- FIXME: We actually go through the whole list and make sure that
 349         --        either all or none of the constructors are fake parallel
 350         --        array constructors.  This is to spot equations that mix fake
 351         --        constructors with the real representation defined in
 352         --        `PrelPArr'.  It would be nicer to spot this situation
 353         --        earlier and raise a proper error message, but it can really
 354         --        only happen in `PrelPArr' anyway.
 355         --
 356     isPArrFakeAlts [(dcon, _, _)]      = isPArrFakeCon dcon
 357     isPArrFakeAlts ((dcon, _, _):alts) =
 358       case (isPArrFakeCon dcon, isPArrFakeAlts alts) of
 359         (True , True ) -> True
 360         (False, False) -> False
 361         _              ->
 362           panic "DsUtils: You may not mix `[:...:]' with `PArr' patterns"
 363     --
 364     mk_parrCase fail =
 365       dsLookupGlobalId lengthPName                      `thenDs` \lengthP  ->
 366       unboxAlt                                          `thenDs` \alt      ->
 367       returnDs (Case (len lengthP) (mkWildId intTy) ty [alt])
 368       where
 369         elemTy      = case splitTyConApp (idType var) of
 370                         (_, [elemTy]) -> elemTy
 371                         _               -> panic panicMsg
 372         panicMsg    = "DsUtils.mkCoAlgCaseMatchResult: not a parallel array?"
 373         len lengthP = mkApps (Var lengthP) [Type elemTy, Var var]
 374         --
 375         unboxAlt =
 376           newSysLocalDs intPrimTy                       `thenDs` \l        ->
 377           dsLookupGlobalId indexPName                   `thenDs` \indexP   ->
 378           mappM (mkAlt indexP) sorted_alts              `thenDs` \alts     ->
 379           returnDs (DataAlt intDataCon, [l], (Case (Var l) wild ty (dft : alts)))
 380           where
 381             wild = mkWildId intPrimTy
 382             dft  = (DEFAULT, [], fail)
 383         --
 384         -- each alternative matches one array length (corresponding to one
 385         -- fake array constructor), so the match is on a literal; each
 386         -- alternative's body is extended by a local binding for each
 387         -- constructor argument, which are bound to array elements starting
 388         -- with the first
 389         --
 390         mkAlt indexP (con, args, MatchResult _ bodyFun) =
 391           bodyFun fail                                  `thenDs` \body     ->
 392           returnDs (LitAlt lit, [], mkDsLets binds body)
 393           where
 394             lit   = MachInt $ toInteger (dataConSourceArity con)
 395             binds = [NonRec arg (indexExpr i) | (i, arg) <- zip [1..] args]
 396             --
 397             indexExpr i = mkApps (Var indexP) [Type elemTy, Var var, mkIntExpr i]
 398 \end{code}
 399
 400
 401 %************************************************************************
 402 %*                                                                      *
 403 \subsection{Desugarer's versions of some Core functions}
 404 %*                                                                      *
 405 %************************************************************************
 406
 407 \begin{code}
 408 mkErrorAppDs :: Id              -- The error function
 409              -> Type            -- Type to which it should be applied
 410              -> String          -- The error message string to pass
 411              -> DsM CoreExpr
 412
 413 mkErrorAppDs err_id ty msg
 414   = getSrcSpanDs                `thenDs` \ src_loc ->
 415     let
 416         full_msg = showSDoc (hcat [ppr src_loc, text "|", text msg])
 417         core_msg = Lit (mkStringLit full_msg)
 418         -- mkStringLit returns a result of type String#
 419     in
 420     returnDs (mkApps (Var err_id) [Type ty, core_msg])
 421 \end{code}
 422
 423
 424 *************************************************************
 425 %*                                                                      *
 426 \subsection{Making literals}
 427 %*                                                                      *
 428 %************************************************************************
 429
 430 \begin{code}
 431 mkCharExpr     :: Char       -> CoreExpr      -- Returns        C# c :: Int
 432 mkIntExpr      :: Integer    -> CoreExpr      -- Returns        I# i :: Int
 433 mkIntegerExpr  :: Integer    -> DsM CoreExpr  -- Result :: Integer
 434 mkStringExpr   :: String     -> DsM CoreExpr  -- Result :: String
 435 mkStringExprFS :: FastString -> DsM CoreExpr  -- Result :: String
 436
 437 mkIntExpr  i = mkConApp intDataCon  [mkIntLit i]
 438 mkCharExpr c = mkConApp charDataCon [mkLit (MachChar c)]
 439
 440 mkIntegerExpr i
 441   | inIntRange i        -- Small enough, so start from an Int
 442   = dsLookupDataCon  smallIntegerDataConName    `thenDs` \ integer_dc ->
 443     returnDs (mkSmallIntegerLit integer_dc i)
 444
 445 -- Special case for integral literals with a large magnitude:
 446 -- They are transformed into an expression involving only smaller
 447 -- integral literals. This improves constant folding.
 448
 449   | otherwise           -- Big, so start from a string
 450   = dsLookupGlobalId plusIntegerName            `thenDs` \ plus_id ->
 451     dsLookupGlobalId timesIntegerName           `thenDs` \ times_id ->
 452     dsLookupDataCon  smallIntegerDataConName    `thenDs` \ integer_dc ->
 453     let
 454         lit i = mkSmallIntegerLit integer_dc i
 455         plus a b  = Var plus_id  `App` a `App` b
 456         times a b = Var times_id `App` a `App` b
 457
 458         -- Transform i into (x1 + (x2 + (x3 + (...) * b) * b) * b) with abs xi <= b
 459         horner :: Integer -> Integer -> CoreExpr
 460         horner b i | abs q <= 1 = if r == 0 || r == i
 461                                   then lit i
 462                                   else lit r `plus` lit (i-r)
 463                    | r == 0     =               horner b q `times` lit b
 464                    | otherwise  = lit r `plus` (horner b q `times` lit b)
 465                    where
 466                      (q,r) = i `quotRem` b
 467
 468     in
 469     returnDs (horner tARGET_MAX_INT i)
 470
 471 mkSmallIntegerLit small_integer_data_con i = mkConApp small_integer_data_con [mkIntLit i]
 472
 473 mkStringExpr str = mkStringExprFS (mkFastString str)
 474
 475 mkStringExprFS str
 476   | nullFS str
 477   = returnDs (mkNilExpr charTy)
 478
 479   | lengthFS str == 1
 480   = let
 481         the_char = mkCharExpr (headFS str)
 482     in
 483     returnDs (mkConsExpr charTy the_char (mkNilExpr charTy))
 484
 485   | all safeChar chars
 486   = dsLookupGlobalId unpackCStringName  `thenDs` \ unpack_id ->
 487     returnDs (App (Var unpack_id) (Lit (MachStr str)))
 488
 489   | otherwise
 490   = dsLookupGlobalId unpackCStringUtf8Name      `thenDs` \ unpack_id ->
 491     returnDs (App (Var unpack_id) (Lit (MachStr str)))
 492
 493   where
 494     chars = unpackFS str
 495     safeChar c = ord c >= 1 && ord c <= 0x7F
 496 \end{code}
 497
 498
 499 %************************************************************************
 500 %*                                                                      *
 501 \subsection[mkSelectorBind]{Make a selector bind}
 502 %*                                                                      *
 503 %************************************************************************
 504
 505 This is used in various places to do with lazy patterns.
 506 For each binder $b$ in the pattern, we create a binding:
 507 \begin{verbatim}
 508     b = case v of pat' -> b'
 509 \end{verbatim}
 510 where @pat'@ is @pat@ with each binder @b@ cloned into @b'@.
 511
 512 ToDo: making these bindings should really depend on whether there's
 513 much work to be done per binding.  If the pattern is complex, it
 514 should be de-mangled once, into a tuple (and then selected from).
 515 Otherwise the demangling can be in-line in the bindings (as here).
 516
 517 Boring!  Boring!  One error message per binder.  The above ToDo is
 518 even more helpful.  Something very similar happens for pattern-bound
 519 expressions.
 520
 521 \begin{code}
 522 mkSelectorBinds :: LPat Id      -- The pattern
 523                 -> CoreExpr     -- Expression to which the pattern is bound
 524                 -> DsM [(Id,CoreExpr)]
 525
 526 mkSelectorBinds (L _ (VarPat v)) val_expr
 527   = returnDs [(v, val_expr)]
 528
 529 mkSelectorBinds pat val_expr
 530   | isSingleton binders || is_simple_lpat pat
 531   =     -- Given   p = e, where p binds x,y
 532         -- we are going to make
 533         --      v = p   (where v is fresh)
 534         --      x = case v of p -> x
 535         --      y = case v of p -> x
 536
 537         -- Make up 'v'
 538         -- NB: give it the type of *pattern* p, not the type of the *rhs* e.
 539         -- This does not matter after desugaring, but there's a subtle
 540         -- issue with implicit parameters. Consider
 541         --      (x,y) = ?i
 542         -- Then, ?i is given type {?i :: Int}, a PredType, which is opaque
 543         -- to the desugarer.  (Why opaque?  Because newtypes have to be.  Why
 544         -- does it get that type?  So that when we abstract over it we get the
 545         -- right top-level type  (?i::Int) => ...)
 546         --
 547         -- So to get the type of 'v', use the pattern not the rhs.  Often more
 548         -- efficient too.
 549     newSysLocalDs (hsPatType pat)       `thenDs` \ val_var ->
 550
 551         -- For the error message we make one error-app, to avoid duplication.
 552         -- But we need it at different types... so we use coerce for that
 553     mkErrorAppDs iRREFUT_PAT_ERROR_ID
 554                  unitTy (showSDoc (ppr pat))    `thenDs` \ err_expr ->
 555     newSysLocalDs unitTy                        `thenDs` \ err_var ->
 556     mappM (mk_bind val_var err_var) binders     `thenDs` \ binds ->
 557     returnDs ( (val_var, val_expr) :
 558                (err_var, err_expr) :
 559                binds )
 560
 561
 562   | otherwise
 563   = mkErrorAppDs iRREFUT_PAT_ERROR_ID
 564                  tuple_ty (showSDoc (ppr pat))                  `thenDs` \ error_expr ->
 565     matchSimply val_expr PatBindRhs pat local_tuple error_expr  `thenDs` \ tuple_expr ->
 566     newSysLocalDs tuple_ty                                      `thenDs` \ tuple_var ->
 567     let
 568         mk_tup_bind binder
 569           = (binder, mkTupleSelector binders binder tuple_var (Var tuple_var))
 570     in
 571     returnDs ( (tuple_var, tuple_expr) : map mk_tup_bind binders )
 572   where
 573     binders     = collectPatBinders pat
 574     local_tuple = mkTupleExpr binders
 575     tuple_ty    = exprType local_tuple
 576
 577     mk_bind scrut_var err_var bndr_var
 578     -- (mk_bind sv err_var) generates
 579     --          bv = case sv of { pat -> bv; other -> coerce (type-of-bv) err_var }
 580     -- Remember, pat binds bv
 581       = matchSimply (Var scrut_var) PatBindRhs pat
 582                     (Var bndr_var) error_expr                   `thenDs` \ rhs_expr ->
 583         returnDs (bndr_var, rhs_expr)
 584       where
 585         error_expr = mkCoerce (idType bndr_var) (Var err_var)
 586
 587     is_simple_lpat p = is_simple_pat (unLoc p)
 588
 589     is_simple_pat (TuplePat ps Boxed _)    = all is_triv_lpat ps
 590     is_simple_pat (ConPatOut _ _ _ _ ps _) = all is_triv_lpat (hsConArgs ps)
 591     is_simple_pat (VarPat _)               = True
 592     is_simple_pat (ParPat p)               = is_simple_lpat p
 593     is_simple_pat other                    = False
 594
 595     is_triv_lpat p = is_triv_pat (unLoc p)
 596
 597     is_triv_pat (VarPat v)  = True
 598     is_triv_pat (WildPat _) = True
 599     is_triv_pat (ParPat p)  = is_triv_lpat p
 600     is_triv_pat other       = False
 601 \end{code}
 602
 603
 604 %************************************************************************
 605 %*                                                                      *
 606                 Tuples
 607 %*                                                                      *
 608 %************************************************************************
 609
 610 @mkTupleExpr@ builds a tuple; the inverse to @mkTupleSelector@.
 611
 612 * If it has only one element, it is the identity function.
 613
 614 * If there are more elements than a big tuple can have, it nests
 615   the tuples.
 616
 617 Nesting policy.  Better a 2-tuple of 10-tuples (3 objects) than
 618 a 10-tuple of 2-tuples (11 objects).  So we want the leaves to be big.
 619
 620 \begin{code}
 621 mkTupleExpr :: [Id] -> CoreExpr
 622 mkTupleExpr ids = mkBigCoreTup (map Var ids)
 623
 624 -- corresponding type
 625 mkTupleType :: [Id] -> Type
 626 mkTupleType ids = mkBigTuple mkCoreTupTy (map idType ids)
 627
 628 mkBigCoreTup :: [CoreExpr] -> CoreExpr
 629 mkBigCoreTup = mkBigTuple mkCoreTup
 630
 631 mkBigTuple :: ([a] -> a) -> [a] -> a
 632 mkBigTuple small_tuple as = mk_big_tuple (chunkify as)
 633   where
 634         -- Each sub-list is short enough to fit in a tuple
 635     mk_big_tuple [as] = small_tuple as
 636     mk_big_tuple as_s = mk_big_tuple (chunkify (map small_tuple as_s))
 637
 638 chunkify :: [a] -> [[a]]
 639 -- The sub-lists of the result all have length <= mAX_TUPLE_SIZE
 640 -- But there may be more than mAX_TUPLE_SIZE sub-lists
 641 chunkify xs
 642   | n_xs <= mAX_TUPLE_SIZE = {- pprTrace "Small" (ppr n_xs) -} [xs]
 643   | otherwise              = {- pprTrace "Big"   (ppr n_xs) -} (split xs)
 644   where
 645     n_xs     = length xs
 646     split [] = []
 647     split xs = take mAX_TUPLE_SIZE xs : split (drop mAX_TUPLE_SIZE xs)
 648 \end{code}
 649
 650
 651 @mkTupleSelector@ builds a selector which scrutises the given
 652 expression and extracts the one name from the list given.
 653 If you want the no-shadowing rule to apply, the caller
 654 is responsible for making sure that none of these names
 655 are in scope.
 656
 657 If there is just one id in the ``tuple'', then the selector is
 658 just the identity.
 659
 660 If it's big, it does nesting
 661         mkTupleSelector [a,b,c,d] b v e
 662           = case e of v {
 663                 (p,q) -> case p of p {
 664                            (a,b) -> b }}
 665 We use 'tpl' vars for the p,q, since shadowing does not matter.
 666
 667 In fact, it's more convenient to generate it innermost first, getting
 668
 669         case (case e of v
 670                 (p,q) -> p) of p
 671           (a,b) -> b
 672
 673 \begin{code}
 674 mkTupleSelector :: [Id]         -- The tuple args
 675                 -> Id           -- The selected one
 676                 -> Id           -- A variable of the same type as the scrutinee
 677                 -> CoreExpr     -- Scrutinee
 678                 -> CoreExpr
 679
 680 mkTupleSelector vars the_var scrut_var scrut
 681   = mk_tup_sel (chunkify vars) the_var
 682   where
 683     mk_tup_sel [vars] the_var = mkCoreSel vars the_var scrut_var scrut
 684     mk_tup_sel vars_s the_var = mkCoreSel group the_var tpl_v $
 685                                 mk_tup_sel (chunkify tpl_vs) tpl_v
 686         where
 687           tpl_tys = [mkCoreTupTy (map idType gp) | gp <- vars_s]
 688           tpl_vs  = mkTemplateLocals tpl_tys
 689           [(tpl_v, group)] = [(tpl,gp) | (tpl,gp) <- zipEqual "mkTupleSelector" tpl_vs vars_s,
 690                                          the_var `elem` gp ]
 691 \end{code}
 692
 693 A generalization of @mkTupleSelector@, allowing the body
 694 of the case to be an arbitrary expression.
 695
 696 If the tuple is big, it is nested:
 697
 698         mkTupleCase uniqs [a,b,c,d] body v e
 699           = case e of v { (p,q) ->
 700             case p of p { (a,b) ->
 701             case q of q { (c,d) ->
 702             body }}}
 703
 704 To avoid shadowing, we use uniqs to invent new variables p,q.
 705
 706 ToDo: eliminate cases where none of the variables are needed.
 707
 708 \begin{code}
 709 mkTupleCase
 710         :: UniqSupply   -- for inventing names of intermediate variables
 711         -> [Id]         -- the tuple args
 712         -> CoreExpr     -- body of the case
 713         -> Id           -- a variable of the same type as the scrutinee
 714         -> CoreExpr     -- scrutinee
 715         -> CoreExpr
 716
 717 mkTupleCase uniqs vars body scrut_var scrut
 718   = mk_tuple_case uniqs (chunkify vars) body
 719   where
 720     mk_tuple_case us [vars] body
 721       = mkSmallTupleCase vars body scrut_var scrut
 722     mk_tuple_case us vars_s body
 723       = let
 724             (us', vars', body') = foldr one_tuple_case (us, [], body) vars_s
 725         in
 726         mk_tuple_case us' (chunkify vars') body'
 727     one_tuple_case chunk_vars (us, vs, body)
 728       = let
 729             (us1, us2) = splitUniqSupply us
 730             scrut_var = mkSysLocal FSLIT("ds") (uniqFromSupply us1)
 731                         (mkCoreTupTy (map idType chunk_vars))
 732             body' = mkSmallTupleCase chunk_vars body scrut_var (Var scrut_var)
 733         in (us2, scrut_var:vs, body')
 734 \end{code}
 735
 736 The same, but with a tuple small enough not to need nesting.
 737
 738 \begin{code}
 739 mkSmallTupleCase
 740         :: [Id]         -- the tuple args
 741         -> CoreExpr     -- body of the case
 742         -> Id           -- a variable of the same type as the scrutinee
 743         -> CoreExpr     -- scrutinee
 744         -> CoreExpr
 745
 746 mkSmallTupleCase [var] body _scrut_var scrut
 747   = bindNonRec var scrut body
 748 mkSmallTupleCase vars body scrut_var scrut
 749 -- One branch no refinement?
 750   = Case scrut scrut_var (exprType body) [(DataAlt (tupleCon Boxed (length vars)), vars, body)]
 751 \end{code}
 752
 753 %************************************************************************
 754 %*                                                                      *
 755 \subsection[mkFailurePair]{Code for pattern-matching and other failures}
 756 %*                                                                      *
 757 %************************************************************************
 758
 759 Call the constructor Ids when building explicit lists, so that they
 760 interact well with rules.
 761
 762 \begin{code}
 763 mkNilExpr :: Type -> CoreExpr
 764 mkNilExpr ty = mkConApp nilDataCon [Type ty]
 765
 766 mkConsExpr :: Type -> CoreExpr -> CoreExpr -> CoreExpr
 767 mkConsExpr ty hd tl = mkConApp consDataCon [Type ty, hd, tl]
 768
 769 mkListExpr :: Type -> [CoreExpr] -> CoreExpr
 770 mkListExpr ty xs = foldr (mkConsExpr ty) (mkNilExpr ty) xs
 771
 772
 773 -- The next three functions make tuple types, constructors and selectors,
 774 -- with the rule that a 1-tuple is represented by the thing itselg
 775 mkCoreTupTy :: [Type] -> Type
 776 mkCoreTupTy [ty] = ty
 777 mkCoreTupTy tys  = mkTupleTy Boxed (length tys) tys
 778
 779 mkCoreTup :: [CoreExpr] -> CoreExpr
 780 -- Builds exactly the specified tuple.
 781 -- No fancy business for big tuples
 782 mkCoreTup []  = Var unitDataConId
 783 mkCoreTup [c] = c
 784 mkCoreTup cs  = mkConApp (tupleCon Boxed (length cs))
 785                          (map (Type . exprType) cs ++ cs)
 786
 787 mkCoreSel :: [Id]       -- The tuple args
 788           -> Id         -- The selected one
 789           -> Id         -- A variable of the same type as the scrutinee
 790           -> CoreExpr   -- Scrutinee
 791           -> CoreExpr
 792 -- mkCoreSel [x,y,z] x v e
 793 -- ===>  case e of v { (x,y,z) -> x
 794 mkCoreSel [var] should_be_the_same_var scrut_var scrut
 795   = ASSERT(var == should_be_the_same_var)
 796     scrut
 797
 798 mkCoreSel vars the_var scrut_var scrut
 799   = ASSERT( notNull vars )
 800     Case scrut scrut_var (idType the_var)
 801          [(DataAlt (tupleCon Boxed (length vars)), vars, Var the_var)]
 802 \end{code}
 803
 804
 805 %************************************************************************
 806 %*                                                                      *
 807 \subsection[mkFailurePair]{Code for pattern-matching and other failures}
 808 %*                                                                      *
 809 %************************************************************************
 810
 811 Generally, we handle pattern matching failure like this: let-bind a
 812 fail-variable, and use that variable if the thing fails:
 813 \begin{verbatim}
 814         let fail.33 = error "Help"
 815         in
 816         case x of
 817                 p1 -> ...
 818                 p2 -> fail.33
 819                 p3 -> fail.33
 820                 p4 -> ...
 821 \end{verbatim}
 822 Then
 823 \begin{itemize}
 824 \item
 825 If the case can't fail, then there'll be no mention of @fail.33@, and the
 826 simplifier will later discard it.
 827
 828 \item
 829 If it can fail in only one way, then the simplifier will inline it.
 830
 831 \item
 832 Only if it is used more than once will the let-binding remain.
 833 \end{itemize}
 834
 835 There's a problem when the result of the case expression is of
 836 unboxed type.  Then the type of @fail.33@ is unboxed too, and
 837 there is every chance that someone will change the let into a case:
 838 \begin{verbatim}
 839         case error "Help" of
 840           fail.33 -> case ....
 841 \end{verbatim}
 842
 843 which is of course utterly wrong.  Rather than drop the condition that
 844 only boxed types can be let-bound, we just turn the fail into a function
 845 for the primitive case:
 846 \begin{verbatim}
 847         let fail.33 :: Void -> Int#
 848             fail.33 = \_ -> error "Help"
 849         in
 850         case x of
 851                 p1 -> ...
 852                 p2 -> fail.33 void
 853                 p3 -> fail.33 void
 854                 p4 -> ...
 855 \end{verbatim}
 856
 857 Now @fail.33@ is a function, so it can be let-bound.
 858
 859 \begin{code}
 860 mkFailurePair :: CoreExpr       -- Result type of the whole case expression
 861               -> DsM (CoreBind, -- Binds the newly-created fail variable
 862                                 -- to either the expression or \ _ -> expression
 863                       CoreExpr) -- Either the fail variable, or fail variable
 864                                 -- applied to unit tuple
 865 mkFailurePair expr
 866   | isUnLiftedType ty
 867   = newFailLocalDs (unitTy `mkFunTy` ty)        `thenDs` \ fail_fun_var ->
 868     newSysLocalDs unitTy                        `thenDs` \ fail_fun_arg ->
 869     returnDs (NonRec fail_fun_var (Lam fail_fun_arg expr),
 870               App (Var fail_fun_var) (Var unitDataConId))
 871
 872   | otherwise
 873   = newFailLocalDs ty           `thenDs` \ fail_var ->
 874     returnDs (NonRec fail_var expr, Var fail_var)
 875   where
 876     ty = exprType expr
 877 \end{code}
 878
 879