ghc/compiler/hsSyn/HsDecls.lhs

   1 %
   2 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   3 %
   4 \section[HsDecls]{Abstract syntax: global declarations}
   5
   6 Definitions for: @TyDecl@ and @oCnDecl@, @ClassDecl@,
   7 @InstDecl@, @DefaultDecl@ and @ForeignDecl@.
   8
   9 \begin{code}
  10 module HsDecls (
  11         HsDecl(..), TyClDecl(..), InstDecl(..), RuleDecl(..), RuleBndr(..),
  12         DefaultDecl(..),
  13         ForeignDecl(..), ForeignImport(..), ForeignExport(..),
  14         CImportSpec(..), FoType(..),
  15         ConDecl(..), ConDetails(..),
  16         BangType(..), getBangType, getBangStrictness, unbangedType,
  17         DeprecDecl(..), DeprecTxt,
  18         hsDeclName, instDeclName,
  19         tyClDeclName, tyClDeclNames, tyClDeclSysNames, tyClDeclTyVars,
  20         isClassDecl, isSynDecl, isDataDecl, isIfaceSigDecl, countTyClDecls,
  21         mkClassDeclSysNames, isSourceInstDecl, ifaceRuleDeclName,
  22         getClassDeclSysNames, conDetailsTys,
  23         collectRuleBndrSigTys
  24     ) where
  25
  26 #include "HsVersions.h"
  27
  28 -- friends:
  29 import HsBinds          ( HsBinds, MonoBinds, Sig(..), FixitySig(..) )
  30 import HsExpr           ( HsExpr )
  31 import HsImpExp         ( ppr_var )
  32 import HsTypes
  33 import PprCore          ( pprCoreRule )
  34 import HsCore           ( UfExpr, UfBinder, HsIdInfo, pprHsIdInfo,
  35                           eq_ufBinders, eq_ufExpr, pprUfExpr
  36                         )
  37 import CoreSyn          ( CoreRule(..), RuleName )
  38 import BasicTypes       ( NewOrData(..), StrictnessMark(..), Activation(..) )
  39 import ForeignCall      ( CCallTarget(..), DNCallSpec, CCallConv, Safety,
  40                           CExportSpec(..))
  41
  42 -- others:
  43 import Name             ( NamedThing )
  44 import FunDeps          ( pprFundeps )
  45 import TyCon            ( DataConDetails(..), visibleDataCons )
  46 import Class            ( FunDep, DefMeth(..) )
  47 import CStrings         ( CLabelString )
  48 import Outputable
  49 import Util             ( eqListBy, count )
  50 import SrcLoc           ( SrcLoc )
  51 import FastString
  52
  53 import Maybe            ( isNothing, fromJust )
  54 \end{code}
  55
  56
  57 %************************************************************************
  58 %*                                                                      *
  59 \subsection[HsDecl]{Declarations}
  60 %*                                                                      *
  61 %************************************************************************
  62
  63 \begin{code}
  64 data HsDecl name pat
  65   = TyClD       (TyClDecl name pat)
  66   | InstD       (InstDecl  name pat)
  67   | DefD        (DefaultDecl name)
  68   | ValD        (HsBinds name pat)
  69   | ForD        (ForeignDecl name)
  70   | FixD        (FixitySig name)
  71   | DeprecD     (DeprecDecl name)
  72   | RuleD       (RuleDecl name pat)
  73
  74 -- NB: all top-level fixity decls are contained EITHER
  75 -- EITHER FixDs
  76 -- OR     in the ClassDecls in TyClDs
  77 --
  78 -- The former covers
  79 --      a) data constructors
  80 --      b) class methods (but they can be also done in the
  81 --              signatures of class decls)
  82 --      c) imported functions (that have an IfacSig)
  83 --      d) top level decls
  84 --
  85 -- The latter is for class methods only
  86 \end{code}
  87
  88 \begin{code}
  89 #ifdef DEBUG
  90 hsDeclName :: (NamedThing name, Outputable name, Outputable pat)
  91            => HsDecl name pat -> name
  92 #endif
  93 hsDeclName (TyClD decl)                 = tyClDeclName     decl
  94 hsDeclName (InstD decl)                 = instDeclName     decl
  95 hsDeclName (ForD  decl)                 = foreignDeclName decl
  96 hsDeclName (FixD  (FixitySig name _ _)) = name
  97 -- Others don't make sense
  98 #ifdef DEBUG
  99 hsDeclName x                            = pprPanic "HsDecls.hsDeclName" (ppr x)
 100 #endif
 101
 102
 103 instDeclName :: InstDecl name pat -> name
 104 instDeclName (InstDecl _ _ _ (Just name) _) = name
 105
 106 \end{code}
 107
 108 \begin{code}
 109 instance (NamedThing name, Outputable name, Outputable pat)
 110         => Outputable (HsDecl name pat) where
 111
 112     ppr (TyClD dcl)  = ppr dcl
 113     ppr (ValD binds) = ppr binds
 114     ppr (DefD def)   = ppr def
 115     ppr (InstD inst) = ppr inst
 116     ppr (ForD fd)    = ppr fd
 117     ppr (FixD fd)    = ppr fd
 118     ppr (RuleD rd)   = ppr rd
 119     ppr (DeprecD dd) = ppr dd
 120 \end{code}
 121
 122
 123 %************************************************************************
 124 %*                                                                      *
 125 \subsection[TyDecl]{@data@, @newtype@ or @type@ (synonym) type declaration}
 126 %*                                                                      *
 127 %************************************************************************
 128
 129                 --------------------------------
 130                         THE NAMING STORY
 131                 --------------------------------
 132
 133 Here is the story about the implicit names that go with type, class, and instance
 134 decls.  It's a bit tricky, so pay attention!
 135
 136 "Implicit" (or "system") binders
 137 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 138   Each data type decl defines
 139         a worker name for each constructor
 140         to-T and from-T convertors
 141   Each class decl defines
 142         a tycon for the class
 143         a data constructor for that tycon
 144         the worker for that constructor
 145         a selector for each superclass
 146
 147 All have occurrence names that are derived uniquely from their parent declaration.
 148
 149 None of these get separate definitions in an interface file; they are
 150 fully defined by the data or class decl.  But they may *occur* in
 151 interface files, of course.  Any such occurrence must haul in the
 152 relevant type or class decl.
 153
 154 Plan of attack:
 155  - Make up their occurrence names immediately
 156    This is done in RdrHsSyn.mkClassDecl, mkTyDecl, mkConDecl
 157
 158  - Ensure they "point to" the parent data/class decl
 159    when loading that decl from an interface file
 160    (See RnHiFiles.getTyClDeclSysNames)
 161
 162  - When renaming the decl look them up in the name cache,
 163    ensure correct module and provenance is set
 164
 165 Default methods
 166 ~~~~~~~~~~~~~~~
 167  - Occurrence name is derived uniquely from the method name
 168    E.g. $dmmax
 169
 170  - If there is a default method name at all, it's recorded in
 171    the ClassOpSig (in HsBinds), in the DefMeth field.
 172    (DefMeth is defined in Class.lhs)
 173
 174 Source-code class decls and interface-code class decls are treated subtly
 175 differently, which has given me a great deal of confusion over the years.
 176 Here's the deal.  (We distinguish the two cases because source-code decls
 177 have (Just binds) in the tcdMeths field, whereas interface decls have Nothing.
 178
 179 In *source-code* class declarations:
 180  - When parsing, every ClassOpSig gets a DefMeth with a suitable RdrName
 181    This is done by RdrHsSyn.mkClassOpSigDM
 182
 183  - The renamer renames it to a Name
 184
 185  - During typechecking, we generate a binding for each $dm for
 186    which there's a programmer-supplied default method:
 187         class Foo a where
 188           op1 :: <type>
 189           op2 :: <type>
 190           op1 = ...
 191    We generate a binding for $dmop1 but not for $dmop2.
 192    The Class for Foo has a NoDefMeth for op2 and a DefMeth for op1.
 193    The Name for $dmop2 is simply discarded.
 194
 195 In *interface-file* class declarations:
 196   - When parsing, we see if there's an explicit programmer-supplied default method
 197     because there's an '=' sign to indicate it:
 198         class Foo a where
 199           op1 = :: <type>       -- NB the '='
 200           op2   :: <type>
 201     We use this info to generate a DefMeth with a suitable RdrName for op1,
 202     and a NoDefMeth for op2
 203   - The interface file has a separate definition for $dmop1, with unfolding etc.
 204   - The renamer renames it to a Name.
 205   - The renamer treats $dmop1 as a free variable of the declaration, so that
 206     the binding for $dmop1 will be sucked in.  (See RnHsSyn.tyClDeclFVs)
 207     This doesn't happen for source code class decls, because they *bind* the default method.
 208
 209 Dictionary functions
 210 ~~~~~~~~~~~~~~~~~~~~
 211 Each instance declaration gives rise to one dictionary function binding.
 212
 213 The type checker makes up new source-code instance declarations
 214 (e.g. from 'deriving' or generic default methods --- see
 215 TcInstDcls.tcInstDecls1).  So we can't generate the names for
 216 dictionary functions in advance (we don't know how many we need).
 217
 218 On the other hand for interface-file instance declarations, the decl
 219 specifies the name of the dictionary function, and it has a binding elsewhere
 220 in the interface file:
 221         instance {Eq Int} = dEqInt
 222         dEqInt :: {Eq Int} <pragma info>
 223
 224 So again we treat source code and interface file code slightly differently.
 225
 226 Source code:
 227   - Source code instance decls have a Nothing in the (Maybe name) field
 228     (see data InstDecl below)
 229
 230   - The typechecker makes up a Local name for the dict fun for any source-code
 231     instance decl, whether it comes from a source-code instance decl, or whether
 232     the instance decl is derived from some other construct (e.g. 'deriving').
 233
 234   - The occurrence name it chooses is derived from the instance decl (just for
 235     documentation really) --- e.g. dNumInt.  Two dict funs may share a common
 236     occurrence name, but will have different uniques.  E.g.
 237         instance Foo [Int]  where ...
 238         instance Foo [Bool] where ...
 239     These might both be dFooList
 240
 241   - The CoreTidy phase externalises the name, and ensures the occurrence name is
 242     unique (this isn't special to dict funs).  So we'd get dFooList and dFooList1.
 243
 244   - We can take this relaxed approach (changing the occurrence name later)
 245     because dict fun Ids are not captured in a TyCon or Class (unlike default
 246     methods, say).  Instead, they are kept separately in the InstEnv.  This
 247     makes it easy to adjust them after compiling a module.  (Once we've finished
 248     compiling that module, they don't change any more.)
 249
 250
 251 Interface file code:
 252   - The instance decl gives the dict fun name, so the InstDecl has a (Just name)
 253     in the (Maybe name) field.
 254
 255   - RnHsSyn.instDeclFVs treats the dict fun name as free in the decl, so that we
 256     suck in the dfun binding
 257
 258
 259 \begin{code}
 260 -- TyClDecls are precisely the kind of declarations that can
 261 -- appear in interface files; or (internally) in GHC's interface
 262 -- for a module.  That's why (despite the misnomer) IfaceSig and ForeignType
 263 -- are both in TyClDecl
 264
 265 data TyClDecl name pat
 266   = IfaceSig {  tcdName :: name,                -- It may seem odd to classify an interface-file signature
 267                 tcdType :: HsType name,         -- as a 'TyClDecl', but it's very convenient.
 268                 tcdIdInfo :: [HsIdInfo name],
 269                 tcdLoc :: SrcLoc
 270     }
 271
 272   | ForeignType { tcdName    :: name,           -- See remarks about IfaceSig above
 273                   tcdExtName :: Maybe FastString,
 274                   tcdFoType  :: FoType,
 275                   tcdLoc     :: SrcLoc }
 276
 277   | TyData {    tcdND     :: NewOrData,
 278                 tcdCtxt   :: HsContext name,     -- context
 279                 tcdName   :: name,               -- type constructor
 280                 tcdTyVars :: [HsTyVarBndr name], -- type variables
 281                 tcdCons   :: DataConDetails (ConDecl name),      -- data constructors (empty if abstract)
 282                 tcdDerivs :: Maybe (HsContext name),    -- derivings; Nothing => not specified
 283                                                         -- Just [] => derive exactly what is asked
 284                 tcdSysNames :: DataSysNames name,       -- Generic converter functions
 285                 tcdLoc      :: SrcLoc
 286     }
 287
 288   | TySynonym { tcdName :: name,                        -- type constructor
 289                 tcdTyVars :: [HsTyVarBndr name],        -- type variables
 290                 tcdSynRhs :: HsType name,               -- synonym expansion
 291                 tcdLoc    :: SrcLoc
 292     }
 293
 294   | ClassDecl { tcdCtxt    :: HsContext name,           -- Context...
 295                 tcdName    :: name,                     -- Name of the class
 296                 tcdTyVars  :: [HsTyVarBndr name],       -- The class type variables
 297                 tcdFDs     :: [FunDep name],            -- Functional dependencies
 298                 tcdSigs    :: [Sig name],               -- Methods' signatures
 299                 tcdMeths   :: Maybe (MonoBinds name pat),       -- Default methods
 300                                                                 -- Nothing for imported class decls
 301                                                                 -- Just bs for source   class decls
 302                 tcdSysNames :: ClassSysNames name,
 303                 tcdLoc      :: SrcLoc
 304     }
 305 \end{code}
 306
 307 Simple classifiers
 308
 309 \begin{code}
 310 isIfaceSigDecl, isDataDecl, isSynDecl, isClassDecl :: TyClDecl name pat -> Bool
 311
 312 isIfaceSigDecl (IfaceSig {}) = True
 313 isIfaceSigDecl other         = False
 314
 315 isSynDecl (TySynonym {}) = True
 316 isSynDecl other          = False
 317
 318 isDataDecl (TyData {}) = True
 319 isDataDecl other       = False
 320
 321 isClassDecl (ClassDecl {}) = True
 322 isClassDecl other          = False
 323 \end{code}
 324
 325 Dealing with names
 326
 327 \begin{code}
 328 --------------------------------
 329 tyClDeclName :: TyClDecl name pat -> name
 330 tyClDeclName tycl_decl = tcdName tycl_decl
 331
 332 --------------------------------
 333 tyClDeclNames :: Eq name => TyClDecl name pat -> [(name, SrcLoc)]
 334 -- Returns all the *binding* names of the decl, along with their SrcLocs
 335 -- The first one is guaranteed to be the name of the decl
 336 -- For record fields, the first one counts as the SrcLoc
 337 -- We use the equality to filter out duplicate field names
 338
 339 tyClDeclNames (TySynonym   {tcdName = name, tcdLoc = loc})  = [(name,loc)]
 340 tyClDeclNames (IfaceSig    {tcdName = name, tcdLoc = loc})  = [(name,loc)]
 341 tyClDeclNames (ForeignType {tcdName = name, tcdLoc = loc})  = [(name,loc)]
 342
 343 tyClDeclNames (ClassDecl {tcdName = cls_name, tcdSigs = sigs, tcdLoc = loc})
 344   = (cls_name,loc) : [(n,loc) | ClassOpSig n _ _ loc <- sigs]
 345
 346 tyClDeclNames (TyData {tcdName = tc_name, tcdCons = cons, tcdLoc = loc})
 347   = (tc_name,loc) : conDeclsNames cons
 348
 349
 350 tyClDeclTyVars (TySynonym {tcdTyVars = tvs}) = tvs
 351 tyClDeclTyVars (TyData    {tcdTyVars = tvs}) = tvs
 352 tyClDeclTyVars (ClassDecl {tcdTyVars = tvs}) = tvs
 353 tyClDeclTyVars (ForeignType {})              = []
 354 tyClDeclTyVars (IfaceSig {})                 = []
 355
 356
 357 --------------------------------
 358 -- The "system names" are extra implicit names *bound* by the decl.
 359 -- They are kept in a list rather than a tuple
 360 -- to make the renamer easier.
 361
 362 type ClassSysNames name = [name]
 363 -- For class decls they are:
 364 --      [tycon, datacon wrapper, datacon worker,
 365 --       superclass selector 1, ..., superclass selector n]
 366
 367 type DataSysNames name =  [name]
 368 -- For data decls they are
 369 --      [from, to]
 370 -- where from :: T -> Tring
 371 --       to   :: Tring -> T
 372
 373 tyClDeclSysNames :: TyClDecl name pat -> [(name, SrcLoc)]
 374 -- Similar to tyClDeclNames, but returns the "implicit"
 375 -- or "system" names of the declaration
 376
 377 tyClDeclSysNames (ClassDecl {tcdSysNames = names, tcdLoc = loc})
 378   = [(n,loc) | n <- names]
 379 tyClDeclSysNames (TyData {tcdCons = DataCons cons, tcdSysNames = names, tcdLoc = loc})
 380   = [(n,loc) | n <- names] ++
 381     [(wkr_name,loc) | ConDecl _ wkr_name _ _ _ loc <- cons]
 382 tyClDeclSysNames decl = []
 383
 384
 385 mkClassDeclSysNames  :: (name, name, name, [name]) -> [name]
 386 getClassDeclSysNames :: [name] -> (name, name, name, [name])
 387 mkClassDeclSysNames  (a,b,c,ds) = a:b:c:ds
 388 getClassDeclSysNames (a:b:c:ds) = (a,b,c,ds)
 389 \end{code}
 390
 391 \begin{code}
 392 instance (NamedThing name, Ord name) => Eq (TyClDecl name pat) where
 393         -- Used only when building interface files
 394   (==) d1@(IfaceSig {}) d2@(IfaceSig {})
 395       = tcdName d1 == tcdName d2 &&
 396         tcdType d1 == tcdType d2 &&
 397         tcdIdInfo d1 == tcdIdInfo d2
 398
 399   (==) d1@(ForeignType {}) d2@(ForeignType {})
 400       = tcdName d1 == tcdName d2 &&
 401         tcdFoType d1 == tcdFoType d2
 402
 403   (==) d1@(TyData {}) d2@(TyData {})
 404       = tcdName d1 == tcdName d2 &&
 405         tcdND d1   == tcdND   d2 &&
 406         eqWithHsTyVars (tcdTyVars d1) (tcdTyVars d2) (\ env ->
 407           eq_hsContext env (tcdCtxt d1) (tcdCtxt d2)  &&
 408           eq_hsCD      env (tcdCons d1) (tcdCons d2)
 409         )
 410
 411   (==) d1@(TySynonym {}) d2@(TySynonym {})
 412       = tcdName d1 == tcdName d2 &&
 413         eqWithHsTyVars (tcdTyVars d1) (tcdTyVars d2) (\ env ->
 414           eq_hsType env (tcdSynRhs d1) (tcdSynRhs d2)
 415         )
 416
 417   (==) d1@(ClassDecl {}) d2@(ClassDecl {})
 418     = tcdName d1 == tcdName d2 &&
 419       eqWithHsTyVars (tcdTyVars d1) (tcdTyVars d2) (\ env ->
 420           eq_hsContext env (tcdCtxt d1) (tcdCtxt d2)  &&
 421           eqListBy (eq_hsFD env) (tcdFDs d1) (tcdFDs d2) &&
 422           eqListBy (eq_cls_sig env) (tcdSigs d1) (tcdSigs d2)
 423        )
 424
 425   (==) _ _ = False      -- default case
 426
 427 eq_hsCD env (DataCons c1) (DataCons c2) = eqListBy (eq_ConDecl env) c1 c2
 428 eq_hsCD env Unknown       Unknown       = True
 429 eq_hsCD env (HasCons n1)  (HasCons n2)  = n1 == n2
 430 eq_hsCD env d1            d2            = False
 431
 432 eq_hsFD env (ns1,ms1) (ns2,ms2)
 433   = eqListBy (eq_hsVar env) ns1 ns2 && eqListBy (eq_hsVar env) ms1 ms2
 434
 435 eq_cls_sig env (ClassOpSig n1 dm1 ty1 _) (ClassOpSig n2 dm2 ty2 _)
 436   = n1==n2 && dm1 `eq_dm` dm2 && eq_hsType env ty1 ty2
 437   where
 438         -- Ignore the name of the default method for (DefMeth id)
 439         -- This is used for comparing declarations before putting
 440         -- them into interface files, and the name of the default
 441         -- method isn't relevant
 442     NoDefMeth  `eq_dm` NoDefMeth  = True
 443     GenDefMeth `eq_dm` GenDefMeth = True
 444     DefMeth _  `eq_dm` DefMeth _  = True
 445     dm1        `eq_dm` dm2        = False
 446
 447
 448 \end{code}
 449
 450 \begin{code}
 451 countTyClDecls :: [TyClDecl name pat] -> (Int, Int, Int, Int, Int)
 452         -- class, data, newtype, synonym decls
 453 countTyClDecls decls
 454  = (count isClassDecl     decls,
 455     count isSynDecl       decls,
 456     count isIfaceSigDecl  decls,
 457     count isDataTy        decls,
 458     count isNewTy         decls)
 459  where
 460    isDataTy TyData{tcdND=DataType} = True
 461    isDataTy _                      = False
 462
 463    isNewTy TyData{tcdND=NewType} = True
 464    isNewTy _                     = False
 465 \end{code}
 466
 467 \begin{code}
 468 instance (NamedThing name, Outputable name, Outputable pat)
 469               => Outputable (TyClDecl name pat) where
 470
 471     ppr (IfaceSig {tcdName = var, tcdType = ty, tcdIdInfo = info})
 472         = getPprStyle $ \ sty ->
 473            hsep [ if ifaceStyle sty then ppr var else ppr_var var,
 474                   dcolon, ppr ty, pprHsIdInfo info
 475                 ]
 476
 477     ppr (ForeignType {tcdName = tycon})
 478         = hsep [ptext SLIT("foreign import type dotnet"), ppr tycon]
 479
 480     ppr (TySynonym {tcdName = tycon, tcdTyVars = tyvars, tcdSynRhs = mono_ty})
 481       = hang (ptext SLIT("type") <+> pp_decl_head [] tycon tyvars <+> equals)
 482              4 (ppr mono_ty)
 483
 484     ppr (TyData {tcdND = new_or_data, tcdCtxt = context, tcdName = tycon,
 485                  tcdTyVars = tyvars, tcdCons = condecls,
 486                  tcdDerivs = derivings})
 487       = pp_tydecl (ptext keyword <+> pp_decl_head context tycon tyvars)
 488                   (pp_condecls condecls)
 489                   derivings
 490       where
 491         keyword = case new_or_data of
 492                         NewType  -> SLIT("newtype")
 493                         DataType -> SLIT("data")
 494
 495     ppr (ClassDecl {tcdCtxt = context, tcdName = clas, tcdTyVars = tyvars, tcdFDs = fds,
 496                     tcdSigs = sigs, tcdMeths = methods})
 497       | null sigs       -- No "where" part
 498       = top_matter
 499
 500       | otherwise       -- Laid out
 501       = sep [hsep [top_matter, ptext SLIT("where {")],
 502              nest 4 (sep [sep (map ppr_sig sigs), pp_methods, char '}'])]
 503       where
 504         top_matter  = ptext SLIT("class") <+> pp_decl_head context clas tyvars <+> pprFundeps fds
 505         ppr_sig sig = ppr sig <> semi
 506
 507         pp_methods = getPprStyle $ \ sty ->
 508                      if ifaceStyle sty || isNothing methods
 509                         then empty
 510                         else ppr (fromJust methods)
 511
 512 pp_decl_head :: Outputable name => HsContext name -> name -> [HsTyVarBndr name] -> SDoc
 513 pp_decl_head context thing tyvars = hsep [pprHsContext context, ppr thing, interppSP tyvars]
 514
 515 pp_condecls Unknown       = ptext SLIT("{- abstract -}")
 516 pp_condecls (HasCons n)   = ptext SLIT("{- abstract with") <+> int n <+> ptext SLIT("constructors -}")
 517 pp_condecls (DataCons cs) = equals <+> sep (punctuate (ptext SLIT(" |")) (map ppr cs))
 518
 519 pp_tydecl pp_head pp_decl_rhs derivings
 520   = hang pp_head 4 (sep [
 521         pp_decl_rhs,
 522         case derivings of
 523           Nothing          -> empty
 524           Just ds          -> hsep [ptext SLIT("deriving"), ppr_hs_context ds]
 525     ])
 526 \end{code}
 527
 528
 529 %************************************************************************
 530 %*                                                                      *
 531 \subsection[ConDecl]{A data-constructor declaration}
 532 %*                                                                      *
 533 %************************************************************************
 534
 535 \begin{code}
 536 data ConDecl name
 537   = ConDecl     name                    -- Constructor name; this is used for the
 538                                         -- DataCon itself, and for the user-callable wrapper Id
 539
 540                 name                    -- Name of the constructor's 'worker Id'
 541                                         -- Filled in as the ConDecl is built
 542
 543                 [HsTyVarBndr name]      -- Existentially quantified type variables
 544                 (HsContext name)        -- ...and context
 545                                         -- If both are empty then there are no existentials
 546
 547                 (ConDetails name)
 548                 SrcLoc
 549
 550 data ConDetails name
 551   = VanillaCon                  -- prefix-style con decl
 552                 [BangType name]
 553
 554   | InfixCon                    -- infix-style con decl
 555                 (BangType name)
 556                 (BangType name)
 557
 558   | RecCon                      -- record-style con decl
 559                 [([name], BangType name)]       -- list of "fields"
 560 \end{code}
 561
 562 \begin{code}
 563 conDeclsNames :: Eq name => DataConDetails (ConDecl name) -> [(name,SrcLoc)]
 564   -- See tyClDeclNames for what this does
 565   -- The function is boringly complicated because of the records
 566   -- And since we only have equality, we have to be a little careful
 567 conDeclsNames cons
 568   = snd (foldl do_one ([], []) (visibleDataCons cons))
 569   where
 570     do_one (flds_seen, acc) (ConDecl name _ _ _ details loc)
 571         = do_details ((name,loc):acc) details
 572         where
 573           do_details acc (RecCon flds) = foldl do_fld (flds_seen, acc) flds
 574           do_details acc other         = (flds_seen, acc)
 575
 576           do_fld acc (flds, _) = foldl do_fld1 acc flds
 577
 578           do_fld1 (flds_seen, acc) fld
 579                 | fld `elem` flds_seen = (flds_seen,acc)
 580                 | otherwise            = (fld:flds_seen, (fld,loc):acc)
 581 \end{code}
 582
 583 \begin{code}
 584 conDetailsTys :: ConDetails name -> [HsType name]
 585 conDetailsTys (VanillaCon btys)    = map getBangType btys
 586 conDetailsTys (InfixCon bty1 bty2) = [getBangType bty1, getBangType bty2]
 587 conDetailsTys (RecCon fields)      = [getBangType bty | (_, bty) <- fields]
 588
 589
 590 eq_ConDecl env (ConDecl n1 _ tvs1 cxt1 cds1 _)
 591                (ConDecl n2 _ tvs2 cxt2 cds2 _)
 592   = n1 == n2 &&
 593     (eq_hsTyVars env tvs1 tvs2  $ \ env ->
 594      eq_hsContext env cxt1 cxt2 &&
 595      eq_ConDetails env cds1 cds2)
 596
 597 eq_ConDetails env (VanillaCon bts1) (VanillaCon bts2)
 598   = eqListBy (eq_btype env) bts1 bts2
 599 eq_ConDetails env (InfixCon bta1 btb1) (InfixCon bta2 btb2)
 600   = eq_btype env bta1 bta2 && eq_btype env btb1 btb2
 601 eq_ConDetails env (RecCon fs1) (RecCon fs2)
 602   = eqListBy (eq_fld env) fs1 fs2
 603 eq_ConDetails env _ _ = False
 604
 605 eq_fld env (ns1,bt1) (ns2, bt2) = ns1==ns2 && eq_btype env bt1 bt2
 606 \end{code}
 607
 608 \begin{code}
 609 data BangType name = BangType StrictnessMark (HsType name)
 610
 611 getBangType       (BangType _ ty) = ty
 612 getBangStrictness (BangType s _)  = s
 613
 614 unbangedType ty = BangType NotMarkedStrict ty
 615
 616 eq_btype env (BangType s1 t1) (BangType s2 t2) = s1==s2 && eq_hsType env t1 t2
 617 \end{code}
 618
 619 \begin{code}
 620 instance (Outputable name) => Outputable (ConDecl name) where
 621     ppr (ConDecl con _ tvs cxt con_details  loc)
 622       = sep [pprHsForAll tvs cxt, ppr_con_details con con_details]
 623
 624 ppr_con_details con (InfixCon ty1 ty2)
 625   = hsep [ppr_bang ty1, ppr con, ppr_bang ty2]
 626
 627 -- ConDecls generated by MkIface.ifaceTyThing always have a VanillaCon, even
 628 -- if the constructor is an infix one.  This is because in an interface file
 629 -- we don't distinguish between the two.  Hence when printing these for the
 630 -- user, we need to parenthesise infix constructor names.
 631 ppr_con_details con (VanillaCon tys)
 632   = getPprStyle $ \ sty ->
 633     hsep ((if ifaceStyle sty then ppr con else ppr_var con)
 634           : map (ppr_bang) tys)
 635
 636 ppr_con_details con (RecCon fields)
 637   = ppr con <+> braces (sep (punctuate comma (map ppr_field fields)))
 638   where
 639     ppr_field (ns, ty) = hsep (map (ppr) ns) <+>
 640                          dcolon <+>
 641                          ppr_bang ty
 642
 643 instance Outputable name => Outputable (BangType name) where
 644     ppr = ppr_bang
 645
 646 ppr_bang (BangType s ty) = ppr s <> pprParendHsType ty
 647 \end{code}
 648
 649
 650 %************************************************************************
 651 %*                                                                      *
 652 \subsection[InstDecl]{An instance declaration
 653 %*                                                                      *
 654 %************************************************************************
 655
 656 \begin{code}
 657 data InstDecl name pat
 658   = InstDecl    (HsType name)   -- Context => Class Instance-type
 659                                 -- Using a polytype means that the renamer conveniently
 660                                 -- figures out the quantified type variables for us.
 661
 662                 (MonoBinds name pat)
 663
 664                 [Sig name]              -- User-supplied pragmatic info
 665
 666                 (Maybe name)            -- Name for the dictionary function
 667                                         -- Nothing for source-file instance decls
 668
 669                 SrcLoc
 670
 671 isSourceInstDecl :: InstDecl name pat -> Bool
 672 isSourceInstDecl (InstDecl _ _ _ maybe_dfun _) = isNothing maybe_dfun
 673 \end{code}
 674
 675 \begin{code}
 676 instance (Outputable name, Outputable pat)
 677               => Outputable (InstDecl name pat) where
 678
 679     ppr (InstDecl inst_ty binds uprags maybe_dfun_name src_loc)
 680       = getPprStyle $ \ sty ->
 681         if ifaceStyle sty then
 682            hsep [ptext SLIT("instance"), ppr inst_ty, equals, pp_dfun]
 683         else
 684            vcat [hsep [ptext SLIT("instance"), ppr inst_ty, ptext SLIT("where")],
 685                  nest 4 (ppr uprags),
 686                  nest 4 (ppr binds) ]
 687       where
 688         pp_dfun = case maybe_dfun_name of
 689                     Just df -> ppr df
 690                     Nothing -> empty
 691 \end{code}
 692
 693 \begin{code}
 694 instance Ord name => Eq (InstDecl name pat) where
 695         -- Used for interface comparison only, so don't compare bindings
 696   (==) (InstDecl inst_ty1 _ _ dfun1 _) (InstDecl inst_ty2 _ _ dfun2 _)
 697        = inst_ty1 == inst_ty2 && dfun1 == dfun2
 698 \end{code}
 699
 700
 701 %************************************************************************
 702 %*                                                                      *
 703 \subsection[DefaultDecl]{A @default@ declaration}
 704 %*                                                                      *
 705 %************************************************************************
 706
 707 There can only be one default declaration per module, but it is hard
 708 for the parser to check that; we pass them all through in the abstract
 709 syntax, and that restriction must be checked in the front end.
 710
 711 \begin{code}
 712 data DefaultDecl name
 713   = DefaultDecl [HsType name]
 714                 SrcLoc
 715
 716 instance (Outputable name)
 717               => Outputable (DefaultDecl name) where
 718
 719     ppr (DefaultDecl tys src_loc)
 720       = ptext SLIT("default") <+> parens (interpp'SP tys)
 721 \end{code}
 722
 723 %************************************************************************
 724 %*                                                                      *
 725 \subsection{Foreign function interface declaration}
 726 %*                                                                      *
 727 %************************************************************************
 728
 729 \begin{code}
 730
 731 -- foreign declarations are distinguished as to whether they define or use a
 732 -- Haskell name
 733 --
 734 -- * the Boolean value indicates whether the pre-standard deprecated syntax
 735 --   has been used
 736 --
 737 data ForeignDecl name
 738   = ForeignImport name (HsType name) ForeignImport Bool SrcLoc  -- defines name
 739   | ForeignExport name (HsType name) ForeignExport Bool SrcLoc  -- uses name
 740
 741 -- yield the Haskell name defined or used in a foreign declaration
 742 --
 743 foreignDeclName                           :: ForeignDecl name -> name
 744 foreignDeclName (ForeignImport n _ _ _ _)  = n
 745 foreignDeclName (ForeignExport n _ _ _ _)  = n
 746
 747 -- specification of an imported external entity in dependence on the calling
 748 -- convention
 749 --
 750 data ForeignImport = -- import of a C entity
 751                      --
 752                      -- * the two strings specifying a header file or library
 753                      --   may be empty, which indicates the absence of a
 754                      --   header or object specification (both are not used
 755                      --   in the case of `CWrapper' and when `CFunction'
 756                      --   has a dynamic target)
 757                      --
 758                      -- * the calling convention is irrelevant for code
 759                      --   generation in the case of `CLabel', but is needed
 760                      --   for pretty printing
 761                      --
 762                      -- * `Safety' is irrelevant for `CLabel' and `CWrapper'
 763                      --
 764                      CImport  CCallConv       -- ccall or stdcall
 765                               Safety          -- safe or unsafe
 766                               FastString      -- name of C header
 767                               FastString      -- name of library object
 768                               CImportSpec     -- details of the C entity
 769
 770                      -- import of a .NET function
 771                      --
 772                    | DNImport DNCallSpec
 773
 774 -- details of an external C entity
 775 --
 776 data CImportSpec = CLabel    CLabelString     -- import address of a C label
 777                  | CFunction CCallTarget      -- static or dynamic function
 778                  | CWrapper                   -- wrapper to expose closures
 779                                               -- (former f.e.d.)
 780
 781 -- specification of an externally exported entity in dependence on the calling
 782 -- convention
 783 --
 784 data ForeignExport = CExport  CExportSpec    -- contains the calling convention
 785                    | DNExport                -- presently unused
 786
 787 -- abstract type imported from .NET
 788 --
 789 data FoType = DNType            -- In due course we'll add subtype stuff
 790             deriving (Eq)       -- Used for equality instance for TyClDecl
 791
 792
 793 -- pretty printing of foreign declarations
 794 --
 795
 796 instance Outputable name => Outputable (ForeignDecl name) where
 797   ppr (ForeignImport n ty fimport _ _) =
 798     ptext SLIT("foreign import") <+> ppr fimport <+>
 799     ppr n <+> dcolon <+> ppr ty
 800   ppr (ForeignExport n ty fexport _ _) =
 801     ptext SLIT("foreign export") <+> ppr fexport <+>
 802     ppr n <+> dcolon <+> ppr ty
 803
 804 instance Outputable ForeignImport where
 805   ppr (DNImport                         spec) =
 806     ptext SLIT("dotnet") <+> ppr spec
 807   ppr (CImport  cconv safety header lib spec) =
 808     ppr cconv <+> ppr safety <+>
 809     char '"' <> pprCEntity header lib spec <> char '"'
 810     where
 811       pprCEntity header lib (CLabel lbl) =
 812         ptext SLIT("static") <+> ptext header <+> char '&' <>
 813         pprLib lib <> ppr lbl
 814       pprCEntity header lib (CFunction (StaticTarget lbl)) =
 815         ptext SLIT("static") <+> ptext header <+> char '&' <>
 816         pprLib lib <> ppr lbl
 817       pprCEntity header lib (CFunction (DynamicTarget)) =
 818         ptext SLIT("dynamic")
 819       pprCEntity header lib (CFunction (CasmTarget _)) =
 820         panic "HsDecls.pprCEntity: malformed C function target"
 821       pprCEntity _      _   (CWrapper) = ptext SLIT("wrapper")
 822       --
 823       pprLib lib | nullFastString lib = empty
 824                  | otherwise          = char '[' <> ppr lib <> char ']'
 825
 826 instance Outputable ForeignExport where
 827   ppr (CExport  (CExportStatic lbl cconv)) =
 828     ppr cconv <+> char '"' <> ppr lbl <> char '"'
 829   ppr (DNExport                          ) =
 830     ptext SLIT("dotnet") <+> ptext SLIT("\"<unused>\"")
 831
 832 instance Outputable FoType where
 833   ppr DNType = ptext SLIT("type dotnet")
 834 \end{code}
 835
 836
 837 %************************************************************************
 838 %*                                                                      *
 839 \subsection{Transformation rules}
 840 %*                                                                      *
 841 %************************************************************************
 842
 843 \begin{code}
 844 data RuleDecl name pat
 845   = HsRule                      -- Source rule
 846         RuleName                -- Rule name
 847         Activation
 848         [RuleBndr name]         -- Forall'd vars; after typechecking this includes tyvars
 849         (HsExpr name pat)       -- LHS
 850         (HsExpr name pat)       -- RHS
 851         SrcLoc
 852
 853   | IfaceRule                   -- One that's come in from an interface file; pre-typecheck
 854         RuleName
 855         Activation
 856         [UfBinder name]         -- Tyvars and term vars
 857         name                    -- Head of lhs
 858         [UfExpr name]           -- Args of LHS
 859         (UfExpr name)           -- Pre typecheck
 860         SrcLoc
 861
 862   | IfaceRuleOut                -- Post typecheck
 863         name                    -- Head of LHS
 864         CoreRule
 865
 866 ifaceRuleDeclName :: RuleDecl name pat -> name
 867 ifaceRuleDeclName (IfaceRule _ _ _ n _ _ _) = n
 868 ifaceRuleDeclName (IfaceRuleOut n r)        = n
 869 ifaceRuleDeclName (HsRule fs _ _ _ _ _)     = pprPanic "ifaceRuleDeclName" (ppr fs)
 870
 871 data RuleBndr name
 872   = RuleBndr name
 873   | RuleBndrSig name (HsType name)
 874
 875 collectRuleBndrSigTys :: [RuleBndr name] -> [HsType name]
 876 collectRuleBndrSigTys bndrs = [ty | RuleBndrSig _ ty <- bndrs]
 877
 878 instance (NamedThing name, Ord name) => Eq (RuleDecl name pat) where
 879   -- Works for IfaceRules only; used when comparing interface file versions
 880   (IfaceRule n1 a1 bs1 f1 es1 rhs1 _) == (IfaceRule n2 a2 bs2 f2 es2 rhs2 _)
 881      = n1==n2 && f1 == f2 && a1==a2 &&
 882        eq_ufBinders emptyEqHsEnv bs1 bs2 (\env ->
 883        eqListBy (eq_ufExpr env) (rhs1:es1) (rhs2:es2))
 884
 885 instance (NamedThing name, Outputable name, Outputable pat)
 886               => Outputable (RuleDecl name pat) where
 887   ppr (HsRule name act ns lhs rhs loc)
 888         = sep [text "{-# RULES" <+> doubleQuotes (ptext name) <+> ppr act,
 889                pp_forall, ppr lhs, equals <+> ppr rhs,
 890                text "#-}" ]
 891         where
 892           pp_forall | null ns   = empty
 893                     | otherwise = text "forall" <+> fsep (map ppr ns) <> dot
 894
 895   ppr (IfaceRule name act tpl_vars fn tpl_args rhs loc)
 896     = hsep [ doubleQuotes (ptext name), ppr act,
 897            ptext SLIT("__forall") <+> braces (interppSP tpl_vars),
 898            ppr fn <+> sep (map (pprUfExpr parens) tpl_args),
 899            ptext SLIT("=") <+> ppr rhs
 900       ] <+> semi
 901
 902   ppr (IfaceRuleOut fn rule) = pprCoreRule (ppr fn) rule
 903
 904 instance Outputable name => Outputable (RuleBndr name) where
 905    ppr (RuleBndr name) = ppr name
 906    ppr (RuleBndrSig name ty) = ppr name <> dcolon <> ppr ty
 907 \end{code}
 908
 909
 910 %************************************************************************
 911 %*                                                                      *
 912 \subsection[DeprecDecl]{Deprecations}
 913 %*                                                                      *
 914 %************************************************************************
 915
 916 We use exported entities for things to deprecate.
 917
 918 \begin{code}
 919 data DeprecDecl name = Deprecation name DeprecTxt SrcLoc
 920
 921 type DeprecTxt = FAST_STRING    -- reason/explanation for deprecation
 922
 923 instance Outputable name => Outputable (DeprecDecl name) where
 924     ppr (Deprecation thing txt _)
 925       = hsep [text "{-# DEPRECATED", ppr thing, doubleQuotes (ppr txt), text "#-}"]
 926 \end{code}