ghc/compiler/iface/TcIface.lhs

   1 %
   2 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   3 %
   4 \section[TcIfaceSig]{Type checking of type signatures in interface files}
   5
   6 \begin{code}
   7 module TcIface (
   8         tcImportDecl, typecheckIface, tcIfaceDecl, tcIfaceGlobal,
   9         loadImportedInsts, loadImportedRules,
  10         tcExtCoreBindings
  11  ) where
  12
  13 #include "HsVersions.h"
  14
  15 import IfaceSyn
  16 import LoadIface        ( loadHomeInterface, loadInterface, predInstGates,
  17                           loadDecls )
  18 import IfaceEnv         ( lookupIfaceTop, lookupIfaceExt, newGlobalBinder,
  19                           extendIfaceIdEnv, extendIfaceTyVarEnv, newIPName,
  20                           tcIfaceTyVar, tcIfaceLclId,
  21                           newIfaceName, newIfaceNames )
  22 import BuildTyCl        ( buildSynTyCon, buildAlgTyCon, buildDataCon, buildClass,
  23                           mkAbstractTyConRhs, mkDataTyConRhs, mkNewTyConRhs )
  24 import TcRnMonad
  25 import TcType           ( hoistForAllTys )      -- TEMPORARY HACK
  26 import Type             ( liftedTypeKind, splitTyConApp, mkSynTy, mkTyConApp,
  27                           mkTyVarTys, mkGenTyConApp, ThetaType, pprClassPred )
  28 import TypeRep          ( Type(..), PredType(..) )
  29 import TyCon            ( TyCon, tyConName, isSynTyCon )
  30 import HscTypes         ( ExternalPackageState(..), EpsStats(..), PackageInstEnv,
  31                           HscEnv, TyThing(..), tyThingClass, tyThingTyCon,
  32                           ModIface(..), ModDetails(..), ModGuts,
  33                           extendTypeEnv, lookupTypeEnv, lookupType, typeEnvIds )
  34 import InstEnv          ( extendInstEnvList )
  35 import CoreSyn
  36 import PprCore          ( pprIdRules )
  37 import Rules            ( extendRuleBaseList )
  38 import CoreUtils        ( exprType )
  39 import CoreUnfold
  40 import CoreLint         ( lintUnfolding )
  41 import WorkWrap         ( mkWrapper )
  42 import InstEnv          ( DFunId )
  43 import Id               ( Id, mkVanillaGlobal, mkLocalId )
  44 import MkId             ( mkFCallId )
  45 import IdInfo           ( IdInfo, CafInfo(..), WorkerInfo(..),
  46                           setUnfoldingInfoLazily, setAllStrictnessInfo, setWorkerInfo,
  47                           setArityInfo, setInlinePragInfo, setCafInfo,
  48                           vanillaIdInfo, newStrictnessInfo )
  49 import Class            ( Class )
  50 import TyCon            ( tyConDataCons, isTupleTyCon, mkForeignTyCon )
  51 import DataCon          ( DataCon, dataConWorkId, dataConTyVars, dataConArgTys, isVanillaDataCon )
  52 import TysWiredIn       ( tupleCon, tupleTyCon, listTyCon, intTyCon, boolTyCon, charTyCon, parrTyCon )
  53 import Var              ( TyVar, mkTyVar, tyVarKind )
  54 import Name             ( Name, nameModule, nameIsLocalOrFrom,
  55                           isWiredInName, wiredInNameTyThing_maybe, nameParent )
  56 import NameEnv
  57 import OccName          ( OccName )
  58 import Module           ( Module )
  59 import UniqSupply       ( initUs_ )
  60 import Outputable
  61 import ErrUtils         ( Message )
  62 import Maybes           ( MaybeErr(..) )
  63 import SrcLoc           ( noSrcLoc )
  64 import Util             ( zipWithEqual, dropList, equalLength )
  65 import CmdLineOpts      ( DynFlag(..) )
  66 \end{code}
  67
  68 This module takes
  69
  70         IfaceDecl -> TyThing
  71         IfaceType -> Type
  72         etc
  73
  74 An IfaceDecl is populated with RdrNames, and these are not renamed to
  75 Names before typechecking, because there should be no scope errors etc.
  76
  77         -- For (b) consider: f = $(...h....)
  78         -- where h is imported, and calls f via an hi-boot file.
  79         -- This is bad!  But it is not seen as a staging error, because h
  80         -- is indeed imported.  We don't want the type-checker to black-hole
  81         -- when simplifying and compiling the splice!
  82         --
  83         -- Simple solution: discard any unfolding that mentions a variable
  84         -- bound in this module (and hence not yet processed).
  85         -- The discarding happens when forkM finds a type error.
  86
  87 %************************************************************************
  88 %*                                                                      *
  89 %*      tcImportDecl is the key function for "faulting in"              *
  90 %*      imported things
  91 %*                                                                      *
  92 %************************************************************************
  93
  94 The main idea is this.  We are chugging along type-checking source code, and
  95 find a reference to GHC.Base.map.  We call tcLookupGlobal, which doesn't find
  96 it in the EPS type envt.  So it
  97         1 loads GHC.Base.hi
  98         2 gets the decl for GHC.Base.map
  99         3 typechecks it via tcIfaceDecl
 100         4 and adds it to the type env in the EPS
 101
 102 Note that DURING STEP 4, we may find that map's type mentions a type
 103 constructor that also
 104
 105 Notice that for imported things we read the current version from the EPS
 106 mutable variable.  This is important in situations like
 107         ...$(e1)...$(e2)...
 108 where the code that e1 expands to might import some defns that
 109 also turn out to be needed by the code that e2 expands to.
 110
 111 \begin{code}
 112 tcImportDecl :: Name -> TcM TyThing
 113 -- Entry point for source-code uses of importDecl
 114 tcImportDecl name
 115   = do  { traceIf (text "tcLookupGlobal" <+> ppr name)
 116         ; mb_thing <- initIfaceTcRn (importDecl name)
 117         ; case mb_thing of
 118             Succeeded thing -> return thing
 119             Failed err      -> failWithTc err }
 120
 121 importDecl :: Name -> IfM lcl (MaybeErr Message TyThing)
 122 -- Get the TyThing for this Name from an interface file
 123 importDecl name
 124   | Just thing <- wiredInNameTyThing_maybe name
 125         -- This case definitely happens for tuples, because we
 126         -- don't know how many of them we'll find
 127         -- It also now happens for all other wired in things.  We used
 128         -- to pre-populate the eps_PTE with other wired-in things, but
 129         -- we don't seem to do that any more.  I guess it keeps the PTE smaller?
 130   = do  { updateEps_ (\ eps -> eps { eps_PTE = extendTypeEnv (eps_PTE eps) thing })
 131         ; return (Succeeded thing) }
 132
 133   | otherwise
 134   = do  { traceIf nd_doc
 135
 136         -- Load the interface, which should populate the PTE
 137         ; mb_iface <- loadInterface nd_doc (nameModule name) ImportBySystem
 138         ; case mb_iface of {
 139                 Failed err_msg  -> return (Failed err_msg) ;
 140                 Succeeded iface -> do
 141
 142         -- Now look it up again; this time we should find it
 143         { eps <- getEps
 144         ; case lookupTypeEnv (eps_PTE eps) name of
 145             Just thing -> return (Succeeded thing)
 146             Nothing    -> return (Failed not_found_msg)
 147     }}}
 148   where
 149     nd_doc = ptext SLIT("Need decl for") <+> ppr name
 150     not_found_msg = hang (ptext SLIT("Can't find interface-file declaration for") <+> ppr (nameParent name))
 151                        2 (vcat [ptext SLIT("Probable cause: bug in .hi-boot file, or inconsistent .hi file"),
 152                                 ptext SLIT("Use -ddump-if-trace to get an idea of which file caused the error")])
 153 \end{code}
 154
 155 %************************************************************************
 156 %*                                                                      *
 157                 Type-checking a complete interface
 158 %*                                                                      *
 159 %************************************************************************
 160
 161 Suppose we discover we don't need to recompile.  Then we must type
 162 check the old interface file.  This is a bit different to the
 163 incremental type checking we do as we suck in interface files.  Instead
 164 we do things similarly as when we are typechecking source decls: we
 165 bring into scope the type envt for the interface all at once, using a
 166 knot.  Remember, the decls aren't necessarily in dependency order --
 167 and even if they were, the type decls might be mutually recursive.
 168
 169 \begin{code}
 170 typecheckIface :: HscEnv
 171                -> ModIface      -- Get the decls from here
 172                -> IO ModDetails
 173 typecheckIface hsc_env iface
 174   = initIfaceTc hsc_env iface $ \ tc_env_var -> do
 175         {       -- Get the right set of decls and rules.  If we are compiling without -O
 176                 -- we discard pragmas before typechecking, so that we don't "see"
 177                 -- information that we shouldn't.  From a versioning point of view
 178                 -- It's not actually *wrong* to do so, but in fact GHCi is unable
 179                 -- to handle unboxed tuples, so it must not see unfoldings.
 180           ignore_prags <- doptM Opt_IgnoreInterfacePragmas
 181
 182                 -- Load & typecheck the decls
 183         ; decl_things <- loadDecls ignore_prags (mi_decls iface)
 184
 185         ; let type_env = mkNameEnv decl_things
 186         ; writeMutVar tc_env_var type_env
 187
 188                 -- Now do those rules and instances
 189         ; let { rules | ignore_prags = []
 190                       | otherwise    = mi_rules iface
 191               ; dfuns = mi_insts iface
 192               }
 193         ; dfuns <- mapM tcIfaceInst dfuns
 194         ; rules <- mapM tcIfaceRule rules
 195
 196                 -- Finished
 197         ; return (ModDetails { md_types = type_env, md_insts = dfuns, md_rules = rules })
 198     }
 199 \end{code}
 200
 201
 202 %************************************************************************
 203 %*                                                                      *
 204                 Type and class declarations
 205 %*                                                                      *
 206 %************************************************************************
 207
 208 When typechecking a data type decl, we *lazily* (via forkM) typecheck
 209 the constructor argument types.  This is in the hope that we may never
 210 poke on those argument types, and hence may never need to load the
 211 interface files for types mentioned in the arg types.
 212
 213 E.g.
 214         data Foo.S = MkS Baz.T
 215 Mabye we can get away without even loading the interface for Baz!
 216
 217 This is not just a performance thing.  Suppose we have
 218         data Foo.S = MkS Baz.T
 219         data Baz.T = MkT Foo.S
 220 (in different interface files, of course).
 221 Now, first we load and typecheck Foo.S, and add it to the type envt.
 222 If we do explore MkS's argument, we'll load and typecheck Baz.T.
 223 If we explore MkT's argument we'll find Foo.S already in the envt.
 224
 225 If we typechecked constructor args eagerly, when loading Foo.S we'd try to
 226 typecheck the type Baz.T.  So we'd fault in Baz.T... and then need Foo.S...
 227 which isn't done yet.
 228
 229 All very cunning. However, there is a rather subtle gotcha which bit
 230 me when developing this stuff.  When we typecheck the decl for S, we
 231 extend the type envt with S, MkS, and all its implicit Ids.  Suppose
 232 (a bug, but it happened) that the list of implicit Ids depended in
 233 turn on the constructor arg types.  Then the following sequence of
 234 events takes place:
 235         * we build a thunk <t> for the constructor arg tys
 236         * we build a thunk for the extended type environment (depends on <t>)
 237         * we write the extended type envt into the global EPS mutvar
 238
 239 Now we look something up in the type envt
 240         * that pulls on <t>
 241         * which reads the global type envt out of the global EPS mutvar
 242         * but that depends in turn on <t>
 243
 244 It's subtle, because, it'd work fine if we typechecked the constructor args
 245 eagerly -- they don't need the extended type envt.  They just get the extended
 246 type envt by accident, because they look at it later.
 247
 248 What this means is that the implicitTyThings MUST NOT DEPEND on any of
 249 the forkM stuff.
 250
 251
 252 \begin{code}
 253 tcIfaceDecl :: IfaceDecl -> IfL TyThing
 254
 255 tcIfaceDecl (IfaceId {ifName = occ_name, ifType = iface_type, ifIdInfo = info})
 256   = do  { name <- lookupIfaceTop occ_name
 257         ; ty <- tcIfaceType iface_type
 258         ; info <- tcIdInfo name ty info
 259         ; return (AnId (mkVanillaGlobal name ty info)) }
 260
 261 tcIfaceDecl (IfaceData {ifName = occ_name,
 262                         ifTyVars = tv_bndrs,
 263                         ifCons = rdr_cons,
 264                         ifVrcs = arg_vrcs, ifRec = is_rec,
 265                         ifGeneric = want_generic })
 266   = do  { tc_name <- lookupIfaceTop occ_name
 267         ; bindIfaceTyVars tv_bndrs $ \ tyvars -> do
 268
 269         { tycon <- fixM ( \ tycon -> do
 270             { cons  <- tcIfaceDataCons tycon tyvars rdr_cons
 271             ; tycon <- buildAlgTyCon tc_name tyvars cons
 272                             arg_vrcs is_rec want_generic
 273             ; return tycon
 274             })
 275         ; traceIf (text "tcIfaceDecl4" <+> ppr tycon)
 276         ; return (ATyCon tycon)
 277     }}
 278
 279 tcIfaceDecl (IfaceSyn {ifName = occ_name, ifTyVars = tv_bndrs,
 280                        ifSynRhs = rdr_rhs_ty, ifVrcs = arg_vrcs})
 281    = bindIfaceTyVars tv_bndrs $ \ tyvars -> do
 282      { tc_name <- lookupIfaceTop occ_name
 283      ; rhs_ty <- tcIfaceType rdr_rhs_ty
 284      ; return (ATyCon (buildSynTyCon tc_name tyvars rhs_ty arg_vrcs))
 285      }
 286
 287 tcIfaceDecl (IfaceClass {ifCtxt = rdr_ctxt, ifName = occ_name, ifTyVars = tv_bndrs,
 288                          ifFDs = rdr_fds, ifSigs = rdr_sigs,
 289                          ifVrcs = tc_vrcs, ifRec = tc_isrec })
 290   = bindIfaceTyVars tv_bndrs $ \ tyvars -> do
 291     { cls_name <- lookupIfaceTop occ_name
 292     ; ctxt <- tcIfaceCtxt rdr_ctxt
 293     ; sigs <- mappM tc_sig rdr_sigs
 294     ; fds  <- mappM tc_fd rdr_fds
 295     ; cls  <- buildClass cls_name tyvars ctxt fds sigs tc_isrec tc_vrcs
 296     ; return (AClass cls) }
 297   where
 298    tc_sig (IfaceClassOp occ dm rdr_ty)
 299      = do { op_name <- lookupIfaceTop occ
 300           ; op_ty   <- forkM (mk_doc op_name rdr_ty) (tcIfaceType rdr_ty)
 301                 -- Must be done lazily for just the same reason as the
 302                 -- context of a data decl: the type sig might mention the
 303                 -- class being defined
 304           ; return (op_name, dm, op_ty) }
 305
 306    mk_doc op_name op_ty = ptext SLIT("Class op") <+> sep [ppr op_name, ppr op_ty]
 307
 308    tc_fd (tvs1, tvs2) = do { tvs1' <- mappM tcIfaceTyVar tvs1
 309                            ; tvs2' <- mappM tcIfaceTyVar tvs2
 310                            ; return (tvs1', tvs2') }
 311
 312 tcIfaceDecl (IfaceForeign {ifName = rdr_name, ifExtName = ext_name})
 313   = do  { name <- lookupIfaceTop rdr_name
 314         ; return (ATyCon (mkForeignTyCon name ext_name
 315                                          liftedTypeKind 0 [])) }
 316
 317 tcIfaceDataCons tycon tc_tyvars if_cons
 318   = case if_cons of
 319         IfAbstractTyCon          -> return mkAbstractTyConRhs
 320         IfDataTyCon mb_ctxt cons -> do  { mb_theta <- tc_ctxt mb_ctxt
 321                                         ; data_cons <- mappM tc_con_decl cons
 322                                         ; return (mkDataTyConRhs mb_theta data_cons) }
 323         IfNewTyCon con           -> do  { data_con <- tc_con_decl con
 324                                         ; return (mkNewTyConRhs tycon data_con) }
 325   where
 326     tc_ctxt Nothing     = return Nothing
 327     tc_ctxt (Just ctxt) = do { theta <- tcIfaceCtxt ctxt; return (Just theta) }
 328
 329     tc_con_decl (IfVanillaCon { ifConOcc = occ, ifConInfix = is_infix, ifConArgTys = args,
 330                                 ifConStricts = stricts, ifConFields = field_lbls})
 331       = do { name  <- lookupIfaceTop occ
 332                 -- Read the argument types, but lazily to avoid faulting in
 333                 -- the component types unless they are really needed
 334            ; arg_tys <- forkM (mk_doc name) (mappM tcIfaceType args)
 335            ; lbl_names <- mappM lookupIfaceTop field_lbls
 336            ; buildDataCon name is_infix True {- Vanilla -}
 337                           stricts lbl_names
 338                           tc_tyvars [] arg_tys tycon
 339                           (mkTyVarTys tc_tyvars)        -- Vanilla => we know result tys
 340            }
 341
 342     tc_con_decl (IfGadtCon {    ifConTyVars = con_tvs,
 343                                 ifConOcc = occ, ifConCtxt = ctxt,
 344                                 ifConArgTys = args, ifConResTys = ress,
 345                                 ifConStricts = stricts})
 346       = bindIfaceTyVars con_tvs $ \ con_tyvars -> do
 347         { name  <- lookupIfaceTop occ
 348         ; theta <- tcIfaceCtxt ctxt     -- Laziness seems not worth the bother here
 349                 -- At one stage I thought that this context checking *had*
 350                 -- to be lazy, because of possible mutual recursion between the
 351                 -- type and the classe:
 352                 -- E.g.
 353                 --      class Real a where { toRat :: a -> Ratio Integer }
 354                 --      data (Real a) => Ratio a = ...
 355                 -- But now I think that the laziness in checking class ops breaks
 356                 -- the loop, so no laziness needed
 357
 358         -- Read the argument types, but lazily to avoid faulting in
 359         -- the component types unless they are really needed
 360         ; arg_tys <- forkM (mk_doc name) (mappM tcIfaceType args)
 361         ; res_tys <- forkM (mk_doc name) (mappM tcIfaceType ress)
 362
 363         ; buildDataCon name False {- Not infix -} False {- Not vanilla -}
 364                        stricts [{- No fields -}]
 365                        con_tyvars theta
 366                        arg_tys tycon res_tys
 367         }
 368     mk_doc con_name = ptext SLIT("Constructor") <+> ppr con_name
 369 \end{code}
 370
 371
 372 %************************************************************************
 373 %*                                                                      *
 374                 Instances
 375 %*                                                                      *
 376 %************************************************************************
 377
 378 The gating story for instance declarations
 379 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 380 When we are looking for a dict (C t1..tn), we slurp in instance decls for
 381 C that
 382         mention at least one of the type constructors
 383         at the roots of t1..tn
 384
 385 Why "at least one" rather than "all"?  Because functional dependencies
 386 complicate the picture.  Consider
 387         class C a b | a->b where ...
 388         instance C Foo Baz where ...
 389 Here, the gates are really only C and Foo, *not* Baz.
 390 That is, if C and Foo are visible, even if Baz isn't, we must
 391 slurp the decl, even if Baz is thus far completely unknown to the
 392 system.
 393
 394 Why "roots of the types"?  Reason is overlap.  For example, suppose there
 395 are interfaces in the pool for
 396   (a)   C Int b
 397  (b)    C a [b]
 398   (c)   C a [T]
 399 Then, if we are trying to resolve (C Int x), we need (a)
 400 if we are trying to resolve (C x [y]), we need *both* (b) and (c),
 401 even though T is not involved yet, so that we spot the overlap.
 402
 403
 404 NOTE: if you use an instance decl with NO type constructors
 405         instance C a where ...
 406 and look up an Inst that only has type variables such as (C (n o))
 407 then GHC won't necessarily suck in the instances that overlap with this.
 408
 409
 410 \begin{code}
 411 loadImportedInsts :: Class -> [Type] -> TcM PackageInstEnv
 412 loadImportedInsts cls tys
 413   = do  {       -- Get interfaces for wired-in things, such as Integer
 414                 -- Any non-wired-in tycons will already be loaded, else
 415                 -- we couldn't have them in the Type
 416         ; this_mod <- getModule
 417         ; let { (cls_gate, tc_gates) = predInstGates cls tys
 418               ; imp_wi n = isWiredInName n && this_mod /= nameModule n
 419               ; wired_tcs = filter imp_wi tc_gates }
 420                         -- Wired-in tycons not from this module.  The "this-module"
 421                         -- test bites only when compiling Base etc, because loadHomeInterface
 422                         -- barfs if it's asked to load a non-existent interface
 423         ; if null wired_tcs then returnM ()
 424           else initIfaceTcRn (mapM_ (loadHomeInterface wired_doc) wired_tcs)
 425
 426                 -- Now suck in the relevant instances
 427         ; iface_insts <- updateEps (selectInsts cls_gate tc_gates)
 428
 429         -- Empty => finish up rapidly, without writing to eps
 430         ; if null iface_insts then
 431                 do { eps <- getEps; return (eps_inst_env eps) }
 432           else do
 433         { traceIf (sep [ptext SLIT("Importing instances for") <+> pprClassPred cls tys,
 434                         nest 2 (vcat [ppr i | (_,_,i) <- iface_insts])])
 435
 436         -- Typecheck the new instances
 437         ; dfuns <- initIfaceTcRn (mappM tc_inst iface_insts)
 438
 439         -- And put them in the package instance environment
 440         ; updateEps ( \ eps ->
 441             let
 442                 inst_env' = extendInstEnvList (eps_inst_env eps) dfuns
 443             in
 444             (eps { eps_inst_env = inst_env' }, inst_env')
 445         )}}
 446   where
 447     wired_doc = ptext SLIT("Need home inteface for wired-in thing")
 448
 449 tc_inst (mod, loc, inst) = initIfaceLcl mod full_loc (tcIfaceInst inst)
 450   where
 451     full_loc = loc $$ (nest 2 (ptext SLIT("instance decl") <+> ppr inst))
 452
 453 tcIfaceInst :: IfaceInst -> IfL DFunId
 454 tcIfaceInst (IfaceInst { ifDFun = dfun_occ })
 455   = tcIfaceExtId (LocalTop dfun_occ)
 456
 457 selectInsts :: Name -> [Name] -> ExternalPackageState
 458             -> (ExternalPackageState, [(Module, SDoc, IfaceInst)])
 459 selectInsts cls tycons eps
 460   = (eps { eps_insts = insts', eps_stats = stats' }, iface_insts)
 461   where
 462     insts  = eps_insts eps
 463     stats  = eps_stats eps
 464     stats' = stats { n_insts_out = n_insts_out stats + length iface_insts }
 465
 466     (insts', iface_insts)
 467         = case lookupNameEnv insts cls of {
 468                 Nothing -> (insts, []) ;
 469                 Just gated_insts ->
 470
 471           case choose1 gated_insts  of {
 472             (_, []) -> (insts, []) ;    -- None picked
 473             (gated_insts', iface_insts') ->
 474
 475           (extendNameEnv insts cls gated_insts', iface_insts') }}
 476
 477     choose1 gated_insts
 478         | null tycons                   -- Bizarre special case of C (a b); then there are no tycons
 479         = ([], map snd gated_insts)     -- Just grab all the instances, no real alternative
 480         | otherwise                     -- Normal case
 481         = foldl choose2 ([],[]) gated_insts
 482
 483         -- Reverses the gated decls, but that doesn't matter
 484     choose2 (gis, decls) (gates, decl)
 485         |  null gates   -- Happens when we have 'instance T a where ...'
 486         || any (`elem` tycons) gates = (gis,               decl:decls)
 487         | otherwise                  = ((gates,decl) : gis, decls)
 488 \end{code}
 489
 490 %************************************************************************
 491 %*                                                                      *
 492                 Rules
 493 %*                                                                      *
 494 %************************************************************************
 495
 496 We move a IfaceRule from eps_rules to eps_rule_base when all its LHS free vars
 497 are in the type environment.  However, remember that typechecking a Rule may
 498 (as a side effect) augment the type envt, and so we may need to iterate the process.
 499
 500 \begin{code}
 501 loadImportedRules :: HscEnv -> ModGuts -> IO [IdCoreRule]
 502 -- Returns just the new rules added
 503 loadImportedRules hsc_env guts
 504   = initIfaceRules hsc_env guts $ do
 505         { -- Get new rules
 506           if_rules <- updateEps selectRules
 507
 508         ; traceIf (ptext SLIT("Importing rules:") <+> vcat [ppr r | (_,_,r) <- if_rules])
 509
 510         ; core_rules <- mapM tc_rule if_rules
 511
 512         -- Debug print
 513         ; traceIf (ptext SLIT("Imported rules:") <+> pprIdRules core_rules)
 514
 515         -- Update the rule base and return it
 516         ; updateEps (\ eps ->
 517             let { new_rule_base = extendRuleBaseList (eps_rule_base eps) core_rules }
 518             in (eps { eps_rule_base = new_rule_base }, new_rule_base)
 519           )
 520
 521         -- Strictly speaking, at this point we should go round again, since
 522         -- typechecking one set of rules may bring in new things which enable
 523         -- some more rules to come in.  But we call loadImportedRules several
 524         -- times anyway, so I'm going to be lazy and ignore this.
 525         ; return core_rules
 526     }
 527
 528 tc_rule (mod, loc, rule) = initIfaceLcl mod full_loc (tcIfaceRule rule)
 529   where
 530     full_loc = loc $$ (nest 2 (ptext SLIT("rule") <+> ppr rule))
 531
 532 selectRules :: ExternalPackageState -> (ExternalPackageState, [(Module, SDoc, IfaceRule)])
 533 -- Not terribly efficient.  Look at each rule in the pool to see if
 534 -- all its gates are in the type env.  If so, take it out of the pool.
 535 -- If not, trim its gates for next time.
 536 selectRules eps
 537   = (eps { eps_rules = rules', eps_stats = stats' }, if_rules)
 538   where
 539     stats    = eps_stats eps
 540     rules    = eps_rules eps
 541     type_env = eps_PTE eps
 542     stats'   = stats { n_rules_out = n_rules_out stats + length if_rules }
 543
 544     (rules', if_rules) = foldl do_one ([], []) rules
 545
 546     do_one (pool, if_rules) (gates, rule)
 547         | null gates' = (pool, rule:if_rules)
 548         | otherwise   = ((gates',rule) : pool, if_rules)
 549         where
 550           gates' = filter (not . (`elemNameEnv` type_env)) gates
 551
 552
 553 tcIfaceRule :: IfaceRule -> IfL IdCoreRule
 554 tcIfaceRule (IfaceRule {ifRuleName = rule_name, ifActivation = act, ifRuleBndrs = bndrs,
 555                         ifRuleHead = fn_rdr, ifRuleArgs = args, ifRuleRhs = rhs })
 556   = bindIfaceBndrs bndrs        $ \ bndrs' ->
 557     do  { fn <- tcIfaceExtId fn_rdr
 558         ; args' <- mappM tcIfaceExpr args
 559         ; rhs'  <- tcIfaceExpr rhs
 560         ; let rule = Rule rule_name act bndrs' args' rhs'
 561         ; returnM (IdCoreRule fn (isOrphNm fn_rdr) rule) }
 562   where
 563
 564 tcIfaceRule (IfaceBuiltinRule fn_rdr core_rule)
 565   = do  { fn <- tcIfaceExtId fn_rdr
 566         ; returnM (IdCoreRule fn (isOrphNm fn_rdr) core_rule) }
 567
 568 isOrphNm :: IfaceExtName -> Bool
 569 -- An orphan name comes from somewhere other than this module,
 570 -- so it has a non-local name
 571 isOrphNm name = not (isLocalIfaceExtName name)
 572 \end{code}
 573
 574
 575 %************************************************************************
 576 %*                                                                      *
 577                         Types
 578 %*                                                                      *
 579 %************************************************************************
 580
 581 \begin{code}
 582 tcIfaceType :: IfaceType -> IfL Type
 583 tcIfaceType (IfaceTyVar n)        = do { tv <- tcIfaceTyVar n; return (TyVarTy tv) }
 584 tcIfaceType (IfaceAppTy t1 t2)    = do { t1' <- tcIfaceType t1; t2' <- tcIfaceType t2; return (AppTy t1' t2') }
 585 tcIfaceType (IfaceFunTy t1 t2)    = do { t1' <- tcIfaceType t1; t2' <- tcIfaceType t2; return (FunTy t1' t2') }
 586 tcIfaceType (IfaceTyConApp tc ts) = do { tc' <- tcIfaceTyCon tc; ts' <- tcIfaceTypes ts; return (mkIfTcApp tc' ts') }
 587 tcIfaceType (IfaceForAllTy tv t)  = bindIfaceTyVar tv $ \ tv' -> do { t' <- tcIfaceType t; return (ForAllTy tv' t') }
 588 tcIfaceType (IfacePredTy st)      = do { st' <- tcIfacePredType st; return (PredTy st') }
 589
 590 tcIfaceTypes tys = mapM tcIfaceType tys
 591
 592 mkIfTcApp :: TyCon -> [Type] -> Type
 593 -- In interface files we retain type synonyms (for brevity and better error
 594 -- messages), but type synonyms can expand into non-hoisted types (ones with
 595 -- foralls to the right of an arrow), so we must be careful to hoist them here.
 596 -- This hack should go away when we get rid of hoisting.
 597 mkIfTcApp tc tys
 598   | isSynTyCon tc = hoistForAllTys (mkSynTy tc tys)
 599   | otherwise     = mkTyConApp tc tys
 600
 601 -----------------------------------------
 602 tcIfacePredType :: IfacePredType -> IfL PredType
 603 tcIfacePredType (IfaceClassP cls ts) = do { cls' <- tcIfaceClass cls; ts' <- tcIfaceTypes ts; return (ClassP cls' ts') }
 604 tcIfacePredType (IfaceIParam ip t)   = do { ip' <- newIPName ip; t' <- tcIfaceType t; return (IParam ip' t') }
 605
 606 -----------------------------------------
 607 tcIfaceCtxt :: IfaceContext -> IfL ThetaType
 608 tcIfaceCtxt sts = mappM tcIfacePredType sts
 609 \end{code}
 610
 611
 612 %************************************************************************
 613 %*                                                                      *
 614                         Core
 615 %*                                                                      *
 616 %************************************************************************
 617
 618 \begin{code}
 619 tcIfaceExpr :: IfaceExpr -> IfL CoreExpr
 620 tcIfaceExpr (IfaceType ty)
 621   = tcIfaceType ty              `thenM` \ ty' ->
 622     returnM (Type ty')
 623
 624 tcIfaceExpr (IfaceLcl name)
 625   = tcIfaceLclId name   `thenM` \ id ->
 626     returnM (Var id)
 627
 628 tcIfaceExpr (IfaceExt gbl)
 629   = tcIfaceExtId gbl    `thenM` \ id ->
 630     returnM (Var id)
 631
 632 tcIfaceExpr (IfaceLit lit)
 633   = returnM (Lit lit)
 634
 635 tcIfaceExpr (IfaceFCall cc ty)
 636   = tcIfaceType ty      `thenM` \ ty' ->
 637     newUnique           `thenM` \ u ->
 638     returnM (Var (mkFCallId u cc ty'))
 639
 640 tcIfaceExpr (IfaceTuple boxity args)
 641   = mappM tcIfaceExpr args      `thenM` \ args' ->
 642     let
 643         -- Put the missing type arguments back in
 644         con_args = map (Type . exprType) args' ++ args'
 645     in
 646     returnM (mkApps (Var con_id) con_args)
 647   where
 648     arity = length args
 649     con_id = dataConWorkId (tupleCon boxity arity)
 650
 651
 652 tcIfaceExpr (IfaceLam bndr body)
 653   = bindIfaceBndr bndr          $ \ bndr' ->
 654     tcIfaceExpr body            `thenM` \ body' ->
 655     returnM (Lam bndr' body')
 656
 657 tcIfaceExpr (IfaceApp fun arg)
 658   = tcIfaceExpr fun             `thenM` \ fun' ->
 659     tcIfaceExpr arg             `thenM` \ arg' ->
 660     returnM (App fun' arg')
 661
 662 tcIfaceExpr (IfaceCase scrut case_bndr ty alts)
 663   = tcIfaceExpr scrut           `thenM` \ scrut' ->
 664     newIfaceName case_bndr      `thenM` \ case_bndr_name ->
 665     let
 666         scrut_ty   = exprType scrut'
 667         case_bndr' = mkLocalId case_bndr_name scrut_ty
 668         tc_app     = splitTyConApp scrut_ty
 669                 -- NB: Won't always succeed (polymoprhic case)
 670                 --     but won't be demanded in those cases
 671                 -- NB: not tcSplitTyConApp; we are looking at Core here
 672                 --     look through non-rec newtypes to find the tycon that
 673                 --     corresponds to the datacon in this case alternative
 674     in
 675     extendIfaceIdEnv [case_bndr']       $
 676     mappM (tcIfaceAlt tc_app) alts      `thenM` \ alts' ->
 677     tcIfaceType ty              `thenM` \ ty' ->
 678     returnM (Case scrut' case_bndr' ty' alts')
 679
 680 tcIfaceExpr (IfaceLet (IfaceNonRec bndr rhs) body)
 681   = tcIfaceExpr rhs             `thenM` \ rhs' ->
 682     bindIfaceId bndr            $ \ bndr' ->
 683     tcIfaceExpr body            `thenM` \ body' ->
 684     returnM (Let (NonRec bndr' rhs') body')
 685
 686 tcIfaceExpr (IfaceLet (IfaceRec pairs) body)
 687   = bindIfaceIds bndrs          $ \ bndrs' ->
 688     mappM tcIfaceExpr rhss      `thenM` \ rhss' ->
 689     tcIfaceExpr body            `thenM` \ body' ->
 690     returnM (Let (Rec (bndrs' `zip` rhss')) body')
 691   where
 692     (bndrs, rhss) = unzip pairs
 693
 694 tcIfaceExpr (IfaceNote note expr)
 695   = tcIfaceExpr expr            `thenM` \ expr' ->
 696     case note of
 697         IfaceCoerce to_ty -> tcIfaceType to_ty  `thenM` \ to_ty' ->
 698                              returnM (Note (Coerce to_ty'
 699                                                    (exprType expr')) expr')
 700         IfaceInlineCall   -> returnM (Note InlineCall expr')
 701         IfaceInlineMe     -> returnM (Note InlineMe   expr')
 702         IfaceSCC cc       -> returnM (Note (SCC cc)   expr')
 703         IfaceCoreNote n   -> returnM (Note (CoreNote n) expr')
 704
 705 -------------------------
 706 tcIfaceAlt _ (IfaceDefault, names, rhs)
 707   = ASSERT( null names )
 708     tcIfaceExpr rhs             `thenM` \ rhs' ->
 709     returnM (DEFAULT, [], rhs')
 710
 711 tcIfaceAlt _ (IfaceLitAlt lit, names, rhs)
 712   = ASSERT( null names )
 713     tcIfaceExpr rhs             `thenM` \ rhs' ->
 714     returnM (LitAlt lit, [], rhs')
 715
 716 -- A case alternative is made quite a bit more complicated
 717 -- by the fact that we omit type annotations because we can
 718 -- work them out.  True enough, but its not that easy!
 719 tcIfaceAlt (tycon, inst_tys) (IfaceDataAlt data_occ, arg_occs, rhs)
 720   = do  { let tycon_mod = nameModule (tyConName tycon)
 721         ; con <- tcIfaceDataCon (ExtPkg tycon_mod data_occ)
 722         ; ASSERT2( con `elem` tyConDataCons tycon,
 723                    ppr con $$ ppr tycon $$ ppr (tyConDataCons tycon) )
 724
 725           if isVanillaDataCon con then
 726                 tcVanillaAlt con inst_tys arg_occs rhs
 727           else
 728     do  {       -- General case
 729           arg_names <- newIfaceNames arg_occs
 730         ; let   tyvars   = [ mkTyVar name (tyVarKind tv)
 731                            | (name,tv) <- arg_names `zip` dataConTyVars con]
 732                 arg_tys  = dataConArgTys con (mkTyVarTys tyvars)
 733                 id_names = dropList tyvars arg_names
 734                 arg_ids  = ASSERT2( equalLength id_names arg_tys,
 735                                     ppr (con, arg_names, rhs) $$ ppr tyvars $$ ppr arg_tys )
 736                            zipWith mkLocalId id_names arg_tys
 737
 738         ; rhs' <- extendIfaceTyVarEnv tyvars    $
 739                   extendIfaceIdEnv arg_ids      $
 740                   tcIfaceExpr rhs
 741         ; return (DataAlt con, tyvars ++ arg_ids, rhs') }}
 742
 743 tcIfaceAlt (tycon, inst_tys) (IfaceTupleAlt boxity, arg_occs, rhs)
 744   = ASSERT( isTupleTyCon tycon )
 745     do  { let [data_con] = tyConDataCons tycon
 746         ; tcVanillaAlt data_con inst_tys arg_occs rhs }
 747
 748 tcVanillaAlt data_con inst_tys arg_occs rhs
 749   = do  { arg_names <- newIfaceNames arg_occs
 750         ; let arg_tys = dataConArgTys data_con inst_tys
 751         ; let arg_ids = ASSERT2( equalLength arg_names arg_tys,
 752                                  ppr data_con <+> ppr inst_tys <+> ppr arg_occs $$ ppr rhs )
 753                         zipWith mkLocalId arg_names arg_tys
 754         ; rhs' <- extendIfaceIdEnv arg_ids (tcIfaceExpr rhs)
 755         ; returnM (DataAlt data_con, arg_ids, rhs') }
 756 \end{code}
 757
 758
 759 \begin{code}
 760 tcExtCoreBindings :: [IfaceBinding] -> IfL [CoreBind]   -- Used for external core
 761 tcExtCoreBindings []     = return []
 762 tcExtCoreBindings (b:bs) = do_one b (tcExtCoreBindings bs)
 763
 764 do_one :: IfaceBinding -> IfL [CoreBind] -> IfL [CoreBind]
 765 do_one (IfaceNonRec bndr rhs) thing_inside
 766   = do  { rhs' <- tcIfaceExpr rhs
 767         ; bndr' <- newExtCoreBndr bndr
 768         ; extendIfaceIdEnv [bndr'] $ do
 769         { core_binds <- thing_inside
 770         ; return (NonRec bndr' rhs' : core_binds) }}
 771
 772 do_one (IfaceRec pairs) thing_inside
 773   = do  { bndrs' <- mappM newExtCoreBndr bndrs
 774         ; extendIfaceIdEnv bndrs' $ do
 775         { rhss' <- mappM tcIfaceExpr rhss
 776         ; core_binds <- thing_inside
 777         ; return (Rec (bndrs' `zip` rhss') : core_binds) }}
 778   where
 779     (bndrs,rhss) = unzip pairs
 780 \end{code}
 781
 782
 783 %************************************************************************
 784 %*                                                                      *
 785                 IdInfo
 786 %*                                                                      *
 787 %************************************************************************
 788
 789 \begin{code}
 790 tcIdInfo :: Name -> Type -> IfaceIdInfo -> IfL IdInfo
 791 tcIdInfo name ty NoInfo         = return vanillaIdInfo
 792 tcIdInfo name ty (HasInfo info) = foldlM tcPrag init_info info
 793   where
 794     -- Set the CgInfo to something sensible but uninformative before
 795     -- we start; default assumption is that it has CAFs
 796     init_info = vanillaIdInfo
 797
 798     tcPrag info HsNoCafRefs         = returnM (info `setCafInfo`   NoCafRefs)
 799     tcPrag info (HsArity arity)     = returnM (info `setArityInfo` arity)
 800     tcPrag info (HsStrictness str)  = returnM (info `setAllStrictnessInfo` Just str)
 801
 802         -- The next two are lazy, so they don't transitively suck stuff in
 803     tcPrag info (HsWorker nm arity) = tcWorkerInfo ty info nm arity
 804     tcPrag info (HsUnfold inline_prag expr)
 805         = tcPragExpr name expr  `thenM` \ maybe_expr' ->
 806           let
 807                 -- maybe_expr' doesn't get looked at if the unfolding
 808                 -- is never inspected; so the typecheck doesn't even happen
 809                 unfold_info = case maybe_expr' of
 810                                 Nothing    -> noUnfolding
 811                                 Just expr' -> mkTopUnfolding expr'
 812           in
 813           returnM (info `setUnfoldingInfoLazily` unfold_info
 814                         `setInlinePragInfo`      inline_prag)
 815 \end{code}
 816
 817 \begin{code}
 818 tcWorkerInfo ty info wkr arity
 819   = do  { mb_wkr_id <- forkM_maybe doc (tcIfaceExtId wkr)
 820
 821         -- We return without testing maybe_wkr_id, but as soon as info is
 822         -- looked at we will test it.  That's ok, because its outside the
 823         -- knot; and there seems no big reason to further defer the
 824         -- tcIfaceId lookup.  (Contrast with tcPragExpr, where postponing walking
 825         -- over the unfolding until it's actually used does seem worth while.)
 826         ; us <- newUniqueSupply
 827
 828         ; returnM (case mb_wkr_id of
 829                      Nothing     -> info
 830                      Just wkr_id -> add_wkr_info us wkr_id info) }
 831   where
 832     doc = text "Worker for" <+> ppr wkr
 833     add_wkr_info us wkr_id info
 834         = info `setUnfoldingInfoLazily`  mk_unfolding us wkr_id
 835                `setWorkerInfo`           HasWorker wkr_id arity
 836
 837     mk_unfolding us wkr_id = mkTopUnfolding (initUs_ us (mkWrapper ty strict_sig) wkr_id)
 838
 839         -- We are relying here on strictness info always appearing
 840         -- before worker info,  fingers crossed ....
 841     strict_sig = case newStrictnessInfo info of
 842                    Just sig -> sig
 843                    Nothing  -> pprPanic "Worker info but no strictness for" (ppr wkr)
 844 \end{code}
 845
 846 For unfoldings we try to do the job lazily, so that we never type check
 847 an unfolding that isn't going to be looked at.
 848
 849 \begin{code}
 850 tcPragExpr :: Name -> IfaceExpr -> IfL (Maybe CoreExpr)
 851 tcPragExpr name expr
 852   = forkM_maybe doc $
 853     tcIfaceExpr expr            `thenM` \ core_expr' ->
 854
 855                 -- Check for type consistency in the unfolding
 856     ifOptM Opt_DoCoreLinting (
 857         get_in_scope_ids                        `thenM` \ in_scope ->
 858         case lintUnfolding noSrcLoc in_scope core_expr' of
 859           Nothing       -> returnM ()
 860           Just fail_msg -> pprPanic "Iface Lint failure" (doc <+> fail_msg)
 861     )                           `thenM_`
 862
 863    returnM core_expr'
 864   where
 865     doc = text "Unfolding of" <+> ppr name
 866     get_in_scope_ids    -- Urgh; but just for linting
 867         = setLclEnv () $
 868           do    { env <- getGblEnv
 869                 ; case if_rec_types env of {
 870                           Nothing -> return [] ;
 871                           Just (_, get_env) -> do
 872                 { type_env <- get_env
 873                 ; return (typeEnvIds type_env) }}}
 874 \end{code}
 875
 876
 877
 878 %************************************************************************
 879 %*                                                                      *
 880                 Getting from Names to TyThings
 881 %*                                                                      *
 882 %************************************************************************
 883
 884 \begin{code}
 885 tcIfaceGlobal :: Name -> IfL TyThing
 886 tcIfaceGlobal name
 887   = do  { (eps,hpt) <- getEpsAndHpt
 888         ; case lookupType hpt (eps_PTE eps) name of {
 889             Just thing -> return thing ;
 890             Nothing    -> do
 891
 892         { env <- getGblEnv
 893         ; case if_rec_types env of {
 894             Just (mod, get_type_env)
 895                 | nameIsLocalOrFrom mod name
 896                 -> do           -- It's defined in the module being compiled
 897                 { type_env <- setLclEnv () get_type_env         -- yuk
 898                 ; case lookupNameEnv type_env name of
 899                         Just thing -> return thing
 900                         Nothing    -> pprPanic "tcIfaceGlobal (local): not found:"
 901                                                 (ppr name $$ ppr type_env) }
 902
 903           ; other -> do
 904
 905         { mb_thing <- importDecl name   -- It's imported; go get it
 906         ; case mb_thing of
 907             Failed err      -> failIfM err
 908             Succeeded thing -> return thing
 909     }}}}}
 910
 911 tcIfaceTyCon :: IfaceTyCon -> IfL TyCon
 912 tcIfaceTyCon IfaceIntTc  = return intTyCon
 913 tcIfaceTyCon IfaceBoolTc = return boolTyCon
 914 tcIfaceTyCon IfaceCharTc = return charTyCon
 915 tcIfaceTyCon IfaceListTc = return listTyCon
 916 tcIfaceTyCon IfacePArrTc = return parrTyCon
 917 tcIfaceTyCon (IfaceTupTc bx ar) = return (tupleTyCon bx ar)
 918 tcIfaceTyCon (IfaceTc ext_nm) = do { name <- lookupIfaceExt ext_nm
 919                                    ; thing <- tcIfaceGlobal name
 920                                    ; return (tyThingTyCon thing) }
 921
 922 tcIfaceClass :: IfaceExtName -> IfL Class
 923 tcIfaceClass rdr_name = do { name <- lookupIfaceExt rdr_name
 924                            ; thing <- tcIfaceGlobal name
 925                            ; return (tyThingClass thing) }
 926
 927 tcIfaceDataCon :: IfaceExtName -> IfL DataCon
 928 tcIfaceDataCon gbl = do { name <- lookupIfaceExt gbl
 929                         ; thing <- tcIfaceGlobal name
 930                         ; case thing of
 931                                 ADataCon dc -> return dc
 932                                 other   -> pprPanic "tcIfaceExtDC" (ppr gbl $$ ppr name$$ ppr thing) }
 933
 934 tcIfaceExtId :: IfaceExtName -> IfL Id
 935 tcIfaceExtId gbl = do { name <- lookupIfaceExt gbl
 936                       ; thing <- tcIfaceGlobal name
 937                       ; case thing of
 938                           AnId id -> return id
 939                           other   -> pprPanic "tcIfaceExtId" (ppr gbl $$ ppr name$$ ppr thing) }
 940 \end{code}
 941
 942 %************************************************************************
 943 %*                                                                      *
 944                 Bindings
 945 %*                                                                      *
 946 %************************************************************************
 947
 948 \begin{code}
 949 bindIfaceBndr :: IfaceBndr -> (CoreBndr -> IfL a) -> IfL a
 950 bindIfaceBndr (IfaceIdBndr bndr) thing_inside
 951   = bindIfaceId bndr thing_inside
 952 bindIfaceBndr (IfaceTvBndr bndr) thing_inside
 953   = bindIfaceTyVar bndr thing_inside
 954
 955 bindIfaceBndrs :: [IfaceBndr] -> ([CoreBndr] -> IfL a) -> IfL a
 956 bindIfaceBndrs []     thing_inside = thing_inside []
 957 bindIfaceBndrs (b:bs) thing_inside
 958   = bindIfaceBndr b     $ \ b' ->
 959     bindIfaceBndrs bs   $ \ bs' ->
 960     thing_inside (b':bs')
 961
 962 -----------------------
 963 bindIfaceId :: (OccName, IfaceType) -> (Id -> IfL a) -> IfL a
 964 bindIfaceId (occ, ty) thing_inside
 965   = do  { name <- newIfaceName occ
 966         ; ty' <- tcIfaceType ty
 967         ; let { id = mkLocalId name ty' }
 968         ; extendIfaceIdEnv [id] (thing_inside id) }
 969
 970 bindIfaceIds :: [(OccName, IfaceType)] -> ([Id] -> IfL a) -> IfL a
 971 bindIfaceIds bndrs thing_inside
 972   = do  { names <- newIfaceNames occs
 973         ; tys' <- mappM tcIfaceType tys
 974         ; let { ids = zipWithEqual "tcCoreValBndr" mkLocalId names tys' }
 975         ; extendIfaceIdEnv ids (thing_inside ids) }
 976   where
 977     (occs,tys) = unzip bndrs
 978
 979
 980 -----------------------
 981 newExtCoreBndr :: (OccName, IfaceType) -> IfL Id
 982 newExtCoreBndr (occ, ty)
 983   = do  { mod <- getIfModule
 984         ; name <- newGlobalBinder mod occ Nothing noSrcLoc
 985         ; ty' <- tcIfaceType ty
 986         ; return (mkLocalId name ty') }
 987
 988 -----------------------
 989 bindIfaceTyVar :: IfaceTvBndr -> (TyVar -> IfL a) -> IfL a
 990 bindIfaceTyVar (occ,kind) thing_inside
 991   = do  { name <- newIfaceName occ
 992         ; let tyvar = mk_iface_tyvar name kind
 993         ; extendIfaceTyVarEnv [tyvar] (thing_inside tyvar) }
 994
 995 bindIfaceTyVars :: [IfaceTvBndr] -> ([TyVar] -> IfL a) -> IfL a
 996 bindIfaceTyVars bndrs thing_inside
 997   = do  { names <- newIfaceNames occs
 998         ; let tyvars = zipWith mk_iface_tyvar names kinds
 999         ; extendIfaceTyVarEnv tyvars (thing_inside tyvars) }
1000   where
1001     (occs,kinds) = unzip bndrs
1002
1003 mk_iface_tyvar name kind = mkTyVar name kind
1004 \end{code}
1005