ghc/compiler/hsSyn/HsExpr.lhs

   1 %
   2 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1994
   3 %
   4 \section[HsExpr]{Abstract Haskell syntax: expressions}
   5
   6 \begin{code}
   7 #include "HsVersions.h"
   8
   9 module HsExpr where
  10
  11 import Ubiq{-uitous-}
  12 import HsLoop -- for paranoia checking
  13
  14 -- friends:
  15 import HsBinds          ( HsBinds )
  16 import HsLit            ( HsLit )
  17 import HsMatches        ( pprMatches, pprMatch, Match )
  18 import HsTypes          ( PolyType )
  19
  20 -- others:
  21 import Id               ( DictVar(..), GenId, Id(..) )
  22 import Name             ( isSymLexeme, pprSym )
  23 import Outputable       ( interppSP, interpp'SP, ifnotPprForUser )
  24 import PprType          ( pprGenType, pprParendGenType, GenType{-instance-} )
  25 import Pretty
  26 import PprStyle         ( PprStyle(..) )
  27 import SrcLoc           ( SrcLoc )
  28 import Usage            ( GenUsage{-instance-} )
  29 import Util             ( panic{-ToDo:rm eventually-} )
  30 \end{code}
  31
  32 %************************************************************************
  33 %*                                                                      *
  34 \subsection{Expressions proper}
  35 %*                                                                      *
  36 %************************************************************************
  37
  38 \begin{code}
  39 data HsExpr tyvar uvar id pat
  40   = HsVar       id                              -- variable
  41   | HsLit       HsLit                           -- literal
  42   | HsLitOut    HsLit                           -- TRANSLATION
  43                 (GenType tyvar uvar)            -- (with its type)
  44
  45   | HsLam       (Match  tyvar uvar id pat)      -- lambda
  46   | HsApp       (HsExpr tyvar uvar id pat)      -- application
  47                 (HsExpr tyvar uvar id pat)
  48
  49   -- Operator applications:
  50   -- NB Bracketed ops such as (+) come out as Vars.
  51
  52   -- NB We need an expr for the operator in an OpApp/Section since
  53   -- the typechecker may need to apply the operator to a few types.
  54
  55   | OpApp       (HsExpr tyvar uvar id pat)      -- left operand
  56                 (HsExpr tyvar uvar id pat)      -- operator
  57                 (HsExpr tyvar uvar id pat)      -- right operand
  58
  59   -- We preserve prefix negation and parenthesis for the precedence parser.
  60   -- They are eventually removed by the type checker.
  61
  62   | NegApp      (HsExpr tyvar uvar id pat)      -- negated expr
  63                 id                              -- the negate id
  64
  65   | HsPar       (HsExpr tyvar uvar id pat)      -- parenthesised expr
  66
  67   | SectionL    (HsExpr tyvar uvar id pat)      -- operand
  68                 (HsExpr tyvar uvar id pat)      -- operator
  69   | SectionR    (HsExpr tyvar uvar id pat)      -- operator
  70                 (HsExpr tyvar uvar id pat)      -- operand
  71
  72   | HsCase      (HsExpr tyvar uvar id pat)
  73                 [Match  tyvar uvar id pat]      -- must have at least one Match
  74                 SrcLoc
  75
  76   | HsIf        (HsExpr tyvar uvar id pat)      --  predicate
  77                 (HsExpr tyvar uvar id pat)      --  then part
  78                 (HsExpr tyvar uvar id pat)      --  else part
  79                 SrcLoc
  80
  81   | HsLet       (HsBinds tyvar uvar id pat)     -- let(rec)
  82                 (HsExpr  tyvar uvar id pat)
  83
  84   | HsDo        [Stmt tyvar uvar id pat]        -- "do":one or more stmts
  85                 SrcLoc
  86
  87   | HsDoOut     [Stmt tyvar uvar id pat]        -- "do":one or more stmts
  88                 id id                           -- Monad and MonadZero dicts
  89                 SrcLoc
  90
  91   | ListComp    (HsExpr tyvar uvar id pat)      -- list comprehension
  92                 [Qual   tyvar uvar id pat]      -- at least one Qual(ifier)
  93
  94   | ExplicitList                -- syntactic list
  95                 [HsExpr tyvar uvar id pat]
  96   | ExplicitListOut             -- TRANSLATION
  97                 (GenType tyvar uvar)    -- Gives type of components of list
  98                 [HsExpr tyvar uvar id pat]
  99
 100   | ExplicitTuple               -- tuple
 101                 [HsExpr tyvar uvar id pat]
 102                                 -- NB: Unit is ExplicitTuple []
 103                                 -- for tuples, we can get the types
 104                                 -- direct from the components
 105
 106         -- Record construction
 107   | RecordCon   (HsExpr tyvar uvar id pat)      -- Always (HsVar id) until type checker,
 108                                                 -- but the latter adds its type args too
 109                 (HsRecordBinds tyvar uvar id pat)
 110
 111         -- Record update
 112   | RecordUpd   (HsExpr tyvar uvar id pat)
 113                 (HsRecordBinds tyvar uvar id pat)
 114
 115   | RecordUpdOut (HsExpr tyvar uvar id pat)     -- TRANSLATION
 116                  [id]                           -- Dicts needed for construction
 117                  (HsRecordBinds tyvar uvar id pat)
 118
 119   | ExprWithTySig               -- signature binding
 120                 (HsExpr tyvar uvar id pat)
 121                 (PolyType id)
 122   | ArithSeqIn                  -- arithmetic sequence
 123                 (ArithSeqInfo tyvar uvar id pat)
 124   | ArithSeqOut
 125                 (HsExpr       tyvar uvar id pat) -- (typechecked, of course)
 126                 (ArithSeqInfo tyvar uvar id pat)
 127
 128   | CCall       FAST_STRING     -- call into the C world; string is
 129                 [HsExpr tyvar uvar id pat]      -- the C function; exprs are the
 130                                 -- arguments to pass.
 131                 Bool            -- True <=> might cause Haskell
 132                                 -- garbage-collection (must generate
 133                                 -- more paranoid code)
 134                 Bool            -- True <=> it's really a "casm"
 135                                 -- NOTE: this CCall is the *boxed*
 136                                 -- version; the desugarer will convert
 137                                 -- it into the unboxed "ccall#".
 138                 (GenType tyvar uvar)    -- The result type; will be *bottom*
 139                                 -- until the typechecker gets ahold of it
 140
 141   | HsSCC       FAST_STRING     -- "set cost centre" (_scc_) annotation
 142                 (HsExpr tyvar uvar id pat) -- expr whose cost is to be measured
 143 \end{code}
 144
 145 Everything from here on appears only in typechecker output.
 146
 147 \begin{code}
 148   | TyLam                       -- TRANSLATION
 149                 [tyvar]
 150                 (HsExpr tyvar uvar id pat)
 151   | TyApp                       -- TRANSLATION
 152                 (HsExpr  tyvar uvar id pat) -- generated by Spec
 153                 [GenType tyvar uvar]
 154
 155   -- DictLam and DictApp are "inverses"
 156   |  DictLam
 157                 [id]
 158                 (HsExpr tyvar uvar id pat)
 159   |  DictApp
 160                 (HsExpr tyvar uvar id pat)
 161                 [id]
 162
 163   -- ClassDictLam and Dictionary are "inverses" (see note below)
 164   |  ClassDictLam
 165                 [id]            -- superclass dicts
 166                 [id]            -- methods
 167                 (HsExpr tyvar uvar id pat)
 168   |  Dictionary
 169                 [id]            -- superclass dicts
 170                 [id]            -- methods
 171
 172   |  SingleDict                 -- a simple special case of Dictionary
 173                 id              -- local dictionary name
 174
 175   |  HsCon                      -- TRANSLATION; a constructor application
 176         Id                      -- used only in the RHS of constructor definitions
 177         [GenType tyvar uvar]
 178         [HsExpr tyvar uvar id pat]
 179
 180 type HsRecordBinds tyvar uvar id pat
 181   = [(id, HsExpr tyvar uvar id pat, Bool)]
 182         -- True <=> source code used "punning",
 183         -- i.e. {op1, op2} rather than {op1=e1, op2=e2}
 184 \end{code}
 185
 186 A @Dictionary@, unless of length 0 or 1, becomes a tuple.  A
 187 @ClassDictLam dictvars methods expr@ is, therefore:
 188 \begin{verbatim}
 189 \ x -> case x of ( dictvars-and-methods-tuple ) -> expr
 190 \end{verbatim}
 191
 192 \begin{code}
 193 instance (NamedThing id, Outputable id, Outputable pat,
 194           Eq tyvar, Outputable tyvar, Eq uvar, Outputable uvar) =>
 195                 Outputable (HsExpr tyvar uvar id pat) where
 196     ppr = pprExpr
 197 \end{code}
 198
 199 \begin{code}
 200 pprExpr sty (HsVar v)
 201   = (if (isSymLexeme v) then ppParens else id) (ppr sty v)
 202
 203 pprExpr sty (HsLit    lit)   = ppr sty lit
 204 pprExpr sty (HsLitOut lit _) = ppr sty lit
 205
 206 pprExpr sty (HsLam match)
 207   = ppCat [ppStr "\\", ppNest 2 (pprMatch sty True match)]
 208
 209 pprExpr sty expr@(HsApp e1 e2)
 210   = let (fun, args) = collect_args expr [] in
 211     ppHang (pprParendExpr sty fun) 4 (ppSep (map (pprParendExpr sty) args))
 212   where
 213     collect_args (HsApp fun arg) args = collect_args fun (arg:args)
 214     collect_args fun             args = (fun, args)
 215
 216 pprExpr sty (OpApp e1 op e2)
 217   = case op of
 218       HsVar v -> pp_infixly v
 219       _       -> pp_prefixly
 220   where
 221     pp_e1 = pprParendExpr sty e1
 222     pp_e2 = pprParendExpr sty e2
 223
 224     pp_prefixly
 225       = ppHang (pprParendExpr sty op) 4 (ppSep [pp_e1, pp_e2])
 226
 227     pp_infixly v
 228       = ppSep [pp_e1, ppCat [pprSym sty v, pp_e2]]
 229
 230 pprExpr sty (NegApp e _)
 231   = ppBeside (ppChar '-') (pprParendExpr sty e)
 232
 233 pprExpr sty (HsPar e)
 234   = ppParens (pprExpr sty e)
 235
 236 pprExpr sty (SectionL expr op)
 237   = case op of
 238       HsVar v -> pp_infixly v
 239       _       -> pp_prefixly
 240   where
 241     pp_expr = pprParendExpr sty expr
 242
 243     pp_prefixly = ppHang (ppCat [ppStr "( \\ _x ->", ppr sty op])
 244                        4 (ppCat [pp_expr, ppStr "_x )"])
 245     pp_infixly v
 246       = ppSep [ ppBeside ppLparen pp_expr,
 247                 ppBeside (pprSym sty v) ppRparen ]
 248
 249 pprExpr sty (SectionR op expr)
 250   = case op of
 251       HsVar v -> pp_infixly v
 252       _       -> pp_prefixly
 253   where
 254     pp_expr = pprParendExpr sty expr
 255
 256     pp_prefixly = ppHang (ppCat [ppStr "( \\ _x ->", ppr sty op, ppPStr SLIT("_x")])
 257                        4 (ppBeside pp_expr ppRparen)
 258     pp_infixly v
 259       = ppSep [ ppBeside ppLparen (pprSym sty v),
 260                 ppBeside pp_expr  ppRparen ]
 261
 262 pprExpr sty (HsCase expr matches _)
 263   = ppSep [ ppSep [ppPStr SLIT("case"), ppNest 4 (pprExpr sty expr), ppPStr SLIT("of")],
 264             ppNest 2 (pprMatches sty (True, ppNil) matches) ]
 265
 266 pprExpr sty (HsIf e1 e2 e3 _)
 267   = ppSep [ppCat [ppPStr SLIT("if"), ppNest 2 (pprExpr sty e1), ppPStr SLIT("then")],
 268            ppNest 4 (pprExpr sty e2),
 269            ppPStr SLIT("else"),
 270            ppNest 4 (pprExpr sty e3)]
 271
 272 -- special case: let ... in let ...
 273 pprExpr sty (HsLet binds expr@(HsLet _ _))
 274   = ppSep [ppHang (ppPStr SLIT("let")) 2 (ppCat [ppr sty binds, ppPStr SLIT("in")]),
 275            ppr sty expr]
 276
 277 pprExpr sty (HsLet binds expr)
 278   = ppSep [ppHang (ppPStr SLIT("let")) 2 (ppr sty binds),
 279            ppHang (ppPStr SLIT("in"))  2 (ppr sty expr)]
 280
 281 pprExpr sty (HsDo stmts _)
 282   = ppCat [ppPStr SLIT("do"), ppAboves (map (ppr sty) stmts)]
 283 pprExpr sty (HsDoOut stmts _ _ _)
 284   = ppCat [ppPStr SLIT("do"), ppAboves (map (ppr sty) stmts)]
 285
 286 pprExpr sty (ListComp expr quals)
 287   = ppHang (ppCat [ppLbrack, pprExpr sty expr, ppChar '|'])
 288          4 (ppSep [interpp'SP sty quals, ppRbrack])
 289
 290 pprExpr sty (ExplicitList exprs)
 291   = ppBracket (ppInterleave ppComma (map (pprExpr sty) exprs))
 292 pprExpr sty (ExplicitListOut ty exprs)
 293   = ppBesides [ ppBracket (ppInterleave ppComma (map (pprExpr sty) exprs)),
 294                 ifnotPprForUser sty (ppBeside ppSP (ppParens (pprGenType sty ty))) ]
 295
 296 pprExpr sty (ExplicitTuple exprs)
 297   = ppParens (ppInterleave ppComma (map (pprExpr sty) exprs))
 298
 299 pprExpr sty (RecordCon con  rbinds)
 300   = pp_rbinds sty (ppr sty con) rbinds
 301
 302 pprExpr sty (RecordUpd aexp rbinds)
 303   = pp_rbinds sty (pprParendExpr sty aexp) rbinds
 304 pprExpr sty (RecordUpdOut aexp _ rbinds)
 305   = pp_rbinds sty (pprParendExpr sty aexp) rbinds
 306
 307 pprExpr sty (ExprWithTySig expr sig)
 308   = ppHang (ppBesides [ppLparen, ppNest 2 (pprExpr sty expr), ppPStr SLIT(" ::")])
 309          4 (ppBeside  (ppr sty sig) ppRparen)
 310
 311 pprExpr sty (ArithSeqIn info)
 312   = ppBracket (ppr sty info)
 313 pprExpr sty (ArithSeqOut expr info)
 314   = case sty of
 315         PprForUser ->
 316           ppBracket (ppr sty info)
 317         _          ->
 318           ppBesides [ppLbrack, ppParens (ppr sty expr), ppr sty info, ppRbrack]
 319
 320 pprExpr sty (CCall fun args _ is_asm result_ty)
 321   = ppHang (if is_asm
 322             then ppBesides [ppStr "_casm_ ``", ppPStr fun, ppStr "''"]
 323             else ppBeside  (ppPStr SLIT("_ccall_ ")) (ppPStr fun))
 324          4 (ppSep (map (pprParendExpr sty) args))
 325
 326 pprExpr sty (HsSCC label expr)
 327   = ppSep [ ppBeside (ppPStr SLIT("_scc_ ")) (ppBesides [ppChar '"', ppPStr label, ppChar '"']),
 328             pprParendExpr sty expr ]
 329
 330 pprExpr sty (TyLam tyvars expr)
 331   = ppHang (ppCat [ppStr "/\\", interppSP sty tyvars, ppStr "->"])
 332          4 (pprExpr sty expr)
 333
 334 pprExpr sty (TyApp expr [ty])
 335   = ppHang (pprExpr sty expr) 4 (pprParendGenType sty ty)
 336
 337 pprExpr sty (TyApp expr tys)
 338   = ppHang (pprExpr sty expr)
 339          4 (ppBracket (interpp'SP sty tys))
 340
 341 pprExpr sty (DictLam dictvars expr)
 342   = ppHang (ppCat [ppStr "\\{-dict-}", interppSP sty dictvars, ppStr "->"])
 343          4 (pprExpr sty expr)
 344
 345 pprExpr sty (DictApp expr [dname])
 346   = ppHang (pprExpr sty expr) 4 (ppr sty dname)
 347
 348 pprExpr sty (DictApp expr dnames)
 349   = ppHang (pprExpr sty expr)
 350          4 (ppBracket (interpp'SP sty dnames))
 351
 352 pprExpr sty (ClassDictLam dicts methods expr)
 353   = ppHang (ppCat [ppStr "\\{-classdict-}",
 354                    ppBracket (interppSP sty dicts),
 355                    ppBracket (interppSP sty methods),
 356                    ppStr "->"])
 357          4 (pprExpr sty expr)
 358
 359 pprExpr sty (Dictionary dicts methods)
 360   = ppSep [ppBesides [ppLparen, ppPStr SLIT("{-dict-}")],
 361            ppBracket (interpp'SP sty dicts),
 362            ppBesides [ppBracket (interpp'SP sty methods), ppRparen]]
 363
 364 pprExpr sty (SingleDict dname)
 365   = ppCat [ppPStr SLIT("{-singleDict-}"), ppr sty dname]
 366
 367 pprExpr sty (HsCon con tys exprs)
 368   = ppCat [ppPStr SLIT("{-HsCon-}"), ppr sty con, interppSP sty tys, interppSP sty exprs]
 369 \end{code}
 370
 371 Parenthesize unless very simple:
 372 \begin{code}
 373 pprParendExpr :: (NamedThing id, Outputable id, Outputable pat,
 374                   Eq tyvar, Outputable tyvar, Eq uvar, Outputable uvar)
 375               => PprStyle -> HsExpr tyvar uvar id pat -> Pretty
 376
 377 pprParendExpr sty expr
 378   = let
 379         pp_as_was = pprExpr sty expr
 380     in
 381     case expr of
 382       HsLit l               -> ppr sty l
 383       HsLitOut l _          -> ppr sty l
 384       HsVar _               -> pp_as_was
 385       ExplicitList _        -> pp_as_was
 386       ExplicitListOut _ _   -> pp_as_was
 387       ExplicitTuple _       -> pp_as_was
 388       _                     -> ppParens pp_as_was
 389 \end{code}
 390
 391 %************************************************************************
 392 %*                                                                      *
 393 \subsection{Record binds}
 394 %*                                                                      *
 395 %************************************************************************
 396
 397 \begin{code}
 398 pp_rbinds :: (NamedThing id, Outputable id, Outputable pat,
 399                   Eq tyvar, Outputable tyvar, Eq uvar, Outputable uvar)
 400               => PprStyle -> Pretty
 401               -> HsRecordBinds tyvar uvar id pat -> Pretty
 402
 403 pp_rbinds sty thing rbinds
 404   = ppHang thing 4
 405         (ppBesides [ppChar '{', ppInterleave ppComma (map (pp_rbind sty) rbinds), ppChar '}'])
 406   where
 407     pp_rbind PprForUser (v, _, True) = ppr PprForUser v
 408     pp_rbind sty        (v, e, _)    = ppCat [ppr sty v, ppStr "=", ppr sty e]
 409 \end{code}
 410
 411 %************************************************************************
 412 %*                                                                      *
 413 \subsection{Do stmts}
 414 %*                                                                      *
 415 %************************************************************************
 416
 417 \begin{code}
 418 data Stmt tyvar uvar id pat
 419   = BindStmt    pat
 420                 (HsExpr  tyvar uvar id pat)
 421                 SrcLoc
 422   | ExprStmt    (HsExpr  tyvar uvar id pat)
 423                 SrcLoc
 424   | LetStmt     (HsBinds tyvar uvar id pat)
 425 \end{code}
 426
 427 \begin{code}
 428 instance (NamedThing id, Outputable id, Outputable pat,
 429           Eq tyvar, Outputable tyvar, Eq uvar, Outputable uvar) =>
 430                 Outputable (Stmt tyvar uvar id pat) where
 431     ppr sty (BindStmt pat expr _)
 432      = ppCat [ppr sty pat, ppStr "<-", ppr sty expr]
 433     ppr sty (LetStmt binds)
 434      = ppCat [ppPStr SLIT("let"), ppr sty binds]
 435     ppr sty (ExprStmt expr _)
 436      = ppr sty expr
 437 \end{code}
 438
 439 %************************************************************************
 440 %*                                                                      *
 441 \subsection{Enumerations and list comprehensions}
 442 %*                                                                      *
 443 %************************************************************************
 444
 445 \begin{code}
 446 data ArithSeqInfo  tyvar uvar id pat
 447   = From            (HsExpr tyvar uvar id pat)
 448   | FromThen        (HsExpr tyvar uvar id pat)
 449                     (HsExpr tyvar uvar id pat)
 450   | FromTo          (HsExpr tyvar uvar id pat)
 451                     (HsExpr tyvar uvar id pat)
 452   | FromThenTo      (HsExpr tyvar uvar id pat)
 453                     (HsExpr tyvar uvar id pat)
 454                     (HsExpr tyvar uvar id pat)
 455 \end{code}
 456
 457 \begin{code}
 458 instance (NamedThing id, Outputable id, Outputable pat,
 459           Eq tyvar, Outputable tyvar, Eq uvar, Outputable uvar) =>
 460                 Outputable (ArithSeqInfo tyvar uvar id pat) where
 461     ppr sty (From e1)           = ppBesides [ppr sty e1, pp_dotdot]
 462     ppr sty (FromThen e1 e2)    = ppBesides [ppr sty e1, pp'SP, ppr sty e2, pp_dotdot]
 463     ppr sty (FromTo e1 e3)      = ppBesides [ppr sty e1, pp_dotdot, ppr sty e3]
 464     ppr sty (FromThenTo e1 e2 e3)
 465       = ppBesides [ppr sty e1, pp'SP, ppr sty e2, pp_dotdot, ppr sty e3]
 466
 467 pp_dotdot = ppPStr SLIT(" .. ")
 468 \end{code}
 469
 470 ``Qualifiers'' in list comprehensions:
 471 \begin{code}
 472 data Qual tyvar uvar id pat
 473   = GeneratorQual   pat
 474                     (HsExpr  tyvar uvar id pat)
 475   | LetQual         (HsBinds tyvar uvar id pat)
 476   | FilterQual      (HsExpr  tyvar uvar id pat)
 477 \end{code}
 478
 479 \begin{code}
 480 instance (NamedThing id, Outputable id, Outputable pat,
 481           Eq tyvar, Outputable tyvar, Eq uvar, Outputable uvar) =>
 482                 Outputable (Qual tyvar uvar id pat) where
 483     ppr sty (GeneratorQual pat expr)
 484      = ppCat [ppr sty pat, ppStr "<-", ppr sty expr]
 485     ppr sty (LetQual binds)
 486      = ppCat [ppPStr SLIT("let"), ppr sty binds]
 487     ppr sty (FilterQual expr)
 488      = ppr sty expr
 489 \end{code}