ghc/compiler/main/HscTypes.lhs

   1 %
   2 % (c) The University of Glasgow, 2000
   3 %
   4 \section[HscTypes]{Types for the per-module compiler}
   5
   6 \begin{code}
   7 module HscTypes (
   8         ModuleLocation(..),
   9
  10         ModDetails(..), ModIface(..),
  11         HomeSymbolTable, emptySymbolTable,
  12         PackageTypeEnv,
  13         HomeIfaceTable, PackageIfaceTable, emptyIfaceTable,
  14         lookupIface, lookupIfaceByModName,
  15         emptyModIface,
  16
  17         InteractiveContext(..),
  18
  19         IfaceDecls, mkIfaceDecls, dcl_tycl, dcl_rules, dcl_insts,
  20
  21         VersionInfo(..), initialVersionInfo,
  22
  23         TyThing(..), isTyClThing, implicitTyThingIds,
  24
  25         TypeEnv, lookupType, mkTypeEnv, emptyTypeEnv,
  26         extendTypeEnvList, extendTypeEnvWithIds,
  27         typeEnvClasses, typeEnvTyCons, typeEnvIds,
  28
  29         ImportedModuleInfo, WhetherHasOrphans, ImportVersion, WhatsImported(..),
  30         PersistentRenamerState(..), IsBootInterface, DeclsMap,
  31         IfaceInsts, IfaceRules, GatedDecl, IsExported,
  32         NameSupply(..), OrigNameCache, OrigIParamCache,
  33         Avails, AvailEnv, GenAvailInfo(..), AvailInfo, RdrAvailInfo,
  34         PersistentCompilerState(..),
  35
  36         Deprecations(..), lookupDeprec,
  37
  38         InstEnv, ClsInstEnv, DFunId,
  39         PackageInstEnv, PackageRuleBase,
  40
  41         GlobalRdrEnv, GlobalRdrElt(..), pprGlobalRdrEnv,
  42         LocalRdrEnv, extendLocalRdrEnv,
  43
  44
  45         -- Provenance
  46         Provenance(..), ImportReason(..),
  47         pprNameProvenance, hasBetterProv
  48
  49     ) where
  50
  51 #include "HsVersions.h"
  52
  53 import RdrName          ( RdrNameEnv, addListToRdrEnv, emptyRdrEnv, mkRdrUnqual, rdrEnvToList )
  54 import Name             ( Name, NamedThing, getName, nameOccName, nameModule, nameSrcLoc )
  55 import Name -- Env
  56 import OccName          ( OccName )
  57 import Module           ( Module, ModuleName, ModuleEnv,
  58                           lookupModuleEnv, lookupModuleEnvByName, emptyModuleEnv
  59                         )
  60 import InstEnv          ( InstEnv, ClsInstEnv, DFunId )
  61 import Rules            ( RuleBase )
  62 import Id               ( Id )
  63 import Class            ( Class, classSelIds )
  64 import TyCon            ( TyCon, tyConGenIds, tyConSelIds, tyConDataConsIfAvailable )
  65 import DataCon          ( dataConId, dataConWrapId )
  66
  67 import BasicTypes       ( Version, initialVersion, Fixity )
  68
  69 import HsSyn            ( DeprecTxt, tyClDeclName, ifaceRuleDeclName )
  70 import RdrHsSyn         ( RdrNameInstDecl, RdrNameRuleDecl, RdrNameTyClDecl )
  71 import RnHsSyn          ( RenamedTyClDecl, RenamedRuleDecl, RenamedInstDecl )
  72
  73 import CoreSyn          ( IdCoreRule )
  74
  75 import FiniteMap        ( FiniteMap )
  76 import Bag              ( Bag )
  77 import Maybes           ( seqMaybe )
  78 import Outputable
  79 import SrcLoc           ( SrcLoc, isGoodSrcLoc )
  80 import Util             ( thenCmp, sortLt )
  81 import UniqSupply       ( UniqSupply )
  82 \end{code}
  83
  84 %************************************************************************
  85 %*                                                                      *
  86 \subsection{Module locations}
  87 %*                                                                      *
  88 %************************************************************************
  89
  90 \begin{code}
  91 data ModuleLocation
  92    = ModuleLocation {
  93         ml_hs_file   :: Maybe FilePath,
  94         ml_hspp_file :: Maybe FilePath,  -- path of preprocessed source
  95         ml_hi_file   :: Maybe FilePath,
  96         ml_obj_file  :: Maybe FilePath
  97      }
  98      deriving Show
  99
 100 instance Outputable ModuleLocation where
 101    ppr = text . show
 102 \end{code}
 103
 104 For a module in another package, the hs_file and obj_file
 105 components of ModuleLocation are undefined.
 106
 107 The locations specified by a ModuleLocation may or may not
 108 correspond to actual files yet: for example, even if the object
 109 file doesn't exist, the ModuleLocation still contains the path to
 110 where the object file will reside if/when it is created.
 111
 112
 113 %************************************************************************
 114 %*                                                                      *
 115 \subsection{Symbol tables and Module details}
 116 %*                                                                      *
 117 %************************************************************************
 118
 119 A @ModIface@ plus a @ModDetails@ summarises everything we know
 120 about a compiled module.  The @ModIface@ is the stuff *before* linking,
 121 and can be written out to an interface file.  The @ModDetails@ is after
 122 linking; it is the "linked" form of the mi_decls field.
 123
 124 \begin{code}
 125 data ModIface
 126    = ModIface {
 127         mi_module   :: Module,                  -- Complete with package info
 128         mi_version  :: VersionInfo,             -- Module version number
 129         mi_orphan   :: WhetherHasOrphans,       -- Whether this module has orphans
 130         mi_boot     :: IsBootInterface,         -- Whether this interface was read from an hi-boot file
 131
 132         mi_usages   :: [ImportVersion Name],    -- Usages; kept sorted so that it's easy
 133                                                 -- to decide whether to write a new iface file
 134                                                 -- (changing usages doesn't affect the version of
 135                                                 --  this module)
 136
 137         mi_exports  :: [(ModuleName,Avails)],   -- What it exports
 138                                                 -- Kept sorted by (mod,occ),
 139                                                 -- to make version comparisons easier
 140
 141         mi_globals  :: GlobalRdrEnv,            -- Its top level environment
 142
 143         mi_fixities :: NameEnv Fixity,          -- Fixities
 144         mi_deprecs  :: Deprecations,            -- Deprecations
 145
 146         mi_decls    :: IfaceDecls               -- The RnDecls form of ModDetails
 147      }
 148
 149 data IfaceDecls = IfaceDecls { dcl_tycl  :: [RenamedTyClDecl],  -- Sorted
 150                                dcl_rules :: [RenamedRuleDecl],  -- Sorted
 151                                dcl_insts :: [RenamedInstDecl] } -- Unsorted
 152
 153 mkIfaceDecls :: [RenamedTyClDecl] -> [RenamedRuleDecl] -> [RenamedInstDecl] -> IfaceDecls
 154 mkIfaceDecls tycls rules insts
 155   = IfaceDecls { dcl_tycl  = sortLt lt_tycl tycls,
 156                  dcl_rules = sortLt lt_rule rules,
 157                  dcl_insts = insts }
 158   where
 159     d1 `lt_tycl` d2 = tyClDeclName      d1 < tyClDeclName      d2
 160     r1 `lt_rule` r2 = ifaceRuleDeclName r1 < ifaceRuleDeclName r2
 161
 162
 163 -- typechecker should only look at this, not ModIface
 164 -- Should be able to construct ModDetails from mi_decls in ModIface
 165 data ModDetails
 166    = ModDetails {
 167         -- The next three fields are created by the typechecker
 168         md_types    :: TypeEnv,
 169         md_insts    :: [DFunId],        -- Dfun-ids for the instances in this module
 170         md_rules    :: [IdCoreRule]     -- Domain may include Ids from other modules
 171      }
 172 \end{code}
 173
 174 \begin{code}
 175 emptyModDetails :: ModDetails
 176 emptyModDetails
 177   = ModDetails { md_types = emptyTypeEnv,
 178                  md_insts = [],
 179                  md_rules = []
 180     }
 181
 182 emptyModIface :: Module -> ModIface
 183 emptyModIface mod
 184   = ModIface { mi_module   = mod,
 185                mi_version  = initialVersionInfo,
 186                mi_usages   = [],
 187                mi_orphan   = False,
 188                mi_boot     = False,
 189                mi_exports  = [],
 190                mi_fixities = emptyNameEnv,
 191                mi_globals  = emptyRdrEnv,
 192                mi_deprecs  = NoDeprecs,
 193                mi_decls    = panic "emptyModIface: decls"
 194     }
 195 \end{code}
 196
 197 Symbol tables map modules to ModDetails:
 198
 199 \begin{code}
 200 type SymbolTable        = ModuleEnv ModDetails
 201 type IfaceTable         = ModuleEnv ModIface
 202
 203 type HomeIfaceTable     = IfaceTable
 204 type PackageIfaceTable  = IfaceTable
 205
 206 type HomeSymbolTable    = SymbolTable   -- Domain = modules in the home package
 207
 208 emptySymbolTable :: SymbolTable
 209 emptySymbolTable = emptyModuleEnv
 210
 211 emptyIfaceTable :: IfaceTable
 212 emptyIfaceTable = emptyModuleEnv
 213 \end{code}
 214
 215 Simple lookups in the symbol table.
 216
 217 \begin{code}
 218 lookupIface :: HomeIfaceTable -> PackageIfaceTable -> Name -> Maybe ModIface
 219 -- We often have two IfaceTables, and want to do a lookup
 220 lookupIface hit pit name
 221   = lookupModuleEnv hit mod `seqMaybe` lookupModuleEnv pit mod
 222   where
 223     mod = nameModule name
 224
 225 lookupIfaceByModName :: HomeIfaceTable -> PackageIfaceTable -> ModuleName -> Maybe ModIface
 226 -- We often have two IfaceTables, and want to do a lookup
 227 lookupIfaceByModName hit pit mod
 228   = lookupModuleEnvByName hit mod `seqMaybe` lookupModuleEnvByName pit mod
 229 \end{code}
 230
 231
 232 %************************************************************************
 233 %*                                                                      *
 234 \subsection{The interactive context}
 235 %*                                                                      *
 236 %************************************************************************
 237
 238 \begin{code}
 239 data InteractiveContext
 240   = InteractiveContext {
 241         ic_module :: Module,            -- The current module in which
 242                                         -- the  user is sitting
 243
 244         ic_rn_env :: LocalRdrEnv,       -- Lexical context for variables bound
 245                                         -- during interaction
 246
 247         ic_type_env :: TypeEnv          -- Ditto for types
 248     }
 249 \end{code}
 250
 251
 252 %************************************************************************
 253 %*                                                                      *
 254 \subsection{Type environment stuff}
 255 %*                                                                      *
 256 %************************************************************************
 257
 258 \begin{code}
 259 data TyThing = AnId   Id
 260              | ATyCon TyCon
 261              | AClass Class
 262
 263 isTyClThing :: TyThing -> Bool
 264 isTyClThing (ATyCon _) = True
 265 isTyClThing (AClass _) = True
 266 isTyClThing (AnId   _) = False
 267
 268 instance NamedThing TyThing where
 269   getName (AnId id)   = getName id
 270   getName (ATyCon tc) = getName tc
 271   getName (AClass cl) = getName cl
 272
 273 instance Outputable TyThing where
 274   ppr (AnId   id) = ptext SLIT("AnId")   <+> ppr id
 275   ppr (ATyCon tc) = ptext SLIT("ATyCon") <+> ppr tc
 276   ppr (AClass cl) = ptext SLIT("AClass") <+> ppr cl
 277
 278 typeEnvClasses env = [cl | AClass cl <- nameEnvElts env]
 279 typeEnvTyCons  env = [tc | ATyCon tc <- nameEnvElts env]
 280 typeEnvIds     env = [id | AnId id   <- nameEnvElts env]
 281
 282 implicitTyThingIds :: [TyThing] -> [Id]
 283 -- Add the implicit data cons and selectors etc
 284 implicitTyThingIds things
 285   = concat (map go things)
 286   where
 287     go (AnId f)    = []
 288     go (AClass cl) = classSelIds cl
 289     go (ATyCon tc) = tyConGenIds tc ++
 290                      tyConSelIds tc ++
 291                      [ n | dc <- tyConDataConsIfAvailable tc,
 292                            n  <- [dataConId dc, dataConWrapId dc] ]
 293                 -- Synonyms return empty list of constructors and selectors
 294 \end{code}
 295
 296
 297 \begin{code}
 298 type TypeEnv = NameEnv TyThing
 299
 300 emptyTypeEnv = emptyNameEnv
 301
 302 mkTypeEnv :: [TyThing] -> TypeEnv
 303 mkTypeEnv things = extendTypeEnvList emptyTypeEnv things
 304
 305 extendTypeEnvList :: TypeEnv -> [TyThing] -> TypeEnv
 306 extendTypeEnvList env things
 307   = extendNameEnvList env [(getName thing, thing) | thing <- things]
 308
 309 extendTypeEnvWithIds :: TypeEnv -> [Id] -> TypeEnv
 310 extendTypeEnvWithIds env ids
 311   = extendNameEnvList env [(getName id, AnId id) | id <- ids]
 312 \end{code}
 313
 314 \begin{code}
 315 lookupType :: HomeSymbolTable -> PackageTypeEnv -> Name -> Maybe TyThing
 316 lookupType hst pte name
 317   = case lookupModuleEnv hst (nameModule name) of
 318         Just details -> lookupNameEnv (md_types details) name
 319         Nothing      -> lookupNameEnv pte name
 320 \end{code}
 321
 322 %************************************************************************
 323 %*                                                                      *
 324 \subsection{Auxiliary types}
 325 %*                                                                      *
 326 %************************************************************************
 327
 328 These types are defined here because they are mentioned in ModDetails,
 329 but they are mostly elaborated elsewhere
 330
 331 \begin{code}
 332 data VersionInfo
 333   = VersionInfo {
 334         vers_module  :: Version,        -- Changes when anything changes
 335         vers_exports :: Version,        -- Changes when export list changes
 336         vers_rules   :: Version,        -- Changes when any rule changes
 337         vers_decls   :: NameEnv Version
 338                 -- Versions for "big" names only (not data constructors, class ops)
 339                 -- The version of an Id changes if its fixity changes
 340                 -- Ditto data constructors, class operations, except that the version of
 341                 -- the parent class/tycon changes
 342     }
 343
 344 initialVersionInfo :: VersionInfo
 345 initialVersionInfo = VersionInfo { vers_module  = initialVersion,
 346                                    vers_exports = initialVersion,
 347                                    vers_rules   = initialVersion,
 348                                    vers_decls   = emptyNameEnv }
 349
 350 data Deprecations = NoDeprecs
 351                   | DeprecAll DeprecTxt                         -- Whole module deprecated
 352                   | DeprecSome (NameEnv (Name,DeprecTxt))       -- Some things deprecated
 353                                                                 -- Just "big" names
 354                 -- We keep the Name in the range, so we can print them out
 355
 356 lookupDeprec :: Deprecations -> Name -> Maybe DeprecTxt
 357 lookupDeprec NoDeprecs        name = Nothing
 358 lookupDeprec (DeprecAll  txt) name = Just txt
 359 lookupDeprec (DeprecSome env) name = case lookupNameEnv env name of
 360                                             Just (_, txt) -> Just txt
 361                                             Nothing       -> Nothing
 362
 363 instance Eq Deprecations where
 364   -- Used when checking whether we need write a new interface
 365   NoDeprecs       == NoDeprecs       = True
 366   (DeprecAll t1)  == (DeprecAll t2)  = t1 == t2
 367   (DeprecSome e1) == (DeprecSome e2) = nameEnvElts e1 == nameEnvElts e2
 368   d1              == d2              = False
 369 \end{code}
 370
 371
 372 \begin{code}
 373 type Avails       = [AvailInfo]
 374 type AvailInfo    = GenAvailInfo Name
 375 type RdrAvailInfo = GenAvailInfo OccName
 376
 377 data GenAvailInfo name  = Avail name     -- An ordinary identifier
 378                         | AvailTC name   -- The name of the type or class
 379                                   [name] -- The available pieces of type/class.
 380                                          -- NB: If the type or class is itself
 381                                          -- to be in scope, it must be in this list.
 382                                          -- Thus, typically: AvailTC Eq [Eq, ==, /=]
 383                         deriving( Eq )
 384                         -- Equality used when deciding if the interface has changed
 385
 386 type AvailEnv     = NameEnv AvailInfo   -- Maps a Name to the AvailInfo that contains it
 387
 388 instance Outputable n => Outputable (GenAvailInfo n) where
 389    ppr = pprAvail
 390
 391 pprAvail :: Outputable n => GenAvailInfo n -> SDoc
 392 pprAvail (AvailTC n ns) = ppr n <> case {- filter (/= n) -} ns of
 393                                         []  -> empty
 394                                         ns' -> braces (hsep (punctuate comma (map ppr ns')))
 395
 396 pprAvail (Avail n) = ppr n
 397 \end{code}
 398
 399
 400 %************************************************************************
 401 %*                                                                      *
 402 \subsection{ModIface}
 403 %*                                                                      *
 404 %************************************************************************
 405
 406 \begin{code}
 407 type WhetherHasOrphans   = Bool
 408         -- An "orphan" is
 409         --      * an instance decl in a module other than the defn module for
 410         --              one of the tycons or classes in the instance head
 411         --      * a transformation rule in a module other than the one defining
 412         --              the function in the head of the rule.
 413
 414 type IsBootInterface     = Bool
 415
 416 type ImportVersion name  = (ModuleName, WhetherHasOrphans, IsBootInterface, WhatsImported name)
 417
 418 data WhatsImported name  = NothingAtAll                         -- The module is below us in the
 419                                                                 -- hierarchy, but we import nothing
 420
 421                          | Everything Version           -- Used for modules from other packages;
 422                                                         -- we record only the module's version number
 423
 424                          | Specifically
 425                                 Version                 -- Module version
 426                                 (Maybe Version)         -- Export-list version, if we depend on it
 427                                 [(name,Version)]        -- List guaranteed non-empty
 428                                 Version                 -- Rules version
 429
 430                          deriving( Eq )
 431         -- 'Specifically' doesn't let you say "I imported f but none of the rules in
 432         -- the module". If you use anything in the module you get its rule version
 433         -- So if the rules change, you'll recompile, even if you don't use them.
 434         -- This is easy to implement, and it's safer: you might not have used the rules last
 435         -- time round, but if someone has added a new rule you might need it this time
 436
 437         -- The export list field is (Just v) if we depend on the export list:
 438         --      we imported the module without saying exactly what we imported
 439         -- We need to recompile if the module exports changes, because we might
 440         -- now have a name clash in the importing module.
 441
 442 type IsExported = Name -> Bool          -- True for names that are exported from this module
 443 \end{code}
 444
 445
 446 %************************************************************************
 447 %*                                                                      *
 448 \subsection{The persistent compiler state}
 449 %*                                                                      *
 450 %************************************************************************
 451
 452 \begin{code}
 453 data PersistentCompilerState
 454    = PCS {
 455         pcs_PIT :: PackageIfaceTable,   -- Domain = non-home-package modules
 456                                         --   the mi_decls component is empty
 457
 458         pcs_PTE :: PackageTypeEnv,      -- Domain = non-home-package modules
 459                                         --   except that the InstEnv components is empty
 460
 461         pcs_insts :: PackageInstEnv,    -- The total InstEnv accumulated from all
 462                                         --   the non-home-package modules
 463
 464         pcs_rules :: PackageRuleBase,   -- Ditto RuleEnv
 465
 466         pcs_PRS :: PersistentRenamerState
 467      }
 468 \end{code}
 469
 470 The @PersistentRenamerState@ persists across successive calls to the
 471 compiler.
 472
 473 It contains:
 474   * A name supply, which deals with allocating unique names to
 475     (Module,OccName) original names,
 476
 477   * An accumulated TypeEnv from all the modules in imported packages
 478
 479   * An accumulated InstEnv from all the modules in imported packages
 480     The point is that we don't want to keep recreating it whenever
 481     we compile a new module.  The InstEnv component of pcPST is empty.
 482     (This means we might "see" instances that we shouldn't "really" see;
 483     but the Haskell Report is vague on what is meant to be visible,
 484     so we just take the easy road here.)
 485
 486   * Ditto for rules
 487
 488   * A "holding pen" for declarations that have been read out of
 489     interface files but not yet sucked in, renamed, and typechecked
 490
 491 \begin{code}
 492 type PackageTypeEnv  = TypeEnv
 493 type PackageRuleBase = RuleBase
 494 type PackageInstEnv  = InstEnv
 495
 496 data PersistentRenamerState
 497   = PRS { prsOrig    :: NameSupply,
 498           prsImpMods :: ImportedModuleInfo,
 499           prsDecls   :: DeclsMap,
 500           prsInsts   :: IfaceInsts,
 501           prsRules   :: IfaceRules
 502     }
 503 \end{code}
 504
 505 The NameSupply makes sure that there is just one Unique assigned for
 506 each original name; i.e. (module-name, occ-name) pair.  The Name is
 507 always stored as a Global, and has the SrcLoc of its binding location.
 508 Actually that's not quite right.  When we first encounter the original
 509 name, we might not be at its binding site (e.g. we are reading an
 510 interface file); so we give it 'noSrcLoc' then.  Later, when we find
 511 its binding site, we fix it up.
 512
 513 Exactly the same is true of the Module stored in the Name.  When we first
 514 encounter the occurrence, we may not know the details of the module, so
 515 we just store junk.  Then when we find the binding site, we fix it up.
 516
 517 \begin{code}
 518 data NameSupply
 519  = NameSupply { nsUniqs :: UniqSupply,
 520                 -- Supply of uniques
 521                 nsNames :: OrigNameCache,
 522                 -- Ensures that one original name gets one unique
 523                 nsIPs   :: OrigIParamCache
 524                 -- Ensures that one implicit parameter name gets one unique
 525    }
 526
 527 type OrigNameCache   = FiniteMap (ModuleName,OccName) Name
 528 type OrigIParamCache = FiniteMap OccName Name
 529 \end{code}
 530
 531 @ImportedModuleInfo@ contains info ONLY about modules that have not yet
 532 been loaded into the iPIT.  These modules are mentioned in interfaces we've
 533 already read, so we know a tiny bit about them, but we havn't yet looked
 534 at the interface file for the module itself.  It needs to persist across
 535 invocations of the renamer, at least from Rename.checkOldIface to Rename.renameSource.
 536 And there's no harm in it persisting across multiple compilations.
 537
 538 \begin{code}
 539 type ImportedModuleInfo = FiniteMap ModuleName (WhetherHasOrphans, IsBootInterface)
 540 \end{code}
 541
 542 A DeclsMap contains a binding for each Name in the declaration
 543 including the constructors of a type decl etc.  The Bool is True just
 544 for the 'main' Name.
 545
 546 \begin{code}
 547 type DeclsMap = (NameEnv (AvailInfo, Bool, (Module, RdrNameTyClDecl)), Int)
 548                                                 -- The Int says how many have been sucked in
 549
 550 type IfaceInsts = GatedDecls RdrNameInstDecl
 551 type IfaceRules = GatedDecls RdrNameRuleDecl
 552
 553 type GatedDecls d = (Bag (GatedDecl d), Int)    -- The Int says how many have been sucked in
 554 type GatedDecl  d = ([Name], (Module, d))
 555 \end{code}
 556
 557
 558 %************************************************************************
 559 %*                                                                      *
 560 \subsection{Provenance and export info}
 561 %*                                                                      *
 562 %************************************************************************
 563
 564 A LocalRdrEnv is used for local bindings (let, where, lambda, case)
 565
 566 \begin{code}
 567 type LocalRdrEnv = RdrNameEnv Name
 568
 569 extendLocalRdrEnv :: LocalRdrEnv -> [Name] -> LocalRdrEnv
 570 extendLocalRdrEnv env names
 571   = addListToRdrEnv env [(mkRdrUnqual (nameOccName n), n) | n <- names]
 572 \end{code}
 573
 574 The GlobalRdrEnv gives maps RdrNames to Names.  There is a separate
 575 one for each module, corresponding to that module's top-level scope.
 576
 577 \begin{code}
 578 type GlobalRdrEnv = RdrNameEnv [GlobalRdrElt]
 579         -- The list is because there may be name clashes
 580         -- These only get reported on lookup, not on construction
 581
 582 data GlobalRdrElt = GRE Name Provenance (Maybe DeprecTxt)
 583         -- The Maybe DeprecTxt tells whether this name is deprecated
 584
 585 pprGlobalRdrEnv env
 586   = vcat (map pp (rdrEnvToList env))
 587   where
 588     pp (rn, nps) = ppr rn <> colon <+>
 589                    vcat [ppr n <+> pprNameProvenance n p | (GRE n p _) <- nps]
 590 \end{code}
 591
 592 The "provenance" of something says how it came to be in scope.
 593
 594 \begin{code}
 595 data Provenance
 596   = LocalDef                    -- Defined locally
 597
 598   | NonLocalDef                 -- Defined non-locally
 599         ImportReason
 600
 601 -- Just used for grouping error messages (in RnEnv.warnUnusedBinds)
 602 instance Eq Provenance where
 603   p1 == p2 = case p1 `compare` p2 of EQ -> True; _ -> False
 604
 605 instance Eq ImportReason where
 606   p1 == p2 = case p1 `compare` p2 of EQ -> True; _ -> False
 607
 608 instance Ord Provenance where
 609    compare LocalDef LocalDef = EQ
 610    compare LocalDef (NonLocalDef _) = LT
 611    compare (NonLocalDef _) LocalDef = GT
 612
 613    compare (NonLocalDef reason1) (NonLocalDef reason2)
 614       = compare reason1 reason2
 615
 616 instance Ord ImportReason where
 617    compare ImplicitImport ImplicitImport = EQ
 618    compare ImplicitImport (UserImport _ _ _) = LT
 619    compare (UserImport _ _ _) ImplicitImport = GT
 620    compare (UserImport m1 loc1 _) (UserImport m2 loc2 _)
 621       = (m1 `compare` m2) `thenCmp` (loc1 `compare` loc2)
 622
 623
 624 data ImportReason
 625   = UserImport Module SrcLoc Bool       -- Imported from module M on line L
 626                                         -- Note the M may well not be the defining module
 627                                         -- for this thing!
 628         -- The Bool is true iff the thing was named *explicitly* in the import spec,
 629         -- rather than being imported as part of a group; e.g.
 630         --      import B
 631         --      import C( T(..) )
 632         -- Here, everything imported by B, and the constructors of T
 633         -- are not named explicitly; only T is named explicitly.
 634         -- This info is used when warning of unused names.
 635
 636   | ImplicitImport                      -- Imported implicitly for some other reason
 637 \end{code}
 638
 639 \begin{code}
 640 hasBetterProv :: Provenance -> Provenance -> Bool
 641 -- Choose
 642 --      a local thing                 over an   imported thing
 643 --      a user-imported thing         over a    non-user-imported thing
 644 --      an explicitly-imported thing  over an   implicitly imported thing
 645 hasBetterProv LocalDef                            _                            = True
 646 hasBetterProv (NonLocalDef (UserImport _ _ _   )) (NonLocalDef ImplicitImport) = True
 647 hasBetterProv _                                   _                            = False
 648
 649 pprNameProvenance :: Name -> Provenance -> SDoc
 650 pprNameProvenance name LocalDef          = ptext SLIT("defined at") <+> ppr (nameSrcLoc name)
 651 pprNameProvenance name (NonLocalDef why) = sep [ppr_reason why,
 652                                                 nest 2 (parens (ppr_defn (nameSrcLoc name)))]
 653
 654 ppr_reason ImplicitImport         = ptext SLIT("implicitly imported")
 655 ppr_reason (UserImport mod loc _) = ptext SLIT("imported from") <+> ppr mod <+> ptext SLIT("at") <+> ppr loc
 656
 657 ppr_defn loc | isGoodSrcLoc loc = ptext SLIT("at") <+> ppr loc
 658              | otherwise        = empty
 659 \end{code}