ghc/compiler/hsSyn/HsTypes.lhs

   1 %
   2 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   3 %
   4 \section[HsTypes]{Abstract syntax: user-defined types}
   5
   6 \begin{code}
   7 module HsTypes (
   8         HsType(..), LHsType,
   9         HsTyVarBndr(..), LHsTyVarBndr,
  10         HsExplicitForAll(..),
  11         HsContext, LHsContext,
  12         HsPred(..), LHsPred,
  13
  14         LBangType, BangType, HsBang(..),
  15         getBangType, getBangStrictness,
  16
  17         mkExplicitHsForAllTy, mkImplicitHsForAllTy,
  18         hsTyVarName, hsTyVarNames, replaceTyVarName,
  19         hsLTyVarName, hsLTyVarNames, hsLTyVarLocName, hsLTyVarLocNames,
  20         splitHsInstDeclTy, splitHsFunType,
  21
  22         -- Type place holder
  23         PostTcType, placeHolderType,
  24
  25         -- Printing
  26         pprParendHsType, pprHsForAll, pprHsContext, ppr_hs_context, pprHsTyVarBndr
  27     ) where
  28
  29 #include "HsVersions.h"
  30
  31 import {-# SOURCE #-} HsExpr ( HsSplice, pprSplice )
  32
  33 import Type             ( Type )
  34 import Kind             ( {- instance Outputable Kind -}, Kind,
  35                           pprParendKind, pprKind, isLiftedTypeKind )
  36 import BasicTypes       ( IPName, Boxity, tupleParens )
  37 import SrcLoc           ( Located(..), unLoc, noSrcSpan )
  38 import StaticFlags      ( opt_PprStyle_Debug )
  39 import Outputable
  40 \end{code}
  41
  42
  43 %************************************************************************
  44 %*                                                                      *
  45 \subsection{Annotating the syntax}
  46 %*                                                                      *
  47 %************************************************************************
  48
  49 \begin{code}
  50 type PostTcType = Type          -- Used for slots in the abstract syntax
  51                                 -- where we want to keep slot for a type
  52                                 -- to be added by the type checker...but
  53                                 -- before typechecking it's just bogus
  54
  55 placeHolderType :: PostTcType   -- Used before typechecking
  56 placeHolderType  = panic "Evaluated the place holder for a PostTcType"
  57 \end{code}
  58
  59 %************************************************************************
  60 %*                                                                      *
  61 \subsection{Bang annotations}
  62 %*                                                                      *
  63 %************************************************************************
  64
  65 \begin{code}
  66 type LBangType name = Located (BangType name)
  67 type BangType name  = HsType name       -- Bangs are in the HsType data type
  68
  69 data HsBang = HsNoBang  -- Only used as a return value for getBangStrictness,
  70                         -- never appears on a HsBangTy
  71             | HsStrict  -- !
  72             | HsUnbox   -- {-# UNPACK #-} ! (GHC extension, meaning "unbox")
  73
  74 instance Outputable HsBang where
  75     ppr (HsNoBang) = empty
  76     ppr (HsStrict) = char '!'
  77     ppr (HsUnbox)  = ptext SLIT("!!")
  78
  79 getBangType :: LHsType a -> LHsType a
  80 getBangType (L _ (HsBangTy _ ty)) = ty
  81 getBangType ty                    = ty
  82
  83 getBangStrictness :: LHsType a -> HsBang
  84 getBangStrictness (L _ (HsBangTy s _)) = s
  85 getBangStrictness _                    = HsNoBang
  86 \end{code}
  87
  88
  89 %************************************************************************
  90 %*                                                                      *
  91 \subsection{Data types}
  92 %*                                                                      *
  93 %************************************************************************
  94
  95 This is the syntax for types as seen in type signatures.
  96
  97 \begin{code}
  98 type LHsContext name = Located (HsContext name)
  99
 100 type HsContext name = [LHsPred name]
 101
 102 type LHsPred name = Located (HsPred name)
 103
 104 data HsPred name = HsClassP name [LHsType name]
 105                  | HsIParam (IPName name) (LHsType name)
 106
 107 type LHsType name = Located (HsType name)
 108
 109 data HsType name
 110   = HsForAllTy  HsExplicitForAll        -- Renamer leaves this flag unchanged, to record the way
 111                                         -- the user wrote it originally, so that the printer can
 112                                         -- print it as the user wrote it
 113                 [LHsTyVarBndr name]     -- With ImplicitForAll, this is the empty list
 114                                         -- until the renamer fills in the variables
 115                 (LHsContext name)
 116                 (LHsType name)
 117
 118   | HsTyVar             name            -- Type variable or type constructor
 119
 120   | HsBangTy    HsBang (LHsType name)   -- Bang-style type annotations
 121
 122   | HsAppTy             (LHsType name)
 123                         (LHsType name)
 124
 125   | HsFunTy             (LHsType name)   -- function type
 126                         (LHsType name)
 127
 128   | HsListTy            (LHsType name)  -- Element type
 129
 130   | HsPArrTy            (LHsType name)  -- Elem. type of parallel array: [:t:]
 131
 132   | HsTupleTy           Boxity
 133                         [LHsType name]  -- Element types (length gives arity)
 134
 135   | HsOpTy              (LHsType name) (Located name) (LHsType name)
 136
 137   | HsParTy             (LHsType name)
 138         -- Parenthesis preserved for the precedence re-arrangement in RnTypes
 139         -- It's important that a * (b + c) doesn't get rearranged to (a*b) + c!
 140         --
 141         -- However, NB that toHsType doesn't add HsParTys (in an effort to keep
 142         -- interface files smaller), so when printing a HsType we may need to
 143         -- add parens.
 144
 145   | HsNumTy             Integer         -- Generics only
 146
 147   | HsPredTy            (HsPred name)   -- Only used in the type of an instance
 148                                         -- declaration, eg.  Eq [a] -> Eq a
 149                                         --                             ^^^^
 150                                         --                            HsPredTy
 151                                         -- Note no need for location info on the
 152                                         -- enclosed HsPred; the one on the type will do
 153
 154   | HsKindSig           (LHsType name)  -- (ty :: kind)
 155                         Kind            -- A type with a kind signature
 156
 157   | HsSpliceTy          (HsSplice name)
 158
 159 data HsExplicitForAll = Explicit | Implicit
 160
 161 -----------------------
 162 -- Combine adjacent for-alls.
 163 -- The following awkward situation can happen otherwise:
 164 --      f :: forall a. ((Num a) => Int)
 165 -- might generate HsForAll (Just [a]) [] (HsForAll Nothing [Num a] t)
 166 -- Then a isn't discovered as ambiguous, and we abstract the AbsBinds wrt []
 167 -- but the export list abstracts f wrt [a].  Disaster.
 168 --
 169 -- A valid type must have one for-all at the top of the type, or of the fn arg types
 170
 171 mkImplicitHsForAllTy     ctxt ty = mkHsForAllTy Implicit [] ctxt ty
 172 mkExplicitHsForAllTy tvs ctxt ty = mkHsForAllTy Explicit tvs ctxt ty
 173
 174 mkHsForAllTy :: HsExplicitForAll -> [LHsTyVarBndr name] -> LHsContext name -> LHsType name -> HsType name
 175 -- Smart constructor for HsForAllTy
 176 mkHsForAllTy exp tvs (L _ []) ty = mk_forall_ty exp tvs ty
 177 mkHsForAllTy exp tvs ctxt ty = HsForAllTy exp tvs ctxt ty
 178
 179 -- mk_forall_ty makes a pure for-all type (no context)
 180 mk_forall_ty Explicit [] ty                           = unLoc ty        -- Explicit for-all with no tyvars
 181 mk_forall_ty exp  tvs  (L _ (HsParTy ty))                     = mk_forall_ty exp tvs ty
 182 mk_forall_ty exp1 tvs1 (L _ (HsForAllTy exp2 tvs2 ctxt ty)) = mkHsForAllTy (exp1 `plus` exp2) (tvs1 ++ tvs2) ctxt ty
 183 mk_forall_ty exp  tvs  ty                             = HsForAllTy exp tvs (L noSrcSpan []) ty
 184
 185 Implicit `plus` Implicit = Implicit
 186 exp1     `plus` exp2     = Explicit
 187
 188 type LHsTyVarBndr name = Located (HsTyVarBndr name)
 189
 190 data HsTyVarBndr name
 191   = UserTyVar name
 192   | KindedTyVar name Kind
 193         --  *** NOTA BENE *** A "monotype" in a pragma can have
 194         -- for-alls in it, (mostly to do with dictionaries).  These
 195         -- must be explicitly Kinded.
 196
 197 hsTyVarName :: HsTyVarBndr name -> name
 198 hsTyVarName (UserTyVar n)     = n
 199 hsTyVarName (KindedTyVar n _) = n
 200
 201 hsLTyVarName :: LHsTyVarBndr name -> name
 202 hsLTyVarName = hsTyVarName . unLoc
 203
 204 hsTyVarNames :: [HsTyVarBndr name] -> [name]
 205 hsTyVarNames tvs = map hsTyVarName tvs
 206
 207 hsLTyVarNames :: [LHsTyVarBndr name] -> [name]
 208 hsLTyVarNames = map hsLTyVarName
 209
 210 hsLTyVarLocName :: LHsTyVarBndr name -> Located name
 211 hsLTyVarLocName = fmap hsTyVarName
 212
 213 hsLTyVarLocNames :: [LHsTyVarBndr name] -> [Located name]
 214 hsLTyVarLocNames = map hsLTyVarLocName
 215
 216 replaceTyVarName :: HsTyVarBndr name1 -> name2 -> HsTyVarBndr name2
 217 replaceTyVarName (UserTyVar n)     n' = UserTyVar n'
 218 replaceTyVarName (KindedTyVar n k) n' = KindedTyVar n' k
 219 \end{code}
 220
 221
 222 \begin{code}
 223 splitHsInstDeclTy
 224     :: OutputableBndr name
 225     => HsType name
 226     -> ([LHsTyVarBndr name], HsContext name, name, [LHsType name])
 227         -- Split up an instance decl type, returning the pieces
 228
 229 splitHsInstDeclTy inst_ty
 230   = case inst_ty of
 231         HsParTy (L _ ty)              -> splitHsInstDeclTy ty
 232         HsForAllTy _ tvs cxt (L _ ty) -> split_tau tvs (unLoc cxt) ty
 233         other                         -> split_tau []  []          other
 234     -- The type vars should have been computed by now, even if they were implicit
 235   where
 236     split_tau tvs cxt (HsPredTy (HsClassP cls tys)) = (tvs, cxt, cls, tys)
 237     split_tau tvs cxt (HsParTy (L _ ty))            = split_tau tvs cxt ty
 238
 239 -- Splits HsType into the (init, last) parts
 240 -- Breaks up any parens in the result type:
 241 --      splitHsFunType (a -> (b -> c)) = ([a,b], c)
 242 splitHsFunType :: LHsType name -> ([LHsType name], LHsType name)
 243 splitHsFunType (L l (HsFunTy x y)) = (x:args, res)
 244   where
 245   (args, res) = splitHsFunType y
 246 splitHsFunType (L _ (HsParTy ty))  = splitHsFunType ty
 247 splitHsFunType other               = ([], other)
 248 \end{code}
 249
 250
 251 %************************************************************************
 252 %*                                                                      *
 253 \subsection{Pretty printing}
 254 %*                                                                      *
 255 %************************************************************************
 256
 257 NB: these types get printed into interface files, so
 258     don't change the printing format lightly
 259
 260 \begin{code}
 261 instance (OutputableBndr name) => Outputable (HsType name) where
 262     ppr ty = pprHsType ty
 263
 264 instance (Outputable name) => Outputable (HsTyVarBndr name) where
 265     ppr (UserTyVar name)        = ppr name
 266     ppr (KindedTyVar name kind) = pprHsTyVarBndr name kind
 267
 268 instance OutputableBndr name => Outputable (HsPred name) where
 269     ppr (HsClassP clas tys) = ppr clas <+> hsep (map (pprParendHsType.unLoc) tys)
 270     ppr (HsIParam n ty)    = hsep [ppr n, dcolon, ppr ty]
 271
 272 pprHsTyVarBndr :: Outputable name => name -> Kind -> SDoc
 273 pprHsTyVarBndr name kind | isLiftedTypeKind kind = ppr name
 274                          | otherwise             = hsep [ppr name, dcolon, pprParendKind kind]
 275
 276 pprHsForAll exp tvs cxt
 277   | show_forall = forall_part <+> pprHsContext (unLoc cxt)
 278   | otherwise   = pprHsContext (unLoc cxt)
 279   where
 280     show_forall =  opt_PprStyle_Debug
 281                 || (not (null tvs) && is_explicit)
 282     is_explicit = case exp of {Explicit -> True; Implicit -> False}
 283     forall_part = ptext SLIT("forall") <+> interppSP tvs <> dot
 284
 285 pprHsContext :: (OutputableBndr name) => HsContext name -> SDoc
 286 pprHsContext []  = empty
 287 pprHsContext cxt = ppr_hs_context cxt <+> ptext SLIT("=>")
 288
 289 ppr_hs_context []  = empty
 290 ppr_hs_context cxt = parens (interpp'SP cxt)
 291 \end{code}
 292
 293 \begin{code}
 294 pREC_TOP = (0 :: Int)  -- type   in ParseIface.y
 295 pREC_FUN = (1 :: Int)  -- btype  in ParseIface.y
 296                         -- Used for LH arg of (->)
 297 pREC_OP  = (2 :: Int)   -- Used for arg of any infix operator
 298                         -- (we don't keep their fixities around)
 299 pREC_CON = (3 :: Int)   -- Used for arg of type applicn:
 300                         -- always parenthesise unless atomic
 301
 302 maybeParen :: Int       -- Precedence of context
 303            -> Int       -- Precedence of top-level operator
 304            -> SDoc -> SDoc      -- Wrap in parens if (ctxt >= op)
 305 maybeParen ctxt_prec op_prec p | ctxt_prec >= op_prec = parens p
 306                                | otherwise            = p
 307
 308 -- printing works more-or-less as for Types
 309
 310 pprHsType, pprParendHsType :: (OutputableBndr name) => HsType name -> SDoc
 311
 312 pprHsType ty       = getPprStyle $ \sty -> ppr_mono_ty pREC_TOP (prepare sty ty)
 313 pprParendHsType ty = ppr_mono_ty pREC_CON ty
 314
 315 -- Before printing a type
 316 -- (a) Remove outermost HsParTy parens
 317 -- (b) Drop top-level for-all type variables in user style
 318 --     since they are implicit in Haskell
 319 prepare sty (HsParTy ty)          = prepare sty (unLoc ty)
 320 prepare sty ty                    = ty
 321
 322 ppr_mono_lty ctxt_prec ty = ppr_mono_ty ctxt_prec (unLoc ty)
 323
 324 ppr_mono_ty ctxt_prec (HsForAllTy exp tvs ctxt ty)
 325   = maybeParen ctxt_prec pREC_FUN $
 326     sep [pprHsForAll exp tvs ctxt, ppr_mono_lty pREC_TOP ty]
 327
 328 -- gaw 2004
 329 ppr_mono_ty ctxt_prec (HsBangTy b ty)     = ppr b <> ppr ty
 330 ppr_mono_ty ctxt_prec (HsTyVar name)      = ppr name
 331 ppr_mono_ty ctxt_prec (HsFunTy ty1 ty2)   = ppr_fun_ty ctxt_prec ty1 ty2
 332 ppr_mono_ty ctxt_prec (HsTupleTy con tys) = tupleParens con (interpp'SP tys)
 333 ppr_mono_ty ctxt_prec (HsKindSig ty kind) = parens (ppr_mono_lty pREC_TOP ty <+> dcolon <+> pprKind kind)
 334 ppr_mono_ty ctxt_prec (HsListTy ty)       = brackets (ppr_mono_lty pREC_TOP ty)
 335 ppr_mono_ty ctxt_prec (HsPArrTy ty)       = pabrackets (ppr_mono_lty pREC_TOP ty)
 336 ppr_mono_ty ctxt_prec (HsPredTy pred)     = braces (ppr pred)
 337 ppr_mono_ty ctxt_prec (HsNumTy n)         = integer n  -- generics only
 338 ppr_mono_ty ctxt_prec (HsSpliceTy s)      = pprSplice s
 339
 340 ppr_mono_ty ctxt_prec (HsAppTy fun_ty arg_ty)
 341   = maybeParen ctxt_prec pREC_CON $
 342     hsep [ppr_mono_lty pREC_FUN fun_ty, ppr_mono_lty pREC_CON arg_ty]
 343
 344 ppr_mono_ty ctxt_prec (HsOpTy ty1 op ty2)
 345   = maybeParen ctxt_prec pREC_OP $
 346     ppr_mono_lty pREC_OP ty1 <+> ppr op <+> ppr_mono_lty pREC_OP ty2
 347
 348 ppr_mono_ty ctxt_prec (HsParTy ty)
 349   = parens (ppr_mono_lty pREC_TOP ty)
 350   -- Put the parens in where the user did
 351   -- But we still use the precedence stuff to add parens because
 352   --    toHsType doesn't put in any HsParTys, so we may still need them
 353
 354 --------------------------
 355 ppr_fun_ty ctxt_prec ty1 ty2
 356   = let p1 = ppr_mono_lty pREC_FUN ty1
 357         p2 = ppr_mono_lty pREC_TOP ty2
 358     in
 359     maybeParen ctxt_prec pREC_FUN $
 360     sep [p1, ptext SLIT("->") <+> p2]
 361
 362 --------------------------
 363 pabrackets p = ptext SLIT("[:") <> p <> ptext SLIT(":]")
 364 \end{code}
 365
 366