ghc/compiler/iface/MkIface.lhs

   1 %
   2 % (c) The GRASP/AQUA Project, Glasgow University, 1993-1998
   3 %
   4
   5 \begin{code}
   6 module MkIface (
   7         showIface,      -- Print the iface in Foo.hi
   8
   9         mkUsageInfo,    -- Construct the usage info for a module
  10
  11         mkIface,        -- Build a ModIface from a ModGuts,
  12                         -- including computing version information
  13
  14         checkOldIface   -- See if recompilation is required, by
  15                         -- comparing version information
  16  ) where
  17 \end{code}
  18
  19         -----------------------------------------------
  20                 MkIface.lhs deals with versioning
  21         -----------------------------------------------
  22
  23 Here's the version-related info in an interface file
  24
  25   module Foo 8          -- module-version
  26              3          -- export-list-version
  27              2          -- rule-version
  28     Usages:     -- Version info for what this compilation of Foo imported
  29         Baz 3           -- Module version
  30             [4]         -- The export-list version if Foo depended on it
  31             (g,2)       -- Function and its version
  32             (T,1)       -- Type and its version
  33
  34     <version> f :: Int -> Int {- Unfolding: \x -> Wib.t[2] x -}
  35                 -- The [2] says that f's unfolding
  36                 -- mentions verison 2 of Wib.t
  37
  38         -----------------------------------------------
  39                         Basic idea
  40         -----------------------------------------------
  41
  42 Basic idea:
  43   * In the mi_usages information in an interface, we record the
  44     version number of each free variable of the module
  45
  46   * In mkIface, we compute the version number of each exported thing A.f
  47     by comparing its A.f's info with its new info, and bumping its
  48     version number if it differs.  If A.f mentions B.g, and B.g's version
  49     number has changed, then we count A.f as having changed too.
  50
  51   * In checkOldIface we compare the mi_usages for the module with
  52     the actual version info for all each thing recorded in mi_usages
  53
  54
  55 Fixities
  56 ~~~~~~~~
  57 We count A.f as changing if its fixity changes
  58
  59 Rules
  60 ~~~~~
  61 If a rule changes, we want to recompile any module that might be
  62 affected by that rule.  For non-orphan rules, this is relatively easy.
  63 If module M defines f, and a rule for f, just arrange that the version
  64 number for M.f changes if any of the rules for M.f change.  Any module
  65 that does not depend on M.f can't be affected by the rule-change
  66 either.
  67
  68 Orphan rules (ones whose 'head function' is not defined in M) are
  69 harder.  Here's what we do.
  70
  71   * We have a per-module orphan-rule version number which changes if
  72     any orphan rule changes. (It's unaffected by non-orphan rules.)
  73
  74   * We record usage info for any orphan module 'below' this one,
  75     giving the orphan-rule version number.  We recompile if this
  76     changes.
  77
  78 The net effect is that if an orphan rule changes, we recompile every
  79 module above it.  That's very conservative, but it's devilishly hard
  80 to know what it might affect, so we just have to be conservative.
  81
  82 Instance decls
  83 ~~~~~~~~~~~~~~
  84 In an iface file we have
  85      module A where
  86         instance Eq a => Eq [a]  =  dfun29
  87         dfun29 :: ...
  88
  89 We have a version number for dfun29, covering its unfolding
  90 etc. Suppose we are compiling a module M that imports A only
  91 indirectly.  If typechecking M uses this instance decl, we record the
  92 dependency on A.dfun29 as if it were a free variable of the module
  93 (via the tcg_inst_usages accumulator).  That means that A will appear
  94 in M's usage list.  If the shape of the instance declaration changes,
  95 then so will dfun29's version, triggering a recompilation.
  96
  97 Adding an instance declaration, or changing an instance decl that is
  98 not currently used, is more tricky.  (This really only makes a
  99 difference when we have overlapping instance decls, because then the
 100 new instance decl might kick in to override the old one.)  We handle
 101 this in a very similar way that we handle rules above.
 102
 103   * For non-orphan instance decls, identify one locally-defined tycon/class
 104     mentioned in the decl.  Treat the instance decl as part of the defn of that
 105     tycon/class, so that if the shape of the instance decl changes, so does the
 106     tycon/class; that in turn will force recompilation of anything that uses
 107     that tycon/class.
 108
 109   * For orphan instance decls, act the same way as for orphan rules.
 110     Indeed, we use the same global orphan-rule version number.
 111
 112 mkUsageInfo
 113 ~~~~~~~~~~~
 114 mkUsageInfo figures out what the ``usage information'' for this
 115 moudule is; that is, what it must record in its interface file as the
 116 things it uses.
 117
 118 We produce a line for every module B below the module, A, currently being
 119 compiled:
 120         import B <n> ;
 121 to record the fact that A does import B indirectly.  This is used to decide
 122 to look to look for B.hi rather than B.hi-boot when compiling a module that
 123 imports A.  This line says that A imports B, but uses nothing in it.
 124 So we'll get an early bale-out when compiling A if B's version changes.
 125
 126 The usage information records:
 127
 128 \begin{itemize}
 129 \item   (a) anything reachable from its body code
 130 \item   (b) any module exported with a @module Foo@
 131 \item   (c) anything reachable from an exported item
 132 \end{itemize}
 133
 134 Why (b)?  Because if @Foo@ changes then this module's export list
 135 will change, so we must recompile this module at least as far as
 136 making a new interface file --- but in practice that means complete
 137 recompilation.
 138
 139 Why (c)?  Consider this:
 140 \begin{verbatim}
 141         module A( f, g ) where  |       module B( f ) where
 142           import B( f )         |         f = h 3
 143           g = ...               |         h = ...
 144 \end{verbatim}
 145
 146 Here, @B.f@ isn't used in A.  Should we nevertheless record @B.f@ in
 147 @A@'s usages?  Our idea is that we aren't going to touch A.hi if it is
 148 *identical* to what it was before.  If anything about @B.f@ changes
 149 than anyone who imports @A@ should be recompiled in case they use
 150 @B.f@ (they'll get an early exit if they don't).  So, if anything
 151 about @B.f@ changes we'd better make sure that something in A.hi
 152 changes, and the convenient way to do that is to record the version
 153 number @B.f@ in A.hi in the usage list.  If B.f changes that'll force a
 154 complete recompiation of A, which is overkill but it's the only way to
 155 write a new, slightly different, A.hi.
 156
 157 But the example is tricker.  Even if @B.f@ doesn't change at all,
 158 @B.h@ may do so, and this change may not be reflected in @f@'s version
 159 number.  But with -O, a module that imports A must be recompiled if
 160 @B.h@ changes!  So A must record a dependency on @B.h@.  So we treat
 161 the occurrence of @B.f@ in the export list *just as if* it were in the
 162 code of A, and thereby haul in all the stuff reachable from it.
 163
 164         *** Conclusion: if A mentions B.f in its export list,
 165             behave just as if A mentioned B.f in its source code,
 166             and slurp in B.f and all its transitive closure ***
 167
 168 [NB: If B was compiled with -O, but A isn't, we should really *still*
 169 haul in all the unfoldings for B, in case the module that imports A *is*
 170 compiled with -O.  I think this is the case.]
 171
 172
 173 \begin{code}
 174 #include "HsVersions.h"
 175
 176 import HsSyn
 177 import IfaceSyn         ( IfaceDecl(..), IfaceClassOp(..), IfaceConDecl(..),
 178                           IfaceRule(..), IfaceInst(..), IfaceExtName(..), IfaceTyCon(..),
 179                           eqIfDecl, eqIfRule, eqIfInst, IfaceEq(..), (&&&), bool,
 180                           eqMaybeBy, eqListBy,
 181                           tyThingToIfaceDecl, dfunToIfaceInst, coreRuleToIfaceRule )
 182 import LoadIface        ( readIface, loadInterface, ifaceInstGates )
 183 import BasicTypes       ( Version, initialVersion, bumpVersion )
 184 import TcRnMonad
 185 import TcRnTypes        ( ImportAvails(..), mkModDeps )
 186 import HscTypes         ( ModIface(..),
 187                           ModGuts(..), ModGuts, IfaceExport,
 188                           GhciMode(..),
 189                           HscEnv(..), hscEPS,
 190                           Dependencies(..), FixItem(..),
 191                           isImplicitTyThing,
 192                           mkIfaceDepCache, mkIfaceFixCache, mkIfaceVerCache,
 193                           typeEnvElts,
 194                           Avails, AvailInfo, GenAvailInfo(..), availName,
 195                           ExternalPackageState(..),
 196                           Usage(..), IsBootInterface,
 197                           Deprecs(..), IfaceDeprecs, Deprecations,
 198                           lookupIfaceByModName
 199                         )
 200
 201
 202 import CmdLineOpts
 203 import Name             ( Name, nameModule, nameOccName, nameParent, isExternalName,
 204                           nameParent_maybe, isWiredInName, NamedThing(..), nameModuleName )
 205 import NameEnv
 206 import NameSet
 207 import OccName          ( OccName, OccEnv, mkOccEnv, lookupOccEnv, emptyOccEnv, extendOccEnv_C,
 208                           OccSet, emptyOccSet, elemOccSet, occSetElts,
 209                           extendOccSet, extendOccSetList,
 210                           isEmptyOccSet, intersectOccSet, intersectsOccSet,
 211                           occNameFS, isTcOcc )
 212 import TyCon            ( visibleDataCons, tyConDataCons )
 213 import DataCon          ( dataConName )
 214 import Module           ( Module, ModuleName, moduleNameFS, moduleName, isHomeModule,
 215                           ModLocation(..), mkSysModuleNameFS, moduleUserString,
 216                           ModuleEnv, emptyModuleEnv, lookupModuleEnv,
 217                           extendModuleEnv_C, moduleEnvElts
 218                         )
 219 import Outputable
 220 import DriverUtil       ( createDirectoryHierarchy, directoryOf )
 221 import Util             ( sortLt, seqList )
 222 import Binary           ( getBinFileWithDict )
 223 import BinIface         ( writeBinIface, v_IgnoreHiWay )
 224 import Unique           ( Unique, Uniquable(..) )
 225 import ErrUtils         ( dumpIfSet_dyn, showPass )
 226 import Digraph          ( stronglyConnComp, SCC(..) )
 227 import FiniteMap
 228 import FastString
 229
 230 import DATA_IOREF       ( writeIORef )
 231 import Monad            ( when )
 232 import List             ( insert )
 233 import Maybes           ( orElse, mapCatMaybes, isNothing, fromJust, expectJust )
 234 \end{code}
 235
 236
 237
 238 %************************************************************************
 239 %*                                                                      *
 240 \subsection{Completing an interface}
 241 %*                                                                      *
 242 %************************************************************************
 243
 244 \begin{code}
 245 mkIface :: HscEnv
 246         -> ModLocation
 247         -> Maybe ModIface       -- The old interface, if we have it
 248         -> ModGuts              -- The compiled, tidied module
 249         -> IO ModIface          -- The new one, complete with decls and versions
 250 -- mkFinalIface
 251 --      a) completes the interface
 252 --      b) writes it out to a file if necessary
 253
 254 mkIface hsc_env location maybe_old_iface
 255         guts@ModGuts{ mg_module = this_mod,
 256                       mg_usages = usages,
 257                       mg_deps   = deps,
 258                       mg_exports = exports,
 259                       mg_fix_env = fix_env,
 260                       mg_deprecs = src_deprecs,
 261                       mg_insts = insts,
 262                       mg_rules = rules,
 263                       mg_types = type_env }
 264   = do  { eps <- hscEPS hsc_env
 265         ; let   { this_mod_name = moduleName this_mod
 266                 ; ext_nm = mkExtNameFn hsc_env eps this_mod_name
 267                 ; decls  = [ tyThingToIfaceDecl omit_prags omit_data_cons ext_nm thing
 268                            | thing <- typeEnvElts type_env
 269                            , not (isImplicitTyThing thing) && not (isWiredInName (getName thing)) ]
 270                                 -- Don't put implicit Ids and class tycons in the interface file
 271                                 -- Nor wired-in things (GHC knows about them already)
 272
 273                 ; fixities = [(occ,fix) | FixItem occ fix _ <- nameEnvElts fix_env]
 274                 ; deprecs  = mkIfaceDeprec src_deprecs
 275                 ; iface_rules
 276                      | omit_prags = []
 277                      | otherwise  = sortLt lt_rule $
 278                                     map (coreRuleToIfaceRule this_mod_name ext_nm) rules
 279                 ; iface_insts = sortLt lt_inst (map (dfunToIfaceInst this_mod_name) insts)
 280
 281                 ; intermediate_iface = ModIface {
 282                         mi_module   = this_mod,
 283                         mi_package  = opt_InPackage,
 284                         mi_boot     = False,
 285                         mi_deps     = deps,
 286                         mi_usages   = usages,
 287                         mi_exports  = mkIfaceExports exports,
 288                         mi_insts    = iface_insts,
 289                         mi_rules    = iface_rules,
 290                         mi_fixities = fixities,
 291                         mi_deprecs  = deprecs,
 292
 293                         -- Left out deliberately: filled in by addVersionInfo
 294                         mi_mod_vers  = initialVersion,
 295                         mi_exp_vers  = initialVersion,
 296                         mi_rule_vers = initialVersion,
 297                         mi_orphan    = False,   -- Always set by addVersionInfo, but
 298                                                 -- it's a strict field, so we can't omit it.
 299                         mi_decls     = deliberatelyOmitted "decls",
 300                         mi_ver_fn    = deliberatelyOmitted "ver_fn",
 301
 302                         -- And build the cached values
 303                         mi_dep_fn = mkIfaceDepCache deprecs,
 304                         mi_fix_fn = mkIfaceFixCache fixities }
 305
 306                 -- Add version information
 307                 ; (new_iface, no_change_at_all, pp_diffs)
 308                         = _scc_ "versioninfo"
 309                          addVersionInfo maybe_old_iface intermediate_iface decls
 310                 }
 311
 312                 -- Write the interface file, if necessary
 313         ; when (not no_change_at_all && ghci_mode /= Interactive) $ do
 314                 createDirectoryHierarchy (directoryOf hi_file_path)
 315                 writeBinIface hi_file_path new_iface
 316
 317                 -- Debug printing
 318         ; when (dopt Opt_D_dump_hi_diffs dflags) (printDump pp_diffs)
 319         ; dumpIfSet_dyn dflags Opt_D_dump_hi "FINAL INTERFACE"
 320                         (pprModIface new_iface)
 321
 322         ; return new_iface }
 323   where
 324      r1 `lt_rule` r2 = ifRuleName r1 < ifRuleName r2
 325      i1 `lt_inst` i2 = ifDFun     i1 < ifDFun     i2
 326
 327      dflags    = hsc_dflags hsc_env
 328      ghci_mode = hsc_mode hsc_env
 329      hi_file_path = ml_hi_file location
 330      omit_prags = dopt Opt_OmitInterfacePragmas dflags
 331      omit_data_cons tycon       -- Don't expose data constructors if none are
 332                                 -- exported and we are not optimising (i.e. not omit_prags)
 333         | omit_prags = not (any exported_data_con (tyConDataCons tycon))
 334         | otherwise  = False
 335      exported_data_con con = dataConName con `elemNameSet` exports
 336
 337 deliberatelyOmitted x = panic ("Deliberately omitted: " ++ x)
 338
 339 -----------------------------
 340 mkExtNameFn :: HscEnv -> ExternalPackageState -> ModuleName -> Name -> IfaceExtName
 341 mkExtNameFn hsc_env eps this_mod
 342   = ext_nm
 343   where
 344     hpt = hsc_HPT hsc_env
 345     pit = eps_PIT eps
 346
 347     ext_nm name
 348       | mod_nm == this_mod = case nameParent_maybe name of
 349                                 Nothing  -> LocalTop occ
 350                                 Just par -> LocalTopSub occ (nameOccName par)
 351       | isWiredInName name = ExtPkg  mod_nm occ
 352       | isHomeModule mod   = HomePkg mod_nm occ vers
 353       | otherwise          = ExtPkg  mod_nm occ
 354       where
 355         mod      = nameModule name
 356         mod_nm   = moduleName mod
 357         occ      = nameOccName name
 358         par_occ  = nameOccName (nameParent name)
 359                 -- The version of the *parent* is the one want
 360         vers     = lookupVersion mod_nm par_occ
 361
 362     lookupVersion :: ModuleName -> OccName -> Version
 363         -- Even though we're looking up a home-package thing, in
 364         -- one-shot mode the imported interfaces may be in the PIT
 365     lookupVersion mod occ
 366       = mi_ver_fn iface occ `orElse`
 367         pprPanic "lookupVers1" (ppr mod <+> ppr occ)
 368       where
 369         iface = lookupIfaceByModName hpt pit mod `orElse`
 370                 pprPanic "lookupVers2" (ppr mod <+> ppr occ)
 371
 372 -----------------------------
 373 -- Compute version numbers for local decls
 374
 375 addVersionInfo :: Maybe ModIface        -- The old interface, read from M.hi
 376                -> ModIface              -- The new interface decls (lacking decls)
 377                -> [IfaceDecl]           -- The new decls
 378                -> (ModIface,
 379                    Bool,                -- True <=> no changes at all; no need to write new Iface
 380                    SDoc)                -- Differences
 381
 382 addVersionInfo Nothing new_iface new_decls
 383 -- No old interface, so definitely write a new one!
 384   = (new_iface { mi_orphan = anyNothing getInstKey (mi_insts new_iface)
 385                           || anyNothing getRuleKey (mi_rules new_iface),
 386                  mi_decls  = [(initialVersion, decl) | decl <- new_decls],
 387                  mi_ver_fn = \n -> Just initialVersion },
 388      False, ptext SLIT("No old interface file") $$
 389             pprOrphans orph_insts orph_rules)
 390   where
 391     orph_insts = filter (isNothing . getInstKey) (mi_insts new_iface)
 392     orph_rules = filter (isNothing . getRuleKey) (mi_rules new_iface)
 393
 394 addVersionInfo (Just old_iface@(ModIface { mi_mod_vers  = old_mod_vers,
 395                                            mi_exp_vers  = old_exp_vers,
 396                                            mi_rule_vers = old_rule_vers,
 397                                            mi_decls     = old_decls,
 398                                            mi_ver_fn    = old_decl_vers,
 399                                            mi_fix_fn    = old_fixities }))
 400                new_iface@(ModIface { mi_fix_fn = new_fixities })
 401                new_decls
 402
 403   | no_change_at_all = (old_iface,   True,  ptext SLIT("Interface file unchanged") $$ pp_orphs)
 404   | otherwise        = (final_iface, False, vcat [ptext SLIT("Interface file has changed"),
 405                                                   nest 2 pp_diffs,
 406                                                   text "" $$ pp_orphs])
 407   where
 408     final_iface = new_iface { mi_mod_vers  = bump_unless no_output_change old_mod_vers,
 409                               mi_exp_vers  = bump_unless no_export_change old_exp_vers,
 410                               mi_rule_vers = bump_unless no_rule_change   old_rule_vers,
 411                               mi_orphan    = not (null new_orph_rules && null new_orph_insts),
 412                               mi_decls     = decls_w_vers,
 413                               mi_ver_fn    = mkIfaceVerCache decls_w_vers }
 414
 415     decls_w_vers = [(add_vers decl, decl) | decl <- new_decls]
 416
 417     -------------------
 418     (old_non_orph_insts, old_orph_insts) = mkRuleMap getInstKey (mi_insts old_iface)
 419     (new_non_orph_insts, new_orph_insts) = mkRuleMap getInstKey (mi_insts new_iface)
 420     same_insts occ = eqMaybeBy  (eqListBy eqIfInst)
 421                                 (lookupOccEnv old_non_orph_insts occ)
 422                                 (lookupOccEnv new_non_orph_insts occ)
 423
 424     (old_non_orph_rules, old_orph_rules) = mkRuleMap getRuleKey (mi_rules old_iface)
 425     (new_non_orph_rules, new_orph_rules) = mkRuleMap getRuleKey (mi_rules new_iface)
 426     same_rules occ = eqMaybeBy  (eqListBy eqIfRule)
 427                                 (lookupOccEnv old_non_orph_rules occ)
 428                                 (lookupOccEnv new_non_orph_rules occ)
 429     -------------------
 430     -- Computing what changed
 431     no_output_change = no_decl_change   && no_rule_change &&
 432                        no_export_change && no_deprec_change
 433     no_export_change = mi_exports new_iface == mi_exports old_iface     -- Kept sorted
 434     no_decl_change   = isEmptyOccSet changed_occs
 435     no_rule_change   = not (changedWrt changed_occs (eqListBy eqIfRule old_orph_rules new_orph_rules)
 436                          || changedWrt changed_occs (eqListBy eqIfInst old_orph_insts new_orph_insts))
 437     no_deprec_change = mi_deprecs new_iface == mi_deprecs old_iface
 438
 439         -- If the usages havn't changed either, we don't need to write the interface file
 440         -- Question: should we also check for equality of mi_deps?
 441     no_other_changes = mi_usages new_iface == mi_usages old_iface
 442     no_change_at_all = no_output_change && no_other_changes
 443
 444     pp_diffs = vcat [pp_change no_export_change "Export list"
 445                         (ppr old_exp_vers <+> arrow <+> ppr (mi_exp_vers final_iface)),
 446                      pp_change no_rule_change "Rules"
 447                         (ppr old_rule_vers <+> arrow <+> ppr (mi_rule_vers final_iface)),
 448                      pp_change no_deprec_change "Deprecations" empty,
 449                      pp_change no_other_changes  "Usages" empty,
 450                      pp_decl_diffs]
 451     pp_change True  what info = empty
 452     pp_change False what info = text what <+> ptext SLIT("changed") <+> info
 453
 454     -------------------
 455     old_decl_env = mkOccEnv [(ifName decl, decl) | (_,decl) <- old_decls]
 456     same_fixity n = bool (old_fixities n == new_fixities n)
 457
 458     -------------------
 459     -- Adding version info
 460     new_version     = bumpVersion old_mod_vers
 461     add_vers decl | occ `elemOccSet` changed_occs = new_version
 462                   | otherwise = expectJust "add_vers" (old_decl_vers occ)
 463                                 -- If it's unchanged, there jolly well
 464                   where         -- should be an old version number
 465                     occ = ifName decl
 466
 467     -------------------
 468     changed_occs :: OccSet
 469     changed_occs = computeChangedOccs eq_info
 470
 471     eq_info :: [(OccName, IfaceEq)]
 472     eq_info = map check_eq new_decls
 473     check_eq new_decl | Just old_decl <- lookupOccEnv old_decl_env occ
 474                       = (occ, new_decl `eqIfDecl` old_decl &&&
 475                               eq_indirects new_decl)
 476                       | otherwise {- No corresponding old decl -}
 477                       = (occ, NotEqual)
 478                       where
 479                         occ = ifName new_decl
 480
 481     eq_indirects :: IfaceDecl -> IfaceEq
 482                 -- When seeing if two decls are the same, remember to
 483                 -- check whether any relevant fixity or rules have changed
 484     eq_indirects (IfaceId {ifName = occ}) = eq_ind_occ occ
 485     eq_indirects (IfaceClass {ifName = cls_occ, ifSigs = sigs})
 486         = same_insts cls_occ &&&
 487           eq_ind_occs [op | IfaceClassOp op _ _ <- sigs]
 488     eq_indirects (IfaceData {ifName = tc_occ, ifCons = cons})
 489         = same_insts tc_occ &&& same_fixity tc_occ &&&  -- The TyCon can have a fixity too
 490           eq_ind_occs [occ | IfaceConDecl occ _ _ _ _ _ <- visibleDataCons cons]
 491     eq_indirects other = Equal  -- Synonyms and foreign declarations
 492
 493     eq_ind_occ :: OccName -> IfaceEq    -- For class ops and Ids; check fixity and rules
 494     eq_ind_occ occ = same_fixity occ &&& same_rules occ
 495     eq_ind_occs = foldr ((&&&) . eq_ind_occ) Equal
 496
 497     -------------------
 498     -- Diffs
 499     pp_decl_diffs :: SDoc       -- Nothing => no changes
 500     pp_decl_diffs
 501         | isEmptyOccSet changed_occs = empty
 502         | otherwise
 503         = vcat [ptext SLIT("Changed occs:") <+> ppr (occSetElts changed_occs),
 504                 ptext SLIT("Version change for these decls:"),
 505                 nest 2 (vcat (map show_change new_decls))]
 506
 507     eq_env = mkOccEnv eq_info
 508     show_change new_decl
 509         | not (occ `elemOccSet` changed_occs) = empty
 510         | otherwise
 511         = vcat [ppr occ <+> ppr (old_decl_vers occ) <+> arrow <+> ppr new_version,
 512                 nest 2 why]
 513         where
 514           occ = ifName new_decl
 515           why = case lookupOccEnv eq_env occ of
 516                     Just (EqBut occs) -> sep [ppr occ <> colon, ptext SLIT("Free vars (only) changed:"),
 517                                               nest 2 (braces (fsep (map ppr (occSetElts
 518                                                 (occs `intersectOccSet` changed_occs)))))]
 519                     Just NotEqual
 520                         | Just old_decl <- lookupOccEnv old_decl_env occ
 521                         -> vcat [ptext SLIT("Old:") <+> ppr old_decl,
 522                          ptext SLIT("New:") <+> ppr new_decl]
 523                         | otherwise
 524                         -> ppr occ <+> ptext SLIT("only in new interface")
 525                     other -> pprPanic "MkIface.show_change" (ppr occ)
 526
 527     pp_orphs = pprOrphans new_orph_insts new_orph_rules
 528
 529 pprOrphans insts rules
 530   = vcat [if null insts then empty else
 531              ptext SLIT("Orphan instances:") <+> vcat (map ppr insts),
 532           if null rules then empty else
 533              ptext SLIT("Orphan rules:") <+> vcat (map ppr rules)]
 534
 535 computeChangedOccs :: [(OccName, IfaceEq)] -> OccSet
 536 computeChangedOccs eq_info
 537   = foldl add_changes emptyOccSet (stronglyConnComp edges)
 538   where
 539     edges :: [((OccName,IfaceEq), Unique, [Unique])]
 540     edges = [ (node, getUnique occ, map getUnique occs)
 541             | node@(occ, iface_eq) <- eq_info
 542             , let occs = case iface_eq of
 543                            EqBut occ_set -> occSetElts occ_set
 544                            other -> [] ]
 545
 546     -- Changes in declarations
 547     add_changes :: OccSet -> SCC (OccName, IfaceEq) -> OccSet
 548     add_changes so_far (AcyclicSCC (occ, iface_eq))
 549         | changedWrt so_far iface_eq                            -- This one has changed
 550         = extendOccSet so_far occ
 551     add_changes so_far (CyclicSCC pairs)
 552         | changedWrt so_far (foldr1 (&&&) (map snd pairs))      -- One of this group has changed
 553         = extendOccSetList so_far (map fst pairs)
 554     add_changes so_far other = so_far
 555
 556 changedWrt :: OccSet -> IfaceEq -> Bool
 557 changedWrt so_far Equal        = False
 558 changedWrt so_far NotEqual     = True
 559 changedWrt so_far (EqBut kids) = so_far `intersectsOccSet` kids
 560
 561 ----------------------
 562 -- mkRuleMap partitions instance decls or rules into
 563 --      (a) an OccEnv for ones that are not orphans,
 564 --          mapping the local OccName to a list of its decls
 565 --      (b) a list of orphan decls
 566 mkRuleMap :: (decl -> Maybe OccName)    -- (Just occ) for a non-orphan decl, keyed by occ
 567                                         -- Nothing for an orphan decl
 568           -> [decl]                     -- Sorted into canonical order
 569           -> (OccEnv [decl],            -- Non-orphan decls associated with their key;
 570                                         --      each sublist in canonical order
 571               [decl])                   -- Orphan decls; in canonical order
 572 mkRuleMap get_key decls
 573   = foldl go (emptyOccEnv, []) decls
 574   where
 575     go (non_orphs, orphs) d
 576         | Just occ <- get_key d
 577         = (extendOccEnv_C (\ ds _ -> d:ds) non_orphs occ [d], orphs)
 578         | otherwise = (non_orphs, d:orphs)
 579
 580 -- getXxKey: find at least one local OccName that belongs to this decl
 581
 582 getInstKey :: IfaceInst -> Maybe OccName
 583 getInstKey (IfaceInst {ifInstHead = inst_ty})
 584   = case [occ | LocalTop occ <- cls_ext : tc_exts] of
 585         []      -> Nothing
 586         (occ:_) -> Just occ
 587   where
 588     (cls_ext, tcs) = ifaceInstGates inst_ty
 589     tc_exts = [tc | IfaceTc tc <- tcs]
 590         -- Ignore the wired-in IfaceTyCons; the class will do as the key
 591
 592 getRuleKey :: IfaceRule -> Maybe OccName
 593 getRuleKey (IfaceRule {ifRuleHead = LocalTop occ}) = Just occ
 594 getRuleKey other                                   = Nothing
 595
 596 anyNothing :: (a -> Maybe b) -> [a] -> Bool
 597 anyNothing p []     = False
 598 anyNothing p (x:xs) = isNothing (p x) || anyNothing p xs
 599
 600 ----------------------
 601 mkIfaceDeprec :: Deprecations -> IfaceDeprecs
 602 mkIfaceDeprec NoDeprecs        = NoDeprecs
 603 mkIfaceDeprec (DeprecAll t)    = DeprecAll t
 604 mkIfaceDeprec (DeprecSome env) = DeprecSome (sortLt (<) (nameEnvElts env))
 605
 606 ----------------------
 607 bump_unless :: Bool -> Version -> Version
 608 bump_unless True  v = v -- True <=> no change
 609 bump_unless False v = bumpVersion v
 610 \end{code}
 611
 612
 613 %*********************************************************
 614 %*                                                      *
 615 \subsection{Keeping track of what we've slurped, and version numbers}
 616 %*                                                      *
 617 %*********************************************************
 618
 619
 620 \begin{code}
 621 mkUsageInfo :: HscEnv -> ImportAvails -> NameSet -> IO [Usage]
 622 mkUsageInfo hsc_env
 623             (ImportAvails { imp_mods = dir_imp_mods,
 624                             imp_dep_mods = dep_mods })
 625             used_names
 626   = do  { eps <- hscEPS hsc_env
 627         ; return (mk_usage_info (eps_PIT eps) (hsc_HPT hsc_env)
 628                                 dir_imp_mods dep_mods used_names) }
 629
 630 mk_usage_info pit hpt dir_imp_mods dep_mods proto_used_names
 631   = -- seq the list of Usages returned: occasionally these
 632     -- don't get evaluated for a while and we can end up hanging on to
 633     -- the entire collection of Ifaces.
 634     usages `seqList` usages
 635   where
 636     used_names = mkNameSet $                    -- Eliminate duplicates
 637                  [ nameParent n                 -- Just record usage on the 'main' names
 638                  | n <- nameSetToList proto_used_names
 639                  , not (isWiredInName n)        -- Don't record usages for wired-in names
 640                  , isExternalName n             -- Ignore internal names
 641                  ]
 642
 643     -- ent_map groups together all the things imported and used
 644     -- from a particular module in this package
 645     ent_map :: ModuleEnv [OccName]
 646     ent_map  = foldNameSet add_mv emptyModuleEnv used_names
 647     add_mv name mv_map = extendModuleEnv_C add_item mv_map mod [occ]
 648                    where
 649                      occ = nameOccName name
 650                      mod = nameModule name
 651                      add_item occs _ = occ:occs
 652
 653     usages = mapCatMaybes mkUsage (moduleEnvElts dep_mods)
 654         -- ToDo: do we need to sort into canonical order?
 655
 656     import_all mod = case lookupModuleEnv dir_imp_mods mod of
 657                         Just (_,imp_all) -> isNothing imp_all
 658                         Nothing          -> False
 659
 660     -- We want to create a Usage for a home module if
 661     --  a) we used something from; has something in used_names
 662     --  b) we imported all of it, even if we used nothing from it
 663     --          (need to recompile if its export list changes: export_vers)
 664     --  c) is a home-package orphan module (need to recompile if its
 665     --          instance decls change: rules_vers)
 666     mkUsage :: (ModuleName, Bool) -> Maybe Usage
 667     mkUsage (mod_name, _)
 668       |  isNothing maybe_iface  -- We can't depend on it if we didn't
 669       || not (isHomeModule mod) -- even open the interface!
 670       || (null used_occs
 671           && not all_imported
 672           && not orphan_mod)
 673       = Nothing                 -- Record no usage info
 674
 675       | otherwise
 676       = Just (Usage { usg_name     = moduleName mod,
 677                       usg_mod      = mod_vers,
 678                       usg_exports  = export_vers,
 679                       usg_entities = ent_vers,
 680                       usg_rules    = rules_vers })
 681       where
 682         maybe_iface  = lookupIfaceByModName hpt pit mod_name
 683                 -- In one-shot mode, the interfaces for home-package
 684                 -- modules accumulate in the PIT not HPT.  Sigh.
 685
 686         Just iface   = maybe_iface
 687         mod          = mi_module    iface
 688         orphan_mod   = mi_orphan    iface
 689         version_env  = mi_ver_fn    iface
 690         mod_vers     = mi_mod_vers  iface
 691         rules_vers   = mi_rule_vers iface
 692         all_imported = import_all mod
 693         export_vers | all_imported = Just (mi_exp_vers iface)
 694                     | otherwise    = Nothing
 695
 696         -- The sort is to put them into canonical order
 697         used_occs = lookupModuleEnv ent_map mod `orElse` []
 698         ent_vers :: [(OccName,Version)]
 699         ent_vers = [ (occ, version_env occ `orElse` initialVersion)
 700                    | occ <- sortLt (<) used_occs]
 701 \end{code}
 702
 703 \begin{code}
 704 mkIfaceExports :: NameSet -> [(ModuleName, [GenAvailInfo OccName])]
 705   -- Group by module and sort by occurrence
 706   -- This keeps the list in canonical order
 707 mkIfaceExports exports
 708   = [ (mkSysModuleNameFS fs, eltsFM avails)
 709     | (fs, avails) <- fmToList groupFM
 710     ]
 711   where
 712     groupFM :: FiniteMap FastString (FiniteMap FastString (GenAvailInfo OccName))
 713         -- Deliberately use the FastString so we
 714         -- get a canonical ordering
 715     groupFM = foldl add emptyFM (nameSetToList exports)
 716
 717     add env name = addToFM_C add_avail env mod_fs
 718                              (unitFM avail_fs avail)
 719       where
 720         occ    = nameOccName name
 721         occ_fs = occNameFS occ
 722         mod_fs = moduleNameFS (nameModuleName name)
 723         avail | Just p <- nameParent_maybe name = AvailTC (nameOccName p) [occ]
 724               | isTcOcc occ                     = AvailTC occ [occ]
 725               | otherwise                       = Avail occ
 726         avail_fs = occNameFS (availName avail)
 727         add_avail avail_fm _ = addToFM_C add_item avail_fm avail_fs avail
 728
 729         add_item (AvailTC p occs) _ = AvailTC p (insert occ occs)
 730         add_item (Avail n)         _ = pprPanic "MkIface.addAvail" (ppr n <+> ppr name)
 731 \end{code}
 732
 733
 734 %************************************************************************
 735 %*                                                                      *
 736         Load the old interface file for this module (unless
 737         we have it aleady), and check whether it is up to date
 738
 739 %*                                                                      *
 740 %************************************************************************
 741
 742 \begin{code}
 743 checkOldIface :: HscEnv
 744               -> Module
 745               -> FilePath               -- Where the interface file is
 746               -> Bool                   -- Source unchanged
 747               -> Maybe ModIface         -- Old interface from compilation manager, if any
 748               -> IO (RecompileRequired, Maybe ModIface)
 749
 750 checkOldIface hsc_env mod iface_path source_unchanged maybe_iface
 751   = do  { showPass (hsc_dflags hsc_env)
 752                    ("Checking old interface for " ++ moduleUserString mod) ;
 753
 754         ; initIfaceCheck hsc_env $
 755           check_old_iface mod iface_path source_unchanged maybe_iface
 756      }
 757
 758 check_old_iface this_mod iface_path source_unchanged maybe_iface
 759  =      -- CHECK WHETHER THE SOURCE HAS CHANGED
 760     ifM (not source_unchanged)
 761         (traceHiDiffs (nest 4 (text "Source file changed or recompilation check turned off")))
 762                                                 `thenM_`
 763
 764      -- If the source has changed and we're in interactive mode, avoid reading
 765      -- an interface; just return the one we might have been supplied with.
 766     getGhciMode                                 `thenM` \ ghci_mode ->
 767     if (ghci_mode == Interactive) && not source_unchanged then
 768          returnM (outOfDate, maybe_iface)
 769     else
 770
 771     case maybe_iface of {
 772        Just old_iface -> -- Use the one we already have
 773                          checkVersions source_unchanged old_iface       `thenM` \ recomp ->
 774                          returnM (recomp, Just old_iface)
 775
 776     ;  Nothing ->
 777
 778         -- Try and read the old interface for the current module
 779         -- from the .hi file left from the last time we compiled it
 780     readIface (moduleName this_mod) iface_path False            `thenM` \ read_result ->
 781     case read_result of {
 782        Left err ->      -- Old interface file not found, or garbled; give up
 783                    traceIf (text "FYI: cannot read old interface file:"
 784                                  $$ nest 4 err)         `thenM_`
 785                    returnM (outOfDate, Nothing)
 786
 787     ;  Right iface ->
 788
 789         -- We have got the old iface; check its versions
 790     checkVersions source_unchanged iface        `thenM` \ recomp ->
 791     returnM (recomp, Just iface)
 792     }}
 793 \end{code}
 794
 795 @recompileRequired@ is called from the HscMain.   It checks whether
 796 a recompilation is required.  It needs access to the persistent state,
 797 finder, etc, because it may have to load lots of interface files to
 798 check their versions.
 799
 800 \begin{code}
 801 type RecompileRequired = Bool
 802 upToDate  = False       -- Recompile not required
 803 outOfDate = True        -- Recompile required
 804
 805 checkVersions :: Bool           -- True <=> source unchanged
 806               -> ModIface       -- Old interface
 807               -> IfG RecompileRequired
 808 checkVersions source_unchanged iface
 809   | not source_unchanged
 810   = returnM outOfDate
 811   | otherwise
 812   = traceHiDiffs (text "Considering whether compilation is required for" <+>
 813                   ppr (mi_module iface) <> colon)       `thenM_`
 814
 815         -- Source code unchanged and no errors yet... carry on
 816         -- First put the dependent-module info in the envt, just temporarily,
 817         -- so that when we look for interfaces we look for the right one (.hi or .hi-boot)
 818         -- It's just temporary because either the usage check will succeed
 819         -- (in which case we are done with this module) or it'll fail (in which
 820         -- case we'll compile the module from scratch anyhow).
 821     updGblEnv (\ gbl -> gbl { if_is_boot = mod_deps }) (
 822         checkList [checkModUsage u | u <- mi_usages iface]
 823     )
 824   where
 825         -- This is a bit of a hack really
 826     mod_deps :: ModuleEnv (ModuleName, IsBootInterface)
 827     mod_deps = mkModDeps (dep_mods (mi_deps iface))
 828
 829 checkModUsage :: Usage -> IfG RecompileRequired
 830 -- Given the usage information extracted from the old
 831 -- M.hi file for the module being compiled, figure out
 832 -- whether M needs to be recompiled.
 833
 834 checkModUsage (Usage { usg_name = mod_name, usg_mod = old_mod_vers,
 835                        usg_rules = old_rule_vers,
 836                        usg_exports = maybe_old_export_vers,
 837                        usg_entities = old_decl_vers })
 838   =     -- Load the imported interface is possible
 839     let
 840         doc_str = sep [ptext SLIT("need version info for"), ppr mod_name]
 841     in
 842     traceHiDiffs (text "Checking usages for module" <+> ppr mod_name) `thenM_`
 843
 844     loadInterface doc_str mod_name ImportBySystem       `thenM` \ mb_iface ->
 845         -- Load the interface, but don't complain on failure;
 846         -- Instead, get an Either back which we can test
 847
 848     case mb_iface of {
 849         Left exn ->  (out_of_date (sep [ptext SLIT("Can't find version number for module"),
 850                                        ppr mod_name]));
 851                 -- Couldn't find or parse a module mentioned in the
 852                 -- old interface file.  Don't complain -- it might just be that
 853                 -- the current module doesn't need that import and it's been deleted
 854
 855         Right iface ->
 856     let
 857         new_mod_vers    = mi_mod_vers  iface
 858         new_decl_vers   = mi_ver_fn    iface
 859         new_export_vers = mi_exp_vers  iface
 860         new_rule_vers   = mi_rule_vers iface
 861     in
 862         -- CHECK MODULE
 863     checkModuleVersion old_mod_vers new_mod_vers        `thenM` \ recompile ->
 864     if not recompile then
 865         returnM upToDate
 866     else
 867
 868         -- CHECK EXPORT LIST
 869     if checkExportList maybe_old_export_vers new_export_vers then
 870         out_of_date_vers (ptext SLIT("  Export list changed"))
 871                          (fromJust maybe_old_export_vers)
 872                          new_export_vers
 873     else
 874
 875         -- CHECK RULES
 876     if old_rule_vers /= new_rule_vers then
 877         out_of_date_vers (ptext SLIT("  Rules changed"))
 878                          old_rule_vers new_rule_vers
 879     else
 880
 881         -- CHECK ITEMS ONE BY ONE
 882     checkList [checkEntityUsage new_decl_vers u | u <- old_decl_vers]   `thenM` \ recompile ->
 883     if recompile then
 884         returnM outOfDate       -- This one failed, so just bail out now
 885     else
 886         up_to_date (ptext SLIT("  Great!  The bits I use are up to date"))
 887     }
 888
 889 ------------------------
 890 checkModuleVersion old_mod_vers new_mod_vers
 891   | new_mod_vers == old_mod_vers
 892   = up_to_date (ptext SLIT("Module version unchanged"))
 893
 894   | otherwise
 895   = out_of_date_vers (ptext SLIT("  Module version has changed"))
 896                      old_mod_vers new_mod_vers
 897
 898 ------------------------
 899 checkExportList Nothing  new_vers = upToDate
 900 checkExportList (Just v) new_vers = v /= new_vers
 901
 902 ------------------------
 903 checkEntityUsage new_vers (name,old_vers)
 904   = case new_vers name of
 905
 906         Nothing       ->        -- We used it before, but it ain't there now
 907                           out_of_date (sep [ptext SLIT("No longer exported:"), ppr name])
 908
 909         Just new_vers   -- It's there, but is it up to date?
 910           | new_vers == old_vers -> traceHiDiffs (text "  Up to date" <+> ppr name <+> parens (ppr new_vers)) `thenM_`
 911                                     returnM upToDate
 912           | otherwise            -> out_of_date_vers (ptext SLIT("  Out of date:") <+> ppr name)
 913                                                      old_vers new_vers
 914
 915 up_to_date  msg = traceHiDiffs msg `thenM_` returnM upToDate
 916 out_of_date msg = traceHiDiffs msg `thenM_` returnM outOfDate
 917 out_of_date_vers msg old_vers new_vers
 918   = out_of_date (hsep [msg, ppr old_vers, ptext SLIT("->"), ppr new_vers])
 919
 920 ----------------------
 921 checkList :: [IfG RecompileRequired] -> IfG RecompileRequired
 922 -- This helper is used in two places
 923 checkList []             = returnM upToDate
 924 checkList (check:checks) = check        `thenM` \ recompile ->
 925                            if recompile then
 926                                 returnM outOfDate
 927                            else
 928                                 checkList checks
 929 \end{code}
 930
 931 %************************************************************************
 932 %*                                                                      *
 933                 Printing interfaces
 934 %*                                                                      *
 935 %************************************************************************
 936
 937 \begin{code}
 938 showIface :: FilePath -> IO ()
 939 -- Raad binary interface, and print it out
 940 showIface filename = do
 941    -- skip the version check; we don't want to worry about profiled vs.
 942    -- non-profiled interfaces, for example.
 943    writeIORef v_IgnoreHiWay True
 944    iface <- Binary.getBinFileWithDict filename
 945    printDump (pprModIface iface)
 946  where
 947 \end{code}
 948
 949
 950 \begin{code}
 951 pprModIface :: ModIface -> SDoc
 952 -- Show a ModIface
 953 pprModIface iface
 954  = vcat [ ptext SLIT("interface")
 955                 <+> doubleQuotes (ftext (mi_package iface))
 956                 <+> ppr (mi_module iface) <+> ppr (mi_mod_vers iface)
 957                 <+> pp_sub_vers
 958                 <+> (if mi_orphan iface then ptext SLIT("[orphan module]") else empty)
 959                 <+> int opt_HiVersion
 960                 <+> ptext SLIT("where")
 961         , vcat (map pprExport (mi_exports iface))
 962         , pprDeps (mi_deps iface)
 963         , vcat (map pprUsage (mi_usages iface))
 964         , pprFixities (mi_fixities iface)
 965         , vcat (map pprIfaceDecl (mi_decls iface))
 966         , vcat (map ppr (mi_insts iface))
 967         , vcat (map ppr (mi_rules iface))
 968         , pprDeprecs (mi_deprecs iface)
 969         ]
 970   where
 971     exp_vers  = mi_exp_vers iface
 972     rule_vers = mi_rule_vers iface
 973
 974     pp_sub_vers | exp_vers == initialVersion && rule_vers == initialVersion = empty
 975                 | otherwise = brackets (ppr exp_vers <+> ppr rule_vers)
 976 \end{code}
 977
 978 When printing export lists, we print like this:
 979         Avail   f               f
 980         AvailTC C [C, x, y]     C(x,y)
 981         AvailTC C [x, y]        C!(x,y)         -- Exporting x, y but not C
 982
 983 \begin{code}
 984 pprExport :: IfaceExport -> SDoc
 985 pprExport (mod, items)
 986  = hsep [ ptext SLIT("export"), ppr mod, hsep (map pp_avail items) ]
 987   where
 988     pp_avail :: GenAvailInfo OccName -> SDoc
 989     pp_avail (Avail occ)    = ppr occ
 990     pp_avail (AvailTC _ []) = empty
 991     pp_avail (AvailTC n (n':ns))
 992         | n==n'     = ppr n <> pp_export ns
 993         | otherwise = ppr n <> char '|' <> pp_export (n':ns)
 994
 995     pp_export []    = empty
 996     pp_export names = braces (hsep (map ppr names))
 997
 998 pprUsage :: Usage -> SDoc
 999 pprUsage usage
1000   = hsep [ptext SLIT("import"), ppr (usg_name usage),
1001           int (usg_mod usage),
1002           pp_export_version (usg_exports usage),
1003           int (usg_rules usage),
1004           pp_versions (usg_entities usage) ]
1005   where
1006     pp_versions nvs = hsep [ ppr n <+> int v | (n,v) <- nvs ]
1007     pp_export_version Nothing  = empty
1008     pp_export_version (Just v) = int v
1009
1010 pprDeps :: Dependencies -> SDoc
1011 pprDeps (Deps { dep_mods = mods, dep_pkgs = pkgs, dep_orphs = orphs})
1012   = vcat [ptext SLIT("module dependencies:") <+> fsep (map ppr_mod mods),
1013           ptext SLIT("package dependencies:") <+> fsep (map ppr pkgs),
1014           ptext SLIT("orphans:") <+> fsep (map ppr orphs)
1015         ]
1016   where
1017     ppr_mod (mod_name, boot) = ppr mod_name <+> ppr_boot boot
1018     ppr_boot True  = text "[boot]"
1019     ppr_boot False = empty
1020
1021 pprIfaceDecl :: (Version, IfaceDecl) -> SDoc
1022 pprIfaceDecl (ver, decl)
1023   = ppr_vers ver <+> ppr decl
1024   where
1025         -- Print the version for the decl
1026     ppr_vers v | v == initialVersion = empty
1027                | otherwise           = int v
1028
1029 pprFixities :: [(OccName, Fixity)] -> SDoc
1030 pprFixities []    = empty
1031 pprFixities fixes = ptext SLIT("fixities") <+> pprWithCommas pprFix fixes
1032                   where
1033                     pprFix (occ,fix) = ppr fix <+> ppr occ
1034
1035 pprDeprecs NoDeprecs        = empty
1036 pprDeprecs (DeprecAll txt)  = ptext SLIT("Deprecate all") <+> doubleQuotes (ftext txt)
1037 pprDeprecs (DeprecSome prs) = ptext SLIT("Deprecate") <+> vcat (map pprDeprec prs)
1038                             where
1039                               pprDeprec (name, txt) = ppr name <+> doubleQuotes (ftext txt)
1040 \end{code}