ghc/compiler/deSugar/Match.lhs

   1 %
   2 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   3 %
   4 \section[Main_match]{The @match@ function}
   5
   6 \begin{code}
   7 module Match ( match, matchWrapper, matchSimply, matchSinglePat ) where
   8
   9 #include "HsVersions.h"
  10
  11 import CmdLineOpts      ( DynFlag(..), dopt )
  12 import HsSyn
  13 import TcHsSyn          ( hsPatType )
  14 import Check            ( check, ExhaustivePat )
  15 import CoreSyn
  16 import CoreUtils        ( bindNonRec, exprType )
  17 import DsMonad
  18 import DsBinds          ( dsHsNestedBinds )
  19 import DsGRHSs          ( dsGRHSs )
  20 import DsUtils
  21 import Id               ( idName, idType, Id )
  22 import DataCon          ( dataConFieldLabels, dataConInstOrigArgTys, isVanillaDataCon )
  23 import MatchCon         ( matchConFamily )
  24 import MatchLit         ( matchLiterals, matchNPlusKPats, matchNPats, tidyLitPat, tidyNPat )
  25 import PrelInfo         ( pAT_ERROR_ID )
  26 import TcType           ( Type, tcTyConAppArgs )
  27 import Type             ( splitFunTysN )
  28 import TysWiredIn       ( consDataCon, mkTupleTy, mkListTy,
  29                           tupleCon, parrFakeCon, mkPArrTy )
  30 import BasicTypes       ( Boxity(..) )
  31 import ListSetOps       ( runs )
  32 import SrcLoc           ( noSrcSpan, noLoc, unLoc, Located(..) )
  33 import Util             ( lengthExceeds, notNull )
  34 import Name             ( Name )
  35 import Outputable
  36 \end{code}
  37
  38 This function is a wrapper of @match@, it must be called from all the parts where
  39 it was called match, but only substitutes the firs call, ....
  40 if the associated flags are declared, warnings will be issued.
  41 It can not be called matchWrapper because this name already exists :-(
  42
  43 JJCQ 30-Nov-1997
  44
  45 \begin{code}
  46 matchCheck ::  DsMatchContext
  47             -> [Id]             -- Vars rep'ing the exprs we're matching with
  48             -> Type             -- Type of the case expression
  49             -> [EquationInfo]   -- Info about patterns, etc. (type synonym below)
  50             -> DsM MatchResult  -- Desugared result!
  51
  52 matchCheck ctx vars ty qs
  53    = getDOptsDs                                 `thenDs` \ dflags ->
  54      matchCheck_really dflags ctx vars ty qs
  55
  56 matchCheck_really dflags ctx vars ty qs
  57   | incomplete && shadow =
  58       dsShadowWarn ctx eqns_shadow              `thenDs`   \ () ->
  59       dsIncompleteWarn ctx pats                 `thenDs`   \ () ->
  60       match vars ty qs
  61   | incomplete            =
  62       dsIncompleteWarn ctx pats                 `thenDs`   \ () ->
  63       match vars ty qs
  64   | shadow                =
  65       dsShadowWarn ctx eqns_shadow              `thenDs`   \ () ->
  66       match vars ty qs
  67   | otherwise             =
  68       match vars ty qs
  69   where (pats, eqns_shadow) = check qs
  70         incomplete    = want_incomplete && (notNull pats)
  71         want_incomplete = case ctx of
  72                               DsMatchContext RecUpd _ _ ->
  73                                   dopt Opt_WarnIncompletePatternsRecUpd dflags
  74                               _ ->
  75                                   dopt Opt_WarnIncompletePatterns       dflags
  76         shadow        = dopt Opt_WarnOverlappingPatterns dflags
  77                         && not (null eqns_shadow)
  78 \end{code}
  79
  80 This variable shows the maximum number of lines of output generated for warnings.
  81 It will limit the number of patterns/equations displayed to@ maximum_output@.
  82
  83 (ToDo: add command-line option?)
  84
  85 \begin{code}
  86 maximum_output = 4
  87 \end{code}
  88
  89 The next two functions create the warning message.
  90
  91 \begin{code}
  92 dsShadowWarn :: DsMatchContext -> [EquationInfo] -> DsM ()
  93 dsShadowWarn ctx@(DsMatchContext kind _ _) qs = dsWarn warn
  94         where
  95           warn | qs `lengthExceeds` maximum_output
  96                = pp_context ctx (ptext SLIT("are overlapped"))
  97                             (\ f -> vcat (map (ppr_eqn f kind) (take maximum_output qs)) $$
  98                             ptext SLIT("..."))
  99                | otherwise
 100                = pp_context ctx (ptext SLIT("are overlapped"))
 101                             (\ f -> vcat $ map (ppr_eqn f kind) qs)
 102
 103
 104 dsIncompleteWarn :: DsMatchContext -> [ExhaustivePat] -> DsM ()
 105 dsIncompleteWarn ctx@(DsMatchContext kind _ _) pats = dsWarn warn
 106         where
 107           warn = pp_context ctx (ptext SLIT("are non-exhaustive"))
 108                             (\f -> hang (ptext SLIT("Patterns not matched:"))
 109                                    4 ((vcat $ map (ppr_incomplete_pats kind)
 110                                                   (take maximum_output pats))
 111                                       $$ dots))
 112
 113           dots | pats `lengthExceeds` maximum_output = ptext SLIT("...")
 114                | otherwise                           = empty
 115
 116 pp_context NoMatchContext msg rest_of_msg_fun
 117   = (noSrcSpan, ptext SLIT("Some match(es)") <+> hang msg 8 (rest_of_msg_fun id))
 118
 119 pp_context (DsMatchContext kind pats loc) msg rest_of_msg_fun
 120   = (loc, vcat [ptext SLIT("Pattern match(es)") <+> msg,
 121                 sep [ptext SLIT("In") <+> ppr_match <> char ':', nest 4 (rest_of_msg_fun pref)]])
 122   where
 123     (ppr_match, pref)
 124         = case kind of
 125              FunRhs fun -> (pprMatchContext kind, \ pp -> ppr fun <+> pp)
 126              other      -> (pprMatchContext kind, \ pp -> pp)
 127
 128 ppr_pats pats = sep (map ppr pats)
 129
 130 ppr_shadow_pats kind pats
 131   = sep [ppr_pats pats, matchSeparator kind, ptext SLIT("...")]
 132
 133 ppr_incomplete_pats kind (pats,[]) = ppr_pats pats
 134 ppr_incomplete_pats kind (pats,constraints) =
 135                          sep [ppr_pats pats, ptext SLIT("with"),
 136                               sep (map ppr_constraint constraints)]
 137
 138
 139 ppr_constraint (var,pats) = sep [ppr var, ptext SLIT("`notElem`"), ppr pats]
 140
 141 ppr_eqn prefixF kind eqn = prefixF (ppr_shadow_pats kind (eqn_pats eqn))
 142 \end{code}
 143
 144
 145 The function @match@ is basically the same as in the Wadler chapter,
 146 except it is monadised, to carry around the name supply, info about
 147 annotations, etc.
 148
 149 Notes on @match@'s arguments, assuming $m$ equations and $n$ patterns:
 150 \begin{enumerate}
 151 \item
 152 A list of $n$ variable names, those variables presumably bound to the
 153 $n$ expressions being matched against the $n$ patterns.  Using the
 154 list of $n$ expressions as the first argument showed no benefit and
 155 some inelegance.
 156
 157 \item
 158 The second argument, a list giving the ``equation info'' for each of
 159 the $m$ equations:
 160 \begin{itemize}
 161 \item
 162 the $n$ patterns for that equation, and
 163 \item
 164 a list of Core bindings [@(Id, CoreExpr)@ pairs] to be ``stuck on
 165 the front'' of the matching code, as in:
 166 \begin{verbatim}
 167 let <binds>
 168 in  <matching-code>
 169 \end{verbatim}
 170 \item
 171 and finally: (ToDo: fill in)
 172
 173 The right way to think about the ``after-match function'' is that it
 174 is an embryonic @CoreExpr@ with a ``hole'' at the end for the
 175 final ``else expression''.
 176 \end{itemize}
 177
 178 There is a type synonym, @EquationInfo@, defined in module @DsUtils@.
 179
 180 An experiment with re-ordering this information about equations (in
 181 particular, having the patterns available in column-major order)
 182 showed no benefit.
 183
 184 \item
 185 A default expression---what to evaluate if the overall pattern-match
 186 fails.  This expression will (almost?) always be
 187 a measly expression @Var@, unless we know it will only be used once
 188 (as we do in @glue_success_exprs@).
 189
 190 Leaving out this third argument to @match@ (and slamming in lots of
 191 @Var "fail"@s) is a positively {\em bad} idea, because it makes it
 192 impossible to share the default expressions.  (Also, it stands no
 193 chance of working in our post-upheaval world of @Locals@.)
 194 \end{enumerate}
 195 So, the full type signature:
 196 \begin{code}
 197 match :: [Id]             -- Variables rep'ing the exprs we're matching with
 198       -> Type             -- Type of the case expression
 199       -> [EquationInfo]   -- Info about patterns, etc. (type synonym below)
 200       -> DsM MatchResult  -- Desugared result!
 201 \end{code}
 202
 203 Note: @match@ is often called via @matchWrapper@ (end of this module),
 204 a function that does much of the house-keeping that goes with a call
 205 to @match@.
 206
 207 It is also worth mentioning the {\em typical} way a block of equations
 208 is desugared with @match@.  At each stage, it is the first column of
 209 patterns that is examined.  The steps carried out are roughly:
 210 \begin{enumerate}
 211 \item
 212 Tidy the patterns in column~1 with @tidyEqnInfo@ (this may add
 213 bindings to the second component of the equation-info):
 214 \begin{itemize}
 215 \item
 216 Remove the `as' patterns from column~1.
 217 \item
 218 Make all constructor patterns in column~1 into @ConPats@, notably
 219 @ListPats@ and @TuplePats@.
 220 \item
 221 Handle any irrefutable (or ``twiddle'') @LazyPats@.
 222 \end{itemize}
 223 \item
 224 Now {\em unmix} the equations into {\em blocks} [w/ local function
 225 @unmix_eqns@], in which the equations in a block all have variable
 226 patterns in column~1, or they all have constructor patterns in ...
 227 (see ``the mixture rule'' in SLPJ).
 228 \item
 229 Call @matchEqnBlock@ on each block of equations; it will do the
 230 appropriate thing for each kind of column-1 pattern, usually ending up
 231 in a recursive call to @match@.
 232 \end{enumerate}
 233
 234 %************************************************************************
 235 %*                                                                      *
 236 %*  match: empty rule                                                   *
 237 %*                                                                      *
 238 %************************************************************************
 239 \subsection[Match-empty-rule]{The ``empty rule''}
 240
 241 We are a little more paranoid about the ``empty rule'' (SLPJ, p.~87)
 242 than the Wadler-chapter code for @match@ (p.~93, first @match@ clause).
 243 And gluing the ``success expressions'' together isn't quite so pretty.
 244
 245 \begin{code}
 246 match [] ty eqns_info
 247   = ASSERT( not (null eqns_info) )
 248     returnDs (foldr1 combineMatchResults match_results)
 249   where
 250     match_results = [ ASSERT( null (eqn_pats eqn) )
 251                       adjustMatchResult (eqn_wrap eqn) (eqn_rhs eqn)
 252                     | eqn <- eqns_info ]
 253 \end{code}
 254
 255
 256 %************************************************************************
 257 %*                                                                      *
 258 %*  match: non-empty rule                                               *
 259 %*                                                                      *
 260 %************************************************************************
 261 \subsection[Match-nonempty]{@match@ when non-empty: unmixing}
 262
 263 This (more interesting) clause of @match@ uses @tidy_and_unmix_eqns@
 264 (a)~to get `as'- and `twiddle'-patterns out of the way (tidying), and
 265 (b)~to do ``the mixture rule'' (SLPJ, p.~88) [which really {\em
 266 un}mixes the equations], producing a list of equation-info
 267 blocks, each block having as its first column of patterns either all
 268 constructors, or all variables (or similar beasts), etc.
 269
 270 @match_unmixed_eqn_blks@ simply takes the place of the @foldr@ in the
 271 Wadler-chapter @match@ (p.~93, last clause), and @match_unmixed_blk@
 272 corresponds roughly to @matchVarCon@.
 273
 274 \begin{code}
 275 match vars@(v:_) ty eqns_info
 276   = do  { tidy_eqns <- mappM (tidyEqnInfo v) eqns_info
 277         ; let eqns_blks = runs same_family tidy_eqns
 278         ; match_results <- mappM match_block eqns_blks
 279         ; ASSERT( not (null match_results) )
 280           return (foldr1 combineMatchResults match_results) }
 281   where
 282     same_family eqn1 eqn2
 283       = samePatFamily (firstPat eqn1) (firstPat eqn2)
 284
 285     match_block eqns
 286       = case firstPat (head eqns) of
 287           WildPat {}      -> matchVariables  vars ty eqns
 288           ConPatOut {}    -> matchConFamily  vars ty eqns
 289           NPlusKPatOut {} -> matchNPlusKPats vars ty eqns
 290           NPatOut {}      -> matchNPats      vars ty eqns
 291           LitPat {}       -> matchLiterals   vars ty eqns
 292
 293 -- After tidying, there are only five kinds of patterns
 294 samePatFamily (WildPat {})      (WildPat {})      = True
 295 samePatFamily (ConPatOut {})    (ConPatOut {})    = True
 296 samePatFamily (NPlusKPatOut {}) (NPlusKPatOut {}) = True
 297 samePatFamily (NPatOut {})      (NPatOut {})      = True
 298 samePatFamily (LitPat {})       (LitPat {})       = True
 299 samePatFamily _                 _                 = False
 300
 301 matchVariables :: [Id] -> Type -> [EquationInfo] -> DsM MatchResult
 302 -- Real true variables, just like in matchVar, SLPJ p 94
 303 -- No binding to do: they'll all be wildcards by now (done in tidy)
 304 matchVariables (var:vars) ty eqns = match vars ty (shiftEqns eqns)
 305 \end{code}
 306
 307
 308 \end{code}
 309
 310 Tidy up the leftmost pattern in an @EquationInfo@, given the variable @v@
 311 which will be scrutinised.  This means:
 312 \begin{itemize}
 313 \item
 314 Replace variable patterns @x@ (@x /= v@) with the pattern @_@,
 315 together with the binding @x = v@.
 316 \item
 317 Replace the `as' pattern @x@@p@ with the pattern p and a binding @x = v@.
 318 \item
 319 Removing lazy (irrefutable) patterns (you don't want to know...).
 320 \item
 321 Converting explicit tuple-, list-, and parallel-array-pats into ordinary
 322 @ConPats@.
 323 \item
 324 Convert the literal pat "" to [].
 325 \end{itemize}
 326
 327 The result of this tidying is that the column of patterns will include
 328 {\em only}:
 329 \begin{description}
 330 \item[@WildPats@:]
 331 The @VarPat@ information isn't needed any more after this.
 332
 333 \item[@ConPats@:]
 334 @ListPats@, @TuplePats@, etc., are all converted into @ConPats@.
 335
 336 \item[@LitPats@ and @NPats@:]
 337 @LitPats@/@NPats@ of ``known friendly types'' (Int, Char,
 338 Float,  Double, at least) are converted to unboxed form; e.g.,
 339 \tr{(NPat (HsInt i) _ _)} is converted to:
 340 \begin{verbatim}
 341 (ConPat I# _ _ [LitPat (HsIntPrim i)])
 342 \end{verbatim}
 343 \end{description}
 344
 345 \begin{code}
 346 tidyEqnInfo :: Id -> EquationInfo -> DsM EquationInfo
 347         -- DsM'd because of internal call to dsHsNestedBinds
 348         --      and mkSelectorBinds.
 349         -- "tidy1" does the interesting stuff, looking at
 350         -- one pattern and fiddling the list of bindings.
 351         --
 352         -- POST CONDITION: head pattern in the EqnInfo is
 353         --      WildPat
 354         --      ConPat
 355         --      NPat
 356         --      LitPat
 357         --      NPlusKPat
 358         -- but no other
 359
 360 tidyEqnInfo v eqn@(EqnInfo { eqn_wrap = wrap, eqn_pats = pat : pats })
 361   = tidy1 v wrap pat    `thenDs` \ (wrap', pat') ->
 362     returnDs (eqn { eqn_wrap = wrap', eqn_pats = pat' : pats })
 363
 364 tidy1 :: Id                     -- The Id being scrutinised
 365       -> DsWrapper              -- Previous wrapping bindings
 366       -> Pat Id                 -- The pattern against which it is to be matched
 367       -> DsM (DsWrapper,        -- Extra bindings around what to do afterwards
 368               Pat Id)           -- Equivalent pattern
 369
 370 -- The extra bindings etc are all wrapped around the RHS of the match
 371 -- so they are only available when matching is complete.  But that's ok
 372 -- becuase, for example, in the pattern x@(...), the x can only be
 373 -- used in the RHS, not in the nested pattern, nor subsquent patterns
 374 --
 375 -- However this does have an awkward consequence.  The bindings in
 376 -- a VarPatOut get wrapped around the result in right to left order,
 377 -- rather than left to right.  This only matters if one set of
 378 -- bindings can mention things used in another, and that can happen
 379 -- if we allow equality dictionary bindings of form d1=d2.
 380 -- bindIInstsOfLocalFuns is now careful not to do this, but it's a wart.
 381 -- (Without this care in bindInstsOfLocalFuns, compiling
 382 -- Data.Generics.Schemes.hs fails in function everywhereBut.)
 383
 384 -------------------------------------------------------
 385 --      (pat', mr') = tidy1 v pat mr
 386 -- tidies the *outer level only* of pat, giving pat'
 387 -- It eliminates many pattern forms (as-patterns, variable patterns,
 388 -- list patterns, etc) yielding one of:
 389 --      WildPat
 390 --      ConPatOut
 391 --      LitPat
 392 --      NPat
 393 --      NPlusKPat
 394
 395 tidy1 v wrap (ParPat pat)      = tidy1 v wrap (unLoc pat)
 396 tidy1 v wrap (SigPatOut pat _) = tidy1 v wrap (unLoc pat)
 397 tidy1 v wrap (WildPat ty)      = returnDs (wrap, WildPat ty)
 398
 399         -- case v of { x -> mr[] }
 400         -- = case v of { _ -> let x=v in mr[] }
 401 tidy1 v wrap (VarPat var)
 402   = returnDs (wrap . wrapBind var v, WildPat (idType var))
 403
 404 tidy1 v wrap (VarPatOut var binds)
 405   = do  { prs <- dsHsNestedBinds binds
 406         ; return (wrap . wrapBind var v . mkDsLet (Rec prs),
 407                   WildPat (idType var)) }
 408
 409         -- case v of { x@p -> mr[] }
 410         -- = case v of { p -> let x=v in mr[] }
 411 tidy1 v wrap (AsPat (L _ var) pat)
 412   = tidy1 v (wrap . wrapBind var v) (unLoc pat)
 413
 414
 415 {- now, here we handle lazy patterns:
 416     tidy1 v ~p bs = (v, v1 = case v of p -> v1 :
 417                         v2 = case v of p -> v2 : ... : bs )
 418
 419     where the v_i's are the binders in the pattern.
 420
 421     ToDo: in "v_i = ... -> v_i", are the v_i's really the same thing?
 422
 423     The case expr for v_i is just: match [v] [(p, [], \ x -> Var v_i)] any_expr
 424 -}
 425
 426 tidy1 v wrap (LazyPat pat)
 427   = do  { v' <- newSysLocalDs (idType v)
 428         ; sel_prs <- mkSelectorBinds pat (Var v)
 429         ; let sel_binds =  [NonRec b rhs | (b,rhs) <- sel_prs]
 430         ; returnDs (wrap . wrapBind v' v . mkDsLets sel_binds,
 431                     WildPat (idType v)) }
 432
 433 -- re-express <con-something> as (ConPat ...) [directly]
 434
 435 tidy1 v wrap (ConPatOut (L loc con) ex_tvs dicts binds ps pat_ty)
 436   = returnDs (wrap, ConPatOut (L loc con) ex_tvs dicts binds tidy_ps pat_ty)
 437   where
 438     tidy_ps = PrefixCon (tidy_con con pat_ty ps)
 439
 440 tidy1 v wrap (ListPat pats ty)
 441   = returnDs (wrap, unLoc list_ConPat)
 442   where
 443     list_ty     = mkListTy ty
 444     list_ConPat = foldr (\ x y -> mkPrefixConPat consDataCon [x, y] list_ty)
 445                         (mkNilPat list_ty)
 446                         pats
 447
 448 -- Introduce fake parallel array constructors to be able to handle parallel
 449 -- arrays with the existing machinery for constructor pattern
 450 tidy1 v wrap (PArrPat pats ty)
 451   = returnDs (wrap, unLoc parrConPat)
 452   where
 453     arity      = length pats
 454     parrConPat = mkPrefixConPat (parrFakeCon arity) pats (mkPArrTy ty)
 455
 456 tidy1 v wrap (TuplePat pats boxity)
 457   = returnDs (wrap, unLoc tuple_ConPat)
 458   where
 459     arity = length pats
 460     tuple_ConPat = mkPrefixConPat (tupleCon boxity arity) pats
 461                                   (mkTupleTy boxity arity (map hsPatType pats))
 462
 463 tidy1 v wrap (DictPat dicts methods)
 464   = case num_of_d_and_ms of
 465         0 -> tidy1 v wrap (TuplePat [] Boxed)
 466         1 -> tidy1 v wrap (unLoc (head dict_and_method_pats))
 467         _ -> tidy1 v wrap (TuplePat dict_and_method_pats Boxed)
 468   where
 469     num_of_d_and_ms      = length dicts + length methods
 470     dict_and_method_pats = map nlVarPat (dicts ++ methods)
 471
 472 -- LitPats: we *might* be able to replace these w/ a simpler form
 473 tidy1 v wrap pat@(LitPat lit)
 474   = returnDs (wrap, unLoc (tidyLitPat lit (noLoc pat)))
 475
 476 -- NPats: we *might* be able to replace these w/ a simpler form
 477 tidy1 v wrap pat@(NPatOut lit lit_ty _)
 478   = returnDs (wrap, unLoc (tidyNPat lit lit_ty (noLoc pat)))
 479
 480 -- and everything else goes through unchanged...
 481
 482 tidy1 v wrap non_interesting_pat
 483   = returnDs (wrap, non_interesting_pat)
 484
 485
 486 tidy_con data_con pat_ty (PrefixCon ps)   = ps
 487 tidy_con data_con pat_ty (InfixCon p1 p2) = [p1,p2]
 488 tidy_con data_con pat_ty (RecCon rpats)
 489   | null rpats
 490   =     -- Special case for C {}, which can be used for
 491         -- a constructor that isn't declared to have
 492         -- fields at all
 493     map (noLoc . WildPat) con_arg_tys'
 494
 495   | otherwise
 496   = ASSERT( isVanillaDataCon data_con )
 497         -- We're in a record case, so the data con must be vanilla
 498         -- and hence no existentials to worry about
 499     map mk_pat tagged_arg_tys
 500   where
 501         -- Boring stuff to find the arg-tys of the constructor
 502
 503     inst_tys         = tcTyConAppArgs pat_ty    -- Newtypes must be opaque
 504     con_arg_tys'     = dataConInstOrigArgTys data_con inst_tys
 505     tagged_arg_tys   = con_arg_tys' `zip` dataConFieldLabels data_con
 506
 507         -- mk_pat picks a WildPat of the appropriate type for absent fields,
 508         -- and the specified pattern for present fields
 509     mk_pat (arg_ty, lbl) =
 510         case [ pat | (sel_id,pat) <- rpats, idName (unLoc sel_id) == lbl] of
 511           (pat:pats) -> ASSERT( null pats ) pat
 512           []         -> noLoc (WildPat arg_ty)
 513 \end{code}
 514
 515 \noindent
 516 {\bf Previous @matchTwiddled@ stuff:}
 517
 518 Now we get to the only interesting part; note: there are choices for
 519 translation [from Simon's notes]; translation~1:
 520 \begin{verbatim}
 521 deTwiddle [s,t] e
 522 \end{verbatim}
 523 returns
 524 \begin{verbatim}
 525 [ w = e,
 526   s = case w of [s,t] -> s
 527   t = case w of [s,t] -> t
 528 ]
 529 \end{verbatim}
 530
 531 Here \tr{w} is a fresh variable, and the \tr{w}-binding prevents multiple
 532 evaluation of \tr{e}.  An alternative translation (No.~2):
 533 \begin{verbatim}
 534 [ w = case e of [s,t] -> (s,t)
 535   s = case w of (s,t) -> s
 536   t = case w of (s,t) -> t
 537 ]
 538 \end{verbatim}
 539
 540 %************************************************************************
 541 %*                                                                      *
 542 \subsubsection[improved-unmixing]{UNIMPLEMENTED idea for improved unmixing}
 543 %*                                                                      *
 544 %************************************************************************
 545
 546 We might be able to optimise unmixing when confronted by
 547 only-one-constructor-possible, of which tuples are the most notable
 548 examples.  Consider:
 549 \begin{verbatim}
 550 f (a,b,c) ... = ...
 551 f d ... (e:f) = ...
 552 f (g,h,i) ... = ...
 553 f j ...       = ...
 554 \end{verbatim}
 555 This definition would normally be unmixed into four equation blocks,
 556 one per equation.  But it could be unmixed into just one equation
 557 block, because if the one equation matches (on the first column),
 558 the others certainly will.
 559
 560 You have to be careful, though; the example
 561 \begin{verbatim}
 562 f j ...       = ...
 563 -------------------
 564 f (a,b,c) ... = ...
 565 f d ... (e:f) = ...
 566 f (g,h,i) ... = ...
 567 \end{verbatim}
 568 {\em must} be broken into two blocks at the line shown; otherwise, you
 569 are forcing unnecessary evaluation.  In any case, the top-left pattern
 570 always gives the cue.  You could then unmix blocks into groups of...
 571 \begin{description}
 572 \item[all variables:]
 573 As it is now.
 574 \item[constructors or variables (mixed):]
 575 Need to make sure the right names get bound for the variable patterns.
 576 \item[literals or variables (mixed):]
 577 Presumably just a variant on the constructor case (as it is now).
 578 \end{description}
 579
 580 %************************************************************************
 581 %*                                                                      *
 582 %*  matchWrapper: a convenient way to call @match@                      *
 583 %*                                                                      *
 584 %************************************************************************
 585 \subsection[matchWrapper]{@matchWrapper@: a convenient interface to @match@}
 586
 587 Calls to @match@ often involve similar (non-trivial) work; that work
 588 is collected here, in @matchWrapper@.  This function takes as
 589 arguments:
 590 \begin{itemize}
 591 \item
 592 Typchecked @Matches@ (of a function definition, or a case or lambda
 593 expression)---the main input;
 594 \item
 595 An error message to be inserted into any (runtime) pattern-matching
 596 failure messages.
 597 \end{itemize}
 598
 599 As results, @matchWrapper@ produces:
 600 \begin{itemize}
 601 \item
 602 A list of variables (@Locals@) that the caller must ``promise'' to
 603 bind to appropriate values; and
 604 \item
 605 a @CoreExpr@, the desugared output (main result).
 606 \end{itemize}
 607
 608 The main actions of @matchWrapper@ include:
 609 \begin{enumerate}
 610 \item
 611 Flatten the @[TypecheckedMatch]@ into a suitable list of
 612 @EquationInfo@s.
 613 \item
 614 Create as many new variables as there are patterns in a pattern-list
 615 (in any one of the @EquationInfo@s).
 616 \item
 617 Create a suitable ``if it fails'' expression---a call to @error@ using
 618 the error-string input; the {\em type} of this fail value can be found
 619 by examining one of the RHS expressions in one of the @EquationInfo@s.
 620 \item
 621 Call @match@ with all of this information!
 622 \end{enumerate}
 623
 624 \begin{code}
 625 matchWrapper :: HsMatchContext Name     -- For shadowing warning messages
 626              -> MatchGroup Id           -- Matches being desugared
 627              -> DsM ([Id], CoreExpr)    -- Results
 628 \end{code}
 629
 630  There is one small problem with the Lambda Patterns, when somebody
 631  writes something similar to:
 632 \begin{verbatim}
 633     (\ (x:xs) -> ...)
 634 \end{verbatim}
 635  he/she don't want a warning about incomplete patterns, that is done with
 636  the flag @opt_WarnSimplePatterns@.
 637  This problem also appears in the:
 638 \begin{itemize}
 639 \item @do@ patterns, but if the @do@ can fail
 640       it creates another equation if the match can fail
 641       (see @DsExpr.doDo@ function)
 642 \item @let@ patterns, are treated by @matchSimply@
 643    List Comprension Patterns, are treated by @matchSimply@ also
 644 \end{itemize}
 645
 646 We can't call @matchSimply@ with Lambda patterns,
 647 due to the fact that lambda patterns can have more than
 648 one pattern, and match simply only accepts one pattern.
 649
 650 JJQC 30-Nov-1997
 651
 652 \begin{code}
 653 matchWrapper ctxt (MatchGroup matches match_ty)
 654   = do  { eqns_info <- mapM mk_eqn_info matches
 655         ; dflags <- getDOptsDs
 656         ; locn <- getSrcSpanDs
 657         ; let   ds_ctxt      = DsMatchContext ctxt arg_pats locn
 658                 error_string = matchContextErrString ctxt
 659
 660         ; new_vars     <- selectMatchVars arg_pats pat_tys
 661         ; match_result <- match_fun dflags ds_ctxt new_vars rhs_ty eqns_info
 662
 663         ; fail_expr <- mkErrorAppDs pAT_ERROR_ID rhs_ty error_string
 664         ; result_expr <- extractMatchResult match_result fail_expr
 665         ; return (new_vars, result_expr) }
 666   where
 667     arg_pats          = map unLoc (hsLMatchPats (head matches))
 668     n_pats            = length arg_pats
 669     (pat_tys, rhs_ty) = splitFunTysN n_pats match_ty
 670
 671     mk_eqn_info (L _ (Match pats _ grhss))
 672       = do { let upats = map unLoc pats
 673            ; match_result <- dsGRHSs ctxt upats grhss rhs_ty
 674            ; return (EqnInfo { eqn_wrap = idWrapper,
 675                                eqn_pats = upats,
 676                                eqn_rhs = match_result}) }
 677
 678     match_fun dflags ds_ctxt
 679        = case ctxt of
 680            LambdaExpr | dopt Opt_WarnSimplePatterns dflags -> matchCheck ds_ctxt
 681                       | otherwise                          -> match
 682            _                                               -> matchCheck ds_ctxt
 683 \end{code}
 684
 685 %************************************************************************
 686 %*                                                                      *
 687 \subsection[matchSimply]{@matchSimply@: match a single expression against a single pattern}
 688 %*                                                                      *
 689 %************************************************************************
 690
 691 @mkSimpleMatch@ is a wrapper for @match@ which deals with the
 692 situation where we want to match a single expression against a single
 693 pattern. It returns an expression.
 694
 695 \begin{code}
 696 matchSimply :: CoreExpr                 -- Scrutinee
 697             -> HsMatchContext Name      -- Match kind
 698             -> LPat Id                  -- Pattern it should match
 699             -> CoreExpr                 -- Return this if it matches
 700             -> CoreExpr                 -- Return this if it doesn't
 701             -> DsM CoreExpr
 702
 703 matchSimply scrut kind pat result_expr fail_expr
 704   = getSrcSpanDs                                `thenDs` \ locn ->
 705     let
 706       ctx          = DsMatchContext kind [unLoc pat] locn
 707       match_result = cantFailMatchResult result_expr
 708       rhs_ty       = exprType fail_expr
 709         -- Use exprType of fail_expr, because won't refine in the case of failure!
 710     in
 711     matchSinglePat scrut ctx pat rhs_ty match_result    `thenDs` \ match_result' ->
 712     extractMatchResult match_result' fail_expr
 713
 714
 715 matchSinglePat :: CoreExpr -> DsMatchContext -> LPat Id
 716                -> Type -> MatchResult -> DsM MatchResult
 717 matchSinglePat (Var var) ctx pat ty match_result
 718   = getDOptsDs                                  `thenDs` \ dflags ->
 719     match_fn dflags [var] ty [EqnInfo { eqn_wrap = idWrapper,
 720                                         eqn_pats = [unLoc pat],
 721                                         eqn_rhs  = match_result }]
 722   where
 723     match_fn dflags
 724        | dopt Opt_WarnSimplePatterns dflags = matchCheck ctx
 725        | otherwise                          = match
 726
 727 matchSinglePat scrut ctx pat ty match_result
 728   = selectSimpleMatchVarL pat                           `thenDs` \ var ->
 729     matchSinglePat (Var var) ctx pat ty match_result    `thenDs` \ match_result' ->
 730     returnDs (adjustMatchResult (bindNonRec var scrut) match_result')
 731 \end{code}
 732