ghc/compiler/hsSyn/HsExpr.lhs

   1 %
   2 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   3 %
   4 \section[HsExpr]{Abstract Haskell syntax: expressions}
   5
   6 \begin{code}
   7 module HsExpr where
   8
   9 #include "HsVersions.h"
  10
  11 -- friends:
  12 import HsDecls          ( HsGroup )
  13 import HsPat            ( LPat )
  14 import HsLit            ( HsLit(..), HsOverLit )
  15 import HsTypes          ( LHsType, PostTcType )
  16 import HsImpExp         ( isOperator, pprHsVar )
  17 import HsBinds          ( HsLocalBinds, DictBinds, isEmptyLocalBinds )
  18
  19 -- others:
  20 import Type             ( Type, pprParendType )
  21 import Var              ( TyVar, Id )
  22 import Name             ( Name )
  23 import BasicTypes       ( IPName, Boxity, tupleParens, Fixity(..) )
  24 import SrcLoc           ( Located(..), unLoc )
  25 import Outputable
  26 import FastString
  27 \end{code}
  28
  29
  30 %************************************************************************
  31 %*                                                                      *
  32 \subsection{Expressions proper}
  33 %*                                                                      *
  34 %************************************************************************
  35
  36 \begin{code}
  37 type LHsExpr id = Located (HsExpr id)
  38
  39 -------------------------
  40 -- PostTcExpr is an evidence expression attached to the
  41 -- syntax tree by the type checker (c.f. postTcType)
  42 -- We use a PostTcTable where there are a bunch of pieces of
  43 -- evidence, more than is convenient to keep individually
  44 type PostTcExpr  = HsExpr Id
  45 type PostTcTable = [(Name, Id)]
  46
  47 noPostTcExpr :: PostTcExpr
  48 noPostTcExpr = HsLit (HsString FSLIT("noPostTcExpr"))
  49
  50 noPostTcTable :: PostTcTable
  51 noPostTcTable = []
  52
  53 -------------------------
  54 -- SyntaxExpr is like PostTcExpr, but it's filled in a little earlier,
  55 -- by the renamer.  It's used for rebindable syntax.
  56 -- E.g. (>>=) is filled in before the renamer by the appropriate Name
  57 --      for (>>=), and then instantiated by the type checker with its
  58 --      type args tec
  59
  60 type SyntaxExpr id = HsExpr id
  61
  62 noSyntaxExpr :: SyntaxExpr id   -- Before renaming, and sometimes after,
  63                                 -- (if the syntax slot makes no sense)
  64 noSyntaxExpr = HsLit (HsString FSLIT("noSyntaxExpr"))
  65
  66
  67 type SyntaxTable id = [(Name, SyntaxExpr id)]
  68 --      *** Currently used only for CmdTop (sigh) ***
  69 -- * Before the renamer, this list is noSyntaxTable
  70 --
  71 -- * After the renamer, it takes the form [(std_name, HsVar actual_name)]
  72 --   For example, for the 'return' op of a monad
  73 --      normal case:            (GHC.Base.return, HsVar GHC.Base.return)
  74 --      with rebindable syntax: (GHC.Base.return, return_22)
  75 --              where return_22 is whatever "return" is in scope
  76 --
  77 -- * After the type checker, it takes the form [(std_name, <expression>)]
  78 --      where <expression> is the evidence for the method
  79
  80 noSyntaxTable :: SyntaxTable id
  81 noSyntaxTable = []
  82
  83
  84 -------------------------
  85 data HsExpr id
  86   = HsVar       id              -- variable
  87   | HsIPVar     (IPName id)     -- implicit parameter
  88   | HsOverLit   (HsOverLit id)  -- Overloaded literals
  89   | HsLit       HsLit           -- Simple (non-overloaded) literals
  90
  91   | HsLam       (MatchGroup  id)        -- Currently always a single match
  92
  93   | HsApp       (LHsExpr id)            -- Application
  94                 (LHsExpr id)
  95
  96   -- Operator applications:
  97   -- NB Bracketed ops such as (+) come out as Vars.
  98
  99   -- NB We need an expr for the operator in an OpApp/Section since
 100   -- the typechecker may need to apply the operator to a few types.
 101
 102   | OpApp       (LHsExpr id)    -- left operand
 103                 (LHsExpr id)    -- operator
 104                 Fixity          -- Renamer adds fixity; bottom until then
 105                 (LHsExpr id)    -- right operand
 106
 107   | NegApp      (LHsExpr id)    -- negated expr
 108                 (SyntaxExpr id) -- Name of 'negate'
 109
 110   | HsPar       (LHsExpr id)    -- parenthesised expr
 111
 112   | SectionL    (LHsExpr id)    -- operand
 113                 (LHsExpr id)    -- operator
 114   | SectionR    (LHsExpr id)    -- operator
 115                 (LHsExpr id)    -- operand
 116
 117   | HsCase      (LHsExpr id)
 118                 (MatchGroup id)
 119
 120   | HsIf        (LHsExpr id)    --  predicate
 121                 (LHsExpr id)    --  then part
 122                 (LHsExpr id)    --  else part
 123
 124   | HsLet       (HsLocalBinds id) -- let(rec)
 125                 (LHsExpr  id)
 126
 127   | HsDo        (HsStmtContext Name)    -- The parameterisation is unimportant
 128                                         -- because in this context we never use
 129                                         -- the PatGuard or ParStmt variant
 130                 [LStmt id]              -- "do":one or more stmts
 131                 (LHsExpr id)            -- The body; the last expression in the 'do'
 132                                         --           of [ body | ... ] in a list comp
 133                 PostTcType              -- Type of the whole expression
 134
 135   | ExplicitList                -- syntactic list
 136                 PostTcType      -- Gives type of components of list
 137                 [LHsExpr id]
 138
 139   | ExplicitPArr                -- syntactic parallel array: [:e1, ..., en:]
 140                 PostTcType      -- type of elements of the parallel array
 141                 [LHsExpr id]
 142
 143   | ExplicitTuple               -- tuple
 144                 [LHsExpr id]
 145                                 -- NB: Unit is ExplicitTuple []
 146                                 -- for tuples, we can get the types
 147                                 -- direct from the components
 148                 Boxity
 149
 150
 151         -- Record construction
 152   | RecordCon   (Located id)            -- The constructor.  After type checking
 153                                         -- it's the dataConWrapId of the constructor
 154                 PostTcExpr              -- Data con Id applied to type args
 155                 (HsRecordBinds id)
 156
 157         -- Record update
 158   | RecordUpd   (LHsExpr id)
 159                 (HsRecordBinds id)
 160                 PostTcType              -- Type of *input* record
 161                 PostTcType              -- Type of *result* record (may differ from
 162                                         --      type of input record)
 163
 164   | ExprWithTySig                       -- e :: type
 165                 (LHsExpr id)
 166                 (LHsType id)
 167
 168   | ExprWithTySigOut                    -- TRANSLATION
 169                 (LHsExpr id)
 170                 (LHsType Name)          -- Retain the signature for round-tripping purposes
 171
 172   | ArithSeq                            -- arithmetic sequence
 173                 PostTcExpr
 174                 (ArithSeqInfo id)
 175
 176   | PArrSeq                             -- arith. sequence for parallel array
 177                 PostTcExpr              -- [:e1..e2:] or [:e1, e2..e3:]
 178                 (ArithSeqInfo id)
 179
 180   | HsSCC       FastString      -- "set cost centre" (_scc_) annotation
 181                 (LHsExpr id)    -- expr whose cost is to be measured
 182
 183   | HsCoreAnn   FastString      -- hdaume: core annotation
 184                 (LHsExpr id)
 185
 186   -----------------------------------------------------------
 187   -- MetaHaskell Extensions
 188   | HsBracket    (HsBracket id)
 189
 190   | HsBracketOut (HsBracket Name)       -- Output of the type checker is the *original*
 191                  [PendingSplice]        -- renamed expression, plus *typechecked* splices
 192                                         -- to be pasted back in by the desugarer
 193
 194   | HsSpliceE (HsSplice id)
 195
 196   -----------------------------------------------------------
 197   -- Arrow notation extension
 198
 199   | HsProc      (LPat id)               -- arrow abstraction, proc
 200                 (LHsCmdTop id)          -- body of the abstraction
 201                                         -- always has an empty stack
 202
 203   ---------------------------------------
 204   -- The following are commands, not expressions proper
 205
 206   | HsArrApp    -- Arrow tail, or arrow application (f -< arg)
 207         (LHsExpr id)    -- arrow expression, f
 208         (LHsExpr id)    -- input expression, arg
 209         PostTcType      -- type of the arrow expressions f,
 210                         -- of the form a t t', where arg :: t
 211         HsArrAppType    -- higher-order (-<<) or first-order (-<)
 212         Bool            -- True => right-to-left (f -< arg)
 213                         -- False => left-to-right (arg >- f)
 214
 215   | HsArrForm   -- Command formation,  (| e cmd1 .. cmdn |)
 216         (LHsExpr id)    -- the operator
 217                         -- after type-checking, a type abstraction to be
 218                         -- applied to the type of the local environment tuple
 219         (Maybe Fixity)  -- fixity (filled in by the renamer), for forms that
 220                         -- were converted from OpApp's by the renamer
 221         [LHsCmdTop id]  -- argument commands
 222 \end{code}
 223
 224
 225 These constructors only appear temporarily in the parser.
 226 The renamer translates them into the Right Thing.
 227
 228 \begin{code}
 229   | EWildPat                    -- wildcard
 230
 231   | EAsPat      (Located id)    -- as pattern
 232                 (LHsExpr id)
 233
 234   | ELazyPat    (LHsExpr id) -- ~ pattern
 235
 236   | HsType      (LHsType id)     -- Explicit type argument; e.g  f {| Int |} x y
 237 \end{code}
 238
 239 Everything from here on appears only in typechecker output.
 240
 241 \begin{code}
 242   | TyLam                       -- TRANSLATION
 243                 [TyVar]
 244                 (LHsExpr id)
 245   | TyApp                       -- TRANSLATION
 246                 (LHsExpr id) -- generated by Spec
 247                 [Type]
 248
 249   -- DictLam and DictApp are "inverses"
 250   |  DictLam
 251                 [id]
 252                 (LHsExpr id)
 253   |  DictApp
 254                 (LHsExpr id)
 255                 [id]
 256
 257 type PendingSplice = (Name, LHsExpr Id) -- Typechecked splices, waiting to be
 258                                         -- pasted back in by the desugarer
 259 \end{code}
 260
 261 A @Dictionary@, unless of length 0 or 1, becomes a tuple.  A
 262 @ClassDictLam dictvars methods expr@ is, therefore:
 263 \begin{verbatim}
 264 \ x -> case x of ( dictvars-and-methods-tuple ) -> expr
 265 \end{verbatim}
 266
 267 \begin{code}
 268 instance OutputableBndr id => Outputable (HsExpr id) where
 269     ppr expr = pprExpr expr
 270 \end{code}
 271
 272 \begin{code}
 273 pprExpr :: OutputableBndr id => HsExpr id -> SDoc
 274
 275 pprExpr  e = pprDeeper (ppr_expr e)
 276
 277 pprBinds :: OutputableBndr id => HsLocalBinds id -> SDoc
 278 pprBinds b = pprDeeper (ppr b)
 279
 280 ppr_lexpr :: OutputableBndr id => LHsExpr id -> SDoc
 281 ppr_lexpr e = ppr_expr (unLoc e)
 282
 283 ppr_expr (HsVar v)       = pprHsVar v
 284 ppr_expr (HsIPVar v)     = ppr v
 285 ppr_expr (HsLit lit)     = ppr lit
 286 ppr_expr (HsOverLit lit) = ppr lit
 287
 288 ppr_expr (HsApp e1 e2)
 289   = let (fun, args) = collect_args e1 [e2] in
 290     (ppr_lexpr fun) <+> (sep (map pprParendExpr args))
 291   where
 292     collect_args (L _ (HsApp fun arg)) args = collect_args fun (arg:args)
 293     collect_args fun args = (fun, args)
 294
 295 ppr_expr (OpApp e1 op fixity e2)
 296   = case unLoc op of
 297       HsVar v -> pp_infixly v
 298       _       -> pp_prefixly
 299   where
 300     pp_e1 = pprParendExpr e1            -- Add parens to make precedence clear
 301     pp_e2 = pprParendExpr e2
 302
 303     pp_prefixly
 304       = hang (ppr op) 4 (sep [pp_e1, pp_e2])
 305
 306     pp_infixly v
 307       = sep [pp_e1, hsep [pprInfix v, pp_e2]]
 308
 309 ppr_expr (NegApp e _) = char '-' <+> pprParendExpr e
 310
 311 ppr_expr (HsPar e) = parens (ppr_lexpr e)
 312
 313 ppr_expr (SectionL expr op)
 314   = case unLoc op of
 315       HsVar v -> pp_infixly v
 316       _       -> pp_prefixly
 317   where
 318     pp_expr = pprParendExpr expr
 319
 320     pp_prefixly = hang (hsep [text " \\ x_ ->", ppr op])
 321                        4 (hsep [pp_expr, ptext SLIT("x_ )")])
 322     pp_infixly v = parens (sep [pp_expr, pprInfix v])
 323
 324 ppr_expr (SectionR op expr)
 325   = case unLoc op of
 326       HsVar v -> pp_infixly v
 327       _       -> pp_prefixly
 328   where
 329     pp_expr = pprParendExpr expr
 330
 331     pp_prefixly = hang (hsep [text "( \\ x_ ->", ppr op, ptext SLIT("x_")])
 332                        4 ((<>) pp_expr rparen)
 333     pp_infixly v
 334       = parens (sep [pprInfix v, pp_expr])
 335
 336 ppr_expr (HsLam matches)
 337   = pprMatches LambdaExpr matches
 338
 339 ppr_expr (HsCase expr matches)
 340   = sep [ sep [ptext SLIT("case"), nest 4 (ppr expr), ptext SLIT("of")],
 341             nest 2 (pprMatches CaseAlt matches) ]
 342
 343 ppr_expr (HsIf e1 e2 e3)
 344   = sep [hsep [ptext SLIT("if"), nest 2 (ppr e1), ptext SLIT("then")],
 345            nest 4 (ppr e2),
 346            ptext SLIT("else"),
 347            nest 4 (ppr e3)]
 348
 349 -- special case: let ... in let ...
 350 ppr_expr (HsLet binds expr@(L _ (HsLet _ _)))
 351   = sep [hang (ptext SLIT("let")) 2 (hsep [pprBinds binds, ptext SLIT("in")]),
 352          ppr_lexpr expr]
 353
 354 ppr_expr (HsLet binds expr)
 355   = sep [hang (ptext SLIT("let")) 2 (pprBinds binds),
 356          hang (ptext SLIT("in"))  2 (ppr expr)]
 357
 358 ppr_expr (HsDo do_or_list_comp stmts body _) = pprDo do_or_list_comp stmts body
 359
 360 ppr_expr (ExplicitList _ exprs)
 361   = brackets (fsep (punctuate comma (map ppr_lexpr exprs)))
 362
 363 ppr_expr (ExplicitPArr _ exprs)
 364   = pa_brackets (fsep (punctuate comma (map ppr_lexpr exprs)))
 365
 366 ppr_expr (ExplicitTuple exprs boxity)
 367   = tupleParens boxity (sep (punctuate comma (map ppr_lexpr exprs)))
 368
 369 ppr_expr (RecordCon con_id con_expr rbinds)
 370   = pp_rbinds (ppr con_id) rbinds
 371
 372 ppr_expr (RecordUpd aexp rbinds _ _)
 373   = pp_rbinds (pprParendExpr aexp) rbinds
 374
 375 ppr_expr (ExprWithTySig expr sig)
 376   = hang (nest 2 (ppr_lexpr expr) <+> dcolon)
 377          4 (ppr sig)
 378 ppr_expr (ExprWithTySigOut expr sig)
 379   = hang (nest 2 (ppr_lexpr expr) <+> dcolon)
 380          4 (ppr sig)
 381
 382 ppr_expr (ArithSeq expr info) = brackets (ppr info)
 383 ppr_expr (PArrSeq expr info)  = pa_brackets (ppr info)
 384
 385 ppr_expr EWildPat     = char '_'
 386 ppr_expr (ELazyPat e) = char '~' <> pprParendExpr e
 387 ppr_expr (EAsPat v e) = ppr v <> char '@' <> pprParendExpr e
 388
 389 ppr_expr (HsSCC lbl expr)
 390   = sep [ ptext SLIT("_scc_") <+> doubleQuotes (ftext lbl), pprParendExpr expr ]
 391
 392 ppr_expr (TyLam tyvars expr)
 393   = hang (hsep [ptext SLIT("/\\"),
 394                 hsep (map (pprBndr LambdaBind) tyvars),
 395                 ptext SLIT("->")])
 396          4 (ppr_lexpr expr)
 397
 398 ppr_expr (TyApp expr [ty])
 399   = hang (ppr_lexpr expr) 4 (pprParendType ty)
 400
 401 ppr_expr (TyApp expr tys)
 402   = hang (ppr_lexpr expr)
 403          4 (brackets (interpp'SP tys))
 404
 405 ppr_expr (DictLam dictvars expr)
 406   = hang (hsep [ptext SLIT("\\{-dict-}"),
 407                 hsep (map (pprBndr LambdaBind) dictvars),
 408                 ptext SLIT("->")])
 409          4 (ppr_lexpr expr)
 410
 411 ppr_expr (DictApp expr [dname])
 412   = hang (ppr_lexpr expr) 4 (ppr dname)
 413
 414 ppr_expr (DictApp expr dnames)
 415   = hang (ppr_lexpr expr)
 416          4 (brackets (interpp'SP dnames))
 417
 418 ppr_expr (HsType id) = ppr id
 419
 420 ppr_expr (HsSpliceE s)       = pprSplice s
 421 ppr_expr (HsBracket b)       = pprHsBracket b
 422 ppr_expr (HsBracketOut e []) = ppr e
 423 ppr_expr (HsBracketOut e ps) = ppr e $$ ptext SLIT("pending") <+> ppr ps
 424
 425 ppr_expr (HsProc pat (L _ (HsCmdTop cmd _ _ _)))
 426   = hsep [ptext SLIT("proc"), ppr pat, ptext SLIT("->"), ppr cmd]
 427
 428 ppr_expr (HsArrApp arrow arg _ HsFirstOrderApp True)
 429   = hsep [ppr_lexpr arrow, ptext SLIT("-<"), ppr_lexpr arg]
 430 ppr_expr (HsArrApp arrow arg _ HsFirstOrderApp False)
 431   = hsep [ppr_lexpr arg, ptext SLIT(">-"), ppr_lexpr arrow]
 432 ppr_expr (HsArrApp arrow arg _ HsHigherOrderApp True)
 433   = hsep [ppr_lexpr arrow, ptext SLIT("-<<"), ppr_lexpr arg]
 434 ppr_expr (HsArrApp arrow arg _ HsHigherOrderApp False)
 435   = hsep [ppr_lexpr arg, ptext SLIT(">>-"), ppr_lexpr arrow]
 436
 437 ppr_expr (HsArrForm (L _ (HsVar v)) (Just _) [arg1, arg2])
 438   = sep [pprCmdArg (unLoc arg1), hsep [pprInfix v, pprCmdArg (unLoc arg2)]]
 439 ppr_expr (HsArrForm op _ args)
 440   = hang (ptext SLIT("(|") <> ppr_lexpr op)
 441          4 (sep (map (pprCmdArg.unLoc) args) <> ptext SLIT("|)"))
 442
 443 pprCmdArg :: OutputableBndr id => HsCmdTop id -> SDoc
 444 pprCmdArg (HsCmdTop cmd@(L _ (HsArrForm _ Nothing [])) _ _ _)
 445   = ppr_lexpr cmd
 446 pprCmdArg (HsCmdTop cmd _ _ _)
 447   = parens (ppr_lexpr cmd)
 448
 449 -- Put a var in backquotes if it's not an operator already
 450 pprInfix :: Outputable name => name -> SDoc
 451 pprInfix v | isOperator ppr_v = ppr_v
 452            | otherwise        = char '`' <> ppr_v <> char '`'
 453            where
 454              ppr_v = ppr v
 455
 456 -- add parallel array brackets around a document
 457 --
 458 pa_brackets :: SDoc -> SDoc
 459 pa_brackets p = ptext SLIT("[:") <> p <> ptext SLIT(":]")
 460 \end{code}
 461
 462 Parenthesize unless very simple:
 463 \begin{code}
 464 pprParendExpr :: OutputableBndr id => LHsExpr id -> SDoc
 465 pprParendExpr expr
 466   = let
 467         pp_as_was = ppr_lexpr expr
 468         -- Using ppr_expr here avoids the call to 'deeper'
 469         -- Not sure if that's always right.
 470     in
 471     case unLoc expr of
 472       HsLit l           -> ppr l
 473       HsOverLit l       -> ppr l
 474
 475       HsVar _           -> pp_as_was
 476       HsIPVar _         -> pp_as_was
 477       ExplicitList _ _  -> pp_as_was
 478       ExplicitPArr _ _  -> pp_as_was
 479       ExplicitTuple _ _ -> pp_as_was
 480       HsPar _           -> pp_as_was
 481       HsBracket _       -> pp_as_was
 482       HsBracketOut _ [] -> pp_as_was
 483
 484       _                 -> parens pp_as_was
 485 \end{code}
 486
 487 %************************************************************************
 488 %*                                                                      *
 489 \subsection{Commands (in arrow abstractions)}
 490 %*                                                                      *
 491 %************************************************************************
 492
 493 We re-use HsExpr to represent these.
 494
 495 \begin{code}
 496 type HsCmd id = HsExpr id
 497
 498 type LHsCmd id = LHsExpr id
 499
 500 data HsArrAppType = HsHigherOrderApp | HsFirstOrderApp
 501 \end{code}
 502
 503 The legal constructors for commands are:
 504
 505   = HsArrApp ...                -- as above
 506
 507   | HsArrForm ...               -- as above
 508
 509   | HsApp       (HsCmd id)
 510                 (HsExpr id)
 511
 512   | HsLam       (Match  id)     -- kappa
 513
 514   -- the renamer turns this one into HsArrForm
 515   | OpApp       (HsExpr id)     -- left operand
 516                 (HsCmd id)      -- operator
 517                 Fixity          -- Renamer adds fixity; bottom until then
 518                 (HsCmd id)      -- right operand
 519
 520   | HsPar       (HsCmd id)      -- parenthesised command
 521
 522   | HsCase      (HsExpr id)
 523                 [Match id]      -- bodies are HsCmd's
 524                 SrcLoc
 525
 526   | HsIf        (HsExpr id)     --  predicate
 527                 (HsCmd id)      --  then part
 528                 (HsCmd id)      --  else part
 529                 SrcLoc
 530
 531   | HsLet       (HsLocalBinds id)       -- let(rec)
 532                 (HsCmd  id)
 533
 534   | HsDo        (HsStmtContext Name)    -- The parameterisation is unimportant
 535                                         -- because in this context we never use
 536                                         -- the PatGuard or ParStmt variant
 537                 [Stmt id]       -- HsExpr's are really HsCmd's
 538                 PostTcType      -- Type of the whole expression
 539                 SrcLoc
 540
 541 Top-level command, introducing a new arrow.
 542 This may occur inside a proc (where the stack is empty) or as an
 543 argument of a command-forming operator.
 544
 545 \begin{code}
 546 type LHsCmdTop id = Located (HsCmdTop id)
 547
 548 data HsCmdTop id
 549   = HsCmdTop    (LHsCmd id)
 550                 [PostTcType]    -- types of inputs on the command's stack
 551                 PostTcType      -- return type of the command
 552                 (SyntaxTable id)
 553                                 -- after type checking:
 554                                 -- names used in the command's desugaring
 555 \end{code}
 556
 557 %************************************************************************
 558 %*                                                                      *
 559 \subsection{Record binds}
 560 %*                                                                      *
 561 %************************************************************************
 562
 563 \begin{code}
 564 type HsRecordBinds id = [(Located id, LHsExpr id)]
 565
 566 recBindFields :: HsRecordBinds id -> [id]
 567 recBindFields rbinds = [unLoc field | (field,_) <- rbinds]
 568
 569 pp_rbinds :: OutputableBndr id => SDoc -> HsRecordBinds id -> SDoc
 570 pp_rbinds thing rbinds
 571   = hang thing
 572          4 (braces (sep (punctuate comma (map (pp_rbind) rbinds))))
 573   where
 574     pp_rbind (v, e) = hsep [pprBndr LetBind (unLoc v), char '=', ppr e]
 575 \end{code}
 576
 577
 578
 579 %************************************************************************
 580 %*                                                                      *
 581 \subsection{@Match@, @GRHSs@, and @GRHS@ datatypes}
 582 %*                                                                      *
 583 %************************************************************************
 584
 585 @Match@es are sets of pattern bindings and right hand sides for
 586 functions, patterns or case branches. For example, if a function @g@
 587 is defined as:
 588 \begin{verbatim}
 589 g (x,y) = y
 590 g ((x:ys),y) = y+1,
 591 \end{verbatim}
 592 then \tr{g} has two @Match@es: @(x,y) = y@ and @((x:ys),y) = y+1@.
 593
 594 It is always the case that each element of an @[Match]@ list has the
 595 same number of @pats@s inside it.  This corresponds to saying that
 596 a function defined by pattern matching must have the same number of
 597 patterns in each equation.
 598
 599 \begin{code}
 600 data MatchGroup id
 601   = MatchGroup
 602         [LMatch id]     -- The alternatives
 603         PostTcType      -- The type is the type of the entire group
 604                         --      t1 -> ... -> tn -> tr
 605                         -- where there are n patterns
 606
 607 type LMatch id = Located (Match id)
 608
 609 data Match id
 610   = Match
 611         [LPat id]               -- The patterns
 612         (Maybe (LHsType id))    -- A type signature for the result of the match
 613                                 --      Nothing after typechecking
 614         (GRHSs id)
 615
 616 hsLMatchPats :: LMatch id -> [LPat id]
 617 hsLMatchPats (L _ (Match pats _ _)) = pats
 618
 619 -- GRHSs are used both for pattern bindings and for Matches
 620 data GRHSs id
 621   = GRHSs [LGRHS id]            -- Guarded RHSs
 622           (HsLocalBinds id)     -- The where clause
 623
 624 type LGRHS id = Located (GRHS id)
 625
 626 data GRHS id = GRHS [LStmt id]          -- Guards
 627                     (LHsExpr id)        -- Right hand side
 628 \end{code}
 629
 630 We know the list must have at least one @Match@ in it.
 631
 632 \begin{code}
 633 pprMatches :: (OutputableBndr id) => HsMatchContext id -> MatchGroup id -> SDoc
 634 pprMatches ctxt (MatchGroup matches _) = vcat (map (pprMatch ctxt) (map unLoc matches))
 635
 636 -- Exported to HsBinds, which can't see the defn of HsMatchContext
 637 pprFunBind :: (OutputableBndr id) => id -> MatchGroup id -> SDoc
 638 pprFunBind fun matches = pprMatches (FunRhs fun) matches
 639
 640 -- Exported to HsBinds, which can't see the defn of HsMatchContext
 641 pprPatBind :: (OutputableBndr bndr, OutputableBndr id)
 642            => LPat bndr -> GRHSs id -> SDoc
 643 pprPatBind pat grhss = sep [ppr pat, nest 4 (pprGRHSs PatBindRhs grhss)]
 644
 645
 646 pprMatch :: OutputableBndr id => HsMatchContext id -> Match id -> SDoc
 647 pprMatch ctxt (Match pats maybe_ty grhss)
 648   = pp_name ctxt <+> sep [sep (map ppr pats),
 649                      ppr_maybe_ty,
 650                      nest 2 (pprGRHSs ctxt grhss)]
 651   where
 652     pp_name (FunRhs fun) = ppr fun      -- Not pprBndr; the AbsBinds will
 653                                         -- have printed the signature
 654     pp_name LambdaExpr   = char '\\'
 655     pp_name other        = empty
 656
 657     ppr_maybe_ty = case maybe_ty of
 658                         Just ty -> dcolon <+> ppr ty
 659                         Nothing -> empty
 660
 661
 662 pprGRHSs :: OutputableBndr id => HsMatchContext id -> GRHSs id -> SDoc
 663 pprGRHSs ctxt (GRHSs grhss binds)
 664   = vcat (map (pprGRHS ctxt . unLoc) grhss)
 665     $$
 666     (if isEmptyLocalBinds binds then empty
 667      else text "where" $$ nest 4 (pprBinds binds))
 668
 669 pprGRHS :: OutputableBndr id => HsMatchContext id -> GRHS id -> SDoc
 670
 671 pprGRHS ctxt (GRHS [] expr)
 672  =  pp_rhs ctxt expr
 673
 674 pprGRHS ctxt (GRHS guards expr)
 675  = sep [char '|' <+> interpp'SP guards, pp_rhs ctxt expr]
 676
 677 pp_rhs ctxt rhs = matchSeparator ctxt <+> pprDeeper (ppr rhs)
 678 \end{code}
 679
 680 %************************************************************************
 681 %*                                                                      *
 682 \subsection{Do stmts and list comprehensions}
 683 %*                                                                      *
 684 %************************************************************************
 685
 686 \begin{code}
 687 type LStmt id = Located (Stmt id)
 688
 689 -- The SyntaxExprs in here are used *only* for do-notation, which
 690 -- has rebindable syntax.  Otherwise they are unused.
 691 data Stmt id
 692   = BindStmt    (LPat id)
 693                 (LHsExpr id)
 694                 (SyntaxExpr id)         -- The (>>=) operator
 695                 (SyntaxExpr id)         -- The fail operator
 696                 -- The fail operator is noSyntaxExpr
 697                 -- if the pattern match can't fail
 698
 699   | ExprStmt    (LHsExpr id)
 700                 (SyntaxExpr id)         -- The (>>) operator
 701                 PostTcType              -- Element type of the RHS (used for arrows)
 702
 703   | LetStmt     (HsLocalBinds id)
 704
 705         -- ParStmts only occur in a list comprehension
 706   | ParStmt     [([LStmt id], [id])]    -- After renaming, the ids are the binders
 707                                         -- bound by the stmts and used subsequently
 708
 709         -- Recursive statement (see Note [RecStmt] below)
 710   | RecStmt  [LStmt id]
 711                 --- The next two fields are only valid after renaming
 712              [id]       -- The ids are a subset of the variables bound by the stmts
 713                         -- that are used in stmts that follow the RecStmt
 714
 715              [id]       -- Ditto, but these variables are the "recursive" ones, that
 716                         -- are used before they are bound in the stmts of the RecStmt
 717                         -- From a type-checking point of view, these ones have to be monomorphic
 718
 719                 --- These fields are only valid after typechecking
 720              [PostTcExpr]       -- These expressions correspond
 721                                 -- 1-to-1 with the "recursive" [id], and are the expresions that
 722                                 -- should be returned by the recursion.  They may not quite be the
 723                                 -- Ids themselves, because the Id may be *polymorphic*, but
 724                                 -- the returned thing has to be *monomorphic*.
 725              (DictBinds id)     -- Method bindings of Ids bound by the RecStmt,
 726                                 -- and used afterwards
 727 \end{code}
 728
 729 ExprStmts are a bit tricky, because what they mean
 730 depends on the context.  Consider the following contexts:
 731
 732         A do expression of type (m res_ty)
 733         ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 734         * ExprStmt E any_ty:   do { ....; E; ... }
 735                 E :: m any_ty
 736           Translation: E >> ...
 737
 738         A list comprehensions of type [elt_ty]
 739         ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 740         * ExprStmt E Bool:   [ .. | .... E ]
 741                         [ .. | ..., E, ... ]
 742                         [ .. | .... | ..., E | ... ]
 743                 E :: Bool
 744           Translation: if E then fail else ...
 745
 746         A guard list, guarding a RHS of type rhs_ty
 747         ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 748         * ExprStmt E Bool:   f x | ..., E, ... = ...rhs...
 749                 E :: Bool
 750           Translation: if E then fail else ...
 751
 752 Array comprehensions are handled like list comprehensions -=chak
 753
 754 Note [RecStmt]
 755 ~~~~~~~~~~~~~~
 756 Example:
 757         HsDo [ BindStmt x ex
 758
 759              , RecStmt [a::forall a. a -> a, b]
 760                        [a::Int -> Int,       c]
 761                        [ BindStmt b (return x)
 762                        , LetStmt a = ea
 763                        , BindStmt c ec ]
 764
 765              , return (a b) ]
 766
 767 Here, the RecStmt binds a,b,c; but
 768   - Only a,b are used in the stmts *following* the RecStmt,
 769         This 'a' is *polymorphic'
 770   - Only a,c are used in the stmts *inside* the RecStmt
 771         *before* their bindings
 772         This 'a' is monomorphic
 773
 774 Nota Bene: the two a's have different types, even though they
 775 have the same Name.
 776
 777
 778 \begin{code}
 779 instance OutputableBndr id => Outputable (Stmt id) where
 780     ppr stmt = pprStmt stmt
 781
 782 pprStmt (BindStmt pat expr _ _)   = hsep [ppr pat, ptext SLIT("<-"), ppr expr]
 783 pprStmt (LetStmt binds)           = hsep [ptext SLIT("let"), pprBinds binds]
 784 pprStmt (ExprStmt expr _ _)       = ppr expr
 785 pprStmt (ParStmt stmtss)          = hsep (map (\stmts -> ptext SLIT("| ") <> ppr stmts) stmtss)
 786 pprStmt (RecStmt segment _ _ _ _) = ptext SLIT("rec") <+> braces (vcat (map ppr segment))
 787
 788 pprDo :: OutputableBndr id => HsStmtContext any -> [LStmt id] -> LHsExpr id -> SDoc
 789 pprDo DoExpr      stmts body = hang (ptext SLIT("do"))  2 (vcat (map ppr stmts) $$ ppr body)
 790 pprDo (MDoExpr _) stmts body = hang (ptext SLIT("mdo")) 3 (vcat (map ppr stmts) $$ ppr body)
 791 pprDo ListComp    stmts body = pprComp brackets    stmts body
 792 pprDo PArrComp    stmts body = pprComp pa_brackets stmts body
 793
 794 pprComp :: OutputableBndr id => (SDoc -> SDoc) -> [LStmt id] -> LHsExpr id -> SDoc
 795 pprComp brack quals body
 796   = brack $
 797         hang (ppr body <+> char '|')
 798              4 (interpp'SP quals)
 799 \end{code}
 800
 801 %************************************************************************
 802 %*                                                                      *
 803                 Template Haskell quotation brackets
 804 %*                                                                      *
 805 %************************************************************************
 806
 807 \begin{code}
 808 data HsSplice id  = HsSplice    --  $z  or $(f 4)
 809                         id              -- The id is just a unique name to
 810                         (LHsExpr id)    -- identify this splice point
 811
 812 instance OutputableBndr id => Outputable (HsSplice id) where
 813   ppr = pprSplice
 814
 815 pprSplice :: OutputableBndr id => HsSplice id -> SDoc
 816 pprSplice (HsSplice n e) = char '$' <> brackets (ppr n) <> pprParendExpr e
 817
 818
 819 data HsBracket id = ExpBr (LHsExpr id)          -- [|  expr  |]
 820                   | PatBr (LPat id)             -- [p| pat   |]
 821                   | DecBr (HsGroup id)          -- [d| decls |]
 822                   | TypBr (LHsType id)          -- [t| type  |]
 823                   | VarBr id                    -- 'x, ''T
 824
 825 instance OutputableBndr id => Outputable (HsBracket id) where
 826   ppr = pprHsBracket
 827
 828
 829 pprHsBracket (ExpBr e) = thBrackets empty (ppr e)
 830 pprHsBracket (PatBr p) = thBrackets (char 'p') (ppr p)
 831 pprHsBracket (DecBr d) = thBrackets (char 'd') (ppr d)
 832 pprHsBracket (TypBr t) = thBrackets (char 't') (ppr t)
 833 pprHsBracket (VarBr n) = char '\'' <> ppr n
 834         -- Infelicity: can't show ' vs '', because
 835         -- we can't ask n what its OccName is, because the
 836         -- pretty-printer for HsExpr doesn't ask for NamedThings
 837         -- But the pretty-printer for names will show the OccName class
 838
 839 thBrackets pp_kind pp_body = char '[' <> pp_kind <> char '|' <+>
 840                              pp_body <+> ptext SLIT("|]")
 841 \end{code}
 842
 843 %************************************************************************
 844 %*                                                                      *
 845 \subsection{Enumerations and list comprehensions}
 846 %*                                                                      *
 847 %************************************************************************
 848
 849 \begin{code}
 850 data ArithSeqInfo id
 851   = From            (LHsExpr id)
 852   | FromThen        (LHsExpr id)
 853                     (LHsExpr id)
 854   | FromTo          (LHsExpr id)
 855                     (LHsExpr id)
 856   | FromThenTo      (LHsExpr id)
 857                     (LHsExpr id)
 858                     (LHsExpr id)
 859 \end{code}
 860
 861 \begin{code}
 862 instance OutputableBndr id => Outputable (ArithSeqInfo id) where
 863     ppr (From e1)               = hcat [ppr e1, pp_dotdot]
 864     ppr (FromThen e1 e2)        = hcat [ppr e1, comma, space, ppr e2, pp_dotdot]
 865     ppr (FromTo e1 e3)  = hcat [ppr e1, pp_dotdot, ppr e3]
 866     ppr (FromThenTo e1 e2 e3)
 867       = hcat [ppr e1, comma, space, ppr e2, pp_dotdot, ppr e3]
 868
 869 pp_dotdot = ptext SLIT(" .. ")
 870 \end{code}
 871
 872
 873 %************************************************************************
 874 %*                                                                      *
 875 \subsection{HsMatchCtxt}
 876 %*                                                                      *
 877 %************************************************************************
 878
 879 \begin{code}
 880 data HsMatchContext id  -- Context of a Match
 881   = FunRhs id                   -- Function binding for f
 882   | CaseAlt                     -- Guard on a case alternative
 883   | LambdaExpr                  -- Pattern of a lambda
 884   | ProcExpr                    -- Pattern of a proc
 885   | PatBindRhs                  -- Pattern binding
 886   | RecUpd                      -- Record update [used only in DsExpr to tell matchWrapper
 887                                 --      what sort of runtime error message to generate]
 888   | StmtCtxt (HsStmtContext id) -- Pattern of a do-stmt or list comprehension
 889   deriving ()
 890
 891 data HsStmtContext id
 892   = ListComp
 893   | DoExpr
 894   | MDoExpr PostTcTable                 -- Recursive do-expression
 895                                         -- (tiresomely, it needs table
 896                                         --  of its return/bind ops)
 897   | PArrComp                            -- Parallel array comprehension
 898   | PatGuard (HsMatchContext id)        -- Pattern guard for specified thing
 899   | ParStmtCtxt (HsStmtContext id)      -- A branch of a parallel stmt
 900 \end{code}
 901
 902 \begin{code}
 903 isDoExpr :: HsStmtContext id -> Bool
 904 isDoExpr DoExpr      = True
 905 isDoExpr (MDoExpr _) = True
 906 isDoExpr other       = False
 907 \end{code}
 908
 909 \begin{code}
 910 matchSeparator (FunRhs _)   = ptext SLIT("=")
 911 matchSeparator CaseAlt      = ptext SLIT("->")
 912 matchSeparator LambdaExpr   = ptext SLIT("->")
 913 matchSeparator ProcExpr     = ptext SLIT("->")
 914 matchSeparator PatBindRhs   = ptext SLIT("=")
 915 matchSeparator (StmtCtxt _) = ptext SLIT("<-")
 916 matchSeparator RecUpd       = panic "unused"
 917 \end{code}
 918
 919 \begin{code}
 920 pprMatchContext (FunRhs fun)      = ptext SLIT("the definition of") <+> quotes (ppr fun)
 921 pprMatchContext CaseAlt           = ptext SLIT("a case alternative")
 922 pprMatchContext RecUpd            = ptext SLIT("a record-update construct")
 923 pprMatchContext PatBindRhs        = ptext SLIT("a pattern binding")
 924 pprMatchContext LambdaExpr        = ptext SLIT("a lambda abstraction")
 925 pprMatchContext ProcExpr          = ptext SLIT("an arrow abstraction")
 926 pprMatchContext (StmtCtxt ctxt)   = ptext SLIT("a pattern binding in") $$ pprStmtContext ctxt
 927
 928 pprMatchRhsContext (FunRhs fun) = ptext SLIT("a right-hand side of function") <+> quotes (ppr fun)
 929 pprMatchRhsContext CaseAlt      = ptext SLIT("the body of a case alternative")
 930 pprMatchRhsContext PatBindRhs   = ptext SLIT("the right-hand side of a pattern binding")
 931 pprMatchRhsContext LambdaExpr   = ptext SLIT("the body of a lambda")
 932 pprMatchRhsContext ProcExpr     = ptext SLIT("the body of a proc")
 933 pprMatchRhsContext RecUpd       = panic "pprMatchRhsContext"
 934
 935 pprStmtContext (ParStmtCtxt c) = sep [ptext SLIT("a parallel branch of"), pprStmtContext c]
 936 pprStmtContext (PatGuard ctxt) = ptext SLIT("a pattern guard for") $$ pprMatchContext ctxt
 937 pprStmtContext DoExpr          = ptext SLIT("a 'do' expression")
 938 pprStmtContext (MDoExpr _)     = ptext SLIT("an 'mdo' expression")
 939 pprStmtContext ListComp        = ptext SLIT("a list comprehension")
 940 pprStmtContext PArrComp        = ptext SLIT("an array comprehension")
 941
 942 -- Used for the result statement of comprehension
 943 -- e.g. the 'e' in      [ e | ... ]
 944 --      or the 'r' in   f x = r
 945 pprStmtResultContext (PatGuard ctxt) = pprMatchRhsContext ctxt
 946 pprStmtResultContext other           = ptext SLIT("the result of") <+> pprStmtContext other
 947
 948
 949 -- Used to generate the string for a *runtime* error message
 950 matchContextErrString (FunRhs fun)               = "function " ++ showSDoc (ppr fun)
 951 matchContextErrString CaseAlt                    = "case"
 952 matchContextErrString PatBindRhs                 = "pattern binding"
 953 matchContextErrString RecUpd                     = "record update"
 954 matchContextErrString LambdaExpr                 = "lambda"
 955 matchContextErrString ProcExpr                   = "proc"
 956 matchContextErrString (StmtCtxt (ParStmtCtxt c)) = matchContextErrString (StmtCtxt c)
 957 matchContextErrString (StmtCtxt (PatGuard _))    = "pattern guard"
 958 matchContextErrString (StmtCtxt DoExpr)          = "'do' expression"
 959 matchContextErrString (StmtCtxt (MDoExpr _))     = "'mdo' expression"
 960 matchContextErrString (StmtCtxt ListComp)        = "list comprehension"
 961 matchContextErrString (StmtCtxt PArrComp)        = "array comprehension"
 962 \end{code}