ghc/compiler/deSugar/DsUtils.lhs

   1 %
   2 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   3 %
   4 \section[DsUtils]{Utilities for desugaring}
   5
   6 This module exports some utility functions of no great interest.
   7
   8 \begin{code}
   9 module DsUtils (
  10         EquationInfo(..),
  11         firstPat, shiftEqns,
  12
  13         mkDsLet,
  14
  15         MatchResult(..), CanItFail(..),
  16         cantFailMatchResult, alwaysFailMatchResult,
  17         extractMatchResult, combineMatchResults,
  18         adjustMatchResult,  adjustMatchResultDs,
  19         mkCoLetsMatchResult, mkCoLetMatchResult,
  20         mkGuardedMatchResult,
  21         mkCoPrimCaseMatchResult, mkCoAlgCaseMatchResult,
  22         bindInMatchResult, bindOneInMatchResult,
  23
  24         mkErrorAppDs, mkNilExpr, mkConsExpr, mkListExpr,
  25         mkIntExpr, mkCharExpr,
  26         mkStringExpr, mkStringExprFS, mkIntegerExpr,
  27
  28         mkSelectorBinds, mkTupleExpr, mkTupleSelector,
  29         mkTupleType, mkTupleCase, mkBigCoreTup,
  30         mkCoreTup, mkCoreTupTy,
  31
  32         dsReboundNames, lookupReboundName,
  33
  34         selectSimpleMatchVarL, selectMatchVars
  35     ) where
  36
  37 #include "HsVersions.h"
  38
  39 import {-# SOURCE #-}   Match ( matchSimply )
  40 import {-# SOURCE #-}   DsExpr( dsExpr )
  41
  42 import HsSyn
  43 import TcHsSyn          ( hsPatType )
  44 import CoreSyn
  45 import Constants        ( mAX_TUPLE_SIZE )
  46 import DsMonad
  47
  48 import CoreUtils        ( exprType, mkIfThenElse, mkCoerce, bindNonRec )
  49 import MkId             ( iRREFUT_PAT_ERROR_ID, mkReboxingAlt, mkNewTypeBody )
  50 import Id               ( idType, Id, mkWildId, mkTemplateLocals, mkSysLocal )
  51 import Var              ( Var )
  52 import Name             ( Name )
  53 import Literal          ( Literal(..), mkStringLit, inIntRange, tARGET_MAX_INT )
  54 import TyCon            ( isNewTyCon, tyConDataCons )
  55 import DataCon          ( DataCon, dataConSourceArity, dataConTyCon, dataConTag )
  56 import Type             ( mkFunTy, isUnLiftedType, Type, splitTyConApp, mkTyVarTy )
  57 import TcType           ( tcEqType )
  58 import TysPrim          ( intPrimTy )
  59 import TysWiredIn       ( nilDataCon, consDataCon,
  60                           tupleCon, mkTupleTy,
  61                           unitDataConId, unitTy,
  62                           charTy, charDataCon,
  63                           intTy, intDataCon,
  64                           isPArrFakeCon )
  65 import BasicTypes       ( Boxity(..) )
  66 import UniqSet          ( mkUniqSet, minusUniqSet, isEmptyUniqSet )
  67 import UniqSupply       ( splitUniqSupply, uniqFromSupply, uniqsFromSupply )
  68 import PrelNames        ( unpackCStringName, unpackCStringUtf8Name,
  69                           plusIntegerName, timesIntegerName, smallIntegerDataConName,
  70                           lengthPName, indexPName )
  71 import Outputable
  72 import UnicodeUtil      ( intsToUtf8 )
  73 import SrcLoc           ( Located(..), unLoc )
  74 import Util             ( isSingleton, notNull, zipEqual, sortWith )
  75 import ListSetOps       ( assocDefault )
  76 import FastString
  77 \end{code}
  78
  79
  80
  81 %************************************************************************
  82 %*                                                                      *
  83                 Rebindable syntax
  84 %*                                                                      *
  85 %************************************************************************
  86
  87 \begin{code}
  88 dsReboundNames :: ReboundNames Id
  89                -> DsM ([CoreBind],      -- Auxiliary bindings
  90                        [(Name,Id)])     -- Maps the standard name to its value
  91
  92 dsReboundNames rebound_ids
  93   = mapAndUnzipDs mk_bind rebound_ids   `thenDs` \ (binds_s, prs) ->
  94     return (concat binds_s, prs)
  95   where
  96         -- The cheapo special case can happen when we
  97         -- make an intermediate HsDo when desugaring a RecStmt
  98     mk_bind (std_name, HsVar id) = return ([], (std_name, id))
  99     mk_bind (std_name, expr)
 100          = dsExpr expr                          `thenDs` \ rhs ->
 101            newSysLocalDs (exprType rhs)         `thenDs` \ id ->
 102            return ([NonRec id rhs], (std_name, id))
 103
 104 lookupReboundName :: [(Name,Id)] -> Name -> CoreExpr
 105 lookupReboundName prs std_name
 106   = Var (assocDefault (mk_panic std_name) prs std_name)
 107   where
 108     mk_panic std_name = pprPanic "dsReboundNames" (ptext SLIT("Not found:") <+> ppr std_name)
 109 \end{code}
 110
 111
 112 %************************************************************************
 113 %*                                                                      *
 114 \subsection{Building lets}
 115 %*                                                                      *
 116 %************************************************************************
 117
 118 Use case, not let for unlifted types.  The simplifier will turn some
 119 back again.
 120
 121 \begin{code}
 122 mkDsLet :: CoreBind -> CoreExpr -> CoreExpr
 123 mkDsLet (NonRec bndr rhs) body
 124   | isUnLiftedType (idType bndr)
 125   = Case rhs bndr (exprType body) [(DEFAULT,[],body)]
 126 mkDsLet bind body
 127   = Let bind body
 128
 129 mkDsLets :: [CoreBind] -> CoreExpr -> CoreExpr
 130 mkDsLets binds body = foldr mkDsLet body binds
 131 \end{code}
 132
 133
 134 %************************************************************************
 135 %*                                                                      *
 136 \subsection{ Selecting match variables}
 137 %*                                                                      *
 138 %************************************************************************
 139
 140 We're about to match against some patterns.  We want to make some
 141 @Ids@ to use as match variables.  If a pattern has an @Id@ readily at
 142 hand, which should indeed be bound to the pattern as a whole, then use it;
 143 otherwise, make one up.
 144
 145 \begin{code}
 146 selectSimpleMatchVarL :: LPat Id -> DsM Id
 147 selectSimpleMatchVarL pat = selectMatchVar (unLoc pat) (hsPatType pat)
 148
 149 -- (selectMatchVars ps tys) chooses variables of type tys
 150 -- to use for matching ps against.  If the pattern is a variable,
 151 -- we try to use that, to save inventing lots of fresh variables.
 152 -- But even if it is a variable, its type might not match.  Consider
 153 --      data T a where
 154 --        T1 :: Int -> T Int
 155 --        T2 :: a   -> T a
 156 --
 157 --      f :: T a -> a -> Int
 158 --      f (T1 i) (x::Int) = x
 159 --      f (T2 i) (y::a)   = 0
 160 -- Then we must not choose (x::Int) as the matching variable!
 161
 162 selectMatchVars :: [Pat Id] -> [Type] -> DsM [Id]
 163 selectMatchVars []     []       = return []
 164 selectMatchVars (p:ps) (ty:tys) = do { v  <- selectMatchVar  p  ty
 165                                      ; vs <- selectMatchVars ps tys
 166                                      ; return (v:vs) }
 167
 168 selectMatchVar (LazyPat pat)   pat_ty  = selectMatchVar (unLoc pat) pat_ty
 169 selectMatchVar (VarPat var)    pat_ty  = try_for var         pat_ty
 170 selectMatchVar (AsPat var pat) pat_ty  = try_for (unLoc var) pat_ty
 171 selectMatchVar other_pat       pat_ty  = newSysLocalDs pat_ty   -- OK, better make up one...
 172
 173 try_for var pat_ty
 174   | idType var `tcEqType` pat_ty = returnDs var
 175   | otherwise                    = newSysLocalDs pat_ty
 176 \end{code}
 177
 178
 179 %************************************************************************
 180 %*                                                                      *
 181 %* type synonym EquationInfo and access functions for its pieces        *
 182 %*                                                                      *
 183 %************************************************************************
 184 \subsection[EquationInfo-synonym]{@EquationInfo@: a useful synonym}
 185
 186 The ``equation info'' used by @match@ is relatively complicated and
 187 worthy of a type synonym and a few handy functions.
 188
 189 \begin{code}
 190 firstPat :: EquationInfo -> Pat Id
 191 firstPat eqn = head (eqn_pats eqn)
 192
 193 shiftEqns :: [EquationInfo] -> [EquationInfo]
 194 -- Drop the outermost layer of the first pattern in each equation
 195 shiftEqns eqns = [ eqn { eqn_pats = shiftPats (eqn_pats eqn) }
 196                  | eqn <- eqns ]
 197
 198 shiftPats :: [Pat Id] -> [Pat Id]
 199 shiftPats (ConPatOut _ _ _ _ (PrefixCon arg_pats) _ : pats) = map unLoc arg_pats ++ pats
 200 shiftPats (pat_with_no_sub_pats                     : pats) = pats
 201 \end{code}
 202
 203 Functions on MatchResults
 204
 205 \begin{code}
 206 alwaysFailMatchResult :: MatchResult
 207 alwaysFailMatchResult = MatchResult CanFail (\fail -> returnDs fail)
 208
 209 cantFailMatchResult :: CoreExpr -> MatchResult
 210 cantFailMatchResult expr = MatchResult CantFail (\ ignore -> returnDs expr)
 211
 212 extractMatchResult :: MatchResult -> CoreExpr -> DsM CoreExpr
 213 extractMatchResult (MatchResult CantFail match_fn) fail_expr
 214   = match_fn (error "It can't fail!")
 215
 216 extractMatchResult (MatchResult CanFail match_fn) fail_expr
 217   = mkFailurePair fail_expr             `thenDs` \ (fail_bind, if_it_fails) ->
 218     match_fn if_it_fails                `thenDs` \ body ->
 219     returnDs (mkDsLet fail_bind body)
 220
 221
 222 combineMatchResults :: MatchResult -> MatchResult -> MatchResult
 223 combineMatchResults (MatchResult CanFail      body_fn1)
 224                     (MatchResult can_it_fail2 body_fn2)
 225   = MatchResult can_it_fail2 body_fn
 226   where
 227     body_fn fail = body_fn2 fail                        `thenDs` \ body2 ->
 228                    mkFailurePair body2                  `thenDs` \ (fail_bind, duplicatable_expr) ->
 229                    body_fn1 duplicatable_expr           `thenDs` \ body1 ->
 230                    returnDs (Let fail_bind body1)
 231
 232 combineMatchResults match_result1@(MatchResult CantFail body_fn1) match_result2
 233   = match_result1
 234
 235 adjustMatchResult :: (CoreExpr -> CoreExpr) -> MatchResult -> MatchResult
 236 adjustMatchResult encl_fn (MatchResult can_it_fail body_fn)
 237   = MatchResult can_it_fail (\fail -> body_fn fail      `thenDs` \ body ->
 238                                       returnDs (encl_fn body))
 239
 240 adjustMatchResultDs :: (CoreExpr -> DsM CoreExpr) -> MatchResult -> MatchResult
 241 adjustMatchResultDs encl_fn (MatchResult can_it_fail body_fn)
 242   = MatchResult can_it_fail (\fail -> body_fn fail      `thenDs` \ body ->
 243                                       encl_fn body)
 244
 245 bindInMatchResult :: [(Var,Var)] -> MatchResult -> MatchResult
 246 bindInMatchResult binds = adjustMatchResult (\e -> foldr bind e binds)
 247   where
 248     bind (new,old) body = bindMR new old body
 249
 250 bindOneInMatchResult :: Var -> Var -> MatchResult -> MatchResult
 251 bindOneInMatchResult new old = adjustMatchResult (bindMR new old)
 252
 253 bindMR :: Var -> Var -> CoreExpr -> CoreExpr
 254 bindMR new old body
 255   | new==old    = body
 256   | isTyVar new = App (Lam new body) (Type (mkTyVarTy old))
 257   | otherwise   = Let (NonRec new (Var old)) body
 258
 259 mkCoLetsMatchResult :: [CoreBind] -> MatchResult -> MatchResult
 260 mkCoLetsMatchResult binds match_result
 261   = adjustMatchResult (mkDsLets binds) match_result
 262
 263 mkCoLetMatchResult :: CoreBind -> MatchResult -> MatchResult
 264 mkCoLetMatchResult bind match_result
 265   = adjustMatchResult (mkDsLet bind) match_result
 266
 267 mkGuardedMatchResult :: CoreExpr -> MatchResult -> MatchResult
 268 mkGuardedMatchResult pred_expr (MatchResult can_it_fail body_fn)
 269   = MatchResult CanFail (\fail -> body_fn fail  `thenDs` \ body ->
 270                                   returnDs (mkIfThenElse pred_expr body fail))
 271
 272 mkCoPrimCaseMatchResult :: Id                           -- Scrutinee
 273                     -> Type                             -- Type of the case
 274                     -> [(Literal, MatchResult)]         -- Alternatives
 275                     -> MatchResult
 276 mkCoPrimCaseMatchResult var ty match_alts
 277   = MatchResult CanFail mk_case
 278   where
 279     mk_case fail
 280       = mappM (mk_alt fail) sorted_alts         `thenDs` \ alts ->
 281         returnDs (Case (Var var) var ty ((DEFAULT, [], fail) : alts))
 282
 283     sorted_alts = sortWith fst match_alts       -- Right order for a Case
 284     mk_alt fail (lit, MatchResult _ body_fn) = body_fn fail     `thenDs` \ body ->
 285                                                returnDs (LitAlt lit, [], body)
 286
 287
 288 mkCoAlgCaseMatchResult :: Id                                    -- Scrutinee
 289                     -> Type                                     -- Type of exp
 290                     -> [(DataCon, [CoreBndr], MatchResult)]     -- Alternatives
 291                     -> MatchResult
 292 mkCoAlgCaseMatchResult var ty match_alts
 293   | isNewTyCon tycon            -- Newtype case; use a let
 294   = ASSERT( null (tail match_alts) && null (tail arg_ids1) )
 295     mkCoLetsMatchResult [NonRec arg_id1 newtype_rhs] match_result1
 296
 297   | isPArrFakeAlts match_alts   -- Sugared parallel array; use a literal case
 298   = MatchResult CanFail mk_parrCase
 299
 300   | otherwise                   -- Datatype case; use a case
 301   = MatchResult fail_flag mk_case
 302   where
 303     tycon = dataConTyCon con1
 304         -- [Interesting: becuase of GADTs, we can't rely on the type of
 305         --  the scrutinised Id to be sufficiently refined to have a TyCon in it]
 306
 307         -- Stuff for newtype
 308     (con1, arg_ids1, match_result1) = head match_alts
 309     arg_id1     = head arg_ids1
 310     newtype_rhs = mkNewTypeBody tycon (idType arg_id1) (Var var)
 311
 312         -- Stuff for data types
 313     data_cons      = tyConDataCons tycon
 314     match_results  = [match_result | (_,_,match_result) <- match_alts]
 315
 316     fail_flag | exhaustive_case
 317               = foldr1 orFail [can_it_fail | MatchResult can_it_fail _ <- match_results]
 318               | otherwise
 319               = CanFail
 320
 321     wild_var = mkWildId (idType var)
 322     sorted_alts  = sortWith get_tag match_alts
 323     get_tag (con, _, _) = dataConTag con
 324     mk_case fail = mappM (mk_alt fail) sorted_alts      `thenDs` \ alts ->
 325                    returnDs (Case (Var var) wild_var ty (mk_default fail ++ alts))
 326
 327     mk_alt fail (con, args, MatchResult _ body_fn)
 328         = body_fn fail                          `thenDs` \ body ->
 329           newUniqueSupply                       `thenDs` \ us ->
 330           returnDs (mkReboxingAlt (uniqsFromSupply us) con args body)
 331
 332     mk_default fail | exhaustive_case = []
 333                     | otherwise       = [(DEFAULT, [], fail)]
 334
 335     un_mentioned_constructors
 336         = mkUniqSet data_cons `minusUniqSet` mkUniqSet [ con | (con, _, _) <- match_alts]
 337     exhaustive_case = isEmptyUniqSet un_mentioned_constructors
 338
 339         -- Stuff for parallel arrays
 340         --
 341         -- * the following is to desugar cases over fake constructors for
 342         --   parallel arrays, which are introduced by `tidy1' in the `PArrPat'
 343         --   case
 344         --
 345         -- Concerning `isPArrFakeAlts':
 346         --
 347         -- * it is *not* sufficient to just check the type of the type
 348         --   constructor, as we have to be careful not to confuse the real
 349         --   representation of parallel arrays with the fake constructors;
 350         --   moreover, a list of alternatives must not mix fake and real
 351         --   constructors (this is checked earlier on)
 352         --
 353         -- FIXME: We actually go through the whole list and make sure that
 354         --        either all or none of the constructors are fake parallel
 355         --        array constructors.  This is to spot equations that mix fake
 356         --        constructors with the real representation defined in
 357         --        `PrelPArr'.  It would be nicer to spot this situation
 358         --        earlier and raise a proper error message, but it can really
 359         --        only happen in `PrelPArr' anyway.
 360         --
 361     isPArrFakeAlts [(dcon, _, _)]      = isPArrFakeCon dcon
 362     isPArrFakeAlts ((dcon, _, _):alts) =
 363       case (isPArrFakeCon dcon, isPArrFakeAlts alts) of
 364         (True , True ) -> True
 365         (False, False) -> False
 366         _              ->
 367           panic "DsUtils: You may not mix `[:...:]' with `PArr' patterns"
 368     --
 369     mk_parrCase fail =
 370       dsLookupGlobalId lengthPName                      `thenDs` \lengthP  ->
 371       unboxAlt                                          `thenDs` \alt      ->
 372       returnDs (Case (len lengthP) (mkWildId intTy) ty [alt])
 373       where
 374         elemTy      = case splitTyConApp (idType var) of
 375                         (_, [elemTy]) -> elemTy
 376                         _               -> panic panicMsg
 377         panicMsg    = "DsUtils.mkCoAlgCaseMatchResult: not a parallel array?"
 378         len lengthP = mkApps (Var lengthP) [Type elemTy, Var var]
 379         --
 380         unboxAlt =
 381           newSysLocalDs intPrimTy                       `thenDs` \l        ->
 382           dsLookupGlobalId indexPName                   `thenDs` \indexP   ->
 383           mappM (mkAlt indexP) sorted_alts              `thenDs` \alts     ->
 384           returnDs (DataAlt intDataCon, [l], (Case (Var l) wild ty (dft : alts)))
 385           where
 386             wild = mkWildId intPrimTy
 387             dft  = (DEFAULT, [], fail)
 388         --
 389         -- each alternative matches one array length (corresponding to one
 390         -- fake array constructor), so the match is on a literal; each
 391         -- alternative's body is extended by a local binding for each
 392         -- constructor argument, which are bound to array elements starting
 393         -- with the first
 394         --
 395         mkAlt indexP (con, args, MatchResult _ bodyFun) =
 396           bodyFun fail                                  `thenDs` \body     ->
 397           returnDs (LitAlt lit, [], mkDsLets binds body)
 398           where
 399             lit   = MachInt $ toInteger (dataConSourceArity con)
 400             binds = [NonRec arg (indexExpr i) | (i, arg) <- zip [1..] args]
 401             --
 402             indexExpr i = mkApps (Var indexP) [Type elemTy, Var var, mkIntExpr i]
 403 \end{code}
 404
 405
 406 %************************************************************************
 407 %*                                                                      *
 408 \subsection{Desugarer's versions of some Core functions}
 409 %*                                                                      *
 410 %************************************************************************
 411
 412 \begin{code}
 413 mkErrorAppDs :: Id              -- The error function
 414              -> Type            -- Type to which it should be applied
 415              -> String          -- The error message string to pass
 416              -> DsM CoreExpr
 417
 418 mkErrorAppDs err_id ty msg
 419   = getSrcSpanDs                `thenDs` \ src_loc ->
 420     let
 421         full_msg = showSDoc (hcat [ppr src_loc, text "|", text msg])
 422         core_msg = Lit (mkStringLit full_msg)
 423     in
 424     returnDs (mkApps (Var err_id) [Type ty, core_msg])
 425 \end{code}
 426
 427
 428 *************************************************************
 429 %*                                                                      *
 430 \subsection{Making literals}
 431 %*                                                                      *
 432 %************************************************************************
 433
 434 \begin{code}
 435 mkCharExpr     :: Char       -> CoreExpr      -- Returns        C# c :: Int
 436 mkIntExpr      :: Integer    -> CoreExpr      -- Returns        I# i :: Int
 437 mkIntegerExpr  :: Integer    -> DsM CoreExpr  -- Result :: Integer
 438 mkStringExpr   :: String     -> DsM CoreExpr  -- Result :: String
 439 mkStringExprFS :: FastString -> DsM CoreExpr  -- Result :: String
 440
 441 mkIntExpr  i = mkConApp intDataCon  [mkIntLit i]
 442 mkCharExpr c = mkConApp charDataCon [mkLit (MachChar c)]
 443
 444 mkIntegerExpr i
 445   | inIntRange i        -- Small enough, so start from an Int
 446   = dsLookupDataCon  smallIntegerDataConName    `thenDs` \ integer_dc ->
 447     returnDs (mkSmallIntegerLit integer_dc i)
 448
 449 -- Special case for integral literals with a large magnitude:
 450 -- They are transformed into an expression involving only smaller
 451 -- integral literals. This improves constant folding.
 452
 453   | otherwise           -- Big, so start from a string
 454   = dsLookupGlobalId plusIntegerName            `thenDs` \ plus_id ->
 455     dsLookupGlobalId timesIntegerName           `thenDs` \ times_id ->
 456     dsLookupDataCon  smallIntegerDataConName    `thenDs` \ integer_dc ->
 457     let
 458         lit i = mkSmallIntegerLit integer_dc i
 459         plus a b  = Var plus_id  `App` a `App` b
 460         times a b = Var times_id `App` a `App` b
 461
 462         -- Transform i into (x1 + (x2 + (x3 + (...) * b) * b) * b) with abs xi <= b
 463         horner :: Integer -> Integer -> CoreExpr
 464         horner b i | abs q <= 1 = if r == 0 || r == i
 465                                   then lit i
 466                                   else lit r `plus` lit (i-r)
 467                    | r == 0     =               horner b q `times` lit b
 468                    | otherwise  = lit r `plus` (horner b q `times` lit b)
 469                    where
 470                      (q,r) = i `quotRem` b
 471
 472     in
 473     returnDs (horner tARGET_MAX_INT i)
 474
 475 mkSmallIntegerLit small_integer_data_con i = mkConApp small_integer_data_con [mkIntLit i]
 476
 477 mkStringExpr str = mkStringExprFS (mkFastString str)
 478
 479 mkStringExprFS str
 480   | nullFastString str
 481   = returnDs (mkNilExpr charTy)
 482
 483   | lengthFS str == 1
 484   = let
 485         the_char = mkCharExpr (headFS str)
 486     in
 487     returnDs (mkConsExpr charTy the_char (mkNilExpr charTy))
 488
 489   | all safeChar int_chars
 490   = dsLookupGlobalId unpackCStringName  `thenDs` \ unpack_id ->
 491     returnDs (App (Var unpack_id) (Lit (MachStr str)))
 492
 493   | otherwise
 494   = dsLookupGlobalId unpackCStringUtf8Name      `thenDs` \ unpack_id ->
 495     returnDs (App (Var unpack_id) (Lit (MachStr (mkFastString (intsToUtf8 int_chars)))))
 496
 497   where
 498     int_chars = unpackIntFS str
 499     safeChar c = c >= 1 && c <= 0xFF
 500 \end{code}
 501
 502
 503 %************************************************************************
 504 %*                                                                      *
 505 \subsection[mkSelectorBind]{Make a selector bind}
 506 %*                                                                      *
 507 %************************************************************************
 508
 509 This is used in various places to do with lazy patterns.
 510 For each binder $b$ in the pattern, we create a binding:
 511 \begin{verbatim}
 512     b = case v of pat' -> b'
 513 \end{verbatim}
 514 where @pat'@ is @pat@ with each binder @b@ cloned into @b'@.
 515
 516 ToDo: making these bindings should really depend on whether there's
 517 much work to be done per binding.  If the pattern is complex, it
 518 should be de-mangled once, into a tuple (and then selected from).
 519 Otherwise the demangling can be in-line in the bindings (as here).
 520
 521 Boring!  Boring!  One error message per binder.  The above ToDo is
 522 even more helpful.  Something very similar happens for pattern-bound
 523 expressions.
 524
 525 \begin{code}
 526 mkSelectorBinds :: LPat Id      -- The pattern
 527                 -> CoreExpr     -- Expression to which the pattern is bound
 528                 -> DsM [(Id,CoreExpr)]
 529
 530 mkSelectorBinds (L _ (VarPat v)) val_expr
 531   = returnDs [(v, val_expr)]
 532
 533 mkSelectorBinds pat val_expr
 534   | isSingleton binders || is_simple_lpat pat
 535   =     -- Given   p = e, where p binds x,y
 536         -- we are going to make
 537         --      v = p   (where v is fresh)
 538         --      x = case v of p -> x
 539         --      y = case v of p -> x
 540
 541         -- Make up 'v'
 542         -- NB: give it the type of *pattern* p, not the type of the *rhs* e.
 543         -- This does not matter after desugaring, but there's a subtle
 544         -- issue with implicit parameters. Consider
 545         --      (x,y) = ?i
 546         -- Then, ?i is given type {?i :: Int}, a PredType, which is opaque
 547         -- to the desugarer.  (Why opaque?  Because newtypes have to be.  Why
 548         -- does it get that type?  So that when we abstract over it we get the
 549         -- right top-level type  (?i::Int) => ...)
 550         --
 551         -- So to get the type of 'v', use the pattern not the rhs.  Often more
 552         -- efficient too.
 553     newSysLocalDs (hsPatType pat)       `thenDs` \ val_var ->
 554
 555         -- For the error message we make one error-app, to avoid duplication.
 556         -- But we need it at different types... so we use coerce for that
 557     mkErrorAppDs iRREFUT_PAT_ERROR_ID
 558                  unitTy (showSDoc (ppr pat))    `thenDs` \ err_expr ->
 559     newSysLocalDs unitTy                        `thenDs` \ err_var ->
 560     mappM (mk_bind val_var err_var) binders     `thenDs` \ binds ->
 561     returnDs ( (val_var, val_expr) :
 562                (err_var, err_expr) :
 563                binds )
 564
 565
 566   | otherwise
 567   = mkErrorAppDs iRREFUT_PAT_ERROR_ID
 568                  tuple_ty (showSDoc (ppr pat))                  `thenDs` \ error_expr ->
 569     matchSimply val_expr PatBindRhs pat local_tuple error_expr  `thenDs` \ tuple_expr ->
 570     newSysLocalDs tuple_ty                                      `thenDs` \ tuple_var ->
 571     let
 572         mk_tup_bind binder
 573           = (binder, mkTupleSelector binders binder tuple_var (Var tuple_var))
 574     in
 575     returnDs ( (tuple_var, tuple_expr) : map mk_tup_bind binders )
 576   where
 577     binders     = collectPatBinders pat
 578     local_tuple = mkTupleExpr binders
 579     tuple_ty    = exprType local_tuple
 580
 581     mk_bind scrut_var err_var bndr_var
 582     -- (mk_bind sv err_var) generates
 583     --          bv = case sv of { pat -> bv; other -> coerce (type-of-bv) err_var }
 584     -- Remember, pat binds bv
 585       = matchSimply (Var scrut_var) PatBindRhs pat
 586                     (Var bndr_var) error_expr                   `thenDs` \ rhs_expr ->
 587         returnDs (bndr_var, rhs_expr)
 588       where
 589         error_expr = mkCoerce (idType bndr_var) (Var err_var)
 590
 591     is_simple_lpat p = is_simple_pat (unLoc p)
 592
 593     is_simple_pat (TuplePat ps Boxed)      = all is_triv_lpat ps
 594     is_simple_pat (ConPatOut _ _ _ _ ps _) = all is_triv_lpat (hsConArgs ps)
 595     is_simple_pat (VarPat _)               = True
 596     is_simple_pat (ParPat p)               = is_simple_lpat p
 597     is_simple_pat other                    = False
 598
 599     is_triv_lpat p = is_triv_pat (unLoc p)
 600
 601     is_triv_pat (VarPat v)  = True
 602     is_triv_pat (WildPat _) = True
 603     is_triv_pat (ParPat p)  = is_triv_lpat p
 604     is_triv_pat other       = False
 605 \end{code}
 606
 607
 608 %************************************************************************
 609 %*                                                                      *
 610                 Tuples
 611 %*                                                                      *
 612 %************************************************************************
 613
 614 @mkTupleExpr@ builds a tuple; the inverse to @mkTupleSelector@.
 615
 616 * If it has only one element, it is the identity function.
 617
 618 * If there are more elements than a big tuple can have, it nests
 619   the tuples.
 620
 621 Nesting policy.  Better a 2-tuple of 10-tuples (3 objects) than
 622 a 10-tuple of 2-tuples (11 objects).  So we want the leaves to be big.
 623
 624 \begin{code}
 625 mkTupleExpr :: [Id] -> CoreExpr
 626 mkTupleExpr ids = mkBigCoreTup (map Var ids)
 627
 628 -- corresponding type
 629 mkTupleType :: [Id] -> Type
 630 mkTupleType ids = mkBigTuple mkCoreTupTy (map idType ids)
 631
 632 mkBigCoreTup :: [CoreExpr] -> CoreExpr
 633 mkBigCoreTup = mkBigTuple mkCoreTup
 634
 635 mkBigTuple :: ([a] -> a) -> [a] -> a
 636 mkBigTuple small_tuple as = mk_big_tuple (chunkify as)
 637   where
 638         -- Each sub-list is short enough to fit in a tuple
 639     mk_big_tuple [as] = small_tuple as
 640     mk_big_tuple as_s = mk_big_tuple (chunkify (map small_tuple as_s))
 641
 642 chunkify :: [a] -> [[a]]
 643 -- The sub-lists of the result all have length <= mAX_TUPLE_SIZE
 644 -- But there may be more than mAX_TUPLE_SIZE sub-lists
 645 chunkify xs
 646   | n_xs <= mAX_TUPLE_SIZE = {- pprTrace "Small" (ppr n_xs) -} [xs]
 647   | otherwise              = {- pprTrace "Big"   (ppr n_xs) -} (split xs)
 648   where
 649     n_xs     = length xs
 650     split [] = []
 651     split xs = take mAX_TUPLE_SIZE xs : split (drop mAX_TUPLE_SIZE xs)
 652 \end{code}
 653
 654
 655 @mkTupleSelector@ builds a selector which scrutises the given
 656 expression and extracts the one name from the list given.
 657 If you want the no-shadowing rule to apply, the caller
 658 is responsible for making sure that none of these names
 659 are in scope.
 660
 661 If there is just one id in the ``tuple'', then the selector is
 662 just the identity.
 663
 664 If it's big, it does nesting
 665         mkTupleSelector [a,b,c,d] b v e
 666           = case e of v {
 667                 (p,q) -> case p of p {
 668                            (a,b) -> b }}
 669 We use 'tpl' vars for the p,q, since shadowing does not matter.
 670
 671 In fact, it's more convenient to generate it innermost first, getting
 672
 673         case (case e of v
 674                 (p,q) -> p) of p
 675           (a,b) -> b
 676
 677 \begin{code}
 678 mkTupleSelector :: [Id]         -- The tuple args
 679                 -> Id           -- The selected one
 680                 -> Id           -- A variable of the same type as the scrutinee
 681                 -> CoreExpr     -- Scrutinee
 682                 -> CoreExpr
 683
 684 mkTupleSelector vars the_var scrut_var scrut
 685   = mk_tup_sel (chunkify vars) the_var
 686   where
 687     mk_tup_sel [vars] the_var = mkCoreSel vars the_var scrut_var scrut
 688     mk_tup_sel vars_s the_var = mkCoreSel group the_var tpl_v $
 689                                 mk_tup_sel (chunkify tpl_vs) tpl_v
 690         where
 691           tpl_tys = [mkCoreTupTy (map idType gp) | gp <- vars_s]
 692           tpl_vs  = mkTemplateLocals tpl_tys
 693           [(tpl_v, group)] = [(tpl,gp) | (tpl,gp) <- zipEqual "mkTupleSelector" tpl_vs vars_s,
 694                                          the_var `elem` gp ]
 695 \end{code}
 696
 697 A generalization of @mkTupleSelector@, allowing the body
 698 of the case to be an arbitrary expression.
 699
 700 If the tuple is big, it is nested:
 701
 702         mkTupleCase uniqs [a,b,c,d] body v e
 703           = case e of v { (p,q) ->
 704             case p of p { (a,b) ->
 705             case q of q { (c,d) ->
 706             body }}}
 707
 708 To avoid shadowing, we use uniqs to invent new variables p,q.
 709
 710 ToDo: eliminate cases where none of the variables are needed.
 711
 712 \begin{code}
 713 mkTupleCase
 714         :: UniqSupply   -- for inventing names of intermediate variables
 715         -> [Id]         -- the tuple args
 716         -> CoreExpr     -- body of the case
 717         -> Id           -- a variable of the same type as the scrutinee
 718         -> CoreExpr     -- scrutinee
 719         -> CoreExpr
 720
 721 mkTupleCase uniqs vars body scrut_var scrut
 722   = mk_tuple_case uniqs (chunkify vars) body
 723   where
 724     mk_tuple_case us [vars] body
 725       = mkSmallTupleCase vars body scrut_var scrut
 726     mk_tuple_case us vars_s body
 727       = let
 728             (us', vars', body') = foldr one_tuple_case (us, [], body) vars_s
 729         in
 730         mk_tuple_case us' (chunkify vars') body'
 731     one_tuple_case chunk_vars (us, vs, body)
 732       = let
 733             (us1, us2) = splitUniqSupply us
 734             scrut_var = mkSysLocal FSLIT("ds") (uniqFromSupply us1)
 735                         (mkCoreTupTy (map idType chunk_vars))
 736             body' = mkSmallTupleCase chunk_vars body scrut_var (Var scrut_var)
 737         in (us2, scrut_var:vs, body')
 738 \end{code}
 739
 740 The same, but with a tuple small enough not to need nesting.
 741
 742 \begin{code}
 743 mkSmallTupleCase
 744         :: [Id]         -- the tuple args
 745         -> CoreExpr     -- body of the case
 746         -> Id           -- a variable of the same type as the scrutinee
 747         -> CoreExpr     -- scrutinee
 748         -> CoreExpr
 749
 750 mkSmallTupleCase [var] body _scrut_var scrut
 751   = bindNonRec var scrut body
 752 mkSmallTupleCase vars body scrut_var scrut
 753 -- One branch no refinement?
 754   = Case scrut scrut_var (exprType body) [(DataAlt (tupleCon Boxed (length vars)), vars, body)]
 755 \end{code}
 756
 757 %************************************************************************
 758 %*                                                                      *
 759 \subsection[mkFailurePair]{Code for pattern-matching and other failures}
 760 %*                                                                      *
 761 %************************************************************************
 762
 763 Call the constructor Ids when building explicit lists, so that they
 764 interact well with rules.
 765
 766 \begin{code}
 767 mkNilExpr :: Type -> CoreExpr
 768 mkNilExpr ty = mkConApp nilDataCon [Type ty]
 769
 770 mkConsExpr :: Type -> CoreExpr -> CoreExpr -> CoreExpr
 771 mkConsExpr ty hd tl = mkConApp consDataCon [Type ty, hd, tl]
 772
 773 mkListExpr :: Type -> [CoreExpr] -> CoreExpr
 774 mkListExpr ty xs = foldr (mkConsExpr ty) (mkNilExpr ty) xs
 775
 776
 777 -- The next three functions make tuple types, constructors and selectors,
 778 -- with the rule that a 1-tuple is represented by the thing itselg
 779 mkCoreTupTy :: [Type] -> Type
 780 mkCoreTupTy [ty] = ty
 781 mkCoreTupTy tys  = mkTupleTy Boxed (length tys) tys
 782
 783 mkCoreTup :: [CoreExpr] -> CoreExpr
 784 -- Builds exactly the specified tuple.
 785 -- No fancy business for big tuples
 786 mkCoreTup []  = Var unitDataConId
 787 mkCoreTup [c] = c
 788 mkCoreTup cs  = mkConApp (tupleCon Boxed (length cs))
 789                          (map (Type . exprType) cs ++ cs)
 790
 791 mkCoreSel :: [Id]       -- The tuple args
 792           -> Id         -- The selected one
 793           -> Id         -- A variable of the same type as the scrutinee
 794           -> CoreExpr   -- Scrutinee
 795           -> CoreExpr
 796 -- mkCoreSel [x,y,z] x v e
 797 -- ===>  case e of v { (x,y,z) -> x
 798 mkCoreSel [var] should_be_the_same_var scrut_var scrut
 799   = ASSERT(var == should_be_the_same_var)
 800     scrut
 801
 802 mkCoreSel vars the_var scrut_var scrut
 803   = ASSERT( notNull vars )
 804     Case scrut scrut_var (idType the_var)
 805          [(DataAlt (tupleCon Boxed (length vars)), vars, Var the_var)]
 806 \end{code}
 807
 808
 809 %************************************************************************
 810 %*                                                                      *
 811 \subsection[mkFailurePair]{Code for pattern-matching and other failures}
 812 %*                                                                      *
 813 %************************************************************************
 814
 815 Generally, we handle pattern matching failure like this: let-bind a
 816 fail-variable, and use that variable if the thing fails:
 817 \begin{verbatim}
 818         let fail.33 = error "Help"
 819         in
 820         case x of
 821                 p1 -> ...
 822                 p2 -> fail.33
 823                 p3 -> fail.33
 824                 p4 -> ...
 825 \end{verbatim}
 826 Then
 827 \begin{itemize}
 828 \item
 829 If the case can't fail, then there'll be no mention of @fail.33@, and the
 830 simplifier will later discard it.
 831
 832 \item
 833 If it can fail in only one way, then the simplifier will inline it.
 834
 835 \item
 836 Only if it is used more than once will the let-binding remain.
 837 \end{itemize}
 838
 839 There's a problem when the result of the case expression is of
 840 unboxed type.  Then the type of @fail.33@ is unboxed too, and
 841 there is every chance that someone will change the let into a case:
 842 \begin{verbatim}
 843         case error "Help" of
 844           fail.33 -> case ....
 845 \end{verbatim}
 846
 847 which is of course utterly wrong.  Rather than drop the condition that
 848 only boxed types can be let-bound, we just turn the fail into a function
 849 for the primitive case:
 850 \begin{verbatim}
 851         let fail.33 :: Void -> Int#
 852             fail.33 = \_ -> error "Help"
 853         in
 854         case x of
 855                 p1 -> ...
 856                 p2 -> fail.33 void
 857                 p3 -> fail.33 void
 858                 p4 -> ...
 859 \end{verbatim}
 860
 861 Now @fail.33@ is a function, so it can be let-bound.
 862
 863 \begin{code}
 864 mkFailurePair :: CoreExpr       -- Result type of the whole case expression
 865               -> DsM (CoreBind, -- Binds the newly-created fail variable
 866                                 -- to either the expression or \ _ -> expression
 867                       CoreExpr) -- Either the fail variable, or fail variable
 868                                 -- applied to unit tuple
 869 mkFailurePair expr
 870   | isUnLiftedType ty
 871   = newFailLocalDs (unitTy `mkFunTy` ty)        `thenDs` \ fail_fun_var ->
 872     newSysLocalDs unitTy                        `thenDs` \ fail_fun_arg ->
 873     returnDs (NonRec fail_fun_var (Lam fail_fun_arg expr),
 874               App (Var fail_fun_var) (Var unitDataConId))
 875
 876   | otherwise
 877   = newFailLocalDs ty           `thenDs` \ fail_var ->
 878     returnDs (NonRec fail_var expr, Var fail_var)
 879   where
 880     ty = exprType expr
 881 \end{code}
 882
 883