ghc/compiler/deSugar/DsUtils.lhs

   1 %
   2 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   3 %
   4 \section[DsUtils]{Utilities for desugaring}
   5
   6 This module exports some utility functions of no great interest.
   7
   8 \begin{code}
   9 module DsUtils (
  10         EquationInfo(..),
  11         firstPat, shiftEqns,
  12
  13         mkDsLet,
  14
  15         MatchResult(..), CanItFail(..),
  16         cantFailMatchResult, alwaysFailMatchResult,
  17         extractMatchResult, combineMatchResults,
  18         adjustMatchResult,  adjustMatchResultDs,
  19         mkCoLetsMatchResult, mkCoLetMatchResult,
  20         mkGuardedMatchResult,
  21         mkCoPrimCaseMatchResult, mkCoAlgCaseMatchResult,
  22         bindInMatchResult, bindOneInMatchResult,
  23
  24         mkErrorAppDs, mkNilExpr, mkConsExpr, mkListExpr,
  25         mkIntExpr, mkCharExpr,
  26         mkStringExpr, mkStringExprFS, mkIntegerExpr,
  27
  28         mkSelectorBinds, mkTupleExpr, mkTupleSelector,
  29         mkTupleType, mkTupleCase, mkBigCoreTup,
  30         mkCoreTup, mkCoreTupTy,
  31
  32         dsReboundNames, lookupReboundName,
  33
  34         selectSimpleMatchVarL, selectMatchVars
  35     ) where
  36
  37 #include "HsVersions.h"
  38
  39 import {-# SOURCE #-}   Match ( matchSimply )
  40 import {-# SOURCE #-}   DsExpr( dsExpr )
  41
  42 import HsSyn
  43 import TcHsSyn          ( hsPatType )
  44 import CoreSyn
  45 import Constants        ( mAX_TUPLE_SIZE )
  46 import DsMonad
  47
  48 import CoreUtils        ( exprType, mkIfThenElse, mkCoerce, bindNonRec )
  49 import MkId             ( iRREFUT_PAT_ERROR_ID, mkReboxingAlt, mkNewTypeBody )
  50 import Id               ( idType, Id, mkWildId, mkTemplateLocals, mkSysLocal )
  51 import Var              ( Var )
  52 import Name             ( Name )
  53 import Literal          ( Literal(..), mkStringLit, inIntRange, tARGET_MAX_INT )
  54 import TyCon            ( isNewTyCon, tyConDataCons )
  55 import DataCon          ( DataCon, dataConSourceArity, dataConTyCon, dataConTag )
  56 import Type             ( mkFunTy, isUnLiftedType, Type, splitTyConApp, mkTyVarTy )
  57 import TcType           ( tcEqType )
  58 import TysPrim          ( intPrimTy )
  59 import TysWiredIn       ( nilDataCon, consDataCon,
  60                           tupleCon, mkTupleTy,
  61                           unitDataConId, unitTy,
  62                           charTy, charDataCon,
  63                           intTy, intDataCon,
  64                           isPArrFakeCon )
  65 import BasicTypes       ( Boxity(..) )
  66 import UniqSet          ( mkUniqSet, minusUniqSet, isEmptyUniqSet )
  67 import UniqSupply       ( splitUniqSupply, uniqFromSupply, uniqsFromSupply )
  68 import PrelNames        ( unpackCStringName, unpackCStringUtf8Name,
  69                           plusIntegerName, timesIntegerName, smallIntegerDataConName,
  70                           lengthPName, indexPName )
  71 import Outputable
  72 import UnicodeUtil      ( intsToUtf8 )
  73 import SrcLoc           ( Located(..), unLoc )
  74 import Util             ( isSingleton, notNull, zipEqual, sortWith )
  75 import ListSetOps       ( assocDefault )
  76 import FastString
  77 \end{code}
  78
  79
  80
  81 %************************************************************************
  82 %*                                                                      *
  83                 Rebindable syntax
  84 %*                                                                      *
  85 %************************************************************************
  86
  87 \begin{code}
  88 dsReboundNames :: ReboundNames Id
  89                -> DsM ([CoreBind],      -- Auxiliary bindings
  90                        [(Name,Id)])     -- Maps the standard name to its value
  91
  92 dsReboundNames rebound_ids
  93   = mapAndUnzipDs mk_bind rebound_ids   `thenDs` \ (binds_s, prs) ->
  94     return (concat binds_s, prs)
  95   where
  96         -- The cheapo special case can happen when we
  97         -- make an intermediate HsDo when desugaring a RecStmt
  98     mk_bind (std_name, HsVar id) = return ([], (std_name, id))
  99     mk_bind (std_name, expr)
 100          = dsExpr expr                          `thenDs` \ rhs ->
 101            newSysLocalDs (exprType rhs)         `thenDs` \ id ->
 102            return ([NonRec id rhs], (std_name, id))
 103
 104 lookupReboundName :: [(Name,Id)] -> Name -> CoreExpr
 105 lookupReboundName prs std_name
 106   = Var (assocDefault (mk_panic std_name) prs std_name)
 107   where
 108     mk_panic std_name = pprPanic "dsReboundNames" (ptext SLIT("Not found:") <+> ppr std_name)
 109 \end{code}
 110
 111
 112 %************************************************************************
 113 %*                                                                      *
 114 \subsection{Building lets}
 115 %*                                                                      *
 116 %************************************************************************
 117
 118 Use case, not let for unlifted types.  The simplifier will turn some
 119 back again.
 120
 121 \begin{code}
 122 mkDsLet :: CoreBind -> CoreExpr -> CoreExpr
 123 mkDsLet (NonRec bndr rhs) body
 124   | isUnLiftedType (idType bndr)
 125   = Case rhs bndr (exprType body) [(DEFAULT,[],body)]
 126 mkDsLet bind body
 127   = Let bind body
 128
 129 mkDsLets :: [CoreBind] -> CoreExpr -> CoreExpr
 130 mkDsLets binds body = foldr mkDsLet body binds
 131 \end{code}
 132
 133
 134 %************************************************************************
 135 %*                                                                      *
 136 \subsection{ Selecting match variables}
 137 %*                                                                      *
 138 %************************************************************************
 139
 140 We're about to match against some patterns.  We want to make some
 141 @Ids@ to use as match variables.  If a pattern has an @Id@ readily at
 142 hand, which should indeed be bound to the pattern as a whole, then use it;
 143 otherwise, make one up.
 144
 145 \begin{code}
 146 selectSimpleMatchVarL :: LPat Id -> DsM Id
 147 selectSimpleMatchVarL pat = selectMatchVar (unLoc pat) (hsPatType pat)
 148
 149 -- (selectMatchVars ps tys) chooses variables of type tys
 150 -- to use for matching ps against.  If the pattern is a variable,
 151 -- we try to use that, to save inventing lots of fresh variables.
 152 -- But even if it is a variable, its type might not match.  Consider
 153 --      data T a where
 154 --        T1 :: Int -> T Int
 155 --        T2 :: a   -> T a
 156 --
 157 --      f :: T a -> a -> Int
 158 --      f (T1 i) (x::Int) = x
 159 --      f (T2 i) (y::a)   = 0
 160 -- Then we must not choose (x::Int) as the matching variable!
 161
 162 selectMatchVars :: [Pat Id] -> [Type] -> DsM [Id]
 163 selectMatchVars []     []       = return []
 164 selectMatchVars (p:ps) (ty:tys) = do { v  <- selectMatchVar  p  ty
 165                                      ; vs <- selectMatchVars ps tys
 166                                      ; return (v:vs) }
 167
 168 selectMatchVar (LazyPat pat)   pat_ty  = selectMatchVar (unLoc pat) pat_ty
 169 selectMatchVar (VarPat var)    pat_ty  = try_for var         pat_ty
 170 selectMatchVar (AsPat var pat) pat_ty  = try_for (unLoc var) pat_ty
 171 selectMatchVar other_pat       pat_ty  = newSysLocalDs pat_ty   -- OK, better make up one...
 172
 173 try_for var pat_ty
 174   | idType var `tcEqType` pat_ty = returnDs var
 175   | otherwise                    = newSysLocalDs pat_ty
 176 \end{code}
 177
 178
 179 %************************************************************************
 180 %*                                                                      *
 181 %* type synonym EquationInfo and access functions for its pieces        *
 182 %*                                                                      *
 183 %************************************************************************
 184 \subsection[EquationInfo-synonym]{@EquationInfo@: a useful synonym}
 185
 186 The ``equation info'' used by @match@ is relatively complicated and
 187 worthy of a type synonym and a few handy functions.
 188
 189 \begin{code}
 190 data EquationInfo
 191   = EqnInfo { eqn_pats :: [Pat Id],     -- The patterns for an eqn
 192               eqn_rhs  :: MatchResult } -- What to do after match
 193
 194 -- The semantics of (match vs (EqnInfo wrap pats rhs)) is the MatchResult
 195 --      \fail. wrap (case vs of { pats -> rhs fail })
 196 -- where vs are not in the domain of wrap
 197
 198 firstPat :: EquationInfo -> Pat Id
 199 firstPat eqn = head (eqn_pats eqn)
 200
 201 shiftEqns :: [EquationInfo] -> [EquationInfo]
 202 -- Drop the outermost layer of the first pattern in each equation
 203 shiftEqns eqns = [ eqn { eqn_pats = shiftPats (eqn_pats eqn) }
 204                  | eqn <- eqns ]
 205
 206 shiftPats :: [Pat Id] -> [Pat Id]
 207 shiftPats (ConPatOut _ _ _ _ (PrefixCon arg_pats) _ : pats) = map unLoc arg_pats ++ pats
 208 shiftPats (pat_with_no_sub_pats                     : pats) = pats
 209 \end{code}
 210
 211
 212 \begin{code}
 213 -- A MatchResult is an expression with a hole in it
 214 data MatchResult
 215   = MatchResult
 216         CanItFail       -- Tells whether the failure expression is used
 217         (CoreExpr -> DsM CoreExpr)
 218                         -- Takes a expression to plug in at the
 219                         -- failure point(s). The expression should
 220                         -- be duplicatable!
 221
 222 data CanItFail = CanFail | CantFail
 223
 224 orFail CantFail CantFail = CantFail
 225 orFail _        _        = CanFail
 226 \end{code}
 227
 228 Functions on MatchResults
 229
 230 \begin{code}
 231 alwaysFailMatchResult :: MatchResult
 232 alwaysFailMatchResult = MatchResult CanFail (\fail -> returnDs fail)
 233
 234 cantFailMatchResult :: CoreExpr -> MatchResult
 235 cantFailMatchResult expr = MatchResult CantFail (\ ignore -> returnDs expr)
 236
 237 extractMatchResult :: MatchResult -> CoreExpr -> DsM CoreExpr
 238 extractMatchResult (MatchResult CantFail match_fn) fail_expr
 239   = match_fn (error "It can't fail!")
 240
 241 extractMatchResult (MatchResult CanFail match_fn) fail_expr
 242   = mkFailurePair fail_expr             `thenDs` \ (fail_bind, if_it_fails) ->
 243     match_fn if_it_fails                `thenDs` \ body ->
 244     returnDs (mkDsLet fail_bind body)
 245
 246
 247 combineMatchResults :: MatchResult -> MatchResult -> MatchResult
 248 combineMatchResults (MatchResult CanFail      body_fn1)
 249                     (MatchResult can_it_fail2 body_fn2)
 250   = MatchResult can_it_fail2 body_fn
 251   where
 252     body_fn fail = body_fn2 fail                        `thenDs` \ body2 ->
 253                    mkFailurePair body2                  `thenDs` \ (fail_bind, duplicatable_expr) ->
 254                    body_fn1 duplicatable_expr           `thenDs` \ body1 ->
 255                    returnDs (Let fail_bind body1)
 256
 257 combineMatchResults match_result1@(MatchResult CantFail body_fn1) match_result2
 258   = match_result1
 259
 260 adjustMatchResult :: (CoreExpr -> CoreExpr) -> MatchResult -> MatchResult
 261 adjustMatchResult encl_fn (MatchResult can_it_fail body_fn)
 262   = MatchResult can_it_fail (\fail -> body_fn fail      `thenDs` \ body ->
 263                                       returnDs (encl_fn body))
 264
 265 adjustMatchResultDs :: (CoreExpr -> DsM CoreExpr) -> MatchResult -> MatchResult
 266 adjustMatchResultDs encl_fn (MatchResult can_it_fail body_fn)
 267   = MatchResult can_it_fail (\fail -> body_fn fail      `thenDs` \ body ->
 268                                       encl_fn body)
 269
 270 bindInMatchResult :: [(Var,Var)] -> MatchResult -> MatchResult
 271 bindInMatchResult binds = adjustMatchResult (\e -> foldr bind e binds)
 272   where
 273     bind (new,old) body = bindMR new old body
 274
 275 bindOneInMatchResult :: Var -> Var -> MatchResult -> MatchResult
 276 bindOneInMatchResult new old = adjustMatchResult (bindMR new old)
 277
 278 bindMR :: Var -> Var -> CoreExpr -> CoreExpr
 279 bindMR new old body
 280   | new==old    = body
 281   | isTyVar new = App (Lam new body) (Type (mkTyVarTy old))
 282   | otherwise   = Let (NonRec new (Var old)) body
 283
 284 mkCoLetsMatchResult :: [CoreBind] -> MatchResult -> MatchResult
 285 mkCoLetsMatchResult binds match_result
 286   = adjustMatchResult (mkDsLets binds) match_result
 287
 288 mkCoLetMatchResult :: CoreBind -> MatchResult -> MatchResult
 289 mkCoLetMatchResult bind match_result
 290   = adjustMatchResult (mkDsLet bind) match_result
 291
 292 mkGuardedMatchResult :: CoreExpr -> MatchResult -> MatchResult
 293 mkGuardedMatchResult pred_expr (MatchResult can_it_fail body_fn)
 294   = MatchResult CanFail (\fail -> body_fn fail  `thenDs` \ body ->
 295                                   returnDs (mkIfThenElse pred_expr body fail))
 296
 297 mkCoPrimCaseMatchResult :: Id                           -- Scrutinee
 298                     -> Type                             -- Type of the case
 299                     -> [(Literal, MatchResult)]         -- Alternatives
 300                     -> MatchResult
 301 mkCoPrimCaseMatchResult var ty match_alts
 302   = MatchResult CanFail mk_case
 303   where
 304     mk_case fail
 305       = mappM (mk_alt fail) sorted_alts         `thenDs` \ alts ->
 306         returnDs (Case (Var var) var ty ((DEFAULT, [], fail) : alts))
 307
 308     sorted_alts = sortWith fst match_alts       -- Right order for a Case
 309     mk_alt fail (lit, MatchResult _ body_fn) = body_fn fail     `thenDs` \ body ->
 310                                                returnDs (LitAlt lit, [], body)
 311
 312
 313 mkCoAlgCaseMatchResult :: Id                                    -- Scrutinee
 314                     -> Type                                     -- Type of exp
 315                     -> [(DataCon, [CoreBndr], MatchResult)]     -- Alternatives
 316                     -> MatchResult
 317 mkCoAlgCaseMatchResult var ty match_alts
 318   | isNewTyCon tycon            -- Newtype case; use a let
 319   = ASSERT( null (tail match_alts) && null (tail arg_ids1) )
 320     mkCoLetsMatchResult [NonRec arg_id1 newtype_rhs] match_result1
 321
 322   | isPArrFakeAlts match_alts   -- Sugared parallel array; use a literal case
 323   = MatchResult CanFail mk_parrCase
 324
 325   | otherwise                   -- Datatype case; use a case
 326   = MatchResult fail_flag mk_case
 327   where
 328     tycon = dataConTyCon con1
 329         -- [Interesting: becuase of GADTs, we can't rely on the type of
 330         --  the scrutinised Id to be sufficiently refined to have a TyCon in it]
 331
 332         -- Stuff for newtype
 333     (con1, arg_ids1, match_result1) = head match_alts
 334     arg_id1     = head arg_ids1
 335     newtype_rhs = mkNewTypeBody tycon (idType arg_id1) (Var var)
 336
 337         -- Stuff for data types
 338     data_cons      = tyConDataCons tycon
 339     match_results  = [match_result | (_,_,match_result) <- match_alts]
 340
 341     fail_flag | exhaustive_case
 342               = foldr1 orFail [can_it_fail | MatchResult can_it_fail _ <- match_results]
 343               | otherwise
 344               = CanFail
 345
 346     wild_var = mkWildId (idType var)
 347     sorted_alts  = sortWith get_tag match_alts
 348     get_tag (con, _, _) = dataConTag con
 349     mk_case fail = mappM (mk_alt fail) sorted_alts      `thenDs` \ alts ->
 350                    returnDs (Case (Var var) wild_var ty (mk_default fail ++ alts))
 351
 352     mk_alt fail (con, args, MatchResult _ body_fn)
 353         = body_fn fail                          `thenDs` \ body ->
 354           newUniqueSupply                       `thenDs` \ us ->
 355           returnDs (mkReboxingAlt (uniqsFromSupply us) con args body)
 356
 357     mk_default fail | exhaustive_case = []
 358                     | otherwise       = [(DEFAULT, [], fail)]
 359
 360     un_mentioned_constructors
 361         = mkUniqSet data_cons `minusUniqSet` mkUniqSet [ con | (con, _, _) <- match_alts]
 362     exhaustive_case = isEmptyUniqSet un_mentioned_constructors
 363
 364         -- Stuff for parallel arrays
 365         --
 366         -- * the following is to desugar cases over fake constructors for
 367         --   parallel arrays, which are introduced by `tidy1' in the `PArrPat'
 368         --   case
 369         --
 370         -- Concerning `isPArrFakeAlts':
 371         --
 372         -- * it is *not* sufficient to just check the type of the type
 373         --   constructor, as we have to be careful not to confuse the real
 374         --   representation of parallel arrays with the fake constructors;
 375         --   moreover, a list of alternatives must not mix fake and real
 376         --   constructors (this is checked earlier on)
 377         --
 378         -- FIXME: We actually go through the whole list and make sure that
 379         --        either all or none of the constructors are fake parallel
 380         --        array constructors.  This is to spot equations that mix fake
 381         --        constructors with the real representation defined in
 382         --        `PrelPArr'.  It would be nicer to spot this situation
 383         --        earlier and raise a proper error message, but it can really
 384         --        only happen in `PrelPArr' anyway.
 385         --
 386     isPArrFakeAlts [(dcon, _, _)]      = isPArrFakeCon dcon
 387     isPArrFakeAlts ((dcon, _, _):alts) =
 388       case (isPArrFakeCon dcon, isPArrFakeAlts alts) of
 389         (True , True ) -> True
 390         (False, False) -> False
 391         _              ->
 392           panic "DsUtils: You may not mix `[:...:]' with `PArr' patterns"
 393     --
 394     mk_parrCase fail =
 395       dsLookupGlobalId lengthPName                      `thenDs` \lengthP  ->
 396       unboxAlt                                          `thenDs` \alt      ->
 397       returnDs (Case (len lengthP) (mkWildId intTy) ty [alt])
 398       where
 399         elemTy      = case splitTyConApp (idType var) of
 400                         (_, [elemTy]) -> elemTy
 401                         _               -> panic panicMsg
 402         panicMsg    = "DsUtils.mkCoAlgCaseMatchResult: not a parallel array?"
 403         len lengthP = mkApps (Var lengthP) [Type elemTy, Var var]
 404         --
 405         unboxAlt =
 406           newSysLocalDs intPrimTy                       `thenDs` \l        ->
 407           dsLookupGlobalId indexPName                   `thenDs` \indexP   ->
 408           mappM (mkAlt indexP) sorted_alts              `thenDs` \alts     ->
 409           returnDs (DataAlt intDataCon, [l], (Case (Var l) wild ty (dft : alts)))
 410           where
 411             wild = mkWildId intPrimTy
 412             dft  = (DEFAULT, [], fail)
 413         --
 414         -- each alternative matches one array length (corresponding to one
 415         -- fake array constructor), so the match is on a literal; each
 416         -- alternative's body is extended by a local binding for each
 417         -- constructor argument, which are bound to array elements starting
 418         -- with the first
 419         --
 420         mkAlt indexP (con, args, MatchResult _ bodyFun) =
 421           bodyFun fail                                  `thenDs` \body     ->
 422           returnDs (LitAlt lit, [], mkDsLets binds body)
 423           where
 424             lit   = MachInt $ toInteger (dataConSourceArity con)
 425             binds = [NonRec arg (indexExpr i) | (i, arg) <- zip [1..] args]
 426             --
 427             indexExpr i = mkApps (Var indexP) [Type elemTy, Var var, mkIntExpr i]
 428 \end{code}
 429
 430
 431 %************************************************************************
 432 %*                                                                      *
 433 \subsection{Desugarer's versions of some Core functions}
 434 %*                                                                      *
 435 %************************************************************************
 436
 437 \begin{code}
 438 mkErrorAppDs :: Id              -- The error function
 439              -> Type            -- Type to which it should be applied
 440              -> String          -- The error message string to pass
 441              -> DsM CoreExpr
 442
 443 mkErrorAppDs err_id ty msg
 444   = getSrcSpanDs                `thenDs` \ src_loc ->
 445     let
 446         full_msg = showSDoc (hcat [ppr src_loc, text "|", text msg])
 447         core_msg = Lit (mkStringLit full_msg)
 448     in
 449     returnDs (mkApps (Var err_id) [Type ty, core_msg])
 450 \end{code}
 451
 452
 453 *************************************************************
 454 %*                                                                      *
 455 \subsection{Making literals}
 456 %*                                                                      *
 457 %************************************************************************
 458
 459 \begin{code}
 460 mkCharExpr     :: Char       -> CoreExpr      -- Returns        C# c :: Int
 461 mkIntExpr      :: Integer    -> CoreExpr      -- Returns        I# i :: Int
 462 mkIntegerExpr  :: Integer    -> DsM CoreExpr  -- Result :: Integer
 463 mkStringExpr   :: String     -> DsM CoreExpr  -- Result :: String
 464 mkStringExprFS :: FastString -> DsM CoreExpr  -- Result :: String
 465
 466 mkIntExpr  i = mkConApp intDataCon  [mkIntLit i]
 467 mkCharExpr c = mkConApp charDataCon [mkLit (MachChar c)]
 468
 469 mkIntegerExpr i
 470   | inIntRange i        -- Small enough, so start from an Int
 471   = dsLookupDataCon  smallIntegerDataConName    `thenDs` \ integer_dc ->
 472     returnDs (mkSmallIntegerLit integer_dc i)
 473
 474 -- Special case for integral literals with a large magnitude:
 475 -- They are transformed into an expression involving only smaller
 476 -- integral literals. This improves constant folding.
 477
 478   | otherwise           -- Big, so start from a string
 479   = dsLookupGlobalId plusIntegerName            `thenDs` \ plus_id ->
 480     dsLookupGlobalId timesIntegerName           `thenDs` \ times_id ->
 481     dsLookupDataCon  smallIntegerDataConName    `thenDs` \ integer_dc ->
 482     let
 483         lit i = mkSmallIntegerLit integer_dc i
 484         plus a b  = Var plus_id  `App` a `App` b
 485         times a b = Var times_id `App` a `App` b
 486
 487         -- Transform i into (x1 + (x2 + (x3 + (...) * b) * b) * b) with abs xi <= b
 488         horner :: Integer -> Integer -> CoreExpr
 489         horner b i | abs q <= 1 = if r == 0 || r == i
 490                                   then lit i
 491                                   else lit r `plus` lit (i-r)
 492                    | r == 0     =               horner b q `times` lit b
 493                    | otherwise  = lit r `plus` (horner b q `times` lit b)
 494                    where
 495                      (q,r) = i `quotRem` b
 496
 497     in
 498     returnDs (horner tARGET_MAX_INT i)
 499
 500 mkSmallIntegerLit small_integer_data_con i = mkConApp small_integer_data_con [mkIntLit i]
 501
 502 mkStringExpr str = mkStringExprFS (mkFastString str)
 503
 504 mkStringExprFS str
 505   | nullFastString str
 506   = returnDs (mkNilExpr charTy)
 507
 508   | lengthFS str == 1
 509   = let
 510         the_char = mkCharExpr (headFS str)
 511     in
 512     returnDs (mkConsExpr charTy the_char (mkNilExpr charTy))
 513
 514   | all safeChar int_chars
 515   = dsLookupGlobalId unpackCStringName  `thenDs` \ unpack_id ->
 516     returnDs (App (Var unpack_id) (Lit (MachStr str)))
 517
 518   | otherwise
 519   = dsLookupGlobalId unpackCStringUtf8Name      `thenDs` \ unpack_id ->
 520     returnDs (App (Var unpack_id) (Lit (MachStr (mkFastString (intsToUtf8 int_chars)))))
 521
 522   where
 523     int_chars = unpackIntFS str
 524     safeChar c = c >= 1 && c <= 0xFF
 525 \end{code}
 526
 527
 528 %************************************************************************
 529 %*                                                                      *
 530 \subsection[mkSelectorBind]{Make a selector bind}
 531 %*                                                                      *
 532 %************************************************************************
 533
 534 This is used in various places to do with lazy patterns.
 535 For each binder $b$ in the pattern, we create a binding:
 536 \begin{verbatim}
 537     b = case v of pat' -> b'
 538 \end{verbatim}
 539 where @pat'@ is @pat@ with each binder @b@ cloned into @b'@.
 540
 541 ToDo: making these bindings should really depend on whether there's
 542 much work to be done per binding.  If the pattern is complex, it
 543 should be de-mangled once, into a tuple (and then selected from).
 544 Otherwise the demangling can be in-line in the bindings (as here).
 545
 546 Boring!  Boring!  One error message per binder.  The above ToDo is
 547 even more helpful.  Something very similar happens for pattern-bound
 548 expressions.
 549
 550 \begin{code}
 551 mkSelectorBinds :: LPat Id      -- The pattern
 552                 -> CoreExpr     -- Expression to which the pattern is bound
 553                 -> DsM [(Id,CoreExpr)]
 554
 555 mkSelectorBinds (L _ (VarPat v)) val_expr
 556   = returnDs [(v, val_expr)]
 557
 558 mkSelectorBinds pat val_expr
 559   | isSingleton binders || is_simple_lpat pat
 560   =     -- Given   p = e, where p binds x,y
 561         -- we are going to make
 562         --      v = p   (where v is fresh)
 563         --      x = case v of p -> x
 564         --      y = case v of p -> x
 565
 566         -- Make up 'v'
 567         -- NB: give it the type of *pattern* p, not the type of the *rhs* e.
 568         -- This does not matter after desugaring, but there's a subtle
 569         -- issue with implicit parameters. Consider
 570         --      (x,y) = ?i
 571         -- Then, ?i is given type {?i :: Int}, a PredType, which is opaque
 572         -- to the desugarer.  (Why opaque?  Because newtypes have to be.  Why
 573         -- does it get that type?  So that when we abstract over it we get the
 574         -- right top-level type  (?i::Int) => ...)
 575         --
 576         -- So to get the type of 'v', use the pattern not the rhs.  Often more
 577         -- efficient too.
 578     newSysLocalDs (hsPatType pat)       `thenDs` \ val_var ->
 579
 580         -- For the error message we make one error-app, to avoid duplication.
 581         -- But we need it at different types... so we use coerce for that
 582     mkErrorAppDs iRREFUT_PAT_ERROR_ID
 583                  unitTy (showSDoc (ppr pat))    `thenDs` \ err_expr ->
 584     newSysLocalDs unitTy                        `thenDs` \ err_var ->
 585     mappM (mk_bind val_var err_var) binders     `thenDs` \ binds ->
 586     returnDs ( (val_var, val_expr) :
 587                (err_var, err_expr) :
 588                binds )
 589
 590
 591   | otherwise
 592   = mkErrorAppDs iRREFUT_PAT_ERROR_ID
 593                  tuple_ty (showSDoc (ppr pat))                  `thenDs` \ error_expr ->
 594     matchSimply val_expr PatBindRhs pat local_tuple error_expr  `thenDs` \ tuple_expr ->
 595     newSysLocalDs tuple_ty                                      `thenDs` \ tuple_var ->
 596     let
 597         mk_tup_bind binder
 598           = (binder, mkTupleSelector binders binder tuple_var (Var tuple_var))
 599     in
 600     returnDs ( (tuple_var, tuple_expr) : map mk_tup_bind binders )
 601   where
 602     binders     = collectPatBinders pat
 603     local_tuple = mkTupleExpr binders
 604     tuple_ty    = exprType local_tuple
 605
 606     mk_bind scrut_var err_var bndr_var
 607     -- (mk_bind sv err_var) generates
 608     --          bv = case sv of { pat -> bv; other -> coerce (type-of-bv) err_var }
 609     -- Remember, pat binds bv
 610       = matchSimply (Var scrut_var) PatBindRhs pat
 611                     (Var bndr_var) error_expr                   `thenDs` \ rhs_expr ->
 612         returnDs (bndr_var, rhs_expr)
 613       where
 614         error_expr = mkCoerce (idType bndr_var) (Var err_var)
 615
 616     is_simple_lpat p = is_simple_pat (unLoc p)
 617
 618     is_simple_pat (TuplePat ps Boxed)      = all is_triv_lpat ps
 619     is_simple_pat (ConPatOut _ _ _ _ ps _) = all is_triv_lpat (hsConArgs ps)
 620     is_simple_pat (VarPat _)               = True
 621     is_simple_pat (ParPat p)               = is_simple_lpat p
 622     is_simple_pat other                    = False
 623
 624     is_triv_lpat p = is_triv_pat (unLoc p)
 625
 626     is_triv_pat (VarPat v)  = True
 627     is_triv_pat (WildPat _) = True
 628     is_triv_pat (ParPat p)  = is_triv_lpat p
 629     is_triv_pat other       = False
 630 \end{code}
 631
 632
 633 %************************************************************************
 634 %*                                                                      *
 635                 Tuples
 636 %*                                                                      *
 637 %************************************************************************
 638
 639 @mkTupleExpr@ builds a tuple; the inverse to @mkTupleSelector@.
 640
 641 * If it has only one element, it is the identity function.
 642
 643 * If there are more elements than a big tuple can have, it nests
 644   the tuples.
 645
 646 Nesting policy.  Better a 2-tuple of 10-tuples (3 objects) than
 647 a 10-tuple of 2-tuples (11 objects).  So we want the leaves to be big.
 648
 649 \begin{code}
 650 mkTupleExpr :: [Id] -> CoreExpr
 651 mkTupleExpr ids = mkBigCoreTup (map Var ids)
 652
 653 -- corresponding type
 654 mkTupleType :: [Id] -> Type
 655 mkTupleType ids = mkBigTuple mkCoreTupTy (map idType ids)
 656
 657 mkBigCoreTup :: [CoreExpr] -> CoreExpr
 658 mkBigCoreTup = mkBigTuple mkCoreTup
 659
 660 mkBigTuple :: ([a] -> a) -> [a] -> a
 661 mkBigTuple small_tuple as = mk_big_tuple (chunkify as)
 662   where
 663         -- Each sub-list is short enough to fit in a tuple
 664     mk_big_tuple [as] = small_tuple as
 665     mk_big_tuple as_s = mk_big_tuple (chunkify (map small_tuple as_s))
 666
 667 chunkify :: [a] -> [[a]]
 668 -- The sub-lists of the result all have length <= mAX_TUPLE_SIZE
 669 -- But there may be more than mAX_TUPLE_SIZE sub-lists
 670 chunkify xs
 671   | n_xs <= mAX_TUPLE_SIZE = {- pprTrace "Small" (ppr n_xs) -} [xs]
 672   | otherwise              = {- pprTrace "Big"   (ppr n_xs) -} (split xs)
 673   where
 674     n_xs     = length xs
 675     split [] = []
 676     split xs = take mAX_TUPLE_SIZE xs : split (drop mAX_TUPLE_SIZE xs)
 677 \end{code}
 678
 679
 680 @mkTupleSelector@ builds a selector which scrutises the given
 681 expression and extracts the one name from the list given.
 682 If you want the no-shadowing rule to apply, the caller
 683 is responsible for making sure that none of these names
 684 are in scope.
 685
 686 If there is just one id in the ``tuple'', then the selector is
 687 just the identity.
 688
 689 If it's big, it does nesting
 690         mkTupleSelector [a,b,c,d] b v e
 691           = case e of v {
 692                 (p,q) -> case p of p {
 693                            (a,b) -> b }}
 694 We use 'tpl' vars for the p,q, since shadowing does not matter.
 695
 696 In fact, it's more convenient to generate it innermost first, getting
 697
 698         case (case e of v
 699                 (p,q) -> p) of p
 700           (a,b) -> b
 701
 702 \begin{code}
 703 mkTupleSelector :: [Id]         -- The tuple args
 704                 -> Id           -- The selected one
 705                 -> Id           -- A variable of the same type as the scrutinee
 706                 -> CoreExpr     -- Scrutinee
 707                 -> CoreExpr
 708
 709 mkTupleSelector vars the_var scrut_var scrut
 710   = mk_tup_sel (chunkify vars) the_var
 711   where
 712     mk_tup_sel [vars] the_var = mkCoreSel vars the_var scrut_var scrut
 713     mk_tup_sel vars_s the_var = mkCoreSel group the_var tpl_v $
 714                                 mk_tup_sel (chunkify tpl_vs) tpl_v
 715         where
 716           tpl_tys = [mkCoreTupTy (map idType gp) | gp <- vars_s]
 717           tpl_vs  = mkTemplateLocals tpl_tys
 718           [(tpl_v, group)] = [(tpl,gp) | (tpl,gp) <- zipEqual "mkTupleSelector" tpl_vs vars_s,
 719                                          the_var `elem` gp ]
 720 \end{code}
 721
 722 A generalization of @mkTupleSelector@, allowing the body
 723 of the case to be an arbitrary expression.
 724
 725 If the tuple is big, it is nested:
 726
 727         mkTupleCase uniqs [a,b,c,d] body v e
 728           = case e of v { (p,q) ->
 729             case p of p { (a,b) ->
 730             case q of q { (c,d) ->
 731             body }}}
 732
 733 To avoid shadowing, we use uniqs to invent new variables p,q.
 734
 735 ToDo: eliminate cases where none of the variables are needed.
 736
 737 \begin{code}
 738 mkTupleCase
 739         :: UniqSupply   -- for inventing names of intermediate variables
 740         -> [Id]         -- the tuple args
 741         -> CoreExpr     -- body of the case
 742         -> Id           -- a variable of the same type as the scrutinee
 743         -> CoreExpr     -- scrutinee
 744         -> CoreExpr
 745
 746 mkTupleCase uniqs vars body scrut_var scrut
 747   = mk_tuple_case uniqs (chunkify vars) body
 748   where
 749     mk_tuple_case us [vars] body
 750       = mkSmallTupleCase vars body scrut_var scrut
 751     mk_tuple_case us vars_s body
 752       = let
 753             (us', vars', body') = foldr one_tuple_case (us, [], body) vars_s
 754         in
 755         mk_tuple_case us' (chunkify vars') body'
 756     one_tuple_case chunk_vars (us, vs, body)
 757       = let
 758             (us1, us2) = splitUniqSupply us
 759             scrut_var = mkSysLocal FSLIT("ds") (uniqFromSupply us1)
 760                         (mkCoreTupTy (map idType chunk_vars))
 761             body' = mkSmallTupleCase chunk_vars body scrut_var (Var scrut_var)
 762         in (us2, scrut_var:vs, body')
 763 \end{code}
 764
 765 The same, but with a tuple small enough not to need nesting.
 766
 767 \begin{code}
 768 mkSmallTupleCase
 769         :: [Id]         -- the tuple args
 770         -> CoreExpr     -- body of the case
 771         -> Id           -- a variable of the same type as the scrutinee
 772         -> CoreExpr     -- scrutinee
 773         -> CoreExpr
 774
 775 mkSmallTupleCase [var] body _scrut_var scrut
 776   = bindNonRec var scrut body
 777 mkSmallTupleCase vars body scrut_var scrut
 778 -- One branch no refinement?
 779   = Case scrut scrut_var (exprType body) [(DataAlt (tupleCon Boxed (length vars)), vars, body)]
 780 \end{code}
 781
 782 %************************************************************************
 783 %*                                                                      *
 784 \subsection[mkFailurePair]{Code for pattern-matching and other failures}
 785 %*                                                                      *
 786 %************************************************************************
 787
 788 Call the constructor Ids when building explicit lists, so that they
 789 interact well with rules.
 790
 791 \begin{code}
 792 mkNilExpr :: Type -> CoreExpr
 793 mkNilExpr ty = mkConApp nilDataCon [Type ty]
 794
 795 mkConsExpr :: Type -> CoreExpr -> CoreExpr -> CoreExpr
 796 mkConsExpr ty hd tl = mkConApp consDataCon [Type ty, hd, tl]
 797
 798 mkListExpr :: Type -> [CoreExpr] -> CoreExpr
 799 mkListExpr ty xs = foldr (mkConsExpr ty) (mkNilExpr ty) xs
 800
 801
 802 -- The next three functions make tuple types, constructors and selectors,
 803 -- with the rule that a 1-tuple is represented by the thing itselg
 804 mkCoreTupTy :: [Type] -> Type
 805 mkCoreTupTy [ty] = ty
 806 mkCoreTupTy tys  = mkTupleTy Boxed (length tys) tys
 807
 808 mkCoreTup :: [CoreExpr] -> CoreExpr
 809 -- Builds exactly the specified tuple.
 810 -- No fancy business for big tuples
 811 mkCoreTup []  = Var unitDataConId
 812 mkCoreTup [c] = c
 813 mkCoreTup cs  = mkConApp (tupleCon Boxed (length cs))
 814                          (map (Type . exprType) cs ++ cs)
 815
 816 mkCoreSel :: [Id]       -- The tuple args
 817           -> Id         -- The selected one
 818           -> Id         -- A variable of the same type as the scrutinee
 819           -> CoreExpr   -- Scrutinee
 820           -> CoreExpr
 821 -- mkCoreSel [x,y,z] x v e
 822 -- ===>  case e of v { (x,y,z) -> x
 823 mkCoreSel [var] should_be_the_same_var scrut_var scrut
 824   = ASSERT(var == should_be_the_same_var)
 825     scrut
 826
 827 mkCoreSel vars the_var scrut_var scrut
 828   = ASSERT( notNull vars )
 829     Case scrut scrut_var (idType the_var)
 830          [(DataAlt (tupleCon Boxed (length vars)), vars, Var the_var)]
 831 \end{code}
 832
 833
 834 %************************************************************************
 835 %*                                                                      *
 836 \subsection[mkFailurePair]{Code for pattern-matching and other failures}
 837 %*                                                                      *
 838 %************************************************************************
 839
 840 Generally, we handle pattern matching failure like this: let-bind a
 841 fail-variable, and use that variable if the thing fails:
 842 \begin{verbatim}
 843         let fail.33 = error "Help"
 844         in
 845         case x of
 846                 p1 -> ...
 847                 p2 -> fail.33
 848                 p3 -> fail.33
 849                 p4 -> ...
 850 \end{verbatim}
 851 Then
 852 \begin{itemize}
 853 \item
 854 If the case can't fail, then there'll be no mention of @fail.33@, and the
 855 simplifier will later discard it.
 856
 857 \item
 858 If it can fail in only one way, then the simplifier will inline it.
 859
 860 \item
 861 Only if it is used more than once will the let-binding remain.
 862 \end{itemize}
 863
 864 There's a problem when the result of the case expression is of
 865 unboxed type.  Then the type of @fail.33@ is unboxed too, and
 866 there is every chance that someone will change the let into a case:
 867 \begin{verbatim}
 868         case error "Help" of
 869           fail.33 -> case ....
 870 \end{verbatim}
 871
 872 which is of course utterly wrong.  Rather than drop the condition that
 873 only boxed types can be let-bound, we just turn the fail into a function
 874 for the primitive case:
 875 \begin{verbatim}
 876         let fail.33 :: Void -> Int#
 877             fail.33 = \_ -> error "Help"
 878         in
 879         case x of
 880                 p1 -> ...
 881                 p2 -> fail.33 void
 882                 p3 -> fail.33 void
 883                 p4 -> ...
 884 \end{verbatim}
 885
 886 Now @fail.33@ is a function, so it can be let-bound.
 887
 888 \begin{code}
 889 mkFailurePair :: CoreExpr       -- Result type of the whole case expression
 890               -> DsM (CoreBind, -- Binds the newly-created fail variable
 891                                 -- to either the expression or \ _ -> expression
 892                       CoreExpr) -- Either the fail variable, or fail variable
 893                                 -- applied to unit tuple
 894 mkFailurePair expr
 895   | isUnLiftedType ty
 896   = newFailLocalDs (unitTy `mkFunTy` ty)        `thenDs` \ fail_fun_var ->
 897     newSysLocalDs unitTy                        `thenDs` \ fail_fun_arg ->
 898     returnDs (NonRec fail_fun_var (Lam fail_fun_arg expr),
 899               App (Var fail_fun_var) (Var unitDataConId))
 900
 901   | otherwise
 902   = newFailLocalDs ty           `thenDs` \ fail_var ->
 903     returnDs (NonRec fail_var expr, Var fail_var)
 904   where
 905     ty = exprType expr
 906 \end{code}
 907
 908