ghc/compiler/main/GHC.hs

   1 -- -----------------------------------------------------------------------------
   2 --
   3 -- (c) The University of Glasgow, 2005
   4 --
   5 -- The GHC API
   6 --
   7 -- -----------------------------------------------------------------------------
   8
   9 module GHC (
  10         -- * Initialisation
  11         Session,
  12         defaultErrorHandler,
  13         defaultCleanupHandler,
  14         init, initFromArgs,
  15         newSession,
  16
  17         -- * Flags and settings
  18         DynFlags(..), DynFlag(..), Severity(..), GhcMode(..), HscTarget(..), dopt,
  19         parseDynamicFlags,
  20         initPackages,
  21         getSessionDynFlags,
  22         setSessionDynFlags,
  23
  24         -- * Targets
  25         Target(..), TargetId(..), Phase,
  26         setTargets,
  27         getTargets,
  28         addTarget,
  29         removeTarget,
  30         guessTarget,
  31
  32         -- * Loading\/compiling the program
  33         depanal,
  34         load, LoadHowMuch(..), SuccessFlag(..), -- also does depanal
  35         workingDirectoryChanged,
  36         checkModule, CheckedModule(..),
  37         TypecheckedSource, ParsedSource, RenamedSource,
  38
  39         -- * Inspecting the module structure of the program
  40         ModuleGraph, ModSummary(..), ModLocation(..),
  41         getModuleGraph,
  42         isLoaded,
  43         topSortModuleGraph,
  44
  45         -- * Inspecting modules
  46         ModuleInfo,
  47         getModuleInfo,
  48         modInfoTyThings,
  49         modInfoTopLevelScope,
  50         modInfoPrintUnqualified,
  51         modInfoExports,
  52         modInfoInstances,
  53         modInfoIsExportedName,
  54         modInfoLookupName,
  55         lookupGlobalName,
  56
  57         -- * Printing
  58         PrintUnqualified, alwaysQualify,
  59
  60         -- * Interactive evaluation
  61         getBindings, getPrintUnqual,
  62 #ifdef GHCI
  63         setContext, getContext,
  64         getNamesInScope,
  65         getRdrNamesInScope,
  66         moduleIsInterpreted,
  67         getInfo,
  68         exprType,
  69         typeKind,
  70         parseName,
  71         RunResult(..),
  72         runStmt,
  73         showModule,
  74         compileExpr, HValue,
  75         lookupName,
  76 #endif
  77
  78         -- * Abstract syntax elements
  79
  80         -- ** Modules
  81         Module, mkModule, pprModule,
  82
  83         -- ** Names
  84         Name,
  85         nameModule, nameParent_maybe, pprParenSymName, nameSrcLoc,
  86         NamedThing(..),
  87         RdrName(Qual,Unqual),
  88
  89         -- ** Identifiers
  90         Id, idType,
  91         isImplicitId, isDeadBinder,
  92         isExportedId, isLocalId, isGlobalId,
  93         isRecordSelector,
  94         isPrimOpId, isFCallId, isClassOpId_maybe,
  95         isDataConWorkId, idDataCon,
  96         isBottomingId, isDictonaryId,
  97         recordSelectorFieldLabel,
  98
  99         -- ** Type constructors
 100         TyCon,
 101         tyConTyVars, tyConDataCons, tyConArity,
 102         isClassTyCon, isSynTyCon, isNewTyCon, isPrimTyCon, isFunTyCon,
 103         synTyConDefn, synTyConRhs,
 104
 105         -- ** Type variables
 106         TyVar,
 107         alphaTyVars,
 108
 109         -- ** Data constructors
 110         DataCon,
 111         dataConSig, dataConType, dataConTyCon, dataConFieldLabels,
 112         dataConIsInfix, isVanillaDataCon,
 113         dataConStrictMarks,
 114         StrictnessMark(..), isMarkedStrict,
 115
 116         -- ** Classes
 117         Class,
 118         classMethods, classSCTheta, classTvsFds,
 119         pprFundeps,
 120
 121         -- ** Instances
 122         Instance,
 123         instanceDFunId, pprInstance, pprInstanceHdr,
 124
 125         -- ** Types and Kinds
 126         Type, dropForAlls, splitForAllTys, funResultTy, pprParendType,
 127         Kind,
 128         PredType,
 129         ThetaType, pprThetaArrow,
 130
 131         -- ** Entities
 132         TyThing(..),
 133
 134         -- ** Syntax
 135         module HsSyn, -- ToDo: remove extraneous bits
 136
 137         -- ** Fixities
 138         FixityDirection(..),
 139         defaultFixity, maxPrecedence,
 140         negateFixity,
 141         compareFixity,
 142
 143         -- ** Source locations
 144         SrcLoc, pprDefnLoc,
 145
 146         -- * Exceptions
 147         GhcException(..), showGhcException,
 148
 149         -- * Miscellaneous
 150         sessionHscEnv,
 151         cyclicModuleErr,
 152   ) where
 153
 154 {-
 155  ToDo:
 156
 157   * inline bits of HscMain here to simplify layering: hscTcExpr, hscStmt.
 158   * we need to expose DynFlags, so should parseDynamicFlags really be
 159     part of this interface?
 160   * what StaticFlags should we expose, if any?
 161 -}
 162
 163 #include "HsVersions.h"
 164
 165 #ifdef GHCI
 166 import qualified Linker
 167 import Linker           ( HValue, extendLinkEnv )
 168 import TcRnDriver       ( tcRnLookupRdrName, tcRnGetInfo,
 169                           tcRnLookupName, getModuleExports )
 170 import RdrName          ( plusGlobalRdrEnv, Provenance(..),
 171                           ImportSpec(..), ImpDeclSpec(..), ImpItemSpec(..),
 172                           emptyGlobalRdrEnv, mkGlobalRdrEnv )
 173 import HscMain          ( hscParseIdentifier, hscStmt, hscTcExpr, hscKcType )
 174 import Type             ( tidyType )
 175 import VarEnv           ( emptyTidyEnv )
 176 import GHC.Exts         ( unsafeCoerce# )
 177 #endif
 178
 179 import Packages         ( initPackages )
 180 import NameSet          ( NameSet, nameSetToList, elemNameSet )
 181 import RdrName          ( GlobalRdrEnv, GlobalRdrElt(..), RdrName(..),
 182                           globalRdrEnvElts )
 183 import HsSyn
 184 import Type             ( Kind, Type, dropForAlls, PredType, ThetaType,
 185                           pprThetaArrow, pprParendType, splitForAllTys,
 186                           funResultTy )
 187 import Id               ( Id, idType, isImplicitId, isDeadBinder,
 188                           isExportedId, isLocalId, isGlobalId,
 189                           isRecordSelector, recordSelectorFieldLabel,
 190                           isPrimOpId, isFCallId, isClassOpId_maybe,
 191                           isDataConWorkId, idDataCon,
 192                           isBottomingId )
 193 import Var              ( TyVar )
 194 import TysPrim          ( alphaTyVars )
 195 import TyCon            ( TyCon, isClassTyCon, isSynTyCon, isNewTyCon,
 196                           isPrimTyCon, isFunTyCon, tyConArity,
 197                           tyConTyVars, tyConDataCons, synTyConDefn, synTyConRhs )
 198 import Class            ( Class, classSCTheta, classTvsFds, classMethods )
 199 import FunDeps          ( pprFundeps )
 200 import DataCon          ( DataCon, dataConWrapId, dataConSig, dataConTyCon,
 201                           dataConFieldLabels, dataConStrictMarks,
 202                           dataConIsInfix, isVanillaDataCon )
 203 import Name             ( Name, nameModule, NamedThing(..), nameParent_maybe,
 204                           nameSrcLoc, nameOccName )
 205 import OccName          ( parenSymOcc )
 206 import NameEnv          ( nameEnvElts )
 207 import InstEnv          ( Instance, instanceDFunId, pprInstance, pprInstanceHdr )
 208 import SrcLoc
 209 import DriverPipeline
 210 import DriverPhases     ( Phase(..), isHaskellSrcFilename, startPhase )
 211 import HeaderInfo       ( getImports, getOptions, optionsErrorMsgs )
 212 import Packages         ( isHomePackage )
 213 import Finder
 214 import HscMain          ( newHscEnv, hscFileCheck, HscChecked(..) )
 215 import HscTypes
 216 import DynFlags
 217 import StaticFlags
 218 import SysTools         ( initSysTools, cleanTempFiles )
 219 import Module
 220 import FiniteMap
 221 import Panic
 222 import Digraph
 223 import Bag              ( unitBag )
 224 import ErrUtils         ( Severity(..), showPass, fatalErrorMsg, debugTraceMsg,
 225                           mkPlainErrMsg, printBagOfErrors, printErrorsAndWarnings )
 226 import qualified ErrUtils
 227 import Util
 228 import StringBuffer     ( StringBuffer, hGetStringBuffer )
 229 import Outputable
 230 import SysTools         ( cleanTempFilesExcept )
 231 import BasicTypes
 232 import TcType           ( tcSplitSigmaTy, isDictTy )
 233 import Maybes           ( expectJust, mapCatMaybes )
 234
 235 import Control.Concurrent
 236 import System.Directory ( getModificationTime, doesFileExist )
 237 import Data.Maybe       ( isJust, isNothing )
 238 import Data.List        ( partition, nub )
 239 import qualified Data.List as List
 240 import Control.Monad    ( unless, when )
 241 import System.Exit      ( exitWith, ExitCode(..) )
 242 import System.Time      ( ClockTime )
 243 import Control.Exception as Exception hiding (handle)
 244 import Data.IORef
 245 import System.IO
 246 import System.IO.Error  ( isDoesNotExistError )
 247 import System.IO.Unsafe ( unsafePerformIO )
 248 import Prelude hiding (init)
 249
 250 #if __GLASGOW_HASKELL__ < 600
 251 import System.IO as System.IO.Error ( try )
 252 #else
 253 import System.IO.Error  ( try )
 254 #endif
 255
 256 -- -----------------------------------------------------------------------------
 257 -- Exception handlers
 258
 259 -- | Install some default exception handlers and run the inner computation.
 260 -- Unless you want to handle exceptions yourself, you should wrap this around
 261 -- the top level of your program.  The default handlers output the error
 262 -- message(s) to stderr and exit cleanly.
 263 defaultErrorHandler :: DynFlags -> IO a -> IO a
 264 defaultErrorHandler dflags inner =
 265   -- top-level exception handler: any unrecognised exception is a compiler bug.
 266   handle (\exception -> do
 267            hFlush stdout
 268            case exception of
 269                 -- an IO exception probably isn't our fault, so don't panic
 270                 IOException _ ->
 271                   fatalErrorMsg dflags (text (show exception))
 272                 AsyncException StackOverflow ->
 273                   fatalErrorMsg dflags (text "stack overflow: use +RTS -K<size> to increase it")
 274                 _other ->
 275                   fatalErrorMsg dflags (text (show (Panic (show exception))))
 276            exitWith (ExitFailure 1)
 277          ) $
 278
 279   -- program errors: messages with locations attached.  Sometimes it is
 280   -- convenient to just throw these as exceptions.
 281   handleDyn (\dyn -> do printBagOfErrors dflags (unitBag dyn)
 282                         exitWith (ExitFailure 1)) $
 283
 284   -- error messages propagated as exceptions
 285   handleDyn (\dyn -> do
 286                 hFlush stdout
 287                 case dyn of
 288                      PhaseFailed _ code -> exitWith code
 289                      Interrupted -> exitWith (ExitFailure 1)
 290                      _ -> do fatalErrorMsg dflags (text (show (dyn :: GhcException)))
 291                              exitWith (ExitFailure 1)
 292             ) $
 293   inner
 294
 295 -- | Install a default cleanup handler to remove temporary files
 296 -- deposited by a GHC run.  This is seperate from
 297 -- 'defaultErrorHandler', because you might want to override the error
 298 -- handling, but still get the ordinary cleanup behaviour.
 299 defaultCleanupHandler :: DynFlags -> IO a -> IO a
 300 defaultCleanupHandler dflags inner =
 301    -- make sure we clean up after ourselves
 302    later (unless (dopt Opt_KeepTmpFiles dflags) $
 303             cleanTempFiles dflags)
 304         -- exceptions will be blocked while we clean the temporary files,
 305         -- so there shouldn't be any difficulty if we receive further
 306         -- signals.
 307    inner
 308
 309
 310 -- | Initialises GHC.  This must be done /once/ only.  Takes the
 311 -- TopDir path without the '-B' prefix.
 312
 313 init :: Maybe String -> IO ()
 314 init mbMinusB = do
 315    -- catch ^C
 316    main_thread <- myThreadId
 317    putMVar interruptTargetThread [main_thread]
 318    installSignalHandlers
 319
 320    dflags0 <- initSysTools mbMinusB defaultDynFlags
 321    writeIORef v_initDynFlags dflags0
 322
 323 -- | Initialises GHC. This must be done /once/ only. Takes the
 324 -- command-line arguments.  All command-line arguments which aren't
 325 -- understood by GHC will be returned.
 326
 327 initFromArgs :: [String] -> IO [String]
 328 initFromArgs args
 329     = do init mbMinusB
 330          return argv1
 331     where -- Grab the -B option if there is one
 332           (minusB_args, argv1) = partition (prefixMatch "-B") args
 333           mbMinusB | null minusB_args
 334                        = Nothing
 335                    | otherwise
 336                        = Just (drop 2 (last minusB_args))
 337
 338 GLOBAL_VAR(v_initDynFlags, error "initDynFlags", DynFlags)
 339         -- stores the DynFlags between the call to init and subsequent
 340         -- calls to newSession.
 341
 342 -- | Starts a new session.  A session consists of a set of loaded
 343 -- modules, a set of options (DynFlags), and an interactive context.
 344 -- ToDo: GhcMode should say "keep typechecked code" and\/or "keep renamed
 345 -- code".
 346 newSession :: GhcMode -> IO Session
 347 newSession mode = do
 348   dflags0 <- readIORef v_initDynFlags
 349   dflags <- initDynFlags dflags0
 350   env <- newHscEnv dflags{ ghcMode=mode }
 351   ref <- newIORef env
 352   return (Session ref)
 353
 354 -- tmp: this breaks the abstraction, but required because DriverMkDepend
 355 -- needs to call the Finder.  ToDo: untangle this.
 356 sessionHscEnv :: Session -> IO HscEnv
 357 sessionHscEnv (Session ref) = readIORef ref
 358
 359 withSession :: Session -> (HscEnv -> IO a) -> IO a
 360 withSession (Session ref) f = do h <- readIORef ref; f h
 361
 362 modifySession :: Session -> (HscEnv -> HscEnv) -> IO ()
 363 modifySession (Session ref) f = do h <- readIORef ref; writeIORef ref $! f h
 364
 365 -- -----------------------------------------------------------------------------
 366 -- Flags & settings
 367
 368 -- | Grabs the DynFlags from the Session
 369 getSessionDynFlags :: Session -> IO DynFlags
 370 getSessionDynFlags s = withSession s (return . hsc_dflags)
 371
 372 -- | Updates the DynFlags in a Session
 373 setSessionDynFlags :: Session -> DynFlags -> IO ()
 374 setSessionDynFlags s dflags = modifySession s (\h -> h{ hsc_dflags = dflags })
 375
 376 -- | If there is no -o option, guess the name of target executable
 377 -- by using top-level source file name as a base.
 378 guessOutputFile :: Session -> IO ()
 379 guessOutputFile s = modifySession s $ \env ->
 380     let dflags = hsc_dflags env
 381         mod_graph = hsc_mod_graph env
 382         mainModuleSrcPath, guessedName :: Maybe String
 383         mainModuleSrcPath = do
 384             let isMain = (== mainModIs dflags) . ms_mod
 385             [ms] <- return (filter isMain mod_graph)
 386             ml_hs_file (ms_location ms)
 387         guessedName = fmap basenameOf mainModuleSrcPath
 388     in
 389     case outputFile dflags of
 390         Just _ -> env
 391         Nothing -> env { hsc_dflags = dflags { outputFile = guessedName } }
 392
 393 -- -----------------------------------------------------------------------------
 394 -- Targets
 395
 396 -- ToDo: think about relative vs. absolute file paths. And what
 397 -- happens when the current directory changes.
 398
 399 -- | Sets the targets for this session.  Each target may be a module name
 400 -- or a filename.  The targets correspond to the set of root modules for
 401 -- the program\/library.  Unloading the current program is achieved by
 402 -- setting the current set of targets to be empty, followed by load.
 403 setTargets :: Session -> [Target] -> IO ()
 404 setTargets s targets = modifySession s (\h -> h{ hsc_targets = targets })
 405
 406 -- | returns the current set of targets
 407 getTargets :: Session -> IO [Target]
 408 getTargets s = withSession s (return . hsc_targets)
 409
 410 -- | Add another target
 411 addTarget :: Session -> Target -> IO ()
 412 addTarget s target
 413   = modifySession s (\h -> h{ hsc_targets = target : hsc_targets h })
 414
 415 -- | Remove a target
 416 removeTarget :: Session -> TargetId -> IO ()
 417 removeTarget s target_id
 418   = modifySession s (\h -> h{ hsc_targets = filter (hsc_targets h) })
 419   where
 420    filter targets = [ t | t@(Target id _) <- targets, id /= target_id ]
 421
 422 -- Attempts to guess what Target a string refers to.  This function implements
 423 -- the --make/GHCi command-line syntax for filenames:
 424 --
 425 --      - if the string looks like a Haskell source filename, then interpret
 426 --        it as such
 427 --      - if adding a .hs or .lhs suffix yields the name of an existing file,
 428 --        then use that
 429 --      - otherwise interpret the string as a module name
 430 --
 431 guessTarget :: String -> Maybe Phase -> IO Target
 432 guessTarget file (Just phase)
 433    = return (Target (TargetFile file (Just phase)) Nothing)
 434 guessTarget file Nothing
 435    | isHaskellSrcFilename file
 436    = return (Target (TargetFile file Nothing) Nothing)
 437    | otherwise
 438    = do exists <- doesFileExist hs_file
 439         if exists
 440            then return (Target (TargetFile hs_file Nothing) Nothing)
 441            else do
 442         exists <- doesFileExist lhs_file
 443         if exists
 444            then return (Target (TargetFile lhs_file Nothing) Nothing)
 445            else do
 446         return (Target (TargetModule (mkModule file)) Nothing)
 447      where
 448          hs_file  = file `joinFileExt` "hs"
 449          lhs_file = file `joinFileExt` "lhs"
 450
 451 -- -----------------------------------------------------------------------------
 452 -- Loading the program
 453
 454 -- Perform a dependency analysis starting from the current targets
 455 -- and update the session with the new module graph.
 456 depanal :: Session -> [Module] -> Bool -> IO (Maybe ModuleGraph)
 457 depanal (Session ref) excluded_mods allow_dup_roots = do
 458   hsc_env <- readIORef ref
 459   let
 460          dflags  = hsc_dflags hsc_env
 461          gmode   = ghcMode (hsc_dflags hsc_env)
 462          targets = hsc_targets hsc_env
 463          old_graph = hsc_mod_graph hsc_env
 464
 465   showPass dflags "Chasing dependencies"
 466   when (gmode == BatchCompile) $
 467         debugTraceMsg dflags 1 (hcat [
 468                      text "Chasing modules from: ",
 469                         hcat (punctuate comma (map pprTarget targets))])
 470
 471   r <- downsweep hsc_env old_graph excluded_mods allow_dup_roots
 472   case r of
 473     Just mod_graph -> writeIORef ref hsc_env{ hsc_mod_graph = mod_graph }
 474     _ -> return ()
 475   return r
 476
 477 {-
 478 -- | The result of load.
 479 data LoadResult
 480   = LoadOk      Errors  -- ^ all specified targets were loaded successfully.
 481   | LoadFailed  Errors  -- ^ not all modules were loaded.
 482
 483 type Errors = [String]
 484
 485 data ErrMsg = ErrMsg {
 486         errMsgSeverity  :: Severity,  -- warning, error, etc.
 487         errMsgSpans     :: [SrcSpan],
 488         errMsgShortDoc  :: Doc,
 489         errMsgExtraInfo :: Doc
 490         }
 491 -}
 492
 493 data LoadHowMuch
 494    = LoadAllTargets
 495    | LoadUpTo Module
 496    | LoadDependenciesOf Module
 497
 498 -- | Try to load the program.  If a Module is supplied, then just
 499 -- attempt to load up to this target.  If no Module is supplied,
 500 -- then try to load all targets.
 501 load :: Session -> LoadHowMuch -> IO SuccessFlag
 502 load s@(Session ref) how_much
 503    = do
 504         -- Dependency analysis first.  Note that this fixes the module graph:
 505         -- even if we don't get a fully successful upsweep, the full module
 506         -- graph is still retained in the Session.  We can tell which modules
 507         -- were successfully loaded by inspecting the Session's HPT.
 508         mb_graph <- depanal s [] False
 509         case mb_graph of
 510            Just mod_graph -> load2 s how_much mod_graph
 511            Nothing        -> return Failed
 512
 513 load2 s@(Session ref) how_much mod_graph = do
 514         guessOutputFile s
 515         hsc_env <- readIORef ref
 516
 517         let hpt1      = hsc_HPT hsc_env
 518         let dflags    = hsc_dflags hsc_env
 519         let ghci_mode = ghcMode dflags -- this never changes
 520
 521         -- The "bad" boot modules are the ones for which we have
 522         -- B.hs-boot in the module graph, but no B.hs
 523         -- The downsweep should have ensured this does not happen
 524         -- (see msDeps)
 525         let all_home_mods = [ms_mod s | s <- mod_graph, not (isBootSummary s)]
 526 #ifdef DEBUG
 527             bad_boot_mods = [s        | s <- mod_graph, isBootSummary s,
 528                                         not (ms_mod s `elem` all_home_mods)]
 529 #endif
 530         ASSERT( null bad_boot_mods ) return ()
 531
 532         -- mg2_with_srcimps drops the hi-boot nodes, returning a
 533         -- graph with cycles.  Among other things, it is used for
 534         -- backing out partially complete cycles following a failed
 535         -- upsweep, and for removing from hpt all the modules
 536         -- not in strict downwards closure, during calls to compile.
 537         let mg2_with_srcimps :: [SCC ModSummary]
 538             mg2_with_srcimps = topSortModuleGraph True mod_graph Nothing
 539
 540             -- check the stability property for each module.
 541             stable_mods@(stable_obj,stable_bco)
 542                 | BatchCompile <- ghci_mode = ([],[])
 543                 | otherwise = checkStability hpt1 mg2_with_srcimps all_home_mods
 544
 545             -- prune bits of the HPT which are definitely redundant now,
 546             -- to save space.
 547             pruned_hpt = pruneHomePackageTable hpt1
 548                                 (flattenSCCs mg2_with_srcimps)
 549                                 stable_mods
 550
 551         evaluate pruned_hpt
 552
 553         debugTraceMsg dflags 2 (text "Stable obj:" <+> ppr stable_obj $$
 554                                 text "Stable BCO:" <+> ppr stable_bco)
 555
 556         -- Unload any modules which are going to be re-linked this time around.
 557         let stable_linkables = [ linkable
 558                                | m <- stable_obj++stable_bco,
 559                                  Just hmi <- [lookupModuleEnv pruned_hpt m],
 560                                  Just linkable <- [hm_linkable hmi] ]
 561         unload hsc_env stable_linkables
 562
 563         -- We could at this point detect cycles which aren't broken by
 564         -- a source-import, and complain immediately, but it seems better
 565         -- to let upsweep_mods do this, so at least some useful work gets
 566         -- done before the upsweep is abandoned.
 567         --hPutStrLn stderr "after tsort:\n"
 568         --hPutStrLn stderr (showSDoc (vcat (map ppr mg2)))
 569
 570         -- Now do the upsweep, calling compile for each module in
 571         -- turn.  Final result is version 3 of everything.
 572
 573         -- Topologically sort the module graph, this time including hi-boot
 574         -- nodes, and possibly just including the portion of the graph
 575         -- reachable from the module specified in the 2nd argument to load.
 576         -- This graph should be cycle-free.
 577         -- If we're restricting the upsweep to a portion of the graph, we
 578         -- also want to retain everything that is still stable.
 579         let full_mg :: [SCC ModSummary]
 580             full_mg    = topSortModuleGraph False mod_graph Nothing
 581
 582             maybe_top_mod = case how_much of
 583                                 LoadUpTo m           -> Just m
 584                                 LoadDependenciesOf m -> Just m
 585                                 _                    -> Nothing
 586
 587             partial_mg0 :: [SCC ModSummary]
 588             partial_mg0 = topSortModuleGraph False mod_graph maybe_top_mod
 589
 590             -- LoadDependenciesOf m: we want the upsweep to stop just
 591             -- short of the specified module (unless the specified module
 592             -- is stable).
 593             partial_mg
 594                 | LoadDependenciesOf mod <- how_much
 595                 = ASSERT( case last partial_mg0 of
 596                             AcyclicSCC ms -> ms_mod ms == mod; _ -> False )
 597                   List.init partial_mg0
 598                 | otherwise
 599                 = partial_mg0
 600
 601             stable_mg =
 602                 [ AcyclicSCC ms
 603                 | AcyclicSCC ms <- full_mg,
 604                   ms_mod ms `elem` stable_obj++stable_bco,
 605                   ms_mod ms `notElem` [ ms_mod ms' |
 606                                         AcyclicSCC ms' <- partial_mg ] ]
 607
 608             mg = stable_mg ++ partial_mg
 609
 610         -- clean up between compilations
 611         let cleanup = cleanTempFilesExcept dflags
 612                           (ppFilesFromSummaries (flattenSCCs mg2_with_srcimps))
 613
 614         (upsweep_ok, hsc_env1, modsUpswept)
 615            <- upsweep (hsc_env { hsc_HPT = emptyHomePackageTable })
 616                            pruned_hpt stable_mods cleanup mg
 617
 618         -- Make modsDone be the summaries for each home module now
 619         -- available; this should equal the domain of hpt3.
 620         -- Get in in a roughly top .. bottom order (hence reverse).
 621
 622         let modsDone = reverse modsUpswept
 623
 624         -- Try and do linking in some form, depending on whether the
 625         -- upsweep was completely or only partially successful.
 626
 627         if succeeded upsweep_ok
 628
 629          then
 630            -- Easy; just relink it all.
 631            do debugTraceMsg dflags 2 (text "Upsweep completely successful.")
 632
 633               -- Clean up after ourselves
 634               cleanTempFilesExcept dflags (ppFilesFromSummaries modsDone)
 635
 636               -- Issue a warning for the confusing case where the user
 637               -- said '-o foo' but we're not going to do any linking.
 638               -- We attempt linking if either (a) one of the modules is
 639               -- called Main, or (b) the user said -no-hs-main, indicating
 640               -- that main() is going to come from somewhere else.
 641               --
 642               let ofile = outputFile dflags
 643               let no_hs_main = dopt Opt_NoHsMain dflags
 644               let
 645                 main_mod = mainModIs dflags
 646                 a_root_is_Main = any ((==main_mod).ms_mod) mod_graph
 647                 do_linking = a_root_is_Main || no_hs_main
 648
 649               when (ghci_mode == BatchCompile && isJust ofile && not do_linking) $
 650                 debugTraceMsg dflags 1 (text ("Warning: output was redirected with -o, " ++
 651                                               "but no output will be generated\n" ++
 652                                               "because there is no " ++ moduleString main_mod ++ " module."))
 653
 654               -- link everything together
 655               linkresult <- link ghci_mode dflags do_linking (hsc_HPT hsc_env1)
 656
 657               loadFinish Succeeded linkresult ref hsc_env1
 658
 659          else
 660            -- Tricky.  We need to back out the effects of compiling any
 661            -- half-done cycles, both so as to clean up the top level envs
 662            -- and to avoid telling the interactive linker to link them.
 663            do debugTraceMsg dflags 2 (text "Upsweep partially successful.")
 664
 665               let modsDone_names
 666                      = map ms_mod modsDone
 667               let mods_to_zap_names
 668                      = findPartiallyCompletedCycles modsDone_names
 669                           mg2_with_srcimps
 670               let mods_to_keep
 671                      = filter ((`notElem` mods_to_zap_names).ms_mod)
 672                           modsDone
 673
 674               let hpt4 = retainInTopLevelEnvs (map ms_mod mods_to_keep)
 675                                               (hsc_HPT hsc_env1)
 676
 677               -- Clean up after ourselves
 678               cleanTempFilesExcept dflags (ppFilesFromSummaries mods_to_keep)
 679
 680               -- there should be no Nothings where linkables should be, now
 681               ASSERT(all (isJust.hm_linkable)
 682                         (moduleEnvElts (hsc_HPT hsc_env))) do
 683
 684               -- Link everything together
 685               linkresult <- link ghci_mode dflags False hpt4
 686
 687               let hsc_env4 = hsc_env1{ hsc_HPT = hpt4 }
 688               loadFinish Failed linkresult ref hsc_env4
 689
 690 -- Finish up after a load.
 691
 692 -- If the link failed, unload everything and return.
 693 loadFinish all_ok Failed ref hsc_env
 694   = do unload hsc_env []
 695        writeIORef ref $! discardProg hsc_env
 696        return Failed
 697
 698 -- Empty the interactive context and set the module context to the topmost
 699 -- newly loaded module, or the Prelude if none were loaded.
 700 loadFinish all_ok Succeeded ref hsc_env
 701   = do writeIORef ref $! hsc_env{ hsc_IC = emptyInteractiveContext }
 702        return all_ok
 703
 704
 705 -- Forget the current program, but retain the persistent info in HscEnv
 706 discardProg :: HscEnv -> HscEnv
 707 discardProg hsc_env
 708   = hsc_env { hsc_mod_graph = emptyMG,
 709               hsc_IC = emptyInteractiveContext,
 710               hsc_HPT = emptyHomePackageTable }
 711
 712 -- used to fish out the preprocess output files for the purposes of
 713 -- cleaning up.  The preprocessed file *might* be the same as the
 714 -- source file, but that doesn't do any harm.
 715 ppFilesFromSummaries summaries = map ms_hspp_file summaries
 716
 717 -- -----------------------------------------------------------------------------
 718 -- Check module
 719
 720 data CheckedModule =
 721   CheckedModule { parsedSource      :: ParsedSource,
 722                   renamedSource     :: Maybe RenamedSource,
 723                   typecheckedSource :: Maybe TypecheckedSource,
 724                   checkedModuleInfo :: Maybe ModuleInfo
 725                 }
 726         -- ToDo: improvements that could be made here:
 727         --  if the module succeeded renaming but not typechecking,
 728         --  we can still get back the GlobalRdrEnv and exports, so
 729         --  perhaps the ModuleInfo should be split up into separate
 730         --  fields within CheckedModule.
 731
 732 type ParsedSource      = Located (HsModule RdrName)
 733 type RenamedSource     = (HsGroup Name, [LImportDecl Name], Maybe [LIE Name])
 734 type TypecheckedSource = LHsBinds Id
 735
 736 -- NOTE:
 737 --   - things that aren't in the output of the typechecker right now:
 738 --     - the export list
 739 --     - the imports
 740 --     - type signatures
 741 --     - type/data/newtype declarations
 742 --     - class declarations
 743 --     - instances
 744 --   - extra things in the typechecker's output:
 745 --     - default methods are turned into top-level decls.
 746 --     - dictionary bindings
 747
 748
 749 -- | This is the way to get access to parsed and typechecked source code
 750 -- for a module.  'checkModule' loads all the dependencies of the specified
 751 -- module in the Session, and then attempts to typecheck the module.  If
 752 -- successful, it returns the abstract syntax for the module.
 753 checkModule :: Session -> Module -> IO (Maybe CheckedModule)
 754 checkModule session@(Session ref) mod = do
 755         -- load up the dependencies first
 756    r <- load session (LoadDependenciesOf mod)
 757    if (failed r) then return Nothing else do
 758
 759         -- now parse & typecheck the module
 760    hsc_env <- readIORef ref
 761    let mg  = hsc_mod_graph hsc_env
 762    case [ ms | ms <- mg, ms_mod ms == mod ] of
 763         [] -> return Nothing
 764         (ms:_) -> do
 765            mbChecked <- hscFileCheck hsc_env{hsc_dflags=ms_hspp_opts ms} ms
 766            case mbChecked of
 767              Nothing -> return Nothing
 768              Just (HscChecked parsed renamed Nothing) ->
 769                    return (Just (CheckedModule {
 770                                         parsedSource = parsed,
 771                                         renamedSource = renamed,
 772                                         typecheckedSource = Nothing,
 773                                         checkedModuleInfo = Nothing }))
 774              Just (HscChecked parsed renamed
 775                            (Just (tc_binds, rdr_env, details))) -> do
 776                    let minf = ModuleInfo {
 777                                 minf_type_env  = md_types details,
 778                                 minf_exports   = md_exports details,
 779                                 minf_rdr_env   = Just rdr_env,
 780                                 minf_instances = md_insts details
 781                               }
 782                    return (Just (CheckedModule {
 783                                         parsedSource = parsed,
 784                                         renamedSource = renamed,
 785                                         typecheckedSource = Just tc_binds,
 786                                         checkedModuleInfo = Just minf }))
 787              _other ->
 788                         panic "checkModule"
 789
 790 -- ---------------------------------------------------------------------------
 791 -- Unloading
 792
 793 unload :: HscEnv -> [Linkable] -> IO ()
 794 unload hsc_env stable_linkables -- Unload everthing *except* 'stable_linkables'
 795   = case ghcMode (hsc_dflags hsc_env) of
 796         BatchCompile  -> return ()
 797         JustTypecheck -> return ()
 798 #ifdef GHCI
 799         Interactive -> Linker.unload (hsc_dflags hsc_env) stable_linkables
 800 #else
 801         Interactive -> panic "unload: no interpreter"
 802 #endif
 803         other -> panic "unload: strange mode"
 804
 805 -- -----------------------------------------------------------------------------
 806 -- checkStability
 807
 808 {-
 809   Stability tells us which modules definitely do not need to be recompiled.
 810   There are two main reasons for having stability:
 811
 812    - avoid doing a complete upsweep of the module graph in GHCi when
 813      modules near the bottom of the tree have not changed.
 814
 815    - to tell GHCi when it can load object code: we can only load object code
 816      for a module when we also load object code fo  all of the imports of the
 817      module.  So we need to know that we will definitely not be recompiling
 818      any of these modules, and we can use the object code.
 819
 820   NB. stability is of no importance to BatchCompile at all, only Interactive.
 821   (ToDo: what about JustTypecheck?)
 822
 823   The stability check is as follows.  Both stableObject and
 824   stableBCO are used during the upsweep phase later.
 825
 826   -------------------
 827   stable m = stableObject m || stableBCO m
 828
 829   stableObject m =
 830         all stableObject (imports m)
 831         && old linkable does not exist, or is == on-disk .o
 832         && date(on-disk .o) > date(.hs)
 833
 834   stableBCO m =
 835         all stable (imports m)
 836         && date(BCO) > date(.hs)
 837   -------------------
 838
 839   These properties embody the following ideas:
 840
 841     - if a module is stable:
 842         - if it has been compiled in a previous pass (present in HPT)
 843           then it does not need to be compiled or re-linked.
 844         - if it has not been compiled in a previous pass,
 845           then we only need to read its .hi file from disk and
 846           link it to produce a ModDetails.
 847
 848     - if a modules is not stable, we will definitely be at least
 849       re-linking, and possibly re-compiling it during the upsweep.
 850       All non-stable modules can (and should) therefore be unlinked
 851       before the upsweep.
 852
 853     - Note that objects are only considered stable if they only depend
 854       on other objects.  We can't link object code against byte code.
 855 -}
 856
 857 checkStability
 858         :: HomePackageTable             -- HPT from last compilation
 859         -> [SCC ModSummary]             -- current module graph (cyclic)
 860         -> [Module]                     -- all home modules
 861         -> ([Module],                   -- stableObject
 862             [Module])                   -- stableBCO
 863
 864 checkStability hpt sccs all_home_mods = foldl checkSCC ([],[]) sccs
 865   where
 866    checkSCC (stable_obj, stable_bco) scc0
 867      | stableObjects = (scc_mods ++ stable_obj, stable_bco)
 868      | stableBCOs    = (stable_obj, scc_mods ++ stable_bco)
 869      | otherwise     = (stable_obj, stable_bco)
 870      where
 871         scc = flattenSCC scc0
 872         scc_mods = map ms_mod scc
 873         home_module m   = m `elem` all_home_mods && m `notElem` scc_mods
 874
 875         scc_allimps = nub (filter home_module (concatMap ms_allimps scc))
 876             -- all imports outside the current SCC, but in the home pkg
 877
 878         stable_obj_imps = map (`elem` stable_obj) scc_allimps
 879         stable_bco_imps = map (`elem` stable_bco) scc_allimps
 880
 881         stableObjects =
 882            and stable_obj_imps
 883            && all object_ok scc
 884
 885         stableBCOs =
 886            and (zipWith (||) stable_obj_imps stable_bco_imps)
 887            && all bco_ok scc
 888
 889         object_ok ms
 890           | Just t <- ms_obj_date ms  =  t >= ms_hs_date ms
 891                                          && same_as_prev t
 892           | otherwise = False
 893           where
 894              same_as_prev t = case lookupModuleEnv hpt (ms_mod ms) of
 895                                 Just hmi  | Just l <- hm_linkable hmi
 896                                  -> isObjectLinkable l && t == linkableTime l
 897                                 _other  -> True
 898                 -- why '>=' rather than '>' above?  If the filesystem stores
 899                 -- times to the nearset second, we may occasionally find that
 900                 -- the object & source have the same modification time,
 901                 -- especially if the source was automatically generated
 902                 -- and compiled.  Using >= is slightly unsafe, but it matches
 903                 -- make's behaviour.
 904
 905         bco_ok ms
 906           = case lookupModuleEnv hpt (ms_mod ms) of
 907                 Just hmi  | Just l <- hm_linkable hmi ->
 908                         not (isObjectLinkable l) &&
 909                         linkableTime l >= ms_hs_date ms
 910                 _other  -> False
 911
 912 ms_allimps :: ModSummary -> [Module]
 913 ms_allimps ms = map unLoc (ms_srcimps ms ++ ms_imps ms)
 914
 915 -- -----------------------------------------------------------------------------
 916 -- Prune the HomePackageTable
 917
 918 -- Before doing an upsweep, we can throw away:
 919 --
 920 --   - For non-stable modules:
 921 --      - all ModDetails, all linked code
 922 --   - all unlinked code that is out of date with respect to
 923 --     the source file
 924 --
 925 -- This is VERY IMPORTANT otherwise we'll end up requiring 2x the
 926 -- space at the end of the upsweep, because the topmost ModDetails of the
 927 -- old HPT holds on to the entire type environment from the previous
 928 -- compilation.
 929
 930 pruneHomePackageTable
 931    :: HomePackageTable
 932    -> [ModSummary]
 933    -> ([Module],[Module])
 934    -> HomePackageTable
 935
 936 pruneHomePackageTable hpt summ (stable_obj, stable_bco)
 937   = mapModuleEnv prune hpt
 938   where prune hmi
 939           | is_stable modl = hmi'
 940           | otherwise      = hmi'{ hm_details = emptyModDetails }
 941           where
 942            modl = mi_module (hm_iface hmi)
 943            hmi' | Just l <- hm_linkable hmi, linkableTime l < ms_hs_date ms
 944                 = hmi{ hm_linkable = Nothing }
 945                 | otherwise
 946                 = hmi
 947                 where ms = expectJust "prune" (lookupModuleEnv ms_map modl)
 948
 949         ms_map = mkModuleEnv [(ms_mod ms, ms) | ms <- summ]
 950
 951         is_stable m = m `elem` stable_obj || m `elem` stable_bco
 952
 953 -- -----------------------------------------------------------------------------
 954
 955 -- Return (names of) all those in modsDone who are part of a cycle
 956 -- as defined by theGraph.
 957 findPartiallyCompletedCycles :: [Module] -> [SCC ModSummary] -> [Module]
 958 findPartiallyCompletedCycles modsDone theGraph
 959    = chew theGraph
 960      where
 961         chew [] = []
 962         chew ((AcyclicSCC v):rest) = chew rest    -- acyclic?  not interesting.
 963         chew ((CyclicSCC vs):rest)
 964            = let names_in_this_cycle = nub (map ms_mod vs)
 965                  mods_in_this_cycle
 966                     = nub ([done | done <- modsDone,
 967                                    done `elem` names_in_this_cycle])
 968                  chewed_rest = chew rest
 969              in
 970              if   notNull mods_in_this_cycle
 971                   && length mods_in_this_cycle < length names_in_this_cycle
 972              then mods_in_this_cycle ++ chewed_rest
 973              else chewed_rest
 974
 975 -- -----------------------------------------------------------------------------
 976 -- The upsweep
 977
 978 -- This is where we compile each module in the module graph, in a pass
 979 -- from the bottom to the top of the graph.
 980
 981 -- There better had not be any cyclic groups here -- we check for them.
 982
 983 upsweep
 984     :: HscEnv                   -- Includes initially-empty HPT
 985     -> HomePackageTable         -- HPT from last time round (pruned)
 986     -> ([Module],[Module])      -- stable modules (see checkStability)
 987     -> IO ()                    -- How to clean up unwanted tmp files
 988     -> [SCC ModSummary]         -- Mods to do (the worklist)
 989     -> IO (SuccessFlag,
 990            HscEnv,              -- With an updated HPT
 991            [ModSummary])        -- Mods which succeeded
 992
 993 upsweep hsc_env old_hpt stable_mods cleanup mods
 994    = upsweep' hsc_env old_hpt stable_mods cleanup mods 1 (length mods)
 995
 996 upsweep' hsc_env old_hpt stable_mods cleanup
 997      [] _ _
 998    = return (Succeeded, hsc_env, [])
 999
1000 upsweep' hsc_env old_hpt stable_mods cleanup
1001      (CyclicSCC ms:_) _ _
1002    = do fatalErrorMsg (hsc_dflags hsc_env) (cyclicModuleErr ms)
1003         return (Failed, hsc_env, [])
1004
1005 upsweep' hsc_env old_hpt stable_mods cleanup
1006      (AcyclicSCC mod:mods) mod_index nmods
1007    = do -- putStrLn ("UPSWEEP_MOD: hpt = " ++
1008         --           show (map (moduleUserString.moduleName.mi_module.hm_iface)
1009         --                     (moduleEnvElts (hsc_HPT hsc_env)))
1010
1011         mb_mod_info <- upsweep_mod hsc_env old_hpt stable_mods mod
1012                        mod_index nmods
1013
1014         cleanup         -- Remove unwanted tmp files between compilations
1015
1016         case mb_mod_info of
1017             Nothing -> return (Failed, hsc_env, [])
1018             Just mod_info -> do
1019                 { let this_mod = ms_mod mod
1020
1021                         -- Add new info to hsc_env
1022                       hpt1     = extendModuleEnv (hsc_HPT hsc_env)
1023                                         this_mod mod_info
1024                       hsc_env1 = hsc_env { hsc_HPT = hpt1 }
1025
1026                         -- Space-saving: delete the old HPT entry
1027                         -- for mod BUT if mod is a hs-boot
1028                         -- node, don't delete it.  For the
1029                         -- interface, the HPT entry is probaby for the
1030                         -- main Haskell source file.  Deleting it
1031                         -- would force .. (what?? --SDM)
1032                       old_hpt1 | isBootSummary mod = old_hpt
1033                                | otherwise = delModuleEnv old_hpt this_mod
1034
1035                 ; (restOK, hsc_env2, modOKs)
1036                         <- upsweep' hsc_env1 old_hpt1 stable_mods cleanup
1037                                 mods (mod_index+1) nmods
1038                 ; return (restOK, hsc_env2, mod:modOKs)
1039                 }
1040
1041
1042 -- Compile a single module.  Always produce a Linkable for it if
1043 -- successful.  If no compilation happened, return the old Linkable.
1044 upsweep_mod :: HscEnv
1045             -> HomePackageTable
1046             -> ([Module],[Module])
1047             -> ModSummary
1048             -> Int  -- index of module
1049             -> Int  -- total number of modules
1050             -> IO (Maybe HomeModInfo)   -- Nothing => Failed
1051
1052 upsweep_mod hsc_env old_hpt (stable_obj, stable_bco) summary mod_index nmods
1053    = do
1054         let
1055             this_mod    = ms_mod summary
1056             mb_obj_date = ms_obj_date summary
1057             obj_fn      = ml_obj_file (ms_location summary)
1058             hs_date     = ms_hs_date summary
1059
1060             compile_it :: Maybe Linkable -> IO (Maybe HomeModInfo)
1061             compile_it  = upsweep_compile hsc_env old_hpt this_mod
1062                                 summary mod_index nmods
1063
1064         case ghcMode (hsc_dflags hsc_env) of
1065             BatchCompile ->
1066                 case () of
1067                    -- Batch-compilating is easy: just check whether we have
1068                    -- an up-to-date object file.  If we do, then the compiler
1069                    -- needs to do a recompilation check.
1070                    _ | Just obj_date <- mb_obj_date, obj_date >= hs_date -> do
1071                            linkable <-
1072                                 findObjectLinkable this_mod obj_fn obj_date
1073                            compile_it (Just linkable)
1074
1075                      | otherwise ->
1076                            compile_it Nothing
1077
1078             interactive ->
1079                 case () of
1080                     _ | is_stable_obj, isJust old_hmi ->
1081                            return old_hmi
1082                         -- object is stable, and we have an entry in the
1083                         -- old HPT: nothing to do
1084
1085                       | is_stable_obj, isNothing old_hmi -> do
1086                            linkable <-
1087                                 findObjectLinkable this_mod obj_fn
1088                                         (expectJust "upseep1" mb_obj_date)
1089                            compile_it (Just linkable)
1090                         -- object is stable, but we need to load the interface
1091                         -- off disk to make a HMI.
1092
1093                       | is_stable_bco ->
1094                            ASSERT(isJust old_hmi) -- must be in the old_hpt
1095                            return old_hmi
1096                         -- BCO is stable: nothing to do
1097
1098                       | Just hmi <- old_hmi,
1099                         Just l <- hm_linkable hmi, not (isObjectLinkable l),
1100                         linkableTime l >= ms_hs_date summary ->
1101                            compile_it (Just l)
1102                         -- we have an old BCO that is up to date with respect
1103                         -- to the source: do a recompilation check as normal.
1104
1105                       | otherwise ->
1106                           compile_it Nothing
1107                         -- no existing code at all: we must recompile.
1108                    where
1109                     is_stable_obj = this_mod `elem` stable_obj
1110                     is_stable_bco = this_mod `elem` stable_bco
1111
1112                     old_hmi = lookupModuleEnv old_hpt this_mod
1113
1114 -- Run hsc to compile a module
1115 upsweep_compile hsc_env old_hpt this_mod summary
1116                 mod_index nmods
1117                 mb_old_linkable = do
1118   let
1119         -- The old interface is ok if it's in the old HPT
1120         --      a) we're compiling a source file, and the old HPT
1121         --         entry is for a source file
1122         --      b) we're compiling a hs-boot file
1123         -- Case (b) allows an hs-boot file to get the interface of its
1124         -- real source file on the second iteration of the compilation
1125         -- manager, but that does no harm.  Otherwise the hs-boot file
1126         -- will always be recompiled
1127
1128         mb_old_iface
1129                 = case lookupModuleEnv old_hpt this_mod of
1130                      Nothing                              -> Nothing
1131                      Just hm_info | isBootSummary summary -> Just iface
1132                                   | not (mi_boot iface)   -> Just iface
1133                                   | otherwise             -> Nothing
1134                                    where
1135                                      iface = hm_iface hm_info
1136
1137   compresult <- compile hsc_env summary mb_old_linkable mb_old_iface
1138                         mod_index nmods
1139
1140   case compresult of
1141         -- Compilation failed.  Compile may still have updated the PCS, tho.
1142         CompErrs -> return Nothing
1143
1144         -- Compilation "succeeded", and may or may not have returned a new
1145         -- linkable (depending on whether compilation was actually performed
1146         -- or not).
1147         CompOK new_details new_iface new_linkable
1148               -> do let new_info = HomeModInfo { hm_iface = new_iface,
1149                                                  hm_details = new_details,
1150                                                  hm_linkable = new_linkable }
1151                     return (Just new_info)
1152
1153
1154 -- Filter modules in the HPT
1155 retainInTopLevelEnvs :: [Module] -> HomePackageTable -> HomePackageTable
1156 retainInTopLevelEnvs keep_these hpt
1157    = mkModuleEnv [ (mod, expectJust "retain" mb_mod_info)
1158                  | mod <- keep_these
1159                  , let mb_mod_info = lookupModuleEnv hpt mod
1160                  , isJust mb_mod_info ]
1161
1162 -- ---------------------------------------------------------------------------
1163 -- Topological sort of the module graph
1164
1165 topSortModuleGraph
1166           :: Bool               -- Drop hi-boot nodes? (see below)
1167           -> [ModSummary]
1168           -> Maybe Module
1169           -> [SCC ModSummary]
1170 -- Calculate SCCs of the module graph, possibly dropping the hi-boot nodes
1171 -- The resulting list of strongly-connected-components is in topologically
1172 -- sorted order, starting with the module(s) at the bottom of the
1173 -- dependency graph (ie compile them first) and ending with the ones at
1174 -- the top.
1175 --
1176 -- Drop hi-boot nodes (first boolean arg)?
1177 --
1178 --   False:     treat the hi-boot summaries as nodes of the graph,
1179 --              so the graph must be acyclic
1180 --
1181 --   True:      eliminate the hi-boot nodes, and instead pretend
1182 --              the a source-import of Foo is an import of Foo
1183 --              The resulting graph has no hi-boot nodes, but can by cyclic
1184
1185 topSortModuleGraph drop_hs_boot_nodes summaries Nothing
1186   = stronglyConnComp (fst (moduleGraphNodes drop_hs_boot_nodes summaries))
1187 topSortModuleGraph drop_hs_boot_nodes summaries (Just mod)
1188   = stronglyConnComp (map vertex_fn (reachable graph root))
1189   where
1190         -- restrict the graph to just those modules reachable from
1191         -- the specified module.  We do this by building a graph with
1192         -- the full set of nodes, and determining the reachable set from
1193         -- the specified node.
1194         (nodes, lookup_key) = moduleGraphNodes drop_hs_boot_nodes summaries
1195         (graph, vertex_fn, key_fn) = graphFromEdges' nodes
1196         root
1197           | Just key <- lookup_key HsSrcFile mod, Just v <- key_fn key = v
1198           | otherwise  = throwDyn (ProgramError "module does not exist")
1199
1200 moduleGraphNodes :: Bool -> [ModSummary]
1201   -> ([(ModSummary, Int, [Int])], HscSource -> Module -> Maybe Int)
1202 moduleGraphNodes drop_hs_boot_nodes summaries = (nodes, lookup_key)
1203    where
1204         -- Drop hs-boot nodes by using HsSrcFile as the key
1205         hs_boot_key | drop_hs_boot_nodes = HsSrcFile
1206                     | otherwise          = HsBootFile
1207
1208         -- We use integers as the keys for the SCC algorithm
1209         nodes :: [(ModSummary, Int, [Int])]
1210         nodes = [(s, expectJust "topSort" (lookup_key (ms_hsc_src s) (ms_mod s)),
1211                      out_edge_keys hs_boot_key (map unLoc (ms_srcimps s)) ++
1212                      out_edge_keys HsSrcFile   (map unLoc (ms_imps s))    )
1213                 | s <- summaries
1214                 , not (isBootSummary s && drop_hs_boot_nodes) ]
1215                 -- Drop the hi-boot ones if told to do so
1216
1217         key_map :: NodeMap Int
1218         key_map = listToFM ([(ms_mod s, ms_hsc_src s) | s <- summaries]
1219                            `zip` [1..])
1220
1221         lookup_key :: HscSource -> Module -> Maybe Int
1222         lookup_key hs_src mod = lookupFM key_map (mod, hs_src)
1223
1224         out_edge_keys :: HscSource -> [Module] -> [Int]
1225         out_edge_keys hi_boot ms = mapCatMaybes (lookup_key hi_boot) ms
1226                 -- If we want keep_hi_boot_nodes, then we do lookup_key with
1227                 -- the IsBootInterface parameter True; else False
1228
1229
1230 type NodeKey   = (Module, HscSource)      -- The nodes of the graph are
1231 type NodeMap a = FiniteMap NodeKey a      -- keyed by (mod, src_file_type) pairs
1232
1233 msKey :: ModSummary -> NodeKey
1234 msKey (ModSummary { ms_mod = mod, ms_hsc_src = boot }) = (mod,boot)
1235
1236 mkNodeMap :: [ModSummary] -> NodeMap ModSummary
1237 mkNodeMap summaries = listToFM [ (msKey s, s) | s <- summaries]
1238
1239 nodeMapElts :: NodeMap a -> [a]
1240 nodeMapElts = eltsFM
1241
1242 -----------------------------------------------------------------------------
1243 -- Downsweep (dependency analysis)
1244
1245 -- Chase downwards from the specified root set, returning summaries
1246 -- for all home modules encountered.  Only follow source-import
1247 -- links.
1248
1249 -- We pass in the previous collection of summaries, which is used as a
1250 -- cache to avoid recalculating a module summary if the source is
1251 -- unchanged.
1252 --
1253 -- The returned list of [ModSummary] nodes has one node for each home-package
1254 -- module, plus one for any hs-boot files.  The imports of these nodes
1255 -- are all there, including the imports of non-home-package modules.
1256
1257 downsweep :: HscEnv
1258           -> [ModSummary]       -- Old summaries
1259           -> [Module]           -- Ignore dependencies on these; treat
1260                                 -- them as if they were package modules
1261           -> Bool               -- True <=> allow multiple targets to have
1262                                 --          the same module name; this is
1263                                 --          very useful for ghc -M
1264           -> IO (Maybe [ModSummary])
1265                 -- The elts of [ModSummary] all have distinct
1266                 -- (Modules, IsBoot) identifiers, unless the Bool is true
1267                 -- in which case there can be repeats
1268 downsweep hsc_env old_summaries excl_mods allow_dup_roots
1269    = -- catch error messages and return them
1270      handleDyn (\err_msg -> printBagOfErrors (hsc_dflags hsc_env) (unitBag err_msg) >> return Nothing) $ do
1271        rootSummaries <- mapM getRootSummary roots
1272        let root_map = mkRootMap rootSummaries
1273        checkDuplicates root_map
1274        summs <- loop (concatMap msDeps rootSummaries) root_map
1275        return (Just summs)
1276      where
1277         roots = hsc_targets hsc_env
1278
1279         old_summary_map :: NodeMap ModSummary
1280         old_summary_map = mkNodeMap old_summaries
1281
1282         getRootSummary :: Target -> IO ModSummary
1283         getRootSummary (Target (TargetFile file mb_phase) maybe_buf)
1284            = do exists <- doesFileExist file
1285                 if exists
1286                     then summariseFile hsc_env old_summaries file mb_phase maybe_buf
1287                     else throwDyn $ mkPlainErrMsg noSrcSpan $
1288                            text "can't find file:" <+> text file
1289         getRootSummary (Target (TargetModule modl) maybe_buf)
1290            = do maybe_summary <- summariseModule hsc_env old_summary_map False
1291                                            (L rootLoc modl) maybe_buf excl_mods
1292                 case maybe_summary of
1293                    Nothing -> packageModErr modl
1294                    Just s  -> return s
1295
1296         rootLoc = mkGeneralSrcSpan FSLIT("<command line>")
1297
1298         -- In a root module, the filename is allowed to diverge from the module
1299         -- name, so we have to check that there aren't multiple root files
1300         -- defining the same module (otherwise the duplicates will be silently
1301         -- ignored, leading to confusing behaviour).
1302         checkDuplicates :: NodeMap [ModSummary] -> IO ()
1303         checkDuplicates root_map
1304            | allow_dup_roots = return ()
1305            | null dup_roots  = return ()
1306            | otherwise       = multiRootsErr (head dup_roots)
1307            where
1308              dup_roots :: [[ModSummary]]        -- Each at least of length 2
1309              dup_roots = filterOut isSingleton (nodeMapElts root_map)
1310
1311         loop :: [(Located Module,IsBootInterface)]
1312                         -- Work list: process these modules
1313              -> NodeMap [ModSummary]
1314                         -- Visited set; the range is a list because
1315                         -- the roots can have the same module names
1316                         -- if allow_dup_roots is True
1317              -> IO [ModSummary]
1318                         -- The result includes the worklist, except
1319                         -- for those mentioned in the visited set
1320         loop [] done      = return (concat (nodeMapElts done))
1321         loop ((wanted_mod, is_boot) : ss) done
1322           | Just summs <- lookupFM done key
1323           = if isSingleton summs then
1324                 loop ss done
1325             else
1326                 do { multiRootsErr summs; return [] }
1327           | otherwise         = do { mb_s <- summariseModule hsc_env old_summary_map
1328                                                  is_boot wanted_mod Nothing excl_mods
1329                                    ; case mb_s of
1330                                         Nothing -> loop ss done
1331                                         Just s  -> loop (msDeps s ++ ss)
1332                                                         (addToFM done key [s]) }
1333           where
1334             key = (unLoc wanted_mod, if is_boot then HsBootFile else HsSrcFile)
1335
1336 mkRootMap :: [ModSummary] -> NodeMap [ModSummary]
1337 mkRootMap summaries = addListToFM_C (++) emptyFM
1338                         [ (msKey s, [s]) | s <- summaries ]
1339
1340 msDeps :: ModSummary -> [(Located Module, IsBootInterface)]
1341 -- (msDeps s) returns the dependencies of the ModSummary s.
1342 -- A wrinkle is that for a {-# SOURCE #-} import we return
1343 --      *both* the hs-boot file
1344 --      *and* the source file
1345 -- as "dependencies".  That ensures that the list of all relevant
1346 -- modules always contains B.hs if it contains B.hs-boot.
1347 -- Remember, this pass isn't doing the topological sort.  It's
1348 -- just gathering the list of all relevant ModSummaries
1349 msDeps s =
1350     concat [ [(m,True), (m,False)] | m <- ms_srcimps s ]
1351          ++ [ (m,False) | m <- ms_imps s ]
1352
1353 -----------------------------------------------------------------------------
1354 -- Summarising modules
1355
1356 -- We have two types of summarisation:
1357 --
1358 --    * Summarise a file.  This is used for the root module(s) passed to
1359 --      cmLoadModules.  The file is read, and used to determine the root
1360 --      module name.  The module name may differ from the filename.
1361 --
1362 --    * Summarise a module.  We are given a module name, and must provide
1363 --      a summary.  The finder is used to locate the file in which the module
1364 --      resides.
1365
1366 summariseFile
1367         :: HscEnv
1368         -> [ModSummary]                 -- old summaries
1369         -> FilePath                     -- source file name
1370         -> Maybe Phase                  -- start phase
1371         -> Maybe (StringBuffer,ClockTime)
1372         -> IO ModSummary
1373
1374 summariseFile hsc_env old_summaries file mb_phase maybe_buf
1375         -- we can use a cached summary if one is available and the
1376         -- source file hasn't changed,  But we have to look up the summary
1377         -- by source file, rather than module name as we do in summarise.
1378    | Just old_summary <- findSummaryBySourceFile old_summaries file
1379    = do
1380         let location = ms_location old_summary
1381
1382                 -- return the cached summary if the source didn't change
1383         src_timestamp <- case maybe_buf of
1384                            Just (_,t) -> return t
1385                            Nothing    -> getModificationTime file
1386                 -- The file exists; we checked in getRootSummary above.
1387                 -- If it gets removed subsequently, then this
1388                 -- getModificationTime may fail, but that's the right
1389                 -- behaviour.
1390
1391         if ms_hs_date old_summary == src_timestamp
1392            then do -- update the object-file timestamp
1393                   obj_timestamp <- getObjTimestamp location False
1394                   return old_summary{ ms_obj_date = obj_timestamp }
1395            else
1396                 new_summary
1397
1398    | otherwise
1399    = new_summary
1400   where
1401     new_summary = do
1402         let dflags = hsc_dflags hsc_env
1403
1404         (dflags', hspp_fn, buf)
1405             <- preprocessFile dflags file mb_phase maybe_buf
1406
1407         (srcimps,the_imps, L _ mod) <- getImports dflags' buf hspp_fn
1408
1409         -- Make a ModLocation for this file
1410         location <- mkHomeModLocation dflags mod file
1411
1412         -- Tell the Finder cache where it is, so that subsequent calls
1413         -- to findModule will find it, even if it's not on any search path
1414         addHomeModuleToFinder hsc_env mod location
1415
1416         src_timestamp <- case maybe_buf of
1417                            Just (_,t) -> return t
1418                            Nothing    -> getModificationTime file
1419                         -- getMofificationTime may fail
1420
1421         obj_timestamp <- modificationTimeIfExists (ml_obj_file location)
1422
1423         return (ModSummary { ms_mod = mod, ms_hsc_src = HsSrcFile,
1424                              ms_location = location,
1425                              ms_hspp_file = hspp_fn,
1426                              ms_hspp_opts = dflags',
1427                              ms_hspp_buf  = Just buf,
1428                              ms_srcimps = srcimps, ms_imps = the_imps,
1429                              ms_hs_date = src_timestamp,
1430                              ms_obj_date = obj_timestamp })
1431
1432 findSummaryBySourceFile :: [ModSummary] -> FilePath -> Maybe ModSummary
1433 findSummaryBySourceFile summaries file
1434   = case [ ms | ms <- summaries, HsSrcFile <- [ms_hsc_src ms],
1435                                  expectJust "findSummaryBySourceFile" (ml_hs_file (ms_location ms)) == file ] of
1436         [] -> Nothing
1437         (x:xs) -> Just x
1438
1439 -- Summarise a module, and pick up source and timestamp.
1440 summariseModule
1441           :: HscEnv
1442           -> NodeMap ModSummary -- Map of old summaries
1443           -> IsBootInterface    -- True <=> a {-# SOURCE #-} import
1444           -> Located Module     -- Imported module to be summarised
1445           -> Maybe (StringBuffer, ClockTime)
1446           -> [Module]           -- Modules to exclude
1447           -> IO (Maybe ModSummary)      -- Its new summary
1448
1449 summariseModule hsc_env old_summary_map is_boot (L loc wanted_mod) maybe_buf excl_mods
1450   | wanted_mod `elem` excl_mods
1451   = return Nothing
1452
1453   | Just old_summary <- lookupFM old_summary_map (wanted_mod, hsc_src)
1454   = do          -- Find its new timestamp; all the
1455                 -- ModSummaries in the old map have valid ml_hs_files
1456         let location = ms_location old_summary
1457             src_fn = expectJust "summariseModule" (ml_hs_file location)
1458
1459                 -- check the modification time on the source file, and
1460                 -- return the cached summary if it hasn't changed.  If the
1461                 -- file has disappeared, we need to call the Finder again.
1462         case maybe_buf of
1463            Just (_,t) -> check_timestamp old_summary location src_fn t
1464            Nothing    -> do
1465                 m <- System.IO.Error.try (getModificationTime src_fn)
1466                 case m of
1467                    Right t -> check_timestamp old_summary location src_fn t
1468                    Left e | isDoesNotExistError e -> find_it
1469                           | otherwise             -> ioError e
1470
1471   | otherwise  = find_it
1472   where
1473     dflags = hsc_dflags hsc_env
1474
1475     hsc_src = if is_boot then HsBootFile else HsSrcFile
1476
1477     check_timestamp old_summary location src_fn src_timestamp
1478         | ms_hs_date old_summary == src_timestamp = do
1479                 -- update the object-file timestamp
1480                 obj_timestamp <- getObjTimestamp location is_boot
1481                 return (Just old_summary{ ms_obj_date = obj_timestamp })
1482         | otherwise =
1483                 -- source changed: find and re-summarise.  We call the finder
1484                 -- again, because the user may have moved the source file.
1485                 new_summary location src_fn src_timestamp
1486
1487     find_it = do
1488         -- Don't use the Finder's cache this time.  If the module was
1489         -- previously a package module, it may have now appeared on the
1490         -- search path, so we want to consider it to be a home module.  If
1491         -- the module was previously a home module, it may have moved.
1492         uncacheModule hsc_env wanted_mod
1493         found <- findModule hsc_env wanted_mod True {-explicit-}
1494         case found of
1495              Found location pkg
1496                 | not (isHomePackage pkg) -> return Nothing
1497                         -- Drop external-pkg
1498                 | isJust (ml_hs_file location) -> just_found location
1499                         -- Home package
1500              err -> noModError dflags loc wanted_mod err
1501                         -- Not found
1502
1503     just_found location = do
1504                 -- Adjust location to point to the hs-boot source file,
1505                 -- hi file, object file, when is_boot says so
1506         let location' | is_boot   = addBootSuffixLocn location
1507                       | otherwise = location
1508             src_fn = expectJust "summarise2" (ml_hs_file location')
1509
1510                 -- Check that it exists
1511                 -- It might have been deleted since the Finder last found it
1512         maybe_t <- modificationTimeIfExists src_fn
1513         case maybe_t of
1514           Nothing -> noHsFileErr loc src_fn
1515           Just t  -> new_summary location' src_fn t
1516
1517
1518     new_summary location src_fn src_timestamp
1519       = do
1520         -- Preprocess the source file and get its imports
1521         -- The dflags' contains the OPTIONS pragmas
1522         (dflags', hspp_fn, buf) <- preprocessFile dflags src_fn Nothing maybe_buf
1523         (srcimps, the_imps, L mod_loc mod_name) <- getImports dflags' buf hspp_fn
1524
1525         when (mod_name /= wanted_mod) $
1526                 throwDyn $ mkPlainErrMsg mod_loc $
1527                               text "file name does not match module name"
1528                               <+> quotes (ppr mod_name)
1529
1530                 -- Find the object timestamp, and return the summary
1531         obj_timestamp <- getObjTimestamp location is_boot
1532
1533         return (Just ( ModSummary { ms_mod       = wanted_mod,
1534                                     ms_hsc_src   = hsc_src,
1535                                     ms_location  = location,
1536                                     ms_hspp_file = hspp_fn,
1537                                     ms_hspp_opts = dflags',
1538                                     ms_hspp_buf  = Just buf,
1539                                     ms_srcimps   = srcimps,
1540                                     ms_imps      = the_imps,
1541                                     ms_hs_date   = src_timestamp,
1542                                     ms_obj_date  = obj_timestamp }))
1543
1544
1545 getObjTimestamp location is_boot
1546   = if is_boot then return Nothing
1547                else modificationTimeIfExists (ml_obj_file location)
1548
1549
1550 preprocessFile :: DynFlags -> FilePath -> Maybe Phase -> Maybe (StringBuffer,ClockTime)
1551   -> IO (DynFlags, FilePath, StringBuffer)
1552 preprocessFile dflags src_fn mb_phase Nothing
1553   = do
1554         (dflags', hspp_fn) <- preprocess dflags (src_fn, mb_phase)
1555         buf <- hGetStringBuffer hspp_fn
1556         return (dflags', hspp_fn, buf)
1557
1558 preprocessFile dflags src_fn mb_phase (Just (buf, time))
1559   = do
1560         -- case we bypass the preprocessing stage?
1561         let
1562             local_opts = getOptions buf src_fn
1563         --
1564         (dflags', errs) <- parseDynamicFlags dflags (map unLoc local_opts)
1565
1566         let
1567             needs_preprocessing
1568                 | Just (Unlit _) <- mb_phase    = True
1569                 | Nothing <- mb_phase, Unlit _ <- startPhase src_fn  = True
1570                   -- note: local_opts is only required if there's no Unlit phase
1571                 | dopt Opt_Cpp dflags'          = True
1572                 | dopt Opt_Pp  dflags'          = True
1573                 | otherwise                     = False
1574
1575         when needs_preprocessing $
1576            ghcError (ProgramError "buffer needs preprocesing; interactive check disabled")
1577
1578         return (dflags', src_fn, buf)
1579
1580
1581 -----------------------------------------------------------------------------
1582 --                      Error messages
1583 -----------------------------------------------------------------------------
1584
1585 noModError :: DynFlags -> SrcSpan -> Module -> FindResult -> IO ab
1586 -- ToDo: we don't have a proper line number for this error
1587 noModError dflags loc wanted_mod err
1588   = throwDyn $ mkPlainErrMsg loc $ cantFindError dflags wanted_mod err
1589
1590 noHsFileErr loc path
1591   = throwDyn $ mkPlainErrMsg loc $ text "Can't find" <+> text path
1592
1593 packageModErr mod
1594   = throwDyn $ mkPlainErrMsg noSrcSpan $
1595         text "module" <+> quotes (ppr mod) <+> text "is a package module"
1596
1597 multiRootsErr :: [ModSummary] -> IO ()
1598 multiRootsErr summs@(summ1:_)
1599   = throwDyn $ mkPlainErrMsg noSrcSpan $
1600         text "module" <+> quotes (ppr mod) <+>
1601         text "is defined in multiple files:" <+>
1602         sep (map text files)
1603   where
1604     mod = ms_mod summ1
1605     files = map (expectJust "checkDup" . ml_hs_file . ms_location) summs
1606
1607 cyclicModuleErr :: [ModSummary] -> SDoc
1608 cyclicModuleErr ms
1609   = hang (ptext SLIT("Module imports form a cycle for modules:"))
1610        2 (vcat (map show_one ms))
1611   where
1612     show_one ms = sep [ show_mod (ms_hsc_src ms) (ms_mod ms),
1613                         nest 2 $ ptext SLIT("imports:") <+>
1614                                    (pp_imps HsBootFile (ms_srcimps ms)
1615                                    $$ pp_imps HsSrcFile  (ms_imps ms))]
1616     show_mod hsc_src mod = ppr mod <> text (hscSourceString hsc_src)
1617     pp_imps src mods = fsep (map (show_mod src) mods)
1618
1619
1620 -- | Inform GHC that the working directory has changed.  GHC will flush
1621 -- its cache of module locations, since it may no longer be valid.
1622 -- Note: if you change the working directory, you should also unload
1623 -- the current program (set targets to empty, followed by load).
1624 workingDirectoryChanged :: Session -> IO ()
1625 workingDirectoryChanged s = withSession s $ \hsc_env ->
1626   flushFinderCache (hsc_FC hsc_env)
1627
1628 -- -----------------------------------------------------------------------------
1629 -- inspecting the session
1630
1631 -- | Get the module dependency graph.
1632 getModuleGraph :: Session -> IO ModuleGraph -- ToDo: DiGraph ModSummary
1633 getModuleGraph s = withSession s (return . hsc_mod_graph)
1634
1635 isLoaded :: Session -> Module -> IO Bool
1636 isLoaded s m = withSession s $ \hsc_env ->
1637   return $! isJust (lookupModuleEnv (hsc_HPT hsc_env) m)
1638
1639 getBindings :: Session -> IO [TyThing]
1640 getBindings s = withSession s (return . nameEnvElts . ic_type_env . hsc_IC)
1641
1642 getPrintUnqual :: Session -> IO PrintUnqualified
1643 getPrintUnqual s = withSession s (return . icPrintUnqual . hsc_IC)
1644
1645 -- | Container for information about a 'Module'.
1646 data ModuleInfo = ModuleInfo {
1647         minf_type_env  :: TypeEnv,
1648         minf_exports   :: NameSet,
1649         minf_rdr_env   :: Maybe GlobalRdrEnv,   -- Nothing for a compiled/package mod
1650         minf_instances :: [Instance]
1651         -- ToDo: this should really contain the ModIface too
1652   }
1653         -- We don't want HomeModInfo here, because a ModuleInfo applies
1654         -- to package modules too.
1655
1656 -- | Request information about a loaded 'Module'
1657 getModuleInfo :: Session -> Module -> IO (Maybe ModuleInfo)
1658 getModuleInfo s mdl = withSession s $ \hsc_env -> do
1659   let mg = hsc_mod_graph hsc_env
1660   if mdl `elem` map ms_mod mg
1661         then getHomeModuleInfo hsc_env mdl
1662         else do
1663   {- if isHomeModule (hsc_dflags hsc_env) mdl
1664         then return Nothing
1665         else -} getPackageModuleInfo hsc_env mdl
1666    -- getPackageModuleInfo will attempt to find the interface, so
1667    -- we don't want to call it for a home module, just in case there
1668    -- was a problem loading the module and the interface doesn't
1669    -- exist... hence the isHomeModule test here.  (ToDo: reinstate)
1670
1671 getPackageModuleInfo :: HscEnv -> Module -> IO (Maybe ModuleInfo)
1672 getPackageModuleInfo hsc_env mdl = do
1673 #ifdef GHCI
1674   (_msgs, mb_names) <- getModuleExports hsc_env mdl
1675   case mb_names of
1676     Nothing -> return Nothing
1677     Just names -> do
1678         eps <- readIORef (hsc_EPS hsc_env)
1679         let
1680             pte    = eps_PTE eps
1681             n_list = nameSetToList names
1682             tys    = [ ty | name <- n_list,
1683                             Just ty <- [lookupTypeEnv pte name] ]
1684         --
1685         return (Just (ModuleInfo {
1686                         minf_type_env  = mkTypeEnv tys,
1687                         minf_exports   = names,
1688                         minf_rdr_env   = Just $! nameSetToGlobalRdrEnv names mdl,
1689                         minf_instances = error "getModuleInfo: instances for package module unimplemented"
1690                 }))
1691 #else
1692   -- bogusly different for non-GHCI (ToDo)
1693   return Nothing
1694 #endif
1695
1696 getHomeModuleInfo hsc_env mdl =
1697   case lookupModuleEnv (hsc_HPT hsc_env) mdl of
1698     Nothing  -> return Nothing
1699     Just hmi -> do
1700       let details = hm_details hmi
1701       return (Just (ModuleInfo {
1702                         minf_type_env  = md_types details,
1703                         minf_exports   = md_exports details,
1704                         minf_rdr_env   = mi_globals $! hm_iface hmi,
1705                         minf_instances = md_insts details
1706                         }))
1707
1708 -- | The list of top-level entities defined in a module
1709 modInfoTyThings :: ModuleInfo -> [TyThing]
1710 modInfoTyThings minf = typeEnvElts (minf_type_env minf)
1711
1712 modInfoTopLevelScope :: ModuleInfo -> Maybe [Name]
1713 modInfoTopLevelScope minf
1714   = fmap (map gre_name . globalRdrEnvElts) (minf_rdr_env minf)
1715
1716 modInfoExports :: ModuleInfo -> [Name]
1717 modInfoExports minf = nameSetToList $! minf_exports minf
1718
1719 -- | Returns the instances defined by the specified module.
1720 -- Warning: currently unimplemented for package modules.
1721 modInfoInstances :: ModuleInfo -> [Instance]
1722 modInfoInstances = minf_instances
1723
1724 modInfoIsExportedName :: ModuleInfo -> Name -> Bool
1725 modInfoIsExportedName minf name = elemNameSet name (minf_exports minf)
1726
1727 modInfoPrintUnqualified :: ModuleInfo -> Maybe PrintUnqualified
1728 modInfoPrintUnqualified minf = fmap unQualInScope (minf_rdr_env minf)
1729
1730 modInfoLookupName :: Session -> ModuleInfo -> Name -> IO (Maybe TyThing)
1731 modInfoLookupName s minf name = withSession s $ \hsc_env -> do
1732    case lookupTypeEnv (minf_type_env minf) name of
1733      Just tyThing -> return (Just tyThing)
1734      Nothing      -> do
1735        eps <- readIORef (hsc_EPS hsc_env)
1736        return $! lookupType (hsc_HPT hsc_env) (eps_PTE eps) name
1737
1738 isDictonaryId :: Id -> Bool
1739 isDictonaryId id
1740   = case tcSplitSigmaTy (idType id) of { (tvs, theta, tau) -> isDictTy tau }
1741
1742 -- | Looks up a global name: that is, any top-level name in any
1743 -- visible module.  Unlike 'lookupName', lookupGlobalName does not use
1744 -- the interactive context, and therefore does not require a preceding
1745 -- 'setContext'.
1746 lookupGlobalName :: Session -> Name -> IO (Maybe TyThing)
1747 lookupGlobalName s name = withSession s $ \hsc_env -> do
1748    eps <- readIORef (hsc_EPS hsc_env)
1749    return $! lookupType (hsc_HPT hsc_env) (eps_PTE eps) name
1750
1751 -- -----------------------------------------------------------------------------
1752 -- Misc exported utils
1753
1754 dataConType :: DataCon -> Type
1755 dataConType dc = idType (dataConWrapId dc)
1756
1757 -- | print a 'NamedThing', adding parentheses if the name is an operator.
1758 pprParenSymName :: NamedThing a => a -> SDoc
1759 pprParenSymName a = parenSymOcc (getOccName a) (ppr (getName a))
1760
1761 -- ----------------------------------------------------------------------------
1762
1763 #if 0
1764
1765 -- ToDo:
1766 --   - Data and Typeable instances for HsSyn.
1767
1768 -- ToDo: check for small transformations that happen to the syntax in
1769 -- the typechecker (eg. -e ==> negate e, perhaps for fromIntegral)
1770
1771 -- ToDo: maybe use TH syntax instead of IfaceSyn?  There's already a way
1772 -- to get from TyCons, Ids etc. to TH syntax (reify).
1773
1774 -- :browse will use either lm_toplev or inspect lm_interface, depending
1775 -- on whether the module is interpreted or not.
1776
1777 -- This is for reconstructing refactored source code
1778 -- Calls the lexer repeatedly.
1779 -- ToDo: add comment tokens to token stream
1780 getTokenStream :: Session -> Module -> IO [Located Token]
1781 #endif
1782
1783 -- -----------------------------------------------------------------------------
1784 -- Interactive evaluation
1785
1786 #ifdef GHCI
1787
1788 -- | Set the interactive evaluation context.
1789 --
1790 -- Setting the context doesn't throw away any bindings; the bindings
1791 -- we've built up in the InteractiveContext simply move to the new
1792 -- module.  They always shadow anything in scope in the current context.
1793 setContext :: Session
1794            -> [Module]  -- entire top level scope of these modules
1795            -> [Module]  -- exports only of these modules
1796            -> IO ()
1797 setContext (Session ref) toplevs exports = do
1798   hsc_env <- readIORef ref
1799   let old_ic  = hsc_IC     hsc_env
1800       hpt     = hsc_HPT    hsc_env
1801
1802   mapM_ (checkModuleExists hsc_env hpt) exports
1803   export_env  <- mkExportEnv hsc_env exports
1804   toplev_envs <- mapM (mkTopLevEnv hpt) toplevs
1805   let all_env = foldr plusGlobalRdrEnv export_env toplev_envs
1806   writeIORef ref hsc_env{ hsc_IC = old_ic { ic_toplev_scope = toplevs,
1807                                             ic_exports      = exports,
1808                                             ic_rn_gbl_env   = all_env }}
1809
1810
1811 -- Make a GlobalRdrEnv based on the exports of the modules only.
1812 mkExportEnv :: HscEnv -> [Module] -> IO GlobalRdrEnv
1813 mkExportEnv hsc_env mods = do
1814   stuff <- mapM (getModuleExports hsc_env) mods
1815   let
1816         (_msgs, mb_name_sets) = unzip stuff
1817         gres = [ nameSetToGlobalRdrEnv name_set mod
1818                | (Just name_set, mod) <- zip mb_name_sets mods ]
1819   --
1820   return $! foldr plusGlobalRdrEnv emptyGlobalRdrEnv gres
1821
1822 nameSetToGlobalRdrEnv :: NameSet -> Module -> GlobalRdrEnv
1823 nameSetToGlobalRdrEnv names mod =
1824   mkGlobalRdrEnv [ GRE  { gre_name = name, gre_prov = vanillaProv mod }
1825                  | name <- nameSetToList names ]
1826
1827 vanillaProv :: Module -> Provenance
1828 -- We're building a GlobalRdrEnv as if the user imported
1829 -- all the specified modules into the global interactive module
1830 vanillaProv mod = Imported [ImpSpec { is_decl = decl, is_item = ImpAll}]
1831   where
1832     decl = ImpDeclSpec { is_mod = mod, is_as = mod,
1833                          is_qual = False,
1834                          is_dloc = srcLocSpan interactiveSrcLoc }
1835
1836 checkModuleExists :: HscEnv -> HomePackageTable -> Module -> IO ()
1837 checkModuleExists hsc_env hpt mod =
1838   case lookupModuleEnv hpt mod of
1839     Just mod_info -> return ()
1840     _not_a_home_module -> do
1841           res <- findPackageModule hsc_env mod True
1842           case res of
1843             Found _ _ -> return  ()
1844             err -> let msg = cantFindError (hsc_dflags hsc_env) mod err in
1845                    throwDyn (CmdLineError (showSDoc msg))
1846
1847 mkTopLevEnv :: HomePackageTable -> Module -> IO GlobalRdrEnv
1848 mkTopLevEnv hpt modl
1849  = case lookupModuleEnv hpt modl of
1850       Nothing ->
1851          throwDyn (ProgramError ("mkTopLevEnv: not a home module "
1852                         ++ showSDoc (pprModule modl)))
1853       Just details ->
1854          case mi_globals (hm_iface details) of
1855                 Nothing  ->
1856                    throwDyn (ProgramError ("mkTopLevEnv: not interpreted "
1857                                                 ++ showSDoc (pprModule modl)))
1858                 Just env -> return env
1859
1860 -- | Get the interactive evaluation context, consisting of a pair of the
1861 -- set of modules from which we take the full top-level scope, and the set
1862 -- of modules from which we take just the exports respectively.
1863 getContext :: Session -> IO ([Module],[Module])
1864 getContext s = withSession s (\HscEnv{ hsc_IC=ic } ->
1865                                 return (ic_toplev_scope ic, ic_exports ic))
1866
1867 -- | Returns 'True' if the specified module is interpreted, and hence has
1868 -- its full top-level scope available.
1869 moduleIsInterpreted :: Session -> Module -> IO Bool
1870 moduleIsInterpreted s modl = withSession s $ \h ->
1871  case lookupModuleEnv (hsc_HPT h) modl of
1872       Just details       -> return (isJust (mi_globals (hm_iface details)))
1873       _not_a_home_module -> return False
1874
1875 -- | Looks up an identifier in the current interactive context (for :info)
1876 getInfo :: Session -> Name -> IO (Maybe (TyThing,Fixity,[Instance]))
1877 getInfo s name = withSession s $ \hsc_env -> tcRnGetInfo hsc_env name
1878
1879 -- | Returns all names in scope in the current interactive context
1880 getNamesInScope :: Session -> IO [Name]
1881 getNamesInScope s = withSession s $ \hsc_env -> do
1882   return (map gre_name (globalRdrEnvElts (ic_rn_gbl_env (hsc_IC hsc_env))))
1883
1884 getRdrNamesInScope :: Session -> IO [RdrName]
1885 getRdrNamesInScope  s = withSession s $ \hsc_env -> do
1886   let env = ic_rn_gbl_env (hsc_IC hsc_env)
1887   return (concat (map greToRdrNames (globalRdrEnvElts env)))
1888
1889 -- ToDo: move to RdrName
1890 greToRdrNames :: GlobalRdrElt -> [RdrName]
1891 greToRdrNames GRE{ gre_name = name, gre_prov = prov }
1892   = case prov of
1893      LocalDef -> [unqual]
1894      Imported specs -> concat (map do_spec (map is_decl specs))
1895   where
1896     occ = nameOccName name
1897     unqual = Unqual occ
1898     do_spec decl_spec
1899         | is_qual decl_spec = [qual]
1900         | otherwise         = [unqual,qual]
1901         where qual = Qual (is_as decl_spec) occ
1902
1903 -- | Parses a string as an identifier, and returns the list of 'Name's that
1904 -- the identifier can refer to in the current interactive context.
1905 parseName :: Session -> String -> IO [Name]
1906 parseName s str = withSession s $ \hsc_env -> do
1907    maybe_rdr_name <- hscParseIdentifier (hsc_dflags hsc_env) str
1908    case maybe_rdr_name of
1909         Nothing -> return []
1910         Just (L _ rdr_name) -> do
1911             mb_names <- tcRnLookupRdrName hsc_env rdr_name
1912             case mb_names of
1913                 Nothing -> return []
1914                 Just ns -> return ns
1915                 -- ToDo: should return error messages
1916
1917 -- | Returns the 'TyThing' for a 'Name'.  The 'Name' may refer to any
1918 -- entity known to GHC, including 'Name's defined using 'runStmt'.
1919 lookupName :: Session -> Name -> IO (Maybe TyThing)
1920 lookupName s name = withSession s $ \hsc_env -> tcRnLookupName hsc_env name
1921
1922 -- -----------------------------------------------------------------------------
1923 -- Getting the type of an expression
1924
1925 -- | Get the type of an expression
1926 exprType :: Session -> String -> IO (Maybe Type)
1927 exprType s expr = withSession s $ \hsc_env -> do
1928    maybe_stuff <- hscTcExpr hsc_env expr
1929    case maybe_stuff of
1930         Nothing -> return Nothing
1931         Just ty -> return (Just tidy_ty)
1932              where
1933                 tidy_ty = tidyType emptyTidyEnv ty
1934
1935 -- -----------------------------------------------------------------------------
1936 -- Getting the kind of a type
1937
1938 -- | Get the kind of a  type
1939 typeKind  :: Session -> String -> IO (Maybe Kind)
1940 typeKind s str = withSession s $ \hsc_env -> do
1941    maybe_stuff <- hscKcType hsc_env str
1942    case maybe_stuff of
1943         Nothing -> return Nothing
1944         Just kind -> return (Just kind)
1945
1946 -----------------------------------------------------------------------------
1947 -- cmCompileExpr: compile an expression and deliver an HValue
1948
1949 compileExpr :: Session -> String -> IO (Maybe HValue)
1950 compileExpr s expr = withSession s $ \hsc_env -> do
1951   maybe_stuff <- hscStmt hsc_env ("let __cmCompileExpr = "++expr)
1952   case maybe_stuff of
1953         Nothing -> return Nothing
1954         Just (new_ic, names, hval) -> do
1955                         -- Run it!
1956                 hvals <- (unsafeCoerce# hval) :: IO [HValue]
1957
1958                 case (names,hvals) of
1959                   ([n],[hv]) -> return (Just hv)
1960                   _          -> panic "compileExpr"
1961
1962 -- -----------------------------------------------------------------------------
1963 -- running a statement interactively
1964
1965 data RunResult
1966   = RunOk [Name]                -- ^ names bound by this evaluation
1967   | RunFailed                   -- ^ statement failed compilation
1968   | RunException Exception      -- ^ statement raised an exception
1969
1970 -- | Run a statement in the current interactive context.  Statemenet
1971 -- may bind multple values.
1972 runStmt :: Session -> String -> IO RunResult
1973 runStmt (Session ref) expr
1974    = do
1975         hsc_env <- readIORef ref
1976
1977         -- Turn off -fwarn-unused-bindings when running a statement, to hide
1978         -- warnings about the implicit bindings we introduce.
1979         let dflags'  = dopt_unset (hsc_dflags hsc_env) Opt_WarnUnusedBinds
1980             hsc_env' = hsc_env{ hsc_dflags = dflags' }
1981
1982         maybe_stuff <- hscStmt hsc_env' expr
1983
1984         case maybe_stuff of
1985            Nothing -> return RunFailed
1986            Just (new_hsc_env, names, hval) -> do
1987
1988                 let thing_to_run = unsafeCoerce# hval :: IO [HValue]
1989                 either_hvals <- sandboxIO thing_to_run
1990
1991                 case either_hvals of
1992                     Left e -> do
1993                         -- on error, keep the *old* interactive context,
1994                         -- so that 'it' is not bound to something
1995                         -- that doesn't exist.
1996                         return (RunException e)
1997
1998                     Right hvals -> do
1999                         -- Get the newly bound things, and bind them.
2000                         -- Don't need to delete any shadowed bindings;
2001                         -- the new ones override the old ones.
2002                         extendLinkEnv (zip names hvals)
2003
2004                         writeIORef ref new_hsc_env
2005                         return (RunOk names)
2006
2007 -- When running a computation, we redirect ^C exceptions to the running
2008 -- thread.  ToDo: we might want a way to continue even if the target
2009 -- thread doesn't die when it receives the exception... "this thread
2010 -- is not responding".
2011 sandboxIO :: IO a -> IO (Either Exception a)
2012 sandboxIO thing = do
2013   m <- newEmptyMVar
2014   ts <- takeMVar interruptTargetThread
2015   child <- forkIO (do res <- Exception.try thing; putMVar m res)
2016   putMVar interruptTargetThread (child:ts)
2017   takeMVar m `finally` modifyMVar_ interruptTargetThread (return.tail)
2018
2019 {-
2020 -- This version of sandboxIO runs the expression in a completely new
2021 -- RTS main thread.  It is disabled for now because ^C exceptions
2022 -- won't be delivered to the new thread, instead they'll be delivered
2023 -- to the (blocked) GHCi main thread.
2024
2025 -- SLPJ: when re-enabling this, reflect a wrong-stat error as an exception
2026
2027 sandboxIO :: IO a -> IO (Either Int (Either Exception a))
2028 sandboxIO thing = do
2029   st_thing <- newStablePtr (Exception.try thing)
2030   alloca $ \ p_st_result -> do
2031     stat <- rts_evalStableIO st_thing p_st_result
2032     freeStablePtr st_thing
2033     if stat == 1
2034         then do st_result <- peek p_st_result
2035                 result <- deRefStablePtr st_result
2036                 freeStablePtr st_result
2037                 return (Right result)
2038         else do
2039                 return (Left (fromIntegral stat))
2040
2041 foreign import "rts_evalStableIO"  {- safe -}
2042   rts_evalStableIO :: StablePtr (IO a) -> Ptr (StablePtr a) -> IO CInt
2043   -- more informative than the C type!
2044 -}
2045
2046 -----------------------------------------------------------------------------
2047 -- show a module and it's source/object filenames
2048
2049 showModule :: Session -> ModSummary -> IO String
2050 showModule s mod_summary = withSession s $ \hsc_env -> do
2051   case lookupModuleEnv (hsc_HPT hsc_env) (ms_mod mod_summary) of
2052         Nothing       -> panic "missing linkable"
2053         Just mod_info -> return (showModMsg obj_linkable mod_summary)
2054                       where
2055                          obj_linkable = isObjectLinkable (expectJust "showModule" (hm_linkable mod_info))
2056
2057 #endif /* GHCI */