ghc/compiler/hsSyn/HsTypes.lhs

   1 ]%
   2 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   3 %
   4 \section[HsTypes]{Abstract syntax: user-defined types}
   5
   6 \begin{code}
   7 module HsTypes (
   8         HsType(..), LHsType,
   9         HsTyVarBndr(..), LHsTyVarBndr,
  10         HsExplicitForAll(..),
  11         HsContext, LHsContext,
  12         HsPred(..), LHsPred,
  13
  14         mkExplicitHsForAllTy, mkImplicitHsForAllTy,
  15         hsTyVarName, hsTyVarNames, replaceTyVarName,
  16         hsLTyVarName, hsLTyVarNames, hsLTyVarLocName, hsLTyVarLocNames,
  17         splitHsInstDeclTy,
  18
  19         -- Type place holder
  20         PostTcType, placeHolderType,
  21
  22         -- Name place holder
  23         SyntaxName, placeHolderName,
  24
  25         -- Printing
  26         pprParendHsType, pprHsForAll, pprHsContext, ppr_hs_context, pprHsTyVarBndr
  27     ) where
  28
  29 #include "HsVersions.h"
  30
  31 import {-# SOURCE #-} HsExpr ( HsSplice, pprSplice )
  32
  33 import Type             ( Type )
  34 import Kind             ( {- instance Outputable Kind -}, Kind,
  35                           pprParendKind, pprKind, isLiftedTypeKind )
  36 import Name             ( Name, mkInternalName )
  37 import OccName          ( mkVarOcc )
  38 import BasicTypes       ( IPName, Boxity, tupleParens )
  39 import PrelNames        ( unboundKey )
  40 import SrcLoc           ( noSrcLoc, Located(..), unLoc, noSrcSpan )
  41 import CmdLineOpts      ( opt_PprStyle_Debug )
  42 import Outputable
  43 \end{code}
  44
  45
  46 %************************************************************************
  47 %*                                                                      *
  48 \subsection{Annotating the syntax}
  49 %*                                                                      *
  50 %************************************************************************
  51
  52 \begin{code}
  53 type PostTcType = Type          -- Used for slots in the abstract syntax
  54                                 -- where we want to keep slot for a type
  55                                 -- to be added by the type checker...but
  56                                 -- before typechecking it's just bogus
  57
  58 placeHolderType :: PostTcType   -- Used before typechecking
  59 placeHolderType  = panic "Evaluated the place holder for a PostTcType"
  60
  61
  62 type SyntaxName = Name          -- These names are filled in by the renamer
  63                                 -- Before then they are a placeHolderName (so that
  64                                 --      we can still print the HsSyn)
  65                                 -- They correspond to "rebindable syntax";
  66                                 -- See RnEnv.lookupSyntaxName
  67
  68 placeHolderName :: SyntaxName
  69 placeHolderName = mkInternalName unboundKey
  70                         (mkVarOcc FSLIT("syntaxPlaceHolder"))
  71                         noSrcLoc
  72 \end{code}
  73
  74
  75 %************************************************************************
  76 %*                                                                      *
  77 \subsection{Data types}
  78 %*                                                                      *
  79 %************************************************************************
  80
  81 This is the syntax for types as seen in type signatures.
  82
  83 \begin{code}
  84 type LHsContext name = Located (HsContext name)
  85
  86 type HsContext name = [LHsPred name]
  87
  88 type LHsPred name = Located (HsPred name)
  89
  90 data HsPred name = HsClassP name [LHsType name]
  91                  | HsIParam (IPName name) (LHsType name)
  92
  93 type LHsType name = Located (HsType name)
  94
  95 data HsType name
  96   = HsForAllTy  HsExplicitForAll        -- Renamer leaves this flag unchanged, to record the way
  97                                         -- the user wrote it originally, so that the printer can
  98                                         -- print it as the user wrote it
  99                 [LHsTyVarBndr name]     -- With ImplicitForAll, this is the empty list
 100                                         -- until the renamer fills in the variables
 101                 (LHsContext name)
 102                 (LHsType name)
 103
 104   | HsTyVar             name            -- Type variable or type constructor
 105
 106   | HsAppTy             (LHsType name)
 107                         (LHsType name)
 108
 109   | HsFunTy             (LHsType name)   -- function type
 110                         (LHsType name)
 111
 112   | HsListTy            (LHsType name)  -- Element type
 113
 114   | HsPArrTy            (LHsType name)  -- Elem. type of parallel array: [:t:]
 115
 116   | HsTupleTy           Boxity
 117                         [LHsType name]  -- Element types (length gives arity)
 118
 119   | HsOpTy              (LHsType name) (Located name) (LHsType name)
 120
 121   | HsParTy             (LHsType name)
 122         -- Parenthesis preserved for the precedence re-arrangement in RnTypes
 123         -- It's important that a * (b + c) doesn't get rearranged to (a*b) + c!
 124         --
 125         -- However, NB that toHsType doesn't add HsParTys (in an effort to keep
 126         -- interface files smaller), so when printing a HsType we may need to
 127         -- add parens.
 128
 129   | HsNumTy             Integer         -- Generics only
 130
 131   | HsPredTy            (LHsPred name)  -- Only used in the type of an instance
 132                                         -- declaration, eg.  Eq [a] -> Eq a
 133                                         --                             ^^^^
 134                                         --                            HsPredTy
 135
 136   | HsKindSig           (LHsType name)  -- (ty :: kind)
 137                         Kind            -- A type with a kind signature
 138
 139   | HsSpliceTy          (HsSplice name)
 140
 141 data HsExplicitForAll = Explicit | Implicit
 142
 143 -----------------------
 144 -- Combine adjacent for-alls.
 145 -- The following awkward situation can happen otherwise:
 146 --      f :: forall a. ((Num a) => Int)
 147 -- might generate HsForAll (Just [a]) [] (HsForAll Nothing [Num a] t)
 148 -- Then a isn't discovered as ambiguous, and we abstract the AbsBinds wrt []
 149 -- but the export list abstracts f wrt [a].  Disaster.
 150 --
 151 -- A valid type must have one for-all at the top of the type, or of the fn arg types
 152
 153 mkImplicitHsForAllTy     ctxt ty = mkHsForAllTy Implicit [] ctxt ty
 154 mkExplicitHsForAllTy tvs ctxt ty = mkHsForAllTy Explicit tvs ctxt ty
 155
 156 mkHsForAllTy :: HsExplicitForAll -> [LHsTyVarBndr name] -> LHsContext name -> LHsType name -> HsType name
 157 -- Smart constructor for HsForAllTy
 158 mkHsForAllTy exp tvs (L _ []) ty = mk_forall_ty exp tvs ty
 159 mkHsForAllTy exp tvs ctxt ty = HsForAllTy exp tvs ctxt ty
 160
 161 -- mk_forall_ty makes a pure for-all type (no context)
 162 mk_forall_ty Explicit [] ty                           = unLoc ty        -- Explicit for-all with no tyvars
 163 mk_forall_ty exp  tvs  (L _ (HsParTy ty))                     = mk_forall_ty exp tvs ty
 164 mk_forall_ty exp1 tvs1 (L _ (HsForAllTy exp2 tvs2 ctxt ty)) = mkHsForAllTy (exp1 `plus` exp2) (tvs1 ++ tvs2) ctxt ty
 165 mk_forall_ty exp  tvs  ty                             = HsForAllTy exp tvs (L noSrcSpan []) ty
 166
 167 Implicit `plus` Implicit = Implicit
 168 exp1     `plus` exp2     = Explicit
 169
 170 type LHsTyVarBndr name = Located (HsTyVarBndr name)
 171
 172 data HsTyVarBndr name
 173   = UserTyVar name
 174   | KindedTyVar name Kind
 175         -- *** NOTA BENE *** A "monotype" in a pragma can have
 176         -- for-alls in it, (mostly to do with dictionaries).  These
 177         -- must be explicitly Kinded.
 178
 179 hsTyVarName :: HsTyVarBndr name -> name
 180 hsTyVarName (UserTyVar n)     = n
 181 hsTyVarName (KindedTyVar n _) = n
 182
 183 hsLTyVarName :: LHsTyVarBndr name -> name
 184 hsLTyVarName = hsTyVarName . unLoc
 185
 186 hsTyVarNames :: [HsTyVarBndr name] -> [name]
 187 hsTyVarNames tvs = map hsTyVarName tvs
 188
 189 hsLTyVarNames :: [LHsTyVarBndr name] -> [name]
 190 hsLTyVarNames = map hsLTyVarName
 191
 192 hsLTyVarLocName :: LHsTyVarBndr name -> Located name
 193 hsLTyVarLocName = fmap hsTyVarName
 194
 195 hsLTyVarLocNames :: [LHsTyVarBndr name] -> [Located name]
 196 hsLTyVarLocNames = map hsLTyVarLocName
 197
 198 replaceTyVarName :: HsTyVarBndr name1 -> name2 -> HsTyVarBndr name2
 199 replaceTyVarName (UserTyVar n)     n' = UserTyVar n'
 200 replaceTyVarName (KindedTyVar n k) n' = KindedTyVar n' k
 201 \end{code}
 202
 203
 204 \begin{code}
 205 splitHsInstDeclTy
 206     :: OutputableBndr name
 207     => HsType name
 208     -> ([LHsTyVarBndr name], HsContext name, name, [LHsType name])
 209         -- Split up an instance decl type, returning the pieces
 210
 211 -- In interface files, the instance declaration head is created
 212 -- by HsTypes.toHsType, which does not guarantee to produce a
 213 -- HsForAllTy.  For example, if we had the weird decl
 214 --      instance Foo T => Foo [T]
 215 -- then we'd get the instance type
 216 --      Foo T -> Foo [T]
 217 -- So when colleting the instance context, to be on the safe side
 218 -- we gather predicate arguments
 219 --
 220 -- For source code, the parser ensures the type will have the right shape.
 221 -- (e.g. see ParseUtil.checkInstType)
 222
 223 splitHsInstDeclTy inst_ty
 224   = case inst_ty of
 225         HsForAllTy _ tvs cxt1 tau       -- The type vars should have been
 226                                         -- computed by now, even if they were implicit
 227               -> (tvs, unLoc cxt1 ++ cxt2, cls, tys)
 228               where
 229                  (cxt2, cls, tys) = split_tau (unLoc tau)
 230
 231         other -> ([],  cxt2,  cls, tys)
 232               where
 233                  (cxt2, cls, tys) = split_tau inst_ty
 234
 235   where
 236     split_tau (HsFunTy (L _ (HsPredTy p)) ty) = (p:ps, cls, tys)
 237                                         where
 238                                           (ps, cls, tys) = split_tau (unLoc ty)
 239     split_tau (HsPredTy (L _ (HsClassP cls tys))) = ([], cls, tys)
 240     split_tau other = pprPanic "splitHsInstDeclTy" (ppr inst_ty)
 241 \end{code}
 242
 243
 244 %************************************************************************
 245 %*                                                                      *
 246 \subsection{Pretty printing}
 247 %*                                                                      *
 248 %************************************************************************
 249
 250 NB: these types get printed into interface files, so
 251     don't change the printing format lightly
 252
 253 \begin{code}
 254 instance (OutputableBndr name) => Outputable (HsType name) where
 255     ppr ty = pprHsType ty
 256
 257 instance (Outputable name) => Outputable (HsTyVarBndr name) where
 258     ppr (UserTyVar name)        = ppr name
 259     ppr (KindedTyVar name kind) = pprHsTyVarBndr name kind
 260
 261 instance OutputableBndr name => Outputable (HsPred name) where
 262     ppr (HsClassP clas tys) = ppr clas <+> hsep (map (pprParendHsType.unLoc) tys)
 263     ppr (HsIParam n ty)    = hsep [ppr n, dcolon, ppr ty]
 264
 265 pprHsTyVarBndr :: Outputable name => name -> Kind -> SDoc
 266 pprHsTyVarBndr name kind | isLiftedTypeKind kind = ppr name
 267                          | otherwise             = hsep [ppr name, dcolon, pprParendKind kind]
 268
 269 pprHsForAll exp tvs cxt
 270   | show_forall = forall_part <+> pprHsContext (unLoc cxt)
 271   | otherwise   = pprHsContext (unLoc cxt)
 272   where
 273     show_forall =  opt_PprStyle_Debug
 274                 || (not (null tvs) && is_explicit)
 275     is_explicit = case exp of {Explicit -> True; Implicit -> False}
 276     forall_part = ptext SLIT("forall") <+> interppSP tvs <> dot
 277
 278 pprHsContext :: (OutputableBndr name) => HsContext name -> SDoc
 279 pprHsContext []  = empty
 280 pprHsContext cxt = ppr_hs_context cxt <+> ptext SLIT("=>")
 281
 282 ppr_hs_context []  = empty
 283 ppr_hs_context cxt = parens (interpp'SP cxt)
 284 \end{code}
 285
 286 \begin{code}
 287 pREC_TOP = (0 :: Int)  -- type   in ParseIface.y
 288 pREC_FUN = (1 :: Int)  -- btype  in ParseIface.y
 289                         -- Used for LH arg of (->)
 290 pREC_OP  = (2 :: Int)   -- Used for arg of any infix operator
 291                         -- (we don't keep their fixities around)
 292 pREC_CON = (3 :: Int)   -- Used for arg of type applicn:
 293                         -- always parenthesise unless atomic
 294
 295 maybeParen :: Int       -- Precedence of context
 296            -> Int       -- Precedence of top-level operator
 297            -> SDoc -> SDoc      -- Wrap in parens if (ctxt >= op)
 298 maybeParen ctxt_prec op_prec p | ctxt_prec >= op_prec = parens p
 299                                | otherwise            = p
 300
 301 -- printing works more-or-less as for Types
 302
 303 pprHsType, pprParendHsType :: (OutputableBndr name) => HsType name -> SDoc
 304
 305 pprHsType ty       = getPprStyle $ \sty -> ppr_mono_ty pREC_TOP (prepare sty ty)
 306 pprParendHsType ty = ppr_mono_ty pREC_CON ty
 307
 308 -- Before printing a type
 309 -- (a) Remove outermost HsParTy parens
 310 -- (b) Drop top-level for-all type variables in user style
 311 --     since they are implicit in Haskell
 312 prepare sty (HsParTy ty)          = prepare sty (unLoc ty)
 313 prepare sty ty                    = ty
 314
 315 ppr_mono_lty ctxt_prec ty = ppr_mono_ty ctxt_prec (unLoc ty)
 316
 317 ppr_mono_ty ctxt_prec (HsForAllTy exp tvs ctxt ty)
 318   = maybeParen ctxt_prec pREC_FUN $
 319     sep [pprHsForAll exp tvs ctxt, ppr_mono_lty pREC_TOP ty]
 320
 321 ppr_mono_ty ctxt_prec (HsTyVar name)      = ppr name
 322 ppr_mono_ty ctxt_prec (HsFunTy ty1 ty2)   = ppr_fun_ty ctxt_prec ty1 ty2
 323 ppr_mono_ty ctxt_prec (HsTupleTy con tys) = tupleParens con (interpp'SP tys)
 324 ppr_mono_ty ctxt_prec (HsKindSig ty kind) = parens (ppr_mono_lty pREC_TOP ty <+> dcolon <+> pprKind kind)
 325 ppr_mono_ty ctxt_prec (HsListTy ty)       = brackets (ppr_mono_lty pREC_TOP ty)
 326 ppr_mono_ty ctxt_prec (HsPArrTy ty)       = pabrackets (ppr_mono_lty pREC_TOP ty)
 327 ppr_mono_ty ctxt_prec (HsPredTy pred)     = braces (ppr pred)
 328 ppr_mono_ty ctxt_prec (HsNumTy n)         = integer n  -- generics only
 329 ppr_mono_ty ctxt_prec (HsSpliceTy s)      = pprSplice s
 330
 331 ppr_mono_ty ctxt_prec (HsAppTy fun_ty arg_ty)
 332   = maybeParen ctxt_prec pREC_CON $
 333     hsep [ppr_mono_lty pREC_FUN fun_ty, ppr_mono_lty pREC_CON arg_ty]
 334
 335 ppr_mono_ty ctxt_prec (HsOpTy ty1 op ty2)
 336   = maybeParen ctxt_prec pREC_OP $
 337     ppr_mono_lty pREC_OP ty1 <+> ppr op <+> ppr_mono_lty pREC_OP ty2
 338
 339 ppr_mono_ty ctxt_prec (HsParTy ty)
 340   = parens (ppr_mono_lty pREC_TOP ty)
 341   -- Put the parens in where the user did
 342   -- But we still use the precedence stuff to add parens because
 343   --    toHsType doesn't put in any HsParTys, so we may still need them
 344
 345 --------------------------
 346 ppr_fun_ty ctxt_prec ty1 ty2
 347   = let p1 = ppr_mono_lty pREC_FUN ty1
 348         p2 = ppr_mono_lty pREC_TOP ty2
 349     in
 350     maybeParen ctxt_prec pREC_FUN $
 351     sep [p1, ptext SLIT("->") <+> p2]
 352
 353 --------------------------
 354 pabrackets p = ptext SLIT("[:") <> p <> ptext SLIT(":]")
 355 \end{code}
 356
 357