ghc/compiler/deSugar/MatchLit.lhs

   1 %
   2 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   3 %
   4 \section[MatchLit]{Pattern-matching literal patterns}
   5
   6 \begin{code}
   7 module MatchLit ( matchLiterals ) where
   8
   9 #include "HsVersions.h"
  10
  11 import {-# SOURCE #-} Match  ( match )
  12 import {-# SOURCE #-} DsExpr ( dsExpr )
  13
  14 import HsSyn            ( HsLit(..), OutPat(..), HsExpr(..) )
  15 import TcHsSyn          ( TypecheckedHsExpr, TypecheckedPat )
  16 import CoreSyn          ( Expr(..), Bind(..) )
  17 import Id               ( Id )
  18
  19 import DsMonad
  20 import DsUtils
  21
  22 import Const            ( mkMachInt, Literal(..) )
  23 import PrimRep          ( PrimRep(IntRep) )
  24 import Maybes           ( catMaybes )
  25 import Type             ( Type, isUnLiftedType )
  26 import Util             ( panic, assertPanic )
  27 \end{code}
  28
  29 \begin{code}
  30 matchLiterals :: [Id]
  31               -> [EquationInfo]
  32               -> DsM MatchResult
  33 \end{code}
  34
  35 This first one is a {\em special case} where the literal patterns are
  36 unboxed numbers (NB: the fiddling introduced by @tidyEqnInfo@).  We
  37 want to avoid using the ``equality'' stuff provided by the
  38 typechecker, and do a real ``case'' instead.  In that sense, the code
  39 is much like @matchConFamily@, which uses @match_cons_used@ to create
  40 the alts---here we use @match_prims_used@.
  41
  42 \begin{code}
  43 matchLiterals all_vars@(var:vars) eqns_info@(EqnInfo n ctx (LitPat literal lit_ty : ps1) _ : eqns)
  44   = -- GENERATE THE ALTS
  45     match_prims_used vars eqns_info `thenDs` \ prim_alts ->
  46
  47     -- MAKE THE PRIMITIVE CASE
  48     returnDs (mkCoPrimCaseMatchResult var prim_alts)
  49   where
  50     match_prims_used _ [{-no more eqns-}] = returnDs []
  51
  52     match_prims_used vars eqns_info@(EqnInfo n ctx ((LitPat literal lit_ty):ps1) _ : eqns)
  53       = let
  54             (shifted_eqns_for_this_lit, eqns_not_for_this_lit)
  55               = partitionEqnsByLit Nothing literal eqns_info
  56         in
  57         -- recursive call to make other alts...
  58         match_prims_used vars eqns_not_for_this_lit       `thenDs` \ rest_of_alts ->
  59
  60         -- (prim pats have no args; no selectMatchVars as in match_cons_used)
  61         -- now do the business to make the alt for _this_ LitPat ...
  62         match vars shifted_eqns_for_this_lit    `thenDs` \ match_result ->
  63         returnDs (
  64             (mk_core_lit lit_ty literal, match_result)
  65             : rest_of_alts
  66         )
  67       where
  68         mk_core_lit :: Type -> HsLit -> Literal
  69
  70         mk_core_lit ty (HsIntPrim     i) = mkMachInt  i
  71         mk_core_lit ty (HsCharPrim    c) = MachChar   c
  72         mk_core_lit ty (HsStringPrim  s) = MachStr    s
  73         mk_core_lit ty (HsFloatPrim   f) = MachFloat  f
  74         mk_core_lit ty (HsDoublePrim  d) = MachDouble d
  75         mk_core_lit ty (HsLitLit      s) = ASSERT(isUnLiftedType ty)
  76                                            MachLitLit s (panic "MatchLit.matchLiterals:mk_core_lit:HsLitLit; typePrimRep???")
  77         mk_core_lit ty other             = panic "matchLiterals:mk_core_lit:unhandled"
  78 \end{code}
  79
  80 \begin{code}
  81 matchLiterals all_vars@(var:vars) eqns_info@(EqnInfo n ctx ((NPat literal lit_ty eq_chk):ps1) _ : eqns)
  82   = let
  83         (shifted_eqns_for_this_lit, eqns_not_for_this_lit)
  84           = partitionEqnsByLit Nothing literal eqns_info
  85     in
  86     dsExpr (HsApp eq_chk (HsVar var))                     `thenDs` \ pred_expr ->
  87     match vars shifted_eqns_for_this_lit                  `thenDs` \ inner_match_result ->
  88     let
  89         match_result1 = mkGuardedMatchResult pred_expr inner_match_result
  90     in
  91     if (null eqns_not_for_this_lit)
  92     then
  93         returnDs match_result1
  94     else
  95         matchLiterals all_vars eqns_not_for_this_lit      `thenDs` \ match_result2 ->
  96         returnDs (combineMatchResults match_result1 match_result2)
  97 \end{code}
  98
  99 For an n+k pattern, we use the various magic expressions we've been given.
 100 We generate:
 101 \begin{verbatim}
 102     if ge var lit then
 103         let n = sub var lit
 104         in  <expr-for-a-successful-match>
 105     else
 106         <try-next-pattern-or-whatever>
 107 \end{verbatim}
 108
 109
 110 \begin{code}
 111 matchLiterals all_vars@(var:vars) eqns_info@(EqnInfo n ctx ((NPlusKPat master_n k ty ge sub):ps1) _ : eqns)
 112   = let
 113         (shifted_eqns_for_this_lit, eqns_not_for_this_lit)
 114           = partitionEqnsByLit (Just master_n) k eqns_info
 115     in
 116     match vars shifted_eqns_for_this_lit        `thenDs` \ inner_match_result ->
 117
 118     dsExpr (HsApp ge (HsVar var))               `thenDs` \ ge_expr ->
 119     dsExpr (HsApp sub (HsVar var))              `thenDs` \ nminusk_expr ->
 120
 121     let
 122         match_result1 = mkGuardedMatchResult ge_expr $
 123                         mkCoLetsMatchResult [NonRec master_n nminusk_expr] $
 124                         inner_match_result
 125     in
 126     if (null eqns_not_for_this_lit)
 127     then
 128         returnDs match_result1
 129     else
 130         matchLiterals all_vars eqns_not_for_this_lit    `thenDs` \ match_result2 ->
 131         returnDs (combineMatchResults match_result1 match_result2)
 132 \end{code}
 133
 134 Given a blob of LitPats/NPats, we want to split them into those
 135 that are ``same''/different as one we are looking at.  We need to know
 136 whether we're looking at a LitPat/NPat, and what literal we're after.
 137
 138 \begin{code}
 139 partitionEqnsByLit :: Maybe Id  -- (Just v) for N-plus-K patterns, where v
 140                                 -- is the "master" variable;
 141                                 -- Nothing for NPats and LitPats
 142                    -> HsLit
 143                    -> [EquationInfo]
 144                    -> ([EquationInfo],  -- These ones are for this lit, AND
 145                                         -- they've been "shifted" by stripping
 146                                         -- off the first pattern
 147                        [EquationInfo]   -- These are not for this lit; they
 148                                         -- are exactly as fed in.
 149                       )
 150
 151 partitionEqnsByLit nPlusK lit eqns
 152   = ( \ (xs,ys) -> (catMaybes xs, catMaybes ys))
 153         (unzip (map (partition_eqn nPlusK lit) eqns))
 154   where
 155     partition_eqn :: Maybe Id -> HsLit -> EquationInfo ->
 156                 (Maybe EquationInfo, Maybe EquationInfo)
 157
 158     partition_eqn Nothing lit (EqnInfo n ctx (LitPat k _ : remaining_pats) match_result)
 159       | lit `eq_lit` k  = (Just (EqnInfo n ctx remaining_pats match_result), Nothing)
 160                           -- NB the pattern is stripped off the EquationInfo
 161
 162     partition_eqn Nothing lit (EqnInfo n ctx (NPat k _ _ : remaining_pats) match_result)
 163       | lit `eq_lit` k  = (Just (EqnInfo n ctx remaining_pats match_result), Nothing)
 164                           -- NB the pattern is stripped off the EquationInfo
 165
 166     partition_eqn (Just master_n) lit  (EqnInfo n ctx (NPlusKPat n' k _ _ _ : remaining_pats) match_result)
 167       | lit `eq_lit` k  = (Just (EqnInfo n ctx remaining_pats new_match_result), Nothing)
 168                           -- NB the pattern is stripped off the EquationInfo
 169       where
 170         new_match_result | master_n == n' = match_result
 171                          | otherwise      = mkCoLetsMatchResult [NonRec n' (Var master_n)] match_result
 172
 173         -- Wild-card patterns, which will only show up in the shadows, go into both groups
 174     partition_eqn nPlusK lit eqn@(EqnInfo n ctx (WildPat _ : remaining_pats) match_result)
 175                         = (Just (EqnInfo n ctx remaining_pats match_result), Just eqn)
 176
 177         -- Default case; not for this pattern
 178     partition_eqn nPlusK lit eqn = (Nothing, Just eqn)
 179
 180 -- ToDo: meditate about this equality business...
 181
 182 eq_lit (HsInt  i1)       (HsInt  i2)       = i1 == i2
 183 eq_lit (HsFrac f1)       (HsFrac f2)       = f1 == f2
 184
 185 eq_lit (HsIntPrim i1)    (HsIntPrim i2)    = i1 == i2
 186 eq_lit (HsFloatPrim f1)  (HsFloatPrim f2)  = f1 == f2
 187 eq_lit (HsDoublePrim d1) (HsDoublePrim d2) = d1 == d2
 188 eq_lit (HsChar c1)       (HsChar c2)       = c1 == c2
 189 eq_lit (HsCharPrim c1)   (HsCharPrim c2)   = c1 == c2
 190 eq_lit (HsString s1)     (HsString s2)     = s1 == s2
 191 eq_lit (HsStringPrim s1) (HsStringPrim s2) = s1 == s2
 192 eq_lit (HsLitLit s1)     (HsLitLit s2)     = s1 == s2 -- ToDo: ??? (dubious)
 193 eq_lit other1            other2            = panic "matchLiterals:eq_lit"
 194 \end{code}