ghc/compiler/ghci/Linker.lhs

   1 %
   2 % (c) The University of Glasgow 2000
   3 %
   4
   5 -- --------------------------------------
   6 --      The dynamic linker for GHCi
   7 -- --------------------------------------
   8
   9 This module deals with the top-level issues of dynamic linking,
  10 calling the object-code linker and the byte-code linker where
  11 necessary.
  12
  13
  14 \begin{code}
  15
  16 {-# OPTIONS -optc-DNON_POSIX_SOURCE -#include "Linker.h" #-}
  17
  18 module Linker ( HValue, initDynLinker, showLinkerState,
  19                 linkExpr, unload, extendLinkEnv,
  20                 linkPackages,
  21         ) where
  22
  23 #include "../includes/config.h"
  24 #include "HsVersions.h"
  25
  26 import ObjLink          ( loadDLL, loadObj, unloadObj, resolveObjs, initObjLinker )
  27 import ByteCodeLink     ( HValue, ClosureEnv, extendClosureEnv, linkBCO )
  28 import ByteCodeItbls    ( ItblEnv )
  29 import ByteCodeAsm      ( CompiledByteCode(..), bcoFreeNames, UnlinkedBCO(..))
  30
  31 import Packages
  32 import DriverState      ( v_Library_paths, v_Opt_l, v_Ld_inputs, getStaticOpts, v_ExplicitPackages )
  33 #ifdef darwin_TARGET_OS
  34 import DriverState      ( v_Cmdline_frameworks, v_Framework_paths )
  35 #endif
  36 import Finder           ( findModule, findLinkable )
  37 import HscTypes
  38 import Name             ( Name,  nameModule, isExternalName )
  39 import NameEnv
  40 import NameSet          ( nameSetToList )
  41 import Module
  42 import FastString       ( FastString(..), unpackFS )
  43 import ListSetOps       ( minusList )
  44 import CmdLineOpts      ( DynFlags(verbosity), getDynFlags )
  45 import BasicTypes       ( SuccessFlag(..), succeeded, failed )
  46 import Outputable
  47 import Panic            ( GhcException(..) )
  48 import Util             ( zipLazy, global )
  49
  50 -- Standard libraries
  51 import Control.Monad    ( when, filterM, foldM )
  52
  53 import Data.IORef       ( IORef, readIORef, writeIORef )
  54 import Data.List        ( partition, nub )
  55
  56 import System.IO        ( putStr, putStrLn, hPutStrLn, stderr, fixIO )
  57 import System.Directory ( doesFileExist )
  58
  59 import Control.Exception ( block, throwDyn )
  60
  61 #if __GLASGOW_HASKELL__ >= 503
  62 import GHC.IOBase       ( IO(..) )
  63 #else
  64 import PrelIOBase       ( IO(..) )
  65 #endif
  66 \end{code}
  67
  68
  69 %************************************************************************
  70 %*                                                                      *
  71                         The Linker's state
  72 %*                                                                      *
  73 %************************************************************************
  74
  75 The persistent linker state *must* match the actual state of the
  76 C dynamic linker at all times, so we keep it in a private global variable.
  77
  78
  79 The PersistentLinkerState maps Names to actual closures (for
  80 interpreted code only), for use during linking.
  81
  82 \begin{code}
  83 GLOBAL_VAR(v_PersistentLinkerState, panic "Dynamic linker not initialised", PersistentLinkerState)
  84 GLOBAL_VAR(v_InitLinkerDone, False, Bool)       -- Set True when dynamic linker is initialised
  85
  86 data PersistentLinkerState
  87    = PersistentLinkerState {
  88
  89         -- Current global mapping from Names to their true values
  90         closure_env :: ClosureEnv,
  91
  92         -- The current global mapping from RdrNames of DataCons to
  93         -- info table addresses.
  94         -- When a new Unlinked is linked into the running image, or an existing
  95         -- module in the image is replaced, the itbl_env must be updated
  96         -- appropriately.
  97         itbl_env    :: ItblEnv,
  98
  99         -- The currently loaded interpreted modules (home package)
 100         bcos_loaded :: [Linkable],
 101
 102         -- And the currently-loaded compiled modules (home package)
 103         objs_loaded :: [Linkable],
 104
 105         -- The currently-loaded packages; always object code
 106         -- Held, as usual, in dependency order; though I am not sure if
 107         -- that is really important
 108         pkgs_loaded :: [PackageName]
 109      }
 110
 111 emptyPLS :: PersistentLinkerState
 112 emptyPLS = PersistentLinkerState { closure_env = emptyNameEnv,
 113                                    itbl_env    = emptyNameEnv,
 114                                    pkgs_loaded = init_pkgs_loaded,
 115                                    bcos_loaded = [],
 116                                    objs_loaded = [] }
 117
 118 -- Packages that don't need loading, because the compiler
 119 -- shares them with the interpreted program.
 120 --
 121 -- The linker's symbol table is populated with RTS symbols using an
 122 -- explicit list.  See rts/Linker.c for details.
 123 init_pkgs_loaded = [ FSLIT("rts") ]
 124 \end{code}
 125
 126 \begin{code}
 127 extendLinkEnv :: [(Name,HValue)] -> IO ()
 128 -- Automatically discards shadowed bindings
 129 extendLinkEnv new_bindings
 130   = do  pls <- readIORef v_PersistentLinkerState
 131         let new_closure_env = extendClosureEnv (closure_env pls) new_bindings
 132             new_pls = pls { closure_env = new_closure_env }
 133         writeIORef v_PersistentLinkerState new_pls
 134
 135 -- filterNameMap removes from the environment all entries except
 136 --      those for a given set of modules;
 137 -- Note that this removes all *local* (i.e. non-isExternal) names too
 138 --      (these are the temporary bindings from the command line).
 139 -- Used to filter both the ClosureEnv and ItblEnv
 140
 141 filterNameMap :: [ModuleName] -> NameEnv (Name, a) -> NameEnv (Name, a)
 142 filterNameMap mods env
 143    = filterNameEnv keep_elt env
 144    where
 145      keep_elt (n,_) = isExternalName n
 146                       && (moduleName (nameModule n) `elem` mods)
 147 \end{code}
 148
 149
 150 \begin{code}
 151 showLinkerState :: IO ()
 152 -- Display the persistent linker state
 153 showLinkerState
 154   = do pls <- readIORef v_PersistentLinkerState
 155        printDump (vcat [text "----- Linker state -----",
 156                         text "Pkgs:" <+> ppr (pkgs_loaded pls),
 157                         text "Objs:" <+> ppr (objs_loaded pls),
 158                         text "BCOs:" <+> ppr (bcos_loaded pls)])
 159 \end{code}
 160
 161
 162
 163
 164 %************************************************************************
 165 %*                                                                      *
 166 \subsection{Initialisation}
 167 %*                                                                      *
 168 %************************************************************************
 169
 170 We initialise the dynamic linker by
 171
 172 a) calling the C initialisation procedure
 173
 174 b) Loading any packages specified on the command line,
 175    now held in v_ExplicitPackages
 176
 177 c) Loading any packages specified on the command line,
 178    now held in the -l options in v_Opt_l
 179
 180 d) Loading any .o/.dll files specified on the command line,
 181    now held in v_Ld_inputs
 182
 183 e) Loading any MacOS frameworks
 184
 185 \begin{code}
 186 initDynLinker :: IO ()
 187 -- This function is idempotent; if called more than once, it does nothing
 188 -- This is useful in Template Haskell, where we call it before trying to link
 189 initDynLinker
 190   = do  { done <- readIORef v_InitLinkerDone
 191         ; if done then return ()
 192                   else do { writeIORef v_InitLinkerDone True
 193                           ; reallyInitDynLinker }
 194         }
 195
 196 reallyInitDynLinker
 197   = do  { dflags <- getDynFlags
 198
 199                 -- Initialise the linker state
 200         ; writeIORef v_PersistentLinkerState emptyPLS
 201
 202                 -- (a) initialise the C dynamic linker
 203         ; initObjLinker
 204
 205                 -- (b) Load packages from the command-line
 206         ; expl <- readIORef v_ExplicitPackages
 207         ; linkPackages dflags expl
 208
 209                 -- (c) Link libraries from the command-line
 210         ; opt_l  <- getStaticOpts v_Opt_l
 211         ; let minus_ls = [ lib | '-':'l':lib <- opt_l ]
 212
 213                 -- (d) Link .o files from the command-line
 214         ; lib_paths    <- readIORef v_Library_paths
 215         ; cmdline_objs <- readIORef v_Ld_inputs
 216
 217                 -- (e) Link any MacOS frameworks
 218 #ifdef darwin_TARGET_OS
 219         ; framework_paths <- readIORef v_Framework_paths
 220         ; frameworks      <- readIORef v_Cmdline_frameworks
 221 #else
 222         ; let frameworks      = []
 223         ; let framework_paths = []
 224 #endif
 225                 -- Finally do (c),(d),(e)
 226         ; let cmdline_lib_specs = map Object    cmdline_objs
 227                                ++ map DLL       minus_ls
 228                                ++ map Framework frameworks
 229         ; if null cmdline_lib_specs then return ()
 230                                     else do
 231
 232         { mapM_ (preloadLib dflags lib_paths framework_paths) cmdline_lib_specs
 233         ; maybePutStr dflags "final link ... "
 234         ; ok <- resolveObjs
 235
 236         ; if succeeded ok then maybePutStrLn dflags "done"
 237           else throwDyn (InstallationError "linking extra libraries/objects failed")
 238         }}
 239
 240 preloadLib :: DynFlags -> [String] -> [String] -> LibrarySpec -> IO ()
 241 preloadLib dflags lib_paths framework_paths lib_spec
 242   = do maybePutStr dflags ("Loading object " ++ showLS lib_spec ++ " ... ")
 243        case lib_spec of
 244           Object static_ish
 245              -> do b <- preload_static lib_paths static_ish
 246                    maybePutStrLn dflags (if b  then "done"
 247                                                 else "not found")
 248
 249           DLL dll_unadorned
 250              -> do maybe_errstr <- loadDynamic lib_paths dll_unadorned
 251                    case maybe_errstr of
 252                       Nothing -> maybePutStrLn dflags "done"
 253                       Just mm -> preloadFailed mm lib_paths lib_spec
 254
 255 #ifdef darwin_TARGET_OS
 256           Framework framework
 257              -> do maybe_errstr <- loadFramework framework_paths framework
 258                    case maybe_errstr of
 259                       Nothing -> maybePutStrLn dflags "done"
 260                       Just mm -> preloadFailed mm framework_paths lib_spec
 261 #endif
 262   where
 263     preloadFailed :: String -> [String] -> LibrarySpec -> IO ()
 264     preloadFailed sys_errmsg paths spec
 265        = do maybePutStr dflags
 266                ("failed.\nDynamic linker error message was:\n   "
 267                     ++ sys_errmsg  ++ "\nWhilst trying to load:  "
 268                     ++ showLS spec ++ "\nDirectories to search are:\n"
 269                     ++ unlines (map ("   "++) paths) )
 270             give_up
 271
 272     -- Not interested in the paths in the static case.
 273     preload_static paths name
 274        = do b <- doesFileExist name
 275             if not b then return False
 276                      else loadObj name >> return True
 277
 278     give_up = throwDyn $
 279               CmdLineError "user specified .o/.so/.DLL could not be loaded."
 280 \end{code}
 281
 282
 283 %************************************************************************
 284 %*                                                                      *
 285                 Link a byte-code expression
 286 %*                                                                      *
 287 %************************************************************************
 288
 289 \begin{code}
 290 linkExpr :: HscEnv -> PersistentCompilerState
 291          -> UnlinkedBCO -> IO HValue
 292
 293 -- Link a single expression, *including* first linking packages and
 294 -- modules that this expression depends on.
 295 --
 296 -- Raises an IO exception if it can't find a compiled version of the
 297 -- dependents to link.
 298
 299 linkExpr hsc_env pcs root_ul_bco
 300   = do {
 301         -- Initialise the linker (if it's not been done already)
 302      initDynLinker
 303
 304         -- Find what packages and linkables are required
 305    ; (lnks, pkgs) <- getLinkDeps hpt pit needed_mods
 306
 307         -- Link the packages and modules required
 308    ; linkPackages dflags pkgs
 309    ; ok <- linkModules dflags lnks
 310    ; if failed ok then
 311         dieWith empty
 312      else do {
 313
 314         -- Link the expression itself
 315      pls <- readIORef v_PersistentLinkerState
 316    ; let ie = itbl_env pls
 317          ce = closure_env pls
 318
 319         -- Link the necessary packages and linkables
 320    ; (_, (root_hval:_)) <- linkSomeBCOs False ie ce [root_ul_bco]
 321    ; return root_hval
 322    }}
 323    where
 324      pit    = eps_PIT (pcs_EPS pcs)
 325      hpt    = hsc_HPT hsc_env
 326      dflags = hsc_dflags hsc_env
 327      free_names = nameSetToList (bcoFreeNames root_ul_bco)
 328
 329      needed_mods :: [Module]
 330      needed_mods = [ nameModule n | n <- free_names, isExternalName n ]
 331
 332 dieWith msg = throwDyn (ProgramError (showSDoc msg))
 333
 334 getLinkDeps :: HomePackageTable -> PackageIfaceTable
 335             -> [Module]                         -- If you need these
 336             -> IO ([Linkable], [PackageName])   -- ... then link these first
 337 -- Fails with an IO exception if it can't find enough files
 338
 339 getLinkDeps hpt pit mods
 340 -- Find all the packages and linkables that a set of modules depends on
 341  = do { pls <- readIORef v_PersistentLinkerState ;
 342         let {
 343         -- 1.  Find the dependent home-pkg-modules/packages from each iface
 344             (mods_s, pkgs_s) = unzip (map get_deps mods) ;
 345
 346         -- 2.  Exclude ones already linked
 347         --      Main reason: avoid findModule calls in get_linkable
 348             mods_needed = nub (concat mods_s) `minusList` linked_mods     ;
 349             pkgs_needed = nub (concat pkgs_s) `minusList` pkgs_loaded pls ;
 350
 351             linked_mods = map linkableModName (objs_loaded pls ++ bcos_loaded pls)
 352         } ;
 353
 354         -- 3.  For each dependent module, find its linkable
 355         --     This will either be in the HPT or (in the case of one-shot
 356         --     compilation) we may need to use maybe_getFileLinkable
 357         lnks_needed <- mapM get_linkable mods_needed ;
 358
 359         return (lnks_needed, pkgs_needed) }
 360   where
 361     get_deps :: Module -> ([ModuleName],[PackageName])
 362         -- Get the things needed for the specified module
 363         -- This is rather similar to the code in RnNames.importsFromImportDecl
 364     get_deps mod
 365         | isHomeModule (mi_module iface)
 366         = (moduleName mod : [m | (m,_) <- dep_mods deps], dep_pkgs deps)
 367         | otherwise
 368         = ([], mi_package iface : dep_pkgs deps)
 369         where
 370           iface = get_iface mod
 371           deps  = mi_deps iface
 372
 373     get_iface mod = case lookupIface hpt pit mod of
 374                             Just iface -> iface
 375                             Nothing    -> pprPanic "getLinkDeps" (no_iface mod)
 376     no_iface mod = ptext SLIT("No iface for") <+> ppr mod
 377         -- This one is a GHC bug
 378
 379     no_obj mod = dieWith (ptext SLIT("No compiled code for") <+> ppr mod)
 380         -- This one is a build-system bug
 381
 382     get_linkable mod_name       -- A home-package module
 383         | Just mod_info <- lookupModuleEnvByName hpt mod_name
 384         = return (hm_linkable mod_info)
 385         | otherwise
 386         =       -- It's not in the HPT because we are in one shot mode,
 387                 -- so use the Finder to get a ModLocation...
 388           do { mb_stuff <- findModule mod_name ;
 389                case mb_stuff of {
 390                   Left _ -> no_obj mod_name ;
 391                   Right (_, loc) -> do {
 392
 393                 -- ...and then find the linkable for it
 394                mb_lnk <- findLinkable mod_name loc ;
 395                case mb_lnk of {
 396                   Nothing -> no_obj mod_name ;
 397                   Just lnk -> return lnk
 398           }}}}
 399 \end{code}
 400
 401
 402 %************************************************************************
 403 %*                                                                      *
 404                 Link some linkables
 405         The linkables may consist of a mixture of
 406         byte-code modules and object modules
 407 %*                                                                      *
 408 %************************************************************************
 409
 410 \begin{code}
 411 linkModules :: DynFlags -> [Linkable] -> IO SuccessFlag
 412 linkModules dflags linkables
 413   = block $ do  -- don't want to be interrupted by ^C in here
 414
 415         let (objs, bcos) = partition isObjectLinkable
 416                               (concatMap partitionLinkable linkables)
 417
 418                 -- Load objects first; they can't depend on BCOs
 419         ok_flag <- dynLinkObjs dflags objs
 420
 421         if failed ok_flag then
 422                 return Failed
 423           else do
 424                 dynLinkBCOs bcos
 425                 return Succeeded
 426
 427
 428 -- HACK to support f-x-dynamic in the interpreter; no other purpose
 429 partitionLinkable :: Linkable -> [Linkable]
 430 partitionLinkable li
 431    = let li_uls = linkableUnlinked li
 432          li_uls_obj = filter isObject li_uls
 433          li_uls_bco = filter isInterpretable li_uls
 434      in
 435          case (li_uls_obj, li_uls_bco) of
 436             (objs@(_:_), bcos@(_:_))
 437                -> [li{linkableUnlinked=li_uls_obj}, li{linkableUnlinked=li_uls_bco}]
 438             other
 439                -> [li]
 440
 441 findModuleLinkable_maybe :: [Linkable] -> ModuleName -> Maybe Linkable
 442 findModuleLinkable_maybe lis mod
 443    = case [LM time nm us | LM time nm us <- lis, nm == mod] of
 444         []   -> Nothing
 445         [li] -> Just li
 446         many -> pprPanic "findModuleLinkable" (ppr mod)
 447
 448 filterModuleLinkables :: (ModuleName -> Bool) -> [Linkable] -> [Linkable]
 449 filterModuleLinkables p ls = filter (p . linkableModName) ls
 450
 451 linkableInSet :: Linkable -> [Linkable] -> Bool
 452 linkableInSet l objs_loaded =
 453   case findModuleLinkable_maybe objs_loaded (linkableModName l) of
 454         Nothing -> False
 455         Just m  -> linkableTime l == linkableTime m
 456 \end{code}
 457
 458
 459 %************************************************************************
 460 %*                                                                      *
 461 \subsection{The object-code linker}
 462 %*                                                                      *
 463 %************************************************************************
 464
 465 \begin{code}
 466 dynLinkObjs :: DynFlags -> [Linkable] -> IO SuccessFlag
 467         -- Side-effects the PersistentLinkerState
 468
 469 dynLinkObjs dflags objs
 470   = do  pls <- readIORef v_PersistentLinkerState
 471
 472         -- Load the object files and link them
 473         let (objs_loaded', new_objs) = rmDupLinkables (objs_loaded pls) objs
 474             pls1                     = pls { objs_loaded = objs_loaded' }
 475             unlinkeds                = concatMap linkableUnlinked new_objs
 476
 477         mapM loadObj (map nameOfObject unlinkeds)
 478
 479         -- Link the all together
 480         ok <- resolveObjs
 481
 482         -- If resolving failed, unload all our
 483         -- object modules and carry on
 484         if succeeded ok then do
 485                 writeIORef v_PersistentLinkerState pls1
 486                 return Succeeded
 487           else do
 488                 pls2 <- unload_wkr dflags [] pls1
 489                 writeIORef v_PersistentLinkerState pls2
 490                 return Failed
 491
 492
 493 rmDupLinkables :: [Linkable]    -- Already loaded
 494                -> [Linkable]    -- New linkables
 495                -> ([Linkable],  -- New loaded set (including new ones)
 496                    [Linkable])  -- New linkables (excluding dups)
 497 rmDupLinkables already ls
 498   = go already [] ls
 499   where
 500     go already extras [] = (already, extras)
 501     go already extras (l:ls)
 502         | linkableInSet l already = go already     extras     ls
 503         | otherwise               = go (l:already) (l:extras) ls
 504 \end{code}
 505
 506 %************************************************************************
 507 %*                                                                      *
 508 \subsection{The byte-code linker}
 509 %*                                                                      *
 510 %************************************************************************
 511
 512 \begin{code}
 513 dynLinkBCOs :: [Linkable] -> IO ()
 514         -- Side-effects the persistent linker state
 515 dynLinkBCOs bcos
 516   = do  pls <- readIORef v_PersistentLinkerState
 517
 518         let (bcos_loaded', new_bcos) = rmDupLinkables (bcos_loaded pls) bcos
 519             pls1                     = pls { bcos_loaded = bcos_loaded' }
 520             unlinkeds :: [Unlinked]
 521             unlinkeds                = concatMap linkableUnlinked new_bcos
 522
 523             cbcs :: [CompiledByteCode]
 524             cbcs      = map byteCodeOfObject unlinkeds
 525
 526
 527             ul_bcos    = [b | ByteCode bs _  <- cbcs, b <- bs]
 528             ies        = [ie | ByteCode _ ie <- cbcs]
 529             gce       = closure_env pls
 530             final_ie  = foldr plusNameEnv (itbl_env pls) ies
 531
 532         (final_gce, linked_bcos) <- linkSomeBCOs True final_ie gce ul_bcos
 533                 -- What happens to these linked_bcos?
 534
 535         let pls2 = pls1 { closure_env = final_gce,
 536                           itbl_env    = final_ie }
 537
 538         writeIORef v_PersistentLinkerState pls2
 539         return ()
 540
 541 -- Link a bunch of BCOs and return them + updated closure env.
 542 linkSomeBCOs :: Bool    -- False <=> add _all_ BCOs to returned closure env
 543                         -- True  <=> add only toplevel BCOs to closure env
 544              -> ItblEnv
 545              -> ClosureEnv
 546              -> [UnlinkedBCO]
 547              -> IO (ClosureEnv, [HValue])
 548                         -- The returned HValues are associated 1-1 with
 549                         -- the incoming unlinked BCOs.  Each gives the
 550                         -- value of the corresponding unlinked BCO
 551
 552
 553 linkSomeBCOs toplevs_only ie ce_in ul_bcos
 554    = do let nms = map unlinkedBCOName ul_bcos
 555         hvals <- fixIO
 556                     ( \ hvs -> let ce_out = extendClosureEnv ce_in (zipLazy nms hvs)
 557                                in  mapM (linkBCO ie ce_out) ul_bcos )
 558
 559         let ce_all_additions = zip nms hvals
 560             ce_top_additions = filter (isExternalName.fst) ce_all_additions
 561             ce_additions     = if toplevs_only then ce_top_additions
 562                                                else ce_all_additions
 563             ce_out = -- make sure we're not inserting duplicate names into the
 564                      -- closure environment, which leads to trouble.
 565                      ASSERT (all (not . (`elemNameEnv` ce_in)) (map fst ce_additions))
 566                      extendClosureEnv ce_in ce_additions
 567         return (ce_out, hvals)
 568
 569 \end{code}
 570
 571
 572 %************************************************************************
 573 %*                                                                      *
 574                 Unload some object modules
 575 %*                                                                      *
 576 %************************************************************************
 577
 578 \begin{code}
 579 -- ---------------------------------------------------------------------------
 580 -- Unloading old objects ready for a new compilation sweep.
 581 --
 582 -- The compilation manager provides us with a list of linkables that it
 583 -- considers "stable", i.e. won't be recompiled this time around.  For
 584 -- each of the modules current linked in memory,
 585 --
 586 --      * if the linkable is stable (and it's the same one - the
 587 --        user may have recompiled the module on the side), we keep it,
 588 --
 589 --      * otherwise, we unload it.
 590 --
 591 --      * we also implicitly unload all temporary bindings at this point.
 592
 593 unload :: DynFlags -> [Linkable] -> IO ()
 594 -- The 'linkables' are the ones to *keep*
 595
 596 unload dflags linkables
 597   = block $ do -- block, so we're safe from Ctrl-C in here
 598
 599         pls     <- readIORef v_PersistentLinkerState
 600         new_pls <- unload_wkr dflags linkables pls
 601         writeIORef v_PersistentLinkerState new_pls
 602
 603         let verb = verbosity dflags
 604         when (verb >= 3) $ do
 605             hPutStrLn stderr (showSDoc
 606                 (text "unload: retaining objs" <+> ppr (objs_loaded new_pls)))
 607             hPutStrLn stderr (showSDoc
 608                 (text "unload: retaining bcos" <+> ppr (bcos_loaded new_pls)))
 609
 610         return ()
 611
 612 unload_wkr :: DynFlags
 613            -> [Linkable]                -- stable linkables
 614            -> PersistentLinkerState
 615            -> IO PersistentLinkerState
 616 -- Does the core unload business
 617 -- (the wrapper blocks exceptions and deals with the PLS get and put)
 618
 619 unload_wkr dflags linkables pls
 620   = do  let (objs_to_keep, bcos_to_keep) = partition isObjectLinkable linkables
 621
 622         objs_loaded' <- filterM (maybeUnload objs_to_keep) (objs_loaded pls)
 623         bcos_loaded' <- filterM (maybeUnload bcos_to_keep) (bcos_loaded pls)
 624
 625         let objs_retained = map linkableModName objs_loaded'
 626             bcos_retained = map linkableModName bcos_loaded'
 627             itbl_env'     = filterNameMap bcos_retained (itbl_env pls)
 628             closure_env'  = filterNameMap bcos_retained (closure_env pls)
 629             new_pls = pls { itbl_env = itbl_env',
 630                             closure_env = closure_env',
 631                             bcos_loaded = bcos_loaded',
 632                             objs_loaded = objs_loaded' }
 633
 634         return new_pls
 635   where
 636     maybeUnload :: [Linkable] -> Linkable -> IO Bool
 637     maybeUnload keep_linkables lnk
 638       | linkableInSet lnk linkables = return True
 639       | otherwise
 640       = do mapM_ unloadObj [f | DotO f <- linkableUnlinked lnk]
 641                 -- The components of a BCO linkable may contain
 642                 -- dot-o files.  Which is very confusing.
 643                 --
 644                 -- But the BCO parts can be unlinked just by
 645                 -- letting go of them (plus of course depopulating
 646                 -- the symbol table which is done in the main body)
 647            return False
 648 \end{code}
 649
 650
 651 %************************************************************************
 652 %*                                                                      *
 653                 Loading packages
 654 %*                                                                      *
 655 %************************************************************************
 656
 657
 658 \begin{code}
 659 data LibrarySpec
 660    = Object FilePath    -- Full path name of a .o file, including trailing .o
 661                         -- For dynamic objects only, try to find the object
 662                         -- file in all the directories specified in
 663                         -- v_Library_paths before giving up.
 664
 665    | DLL String         -- "Unadorned" name of a .DLL/.so
 666                         --  e.g.    On unix     "qt"  denotes "libqt.so"
 667                         --          On WinDoze  "burble"  denotes "burble.DLL"
 668                         --  loadDLL is platform-specific and adds the lib/.so/.DLL
 669                         --  suffixes platform-dependently
 670
 671    | Framework String   -- Only used for darwin, but does no harm
 672
 673 -- If this package is already part of the GHCi binary, we'll already
 674 -- have the right DLLs for this package loaded, so don't try to
 675 -- load them again.
 676 --
 677 -- But on Win32 we must load them 'again'; doing so is a harmless no-op
 678 -- as far as the loader is concerned, but it does initialise the list
 679 -- of DLL handles that rts/Linker.c maintains, and that in turn is
 680 -- used by lookupSymbol.  So we must call addDLL for each library
 681 -- just to get the DLL handle into the list.
 682 partOfGHCi
 683 #          if defined(mingw32_TARGET_OS) || defined(darwin_TARGET_OS)
 684            = [ ]
 685 #          else
 686            = [ "base", "haskell98", "haskell-src", "readline" ]
 687 #          endif
 688
 689 showLS (Object nm)    = "(static) " ++ nm
 690 showLS (DLL nm)       = "(dynamic) " ++ nm
 691 showLS (Framework nm) = "(framework) " ++ nm
 692
 693 linkPackages :: DynFlags -> [PackageName] -> IO ()
 694 -- Link exactly the specified packages, and their dependents
 695 -- (unless of course they are already linked)
 696 -- The dependents are linked automatically, and it doesn't matter
 697 -- what order you specify the input packages.
 698 --
 699 -- NOTE: in fact, since each module tracks all the packages it depends on,
 700 --       we don't really need to use the package-config dependencies.
 701 -- However we do need the package-config stuff (to find aux libs etc),
 702 -- and following them lets us load libraries in the right order, which
 703 -- perhaps makes the error message a bit more localised if we get a link
 704 -- failure.  So the dependency walking code is still here.
 705
 706 linkPackages dflags new_pkgs
 707    = do { pls     <- readIORef v_PersistentLinkerState
 708         ; pkg_map <- getPackageConfigMap
 709
 710         ; pkgs' <- link pkg_map (pkgs_loaded pls) new_pkgs
 711
 712         ; writeIORef v_PersistentLinkerState (pls { pkgs_loaded = pkgs' })
 713         }
 714    where
 715      link :: PackageConfigMap -> [PackageName] -> [PackageName] -> IO [PackageName]
 716      link pkg_map pkgs new_pkgs
 717         = foldM (link_one pkg_map) pkgs new_pkgs
 718
 719      link_one pkg_map pkgs new_pkg
 720         | new_pkg `elem` pkgs   -- Already linked
 721         = return pkgs
 722
 723         | Just pkg_cfg <- lookupPkg pkg_map new_pkg
 724         = do {  -- Link dependents first
 725                pkgs' <- link pkg_map pkgs (packageDependents pkg_cfg)
 726                 -- Now link the package itself
 727              ; linkPackage dflags pkg_cfg
 728              ; return (new_pkg : pkgs') }
 729
 730         | otherwise
 731         = throwDyn (CmdLineError ("unknown package name: " ++ packageNameString new_pkg))
 732
 733
 734 linkPackage :: DynFlags -> PackageConfig -> IO ()
 735 linkPackage dflags pkg
 736    = do
 737         let dirs      =  Packages.library_dirs pkg
 738         let libs      =  Packages.hs_libraries pkg ++ extra_libraries pkg
 739                                 ++ [ lib | '-':'l':lib <- extra_ld_opts pkg ]
 740         classifieds   <- mapM (locateOneObj dirs) libs
 741
 742         -- Complication: all the .so's must be loaded before any of the .o's.
 743         let dlls = [ dll | DLL dll    <- classifieds ]
 744             objs = [ obj | Object obj <- classifieds ]
 745
 746         maybePutStr dflags ("Loading package " ++ Packages.name pkg ++ " ... ")
 747
 748         -- See comments with partOfGHCi
 749         when (Packages.name pkg `notElem` partOfGHCi) $ do
 750             loadFrameworks pkg
 751             mapM_ (load_dyn dirs) dlls
 752
 753         -- After loading all the DLLs, we can load the static objects.
 754         mapM_ loadObj objs
 755
 756         maybePutStr dflags "linking ... "
 757         ok <- resolveObjs
 758         if succeeded ok then maybePutStrLn dflags "done."
 759               else panic ("can't load package `" ++ name pkg ++ "'")
 760
 761 load_dyn dirs dll = do r <- loadDynamic dirs dll
 762                        case r of
 763                          Nothing  -> return ()
 764                          Just err -> throwDyn (CmdLineError ("can't load .so/.DLL for: "
 765                                                               ++ dll ++ " (" ++ err ++ ")" ))
 766 #ifndef darwin_TARGET_OS
 767 loadFrameworks pkg = return ()
 768 #else
 769 loadFrameworks pkg = mapM_ load frameworks
 770   where
 771     fw_dirs    = Packages.framework_dirs pkg
 772     frameworks = Packages.extra_frameworks pkg
 773
 774     load fw = do  r <- loadFramework fw_dirs fw
 775                   case r of
 776                     Nothing  -> return ()
 777                     Just err -> throwDyn (CmdLineError ("can't load framework: "
 778                                                         ++ fw ++ " (" ++ err ++ ")" ))
 779 #endif
 780
 781 -- Try to find an object file for a given library in the given paths.
 782 -- If it isn't present, we assume it's a dynamic library.
 783 locateOneObj :: [FilePath] -> String -> IO LibrarySpec
 784 locateOneObj dirs lib
 785   = do  { mb_obj_path <- findFile mk_obj_path dirs
 786         ; case mb_obj_path of
 787             Just obj_path -> return (Object obj_path)
 788             Nothing       -> return (DLL lib) }         -- We assume
 789    where
 790      mk_obj_path dir = dir ++ '/':lib ++ ".o"
 791
 792
 793 -- ----------------------------------------------------------------------------
 794 -- Loading a dyanmic library (dlopen()-ish on Unix, LoadLibrary-ish on Win32)
 795
 796 -- return Nothing == success, else Just error message from dlopen
 797 loadDynamic paths rootname
 798   = do  { mb_dll <- findFile mk_dll_path paths
 799         ; case mb_dll of
 800             Just dll -> loadDLL dll
 801             Nothing  -> loadDLL (mkSOName rootname) }
 802                         -- Tried all our known library paths, so let
 803                         -- dlopen() search its own builtin paths now.
 804   where
 805     mk_dll_path dir = dir ++ '/':mkSOName rootname
 806
 807 #if defined(darwin_TARGET_OS)
 808 mkSOName root = "lib" ++ root ++ ".dylib"
 809 #elif defined(mingw32_TARGET_OS)
 810 -- Win32 DLLs have no .dll extension here, because addDLL tries
 811 -- both foo.dll and foo.drv
 812 mkSOName root = root
 813 #else
 814 mkSOName root = "lib" ++ root ++ ".so"
 815 #endif
 816
 817 -- Darwin / MacOS X only: load a framework
 818 -- a framework is a dynamic library packaged inside a directory of the same
 819 -- name. They are searched for in different paths than normal libraries.
 820 #ifdef darwin_TARGET_OS
 821 loadFramework extraPaths rootname
 822    = do { mb_fwk <- findFile mk_fwk (extraPaths ++ defaultFrameworkPaths)
 823         ; case mb_fwk of
 824             Just fwk_path -> loadDLL fwk_path
 825             Nothing       -> return (Just "not found") }
 826                 -- Tried all our known library paths, but dlopen()
 827                 -- has no built-in paths for frameworks: give up
 828    where
 829      mk_fwk dir = dir ++ '/' : rootname ++ ".framework/" ++ rootname
 830         -- sorry for the hardcoded paths, I hope they won't change anytime soon:
 831      defaultFrameworkPaths = ["/Library/Frameworks", "/System/Library/Frameworks"]
 832 #endif
 833 \end{code}
 834
 835 %************************************************************************
 836 %*                                                                      *
 837                 Helper functions
 838 %*                                                                      *
 839 %************************************************************************
 840
 841 \begin{code}
 842 findFile :: (FilePath -> FilePath)      -- Maps a directory path to a file path
 843          -> [FilePath]                  -- Directories to look in
 844          -> IO (Maybe FilePath)         -- The first file path to match
 845 findFile mk_file_path []
 846   = return Nothing
 847 findFile mk_file_path (dir:dirs)
 848   = do  { let file_path = mk_file_path dir
 849         ; b <- doesFileExist file_path
 850         ; if b then
 851              return (Just file_path)
 852           else
 853              findFile mk_file_path dirs }
 854 \end{code}
 855
 856 \begin{code}
 857 maybePutStr dflags s | verbosity dflags > 0 = putStr s
 858                      | otherwise            = return ()
 859
 860 maybePutStrLn dflags s | verbosity dflags > 0 = putStrLn s
 861                        | otherwise            = return ()
 862 \end{code}