ghc/compiler/hsSyn/HsDecls.lhs

   1 %
   2 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   3 %
   4 \section[HsDecls]{Abstract syntax: global declarations}
   5
   6 Definitions for: @TyDecl@ and @oCnDecl@, @ClassDecl@,
   7 @InstDecl@, @DefaultDecl@ and @ForeignDecl@.
   8
   9 \begin{code}
  10 module HsDecls (
  11         HsDecl(..), TyClDecl(..), InstDecl(..), RuleDecl(..), RuleBndr(..),
  12         DefaultDecl(..),
  13         ForeignDecl(..), FoImport(..), FoExport(..), FoType(..),
  14         ConDecl(..), ConDetails(..),
  15         BangType(..), getBangType, getBangStrictness, unbangedType,
  16         DeprecDecl(..), DeprecTxt,
  17         hsDeclName, instDeclName,
  18         tyClDeclName, tyClDeclNames, tyClDeclSysNames, tyClDeclTyVars,
  19         isClassDecl, isSynDecl, isDataDecl, isIfaceSigDecl, countTyClDecls,
  20         mkClassDeclSysNames, isSourceInstDecl, ifaceRuleDeclName,
  21         getClassDeclSysNames, conDetailsTys,
  22         collectRuleBndrSigTys
  23     ) where
  24
  25 #include "HsVersions.h"
  26
  27 -- friends:
  28 import HsBinds          ( HsBinds, MonoBinds, Sig(..), FixitySig(..) )
  29 import HsExpr           ( HsExpr )
  30 import HsImpExp         ( ppr_var )
  31 import HsTypes
  32 import PprCore          ( pprCoreRule )
  33 import HsCore           ( UfExpr, UfBinder, HsIdInfo, pprHsIdInfo,
  34                           eq_ufBinders, eq_ufExpr, pprUfExpr
  35                         )
  36 import CoreSyn          ( CoreRule(..), RuleName )
  37 import BasicTypes       ( NewOrData(..), StrictnessMark(..), Activation(..) )
  38 import ForeignCall      ( CExportSpec, CCallSpec, DNCallSpec, CCallConv )
  39
  40 -- others:
  41 import Name             ( NamedThing )
  42 import FunDeps          ( pprFundeps )
  43 import Class            ( FunDep, DefMeth(..) )
  44 import CStrings         ( CLabelString )
  45 import Outputable
  46 import Util             ( eqListBy, count )
  47 import SrcLoc           ( SrcLoc )
  48 import FastString
  49
  50 import Maybe            ( isNothing, fromJust )
  51 \end{code}
  52
  53
  54 %************************************************************************
  55 %*                                                                      *
  56 \subsection[HsDecl]{Declarations}
  57 %*                                                                      *
  58 %************************************************************************
  59
  60 \begin{code}
  61 data HsDecl name pat
  62   = TyClD       (TyClDecl name pat)
  63   | InstD       (InstDecl  name pat)
  64   | DefD        (DefaultDecl name)
  65   | ValD        (HsBinds name pat)
  66   | ForD        (ForeignDecl name)
  67   | FixD        (FixitySig name)
  68   | DeprecD     (DeprecDecl name)
  69   | RuleD       (RuleDecl name pat)
  70
  71 -- NB: all top-level fixity decls are contained EITHER
  72 -- EITHER FixDs
  73 -- OR     in the ClassDecls in TyClDs
  74 --
  75 -- The former covers
  76 --      a) data constructors
  77 --      b) class methods (but they can be also done in the
  78 --              signatures of class decls)
  79 --      c) imported functions (that have an IfacSig)
  80 --      d) top level decls
  81 --
  82 -- The latter is for class methods only
  83 \end{code}
  84
  85 \begin{code}
  86 #ifdef DEBUG
  87 hsDeclName :: (NamedThing name, Outputable name, Outputable pat)
  88            => HsDecl name pat -> name
  89 #endif
  90 hsDeclName (TyClD decl)                   = tyClDeclName decl
  91 hsDeclName (InstD   decl)                 = instDeclName decl
  92 hsDeclName (ForD    decl)                 = forDeclName decl
  93 hsDeclName (FixD    (FixitySig name _ _)) = name
  94 -- Others don't make sense
  95 #ifdef DEBUG
  96 hsDeclName x                                  = pprPanic "HsDecls.hsDeclName" (ppr x)
  97 #endif
  98
  99
 100 instDeclName :: InstDecl name pat -> name
 101 instDeclName (InstDecl _ _ _ (Just name) _) = name
 102
 103 \end{code}
 104
 105 \begin{code}
 106 instance (NamedThing name, Outputable name, Outputable pat)
 107         => Outputable (HsDecl name pat) where
 108
 109     ppr (TyClD dcl)  = ppr dcl
 110     ppr (ValD binds) = ppr binds
 111     ppr (DefD def)   = ppr def
 112     ppr (InstD inst) = ppr inst
 113     ppr (ForD fd)    = ppr fd
 114     ppr (FixD fd)    = ppr fd
 115     ppr (RuleD rd)   = ppr rd
 116     ppr (DeprecD dd) = ppr dd
 117 \end{code}
 118
 119
 120 %************************************************************************
 121 %*                                                                      *
 122 \subsection[TyDecl]{@data@, @newtype@ or @type@ (synonym) type declaration}
 123 %*                                                                      *
 124 %************************************************************************
 125
 126                 --------------------------------
 127                         THE NAMING STORY
 128                 --------------------------------
 129
 130 Here is the story about the implicit names that go with type, class, and instance
 131 decls.  It's a bit tricky, so pay attention!
 132
 133 "Implicit" (or "system") binders
 134 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 135   Each data type decl defines
 136         a worker name for each constructor
 137         to-T and from-T convertors
 138   Each class decl defines
 139         a tycon for the class
 140         a data constructor for that tycon
 141         the worker for that constructor
 142         a selector for each superclass
 143
 144 All have occurrence names that are derived uniquely from their parent declaration.
 145
 146 None of these get separate definitions in an interface file; they are
 147 fully defined by the data or class decl.  But they may *occur* in
 148 interface files, of course.  Any such occurrence must haul in the
 149 relevant type or class decl.
 150
 151 Plan of attack:
 152  - Make up their occurrence names immediately
 153    This is done in RdrHsSyn.mkClassDecl, mkTyDecl, mkConDecl
 154
 155  - Ensure they "point to" the parent data/class decl
 156    when loading that decl from an interface file
 157    (See RnHiFiles.getTyClDeclSysNames)
 158
 159  - When renaming the decl look them up in the name cache,
 160    ensure correct module and provenance is set
 161
 162 Default methods
 163 ~~~~~~~~~~~~~~~
 164  - Occurrence name is derived uniquely from the method name
 165    E.g. $dmmax
 166
 167  - If there is a default method name at all, it's recorded in
 168    the ClassOpSig (in HsBinds), in the DefMeth field.
 169    (DefMeth is defined in Class.lhs)
 170
 171 Source-code class decls and interface-code class decls are treated subtly
 172 differently, which has given me a great deal of confusion over the years.
 173 Here's the deal.  (We distinguish the two cases because source-code decls
 174 have (Just binds) in the tcdMeths field, whereas interface decls have Nothing.
 175
 176 In *source-code* class declarations:
 177  - When parsing, every ClassOpSig gets a DefMeth with a suitable RdrName
 178    This is done by RdrHsSyn.mkClassOpSigDM
 179
 180  - The renamer renames it to a Name
 181
 182  - During typechecking, we generate a binding for each $dm for
 183    which there's a programmer-supplied default method:
 184         class Foo a where
 185           op1 :: <type>
 186           op2 :: <type>
 187           op1 = ...
 188    We generate a binding for $dmop1 but not for $dmop2.
 189    The Class for Foo has a NoDefMeth for op2 and a DefMeth for op1.
 190    The Name for $dmop2 is simply discarded.
 191
 192 In *interface-file* class declarations:
 193   - When parsing, we see if there's an explicit programmer-supplied default method
 194     because there's an '=' sign to indicate it:
 195         class Foo a where
 196           op1 = :: <type>       -- NB the '='
 197           op2   :: <type>
 198     We use this info to generate a DefMeth with a suitable RdrName for op1,
 199     and a NoDefMeth for op2
 200   - The interface file has a separate definition for $dmop1, with unfolding etc.
 201   - The renamer renames it to a Name.
 202   - The renamer treats $dmop1 as a free variable of the declaration, so that
 203     the binding for $dmop1 will be sucked in.  (See RnHsSyn.tyClDeclFVs)
 204     This doesn't happen for source code class decls, because they *bind* the default method.
 205
 206 Dictionary functions
 207 ~~~~~~~~~~~~~~~~~~~~
 208 Each instance declaration gives rise to one dictionary function binding.
 209
 210 The type checker makes up new source-code instance declarations
 211 (e.g. from 'deriving' or generic default methods --- see
 212 TcInstDcls.tcInstDecls1).  So we can't generate the names for
 213 dictionary functions in advance (we don't know how many we need).
 214
 215 On the other hand for interface-file instance declarations, the decl
 216 specifies the name of the dictionary function, and it has a binding elsewhere
 217 in the interface file:
 218         instance {Eq Int} = dEqInt
 219         dEqInt :: {Eq Int} <pragma info>
 220
 221 So again we treat source code and interface file code slightly differently.
 222
 223 Source code:
 224   - Source code instance decls have a Nothing in the (Maybe name) field
 225     (see data InstDecl below)
 226
 227   - The typechecker makes up a Local name for the dict fun for any source-code
 228     instance decl, whether it comes from a source-code instance decl, or whether
 229     the instance decl is derived from some other construct (e.g. 'deriving').
 230
 231   - The occurrence name it chooses is derived from the instance decl (just for
 232     documentation really) --- e.g. dNumInt.  Two dict funs may share a common
 233     occurrence name, but will have different uniques.  E.g.
 234         instance Foo [Int]  where ...
 235         instance Foo [Bool] where ...
 236     These might both be dFooList
 237
 238   - The CoreTidy phase globalises the name, and ensures the occurrence name is
 239     unique (this isn't special to dict funs).  So we'd get dFooList and dFooList1.
 240
 241   - We can take this relaxed approach (changing the occurrence name later)
 242     because dict fun Ids are not captured in a TyCon or Class (unlike default
 243     methods, say).  Instead, they are kept separately in the InstEnv.  This
 244     makes it easy to adjust them after compiling a module.  (Once we've finished
 245     compiling that module, they don't change any more.)
 246
 247
 248 Interface file code:
 249   - The instance decl gives the dict fun name, so the InstDecl has a (Just name)
 250     in the (Maybe name) field.
 251
 252   - RnHsSyn.instDeclFVs treats the dict fun name as free in the decl, so that we
 253     suck in the dfun binding
 254
 255
 256 \begin{code}
 257 -- TyClDecls are precisely the kind of declarations that can
 258 -- appear in interface files; or (internally) in GHC's interface
 259 -- for a module.  That's why (despite the misnomer) IfaceSig and ForeignType
 260 -- are both in TyClDecl
 261
 262 data TyClDecl name pat
 263   = IfaceSig {  tcdName :: name,                -- It may seem odd to classify an interface-file signature
 264                 tcdType :: HsType name,         -- as a 'TyClDecl', but it's very convenient.
 265                 tcdIdInfo :: [HsIdInfo name],
 266                 tcdLoc :: SrcLoc
 267     }
 268
 269   | ForeignType { tcdName    :: name,           -- See remarks about IfaceSig above
 270                   tcdExtName :: Maybe FastString,
 271                   tcdFoType  :: FoType,
 272                   tcdLoc     :: SrcLoc }
 273
 274   | TyData {    tcdND     :: NewOrData,
 275                 tcdCtxt   :: HsContext name,     -- context
 276                 tcdName   :: name,               -- type constructor
 277                 tcdTyVars :: [HsTyVarBndr name], -- type variables
 278                 tcdCons   :: [ConDecl name],     -- data constructors (empty if abstract)
 279                 tcdNCons  :: Int,                -- Number of data constructors (valid even if type is abstract)
 280                 tcdDerivs :: Maybe (HsContext name),    -- derivings; Nothing => not specified
 281                                                         -- Just [] => derive exactly what is asked
 282                 tcdSysNames :: DataSysNames name,       -- Generic converter functions
 283                 tcdLoc      :: SrcLoc
 284     }
 285
 286   | TySynonym { tcdName :: name,                        -- type constructor
 287                 tcdTyVars :: [HsTyVarBndr name],        -- type variables
 288                 tcdSynRhs :: HsType name,               -- synonym expansion
 289                 tcdLoc    :: SrcLoc
 290     }
 291
 292   | ClassDecl { tcdCtxt    :: HsContext name,           -- Context...
 293                 tcdName    :: name,                     -- Name of the class
 294                 tcdTyVars  :: [HsTyVarBndr name],       -- The class type variables
 295                 tcdFDs     :: [FunDep name],            -- Functional dependencies
 296                 tcdSigs    :: [Sig name],               -- Methods' signatures
 297                 tcdMeths   :: Maybe (MonoBinds name pat),       -- Default methods
 298                                                                 -- Nothing for imported class decls
 299                                                                 -- Just bs for source   class decls
 300                 tcdSysNames :: ClassSysNames name,
 301                 tcdLoc      :: SrcLoc
 302     }
 303 \end{code}
 304
 305 Simple classifiers
 306
 307 \begin{code}
 308 isIfaceSigDecl, isDataDecl, isSynDecl, isClassDecl :: TyClDecl name pat -> Bool
 309
 310 isIfaceSigDecl (IfaceSig {}) = True
 311 isIfaceSigDecl other         = False
 312
 313 isSynDecl (TySynonym {}) = True
 314 isSynDecl other          = False
 315
 316 isDataDecl (TyData {}) = True
 317 isDataDecl other       = False
 318
 319 isClassDecl (ClassDecl {}) = True
 320 isClassDecl other          = False
 321 \end{code}
 322
 323 Dealing with names
 324
 325 \begin{code}
 326 --------------------------------
 327 tyClDeclName :: TyClDecl name pat -> name
 328 tyClDeclName tycl_decl = tcdName tycl_decl
 329
 330 --------------------------------
 331 tyClDeclNames :: Eq name => TyClDecl name pat -> [(name, SrcLoc)]
 332 -- Returns all the *binding* names of the decl, along with their SrcLocs
 333 -- The first one is guaranteed to be the name of the decl
 334 -- For record fields, the first one counts as the SrcLoc
 335 -- We use the equality to filter out duplicate field names
 336
 337 tyClDeclNames (TySynonym   {tcdName = name, tcdLoc = loc})  = [(name,loc)]
 338 tyClDeclNames (IfaceSig    {tcdName = name, tcdLoc = loc})  = [(name,loc)]
 339 tyClDeclNames (ForeignType {tcdName = name, tcdLoc = loc})  = [(name,loc)]
 340
 341 tyClDeclNames (ClassDecl {tcdName = cls_name, tcdSigs = sigs, tcdLoc = loc})
 342   = (cls_name,loc) : [(n,loc) | ClassOpSig n _ _ loc <- sigs]
 343
 344 tyClDeclNames (TyData {tcdName = tc_name, tcdCons = cons, tcdLoc = loc})
 345   = (tc_name,loc) : conDeclsNames cons
 346
 347
 348 tyClDeclTyVars (TySynonym {tcdTyVars = tvs}) = tvs
 349 tyClDeclTyVars (TyData    {tcdTyVars = tvs}) = tvs
 350 tyClDeclTyVars (ClassDecl {tcdTyVars = tvs}) = tvs
 351 tyClDeclTyVars (ForeignType {})              = []
 352 tyClDeclTyVars (IfaceSig {})                 = []
 353
 354
 355 --------------------------------
 356 -- The "system names" are extra implicit names *bound* by the decl.
 357 -- They are kept in a list rather than a tuple
 358 -- to make the renamer easier.
 359
 360 type ClassSysNames name = [name]
 361 -- For class decls they are:
 362 --      [tycon, datacon wrapper, datacon worker,
 363 --       superclass selector 1, ..., superclass selector n]
 364
 365 type DataSysNames name =  [name]
 366 -- For data decls they are
 367 --      [from, to]
 368 -- where from :: T -> Tring
 369 --       to   :: Tring -> T
 370
 371 tyClDeclSysNames :: TyClDecl name pat -> [(name, SrcLoc)]
 372 -- Similar to tyClDeclNames, but returns the "implicit"
 373 -- or "system" names of the declaration
 374
 375 tyClDeclSysNames (ClassDecl {tcdSysNames = names, tcdLoc = loc})
 376   = [(n,loc) | n <- names]
 377 tyClDeclSysNames (TyData {tcdCons = cons, tcdSysNames = names, tcdLoc = loc})
 378   = [(n,loc) | n <- names] ++
 379     [(wkr_name,loc) | ConDecl _ wkr_name _ _ _ loc <- cons]
 380 tyClDeclSysNames decl = []
 381
 382
 383 mkClassDeclSysNames  :: (name, name, name, [name]) -> [name]
 384 getClassDeclSysNames :: [name] -> (name, name, name, [name])
 385 mkClassDeclSysNames  (a,b,c,ds) = a:b:c:ds
 386 getClassDeclSysNames (a:b:c:ds) = (a,b,c,ds)
 387 \end{code}
 388
 389 \begin{code}
 390 instance (NamedThing name, Ord name) => Eq (TyClDecl name pat) where
 391         -- Used only when building interface files
 392   (==) d1@(IfaceSig {}) d2@(IfaceSig {})
 393       = tcdName d1 == tcdName d2 &&
 394         tcdType d1 == tcdType d2 &&
 395         tcdIdInfo d1 == tcdIdInfo d2
 396
 397   (==) d1@(ForeignType {}) d2@(ForeignType {})
 398       = tcdName d1 == tcdName d2 &&
 399         tcdFoType d1 == tcdFoType d2
 400
 401   (==) d1@(TyData {}) d2@(TyData {})
 402       = tcdName d1 == tcdName d2 &&
 403         tcdND d1   == tcdND   d2 &&
 404         eqWithHsTyVars (tcdTyVars d1) (tcdTyVars d2) (\ env ->
 405           eq_hsContext env (tcdCtxt d1) (tcdCtxt d2)  &&
 406           eqListBy (eq_ConDecl env) (tcdCons d1) (tcdCons d2)
 407         )
 408
 409   (==) d1@(TySynonym {}) d2@(TySynonym {})
 410       = tcdName d1 == tcdName d2 &&
 411         eqWithHsTyVars (tcdTyVars d1) (tcdTyVars d2) (\ env ->
 412           eq_hsType env (tcdSynRhs d1) (tcdSynRhs d2)
 413         )
 414
 415   (==) d1@(ClassDecl {}) d2@(ClassDecl {})
 416     = tcdName d1 == tcdName d2 &&
 417       eqWithHsTyVars (tcdTyVars d1) (tcdTyVars d2) (\ env ->
 418           eq_hsContext env (tcdCtxt d1) (tcdCtxt d2)  &&
 419           eqListBy (eq_hsFD env) (tcdFDs d1) (tcdFDs d2) &&
 420           eqListBy (eq_cls_sig env) (tcdSigs d1) (tcdSigs d2)
 421        )
 422
 423   (==) _ _ = False      -- default case
 424
 425 eq_hsFD env (ns1,ms1) (ns2,ms2)
 426   = eqListBy (eq_hsVar env) ns1 ns2 && eqListBy (eq_hsVar env) ms1 ms2
 427
 428 eq_cls_sig env (ClassOpSig n1 dm1 ty1 _) (ClassOpSig n2 dm2 ty2 _)
 429   = n1==n2 && dm1 `eq_dm` dm2 && eq_hsType env ty1 ty2
 430   where
 431         -- Ignore the name of the default method for (DefMeth id)
 432         -- This is used for comparing declarations before putting
 433         -- them into interface files, and the name of the default
 434         -- method isn't relevant
 435     NoDefMeth  `eq_dm` NoDefMeth  = True
 436     GenDefMeth `eq_dm` GenDefMeth = True
 437     DefMeth _  `eq_dm` DefMeth _  = True
 438     dm1        `eq_dm` dm2        = False
 439
 440
 441 \end{code}
 442
 443 \begin{code}
 444 countTyClDecls :: [TyClDecl name pat] -> (Int, Int, Int, Int, Int)
 445         -- class, data, newtype, synonym decls
 446 countTyClDecls decls
 447  = (count isClassDecl     decls,
 448     count isSynDecl       decls,
 449     count isIfaceSigDecl  decls,
 450     count isDataTy        decls,
 451     count isNewTy         decls)
 452  where
 453    isDataTy TyData{tcdND=DataType} = True
 454    isDataTy _                      = False
 455
 456    isNewTy TyData{tcdND=NewType} = True
 457    isNewTy _                     = False
 458 \end{code}
 459
 460 \begin{code}
 461 instance (NamedThing name, Outputable name, Outputable pat)
 462               => Outputable (TyClDecl name pat) where
 463
 464     ppr (IfaceSig {tcdName = var, tcdType = ty, tcdIdInfo = info})
 465         = getPprStyle $ \ sty ->
 466            hsep [ if ifaceStyle sty then ppr var else ppr_var var,
 467                   dcolon, ppr ty, pprHsIdInfo info
 468                 ]
 469
 470     ppr (ForeignType {tcdName = tycon})
 471         = hsep [ptext SLIT("foreign import type dotnet"), ppr tycon]
 472
 473     ppr (TySynonym {tcdName = tycon, tcdTyVars = tyvars, tcdSynRhs = mono_ty})
 474       = hang (ptext SLIT("type") <+> pp_decl_head [] tycon tyvars <+> equals)
 475              4 (ppr mono_ty)
 476
 477     ppr (TyData {tcdND = new_or_data, tcdCtxt = context, tcdName = tycon,
 478                  tcdTyVars = tyvars, tcdCons = condecls, tcdNCons = ncons,
 479                  tcdDerivs = derivings})
 480       = pp_tydecl (ptext keyword <+> pp_decl_head context tycon tyvars)
 481                   (pp_condecls condecls ncons)
 482                   derivings
 483       where
 484         keyword = case new_or_data of
 485                         NewType  -> SLIT("newtype")
 486                         DataType -> SLIT("data")
 487
 488     ppr (ClassDecl {tcdCtxt = context, tcdName = clas, tcdTyVars = tyvars, tcdFDs = fds,
 489                     tcdSigs = sigs, tcdMeths = methods})
 490       | null sigs       -- No "where" part
 491       = top_matter
 492
 493       | otherwise       -- Laid out
 494       = sep [hsep [top_matter, ptext SLIT("where {")],
 495              nest 4 (sep [sep (map ppr_sig sigs), pp_methods, char '}'])]
 496       where
 497         top_matter  = ptext SLIT("class") <+> pp_decl_head context clas tyvars <+> pprFundeps fds
 498         ppr_sig sig = ppr sig <> semi
 499
 500         pp_methods = getPprStyle $ \ sty ->
 501                      if ifaceStyle sty || isNothing methods
 502                         then empty
 503                         else ppr (fromJust methods)
 504
 505 pp_decl_head :: Outputable name => HsContext name -> name -> [HsTyVarBndr name] -> SDoc
 506 pp_decl_head context thing tyvars = hsep [pprHsContext context, ppr thing, interppSP tyvars]
 507
 508 pp_condecls []     ncons = ptext SLIT("{- abstract with") <+> int ncons <+> ptext SLIT("constructors -}")
 509 pp_condecls (c:cs) ncons = equals <+> sep (ppr c : map (\ c -> ptext SLIT("|") <+> ppr c) cs)
 510
 511 pp_tydecl pp_head pp_decl_rhs derivings
 512   = hang pp_head 4 (sep [
 513         pp_decl_rhs,
 514         case derivings of
 515           Nothing          -> empty
 516           Just ds          -> hsep [ptext SLIT("deriving"), ppr_hs_context ds]
 517     ])
 518 \end{code}
 519
 520
 521 %************************************************************************
 522 %*                                                                      *
 523 \subsection[ConDecl]{A data-constructor declaration}
 524 %*                                                                      *
 525 %************************************************************************
 526
 527 \begin{code}
 528 data ConDecl name
 529   = ConDecl     name                    -- Constructor name; this is used for the
 530                                         -- DataCon itself, and for the user-callable wrapper Id
 531
 532                 name                    -- Name of the constructor's 'worker Id'
 533                                         -- Filled in as the ConDecl is built
 534
 535                 [HsTyVarBndr name]      -- Existentially quantified type variables
 536                 (HsContext name)        -- ...and context
 537                                         -- If both are empty then there are no existentials
 538
 539                 (ConDetails name)
 540                 SrcLoc
 541
 542 data ConDetails name
 543   = VanillaCon                  -- prefix-style con decl
 544                 [BangType name]
 545
 546   | InfixCon                    -- infix-style con decl
 547                 (BangType name)
 548                 (BangType name)
 549
 550   | RecCon                      -- record-style con decl
 551                 [([name], BangType name)]       -- list of "fields"
 552 \end{code}
 553
 554 \begin{code}
 555 conDeclsNames :: Eq name => [ConDecl name] -> [(name,SrcLoc)]
 556   -- See tyClDeclNames for what this does
 557   -- The function is boringly complicated because of the records
 558   -- And since we only have equality, we have to be a little careful
 559 conDeclsNames cons
 560   = snd (foldl do_one ([], []) cons)
 561   where
 562     do_one (flds_seen, acc) (ConDecl name _ _ _ details loc)
 563         = do_details ((name,loc):acc) details
 564         where
 565           do_details acc (RecCon flds) = foldl do_fld (flds_seen, acc) flds
 566           do_details acc other         = (flds_seen, acc)
 567
 568           do_fld acc (flds, _) = foldl do_fld1 acc flds
 569
 570           do_fld1 (flds_seen, acc) fld
 571                 | fld `elem` flds_seen = (flds_seen,acc)
 572                 | otherwise            = (fld:flds_seen, (fld,loc):acc)
 573 \end{code}
 574
 575 \begin{code}
 576 conDetailsTys :: ConDetails name -> [HsType name]
 577 conDetailsTys (VanillaCon btys)    = map getBangType btys
 578 conDetailsTys (InfixCon bty1 bty2) = [getBangType bty1, getBangType bty2]
 579 conDetailsTys (RecCon fields)      = [getBangType bty | (_, bty) <- fields]
 580
 581
 582 eq_ConDecl env (ConDecl n1 _ tvs1 cxt1 cds1 _)
 583                (ConDecl n2 _ tvs2 cxt2 cds2 _)
 584   = n1 == n2 &&
 585     (eq_hsTyVars env tvs1 tvs2  $ \ env ->
 586      eq_hsContext env cxt1 cxt2 &&
 587      eq_ConDetails env cds1 cds2)
 588
 589 eq_ConDetails env (VanillaCon bts1) (VanillaCon bts2)
 590   = eqListBy (eq_btype env) bts1 bts2
 591 eq_ConDetails env (InfixCon bta1 btb1) (InfixCon bta2 btb2)
 592   = eq_btype env bta1 bta2 && eq_btype env btb1 btb2
 593 eq_ConDetails env (RecCon fs1) (RecCon fs2)
 594   = eqListBy (eq_fld env) fs1 fs2
 595 eq_ConDetails env _ _ = False
 596
 597 eq_fld env (ns1,bt1) (ns2, bt2) = ns1==ns2 && eq_btype env bt1 bt2
 598 \end{code}
 599
 600 \begin{code}
 601 data BangType name = BangType StrictnessMark (HsType name)
 602
 603 getBangType       (BangType _ ty) = ty
 604 getBangStrictness (BangType s _)  = s
 605
 606 unbangedType ty = BangType NotMarkedStrict ty
 607
 608 eq_btype env (BangType s1 t1) (BangType s2 t2) = s1==s2 && eq_hsType env t1 t2
 609 \end{code}
 610
 611 \begin{code}
 612 instance (Outputable name) => Outputable (ConDecl name) where
 613     ppr (ConDecl con _ tvs cxt con_details  loc)
 614       = sep [pprHsForAll tvs cxt, ppr_con_details con con_details]
 615
 616 ppr_con_details con (InfixCon ty1 ty2)
 617   = hsep [ppr_bang ty1, ppr con, ppr_bang ty2]
 618
 619 -- ConDecls generated by MkIface.ifaceTyThing always have a VanillaCon, even
 620 -- if the constructor is an infix one.  This is because in an interface file
 621 -- we don't distinguish between the two.  Hence when printing these for the
 622 -- user, we need to parenthesise infix constructor names.
 623 ppr_con_details con (VanillaCon tys)
 624   = getPprStyle $ \ sty ->
 625     hsep ((if ifaceStyle sty then ppr con else ppr_var con)
 626           : map (ppr_bang) tys)
 627
 628 ppr_con_details con (RecCon fields)
 629   = ppr con <+> braces (sep (punctuate comma (map ppr_field fields)))
 630   where
 631     ppr_field (ns, ty) = hsep (map (ppr) ns) <+>
 632                          dcolon <+>
 633                          ppr_bang ty
 634
 635 instance Outputable name => Outputable (BangType name) where
 636     ppr = ppr_bang
 637
 638 ppr_bang (BangType s ty) = ppr s <> pprParendHsType ty
 639 \end{code}
 640
 641
 642 %************************************************************************
 643 %*                                                                      *
 644 \subsection[InstDecl]{An instance declaration
 645 %*                                                                      *
 646 %************************************************************************
 647
 648 \begin{code}
 649 data InstDecl name pat
 650   = InstDecl    (HsType name)   -- Context => Class Instance-type
 651                                 -- Using a polytype means that the renamer conveniently
 652                                 -- figures out the quantified type variables for us.
 653
 654                 (MonoBinds name pat)
 655
 656                 [Sig name]              -- User-supplied pragmatic info
 657
 658                 (Maybe name)            -- Name for the dictionary function
 659                                         -- Nothing for source-file instance decls
 660
 661                 SrcLoc
 662
 663 isSourceInstDecl :: InstDecl name pat -> Bool
 664 isSourceInstDecl (InstDecl _ _ _ maybe_dfun _) = isNothing maybe_dfun
 665 \end{code}
 666
 667 \begin{code}
 668 instance (Outputable name, Outputable pat)
 669               => Outputable (InstDecl name pat) where
 670
 671     ppr (InstDecl inst_ty binds uprags maybe_dfun_name src_loc)
 672       = getPprStyle $ \ sty ->
 673         if ifaceStyle sty then
 674            hsep [ptext SLIT("instance"), ppr inst_ty, equals, pp_dfun]
 675         else
 676            vcat [hsep [ptext SLIT("instance"), ppr inst_ty, ptext SLIT("where")],
 677                  nest 4 (ppr uprags),
 678                  nest 4 (ppr binds) ]
 679       where
 680         pp_dfun = case maybe_dfun_name of
 681                     Just df -> ppr df
 682                     Nothing -> empty
 683 \end{code}
 684
 685 \begin{code}
 686 instance Ord name => Eq (InstDecl name pat) where
 687         -- Used for interface comparison only, so don't compare bindings
 688   (==) (InstDecl inst_ty1 _ _ dfun1 _) (InstDecl inst_ty2 _ _ dfun2 _)
 689        = inst_ty1 == inst_ty2 && dfun1 == dfun2
 690 \end{code}
 691
 692
 693 %************************************************************************
 694 %*                                                                      *
 695 \subsection[DefaultDecl]{A @default@ declaration}
 696 %*                                                                      *
 697 %************************************************************************
 698
 699 There can only be one default declaration per module, but it is hard
 700 for the parser to check that; we pass them all through in the abstract
 701 syntax, and that restriction must be checked in the front end.
 702
 703 \begin{code}
 704 data DefaultDecl name
 705   = DefaultDecl [HsType name]
 706                 SrcLoc
 707
 708 instance (Outputable name)
 709               => Outputable (DefaultDecl name) where
 710
 711     ppr (DefaultDecl tys src_loc)
 712       = ptext SLIT("default") <+> parens (interpp'SP tys)
 713 \end{code}
 714
 715 %************************************************************************
 716 %*                                                                      *
 717 \subsection{Foreign function interface declaration}
 718 %*                                                                      *
 719 %************************************************************************
 720
 721 \begin{code}
 722 data ForeignDecl name
 723   = ForeignImport name (HsType name) FoImport     SrcLoc
 724   | ForeignExport name (HsType name) FoExport     SrcLoc
 725
 726 forDeclName (ForeignImport n _ _ _) = n
 727 forDeclName (ForeignExport n _ _ _) = n
 728
 729 data FoImport
 730   = LblImport  CLabelString     -- foreign label
 731   | CImport    CCallSpec        -- foreign import
 732   | CDynImport CCallConv        -- foreign export dynamic
 733   | DNImport   DNCallSpec       -- foreign import dotnet
 734
 735 data FoExport = CExport CExportSpec
 736
 737 data FoType = DNType            -- In due course we'll add subtype stuff
 738             deriving( Eq )      -- Used for equality instance for TyClDecl
 739
 740 instance Outputable name => Outputable (ForeignDecl name) where
 741   ppr (ForeignImport nm ty (LblImport lbl) src_loc)
 742     = ptext SLIT("foreign label") <+> ppr lbl <+> ppr nm <+> dcolon <+> ppr ty
 743   ppr (ForeignImport nm ty decl src_loc)
 744     = ptext SLIT("foreign import") <+> ppr decl <+> ppr nm <+> dcolon <+> ppr ty
 745   ppr (ForeignExport nm ty decl src_loc)
 746     = ptext SLIT("foreign export") <+> ppr decl <+> ppr nm <+> dcolon <+> ppr ty
 747
 748 instance Outputable FoImport where
 749    ppr (CImport  d)      = ppr d
 750    ppr (CDynImport conv) = text "dynamic" <+> ppr conv
 751    ppr (DNImport d)      = ptext SLIT("dotnet") <+> ppr d
 752    ppr (LblImport l)     = ptext SLIT("label") <+> ppr l
 753
 754 instance Outputable FoExport where
 755    ppr (CExport d) = ppr d
 756
 757 instance Outputable FoType where
 758    ppr DNType = ptext SLIT("type dotnet")
 759 \end{code}
 760
 761
 762 %************************************************************************
 763 %*                                                                      *
 764 \subsection{Transformation rules}
 765 %*                                                                      *
 766 %************************************************************************
 767
 768 \begin{code}
 769 data RuleDecl name pat
 770   = HsRule                      -- Source rule
 771         RuleName                -- Rule name
 772         Activation
 773         [RuleBndr name]         -- Forall'd vars; after typechecking this includes tyvars
 774         (HsExpr name pat)       -- LHS
 775         (HsExpr name pat)       -- RHS
 776         SrcLoc
 777
 778   | IfaceRule                   -- One that's come in from an interface file; pre-typecheck
 779         RuleName
 780         Activation
 781         [UfBinder name]         -- Tyvars and term vars
 782         name                    -- Head of lhs
 783         [UfExpr name]           -- Args of LHS
 784         (UfExpr name)           -- Pre typecheck
 785         SrcLoc
 786
 787   | IfaceRuleOut                -- Post typecheck
 788         name                    -- Head of LHS
 789         CoreRule
 790
 791 ifaceRuleDeclName :: RuleDecl name pat -> name
 792 ifaceRuleDeclName (IfaceRule _ _ _ n _ _ _) = n
 793 ifaceRuleDeclName (IfaceRuleOut n r)        = n
 794 ifaceRuleDeclName (HsRule fs _ _ _ _ _)     = pprPanic "ifaceRuleDeclName" (ppr fs)
 795
 796 data RuleBndr name
 797   = RuleBndr name
 798   | RuleBndrSig name (HsType name)
 799
 800 collectRuleBndrSigTys :: [RuleBndr name] -> [HsType name]
 801 collectRuleBndrSigTys bndrs = [ty | RuleBndrSig _ ty <- bndrs]
 802
 803 instance (NamedThing name, Ord name) => Eq (RuleDecl name pat) where
 804   -- Works for IfaceRules only; used when comparing interface file versions
 805   (IfaceRule n1 a1 bs1 f1 es1 rhs1 _) == (IfaceRule n2 a2 bs2 f2 es2 rhs2 _)
 806      = n1==n2 && f1 == f2 && a1==a2 &&
 807        eq_ufBinders emptyEqHsEnv bs1 bs2 (\env ->
 808        eqListBy (eq_ufExpr env) (rhs1:es1) (rhs2:es2))
 809
 810 instance (NamedThing name, Outputable name, Outputable pat)
 811               => Outputable (RuleDecl name pat) where
 812   ppr (HsRule name act ns lhs rhs loc)
 813         = sep [text "{-# RULES" <+> doubleQuotes (ptext name) <+> ppr act,
 814                pp_forall, ppr lhs, equals <+> ppr rhs,
 815                text "#-}" ]
 816         where
 817           pp_forall | null ns   = empty
 818                     | otherwise = text "forall" <+> fsep (map ppr ns) <> dot
 819
 820   ppr (IfaceRule name act tpl_vars fn tpl_args rhs loc)
 821     = hsep [ doubleQuotes (ptext name), ppr act,
 822            ptext SLIT("__forall") <+> braces (interppSP tpl_vars),
 823            ppr fn <+> sep (map (pprUfExpr parens) tpl_args),
 824            ptext SLIT("=") <+> ppr rhs
 825       ] <+> semi
 826
 827   ppr (IfaceRuleOut fn rule) = pprCoreRule (ppr fn) rule
 828
 829 instance Outputable name => Outputable (RuleBndr name) where
 830    ppr (RuleBndr name) = ppr name
 831    ppr (RuleBndrSig name ty) = ppr name <> dcolon <> ppr ty
 832 \end{code}
 833
 834
 835 %************************************************************************
 836 %*                                                                      *
 837 \subsection[DeprecDecl]{Deprecations}
 838 %*                                                                      *
 839 %************************************************************************
 840
 841 We use exported entities for things to deprecate.
 842
 843 \begin{code}
 844 data DeprecDecl name = Deprecation name DeprecTxt SrcLoc
 845
 846 type DeprecTxt = FAST_STRING    -- reason/explanation for deprecation
 847
 848 instance Outputable name => Outputable (DeprecDecl name) where
 849     ppr (Deprecation thing txt _)
 850       = hsep [text "{-# DEPRECATED", ppr thing, doubleQuotes (ppr txt), text "#-}"]
 851 \end{code}