ghc/compiler/iface/TcIface.lhs

   1 %
   2 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   3 %
   4 \section[TcIfaceSig]{Type checking of type signatures in interface files}
   5
   6 \begin{code}
   7 module TcIface (
   8         tcImportDecl, typecheckIface,
   9         tcIfaceKind, loadImportedInsts, loadImportedRules,
  10         tcExtCoreBindings
  11  ) where
  12 #include "HsVersions.h"
  13
  14 import IfaceSyn
  15 import LoadIface        ( loadHomeInterface, predInstGates )
  16 import IfaceEnv         ( lookupIfaceTop, newGlobalBinder, lookupOrig,
  17                           extendIfaceIdEnv, extendIfaceTyVarEnv, newIPName,
  18                           tcIfaceTyVar, tcIfaceTyCon, tcIfaceClass, tcIfaceExtId,
  19                           tcIfaceDataCon, tcIfaceLclId,
  20                           newIfaceName, newIfaceNames )
  21 import BuildTyCl        ( buildSynTyCon, buildAlgTyCon, buildDataCon, buildClass )
  22 import TcRnMonad
  23 import Type             ( Kind, openTypeKind, liftedTypeKind,
  24                           unliftedTypeKind, mkArrowKind, splitTyConApp,
  25                           mkTyVarTys, mkGenTyConApp, mkTyVarTys, ThetaType, pprClassPred )
  26 import TypeRep          ( Type(..), PredType(..) )
  27 import TyCon            ( TyCon, tyConName )
  28 import HscTypes         ( ExternalPackageState(..), PackageInstEnv, PackageRuleBase,
  29                           HscEnv, TyThing(..), implicitTyThings, typeEnvIds,
  30                           ModIface(..), ModDetails(..), InstPool, ModGuts,
  31                           TypeEnv, mkTypeEnv, extendTypeEnvList, lookupTypeEnv,
  32                           DeclPool, RulePool, Pool(..), Gated, addRuleToPool )
  33 import InstEnv          ( extendInstEnv )
  34 import CoreSyn
  35 import PprCore          ( pprIdRules )
  36 import Rules            ( extendRuleBaseList )
  37 import CoreUtils        ( exprType )
  38 import CoreUnfold
  39 import CoreLint         ( lintUnfolding )
  40 import WorkWrap         ( mkWrapper )
  41 import InstEnv          ( DFunId )
  42 import Id               ( Id, mkVanillaGlobal, mkLocalId )
  43 import MkId             ( mkFCallId )
  44 import IdInfo           ( IdInfo, CafInfo(..), WorkerInfo(..),
  45                           setUnfoldingInfoLazily, setAllStrictnessInfo, setWorkerInfo,
  46                           setArityInfo, setInlinePragInfo, setCafInfo,
  47                           vanillaIdInfo, newStrictnessInfo )
  48 import Class            ( Class )
  49 import TyCon            ( DataConDetails(..), tyConDataCons, tyConTyVars, isTupleTyCon, mkForeignTyCon )
  50 import DataCon          ( dataConWorkId, dataConExistentialTyVars, dataConArgTys )
  51 import TysWiredIn       ( tupleCon )
  52 import Var              ( TyVar, mkTyVar, tyVarKind )
  53 import Name             ( Name, NamedThing(..), nameModuleName, nameModule, nameOccName,
  54                           isWiredInName, wiredInNameTyThing_maybe, nameParent )
  55 import NameEnv
  56 import OccName          ( OccName )
  57 import Module           ( Module, ModuleName, moduleName )
  58 import UniqSupply       ( initUs_ )
  59 import Outputable
  60 import SrcLoc           ( noSrcLoc )
  61 import Util             ( zipWithEqual, dropList, equalLength, zipLazy )
  62 import Maybes           ( expectJust )
  63 import CmdLineOpts      ( DynFlag(..) )
  64 \end{code}
  65
  66 This module takes
  67
  68         IfaceDecl -> TyThing
  69         IfaceType -> Type
  70         etc
  71
  72 An IfaceDecl is populated with RdrNames, and these are not renamed to
  73 Names before typechecking, because there should be no scope errors etc.
  74
  75         -- For (b) consider: f = $(...h....)
  76         -- where h is imported, and calls f via an hi-boot file.
  77         -- This is bad!  But it is not seen as a staging error, because h
  78         -- is indeed imported.  We don't want the type-checker to black-hole
  79         -- when simplifying and compiling the splice!
  80         --
  81         -- Simple solution: discard any unfolding that mentions a variable
  82         -- bound in this module (and hence not yet processed).
  83         -- The discarding happens when forkM finds a type error.
  84
  85 %************************************************************************
  86 %*                                                                      *
  87 %*      tcImportDecl is the key function for "faulting in"              *
  88 %*      imported things
  89 %*                                                                      *
  90 %************************************************************************
  91
  92 The main idea is this.  We are chugging along type-checking source code, and
  93 find a reference to GHC.Base.map.  We call tcLookupGlobal, which doesn't find
  94 it in the EPS type envt.  So it
  95         1 loads GHC.Base.hi
  96         2 gets the decl for GHC.Base.map
  97         3 typechecks it via tcIfaceDecl
  98         4 and adds it to the type env in the EPS
  99
 100 Note that DURING STEP 4, we may find that map's type mentions a type
 101 constructor that also
 102
 103 Notice that for imported things we read the current version from the EPS
 104 mutable variable.  This is important in situations like
 105         ...$(e1)...$(e2)...
 106 where the code that e1 expands to might import some defns that
 107 also turn out to be needed by the code that e2 expands to.
 108
 109 \begin{code}
 110 tcImportDecl :: Name -> IfG TyThing
 111 -- Get the TyThing for this Name from an interface file
 112 tcImportDecl name
 113   = do  {
 114     -- Make sure the interface is loaded
 115         ; let { nd_doc = ptext SLIT("Need decl for") <+> ppr name }
 116         ; traceIf (nd_doc <+> char '{')         -- Brace matches the later message
 117         ; loadHomeInterface nd_doc name
 118
 119     -- Get the real name of the thing, with a correct nameParent field.
 120     -- Before the interface is loaded, we may have a non-committal 'Nothing'
 121     -- in the namePareent field (made up by IfaceEnv.lookupOrig), but
 122     -- loading the interface updates the name cache.
 123     -- We need the right nameParent field in getThing
 124         ; real_name <- lookupOrig (nameModuleName name) (nameOccName name)
 125
 126     -- Get the decl out of the EPS
 127         ; main_thing <- ASSERT( real_name == name )     -- Unique should not change!
 128                         getThing real_name
 129
 130     -- Record the import in the type env,
 131     -- slurp any rules it allows in
 132         ; recordImportOf main_thing
 133
 134         ; let { extra | getName main_thing == real_name = empty
 135                       | otherwise = brackets (ptext SLIT("when seeking") <+> ppr real_name) }
 136         ; traceIf (ptext SLIT(" ...imported decl for") <+> ppr main_thing <+> extra <+> char '}')
 137
 138
 139     -- Look up the wanted Name in the type envt; it might be
 140     -- one of the subordinate members of the input thing
 141         ; if real_name == getName main_thing
 142           then return main_thing
 143           else do
 144         { eps <- getEps
 145         ; return (expectJust "tcImportDecl" $
 146                   lookupTypeEnv (eps_PTE eps) real_name) }}
 147
 148 recordImportOf :: TyThing -> IfG ()
 149 -- Update the EPS to record the import of the Thing
 150 --   (a) augment the type environment; this is done even for wired-in
 151 --       things, so that we don't go through this rigmarole a second time
 152 --   (b) slurp in any rules to maintain the invariant that any rule
 153 --           whose gates are all in the type envt, is in eps_rule_base
 154
 155 recordImportOf thing
 156   = do  { new_things <- updateEps (\ eps ->
 157             let { new_things   = thing : implicitTyThings thing
 158                 ; new_type_env = extendTypeEnvList (eps_PTE eps) new_things
 159                 -- NB: opportunity for a very subtle loop here!
 160                 -- If working out what the implicitTyThings are involves poking
 161                 -- any of the fork'd thunks in 'thing', then here's what happens
 162                 --      * recordImportOf succeed, extending type-env with a thunk
 163                 --      * the next guy to pull on type-env forces the thunk
 164                 --      * which pokes the suspended forks
 165                 --      * which, to execute, need to consult type-env (to check
 166                 --        entirely unrelated types, perhaps)
 167             }
 168             in (eps { eps_PTE = new_type_env }, new_things)
 169           )
 170         ; traceIf (text "tcImport: extend type env" <+> ppr new_things)
 171         }
 172
 173 getThing :: Name -> IfG TyThing
 174 -- Find and typecheck the thing; the Name might be a "subordinate name"
 175 -- of the "main thing" (e.g. the constructor of a data type declaration)
 176 -- The Thing we return is the parent "main thing"
 177
 178 getThing name
 179   | Just thing <- wiredInNameTyThing_maybe name
 180    = return thing
 181
 182   | otherwise = do      -- The normal case, not wired in
 183   {     -- Get the decl from the pool
 184     mb_decl <- updateEps (\ eps -> selectDecl eps name)
 185
 186     ; case mb_decl of
 187         Just decl -> initIfaceLcl (nameModuleName name) (tcIfaceDecl decl)
 188                 -- Typecheck it
 189                 -- Side-effects EPS by faulting in any needed decls
 190                 -- (via nested calls to tcImportDecl)
 191
 192
 193         Nothing -> do { ioToIOEnv (printErrs (msg defaultErrStyle)); failM }
 194                 -- Declaration not found
 195                 -- No errors-var to accumulate errors in, so just
 196                 -- print out the error right now
 197
 198     }
 199   where
 200      msg = hang (ptext SLIT("Can't find interface-file declaration for") <+> ppr (nameParent name))
 201               2 (vcat [ptext SLIT("Probable cause: bug in .hi-boot file, or inconsistent .hi file"),
 202                        ptext SLIT("Use -ddump-if-trace to get an idea of which file caused the error")])
 203
 204 selectDecl :: ExternalPackageState -> Name -> (ExternalPackageState, Maybe IfaceDecl)
 205 -- Use nameParent to get the parent name of the thing
 206 selectDecl eps@(EPS { eps_decls = Pool decls_map n_in n_out}) name
 207    = case lookupNameEnv decls_map main_name of
 208         Nothing   -> (eps, Nothing)
 209         Just decl -> (eps {eps_decls = Pool decls' n_in (n_out+1)}, Just decl)
 210    where
 211      main_name = nameParent name
 212      decls'    = delFromNameEnv decls_map main_name
 213 \end{code}
 214
 215 %************************************************************************
 216 %*                                                                      *
 217                 Type-checking a complete interface
 218 %*                                                                      *
 219 %************************************************************************
 220
 221 Suppose we discover we don't need to recompile.  Then we must type
 222 check the old interface file.  This is a bit different to the
 223 incremental type checking we do as we suck in interface files.  Instead
 224 we do things similarly as when we are typechecking source decls: we
 225 bring into scope the type envt for the interface all at once, using a
 226 knot.  Remember, the decls aren't necessarily in dependency order --
 227 and even if they were, the type decls might be mutually recursive.
 228
 229 \begin{code}
 230 typecheckIface :: HscEnv
 231                -> ModIface      -- Get the decls from here
 232                -> IO ModDetails
 233 typecheckIface hsc_env iface@(ModIface { mi_module = mod, mi_decls = ver_decls,
 234                                          mi_rules = rules, mi_insts = dfuns })
 235   = initIfaceTc hsc_env iface $ \ tc_env_var -> do
 236         {       -- Typecheck the decls
 237           names <- mappM (lookupOrig (moduleName mod) . ifName) decls
 238         ; ty_things <- fixM (\ rec_ty_things -> do
 239                 { writeMutVar tc_env_var (mkNameEnv (names `zipLazy` rec_ty_things))
 240                         -- This only makes available the "main" things,
 241                         -- but that's enough for the strictly-checked part
 242                 ; mapM tcIfaceDecl decls })
 243
 244                 -- Now augment the type envt with all the implicit things
 245                 -- These will be needed when type-checking the unfoldings for
 246                 -- the IfaceIds, but this is done lazily, so writing the thing
 247                 -- now is sufficient
 248         ; let   { add_implicits main_thing = main_thing : implicitTyThings main_thing
 249                 ; type_env = mkTypeEnv (concatMap add_implicits ty_things) }
 250         ; writeMutVar tc_env_var type_env
 251
 252                 -- Now do those rules and instances
 253         ; dfuns <- mapM tcIfaceInst (mi_insts iface)
 254         ; rules <- mapM tcIfaceRule (mi_rules iface)
 255
 256                 -- Finished
 257         ; return (ModDetails { md_types = type_env, md_insts = dfuns, md_rules = rules })
 258     }
 259   where
 260     decls = map snd ver_decls
 261 \end{code}
 262
 263
 264 %************************************************************************
 265 %*                                                                      *
 266                 Type and class declarations
 267 %*                                                                      *
 268 %************************************************************************
 269
 270 When typechecking a data type decl, we *lazily* (via forkM) typecheck
 271 the constructor argument types.  This is in the hope that we may never
 272 poke on those argument types, and hence may never need to load the
 273 interface files for types mentioned in the arg types.
 274
 275 E.g.
 276         data Foo.S = MkS Baz.T
 277 Mabye we can get away without even loading the interface for Baz!
 278
 279 This is not just a performance thing.  Suppose we have
 280         data Foo.S = MkS Baz.T
 281         data Baz.T = MkT Foo.S
 282 (in different interface files, of course).
 283 Now, first we load and typecheck Foo.S, and add it to the type envt.
 284 If we do explore MkS's argument, we'll load and typecheck Baz.T.
 285 If we explore MkT's argument we'll find Foo.S already in the envt.
 286
 287 If we typechecked constructor args eagerly, when loading Foo.S we'd try to
 288 typecheck the type Baz.T.  So we'd fault in Baz.T... and then need Foo.S...
 289 which isn't done yet.
 290
 291 All very cunning. However, there is a rather subtle gotcha which bit
 292 me when developing this stuff.  When we typecheck the decl for S, we
 293 extend the type envt with S, MkS, and all its implicit Ids.  Suppose
 294 (a bug, but it happened) that the list of implicit Ids depended in
 295 turn on the constructor arg types.  Then the following sequence of
 296 events takes place:
 297         * we build a thunk <t> for the constructor arg tys
 298         * we build a thunk for the extended type environment (depends on <t>)
 299         * we write the extended type envt into the global EPS mutvar
 300
 301 Now we look something up in the type envt
 302         * that pulls on <t>
 303         * which reads the global type envt out of the global EPS mutvar
 304         * but that depends in turn on <t>
 305
 306 It's subtle, because, it'd work fine if we typechecked the constructor args
 307 eagerly -- they don't need the extended type envt.  They just get the extended
 308 type envt by accident, because they look at it later.
 309
 310 What this means is that the implicitTyThings MUST NOT DEPEND on any of
 311 the forkM stuff.
 312
 313
 314 \begin{code}
 315 tcIfaceDecl :: IfaceDecl -> IfL TyThing
 316
 317 tcIfaceDecl (IfaceId {ifName = occ_name, ifType = iface_type, ifIdInfo = info})
 318   = do  { name <- lookupIfaceTop occ_name
 319         ; ty <- tcIfaceType iface_type
 320         ; info <- tcIdInfo name ty info
 321         ; return (AnId (mkVanillaGlobal name ty info)) }
 322
 323 tcIfaceDecl (IfaceData {ifND = new_or_data, ifName = occ_name,
 324                         ifTyVars = tv_bndrs, ifCtxt = rdr_ctxt,
 325                         ifCons = rdr_cons,
 326                         ifVrcs = arg_vrcs, ifRec = is_rec,
 327                         ifGeneric = want_generic })
 328   = do  { tc_name <- lookupIfaceTop occ_name
 329         ; bindIfaceTyVars tv_bndrs $ \ tyvars -> do
 330
 331         { traceIf (text "tcIfaceDecl" <+> ppr rdr_ctxt)
 332
 333         ; ctxt <- forkM (ptext SLIT("Ctxt of data decl") <+> ppr tc_name) $
 334                      tcIfaceCtxt rdr_ctxt
 335                 -- The reason for laziness here is to postpone
 336                 -- looking at the context, because the class may not
 337                 -- be in the type envt yet.  E.g.
 338                 --      class Real a where { toRat :: a -> Ratio Integer }
 339                 --      data (Real a) => Ratio a = ...
 340                 -- We suck in the decl for Real, and type check it, which sucks
 341                 -- in the data type Ratio; but we must postpone typechecking the
 342                 -- context
 343
 344         ; tycon <- fixM ( \ tycon -> do
 345             { cons <- tcIfaceDataCons tycon tyvars ctxt rdr_cons
 346             ; tycon <- buildAlgTyCon new_or_data tc_name tyvars ctxt cons
 347                             arg_vrcs is_rec want_generic
 348             ; return tycon
 349             })
 350         ; traceIf (text "tcIfaceDecl4" <+> ppr tycon)
 351         ; return (ATyCon tycon)
 352     } }
 353
 354 tcIfaceDecl (IfaceSyn {ifName = occ_name, ifTyVars = tv_bndrs,
 355                        ifSynRhs = rdr_rhs_ty, ifVrcs = arg_vrcs})
 356    = bindIfaceTyVars tv_bndrs $ \ tyvars -> do
 357      { tc_name <- lookupIfaceTop occ_name
 358      ; rhs_ty <- tcIfaceType rdr_rhs_ty
 359      ; return (ATyCon (buildSynTyCon tc_name tyvars rhs_ty arg_vrcs))
 360      }
 361
 362 tcIfaceDecl (IfaceClass {ifCtxt = rdr_ctxt, ifName = occ_name, ifTyVars = tv_bndrs,
 363                          ifFDs = rdr_fds, ifSigs = rdr_sigs,
 364                          ifVrcs = tc_vrcs, ifRec = tc_isrec })
 365   = bindIfaceTyVars tv_bndrs $ \ tyvars -> do
 366     { cls_name <- lookupIfaceTop occ_name
 367     ; ctxt <- tcIfaceCtxt rdr_ctxt
 368     ; sigs <- mappM tc_sig rdr_sigs
 369     ; fds  <- mappM tc_fd rdr_fds
 370     ; cls  <- buildClass cls_name tyvars ctxt fds sigs tc_isrec tc_vrcs
 371     ; return (AClass cls) }
 372   where
 373    tc_sig (IfaceClassOp occ dm rdr_ty)
 374      = do { op_name <- lookupIfaceTop occ
 375           ; op_ty   <- forkM (mk_doc op_name rdr_ty) (tcIfaceType rdr_ty)
 376                 -- Must be done lazily for just the same reason as the
 377                 -- context of a data decl: the type sig might mention the
 378                 -- class being defined
 379           ; return (op_name, dm, op_ty) }
 380
 381    mk_doc op_name op_ty = ptext SLIT("Class op") <+> sep [ppr op_name, ppr op_ty]
 382
 383    tc_fd (tvs1, tvs2) = do { tvs1' <- mappM tcIfaceTyVar tvs1
 384                            ; tvs2' <- mappM tcIfaceTyVar tvs2
 385                            ; return (tvs1', tvs2') }
 386
 387 tcIfaceDecl (IfaceForeign {ifName = rdr_name, ifExtName = ext_name})
 388   = do  { name <- lookupIfaceTop rdr_name
 389         ; return (ATyCon (mkForeignTyCon name ext_name
 390                                          liftedTypeKind 0 [])) }
 391
 392 tcIfaceDataCons tycon tyvars ctxt Unknown
 393   = returnM Unknown
 394
 395 tcIfaceDataCons tycon tyvars ctxt (DataCons cs)
 396   = mappM tc_con_decl cs        `thenM` \ data_cons ->
 397     returnM (DataCons data_cons)
 398   where
 399     tc_con_decl (IfaceConDecl occ ex_tvs ex_ctxt args stricts field_lbls)
 400       = bindIfaceTyVars ex_tvs  $ \ ex_tyvars -> do
 401         { name <- lookupIfaceTop occ
 402         ; ex_theta <- tcIfaceCtxt ex_ctxt       -- Laziness seems not worth the bother here
 403
 404         -- Read the argument types, but lazily to avoid faulting in
 405         -- the component types unless they are really needed
 406         ; arg_tys <- forkM (mk_doc name args) (mappM tcIfaceType args) ;
 407
 408         ; lbl_names <- mappM lookupIfaceTop field_lbls
 409
 410         ; buildDataCon name stricts lbl_names
 411                        tyvars ctxt ex_tyvars ex_theta
 412                        arg_tys tycon
 413         }
 414     mk_doc con_name args = ptext SLIT("Constructor") <+> sep [ppr con_name, ppr args]
 415 \end{code}
 416
 417
 418 %************************************************************************
 419 %*                                                                      *
 420                 Instances
 421 %*                                                                      *
 422 %************************************************************************
 423
 424 The gating story for instance declarations
 425 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 426 When we are looking for a dict (C t1..tn), we slurp in instance decls for
 427 C that
 428         mention at least one of the type constructors
 429         at the roots of t1..tn
 430
 431 Why "at least one" rather than "all"?  Because functional dependencies
 432 complicate the picture.  Consider
 433         class C a b | a->b where ...
 434         instance C Foo Baz where ...
 435 Here, the gates are really only C and Foo, *not* Baz.
 436 That is, if C and Foo are visible, even if Baz isn't, we must
 437 slurp the decl, even if Baz is thus far completely unknown to the
 438 system.
 439
 440 Why "roots of the types"?  Reason is overlap.  For example, suppose there
 441 are interfaces in the pool for
 442   (a)   C Int b
 443  (b)    C a [b]
 444   (c)   C a [T]
 445 Then, if we are trying to resolve (C Int x), we need (a)
 446 if we are trying to resolve (C x [y]), we need *both* (b) and (c),
 447 even though T is not involved yet, so that we spot the overlap.
 448
 449 \begin{code}
 450 loadImportedInsts :: Class -> [Type] -> TcM PackageInstEnv
 451 loadImportedInsts cls tys
 452   = do  {       -- Get interfaces for wired-in things, such as Integer
 453                 -- Any non-wired-in tycons will already be loaded, else
 454                 -- we couldn't have them in the Type
 455         ; this_mod <- getModule
 456         ; let { (cls_gate, tc_gates) = predInstGates cls tys
 457               ; imp_wi n = isWiredInName n && this_mod /= nameModule n
 458               ; wired_tcs = filter imp_wi tc_gates }
 459                         -- Wired-in tycons not from this module.  The "this-module"
 460                         -- test bites only when compiling Base etc, because loadHomeInterface
 461                         -- barfs if it's asked to load a non-existent interface
 462         ; if null wired_tcs then returnM ()
 463           else initIfaceTcRn (mapM_ (loadHomeInterface wired_doc) wired_tcs)
 464
 465         ; eps_var <- getEpsVar
 466         ; eps <- readMutVar eps_var
 467
 468         -- Suck in the instances
 469         ; let { (inst_pool', iface_insts)
 470                     = selectInsts (eps_insts eps) cls_gate tc_gates }
 471
 472         -- Empty => finish up rapidly, without writing to eps
 473         ; if null iface_insts then
 474                 return (eps_inst_env eps)
 475           else do
 476         { writeMutVar eps_var (eps {eps_insts = inst_pool'})
 477
 478         ; traceIf (sep [ptext SLIT("Importing instances for") <+> pprClassPred cls tys,
 479                         nest 2 (vcat (map ppr iface_insts))])
 480
 481         -- Typecheck the new instances
 482         ; dfuns <- initIfaceTcRn (mappM tc_inst iface_insts)
 483
 484         -- And put them in the package instance environment
 485         ; updateEps ( \ eps ->
 486             let
 487                 inst_env' = foldl extendInstEnv (eps_inst_env eps) dfuns
 488             in
 489             (eps { eps_inst_env = inst_env' }, inst_env')
 490         )}}
 491   where
 492     wired_doc = ptext SLIT("Need home inteface for wired-in thing")
 493
 494 tc_inst (mod, inst) = initIfaceLcl mod (tcIfaceInst inst)
 495
 496 tcIfaceInst :: IfaceInst -> IfL DFunId
 497 tcIfaceInst (IfaceInst { ifDFun = dfun_occ })
 498   = tcIfaceExtId (LocalTop dfun_occ)
 499
 500 selectInsts :: InstPool -> Name -> [Name] -> (InstPool, [(ModuleName, IfaceInst)])
 501 selectInsts pool@(Pool insts n_in n_out) cls tycons
 502   = (Pool insts' n_in (n_out + length iface_insts), iface_insts)
 503   where
 504     (insts', iface_insts)
 505         = case lookupNameEnv insts cls of {
 506                 Nothing -> (insts, []) ;
 507                 Just gated_insts ->
 508
 509           case foldl choose ([],[]) gated_insts of {
 510             (_, []) -> (insts, []) ;    -- None picked
 511             (gated_insts', iface_insts') ->
 512
 513           (extendNameEnv insts cls gated_insts', iface_insts') }}
 514
 515         -- Reverses the gated decls, but that doesn't matter
 516     choose (gis, decls) (gates, decl)
 517         | any (`elem` tycons) gates = (gis,                decl:decls)
 518         | otherwise                 = ((gates,decl) : gis, decls)
 519 \end{code}
 520
 521 %************************************************************************
 522 %*                                                                      *
 523                 Rules
 524 %*                                                                      *
 525 %************************************************************************
 526
 527 We move a IfaceRule from eps_rules to eps_rule_base when all its LHS free vars
 528 are in the type environment.  However, remember that typechecking a Rule may
 529 (as a side effect) augment the type envt, and so we may need to iterate the process.
 530
 531 \begin{code}
 532 loadImportedRules :: HscEnv -> ModGuts -> IO PackageRuleBase
 533 loadImportedRules hsc_env guts
 534   = initIfaceRules hsc_env guts $ do
 535         { -- Get new rules
 536           if_rules <- updateEps (\ eps ->
 537                 let { (new_pool, if_rules) = selectRules (eps_rules eps) (eps_PTE eps) }
 538                 in (eps { eps_rules = new_pool }, if_rules) )
 539
 540         ; traceIf (ptext SLIT("Importing rules:") <+> vcat (map ppr if_rules))
 541
 542         ; let tc_rule (mod, rule) = initIfaceLcl mod (tcIfaceRule rule)
 543         ; core_rules <- mapM tc_rule if_rules
 544
 545         -- Debug print
 546         ; traceIf (ptext SLIT("Imported rules:") <+> pprIdRules core_rules)
 547
 548         -- Update the rule base and return it
 549         ; updateEps (\ eps ->
 550             let { new_rule_base = extendRuleBaseList (eps_rule_base eps) core_rules }
 551             in (eps { eps_rule_base = new_rule_base }, new_rule_base)
 552           )
 553
 554         -- Strictly speaking, at this point we should go round again, since
 555         -- typechecking one set of rules may bring in new things which enable
 556         -- some more rules to come in.  But we call loadImportedRules several
 557         -- times anyway, so I'm going to be lazy and ignore this.
 558     }
 559
 560
 561 selectRules :: RulePool -> TypeEnv -> (RulePool, [(ModuleName, IfaceRule)])
 562 -- Not terribly efficient.  Look at each rule in the pool to see if
 563 -- all its gates are in the type env.  If so, take it out of the pool.
 564 -- If not, trim its gates for next time.
 565 selectRules (Pool rules n_in n_out) type_env
 566   = (Pool rules' n_in (n_out + length if_rules), if_rules)
 567   where
 568     (rules', if_rules) = foldl do_one ([], []) rules
 569
 570     do_one (pool, if_rules) (gates, rule)
 571         | null gates' = (pool, rule:if_rules)
 572         | otherwise   = ((gates',rule) : pool, if_rules)
 573         where
 574           gates' = filter (`elemNameEnv` type_env) gates
 575
 576
 577 tcIfaceRule :: IfaceRule -> IfL IdCoreRule
 578 tcIfaceRule (IfaceRule {ifRuleName = rule_name, ifActivation = act, ifRuleBndrs = bndrs,
 579                         ifRuleHead = fn_rdr, ifRuleArgs = args, ifRuleRhs = rhs })
 580   = bindIfaceBndrs bndrs        $ \ bndrs' ->
 581     do  { fn <- tcIfaceExtId fn_rdr
 582         ; args' <- mappM tcIfaceExpr args
 583         ; rhs'  <- tcIfaceExpr rhs
 584         ; returnM (fn, (Rule rule_name act bndrs' args' rhs')) }
 585
 586 tcIfaceRule (IfaceBuiltinRule fn_rdr core_rule)
 587   = do  { fn <- tcIfaceExtId fn_rdr
 588         ; returnM (fn, core_rule) }
 589 \end{code}
 590
 591
 592 %************************************************************************
 593 %*                                                                      *
 594                         Types
 595 %*                                                                      *
 596 %************************************************************************
 597
 598 \begin{code}
 599 tcIfaceKind :: IfaceKind -> Kind
 600 tcIfaceKind IfaceOpenTypeKind     = openTypeKind
 601 tcIfaceKind IfaceLiftedTypeKind   = liftedTypeKind
 602 tcIfaceKind IfaceUnliftedTypeKind = unliftedTypeKind
 603 tcIfaceKind (IfaceFunKind k1 k2)  = mkArrowKind (tcIfaceKind k1) (tcIfaceKind k2)
 604
 605 -----------------------------------------
 606 tcIfaceType :: IfaceType -> IfL Type
 607 tcIfaceType (IfaceTyVar n)        = do { tv <- tcIfaceTyVar n; return (TyVarTy tv) }
 608 tcIfaceType (IfaceAppTy t1 t2)    = do { t1' <- tcIfaceType t1; t2' <- tcIfaceType t2; return (AppTy t1' t2') }
 609 tcIfaceType (IfaceFunTy t1 t2)    = do { t1' <- tcIfaceType t1; t2' <- tcIfaceType t2; return (FunTy t1' t2') }
 610 tcIfaceType (IfaceTyConApp tc ts) = do { tc' <- tcIfaceTyCon tc; ts' <- tcIfaceTypes ts; return (mkGenTyConApp tc' ts') }
 611 tcIfaceType (IfaceForAllTy tv t)  = bindIfaceTyVar tv $ \ tv' -> do { t' <- tcIfaceType t; return (ForAllTy tv' t') }
 612 tcIfaceType (IfacePredTy st)      = do { st' <- tcIfacePredType st; return (PredTy st') }
 613
 614 tcIfaceTypes tys = mapM tcIfaceType tys
 615
 616 -----------------------------------------
 617 tcIfacePredType :: IfacePredType -> IfL PredType
 618 tcIfacePredType (IfaceClassP cls ts) = do { cls' <- tcIfaceClass cls; ts' <- tcIfaceTypes ts; return (ClassP cls' ts') }
 619 tcIfacePredType (IfaceIParam ip t)   = do { ip' <- newIPName ip; t' <- tcIfaceType t; return (IParam ip' t') }
 620
 621 -----------------------------------------
 622 tcIfaceCtxt :: IfaceContext -> IfL ThetaType
 623 tcIfaceCtxt sts = mappM tcIfacePredType sts
 624 \end{code}
 625
 626
 627 %************************************************************************
 628 %*                                                                      *
 629                         Core
 630 %*                                                                      *
 631 %************************************************************************
 632
 633 \begin{code}
 634 tcIfaceExpr :: IfaceExpr -> IfL CoreExpr
 635 tcIfaceExpr (IfaceType ty)
 636   = tcIfaceType ty              `thenM` \ ty' ->
 637     returnM (Type ty')
 638
 639 tcIfaceExpr (IfaceLcl name)
 640   = tcIfaceLclId name   `thenM` \ id ->
 641     returnM (Var id)
 642
 643 tcIfaceExpr (IfaceExt gbl)
 644   = tcIfaceExtId gbl    `thenM` \ id ->
 645     returnM (Var id)
 646
 647 tcIfaceExpr (IfaceLit lit)
 648   = returnM (Lit lit)
 649
 650 tcIfaceExpr (IfaceFCall cc ty)
 651   = tcIfaceType ty      `thenM` \ ty' ->
 652     newUnique           `thenM` \ u ->
 653     returnM (Var (mkFCallId u cc ty'))
 654
 655 tcIfaceExpr (IfaceTuple boxity args)
 656   = mappM tcIfaceExpr args      `thenM` \ args' ->
 657     let
 658         -- Put the missing type arguments back in
 659         con_args = map (Type . exprType) args' ++ args'
 660     in
 661     returnM (mkApps (Var con_id) con_args)
 662   where
 663     arity = length args
 664     con_id = dataConWorkId (tupleCon boxity arity)
 665
 666
 667 tcIfaceExpr (IfaceLam bndr body)
 668   = bindIfaceBndr bndr          $ \ bndr' ->
 669     tcIfaceExpr body            `thenM` \ body' ->
 670     returnM (Lam bndr' body')
 671
 672 tcIfaceExpr (IfaceApp fun arg)
 673   = tcIfaceExpr fun             `thenM` \ fun' ->
 674     tcIfaceExpr arg             `thenM` \ arg' ->
 675     returnM (App fun' arg')
 676
 677 tcIfaceExpr (IfaceCase scrut case_bndr alts)
 678   = tcIfaceExpr scrut           `thenM` \ scrut' ->
 679     newIfaceName case_bndr      `thenM` \ case_bndr_name ->
 680     let
 681         scrut_ty   = exprType scrut'
 682         case_bndr' = mkLocalId case_bndr_name scrut_ty
 683         tc_app     = splitTyConApp scrut_ty
 684                 -- NB: Won't always succeed (polymoprhic case)
 685                 --     but won't be demanded in those cases
 686                 -- NB: not tcSplitTyConApp; we are looking at Core here
 687                 --     look through non-rec newtypes to find the tycon that
 688                 --     corresponds to the datacon in this case alternative
 689     in
 690     extendIfaceIdEnv [case_bndr']       $
 691     mappM (tcIfaceAlt tc_app) alts      `thenM` \ alts' ->
 692     returnM (Case scrut' case_bndr' alts')
 693
 694 tcIfaceExpr (IfaceLet (IfaceNonRec bndr rhs) body)
 695   = tcIfaceExpr rhs             `thenM` \ rhs' ->
 696     bindIfaceId bndr            $ \ bndr' ->
 697     tcIfaceExpr body            `thenM` \ body' ->
 698     returnM (Let (NonRec bndr' rhs') body')
 699
 700 tcIfaceExpr (IfaceLet (IfaceRec pairs) body)
 701   = bindIfaceIds bndrs          $ \ bndrs' ->
 702     mappM tcIfaceExpr rhss      `thenM` \ rhss' ->
 703     tcIfaceExpr body            `thenM` \ body' ->
 704     returnM (Let (Rec (bndrs' `zip` rhss')) body')
 705   where
 706     (bndrs, rhss) = unzip pairs
 707
 708 tcIfaceExpr (IfaceNote note expr)
 709   = tcIfaceExpr expr            `thenM` \ expr' ->
 710     case note of
 711         IfaceCoerce to_ty -> tcIfaceType to_ty  `thenM` \ to_ty' ->
 712                              returnM (Note (Coerce to_ty'
 713                                                    (exprType expr')) expr')
 714         IfaceInlineCall   -> returnM (Note InlineCall expr')
 715         IfaceInlineMe     -> returnM (Note InlineMe   expr')
 716         IfaceSCC cc       -> returnM (Note (SCC cc)   expr')
 717         IfaceCoreNote n   -> returnM (Note (CoreNote n) expr')
 718
 719 -------------------------
 720 tcIfaceAlt _ (IfaceDefault, names, rhs)
 721   = ASSERT( null names )
 722     tcIfaceExpr rhs             `thenM` \ rhs' ->
 723     returnM (DEFAULT, [], rhs')
 724
 725 tcIfaceAlt _ (IfaceLitAlt lit, names, rhs)
 726   = ASSERT( null names )
 727     tcIfaceExpr rhs             `thenM` \ rhs' ->
 728     returnM (LitAlt lit, [], rhs')
 729
 730 -- A case alternative is made quite a bit more complicated
 731 -- by the fact that we omit type annotations because we can
 732 -- work them out.  True enough, but its not that easy!
 733 tcIfaceAlt (tycon, inst_tys) (IfaceDataAlt data_occ, arg_occs, rhs)
 734   = let
 735         tycon_mod = nameModuleName (tyConName tycon)
 736     in
 737     tcIfaceDataCon (ExtPkg tycon_mod data_occ)  `thenM` \ con ->
 738     newIfaceNames arg_occs                      `thenM` \ arg_names ->
 739     let
 740         ex_tyvars   = dataConExistentialTyVars con
 741         main_tyvars = tyConTyVars tycon
 742         ex_tyvars'  = [mkTyVar name (tyVarKind tv) | (name,tv) <- arg_names `zip` ex_tyvars]
 743         ex_tys'     = mkTyVarTys ex_tyvars'
 744         arg_tys     = dataConArgTys con (inst_tys ++ ex_tys')
 745         id_names    = dropList ex_tyvars arg_names
 746         arg_ids
 747 #ifdef DEBUG
 748                 | not (equalLength id_names arg_tys)
 749                 = pprPanic "tcIfaceAlts" (ppr (con, arg_names, rhs) $$
 750                                          (ppr main_tyvars <+> ppr ex_tyvars) $$
 751                                          ppr arg_tys)
 752                 | otherwise
 753 #endif
 754                 = zipWithEqual "tcIfaceAlts" mkLocalId id_names arg_tys
 755     in
 756     ASSERT2( con `elem` tyConDataCons tycon && equalLength inst_tys main_tyvars,
 757              ppr con $$ ppr tycon $$ ppr (tyConDataCons tycon) $$ ppr arg_tys $$  ppr main_tyvars  )
 758     extendIfaceTyVarEnv ex_tyvars'      $
 759     extendIfaceIdEnv arg_ids            $
 760     tcIfaceExpr rhs                     `thenM` \ rhs' ->
 761     returnM (DataAlt con, ex_tyvars' ++ arg_ids, rhs')
 762
 763 tcIfaceAlt (tycon, inst_tys) (IfaceTupleAlt boxity, arg_occs, rhs)
 764   = newIfaceNames arg_occs      `thenM` \ arg_names ->
 765     let
 766         [con]   = tyConDataCons tycon
 767         arg_ids = zipWithEqual "tcIfaceAlts" mkLocalId arg_names inst_tys
 768     in
 769     ASSERT( isTupleTyCon tycon )
 770     extendIfaceIdEnv arg_ids            $
 771     tcIfaceExpr rhs                     `thenM` \ rhs' ->
 772     returnM (DataAlt con, arg_ids, rhs')
 773 \end{code}
 774
 775
 776 \begin{code}
 777 tcExtCoreBindings :: Module -> [IfaceBinding] -> IfL [CoreBind] -- Used for external core
 778 tcExtCoreBindings mod []     = return []
 779 tcExtCoreBindings mod (b:bs) = do_one mod b (tcExtCoreBindings mod bs)
 780
 781 do_one :: Module -> IfaceBinding -> IfL [CoreBind] -> IfL [CoreBind]
 782 do_one mod (IfaceNonRec bndr rhs) thing_inside
 783   = do  { rhs' <- tcIfaceExpr rhs
 784         ; bndr' <- newExtCoreBndr mod bndr
 785         ; extendIfaceIdEnv [bndr'] $ do
 786         { core_binds <- thing_inside
 787         ; return (NonRec bndr' rhs' : core_binds) }}
 788
 789 do_one mod (IfaceRec pairs) thing_inside
 790   = do  { bndrs' <- mappM (newExtCoreBndr mod) bndrs
 791         ; extendIfaceIdEnv bndrs' $ do
 792         { rhss' <- mappM tcIfaceExpr rhss
 793         ; core_binds <- thing_inside
 794         ; return (Rec (bndrs' `zip` rhss') : core_binds) }}
 795   where
 796     (bndrs,rhss) = unzip pairs
 797 \end{code}
 798
 799
 800 %************************************************************************
 801 %*                                                                      *
 802                 IdInfo
 803 %*                                                                      *
 804 %************************************************************************
 805
 806 \begin{code}
 807 tcIdInfo name ty NoInfo        = return vanillaIdInfo
 808 tcIdInfo name ty DiscardedInfo = return vanillaIdInfo
 809 tcIdInfo name ty (HasInfo iface_info)
 810   = foldlM tcPrag init_info iface_info
 811   where
 812     -- Set the CgInfo to something sensible but uninformative before
 813     -- we start; default assumption is that it has CAFs
 814     init_info = vanillaIdInfo
 815
 816     tcPrag info HsNoCafRefs         = returnM (info `setCafInfo`   NoCafRefs)
 817     tcPrag info (HsArity arity)     = returnM (info `setArityInfo` arity)
 818     tcPrag info (HsStrictness str)  = returnM (info `setAllStrictnessInfo` Just str)
 819
 820         -- The next two are lazy, so they don't transitively suck stuff in
 821     tcPrag info (HsWorker nm arity) = tcWorkerInfo ty info nm arity
 822     tcPrag info (HsUnfold inline_prag expr)
 823         = tcPragExpr name expr  `thenM` \ maybe_expr' ->
 824           let
 825                 -- maybe_expr' doesn't get looked at if the unfolding
 826                 -- is never inspected; so the typecheck doesn't even happen
 827                 unfold_info = case maybe_expr' of
 828                                 Nothing    -> noUnfolding
 829                                 Just expr' -> mkTopUnfolding expr'
 830           in
 831           returnM (info `setUnfoldingInfoLazily` unfold_info
 832                         `setInlinePragInfo`      inline_prag)
 833 \end{code}
 834
 835 \begin{code}
 836 tcWorkerInfo ty info wkr_name arity
 837   = do  { mb_wkr_id <- forkM_maybe doc (tcIfaceExtId (LocalTop wkr_name))
 838
 839         -- We return without testing maybe_wkr_id, but as soon as info is
 840         -- looked at we will test it.  That's ok, because its outside the
 841         -- knot; and there seems no big reason to further defer the
 842         -- tcIfaceId lookup.  (Contrast with tcPragExpr, where postponing walking
 843         -- over the unfolding until it's actually used does seem worth while.)
 844         ; us <- newUniqueSupply
 845
 846         ; returnM (case mb_wkr_id of
 847                      Nothing     -> info
 848                      Just wkr_id -> add_wkr_info us wkr_id info) }
 849   where
 850     doc = text "Worker for" <+> ppr wkr_name
 851     add_wkr_info us wkr_id info
 852         = info `setUnfoldingInfoLazily`  mk_unfolding us wkr_id
 853                `setWorkerInfo`           HasWorker wkr_id arity
 854
 855     mk_unfolding us wkr_id = mkTopUnfolding (initUs_ us (mkWrapper ty strict_sig) wkr_id)
 856
 857         -- We are relying here on strictness info always appearing
 858         -- before worker info,  fingers crossed ....
 859     strict_sig = case newStrictnessInfo info of
 860                    Just sig -> sig
 861                    Nothing  -> pprPanic "Worker info but no strictness for" (ppr wkr_name)
 862 \end{code}
 863
 864 For unfoldings we try to do the job lazily, so that we never type check
 865 an unfolding that isn't going to be looked at.
 866
 867 \begin{code}
 868 tcPragExpr :: Name -> IfaceExpr -> IfL (Maybe CoreExpr)
 869 tcPragExpr name expr
 870   = forkM_maybe doc $
 871     tcIfaceExpr expr            `thenM` \ core_expr' ->
 872
 873                 -- Check for type consistency in the unfolding
 874     ifOptM Opt_DoCoreLinting (
 875         get_in_scope_ids                        `thenM` \ in_scope ->
 876         case lintUnfolding noSrcLoc in_scope core_expr' of
 877           Nothing       -> returnM ()
 878           Just fail_msg -> pprPanic "Iface Lint failure" (doc <+> fail_msg)
 879     )                           `thenM_`
 880
 881    returnM core_expr'
 882   where
 883     doc = text "Unfolding of" <+> ppr name
 884     get_in_scope_ids    -- Urgh; but just for linting
 885         = setLclEnv () $
 886           do    { env <- getGblEnv
 887                 ; case if_rec_types env of {
 888                           Nothing -> return [] ;
 889                           Just (_, get_env) -> do
 890                 { type_env <- get_env
 891                 ; return (typeEnvIds type_env) }}}
 892 \end{code}
 893
 894
 895
 896 %************************************************************************
 897 %*                                                                      *
 898                 Bindings
 899 %*                                                                      *
 900 %************************************************************************
 901
 902 \begin{code}
 903 bindIfaceBndr :: IfaceBndr -> (CoreBndr -> IfL a) -> IfL a
 904 bindIfaceBndr (IfaceIdBndr bndr) thing_inside
 905   = bindIfaceId bndr thing_inside
 906 bindIfaceBndr (IfaceTvBndr bndr) thing_inside
 907   = bindIfaceTyVar bndr thing_inside
 908
 909 bindIfaceBndrs :: [IfaceBndr] -> ([CoreBndr] -> IfL a) -> IfL a
 910 bindIfaceBndrs []     thing_inside = thing_inside []
 911 bindIfaceBndrs (b:bs) thing_inside
 912   = bindIfaceBndr b     $ \ b' ->
 913     bindIfaceBndrs bs   $ \ bs' ->
 914     thing_inside (b':bs')
 915
 916 -----------------------
 917 bindIfaceId :: (OccName, IfaceType) -> (Id -> IfL a) -> IfL a
 918 bindIfaceId (occ, ty) thing_inside
 919   = do  { name <- newIfaceName occ
 920         ; ty' <- tcIfaceType ty
 921         ; let { id = mkLocalId name ty' }
 922         ; extendIfaceIdEnv [id] (thing_inside id) }
 923
 924 bindIfaceIds :: [(OccName, IfaceType)] -> ([Id] -> IfL a) -> IfL a
 925 bindIfaceIds bndrs thing_inside
 926   = do  { names <- newIfaceNames occs
 927         ; tys' <- mappM tcIfaceType tys
 928         ; let { ids = zipWithEqual "tcCoreValBndr" mkLocalId names tys' }
 929         ; extendIfaceIdEnv ids (thing_inside ids) }
 930   where
 931     (occs,tys) = unzip bndrs
 932
 933
 934 -----------------------
 935 newExtCoreBndr :: Module -> (OccName, IfaceType) -> IfL Id
 936 newExtCoreBndr mod (occ, ty)
 937   = do  { name <- newGlobalBinder mod occ Nothing noSrcLoc
 938         ; ty' <- tcIfaceType ty
 939         ; return (mkLocalId name ty') }
 940
 941 -----------------------
 942 bindIfaceTyVar :: IfaceTvBndr -> (TyVar -> IfL a) -> IfL a
 943 bindIfaceTyVar (occ,kind) thing_inside
 944   = do  { name <- newIfaceName occ
 945         ; let tyvar = mk_iface_tyvar name kind
 946         ; extendIfaceTyVarEnv [tyvar] (thing_inside tyvar) }
 947
 948 bindIfaceTyVars :: [IfaceTvBndr] -> ([TyVar] -> IfL a) -> IfL a
 949 bindIfaceTyVars bndrs thing_inside
 950   = do  { names <- newIfaceNames occs
 951         ; let tyvars = zipWith mk_iface_tyvar names kinds
 952         ; extendIfaceTyVarEnv tyvars (thing_inside tyvars) }
 953   where
 954     (occs,kinds) = unzip bndrs
 955
 956 mk_iface_tyvar name kind = mkTyVar name (tcIfaceKind kind)
 957 \end{code}