ghc/compiler/main/GHC.hs

   1 -- -----------------------------------------------------------------------------
   2 --
   3 -- (c) The University of Glasgow, 2005
   4 --
   5 -- The GHC API
   6 --
   7 -- -----------------------------------------------------------------------------
   8
   9 module GHC (
  10         -- * Initialisation
  11         Session,
  12         defaultErrorHandler,
  13         defaultCleanupHandler,
  14         init, initFromArgs,
  15         newSession,
  16
  17         -- * Flags and settings
  18         DynFlags(..), DynFlag(..), Severity(..), GhcMode(..), HscTarget(..), dopt,
  19         parseDynamicFlags,
  20         initPackages,
  21         getSessionDynFlags,
  22         setSessionDynFlags,
  23
  24         -- * Targets
  25         Target(..), TargetId(..), Phase,
  26         setTargets,
  27         getTargets,
  28         addTarget,
  29         removeTarget,
  30         guessTarget,
  31
  32         -- * Loading\/compiling the program
  33         depanal,
  34         load, LoadHowMuch(..), SuccessFlag(..), -- also does depanal
  35         workingDirectoryChanged,
  36         checkModule, CheckedModule(..),
  37         TypecheckedSource, ParsedSource, RenamedSource,
  38
  39         -- * Inspecting the module structure of the program
  40         ModuleGraph, ModSummary(..), ModLocation(..),
  41         getModuleGraph,
  42         isLoaded,
  43         topSortModuleGraph,
  44
  45         -- * Inspecting modules
  46         ModuleInfo,
  47         getModuleInfo,
  48         modInfoTyThings,
  49         modInfoTopLevelScope,
  50         modInfoPrintUnqualified,
  51         modInfoExports,
  52         modInfoInstances,
  53         modInfoIsExportedName,
  54         modInfoLookupName,
  55         lookupGlobalName,
  56
  57         -- * Printing
  58         PrintUnqualified, alwaysQualify,
  59
  60         -- * Interactive evaluation
  61         getBindings, getPrintUnqual,
  62 #ifdef GHCI
  63         setContext, getContext,
  64         getNamesInScope,
  65         getRdrNamesInScope,
  66         moduleIsInterpreted,
  67         getInfo,
  68         exprType,
  69         typeKind,
  70         parseName,
  71         RunResult(..),
  72         runStmt,
  73         showModule,
  74         compileExpr, HValue,
  75         lookupName,
  76 #endif
  77
  78         -- * Abstract syntax elements
  79
  80         -- ** Modules
  81         Module, mkModule, pprModule,
  82
  83         -- ** Names
  84         Name,
  85         nameModule, nameParent_maybe, pprParenSymName, nameSrcLoc,
  86         NamedThing(..),
  87         RdrName(Qual,Unqual),
  88
  89         -- ** Identifiers
  90         Id, idType,
  91         isImplicitId, isDeadBinder,
  92         isExportedId, isLocalId, isGlobalId,
  93         isRecordSelector,
  94         isPrimOpId, isFCallId, isClassOpId_maybe,
  95         isDataConWorkId, idDataCon,
  96         isBottomingId, isDictonaryId,
  97         recordSelectorFieldLabel,
  98
  99         -- ** Type constructors
 100         TyCon,
 101         tyConTyVars, tyConDataCons, tyConArity,
 102         isClassTyCon, isSynTyCon, isNewTyCon, isPrimTyCon, isFunTyCon,
 103         synTyConDefn, synTyConRhs,
 104
 105         -- ** Type variables
 106         TyVar,
 107         alphaTyVars,
 108
 109         -- ** Data constructors
 110         DataCon,
 111         dataConSig, dataConType, dataConTyCon, dataConFieldLabels,
 112         dataConIsInfix, isVanillaDataCon,
 113         dataConStrictMarks,
 114         StrictnessMark(..), isMarkedStrict,
 115
 116         -- ** Classes
 117         Class,
 118         classMethods, classSCTheta, classTvsFds,
 119         pprFundeps,
 120
 121         -- ** Instances
 122         Instance,
 123         instanceDFunId, pprInstance, pprInstanceHdr,
 124
 125         -- ** Types and Kinds
 126         Type, dropForAlls, splitForAllTys, funResultTy, pprParendType,
 127         Kind,
 128         PredType,
 129         ThetaType, pprThetaArrow,
 130
 131         -- ** Entities
 132         TyThing(..),
 133
 134         -- ** Syntax
 135         module HsSyn, -- ToDo: remove extraneous bits
 136
 137         -- ** Fixities
 138         FixityDirection(..),
 139         defaultFixity, maxPrecedence,
 140         negateFixity,
 141         compareFixity,
 142
 143         -- ** Source locations
 144         SrcLoc, pprDefnLoc,
 145
 146         -- * Exceptions
 147         GhcException(..), showGhcException,
 148
 149         -- * Miscellaneous
 150         sessionHscEnv,
 151         cyclicModuleErr,
 152   ) where
 153
 154 {-
 155  ToDo:
 156
 157   * inline bits of HscMain here to simplify layering: hscTcExpr, hscStmt.
 158   * we need to expose DynFlags, so should parseDynamicFlags really be
 159     part of this interface?
 160   * what StaticFlags should we expose, if any?
 161 -}
 162
 163 #include "HsVersions.h"
 164
 165 #ifdef GHCI
 166 import qualified Linker
 167 import Linker           ( HValue, extendLinkEnv )
 168 import TcRnDriver       ( tcRnLookupRdrName, tcRnGetInfo,
 169                           tcRnLookupName, getModuleExports )
 170 import RdrName          ( plusGlobalRdrEnv, Provenance(..),
 171                           ImportSpec(..), ImpDeclSpec(..), ImpItemSpec(..),
 172                           emptyGlobalRdrEnv, mkGlobalRdrEnv )
 173 import HscMain          ( hscParseIdentifier, hscStmt, hscTcExpr, hscKcType )
 174 import Type             ( tidyType )
 175 import VarEnv           ( emptyTidyEnv )
 176 import GHC.Exts         ( unsafeCoerce# )
 177 #endif
 178
 179 import Packages         ( initPackages )
 180 import NameSet          ( NameSet, nameSetToList, elemNameSet )
 181 import RdrName          ( GlobalRdrEnv, GlobalRdrElt(..), RdrName(..),
 182                           globalRdrEnvElts )
 183 import HsSyn
 184 import Type             ( Kind, Type, dropForAlls, PredType, ThetaType,
 185                           pprThetaArrow, pprParendType, splitForAllTys,
 186                           funResultTy )
 187 import Id               ( Id, idType, isImplicitId, isDeadBinder,
 188                           isExportedId, isLocalId, isGlobalId,
 189                           isRecordSelector, recordSelectorFieldLabel,
 190                           isPrimOpId, isFCallId, isClassOpId_maybe,
 191                           isDataConWorkId, idDataCon,
 192                           isBottomingId )
 193 import Var              ( TyVar )
 194 import TysPrim          ( alphaTyVars )
 195 import TyCon            ( TyCon, isClassTyCon, isSynTyCon, isNewTyCon,
 196                           isPrimTyCon, isFunTyCon, tyConArity,
 197                           tyConTyVars, tyConDataCons, synTyConDefn, synTyConRhs )
 198 import Class            ( Class, classSCTheta, classTvsFds, classMethods )
 199 import FunDeps          ( pprFundeps )
 200 import DataCon          ( DataCon, dataConWrapId, dataConSig, dataConTyCon,
 201                           dataConFieldLabels, dataConStrictMarks,
 202                           dataConIsInfix, isVanillaDataCon )
 203 import Name             ( Name, nameModule, NamedThing(..), nameParent_maybe,
 204                           nameSrcLoc, nameOccName )
 205 import OccName          ( parenSymOcc )
 206 import NameEnv          ( nameEnvElts )
 207 import InstEnv          ( Instance, instanceDFunId, pprInstance, pprInstanceHdr )
 208 import SrcLoc
 209 import DriverPipeline
 210 import DriverPhases     ( Phase(..), isHaskellSrcFilename, startPhase )
 211 import GetImports       ( getImports )
 212 import Packages         ( isHomePackage )
 213 import Finder
 214 import HscMain          ( newHscEnv, hscFileCheck, HscResult(..) )
 215 import HscTypes
 216 import DynFlags
 217 import StaticFlags
 218 import SysTools         ( initSysTools, cleanTempFiles )
 219 import Module
 220 import FiniteMap
 221 import Panic
 222 import Digraph
 223 import Bag              ( unitBag )
 224 import ErrUtils         ( Severity(..), showPass, fatalErrorMsg, debugTraceMsg,
 225                           mkPlainErrMsg, printBagOfErrors, printErrorsAndWarnings )
 226 import qualified ErrUtils
 227 import Util
 228 import StringBuffer     ( StringBuffer, hGetStringBuffer )
 229 import Outputable
 230 import SysTools         ( cleanTempFilesExcept )
 231 import BasicTypes
 232 import TcType           ( tcSplitSigmaTy, isDictTy )
 233 import Maybes           ( expectJust, mapCatMaybes )
 234
 235 import Control.Concurrent
 236 import System.Directory ( getModificationTime, doesFileExist )
 237 import Data.Maybe       ( isJust, isNothing, fromJust )
 238 import Data.List        ( partition, nub )
 239 import qualified Data.List as List
 240 import Control.Monad    ( unless, when )
 241 import System.Exit      ( exitWith, ExitCode(..) )
 242 import System.Time      ( ClockTime )
 243 import Control.Exception as Exception hiding (handle)
 244 import Data.IORef
 245 import System.IO
 246 import System.IO.Error  ( isDoesNotExistError )
 247 import System.IO.Unsafe ( unsafePerformIO )
 248 import Prelude hiding (init)
 249
 250 #if __GLASGOW_HASKELL__ < 600
 251 import System.IO as System.IO.Error ( try )
 252 #else
 253 import System.IO.Error  ( try )
 254 #endif
 255
 256 -- -----------------------------------------------------------------------------
 257 -- Exception handlers
 258
 259 -- | Install some default exception handlers and run the inner computation.
 260 -- Unless you want to handle exceptions yourself, you should wrap this around
 261 -- the top level of your program.  The default handlers output the error
 262 -- message(s) to stderr and exit cleanly.
 263 defaultErrorHandler :: DynFlags -> IO a -> IO a
 264 defaultErrorHandler dflags inner =
 265   -- top-level exception handler: any unrecognised exception is a compiler bug.
 266   handle (\exception -> do
 267            hFlush stdout
 268            case exception of
 269                 -- an IO exception probably isn't our fault, so don't panic
 270                 IOException _ ->
 271                   fatalErrorMsg dflags (text (show exception))
 272                 AsyncException StackOverflow ->
 273                   fatalErrorMsg dflags (text "stack overflow: use +RTS -K<size> to increase it")
 274                 _other ->
 275                   fatalErrorMsg dflags (text (show (Panic (show exception))))
 276            exitWith (ExitFailure 1)
 277          ) $
 278
 279   -- program errors: messages with locations attached.  Sometimes it is
 280   -- convenient to just throw these as exceptions.
 281   handleDyn (\dyn -> do printBagOfErrors dflags (unitBag dyn)
 282                         exitWith (ExitFailure 1)) $
 283
 284   -- error messages propagated as exceptions
 285   handleDyn (\dyn -> do
 286                 hFlush stdout
 287                 case dyn of
 288                      PhaseFailed _ code -> exitWith code
 289                      Interrupted -> exitWith (ExitFailure 1)
 290                      _ -> do fatalErrorMsg dflags (text (show (dyn :: GhcException)))
 291                              exitWith (ExitFailure 1)
 292             ) $
 293   inner
 294
 295 -- | Install a default cleanup handler to remove temporary files
 296 -- deposited by a GHC run.  This is seperate from
 297 -- 'defaultErrorHandler', because you might want to override the error
 298 -- handling, but still get the ordinary cleanup behaviour.
 299 defaultCleanupHandler :: DynFlags -> IO a -> IO a
 300 defaultCleanupHandler dflags inner =
 301    -- make sure we clean up after ourselves
 302    later (unless (dopt Opt_KeepTmpFiles dflags) $
 303             cleanTempFiles dflags)
 304         -- exceptions will be blocked while we clean the temporary files,
 305         -- so there shouldn't be any difficulty if we receive further
 306         -- signals.
 307    inner
 308
 309
 310 -- | Initialises GHC.  This must be done /once/ only.  Takes the
 311 -- TopDir path without the '-B' prefix.
 312
 313 init :: Maybe String -> IO ()
 314 init mbMinusB = do
 315    -- catch ^C
 316    main_thread <- myThreadId
 317    putMVar interruptTargetThread [main_thread]
 318    installSignalHandlers
 319
 320    dflags0 <- initSysTools mbMinusB defaultDynFlags
 321    writeIORef v_initDynFlags dflags0
 322
 323 -- | Initialises GHC. This must be done /once/ only. Takes the
 324 -- command-line arguments.  All command-line arguments which aren't
 325 -- understood by GHC will be returned.
 326
 327 initFromArgs :: [String] -> IO [String]
 328 initFromArgs args
 329     = do init mbMinusB
 330          return argv1
 331     where -- Grab the -B option if there is one
 332           (minusB_args, argv1) = partition (prefixMatch "-B") args
 333           mbMinusB | null minusB_args
 334                        = Nothing
 335                    | otherwise
 336                        = Just (drop 2 (last minusB_args))
 337
 338 GLOBAL_VAR(v_initDynFlags, error "initDynFlags", DynFlags)
 339         -- stores the DynFlags between the call to init and subsequent
 340         -- calls to newSession.
 341
 342 -- | Starts a new session.  A session consists of a set of loaded
 343 -- modules, a set of options (DynFlags), and an interactive context.
 344 -- ToDo: GhcMode should say "keep typechecked code" and\/or "keep renamed
 345 -- code".
 346 newSession :: GhcMode -> IO Session
 347 newSession mode = do
 348   dflags0 <- readIORef v_initDynFlags
 349   dflags <- initDynFlags dflags0
 350   env <- newHscEnv dflags{ ghcMode=mode }
 351   ref <- newIORef env
 352   return (Session ref)
 353
 354 -- tmp: this breaks the abstraction, but required because DriverMkDepend
 355 -- needs to call the Finder.  ToDo: untangle this.
 356 sessionHscEnv :: Session -> IO HscEnv
 357 sessionHscEnv (Session ref) = readIORef ref
 358
 359 withSession :: Session -> (HscEnv -> IO a) -> IO a
 360 withSession (Session ref) f = do h <- readIORef ref; f h
 361
 362 modifySession :: Session -> (HscEnv -> HscEnv) -> IO ()
 363 modifySession (Session ref) f = do h <- readIORef ref; writeIORef ref $! f h
 364
 365 -- -----------------------------------------------------------------------------
 366 -- Flags & settings
 367
 368 -- | Grabs the DynFlags from the Session
 369 getSessionDynFlags :: Session -> IO DynFlags
 370 getSessionDynFlags s = withSession s (return . hsc_dflags)
 371
 372 -- | Updates the DynFlags in a Session
 373 setSessionDynFlags :: Session -> DynFlags -> IO ()
 374 setSessionDynFlags s dflags = modifySession s (\h -> h{ hsc_dflags = dflags })
 375
 376 -- | If there is no -o option, guess the name of target executable
 377 -- by using top-level source file name as a base.
 378 guessOutputFile :: Session -> IO ()
 379 guessOutputFile s = modifySession s $ \env ->
 380     let dflags = hsc_dflags env
 381         mod_graph = hsc_mod_graph env
 382         mainModuleSrcPath, guessedName :: Maybe String
 383         mainModuleSrcPath = do
 384             let isMain = (== mainModIs dflags) . ms_mod
 385             [ms] <- return (filter isMain mod_graph)
 386             ml_hs_file (ms_location ms)
 387         guessedName = fmap basenameOf mainModuleSrcPath
 388     in
 389     case outputFile dflags of
 390         Just _ -> env
 391         Nothing -> env { hsc_dflags = dflags { outputFile = guessedName } }
 392
 393 -- -----------------------------------------------------------------------------
 394 -- Targets
 395
 396 -- ToDo: think about relative vs. absolute file paths. And what
 397 -- happens when the current directory changes.
 398
 399 -- | Sets the targets for this session.  Each target may be a module name
 400 -- or a filename.  The targets correspond to the set of root modules for
 401 -- the program\/library.  Unloading the current program is achieved by
 402 -- setting the current set of targets to be empty, followed by load.
 403 setTargets :: Session -> [Target] -> IO ()
 404 setTargets s targets = modifySession s (\h -> h{ hsc_targets = targets })
 405
 406 -- | returns the current set of targets
 407 getTargets :: Session -> IO [Target]
 408 getTargets s = withSession s (return . hsc_targets)
 409
 410 -- | Add another target
 411 addTarget :: Session -> Target -> IO ()
 412 addTarget s target
 413   = modifySession s (\h -> h{ hsc_targets = target : hsc_targets h })
 414
 415 -- | Remove a target
 416 removeTarget :: Session -> TargetId -> IO ()
 417 removeTarget s target_id
 418   = modifySession s (\h -> h{ hsc_targets = filter (hsc_targets h) })
 419   where
 420    filter targets = [ t | t@(Target id _) <- targets, id /= target_id ]
 421
 422 -- Attempts to guess what Target a string refers to.  This function implements
 423 -- the --make/GHCi command-line syntax for filenames:
 424 --
 425 --      - if the string looks like a Haskell source filename, then interpret
 426 --        it as such
 427 --      - if adding a .hs or .lhs suffix yields the name of an existing file,
 428 --        then use that
 429 --      - otherwise interpret the string as a module name
 430 --
 431 guessTarget :: String -> Maybe Phase -> IO Target
 432 guessTarget file (Just phase)
 433    = return (Target (TargetFile file (Just phase)) Nothing)
 434 guessTarget file Nothing
 435    | isHaskellSrcFilename file
 436    = return (Target (TargetFile file Nothing) Nothing)
 437    | otherwise
 438    = do exists <- doesFileExist hs_file
 439         if exists
 440            then return (Target (TargetFile hs_file Nothing) Nothing)
 441            else do
 442         exists <- doesFileExist lhs_file
 443         if exists
 444            then return (Target (TargetFile lhs_file Nothing) Nothing)
 445            else do
 446         return (Target (TargetModule (mkModule file)) Nothing)
 447      where
 448          hs_file  = file `joinFileExt` "hs"
 449          lhs_file = file `joinFileExt` "lhs"
 450
 451 -- -----------------------------------------------------------------------------
 452 -- Loading the program
 453
 454 -- Perform a dependency analysis starting from the current targets
 455 -- and update the session with the new module graph.
 456 depanal :: Session -> [Module] -> Bool -> IO (Maybe ModuleGraph)
 457 depanal (Session ref) excluded_mods allow_dup_roots = do
 458   hsc_env <- readIORef ref
 459   let
 460          dflags  = hsc_dflags hsc_env
 461          gmode   = ghcMode (hsc_dflags hsc_env)
 462          targets = hsc_targets hsc_env
 463          old_graph = hsc_mod_graph hsc_env
 464
 465   showPass dflags "Chasing dependencies"
 466   when (gmode == BatchCompile) $
 467         debugTraceMsg dflags 1 (hcat [
 468                      text "Chasing modules from: ",
 469                         hcat (punctuate comma (map pprTarget targets))])
 470
 471   r <- downsweep hsc_env old_graph excluded_mods allow_dup_roots
 472   case r of
 473     Just mod_graph -> writeIORef ref hsc_env{ hsc_mod_graph = mod_graph }
 474     _ -> return ()
 475   return r
 476
 477 {-
 478 -- | The result of load.
 479 data LoadResult
 480   = LoadOk      Errors  -- ^ all specified targets were loaded successfully.
 481   | LoadFailed  Errors  -- ^ not all modules were loaded.
 482
 483 type Errors = [String]
 484
 485 data ErrMsg = ErrMsg {
 486         errMsgSeverity  :: Severity,  -- warning, error, etc.
 487         errMsgSpans     :: [SrcSpan],
 488         errMsgShortDoc  :: Doc,
 489         errMsgExtraInfo :: Doc
 490         }
 491 -}
 492
 493 data LoadHowMuch
 494    = LoadAllTargets
 495    | LoadUpTo Module
 496    | LoadDependenciesOf Module
 497
 498 -- | Try to load the program.  If a Module is supplied, then just
 499 -- attempt to load up to this target.  If no Module is supplied,
 500 -- then try to load all targets.
 501 load :: Session -> LoadHowMuch -> IO SuccessFlag
 502 load s@(Session ref) how_much
 503    = do
 504         -- Dependency analysis first.  Note that this fixes the module graph:
 505         -- even if we don't get a fully successful upsweep, the full module
 506         -- graph is still retained in the Session.  We can tell which modules
 507         -- were successfully loaded by inspecting the Session's HPT.
 508         mb_graph <- depanal s [] False
 509         case mb_graph of
 510            Just mod_graph -> load2 s how_much mod_graph
 511            Nothing        -> return Failed
 512
 513 load2 s@(Session ref) how_much mod_graph = do
 514         guessOutputFile s
 515         hsc_env <- readIORef ref
 516
 517         let hpt1      = hsc_HPT hsc_env
 518         let dflags    = hsc_dflags hsc_env
 519         let ghci_mode = ghcMode dflags -- this never changes
 520
 521         -- The "bad" boot modules are the ones for which we have
 522         -- B.hs-boot in the module graph, but no B.hs
 523         -- The downsweep should have ensured this does not happen
 524         -- (see msDeps)
 525         let all_home_mods = [ms_mod s | s <- mod_graph, not (isBootSummary s)]
 526 #ifdef DEBUG
 527             bad_boot_mods = [s        | s <- mod_graph, isBootSummary s,
 528                                         not (ms_mod s `elem` all_home_mods)]
 529 #endif
 530         ASSERT( null bad_boot_mods ) return ()
 531
 532         -- mg2_with_srcimps drops the hi-boot nodes, returning a
 533         -- graph with cycles.  Among other things, it is used for
 534         -- backing out partially complete cycles following a failed
 535         -- upsweep, and for removing from hpt all the modules
 536         -- not in strict downwards closure, during calls to compile.
 537         let mg2_with_srcimps :: [SCC ModSummary]
 538             mg2_with_srcimps = topSortModuleGraph True mod_graph Nothing
 539
 540             -- check the stability property for each module.
 541             stable_mods@(stable_obj,stable_bco)
 542                 | BatchCompile <- ghci_mode = ([],[])
 543                 | otherwise = checkStability hpt1 mg2_with_srcimps all_home_mods
 544
 545             -- prune bits of the HPT which are definitely redundant now,
 546             -- to save space.
 547             pruned_hpt = pruneHomePackageTable hpt1
 548                                 (flattenSCCs mg2_with_srcimps)
 549                                 stable_mods
 550
 551         evaluate pruned_hpt
 552
 553         debugTraceMsg dflags 2 (text "Stable obj:" <+> ppr stable_obj $$
 554                                 text "Stable BCO:" <+> ppr stable_bco)
 555
 556         -- Unload any modules which are going to be re-linked this time around.
 557         let stable_linkables = [ linkable
 558                                | m <- stable_obj++stable_bco,
 559                                  Just hmi <- [lookupModuleEnv pruned_hpt m],
 560                                  Just linkable <- [hm_linkable hmi] ]
 561         unload hsc_env stable_linkables
 562
 563         -- We could at this point detect cycles which aren't broken by
 564         -- a source-import, and complain immediately, but it seems better
 565         -- to let upsweep_mods do this, so at least some useful work gets
 566         -- done before the upsweep is abandoned.
 567         --hPutStrLn stderr "after tsort:\n"
 568         --hPutStrLn stderr (showSDoc (vcat (map ppr mg2)))
 569
 570         -- Now do the upsweep, calling compile for each module in
 571         -- turn.  Final result is version 3 of everything.
 572
 573         -- Topologically sort the module graph, this time including hi-boot
 574         -- nodes, and possibly just including the portion of the graph
 575         -- reachable from the module specified in the 2nd argument to load.
 576         -- This graph should be cycle-free.
 577         -- If we're restricting the upsweep to a portion of the graph, we
 578         -- also want to retain everything that is still stable.
 579         let full_mg :: [SCC ModSummary]
 580             full_mg    = topSortModuleGraph False mod_graph Nothing
 581
 582             maybe_top_mod = case how_much of
 583                                 LoadUpTo m           -> Just m
 584                                 LoadDependenciesOf m -> Just m
 585                                 _                    -> Nothing
 586
 587             partial_mg0 :: [SCC ModSummary]
 588             partial_mg0 = topSortModuleGraph False mod_graph maybe_top_mod
 589
 590             -- LoadDependenciesOf m: we want the upsweep to stop just
 591             -- short of the specified module (unless the specified module
 592             -- is stable).
 593             partial_mg
 594                 | LoadDependenciesOf mod <- how_much
 595                 = ASSERT( case last partial_mg0 of
 596                             AcyclicSCC ms -> ms_mod ms == mod; _ -> False )
 597                   List.init partial_mg0
 598                 | otherwise
 599                 = partial_mg0
 600
 601             stable_mg =
 602                 [ AcyclicSCC ms
 603                 | AcyclicSCC ms <- full_mg,
 604                   ms_mod ms `elem` stable_obj++stable_bco,
 605                   ms_mod ms `notElem` [ ms_mod ms' |
 606                                         AcyclicSCC ms' <- partial_mg ] ]
 607
 608             mg = stable_mg ++ partial_mg
 609
 610         -- clean up between compilations
 611         let cleanup = cleanTempFilesExcept dflags
 612                           (ppFilesFromSummaries (flattenSCCs mg2_with_srcimps))
 613
 614         (upsweep_ok, hsc_env1, modsUpswept)
 615            <- upsweep (hsc_env { hsc_HPT = emptyHomePackageTable })
 616                            pruned_hpt stable_mods cleanup mg
 617
 618         -- Make modsDone be the summaries for each home module now
 619         -- available; this should equal the domain of hpt3.
 620         -- Get in in a roughly top .. bottom order (hence reverse).
 621
 622         let modsDone = reverse modsUpswept
 623
 624         -- Try and do linking in some form, depending on whether the
 625         -- upsweep was completely or only partially successful.
 626
 627         if succeeded upsweep_ok
 628
 629          then
 630            -- Easy; just relink it all.
 631            do debugTraceMsg dflags 2 (text "Upsweep completely successful.")
 632
 633               -- Clean up after ourselves
 634               cleanTempFilesExcept dflags (ppFilesFromSummaries modsDone)
 635
 636               -- Issue a warning for the confusing case where the user
 637               -- said '-o foo' but we're not going to do any linking.
 638               -- We attempt linking if either (a) one of the modules is
 639               -- called Main, or (b) the user said -no-hs-main, indicating
 640               -- that main() is going to come from somewhere else.
 641               --
 642               let ofile = outputFile dflags
 643               let no_hs_main = dopt Opt_NoHsMain dflags
 644               let
 645                 main_mod = mainModIs dflags
 646                 a_root_is_Main = any ((==main_mod).ms_mod) mod_graph
 647                 do_linking = a_root_is_Main || no_hs_main
 648
 649               when (ghci_mode == BatchCompile && isJust ofile && not do_linking) $
 650                 debugTraceMsg dflags 1 (text ("Warning: output was redirected with -o, " ++
 651                                               "but no output will be generated\n" ++
 652                                               "because there is no " ++ moduleString main_mod ++ " module."))
 653
 654               -- link everything together
 655               linkresult <- link ghci_mode dflags do_linking (hsc_HPT hsc_env1)
 656
 657               loadFinish Succeeded linkresult ref hsc_env1
 658
 659          else
 660            -- Tricky.  We need to back out the effects of compiling any
 661            -- half-done cycles, both so as to clean up the top level envs
 662            -- and to avoid telling the interactive linker to link them.
 663            do debugTraceMsg dflags 2 (text "Upsweep partially successful.")
 664
 665               let modsDone_names
 666                      = map ms_mod modsDone
 667               let mods_to_zap_names
 668                      = findPartiallyCompletedCycles modsDone_names
 669                           mg2_with_srcimps
 670               let mods_to_keep
 671                      = filter ((`notElem` mods_to_zap_names).ms_mod)
 672                           modsDone
 673
 674               let hpt4 = retainInTopLevelEnvs (map ms_mod mods_to_keep)
 675                                               (hsc_HPT hsc_env1)
 676
 677               -- Clean up after ourselves
 678               cleanTempFilesExcept dflags (ppFilesFromSummaries mods_to_keep)
 679
 680               -- there should be no Nothings where linkables should be, now
 681               ASSERT(all (isJust.hm_linkable)
 682                         (moduleEnvElts (hsc_HPT hsc_env))) do
 683
 684               -- Link everything together
 685               linkresult <- link ghci_mode dflags False hpt4
 686
 687               let hsc_env4 = hsc_env1{ hsc_HPT = hpt4 }
 688               loadFinish Failed linkresult ref hsc_env4
 689
 690 -- Finish up after a load.
 691
 692 -- If the link failed, unload everything and return.
 693 loadFinish all_ok Failed ref hsc_env
 694   = do unload hsc_env []
 695        writeIORef ref $! discardProg hsc_env
 696        return Failed
 697
 698 -- Empty the interactive context and set the module context to the topmost
 699 -- newly loaded module, or the Prelude if none were loaded.
 700 loadFinish all_ok Succeeded ref hsc_env
 701   = do writeIORef ref $! hsc_env{ hsc_IC = emptyInteractiveContext }
 702        return all_ok
 703
 704
 705 -- Forget the current program, but retain the persistent info in HscEnv
 706 discardProg :: HscEnv -> HscEnv
 707 discardProg hsc_env
 708   = hsc_env { hsc_mod_graph = emptyMG,
 709               hsc_IC = emptyInteractiveContext,
 710               hsc_HPT = emptyHomePackageTable }
 711
 712 -- used to fish out the preprocess output files for the purposes of
 713 -- cleaning up.  The preprocessed file *might* be the same as the
 714 -- source file, but that doesn't do any harm.
 715 ppFilesFromSummaries summaries = [ fn | Just fn <- map ms_hspp_file summaries ]
 716
 717 -- -----------------------------------------------------------------------------
 718 -- Check module
 719
 720 data CheckedModule =
 721   CheckedModule { parsedSource      :: ParsedSource,
 722                   renamedSource     :: Maybe RenamedSource,
 723                   typecheckedSource :: Maybe TypecheckedSource,
 724                   checkedModuleInfo :: Maybe ModuleInfo
 725                 }
 726         -- ToDo: improvements that could be made here:
 727         --  if the module succeeded renaming but not typechecking,
 728         --  we can still get back the GlobalRdrEnv and exports, so
 729         --  perhaps the ModuleInfo should be split up into separate
 730         --  fields within CheckedModule.
 731
 732 type ParsedSource      = Located (HsModule RdrName)
 733 type RenamedSource     = (HsGroup Name, [LImportDecl Name], Maybe [LIE Name])
 734 type TypecheckedSource = LHsBinds Id
 735
 736 -- NOTE:
 737 --   - things that aren't in the output of the typechecker right now:
 738 --     - the export list
 739 --     - the imports
 740 --     - type signatures
 741 --     - type/data/newtype declarations
 742 --     - class declarations
 743 --     - instances
 744 --   - extra things in the typechecker's output:
 745 --     - default methods are turned into top-level decls.
 746 --     - dictionary bindings
 747
 748
 749 -- | This is the way to get access to parsed and typechecked source code
 750 -- for a module.  'checkModule' loads all the dependencies of the specified
 751 -- module in the Session, and then attempts to typecheck the module.  If
 752 -- successful, it returns the abstract syntax for the module.
 753 checkModule :: Session -> Module -> IO (Maybe CheckedModule)
 754 checkModule session@(Session ref) mod = do
 755         -- load up the dependencies first
 756    r <- load session (LoadDependenciesOf mod)
 757    if (failed r) then return Nothing else do
 758
 759         -- now parse & typecheck the module
 760    hsc_env <- readIORef ref
 761    let mg  = hsc_mod_graph hsc_env
 762    case [ ms | ms <- mg, ms_mod ms == mod ] of
 763         [] -> return Nothing
 764         (ms:_) -> do
 765            -- Add in the OPTIONS from the source file This is nasty:
 766            -- we've done this once already, in the compilation manager
 767            -- It might be better to cache the flags in the
 768            -- ml_hspp_file field, say
 769            let dflags0 = hsc_dflags hsc_env
 770                hspp_buf = expectJust "GHC.checkModule" (ms_hspp_buf ms)
 771                filename = fromJust (ml_hs_file (ms_location ms))
 772                opts = getOptionsFromStringBuffer hspp_buf filename
 773            (dflags1,leftovers) <- parseDynamicFlags dflags0 (map snd opts)
 774            if (not (null leftovers))
 775                 then do printErrorsAndWarnings dflags1 (optionsErrorMsgs leftovers opts filename)
 776                         return Nothing
 777                 else do
 778
 779            r <- hscFileCheck hsc_env{hsc_dflags=dflags1} ms
 780            case r of
 781                 HscFail ->
 782                    return Nothing
 783                 HscChecked parsed renamed Nothing ->
 784                    return (Just (CheckedModule {
 785                                         parsedSource = parsed,
 786                                         renamedSource = renamed,
 787                                         typecheckedSource = Nothing,
 788                                         checkedModuleInfo = Nothing }))
 789                 HscChecked parsed renamed
 790                            (Just (tc_binds, rdr_env, details)) -> do
 791                    let minf = ModuleInfo {
 792                                 minf_type_env  = md_types details,
 793                                 minf_exports   = md_exports details,
 794                                 minf_rdr_env   = Just rdr_env,
 795                                 minf_instances = md_insts details
 796                               }
 797                    return (Just (CheckedModule {
 798                                         parsedSource = parsed,
 799                                         renamedSource = renamed,
 800                                         typecheckedSource = Just tc_binds,
 801                                         checkedModuleInfo = Just minf }))
 802                 _other ->
 803                         panic "checkModule"
 804
 805 -- ---------------------------------------------------------------------------
 806 -- Unloading
 807
 808 unload :: HscEnv -> [Linkable] -> IO ()
 809 unload hsc_env stable_linkables -- Unload everthing *except* 'stable_linkables'
 810   = case ghcMode (hsc_dflags hsc_env) of
 811         BatchCompile  -> return ()
 812         JustTypecheck -> return ()
 813 #ifdef GHCI
 814         Interactive -> Linker.unload (hsc_dflags hsc_env) stable_linkables
 815 #else
 816         Interactive -> panic "unload: no interpreter"
 817 #endif
 818         other -> panic "unload: strange mode"
 819
 820 -- -----------------------------------------------------------------------------
 821 -- checkStability
 822
 823 {-
 824   Stability tells us which modules definitely do not need to be recompiled.
 825   There are two main reasons for having stability:
 826
 827    - avoid doing a complete upsweep of the module graph in GHCi when
 828      modules near the bottom of the tree have not changed.
 829
 830    - to tell GHCi when it can load object code: we can only load object code
 831      for a module when we also load object code fo  all of the imports of the
 832      module.  So we need to know that we will definitely not be recompiling
 833      any of these modules, and we can use the object code.
 834
 835   NB. stability is of no importance to BatchCompile at all, only Interactive.
 836   (ToDo: what about JustTypecheck?)
 837
 838   The stability check is as follows.  Both stableObject and
 839   stableBCO are used during the upsweep phase later.
 840
 841   -------------------
 842   stable m = stableObject m || stableBCO m
 843
 844   stableObject m =
 845         all stableObject (imports m)
 846         && old linkable does not exist, or is == on-disk .o
 847         && date(on-disk .o) > date(.hs)
 848
 849   stableBCO m =
 850         all stable (imports m)
 851         && date(BCO) > date(.hs)
 852   -------------------
 853
 854   These properties embody the following ideas:
 855
 856     - if a module is stable:
 857         - if it has been compiled in a previous pass (present in HPT)
 858           then it does not need to be compiled or re-linked.
 859         - if it has not been compiled in a previous pass,
 860           then we only need to read its .hi file from disk and
 861           link it to produce a ModDetails.
 862
 863     - if a modules is not stable, we will definitely be at least
 864       re-linking, and possibly re-compiling it during the upsweep.
 865       All non-stable modules can (and should) therefore be unlinked
 866       before the upsweep.
 867
 868     - Note that objects are only considered stable if they only depend
 869       on other objects.  We can't link object code against byte code.
 870 -}
 871
 872 checkStability
 873         :: HomePackageTable             -- HPT from last compilation
 874         -> [SCC ModSummary]             -- current module graph (cyclic)
 875         -> [Module]                     -- all home modules
 876         -> ([Module],                   -- stableObject
 877             [Module])                   -- stableBCO
 878
 879 checkStability hpt sccs all_home_mods = foldl checkSCC ([],[]) sccs
 880   where
 881    checkSCC (stable_obj, stable_bco) scc0
 882      | stableObjects = (scc_mods ++ stable_obj, stable_bco)
 883      | stableBCOs    = (stable_obj, scc_mods ++ stable_bco)
 884      | otherwise     = (stable_obj, stable_bco)
 885      where
 886         scc = flattenSCC scc0
 887         scc_mods = map ms_mod scc
 888         home_module m   = m `elem` all_home_mods && m `notElem` scc_mods
 889
 890         scc_allimps = nub (filter home_module (concatMap ms_allimps scc))
 891             -- all imports outside the current SCC, but in the home pkg
 892
 893         stable_obj_imps = map (`elem` stable_obj) scc_allimps
 894         stable_bco_imps = map (`elem` stable_bco) scc_allimps
 895
 896         stableObjects =
 897            and stable_obj_imps
 898            && all object_ok scc
 899
 900         stableBCOs =
 901            and (zipWith (||) stable_obj_imps stable_bco_imps)
 902            && all bco_ok scc
 903
 904         object_ok ms
 905           | Just t <- ms_obj_date ms  =  t >= ms_hs_date ms
 906                                          && same_as_prev t
 907           | otherwise = False
 908           where
 909              same_as_prev t = case lookupModuleEnv hpt (ms_mod ms) of
 910                                 Just hmi  | Just l <- hm_linkable hmi
 911                                  -> isObjectLinkable l && t == linkableTime l
 912                                 _other  -> True
 913                 -- why '>=' rather than '>' above?  If the filesystem stores
 914                 -- times to the nearset second, we may occasionally find that
 915                 -- the object & source have the same modification time,
 916                 -- especially if the source was automatically generated
 917                 -- and compiled.  Using >= is slightly unsafe, but it matches
 918                 -- make's behaviour.
 919
 920         bco_ok ms
 921           = case lookupModuleEnv hpt (ms_mod ms) of
 922                 Just hmi  | Just l <- hm_linkable hmi ->
 923                         not (isObjectLinkable l) &&
 924                         linkableTime l >= ms_hs_date ms
 925                 _other  -> False
 926
 927 ms_allimps :: ModSummary -> [Module]
 928 ms_allimps ms = map unLoc (ms_srcimps ms ++ ms_imps ms)
 929
 930 -- -----------------------------------------------------------------------------
 931 -- Prune the HomePackageTable
 932
 933 -- Before doing an upsweep, we can throw away:
 934 --
 935 --   - For non-stable modules:
 936 --      - all ModDetails, all linked code
 937 --   - all unlinked code that is out of date with respect to
 938 --     the source file
 939 --
 940 -- This is VERY IMPORTANT otherwise we'll end up requiring 2x the
 941 -- space at the end of the upsweep, because the topmost ModDetails of the
 942 -- old HPT holds on to the entire type environment from the previous
 943 -- compilation.
 944
 945 pruneHomePackageTable
 946    :: HomePackageTable
 947    -> [ModSummary]
 948    -> ([Module],[Module])
 949    -> HomePackageTable
 950
 951 pruneHomePackageTable hpt summ (stable_obj, stable_bco)
 952   = mapModuleEnv prune hpt
 953   where prune hmi
 954           | is_stable modl = hmi'
 955           | otherwise      = hmi'{ hm_details = emptyModDetails }
 956           where
 957            modl = mi_module (hm_iface hmi)
 958            hmi' | Just l <- hm_linkable hmi, linkableTime l < ms_hs_date ms
 959                 = hmi{ hm_linkable = Nothing }
 960                 | otherwise
 961                 = hmi
 962                 where ms = expectJust "prune" (lookupModuleEnv ms_map modl)
 963
 964         ms_map = mkModuleEnv [(ms_mod ms, ms) | ms <- summ]
 965
 966         is_stable m = m `elem` stable_obj || m `elem` stable_bco
 967
 968 -- -----------------------------------------------------------------------------
 969
 970 -- Return (names of) all those in modsDone who are part of a cycle
 971 -- as defined by theGraph.
 972 findPartiallyCompletedCycles :: [Module] -> [SCC ModSummary] -> [Module]
 973 findPartiallyCompletedCycles modsDone theGraph
 974    = chew theGraph
 975      where
 976         chew [] = []
 977         chew ((AcyclicSCC v):rest) = chew rest    -- acyclic?  not interesting.
 978         chew ((CyclicSCC vs):rest)
 979            = let names_in_this_cycle = nub (map ms_mod vs)
 980                  mods_in_this_cycle
 981                     = nub ([done | done <- modsDone,
 982                                    done `elem` names_in_this_cycle])
 983                  chewed_rest = chew rest
 984              in
 985              if   notNull mods_in_this_cycle
 986                   && length mods_in_this_cycle < length names_in_this_cycle
 987              then mods_in_this_cycle ++ chewed_rest
 988              else chewed_rest
 989
 990 -- -----------------------------------------------------------------------------
 991 -- The upsweep
 992
 993 -- This is where we compile each module in the module graph, in a pass
 994 -- from the bottom to the top of the graph.
 995
 996 -- There better had not be any cyclic groups here -- we check for them.
 997
 998 upsweep
 999     :: HscEnv                   -- Includes initially-empty HPT
1000     -> HomePackageTable         -- HPT from last time round (pruned)
1001     -> ([Module],[Module])      -- stable modules (see checkStability)
1002     -> IO ()                    -- How to clean up unwanted tmp files
1003     -> [SCC ModSummary]         -- Mods to do (the worklist)
1004     -> IO (SuccessFlag,
1005            HscEnv,              -- With an updated HPT
1006            [ModSummary])        -- Mods which succeeded
1007
1008 upsweep hsc_env old_hpt stable_mods cleanup mods
1009    = upsweep' hsc_env old_hpt stable_mods cleanup mods 1 (length mods)
1010
1011 upsweep' hsc_env old_hpt stable_mods cleanup
1012      [] _ _
1013    = return (Succeeded, hsc_env, [])
1014
1015 upsweep' hsc_env old_hpt stable_mods cleanup
1016      (CyclicSCC ms:_) _ _
1017    = do fatalErrorMsg (hsc_dflags hsc_env) (cyclicModuleErr ms)
1018         return (Failed, hsc_env, [])
1019
1020 upsweep' hsc_env old_hpt stable_mods cleanup
1021      (AcyclicSCC mod:mods) mod_index nmods
1022    = do -- putStrLn ("UPSWEEP_MOD: hpt = " ++
1023         --           show (map (moduleUserString.moduleName.mi_module.hm_iface)
1024         --                     (moduleEnvElts (hsc_HPT hsc_env)))
1025
1026         mb_mod_info <- upsweep_mod hsc_env old_hpt stable_mods mod
1027                        mod_index nmods
1028
1029         cleanup         -- Remove unwanted tmp files between compilations
1030
1031         case mb_mod_info of
1032             Nothing -> return (Failed, hsc_env, [])
1033             Just mod_info -> do
1034                 { let this_mod = ms_mod mod
1035
1036                         -- Add new info to hsc_env
1037                       hpt1     = extendModuleEnv (hsc_HPT hsc_env)
1038                                         this_mod mod_info
1039                       hsc_env1 = hsc_env { hsc_HPT = hpt1 }
1040
1041                         -- Space-saving: delete the old HPT entry
1042                         -- for mod BUT if mod is a hs-boot
1043                         -- node, don't delete it.  For the
1044                         -- interface, the HPT entry is probaby for the
1045                         -- main Haskell source file.  Deleting it
1046                         -- would force .. (what?? --SDM)
1047                       old_hpt1 | isBootSummary mod = old_hpt
1048                                | otherwise = delModuleEnv old_hpt this_mod
1049
1050                 ; (restOK, hsc_env2, modOKs)
1051                         <- upsweep' hsc_env1 old_hpt1 stable_mods cleanup
1052                                 mods (mod_index+1) nmods
1053                 ; return (restOK, hsc_env2, mod:modOKs)
1054                 }
1055
1056
1057 -- Compile a single module.  Always produce a Linkable for it if
1058 -- successful.  If no compilation happened, return the old Linkable.
1059 upsweep_mod :: HscEnv
1060             -> HomePackageTable
1061             -> ([Module],[Module])
1062             -> ModSummary
1063             -> Int  -- index of module
1064             -> Int  -- total number of modules
1065             -> IO (Maybe HomeModInfo)   -- Nothing => Failed
1066
1067 upsweep_mod hsc_env old_hpt (stable_obj, stable_bco) summary mod_index nmods
1068    = do
1069         let
1070             this_mod    = ms_mod summary
1071             mb_obj_date = ms_obj_date summary
1072             obj_fn      = ml_obj_file (ms_location summary)
1073             hs_date     = ms_hs_date summary
1074
1075             compile_it :: Maybe Linkable -> IO (Maybe HomeModInfo)
1076             compile_it  = upsweep_compile hsc_env old_hpt this_mod
1077                                 summary mod_index nmods
1078
1079         case ghcMode (hsc_dflags hsc_env) of
1080             BatchCompile ->
1081                 case () of
1082                    -- Batch-compilating is easy: just check whether we have
1083                    -- an up-to-date object file.  If we do, then the compiler
1084                    -- needs to do a recompilation check.
1085                    _ | Just obj_date <- mb_obj_date, obj_date >= hs_date -> do
1086                            linkable <-
1087                                 findObjectLinkable this_mod obj_fn obj_date
1088                            compile_it (Just linkable)
1089
1090                      | otherwise ->
1091                            compile_it Nothing
1092
1093             interactive ->
1094                 case () of
1095                     _ | is_stable_obj, isJust old_hmi ->
1096                            return old_hmi
1097                         -- object is stable, and we have an entry in the
1098                         -- old HPT: nothing to do
1099
1100                       | is_stable_obj, isNothing old_hmi -> do
1101                            linkable <-
1102                                 findObjectLinkable this_mod obj_fn
1103                                         (expectJust "upseep1" mb_obj_date)
1104                            compile_it (Just linkable)
1105                         -- object is stable, but we need to load the interface
1106                         -- off disk to make a HMI.
1107
1108                       | is_stable_bco ->
1109                            ASSERT(isJust old_hmi) -- must be in the old_hpt
1110                            return old_hmi
1111                         -- BCO is stable: nothing to do
1112
1113                       | Just hmi <- old_hmi,
1114                         Just l <- hm_linkable hmi, not (isObjectLinkable l),
1115                         linkableTime l >= ms_hs_date summary ->
1116                            compile_it (Just l)
1117                         -- we have an old BCO that is up to date with respect
1118                         -- to the source: do a recompilation check as normal.
1119
1120                       | otherwise ->
1121                           compile_it Nothing
1122                         -- no existing code at all: we must recompile.
1123                    where
1124                     is_stable_obj = this_mod `elem` stable_obj
1125                     is_stable_bco = this_mod `elem` stable_bco
1126
1127                     old_hmi = lookupModuleEnv old_hpt this_mod
1128
1129 -- Run hsc to compile a module
1130 upsweep_compile hsc_env old_hpt this_mod summary
1131                 mod_index nmods
1132                 mb_old_linkable = do
1133   let
1134         -- The old interface is ok if it's in the old HPT
1135         --      a) we're compiling a source file, and the old HPT
1136         --         entry is for a source file
1137         --      b) we're compiling a hs-boot file
1138         -- Case (b) allows an hs-boot file to get the interface of its
1139         -- real source file on the second iteration of the compilation
1140         -- manager, but that does no harm.  Otherwise the hs-boot file
1141         -- will always be recompiled
1142
1143         mb_old_iface
1144                 = case lookupModuleEnv old_hpt this_mod of
1145                      Nothing                              -> Nothing
1146                      Just hm_info | isBootSummary summary -> Just iface
1147                                   | not (mi_boot iface)   -> Just iface
1148                                   | otherwise             -> Nothing
1149                                    where
1150                                      iface = hm_iface hm_info
1151
1152   compresult <- compile hsc_env summary mb_old_linkable mb_old_iface
1153                         mod_index nmods
1154
1155   case compresult of
1156         -- Compilation failed.  Compile may still have updated the PCS, tho.
1157         CompErrs -> return Nothing
1158
1159         -- Compilation "succeeded", and may or may not have returned a new
1160         -- linkable (depending on whether compilation was actually performed
1161         -- or not).
1162         CompOK new_details new_iface new_linkable
1163               -> do let new_info = HomeModInfo { hm_iface = new_iface,
1164                                                  hm_details = new_details,
1165                                                  hm_linkable = new_linkable }
1166                     return (Just new_info)
1167
1168
1169 -- Filter modules in the HPT
1170 retainInTopLevelEnvs :: [Module] -> HomePackageTable -> HomePackageTable
1171 retainInTopLevelEnvs keep_these hpt
1172    = mkModuleEnv [ (mod, expectJust "retain" mb_mod_info)
1173                  | mod <- keep_these
1174                  , let mb_mod_info = lookupModuleEnv hpt mod
1175                  , isJust mb_mod_info ]
1176
1177 -- ---------------------------------------------------------------------------
1178 -- Topological sort of the module graph
1179
1180 topSortModuleGraph
1181           :: Bool               -- Drop hi-boot nodes? (see below)
1182           -> [ModSummary]
1183           -> Maybe Module
1184           -> [SCC ModSummary]
1185 -- Calculate SCCs of the module graph, possibly dropping the hi-boot nodes
1186 -- The resulting list of strongly-connected-components is in topologically
1187 -- sorted order, starting with the module(s) at the bottom of the
1188 -- dependency graph (ie compile them first) and ending with the ones at
1189 -- the top.
1190 --
1191 -- Drop hi-boot nodes (first boolean arg)?
1192 --
1193 --   False:     treat the hi-boot summaries as nodes of the graph,
1194 --              so the graph must be acyclic
1195 --
1196 --   True:      eliminate the hi-boot nodes, and instead pretend
1197 --              the a source-import of Foo is an import of Foo
1198 --              The resulting graph has no hi-boot nodes, but can by cyclic
1199
1200 topSortModuleGraph drop_hs_boot_nodes summaries Nothing
1201   = stronglyConnComp (fst (moduleGraphNodes drop_hs_boot_nodes summaries))
1202 topSortModuleGraph drop_hs_boot_nodes summaries (Just mod)
1203   = stronglyConnComp (map vertex_fn (reachable graph root))
1204   where
1205         -- restrict the graph to just those modules reachable from
1206         -- the specified module.  We do this by building a graph with
1207         -- the full set of nodes, and determining the reachable set from
1208         -- the specified node.
1209         (nodes, lookup_key) = moduleGraphNodes drop_hs_boot_nodes summaries
1210         (graph, vertex_fn, key_fn) = graphFromEdges' nodes
1211         root
1212           | Just key <- lookup_key HsSrcFile mod, Just v <- key_fn key = v
1213           | otherwise  = throwDyn (ProgramError "module does not exist")
1214
1215 moduleGraphNodes :: Bool -> [ModSummary]
1216   -> ([(ModSummary, Int, [Int])], HscSource -> Module -> Maybe Int)
1217 moduleGraphNodes drop_hs_boot_nodes summaries = (nodes, lookup_key)
1218    where
1219         -- Drop hs-boot nodes by using HsSrcFile as the key
1220         hs_boot_key | drop_hs_boot_nodes = HsSrcFile
1221                     | otherwise          = HsBootFile
1222
1223         -- We use integers as the keys for the SCC algorithm
1224         nodes :: [(ModSummary, Int, [Int])]
1225         nodes = [(s, expectJust "topSort" (lookup_key (ms_hsc_src s) (ms_mod s)),
1226                      out_edge_keys hs_boot_key (map unLoc (ms_srcimps s)) ++
1227                      out_edge_keys HsSrcFile   (map unLoc (ms_imps s))    )
1228                 | s <- summaries
1229                 , not (isBootSummary s && drop_hs_boot_nodes) ]
1230                 -- Drop the hi-boot ones if told to do so
1231
1232         key_map :: NodeMap Int
1233         key_map = listToFM ([(ms_mod s, ms_hsc_src s) | s <- summaries]
1234                            `zip` [1..])
1235
1236         lookup_key :: HscSource -> Module -> Maybe Int
1237         lookup_key hs_src mod = lookupFM key_map (mod, hs_src)
1238
1239         out_edge_keys :: HscSource -> [Module] -> [Int]
1240         out_edge_keys hi_boot ms = mapCatMaybes (lookup_key hi_boot) ms
1241                 -- If we want keep_hi_boot_nodes, then we do lookup_key with
1242                 -- the IsBootInterface parameter True; else False
1243
1244
1245 type NodeKey   = (Module, HscSource)      -- The nodes of the graph are
1246 type NodeMap a = FiniteMap NodeKey a      -- keyed by (mod, src_file_type) pairs
1247
1248 msKey :: ModSummary -> NodeKey
1249 msKey (ModSummary { ms_mod = mod, ms_hsc_src = boot }) = (mod,boot)
1250
1251 mkNodeMap :: [ModSummary] -> NodeMap ModSummary
1252 mkNodeMap summaries = listToFM [ (msKey s, s) | s <- summaries]
1253
1254 nodeMapElts :: NodeMap a -> [a]
1255 nodeMapElts = eltsFM
1256
1257 -----------------------------------------------------------------------------
1258 -- Downsweep (dependency analysis)
1259
1260 -- Chase downwards from the specified root set, returning summaries
1261 -- for all home modules encountered.  Only follow source-import
1262 -- links.
1263
1264 -- We pass in the previous collection of summaries, which is used as a
1265 -- cache to avoid recalculating a module summary if the source is
1266 -- unchanged.
1267 --
1268 -- The returned list of [ModSummary] nodes has one node for each home-package
1269 -- module, plus one for any hs-boot files.  The imports of these nodes
1270 -- are all there, including the imports of non-home-package modules.
1271
1272 downsweep :: HscEnv
1273           -> [ModSummary]       -- Old summaries
1274           -> [Module]           -- Ignore dependencies on these; treat
1275                                 -- them as if they were package modules
1276           -> Bool               -- True <=> allow multiple targets to have
1277                                 --          the same module name; this is
1278                                 --          very useful for ghc -M
1279           -> IO (Maybe [ModSummary])
1280                 -- The elts of [ModSummary] all have distinct
1281                 -- (Modules, IsBoot) identifiers, unless the Bool is true
1282                 -- in which case there can be repeats
1283 downsweep hsc_env old_summaries excl_mods allow_dup_roots
1284    = -- catch error messages and return them
1285      handleDyn (\err_msg -> printBagOfErrors (hsc_dflags hsc_env) (unitBag err_msg) >> return Nothing) $ do
1286        rootSummaries <- mapM getRootSummary roots
1287        let root_map = mkRootMap rootSummaries
1288        checkDuplicates root_map
1289        summs <- loop (concatMap msDeps rootSummaries) root_map
1290        return (Just summs)
1291      where
1292         roots = hsc_targets hsc_env
1293
1294         old_summary_map :: NodeMap ModSummary
1295         old_summary_map = mkNodeMap old_summaries
1296
1297         getRootSummary :: Target -> IO ModSummary
1298         getRootSummary (Target (TargetFile file mb_phase) maybe_buf)
1299            = do exists <- doesFileExist file
1300                 if exists
1301                     then summariseFile hsc_env old_summaries file mb_phase maybe_buf
1302                     else throwDyn $ mkPlainErrMsg noSrcSpan $
1303                            text "can't find file:" <+> text file
1304         getRootSummary (Target (TargetModule modl) maybe_buf)
1305            = do maybe_summary <- summariseModule hsc_env old_summary_map False
1306                                            (L rootLoc modl) maybe_buf excl_mods
1307                 case maybe_summary of
1308                    Nothing -> packageModErr modl
1309                    Just s  -> return s
1310
1311         rootLoc = mkGeneralSrcSpan FSLIT("<command line>")
1312
1313         -- In a root module, the filename is allowed to diverge from the module
1314         -- name, so we have to check that there aren't multiple root files
1315         -- defining the same module (otherwise the duplicates will be silently
1316         -- ignored, leading to confusing behaviour).
1317         checkDuplicates :: NodeMap [ModSummary] -> IO ()
1318         checkDuplicates root_map
1319            | allow_dup_roots = return ()
1320            | null dup_roots  = return ()
1321            | otherwise       = multiRootsErr (head dup_roots)
1322            where
1323              dup_roots :: [[ModSummary]]        -- Each at least of length 2
1324              dup_roots = filterOut isSingleton (nodeMapElts root_map)
1325
1326         loop :: [(Located Module,IsBootInterface)]
1327                         -- Work list: process these modules
1328              -> NodeMap [ModSummary]
1329                         -- Visited set; the range is a list because
1330                         -- the roots can have the same module names
1331                         -- if allow_dup_roots is True
1332              -> IO [ModSummary]
1333                         -- The result includes the worklist, except
1334                         -- for those mentioned in the visited set
1335         loop [] done      = return (concat (nodeMapElts done))
1336         loop ((wanted_mod, is_boot) : ss) done
1337           | Just summs <- lookupFM done key
1338           = if isSingleton summs then
1339                 loop ss done
1340             else
1341                 do { multiRootsErr summs; return [] }
1342           | otherwise         = do { mb_s <- summariseModule hsc_env old_summary_map
1343                                                  is_boot wanted_mod Nothing excl_mods
1344                                    ; case mb_s of
1345                                         Nothing -> loop ss done
1346                                         Just s  -> loop (msDeps s ++ ss)
1347                                                         (addToFM done key [s]) }
1348           where
1349             key = (unLoc wanted_mod, if is_boot then HsBootFile else HsSrcFile)
1350
1351 mkRootMap :: [ModSummary] -> NodeMap [ModSummary]
1352 mkRootMap summaries = addListToFM_C (++) emptyFM
1353                         [ (msKey s, [s]) | s <- summaries ]
1354
1355 msDeps :: ModSummary -> [(Located Module, IsBootInterface)]
1356 -- (msDeps s) returns the dependencies of the ModSummary s.
1357 -- A wrinkle is that for a {-# SOURCE #-} import we return
1358 --      *both* the hs-boot file
1359 --      *and* the source file
1360 -- as "dependencies".  That ensures that the list of all relevant
1361 -- modules always contains B.hs if it contains B.hs-boot.
1362 -- Remember, this pass isn't doing the topological sort.  It's
1363 -- just gathering the list of all relevant ModSummaries
1364 msDeps s =
1365     concat [ [(m,True), (m,False)] | m <- ms_srcimps s ]
1366          ++ [ (m,False) | m <- ms_imps s ]
1367
1368 -----------------------------------------------------------------------------
1369 -- Summarising modules
1370
1371 -- We have two types of summarisation:
1372 --
1373 --    * Summarise a file.  This is used for the root module(s) passed to
1374 --      cmLoadModules.  The file is read, and used to determine the root
1375 --      module name.  The module name may differ from the filename.
1376 --
1377 --    * Summarise a module.  We are given a module name, and must provide
1378 --      a summary.  The finder is used to locate the file in which the module
1379 --      resides.
1380
1381 summariseFile
1382         :: HscEnv
1383         -> [ModSummary]                 -- old summaries
1384         -> FilePath                     -- source file name
1385         -> Maybe Phase                  -- start phase
1386         -> Maybe (StringBuffer,ClockTime)
1387         -> IO ModSummary
1388
1389 summariseFile hsc_env old_summaries file mb_phase maybe_buf
1390         -- we can use a cached summary if one is available and the
1391         -- source file hasn't changed,  But we have to look up the summary
1392         -- by source file, rather than module name as we do in summarise.
1393    | Just old_summary <- findSummaryBySourceFile old_summaries file
1394    = do
1395         let location = ms_location old_summary
1396
1397                 -- return the cached summary if the source didn't change
1398         src_timestamp <- case maybe_buf of
1399                            Just (_,t) -> return t
1400                            Nothing    -> getModificationTime file
1401                 -- The file exists; we checked in getRootSummary above.
1402                 -- If it gets removed subsequently, then this
1403                 -- getModificationTime may fail, but that's the right
1404                 -- behaviour.
1405
1406         if ms_hs_date old_summary == src_timestamp
1407            then do -- update the object-file timestamp
1408                   obj_timestamp <- getObjTimestamp location False
1409                   return old_summary{ ms_obj_date = obj_timestamp }
1410            else
1411                 new_summary
1412
1413    | otherwise
1414    = new_summary
1415   where
1416     new_summary = do
1417         let dflags = hsc_dflags hsc_env
1418
1419         (dflags', hspp_fn, buf)
1420             <- preprocessFile dflags file mb_phase maybe_buf
1421
1422         (srcimps,the_imps, L _ mod) <- getImports dflags' buf hspp_fn
1423
1424         -- Make a ModLocation for this file
1425         location <- mkHomeModLocation dflags mod file
1426
1427         -- Tell the Finder cache where it is, so that subsequent calls
1428         -- to findModule will find it, even if it's not on any search path
1429         addHomeModuleToFinder hsc_env mod location
1430
1431         src_timestamp <- case maybe_buf of
1432                            Just (_,t) -> return t
1433                            Nothing    -> getModificationTime file
1434                         -- getMofificationTime may fail
1435
1436         obj_timestamp <- modificationTimeIfExists (ml_obj_file location)
1437
1438         return (ModSummary { ms_mod = mod, ms_hsc_src = HsSrcFile,
1439                              ms_location = location,
1440                              ms_hspp_file = Just hspp_fn,
1441                              ms_hspp_buf  = Just buf,
1442                              ms_srcimps = srcimps, ms_imps = the_imps,
1443                              ms_hs_date = src_timestamp,
1444                              ms_obj_date = obj_timestamp })
1445
1446 findSummaryBySourceFile :: [ModSummary] -> FilePath -> Maybe ModSummary
1447 findSummaryBySourceFile summaries file
1448   = case [ ms | ms <- summaries, HsSrcFile <- [ms_hsc_src ms],
1449                                  fromJust (ml_hs_file (ms_location ms)) == file ] of
1450         [] -> Nothing
1451         (x:xs) -> Just x
1452
1453 -- Summarise a module, and pick up source and timestamp.
1454 summariseModule
1455           :: HscEnv
1456           -> NodeMap ModSummary -- Map of old summaries
1457           -> IsBootInterface    -- True <=> a {-# SOURCE #-} import
1458           -> Located Module     -- Imported module to be summarised
1459           -> Maybe (StringBuffer, ClockTime)
1460           -> [Module]           -- Modules to exclude
1461           -> IO (Maybe ModSummary)      -- Its new summary
1462
1463 summariseModule hsc_env old_summary_map is_boot (L loc wanted_mod) maybe_buf excl_mods
1464   | wanted_mod `elem` excl_mods
1465   = return Nothing
1466
1467   | Just old_summary <- lookupFM old_summary_map (wanted_mod, hsc_src)
1468   = do          -- Find its new timestamp; all the
1469                 -- ModSummaries in the old map have valid ml_hs_files
1470         let location = ms_location old_summary
1471             src_fn = expectJust "summariseModule" (ml_hs_file location)
1472
1473                 -- check the modification time on the source file, and
1474                 -- return the cached summary if it hasn't changed.  If the
1475                 -- file has disappeared, we need to call the Finder again.
1476         case maybe_buf of
1477            Just (_,t) -> check_timestamp old_summary location src_fn t
1478            Nothing    -> do
1479                 m <- System.IO.Error.try (getModificationTime src_fn)
1480                 case m of
1481                    Right t -> check_timestamp old_summary location src_fn t
1482                    Left e | isDoesNotExistError e -> find_it
1483                           | otherwise             -> ioError e
1484
1485   | otherwise  = find_it
1486   where
1487     dflags = hsc_dflags hsc_env
1488
1489     hsc_src = if is_boot then HsBootFile else HsSrcFile
1490
1491     check_timestamp old_summary location src_fn src_timestamp
1492         | ms_hs_date old_summary == src_timestamp = do
1493                 -- update the object-file timestamp
1494                 obj_timestamp <- getObjTimestamp location is_boot
1495                 return (Just old_summary{ ms_obj_date = obj_timestamp })
1496         | otherwise =
1497                 -- source changed: find and re-summarise.  We call the finder
1498                 -- again, because the user may have moved the source file.
1499                 new_summary location src_fn src_timestamp
1500
1501     find_it = do
1502         -- Don't use the Finder's cache this time.  If the module was
1503         -- previously a package module, it may have now appeared on the
1504         -- search path, so we want to consider it to be a home module.  If
1505         -- the module was previously a home module, it may have moved.
1506         uncacheModule hsc_env wanted_mod
1507         found <- findModule hsc_env wanted_mod True {-explicit-}
1508         case found of
1509              Found location pkg
1510                 | not (isHomePackage pkg) -> return Nothing
1511                         -- Drop external-pkg
1512                 | isJust (ml_hs_file location) -> just_found location
1513                         -- Home package
1514              err -> noModError dflags loc wanted_mod err
1515                         -- Not found
1516
1517     just_found location = do
1518                 -- Adjust location to point to the hs-boot source file,
1519                 -- hi file, object file, when is_boot says so
1520         let location' | is_boot   = addBootSuffixLocn location
1521                       | otherwise = location
1522             src_fn = expectJust "summarise2" (ml_hs_file location')
1523
1524                 -- Check that it exists
1525                 -- It might have been deleted since the Finder last found it
1526         maybe_t <- modificationTimeIfExists src_fn
1527         case maybe_t of
1528           Nothing -> noHsFileErr loc src_fn
1529           Just t  -> new_summary location' src_fn t
1530
1531
1532     new_summary location src_fn src_timestamp
1533       = do
1534         -- Preprocess the source file and get its imports
1535         -- The dflags' contains the OPTIONS pragmas
1536         (dflags', hspp_fn, buf) <- preprocessFile dflags src_fn Nothing maybe_buf
1537         (srcimps, the_imps, L mod_loc mod_name) <- getImports dflags' buf hspp_fn
1538
1539         when (mod_name /= wanted_mod) $
1540                 throwDyn $ mkPlainErrMsg mod_loc $
1541                               text "file name does not match module name"
1542                               <+> quotes (ppr mod_name)
1543
1544                 -- Find the object timestamp, and return the summary
1545         obj_timestamp <- getObjTimestamp location is_boot
1546
1547         return (Just ( ModSummary { ms_mod       = wanted_mod,
1548                                     ms_hsc_src   = hsc_src,
1549                                     ms_location  = location,
1550                                     ms_hspp_file = Just hspp_fn,
1551                                     ms_hspp_buf  = Just buf,
1552                                     ms_srcimps   = srcimps,
1553                                     ms_imps      = the_imps,
1554                                     ms_hs_date   = src_timestamp,
1555                                     ms_obj_date  = obj_timestamp }))
1556
1557
1558 getObjTimestamp location is_boot
1559   = if is_boot then return Nothing
1560                else modificationTimeIfExists (ml_obj_file location)
1561
1562
1563 preprocessFile :: DynFlags -> FilePath -> Maybe Phase -> Maybe (StringBuffer,ClockTime)
1564   -> IO (DynFlags, FilePath, StringBuffer)
1565 preprocessFile dflags src_fn mb_phase Nothing
1566   = do
1567         (dflags', hspp_fn) <- preprocess dflags (src_fn, mb_phase)
1568         buf <- hGetStringBuffer hspp_fn
1569         return (dflags', hspp_fn, buf)
1570
1571 preprocessFile dflags src_fn mb_phase (Just (buf, time))
1572   = do
1573         -- case we bypass the preprocessing stage?
1574         let
1575             local_opts = getOptionsFromStringBuffer buf src_fn
1576         --
1577         (dflags', errs) <- parseDynamicFlags dflags (map snd local_opts)
1578
1579         let
1580             needs_preprocessing
1581                 | Just (Unlit _) <- mb_phase    = True
1582                 | Nothing <- mb_phase, Unlit _ <- startPhase src_fn  = True
1583                   -- note: local_opts is only required if there's no Unlit phase
1584                 | dopt Opt_Cpp dflags'          = True
1585                 | dopt Opt_Pp  dflags'          = True
1586                 | otherwise                     = False
1587
1588         when needs_preprocessing $
1589            ghcError (ProgramError "buffer needs preprocesing; interactive check disabled")
1590
1591         return (dflags', src_fn, buf)
1592
1593
1594 -----------------------------------------------------------------------------
1595 --                      Error messages
1596 -----------------------------------------------------------------------------
1597
1598 noModError :: DynFlags -> SrcSpan -> Module -> FindResult -> IO ab
1599 -- ToDo: we don't have a proper line number for this error
1600 noModError dflags loc wanted_mod err
1601   = throwDyn $ mkPlainErrMsg loc $ cantFindError dflags wanted_mod err
1602
1603 noHsFileErr loc path
1604   = throwDyn $ mkPlainErrMsg loc $ text "Can't find" <+> text path
1605
1606 packageModErr mod
1607   = throwDyn $ mkPlainErrMsg noSrcSpan $
1608         text "module" <+> quotes (ppr mod) <+> text "is a package module"
1609
1610 multiRootsErr :: [ModSummary] -> IO ()
1611 multiRootsErr summs@(summ1:_)
1612   = throwDyn $ mkPlainErrMsg noSrcSpan $
1613         text "module" <+> quotes (ppr mod) <+>
1614         text "is defined in multiple files:" <+>
1615         sep (map text files)
1616   where
1617     mod = ms_mod summ1
1618     files = map (expectJust "checkDup" . ml_hs_file . ms_location) summs
1619
1620 cyclicModuleErr :: [ModSummary] -> SDoc
1621 cyclicModuleErr ms
1622   = hang (ptext SLIT("Module imports form a cycle for modules:"))
1623        2 (vcat (map show_one ms))
1624   where
1625     show_one ms = sep [ show_mod (ms_hsc_src ms) (ms_mod ms),
1626                         nest 2 $ ptext SLIT("imports:") <+>
1627                                    (pp_imps HsBootFile (ms_srcimps ms)
1628                                    $$ pp_imps HsSrcFile  (ms_imps ms))]
1629     show_mod hsc_src mod = ppr mod <> text (hscSourceString hsc_src)
1630     pp_imps src mods = fsep (map (show_mod src) mods)
1631
1632
1633 -- | Inform GHC that the working directory has changed.  GHC will flush
1634 -- its cache of module locations, since it may no longer be valid.
1635 -- Note: if you change the working directory, you should also unload
1636 -- the current program (set targets to empty, followed by load).
1637 workingDirectoryChanged :: Session -> IO ()
1638 workingDirectoryChanged s = withSession s $ \hsc_env ->
1639   flushFinderCache (hsc_FC hsc_env)
1640
1641 -- -----------------------------------------------------------------------------
1642 -- inspecting the session
1643
1644 -- | Get the module dependency graph.
1645 getModuleGraph :: Session -> IO ModuleGraph -- ToDo: DiGraph ModSummary
1646 getModuleGraph s = withSession s (return . hsc_mod_graph)
1647
1648 isLoaded :: Session -> Module -> IO Bool
1649 isLoaded s m = withSession s $ \hsc_env ->
1650   return $! isJust (lookupModuleEnv (hsc_HPT hsc_env) m)
1651
1652 getBindings :: Session -> IO [TyThing]
1653 getBindings s = withSession s (return . nameEnvElts . ic_type_env . hsc_IC)
1654
1655 getPrintUnqual :: Session -> IO PrintUnqualified
1656 getPrintUnqual s = withSession s (return . icPrintUnqual . hsc_IC)
1657
1658 -- | Container for information about a 'Module'.
1659 data ModuleInfo = ModuleInfo {
1660         minf_type_env  :: TypeEnv,
1661         minf_exports   :: NameSet,
1662         minf_rdr_env   :: Maybe GlobalRdrEnv,   -- Nothing for a compiled/package mod
1663         minf_instances :: [Instance]
1664         -- ToDo: this should really contain the ModIface too
1665   }
1666         -- We don't want HomeModInfo here, because a ModuleInfo applies
1667         -- to package modules too.
1668
1669 -- | Request information about a loaded 'Module'
1670 getModuleInfo :: Session -> Module -> IO (Maybe ModuleInfo)
1671 getModuleInfo s mdl = withSession s $ \hsc_env -> do
1672   let mg = hsc_mod_graph hsc_env
1673   if mdl `elem` map ms_mod mg
1674         then getHomeModuleInfo hsc_env mdl
1675         else do
1676   {- if isHomeModule (hsc_dflags hsc_env) mdl
1677         then return Nothing
1678         else -} getPackageModuleInfo hsc_env mdl
1679    -- getPackageModuleInfo will attempt to find the interface, so
1680    -- we don't want to call it for a home module, just in case there
1681    -- was a problem loading the module and the interface doesn't
1682    -- exist... hence the isHomeModule test here.  (ToDo: reinstate)
1683
1684 getPackageModuleInfo :: HscEnv -> Module -> IO (Maybe ModuleInfo)
1685 getPackageModuleInfo hsc_env mdl = do
1686 #ifdef GHCI
1687   (_msgs, mb_names) <- getModuleExports hsc_env mdl
1688   case mb_names of
1689     Nothing -> return Nothing
1690     Just names -> do
1691         eps <- readIORef (hsc_EPS hsc_env)
1692         let
1693             pte    = eps_PTE eps
1694             n_list = nameSetToList names
1695             tys    = [ ty | name <- n_list,
1696                             Just ty <- [lookupTypeEnv pte name] ]
1697         --
1698         return (Just (ModuleInfo {
1699                         minf_type_env  = mkTypeEnv tys,
1700                         minf_exports   = names,
1701                         minf_rdr_env   = Just $! nameSetToGlobalRdrEnv names mdl,
1702                         minf_instances = error "getModuleInfo: instances for package module unimplemented"
1703                 }))
1704 #else
1705   -- bogusly different for non-GHCI (ToDo)
1706   return Nothing
1707 #endif
1708
1709 getHomeModuleInfo hsc_env mdl =
1710   case lookupModuleEnv (hsc_HPT hsc_env) mdl of
1711     Nothing  -> return Nothing
1712     Just hmi -> do
1713       let details = hm_details hmi
1714       return (Just (ModuleInfo {
1715                         minf_type_env  = md_types details,
1716                         minf_exports   = md_exports details,
1717                         minf_rdr_env   = mi_globals $! hm_iface hmi,
1718                         minf_instances = md_insts details
1719                         }))
1720
1721 -- | The list of top-level entities defined in a module
1722 modInfoTyThings :: ModuleInfo -> [TyThing]
1723 modInfoTyThings minf = typeEnvElts (minf_type_env minf)
1724
1725 modInfoTopLevelScope :: ModuleInfo -> Maybe [Name]
1726 modInfoTopLevelScope minf
1727   = fmap (map gre_name . globalRdrEnvElts) (minf_rdr_env minf)
1728
1729 modInfoExports :: ModuleInfo -> [Name]
1730 modInfoExports minf = nameSetToList $! minf_exports minf
1731
1732 -- | Returns the instances defined by the specified module.
1733 -- Warning: currently unimplemented for package modules.
1734 modInfoInstances :: ModuleInfo -> [Instance]
1735 modInfoInstances = minf_instances
1736
1737 modInfoIsExportedName :: ModuleInfo -> Name -> Bool
1738 modInfoIsExportedName minf name = elemNameSet name (minf_exports minf)
1739
1740 modInfoPrintUnqualified :: ModuleInfo -> Maybe PrintUnqualified
1741 modInfoPrintUnqualified minf = fmap unQualInScope (minf_rdr_env minf)
1742
1743 modInfoLookupName :: Session -> ModuleInfo -> Name -> IO (Maybe TyThing)
1744 modInfoLookupName s minf name = withSession s $ \hsc_env -> do
1745    case lookupTypeEnv (minf_type_env minf) name of
1746      Just tyThing -> return (Just tyThing)
1747      Nothing      -> do
1748        eps <- readIORef (hsc_EPS hsc_env)
1749        return $! lookupType (hsc_HPT hsc_env) (eps_PTE eps) name
1750
1751 isDictonaryId :: Id -> Bool
1752 isDictonaryId id
1753   = case tcSplitSigmaTy (idType id) of { (tvs, theta, tau) -> isDictTy tau }
1754
1755 -- | Looks up a global name: that is, any top-level name in any
1756 -- visible module.  Unlike 'lookupName', lookupGlobalName does not use
1757 -- the interactive context, and therefore does not require a preceding
1758 -- 'setContext'.
1759 lookupGlobalName :: Session -> Name -> IO (Maybe TyThing)
1760 lookupGlobalName s name = withSession s $ \hsc_env -> do
1761    eps <- readIORef (hsc_EPS hsc_env)
1762    return $! lookupType (hsc_HPT hsc_env) (eps_PTE eps) name
1763
1764 -- -----------------------------------------------------------------------------
1765 -- Misc exported utils
1766
1767 dataConType :: DataCon -> Type
1768 dataConType dc = idType (dataConWrapId dc)
1769
1770 -- | print a 'NamedThing', adding parentheses if the name is an operator.
1771 pprParenSymName :: NamedThing a => a -> SDoc
1772 pprParenSymName a = parenSymOcc (getOccName a) (ppr (getName a))
1773
1774 -- ----------------------------------------------------------------------------
1775
1776 #if 0
1777
1778 -- ToDo:
1779 --   - Data and Typeable instances for HsSyn.
1780
1781 -- ToDo: check for small transformations that happen to the syntax in
1782 -- the typechecker (eg. -e ==> negate e, perhaps for fromIntegral)
1783
1784 -- ToDo: maybe use TH syntax instead of IfaceSyn?  There's already a way
1785 -- to get from TyCons, Ids etc. to TH syntax (reify).
1786
1787 -- :browse will use either lm_toplev or inspect lm_interface, depending
1788 -- on whether the module is interpreted or not.
1789
1790 -- This is for reconstructing refactored source code
1791 -- Calls the lexer repeatedly.
1792 -- ToDo: add comment tokens to token stream
1793 getTokenStream :: Session -> Module -> IO [Located Token]
1794 #endif
1795
1796 -- -----------------------------------------------------------------------------
1797 -- Interactive evaluation
1798
1799 #ifdef GHCI
1800
1801 -- | Set the interactive evaluation context.
1802 --
1803 -- Setting the context doesn't throw away any bindings; the bindings
1804 -- we've built up in the InteractiveContext simply move to the new
1805 -- module.  They always shadow anything in scope in the current context.
1806 setContext :: Session
1807            -> [Module]  -- entire top level scope of these modules
1808            -> [Module]  -- exports only of these modules
1809            -> IO ()
1810 setContext (Session ref) toplevs exports = do
1811   hsc_env <- readIORef ref
1812   let old_ic  = hsc_IC     hsc_env
1813       hpt     = hsc_HPT    hsc_env
1814
1815   mapM_ (checkModuleExists hsc_env hpt) exports
1816   export_env  <- mkExportEnv hsc_env exports
1817   toplev_envs <- mapM (mkTopLevEnv hpt) toplevs
1818   let all_env = foldr plusGlobalRdrEnv export_env toplev_envs
1819   writeIORef ref hsc_env{ hsc_IC = old_ic { ic_toplev_scope = toplevs,
1820                                             ic_exports      = exports,
1821                                             ic_rn_gbl_env   = all_env }}
1822
1823
1824 -- Make a GlobalRdrEnv based on the exports of the modules only.
1825 mkExportEnv :: HscEnv -> [Module] -> IO GlobalRdrEnv
1826 mkExportEnv hsc_env mods = do
1827   stuff <- mapM (getModuleExports hsc_env) mods
1828   let
1829         (_msgs, mb_name_sets) = unzip stuff
1830         gres = [ nameSetToGlobalRdrEnv name_set mod
1831                | (Just name_set, mod) <- zip mb_name_sets mods ]
1832   --
1833   return $! foldr plusGlobalRdrEnv emptyGlobalRdrEnv gres
1834
1835 nameSetToGlobalRdrEnv :: NameSet -> Module -> GlobalRdrEnv
1836 nameSetToGlobalRdrEnv names mod =
1837   mkGlobalRdrEnv [ GRE  { gre_name = name, gre_prov = vanillaProv mod }
1838                  | name <- nameSetToList names ]
1839
1840 vanillaProv :: Module -> Provenance
1841 -- We're building a GlobalRdrEnv as if the user imported
1842 -- all the specified modules into the global interactive module
1843 vanillaProv mod = Imported [ImpSpec { is_decl = decl, is_item = ImpAll}]
1844   where
1845     decl = ImpDeclSpec { is_mod = mod, is_as = mod,
1846                          is_qual = False,
1847                          is_dloc = srcLocSpan interactiveSrcLoc }
1848
1849 checkModuleExists :: HscEnv -> HomePackageTable -> Module -> IO ()
1850 checkModuleExists hsc_env hpt mod =
1851   case lookupModuleEnv hpt mod of
1852     Just mod_info -> return ()
1853     _not_a_home_module -> do
1854           res <- findPackageModule hsc_env mod True
1855           case res of
1856             Found _ _ -> return  ()
1857             err -> let msg = cantFindError (hsc_dflags hsc_env) mod err in
1858                    throwDyn (CmdLineError (showSDoc msg))
1859
1860 mkTopLevEnv :: HomePackageTable -> Module -> IO GlobalRdrEnv
1861 mkTopLevEnv hpt modl
1862  = case lookupModuleEnv hpt modl of
1863       Nothing ->
1864          throwDyn (ProgramError ("mkTopLevEnv: not a home module "
1865                         ++ showSDoc (pprModule modl)))
1866       Just details ->
1867          case mi_globals (hm_iface details) of
1868                 Nothing  ->
1869                    throwDyn (ProgramError ("mkTopLevEnv: not interpreted "
1870                                                 ++ showSDoc (pprModule modl)))
1871                 Just env -> return env
1872
1873 -- | Get the interactive evaluation context, consisting of a pair of the
1874 -- set of modules from which we take the full top-level scope, and the set
1875 -- of modules from which we take just the exports respectively.
1876 getContext :: Session -> IO ([Module],[Module])
1877 getContext s = withSession s (\HscEnv{ hsc_IC=ic } ->
1878                                 return (ic_toplev_scope ic, ic_exports ic))
1879
1880 -- | Returns 'True' if the specified module is interpreted, and hence has
1881 -- its full top-level scope available.
1882 moduleIsInterpreted :: Session -> Module -> IO Bool
1883 moduleIsInterpreted s modl = withSession s $ \h ->
1884  case lookupModuleEnv (hsc_HPT h) modl of
1885       Just details       -> return (isJust (mi_globals (hm_iface details)))
1886       _not_a_home_module -> return False
1887
1888 -- | Looks up an identifier in the current interactive context (for :info)
1889 getInfo :: Session -> Name -> IO (Maybe (TyThing,Fixity,[Instance]))
1890 getInfo s name = withSession s $ \hsc_env -> tcRnGetInfo hsc_env name
1891
1892 -- | Returns all names in scope in the current interactive context
1893 getNamesInScope :: Session -> IO [Name]
1894 getNamesInScope s = withSession s $ \hsc_env -> do
1895   return (map gre_name (globalRdrEnvElts (ic_rn_gbl_env (hsc_IC hsc_env))))
1896
1897 getRdrNamesInScope :: Session -> IO [RdrName]
1898 getRdrNamesInScope  s = withSession s $ \hsc_env -> do
1899   let env = ic_rn_gbl_env (hsc_IC hsc_env)
1900   return (concat (map greToRdrNames (globalRdrEnvElts env)))
1901
1902 -- ToDo: move to RdrName
1903 greToRdrNames :: GlobalRdrElt -> [RdrName]
1904 greToRdrNames GRE{ gre_name = name, gre_prov = prov }
1905   = case prov of
1906      LocalDef -> [unqual]
1907      Imported specs -> concat (map do_spec (map is_decl specs))
1908   where
1909     occ = nameOccName name
1910     unqual = Unqual occ
1911     do_spec decl_spec
1912         | is_qual decl_spec = [qual]
1913         | otherwise         = [unqual,qual]
1914         where qual = Qual (is_as decl_spec) occ
1915
1916 -- | Parses a string as an identifier, and returns the list of 'Name's that
1917 -- the identifier can refer to in the current interactive context.
1918 parseName :: Session -> String -> IO [Name]
1919 parseName s str = withSession s $ \hsc_env -> do
1920    maybe_rdr_name <- hscParseIdentifier (hsc_dflags hsc_env) str
1921    case maybe_rdr_name of
1922         Nothing -> return []
1923         Just (L _ rdr_name) -> do
1924             mb_names <- tcRnLookupRdrName hsc_env rdr_name
1925             case mb_names of
1926                 Nothing -> return []
1927                 Just ns -> return ns
1928                 -- ToDo: should return error messages
1929
1930 -- | Returns the 'TyThing' for a 'Name'.  The 'Name' may refer to any
1931 -- entity known to GHC, including 'Name's defined using 'runStmt'.
1932 lookupName :: Session -> Name -> IO (Maybe TyThing)
1933 lookupName s name = withSession s $ \hsc_env -> tcRnLookupName hsc_env name
1934
1935 -- -----------------------------------------------------------------------------
1936 -- Getting the type of an expression
1937
1938 -- | Get the type of an expression
1939 exprType :: Session -> String -> IO (Maybe Type)
1940 exprType s expr = withSession s $ \hsc_env -> do
1941    maybe_stuff <- hscTcExpr hsc_env expr
1942    case maybe_stuff of
1943         Nothing -> return Nothing
1944         Just ty -> return (Just tidy_ty)
1945              where
1946                 tidy_ty = tidyType emptyTidyEnv ty
1947
1948 -- -----------------------------------------------------------------------------
1949 -- Getting the kind of a type
1950
1951 -- | Get the kind of a  type
1952 typeKind  :: Session -> String -> IO (Maybe Kind)
1953 typeKind s str = withSession s $ \hsc_env -> do
1954    maybe_stuff <- hscKcType hsc_env str
1955    case maybe_stuff of
1956         Nothing -> return Nothing
1957         Just kind -> return (Just kind)
1958
1959 -----------------------------------------------------------------------------
1960 -- cmCompileExpr: compile an expression and deliver an HValue
1961
1962 compileExpr :: Session -> String -> IO (Maybe HValue)
1963 compileExpr s expr = withSession s $ \hsc_env -> do
1964   maybe_stuff <- hscStmt hsc_env ("let __cmCompileExpr = "++expr)
1965   case maybe_stuff of
1966         Nothing -> return Nothing
1967         Just (new_ic, names, hval) -> do
1968                         -- Run it!
1969                 hvals <- (unsafeCoerce# hval) :: IO [HValue]
1970
1971                 case (names,hvals) of
1972                   ([n],[hv]) -> return (Just hv)
1973                   _          -> panic "compileExpr"
1974
1975 -- -----------------------------------------------------------------------------
1976 -- running a statement interactively
1977
1978 data RunResult
1979   = RunOk [Name]                -- ^ names bound by this evaluation
1980   | RunFailed                   -- ^ statement failed compilation
1981   | RunException Exception      -- ^ statement raised an exception
1982
1983 -- | Run a statement in the current interactive context.  Statemenet
1984 -- may bind multple values.
1985 runStmt :: Session -> String -> IO RunResult
1986 runStmt (Session ref) expr
1987    = do
1988         hsc_env <- readIORef ref
1989
1990         -- Turn off -fwarn-unused-bindings when running a statement, to hide
1991         -- warnings about the implicit bindings we introduce.
1992         let dflags'  = dopt_unset (hsc_dflags hsc_env) Opt_WarnUnusedBinds
1993             hsc_env' = hsc_env{ hsc_dflags = dflags' }
1994
1995         maybe_stuff <- hscStmt hsc_env' expr
1996
1997         case maybe_stuff of
1998            Nothing -> return RunFailed
1999            Just (new_hsc_env, names, hval) -> do
2000
2001                 let thing_to_run = unsafeCoerce# hval :: IO [HValue]
2002                 either_hvals <- sandboxIO thing_to_run
2003
2004                 case either_hvals of
2005                     Left e -> do
2006                         -- on error, keep the *old* interactive context,
2007                         -- so that 'it' is not bound to something
2008                         -- that doesn't exist.
2009                         return (RunException e)
2010
2011                     Right hvals -> do
2012                         -- Get the newly bound things, and bind them.
2013                         -- Don't need to delete any shadowed bindings;
2014                         -- the new ones override the old ones.
2015                         extendLinkEnv (zip names hvals)
2016
2017                         writeIORef ref new_hsc_env
2018                         return (RunOk names)
2019
2020 -- When running a computation, we redirect ^C exceptions to the running
2021 -- thread.  ToDo: we might want a way to continue even if the target
2022 -- thread doesn't die when it receives the exception... "this thread
2023 -- is not responding".
2024 sandboxIO :: IO a -> IO (Either Exception a)
2025 sandboxIO thing = do
2026   m <- newEmptyMVar
2027   ts <- takeMVar interruptTargetThread
2028   child <- forkIO (do res <- Exception.try thing; putMVar m res)
2029   putMVar interruptTargetThread (child:ts)
2030   takeMVar m `finally` modifyMVar_ interruptTargetThread (return.tail)
2031
2032 {-
2033 -- This version of sandboxIO runs the expression in a completely new
2034 -- RTS main thread.  It is disabled for now because ^C exceptions
2035 -- won't be delivered to the new thread, instead they'll be delivered
2036 -- to the (blocked) GHCi main thread.
2037
2038 -- SLPJ: when re-enabling this, reflect a wrong-stat error as an exception
2039
2040 sandboxIO :: IO a -> IO (Either Int (Either Exception a))
2041 sandboxIO thing = do
2042   st_thing <- newStablePtr (Exception.try thing)
2043   alloca $ \ p_st_result -> do
2044     stat <- rts_evalStableIO st_thing p_st_result
2045     freeStablePtr st_thing
2046     if stat == 1
2047         then do st_result <- peek p_st_result
2048                 result <- deRefStablePtr st_result
2049                 freeStablePtr st_result
2050                 return (Right result)
2051         else do
2052                 return (Left (fromIntegral stat))
2053
2054 foreign import "rts_evalStableIO"  {- safe -}
2055   rts_evalStableIO :: StablePtr (IO a) -> Ptr (StablePtr a) -> IO CInt
2056   -- more informative than the C type!
2057 -}
2058
2059 -----------------------------------------------------------------------------
2060 -- show a module and it's source/object filenames
2061
2062 showModule :: Session -> ModSummary -> IO String
2063 showModule s mod_summary = withSession s $ \hsc_env -> do
2064   case lookupModuleEnv (hsc_HPT hsc_env) (ms_mod mod_summary) of
2065         Nothing       -> panic "missing linkable"
2066         Just mod_info -> return (showModMsg obj_linkable mod_summary)
2067                       where
2068                          obj_linkable = isObjectLinkable (fromJust (hm_linkable mod_info))
2069
2070 #endif /* GHCI */