ghc/compiler/main/HscTypes.lhs

   1
   2 % (c) The University of Glasgow, 2000
   3 %
   4 \section[HscTypes]{Types for the per-module compiler}
   5
   6 \begin{code}
   7 module HscTypes (
   8         -- * Sessions and compilation state
   9         Session(..), HscEnv(..), hscEPS,
  10         FinderCache, FinderCacheEntry,
  11         Target(..), TargetId(..), pprTarget, pprTargetId,
  12         ModuleGraph, emptyMG,
  13
  14         ModDetails(..), emptyModDetails,
  15         ModGuts(..), CgGuts(..), ModImports(..), ForeignStubs(..),
  16
  17         ModSummary(..), showModMsg, isBootSummary,
  18         msHsFilePath, msHiFilePath, msObjFilePath,
  19
  20         HscSource(..), isHsBoot, hscSourceString,       -- Re-exported from DriverPhases
  21
  22         HomePackageTable, HomeModInfo(..), emptyHomePackageTable,
  23         hptInstances, hptRules,
  24
  25         ExternalPackageState(..), EpsStats(..), addEpsInStats,
  26         PackageTypeEnv, PackageIfaceTable, emptyPackageIfaceTable,
  27         lookupIface, lookupIfaceByModule, emptyModIface,
  28
  29         InteractiveContext(..), emptyInteractiveContext,
  30         icPrintUnqual, unQualInScope,
  31
  32         ModIface(..), mkIfaceDepCache, mkIfaceVerCache, mkIfaceFixCache,
  33         emptyIfaceDepCache,
  34
  35         Deprecs(..), IfaceDeprecs,
  36
  37         FixityEnv, FixItem(..), lookupFixity, emptyFixityEnv,
  38
  39         implicitTyThings,
  40
  41         TyThing(..), tyThingClass, tyThingTyCon, tyThingDataCon, tyThingId,
  42         TypeEnv, lookupType, mkTypeEnv, emptyTypeEnv,
  43         extendTypeEnv, extendTypeEnvList, extendTypeEnvWithIds, lookupTypeEnv,
  44         typeEnvElts, typeEnvClasses, typeEnvTyCons, typeEnvIds,
  45
  46         WhetherHasOrphans, IsBootInterface, Usage(..),
  47         Dependencies(..), noDependencies,
  48         NameCache(..), OrigNameCache, OrigIParamCache,
  49         Avails, availsToNameSet, availName, availNames,
  50         GenAvailInfo(..), AvailInfo, RdrAvailInfo,
  51         IfaceExport,
  52
  53         Deprecations, DeprecTxt, lookupDeprec, plusDeprecs,
  54
  55         PackageInstEnv, PackageRuleBase,
  56
  57         -- Linker stuff
  58         Linkable(..), isObjectLinkable,
  59         Unlinked(..), CompiledByteCode,
  60         isObject, nameOfObject, isInterpretable, byteCodeOfObject
  61     ) where
  62
  63 #include "HsVersions.h"
  64
  65 #ifdef GHCI
  66 import ByteCodeAsm      ( CompiledByteCode )
  67 #endif
  68
  69 import RdrName          ( GlobalRdrEnv, emptyGlobalRdrEnv,
  70                           LocalRdrEnv, emptyLocalRdrEnv,
  71                           GlobalRdrElt(..), mkRdrUnqual, lookupGRE_RdrName )
  72 import Name             ( Name, NamedThing, getName, nameOccName, nameModule )
  73 import NameEnv
  74 import NameSet
  75 import OccName          ( OccName, OccEnv, lookupOccEnv, mkOccEnv, emptyOccEnv,
  76                           extendOccEnv )
  77 import Module
  78 import InstEnv          ( InstEnv, Instance )
  79 import Rules            ( RuleBase )
  80 import CoreSyn          ( CoreBind )
  81 import Id               ( Id )
  82 import Type             ( TyThing(..) )
  83
  84 import Class            ( Class, classSelIds, classTyCon )
  85 import TyCon            ( TyCon, tyConSelIds, tyConDataCons )
  86 import DataCon          ( dataConImplicitIds )
  87 import Packages         ( PackageIdH, PackageId, PackageConfig )
  88 import DynFlags         ( DynFlags(..), isOneShot )
  89 import DriverPhases     ( HscSource(..), isHsBoot, hscSourceString, Phase )
  90 import BasicTypes       ( Version, initialVersion, IPName,
  91                           Fixity, defaultFixity, DeprecTxt )
  92
  93 import IfaceSyn         ( IfaceInst, IfaceRule, IfaceDecl(ifName) )
  94
  95 import FiniteMap        ( FiniteMap )
  96 import CoreSyn          ( CoreRule )
  97 import Maybes           ( orElse, fromJust, expectJust )
  98 import Outputable
  99 import SrcLoc           ( SrcSpan )
 100 import UniqSupply       ( UniqSupply )
 101 import FastString       ( FastString )
 102
 103 import DATA_IOREF       ( IORef, readIORef )
 104 import StringBuffer     ( StringBuffer )
 105 import Time             ( ClockTime )
 106 \end{code}
 107
 108
 109 %************************************************************************
 110 %*                                                                      *
 111 \subsection{Compilation environment}
 112 %*                                                                      *
 113 %************************************************************************
 114
 115
 116 \begin{code}
 117 -- | The Session is a handle to the complete state of a compilation
 118 -- session.  A compilation session consists of a set of modules
 119 -- constituting the current program or library, the context for
 120 -- interactive evaluation, and various caches.
 121 newtype Session = Session (IORef HscEnv)
 122 \end{code}
 123
 124 HscEnv is like Session, except that some of the fields are immutable.
 125 An HscEnv is used to compile a single module from plain Haskell source
 126 code (after preprocessing) to either C, assembly or C--.  Things like
 127 the module graph don't change during a single compilation.
 128
 129 Historical note: "hsc" used to be the name of the compiler binary,
 130 when there was a separate driver and compiler.  To compile a single
 131 module, the driver would invoke hsc on the source code... so nowadays
 132 we think of hsc as the layer of the compiler that deals with compiling
 133 a single module.
 134
 135 \begin{code}
 136 data HscEnv
 137   = HscEnv {
 138         hsc_dflags :: DynFlags,
 139                 -- The dynamic flag settings
 140
 141         hsc_targets :: [Target],
 142                 -- The targets (or roots) of the current session
 143
 144         hsc_mod_graph :: ModuleGraph,
 145                 -- The module graph of the current session
 146
 147         hsc_IC :: InteractiveContext,
 148                 -- The context for evaluating interactive statements
 149
 150         hsc_HPT    :: HomePackageTable,
 151                 -- The home package table describes already-compiled
 152                 -- home-packge modules, *excluding* the module we
 153                 -- are compiling right now.
 154                 -- (In one-shot mode the current module is the only
 155                 --  home-package module, so hsc_HPT is empty.  All other
 156                 --  modules count as "external-package" modules.
 157                 --  However, even in GHCi mode, hi-boot interfaces are
 158                 --  demand-loadeded into the external-package table.)
 159                 --
 160                 -- hsc_HPT is not mutable because we only demand-load
 161                 -- external packages; the home package is eagerly
 162                 -- loaded, module by module, by the compilation manager.
 163                 --
 164                 -- The HPT may contain modules compiled earlier by --make
 165                 -- but not actually below the current module in the dependency
 166                 -- graph.  (This changes a previous invariant: changed Jan 05.)
 167
 168         hsc_EPS :: {-# UNPACK #-} !(IORef ExternalPackageState),
 169         hsc_NC  :: {-# UNPACK #-} !(IORef NameCache),
 170                 -- These are side-effected by compiling to reflect
 171                 -- sucking in interface files.  They cache the state of
 172                 -- external interface files, in effect.
 173
 174         hsc_FC  :: {-# UNPACK #-} !(IORef FinderCache)
 175                 -- The finder's cache.  This caches the location of modules,
 176                 -- so we don't have to search the filesystem multiple times.
 177  }
 178
 179 hscEPS :: HscEnv -> IO ExternalPackageState
 180 hscEPS hsc_env = readIORef (hsc_EPS hsc_env)
 181
 182 -- | A compilation target.
 183 --
 184 -- A target may be supplied with the actual text of the
 185 -- module.  If so, use this instead of the file contents (this
 186 -- is for use in an IDE where the file hasn't been saved by
 187 -- the user yet).
 188 data Target = Target TargetId (Maybe (StringBuffer,ClockTime))
 189
 190 data TargetId
 191   = TargetModule Module
 192         -- ^ A module name: search for the file
 193   | TargetFile FilePath (Maybe Phase)
 194         -- ^ A filename: preprocess & parse it to find the module name.
 195         -- If specified, the Phase indicates how to compile this file
 196         -- (which phase to start from).  Nothing indicates the starting phase
 197         -- should be determined from the suffix of the filename.
 198   deriving Eq
 199
 200 pprTarget :: Target -> SDoc
 201 pprTarget (Target id _) = pprTargetId id
 202
 203 pprTargetId (TargetModule m) = ppr m
 204 pprTargetId (TargetFile f _) = text f
 205
 206 type FinderCache = ModuleEnv FinderCacheEntry
 207 type FinderCacheEntry = (ModLocation, Maybe (PackageConfig,Bool))
 208         -- The finder's cache (see module Finder)
 209
 210 type HomePackageTable  = ModuleEnv HomeModInfo
 211         -- Domain = modules in the home package
 212 type PackageIfaceTable = ModuleEnv ModIface
 213         -- Domain = modules in the imported packages
 214
 215 emptyHomePackageTable  = emptyModuleEnv
 216 emptyPackageIfaceTable = emptyModuleEnv
 217
 218 data HomeModInfo
 219   = HomeModInfo { hm_iface    :: !ModIface,
 220                   hm_details  :: !ModDetails,
 221                   hm_linkable :: !(Maybe Linkable) }
 222                 -- hm_linkable might be Nothing if:
 223                 --   a) this is an .hs-boot module
 224                 --   b) temporarily during compilation if we pruned away
 225                 --      the old linkable because it was out of date.
 226                 -- after a complete compilation (GHC.load), all hm_linkable
 227                 -- fields in the HPT will be Just.
 228                 --
 229                 -- When re-linking a module (hscNoRecomp), we construct
 230                 -- the HomModInfo by building a new ModDetails from the
 231                 -- old ModIface (only).
 232 \end{code}
 233
 234 Simple lookups in the symbol table.
 235
 236 \begin{code}
 237 lookupIface :: HomePackageTable -> PackageIfaceTable -> Module -> Maybe ModIface
 238 -- We often have two IfaceTables, and want to do a lookup
 239 lookupIface hpt pit mod
 240   = case lookupModuleEnv hpt mod of
 241         Just mod_info -> Just (hm_iface mod_info)
 242         Nothing       -> lookupModuleEnv pit mod
 243
 244 lookupIfaceByModule :: HomePackageTable -> PackageIfaceTable -> Module -> Maybe ModIface
 245 -- We often have two IfaceTables, and want to do a lookup
 246 lookupIfaceByModule hpt pit mod
 247   = case lookupModuleEnv hpt mod of
 248         Just mod_info -> Just (hm_iface mod_info)
 249         Nothing       -> lookupModuleEnv pit mod
 250 \end{code}
 251
 252
 253 \begin{code}
 254 hptInstances :: HscEnv -> (Module -> Bool) -> [Instance]
 255 -- Find all the instance declarations that are in modules imported
 256 -- by this one, directly or indirectly, and are in the Home Package Table
 257 -- This ensures that we don't see instances from modules --make compiled
 258 -- before this one, but which are not below this one
 259 hptInstances hsc_env want_this_module
 260   = [ ispec
 261     | mod_info <- moduleEnvElts (hsc_HPT hsc_env)
 262     , want_this_module (mi_module (hm_iface mod_info))
 263     , ispec <- md_insts (hm_details mod_info) ]
 264
 265 hptRules :: HscEnv -> [(Module, IsBootInterface)] -> [CoreRule]
 266 -- Get rules from modules "below" this one (in the dependency sense)
 267 -- C.f Inst.hptInstances
 268 hptRules hsc_env deps
 269   | isOneShot (ghcMode (hsc_dflags hsc_env)) = []
 270   | otherwise
 271   = let
 272         hpt = hsc_HPT hsc_env
 273     in
 274     [ rule
 275     |   -- Find each non-hi-boot module below me
 276       (mod, False) <- deps
 277
 278         -- Look it up in the HPT
 279     , let mod_info = ASSERT( mod `elemModuleEnv` hpt )
 280                      fromJust (lookupModuleEnv hpt mod)
 281
 282         -- And get its dfuns
 283     , rule <- md_rules (hm_details mod_info) ]
 284 \end{code}
 285
 286
 287 %************************************************************************
 288 %*                                                                      *
 289 \subsection{Symbol tables and Module details}
 290 %*                                                                      *
 291 %************************************************************************
 292
 293 A @ModIface@ plus a @ModDetails@ summarises everything we know
 294 about a compiled module.  The @ModIface@ is the stuff *before* linking,
 295 and can be written out to an interface file.  (The @ModDetails@ is after
 296 linking; it is the "linked" form of the mi_decls field.)
 297
 298 When we *read* an interface file, we also construct a @ModIface@ from it,
 299 except that the mi_decls part is empty; when reading we consolidate
 300 the declarations into a single indexed map in the @PersistentRenamerState@.
 301
 302 \begin{code}
 303 data ModIface
 304    = ModIface {
 305         mi_package  :: !PackageIdH,         -- Which package the module comes from
 306         mi_module   :: !Module,
 307         mi_mod_vers :: !Version,            -- Module version: changes when anything changes
 308
 309         mi_orphan   :: !WhetherHasOrphans,  -- Whether this module has orphans
 310         mi_boot     :: !IsBootInterface,    -- Read from an hi-boot file?
 311
 312         mi_deps     :: Dependencies,
 313                 -- This is consulted for directly-imported modules,
 314                 -- but not for anything else (hence lazy)
 315
 316                 -- Usages; kept sorted so that it's easy to decide
 317                 -- whether to write a new iface file (changing usages
 318                 -- doesn't affect the version of this module)
 319         mi_usages   :: [Usage],
 320                 -- NOT STRICT!  we read this field lazily from the interface file
 321                 -- It is *only* consulted by the recompilation checker
 322
 323                 -- Exports
 324                 -- Kept sorted by (mod,occ), to make version comparisons easier
 325         mi_exports  :: ![IfaceExport],
 326         mi_exp_vers :: !Version,        -- Version number of export list
 327
 328                 -- Fixities
 329         mi_fixities :: [(OccName,Fixity)],
 330                 -- NOT STRICT!  we read this field lazily from the interface file
 331
 332                 -- Deprecations
 333         mi_deprecs  :: IfaceDeprecs,
 334                 -- NOT STRICT!  we read this field lazily from the interface file
 335
 336                 -- Type, class and variable declarations
 337                 -- The version of an Id changes if its fixity or deprecations change
 338                 --      (as well as its type of course)
 339                 -- Ditto data constructors, class operations, except that
 340                 -- the version of the parent class/tycon changes
 341         mi_decls :: [(Version,IfaceDecl)],      -- Sorted
 342
 343         mi_globals  :: !(Maybe GlobalRdrEnv),
 344                 -- Binds all the things defined at the top level in
 345                 -- the *original source* code for this module. which
 346                 -- is NOT the same as mi_exports, nor mi_decls (which
 347                 -- may contains declarations for things not actually
 348                 -- defined by the user).  Used for GHCi and for inspecting
 349                 -- the contents of modules via the GHC API only.
 350                 --
 351                 -- (We need the source file to figure out the
 352                 -- top-level environment, if we didn't compile this module
 353                 -- from source then this field contains Nothing).
 354                 --
 355                 -- Strictly speaking this field should live in the
 356                 -- HomeModInfo, but that leads to more plumbing.
 357
 358                 -- Instance declarations and rules
 359         mi_insts     :: [IfaceInst],    -- Sorted
 360         mi_rules     :: [IfaceRule],    -- Sorted
 361         mi_rule_vers :: !Version,       -- Version number for rules and instances combined
 362
 363                 -- Cached environments for easy lookup
 364                 -- These are computed (lazily) from other fields
 365                 -- and are not put into the interface file
 366         mi_dep_fn  :: Name -> Maybe DeprecTxt,  -- Cached lookup for mi_deprecs
 367         mi_fix_fn  :: OccName -> Fixity,        -- Cached lookup for mi_fixities
 368         mi_ver_fn  :: OccName -> Maybe Version  -- Cached lookup for mi_decls
 369                         -- The Nothing in mi_ver_fn means that the thing
 370                         -- isn't in decls. It's useful to know that when
 371                         -- seeing if we are up to date wrt the old interface
 372      }
 373
 374 -- Should be able to construct ModDetails from mi_decls in ModIface
 375 data ModDetails
 376    = ModDetails {
 377         -- The next three fields are created by the typechecker
 378         md_exports  :: NameSet,
 379         md_types    :: !TypeEnv,
 380         md_insts    :: ![Instance],     -- Dfun-ids for the instances in this module
 381         md_rules    :: ![CoreRule]      -- Domain may include Ids from other modules
 382      }
 383
 384 emptyModDetails = ModDetails { md_types = emptyTypeEnv,
 385                                md_exports = emptyNameSet,
 386                                md_insts = [],
 387                                md_rules = [] }
 388
 389 -- A ModGuts is carried through the compiler, accumulating stuff as it goes
 390 -- There is only one ModGuts at any time, the one for the module
 391 -- being compiled right now.  Once it is compiled, a ModIface and
 392 -- ModDetails are extracted and the ModGuts is dicarded.
 393
 394 data ModGuts
 395   = ModGuts {
 396         mg_module   :: !Module,
 397         mg_boot     :: IsBootInterface, -- Whether it's an hs-boot module
 398         mg_exports  :: !NameSet,        -- What it exports
 399         mg_deps     :: !Dependencies,   -- What is below it, directly or otherwise
 400         mg_dir_imps :: ![Module],       -- Directly-imported modules; used to
 401                                         --      generate initialisation code
 402         mg_usages   :: ![Usage],        -- Version info for what it needed
 403
 404         mg_rdr_env  :: !GlobalRdrEnv,   -- Top-level lexical environment
 405         mg_fix_env  :: !FixityEnv,      -- Fixity env, for things declared in this module
 406         mg_deprecs  :: !Deprecations,   -- Deprecations declared in the module
 407
 408         mg_types    :: !TypeEnv,
 409         mg_insts    :: ![Instance],     -- Instances
 410         mg_rules    :: ![CoreRule],     -- Rules from this module
 411         mg_binds    :: ![CoreBind],     -- Bindings for this module
 412         mg_foreign  :: !ForeignStubs
 413     }
 414
 415 -- The ModGuts takes on several slightly different forms:
 416 --
 417 -- After simplification, the following fields change slightly:
 418 --      mg_rules        Orphan rules only (local ones now attached to binds)
 419 --      mg_binds        With rules attached
 420
 421
 422 ---------------------------------------------------------
 423 -- The Tidy pass forks the information about this module:
 424 --      * one lot goes to interface file generation (ModIface)
 425 --        and later compilations (ModDetails)
 426 --      * the other lot goes to code generation (CgGuts)
 427 data CgGuts
 428   = CgGuts {
 429         cg_module   :: !Module,
 430
 431         cg_tycons   :: [TyCon],         -- Algebraic data types (including ones that started life
 432                                         -- as classes); generate constructors and info tables
 433                                         -- Includes newtypes, just for the benefit of External Core
 434
 435         cg_binds    :: [CoreBind],      -- The tidied main bindings, including previously-implicit
 436                                         -- bindings for record and class selectors, and
 437                                         -- data construtor wrappers.
 438                                         -- But *not* data constructor workers; reason: we
 439                                         -- we regard them as part of the code-gen of tycons
 440
 441         cg_dir_imps :: ![Module],       -- Directly-imported modules; used to generate
 442                                         -- initialisation code
 443
 444         cg_foreign  :: !ForeignStubs,
 445         cg_dep_pkgs :: ![PackageId]     -- Used to generate #includes for C code gen
 446     }
 447
 448 -----------------------------------
 449 data ModImports
 450   = ModImports {
 451         imp_direct     :: ![(Module,Bool)],     -- Explicitly-imported modules
 452                                                 -- Boolean is true if we imported the whole
 453                                                 --      module (apart, perhaps, from hiding some)
 454         imp_pkg_mods   :: !ModuleSet,           -- Non-home-package modules on which we depend,
 455                                                 --      directly or indirectly
 456         imp_home_names :: !NameSet              -- Home package things on which we depend,
 457                                                 --      directly or indirectly
 458     }
 459
 460 -----------------------------------
 461 data ForeignStubs = NoStubs
 462                   | ForeignStubs
 463                         SDoc            -- Header file prototypes for
 464                                         --      "foreign exported" functions
 465                         SDoc            -- C stubs to use when calling
 466                                         --      "foreign exported" functions
 467                         [FastString]    -- Headers that need to be included
 468                                         --      into C code generated for this module
 469                         [Id]            -- Foreign-exported binders
 470                                         --      we have to generate code to register these
 471
 472 \end{code}
 473
 474 \begin{code}
 475 emptyModIface :: PackageIdH -> Module -> ModIface
 476 emptyModIface pkg mod
 477   = ModIface { mi_package  = pkg,
 478                mi_module   = mod,
 479                mi_mod_vers = initialVersion,
 480                mi_orphan   = False,
 481                mi_boot     = False,
 482                mi_deps     = noDependencies,
 483                mi_usages   = [],
 484                mi_exports  = [],
 485                mi_exp_vers = initialVersion,
 486                mi_fixities = [],
 487                mi_deprecs  = NoDeprecs,
 488                mi_insts = [],
 489                mi_rules = [],
 490                mi_decls = [],
 491                mi_globals  = Nothing,
 492                mi_rule_vers = initialVersion,
 493                mi_dep_fn = emptyIfaceDepCache,
 494                mi_fix_fn = emptyIfaceFixCache,
 495                mi_ver_fn = emptyIfaceVerCache
 496     }
 497 \end{code}
 498
 499
 500 %************************************************************************
 501 %*                                                                      *
 502 \subsection{The interactive context}
 503 %*                                                                      *
 504 %************************************************************************
 505
 506 \begin{code}
 507 data InteractiveContext
 508   = InteractiveContext {
 509         ic_toplev_scope :: [Module],    -- Include the "top-level" scope of
 510                                         -- these modules
 511
 512         ic_exports :: [Module],         -- Include just the exports of these
 513                                         -- modules
 514
 515         ic_rn_gbl_env :: GlobalRdrEnv,  -- The cached GlobalRdrEnv, built from
 516                                         -- ic_toplev_scope and ic_exports
 517
 518         ic_rn_local_env :: LocalRdrEnv, -- Lexical context for variables bound
 519                                         -- during interaction
 520
 521         ic_type_env :: TypeEnv          -- Ditto for types
 522     }
 523
 524 emptyInteractiveContext
 525   = InteractiveContext { ic_toplev_scope = [],
 526                          ic_exports = [],
 527                          ic_rn_gbl_env = emptyGlobalRdrEnv,
 528                          ic_rn_local_env = emptyLocalRdrEnv,
 529                          ic_type_env = emptyTypeEnv }
 530
 531 icPrintUnqual :: InteractiveContext -> PrintUnqualified
 532 icPrintUnqual ictxt = unQualInScope (ic_rn_gbl_env ictxt)
 533 \end{code}
 534
 535 @unQualInScope@ returns a function that takes a @Name@ and tells whether
 536 its unqualified name is in scope.  This is put as a boolean flag in
 537 the @Name@'s provenance to guide whether or not to print the name qualified
 538 in error messages.
 539
 540 \begin{code}
 541 unQualInScope :: GlobalRdrEnv -> PrintUnqualified
 542 -- True if 'f' is in scope, and has only one binding,
 543 -- and the thing it is bound to is the name we are looking for
 544 -- (i.e. false if A.f and B.f are both in scope as unqualified 'f')
 545 --
 546 -- [Out of date] Also checks for built-in syntax, which is always 'in scope'
 547 unQualInScope env mod occ
 548   = case lookupGRE_RdrName (mkRdrUnqual occ) env of
 549         [gre] -> nameModule (gre_name gre) == mod
 550         other -> False
 551 \end{code}
 552
 553
 554 %************************************************************************
 555 %*                                                                      *
 556                 TyThing
 557 %*                                                                      *
 558 %************************************************************************
 559
 560 \begin{code}
 561 implicitTyThings :: TyThing -> [TyThing]
 562 implicitTyThings (AnId id)   = []
 563
 564         -- For type constructors, add the data cons (and their extras),
 565         -- and the selectors and generic-programming Ids too
 566         --
 567         -- Newtypes don't have a worker Id, so don't generate that?
 568 implicitTyThings (ATyCon tc) = map AnId (tyConSelIds tc) ++
 569                                concatMap (extras_plus . ADataCon) (tyConDataCons tc)
 570
 571         -- For classes, add the class TyCon too (and its extras)
 572         -- and the class selector Ids
 573 implicitTyThings (AClass cl) = map AnId (classSelIds cl) ++
 574                                extras_plus (ATyCon (classTyCon cl))
 575
 576
 577         -- For data cons add the worker and wrapper (if any)
 578 implicitTyThings (ADataCon dc) = map AnId (dataConImplicitIds dc)
 579
 580 extras_plus thing = thing : implicitTyThings thing
 581
 582 extendTypeEnvWithIds :: TypeEnv -> [Id] -> TypeEnv
 583 extendTypeEnvWithIds env ids
 584   = extendNameEnvList env [(getName id, AnId id) | id <- ids]
 585 \end{code}
 586
 587 %************************************************************************
 588 %*                                                                      *
 589                 TypeEnv
 590 %*                                                                      *
 591 %************************************************************************
 592
 593 \begin{code}
 594 type TypeEnv = NameEnv TyThing
 595
 596 emptyTypeEnv   :: TypeEnv
 597 typeEnvElts    :: TypeEnv -> [TyThing]
 598 typeEnvClasses :: TypeEnv -> [Class]
 599 typeEnvTyCons  :: TypeEnv -> [TyCon]
 600 typeEnvIds     :: TypeEnv -> [Id]
 601 lookupTypeEnv  :: TypeEnv -> Name -> Maybe TyThing
 602
 603 emptyTypeEnv       = emptyNameEnv
 604 typeEnvElts    env = nameEnvElts env
 605 typeEnvClasses env = [cl | AClass cl <- typeEnvElts env]
 606 typeEnvTyCons  env = [tc | ATyCon tc <- typeEnvElts env]
 607 typeEnvIds     env = [id | AnId id   <- typeEnvElts env]
 608
 609 mkTypeEnv :: [TyThing] -> TypeEnv
 610 mkTypeEnv things = extendTypeEnvList emptyTypeEnv things
 611
 612 lookupTypeEnv = lookupNameEnv
 613
 614 -- Extend the type environment
 615 extendTypeEnv :: TypeEnv -> TyThing -> TypeEnv
 616 extendTypeEnv env thing = extendNameEnv env (getName thing) thing
 617
 618 extendTypeEnvList :: TypeEnv -> [TyThing] -> TypeEnv
 619 extendTypeEnvList env things = foldl extendTypeEnv env things
 620 \end{code}
 621
 622 \begin{code}
 623 lookupType :: HomePackageTable -> PackageTypeEnv -> Name -> Maybe TyThing
 624 lookupType hpt pte name
 625   = case lookupModuleEnv hpt (nameModule name) of
 626         Just details -> lookupNameEnv (md_types (hm_details details)) name
 627         Nothing      -> lookupNameEnv pte name
 628 \end{code}
 629
 630
 631 \begin{code}
 632 tyThingTyCon (ATyCon tc) = tc
 633 tyThingTyCon other       = pprPanic "tyThingTyCon" (ppr other)
 634
 635 tyThingClass (AClass cls) = cls
 636 tyThingClass other        = pprPanic "tyThingClass" (ppr other)
 637
 638 tyThingDataCon (ADataCon dc) = dc
 639 tyThingDataCon other         = pprPanic "tyThingDataCon" (ppr other)
 640
 641 tyThingId (AnId id) = id
 642 tyThingId other     = pprPanic "tyThingId" (ppr other)
 643 \end{code}
 644
 645 %************************************************************************
 646 %*                                                                      *
 647 \subsection{Auxiliary types}
 648 %*                                                                      *
 649 %************************************************************************
 650
 651 These types are defined here because they are mentioned in ModDetails,
 652 but they are mostly elaborated elsewhere
 653
 654 \begin{code}
 655 mkIfaceVerCache :: [(Version,IfaceDecl)] -> OccName -> Maybe Version
 656 mkIfaceVerCache pairs
 657   = \occ -> lookupOccEnv env occ
 658   where
 659     env = foldl add emptyOccEnv pairs
 660     add env (v,d) = extendOccEnv env (ifName d) v
 661
 662 emptyIfaceVerCache :: OccName -> Maybe Version
 663 emptyIfaceVerCache occ = Nothing
 664
 665 ------------------ Deprecations -------------------------
 666 data Deprecs a
 667   = NoDeprecs
 668   | DeprecAll DeprecTxt -- Whole module deprecated
 669   | DeprecSome a        -- Some specific things deprecated
 670   deriving( Eq )
 671
 672 type IfaceDeprecs = Deprecs [(OccName,DeprecTxt)]
 673 type Deprecations = Deprecs (NameEnv (OccName,DeprecTxt))
 674         -- Keep the OccName so we can flatten the NameEnv to
 675         -- get an IfaceDeprecs from a Deprecations
 676         -- Only an OccName is needed, because a deprecation always
 677         -- applies to things defined in the module in which the
 678         -- deprecation appears.
 679
 680 mkIfaceDepCache:: IfaceDeprecs -> Name -> Maybe DeprecTxt
 681 mkIfaceDepCache NoDeprecs         = \n -> Nothing
 682 mkIfaceDepCache (DeprecAll t)     = \n -> Just t
 683 mkIfaceDepCache (DeprecSome pairs) = lookupOccEnv (mkOccEnv pairs) . nameOccName
 684
 685 emptyIfaceDepCache :: Name -> Maybe DeprecTxt
 686 emptyIfaceDepCache n = Nothing
 687
 688 lookupDeprec :: Deprecations -> Name -> Maybe DeprecTxt
 689 lookupDeprec NoDeprecs        name = Nothing
 690 lookupDeprec (DeprecAll  txt) name = Just txt
 691 lookupDeprec (DeprecSome env) name = case lookupNameEnv env name of
 692                                             Just (_, txt) -> Just txt
 693                                             Nothing       -> Nothing
 694
 695 plusDeprecs :: Deprecations -> Deprecations -> Deprecations
 696 plusDeprecs d NoDeprecs = d
 697 plusDeprecs NoDeprecs d = d
 698 plusDeprecs d (DeprecAll t) = DeprecAll t
 699 plusDeprecs (DeprecAll t) d = DeprecAll t
 700 plusDeprecs (DeprecSome v1) (DeprecSome v2) = DeprecSome (v1 `plusNameEnv` v2)
 701 \end{code}
 702
 703
 704 \begin{code}
 705 type Avails       = [AvailInfo]
 706 type AvailInfo    = GenAvailInfo Name
 707 type RdrAvailInfo = GenAvailInfo OccName
 708
 709 data GenAvailInfo name  = Avail name     -- An ordinary identifier
 710                         | AvailTC name   -- The name of the type or class
 711                                   [name] -- The available pieces of type/class.
 712                                          -- NB: If the type or class is itself
 713                                          -- to be in scope, it must be in this list.
 714                                          -- Thus, typically: AvailTC Eq [Eq, ==, /=]
 715                         deriving( Eq )
 716                         -- Equality used when deciding if the interface has changed
 717
 718 type IfaceExport = (Module, [GenAvailInfo OccName])
 719
 720 availsToNameSet :: [AvailInfo] -> NameSet
 721 availsToNameSet avails = foldl add emptyNameSet avails
 722                        where
 723                          add set avail = addListToNameSet set (availNames avail)
 724
 725 availName :: GenAvailInfo name -> name
 726 availName (Avail n)     = n
 727 availName (AvailTC n _) = n
 728
 729 availNames :: GenAvailInfo name -> [name]
 730 availNames (Avail n)      = [n]
 731 availNames (AvailTC n ns) = ns
 732
 733 instance Outputable n => Outputable (GenAvailInfo n) where
 734    ppr = pprAvail
 735
 736 pprAvail :: Outputable n => GenAvailInfo n -> SDoc
 737 pprAvail (AvailTC n ns) = ppr n <> case {- filter (/= n) -} ns of
 738                                         []  -> empty
 739                                         ns' -> braces (hsep (punctuate comma (map ppr ns')))
 740
 741 pprAvail (Avail n) = ppr n
 742 \end{code}
 743
 744 \begin{code}
 745 mkIfaceFixCache :: [(OccName, Fixity)] -> OccName -> Fixity
 746 mkIfaceFixCache pairs
 747   = \n -> lookupOccEnv env n `orElse` defaultFixity
 748   where
 749    env = mkOccEnv pairs
 750
 751 emptyIfaceFixCache :: OccName -> Fixity
 752 emptyIfaceFixCache n = defaultFixity
 753
 754 -- This fixity environment is for source code only
 755 type FixityEnv = NameEnv FixItem
 756
 757 -- We keep the OccName in the range so that we can generate an interface from it
 758 data FixItem = FixItem OccName Fixity SrcSpan
 759
 760 instance Outputable FixItem where
 761   ppr (FixItem occ fix loc) = ppr fix <+> ppr occ <+> parens (ppr loc)
 762
 763 emptyFixityEnv :: FixityEnv
 764 emptyFixityEnv = emptyNameEnv
 765
 766 lookupFixity :: FixityEnv -> Name -> Fixity
 767 lookupFixity env n = case lookupNameEnv env n of
 768                         Just (FixItem _ fix _) -> fix
 769                         Nothing                -> defaultFixity
 770 \end{code}
 771
 772
 773 %************************************************************************
 774 %*                                                                      *
 775 \subsection{WhatsImported}
 776 %*                                                                      *
 777 %************************************************************************
 778
 779 \begin{code}
 780 type WhetherHasOrphans   = Bool
 781         -- An "orphan" is
 782         --      * an instance decl in a module other than the defn module for
 783         --              one of the tycons or classes in the instance head
 784         --      * a transformation rule in a module other than the one defining
 785         --              the function in the head of the rule.
 786
 787 type IsBootInterface = Bool
 788
 789 -- Dependency info about modules and packages below this one
 790 -- in the import hierarchy.  See TcRnTypes.ImportAvails for details.
 791 --
 792 -- Invariant: the dependencies of a module M never includes M
 793 -- Invariant: the lists are unordered, with no duplicates
 794 data Dependencies
 795   = Deps { dep_mods  :: [(Module,IsBootInterface)],     -- Home-package module dependencies
 796            dep_pkgs  :: [PackageId],                    -- External package dependencies
 797            dep_orphs :: [Module] }                      -- Orphan modules (whether home or external pkg)
 798   deriving( Eq )
 799         -- Equality used only for old/new comparison in MkIface.addVersionInfo
 800
 801 noDependencies :: Dependencies
 802 noDependencies = Deps [] [] []
 803
 804 data Usage
 805   = Usage { usg_name     :: Module,                     -- Name of the module
 806             usg_mod      :: Version,                    -- Module version
 807             usg_entities :: [(OccName,Version)],        -- Sorted by occurrence name
 808             usg_exports  :: Maybe Version,              -- Export-list version, if we depend on it
 809             usg_rules    :: Version                     -- Orphan-rules version (for non-orphan
 810                                                         -- modules this will always be initialVersion)
 811     }       deriving( Eq )
 812         -- This type doesn't let you say "I imported f but none of the rules in
 813         -- the module". If you use anything in the module you get its rule version
 814         -- So if the rules change, you'll recompile, even if you don't use them.
 815         -- This is easy to implement, and it's safer: you might not have used the rules last
 816         -- time round, but if someone has added a new rule you might need it this time
 817
 818         -- The export list field is (Just v) if we depend on the export list:
 819         --      i.e. we imported the module without saying exactly what we imported
 820         -- We need to recompile if the module exports changes, because we might
 821         -- now have a name clash in the importing module.
 822 \end{code}
 823
 824
 825 %************************************************************************
 826 %*                                                                      *
 827                 The External Package State
 828 %*                                                                      *
 829 %************************************************************************
 830
 831 \begin{code}
 832 type PackageTypeEnv  = TypeEnv
 833 type PackageRuleBase = RuleBase
 834 type PackageInstEnv  = InstEnv
 835
 836 data ExternalPackageState
 837   = EPS {
 838         eps_is_boot :: !(ModuleEnv (Module, IsBootInterface)),
 839                 -- In OneShot mode (only), home-package modules accumulate in the
 840                 -- external package state, and are sucked in lazily.
 841                 -- For these home-pkg modules (only) we need to record which are
 842                 -- boot modules.  We set this field after loading all the
 843                 -- explicitly-imported interfaces, but before doing anything else
 844                 --
 845                 -- The Module part is not necessary, but it's useful for
 846                 -- debug prints, and it's convenient because this field comes
 847                 -- direct from TcRnTypes.ImportAvails.imp_dep_mods
 848
 849         eps_PIT :: !PackageIfaceTable,
 850                 -- The ModuleIFaces for modules in external packages
 851                 -- whose interfaces we have opened
 852                 -- The declarations in these interface files are held in
 853                 -- eps_decls, eps_inst_env, eps_rules (below), not in the
 854                 -- mi_decls fields of the iPIT.
 855                 -- What _is_ in the iPIT is:
 856                 --      * The Module
 857                 --      * Version info
 858                 --      * Its exports
 859                 --      * Fixities
 860                 --      * Deprecations
 861
 862         eps_PTE :: !PackageTypeEnv,             -- Domain = external-package modules
 863
 864         eps_inst_env :: !PackageInstEnv,        -- The total InstEnv accumulated from
 865                                                 --   all the external-package modules
 866         eps_rule_base :: !PackageRuleBase,      -- Ditto RuleEnv
 867
 868         eps_stats :: !EpsStats
 869   }
 870
 871 -- "In" means read from iface files
 872 -- "Out" means actually sucked in and type-checked
 873 data EpsStats = EpsStats { n_ifaces_in
 874                          , n_decls_in, n_decls_out
 875                          , n_rules_in, n_rules_out
 876                          , n_insts_in, n_insts_out :: !Int }
 877
 878 addEpsInStats :: EpsStats -> Int -> Int -> Int -> EpsStats
 879 -- Add stats for one newly-read interface
 880 addEpsInStats stats n_decls n_insts n_rules
 881   = stats { n_ifaces_in = n_ifaces_in stats + 1
 882           , n_decls_in  = n_decls_in stats + n_decls
 883           , n_insts_in  = n_insts_in stats + n_insts
 884           , n_rules_in  = n_rules_in stats + n_rules }
 885 \end{code}
 886
 887 The NameCache makes sure that there is just one Unique assigned for
 888 each original name; i.e. (module-name, occ-name) pair.  The Name is
 889 always stored as a Global, and has the SrcLoc of its binding location.
 890 Actually that's not quite right.  When we first encounter the original
 891 name, we might not be at its binding site (e.g. we are reading an
 892 interface file); so we give it 'noSrcLoc' then.  Later, when we find
 893 its binding site, we fix it up.
 894
 895 \begin{code}
 896 data NameCache
 897  = NameCache {  nsUniqs :: UniqSupply,
 898                 -- Supply of uniques
 899                 nsNames :: OrigNameCache,
 900                 -- Ensures that one original name gets one unique
 901                 nsIPs   :: OrigIParamCache
 902                 -- Ensures that one implicit parameter name gets one unique
 903    }
 904
 905 type OrigNameCache   = ModuleEnv (OccEnv Name)
 906 type OrigIParamCache = FiniteMap (IPName OccName) (IPName Name)
 907 \end{code}
 908
 909
 910
 911 %************************************************************************
 912 %*                                                                      *
 913                 The module graph and ModSummary type
 914         A ModSummary is a node in the compilation manager's
 915         dependency graph, and it's also passed to hscMain
 916 %*                                                                      *
 917 %************************************************************************
 918
 919 A ModuleGraph contains all the nodes from the home package (only).
 920 There will be a node for each source module, plus a node for each hi-boot
 921 module.
 922
 923 \begin{code}
 924 type ModuleGraph = [ModSummary]  -- The module graph,
 925                                  -- NOT NECESSARILY IN TOPOLOGICAL ORDER
 926
 927 emptyMG :: ModuleGraph
 928 emptyMG = []
 929
 930 -- The nodes of the module graph are
 931 --      EITHER a regular Haskell source module
 932 --      OR     a hi-boot source module
 933
 934 data ModSummary
 935    = ModSummary {
 936         ms_mod       :: Module,                 -- Name of the module
 937         ms_hsc_src   :: HscSource,              -- Source is Haskell, hs-boot, external core
 938         ms_location  :: ModLocation,            -- Location
 939         ms_hs_date   :: ClockTime,              -- Timestamp of source file
 940         ms_obj_date  :: Maybe ClockTime,        -- Timestamp of object, maybe
 941         ms_srcimps   :: [Module],               -- Source imports
 942         ms_imps      :: [Module],               -- Non-source imports
 943         ms_hspp_file :: Maybe FilePath,         -- Filename of preprocessed source,
 944                                                 -- once we have preprocessed it.
 945         ms_hspp_buf  :: Maybe StringBuffer      -- The actual preprocessed source, maybe.
 946      }
 947
 948 -- The ModLocation contains both the original source filename and the
 949 -- filename of the cleaned-up source file after all preprocessing has been
 950 -- done.  The point is that the summariser will have to cpp/unlit/whatever
 951 -- all files anyway, and there's no point in doing this twice -- just
 952 -- park the result in a temp file, put the name of it in the location,
 953 -- and let @compile@ read from that file on the way back up.
 954
 955 -- The ModLocation is stable over successive up-sweeps in GHCi, wheres
 956 -- the ms_hs_date and imports can, of course, change
 957
 958 msHsFilePath, msHiFilePath, msObjFilePath :: ModSummary -> FilePath
 959 msHsFilePath  ms = expectJust "msHsFilePath" (ml_hs_file  (ms_location ms))
 960 msHiFilePath  ms = ml_hi_file  (ms_location ms)
 961 msObjFilePath ms = ml_obj_file (ms_location ms)
 962
 963 isBootSummary :: ModSummary -> Bool
 964 isBootSummary ms = isHsBoot (ms_hsc_src ms)
 965
 966 instance Outputable ModSummary where
 967    ppr ms
 968       = sep [text "ModSummary {",
 969              nest 3 (sep [text "ms_hs_date = " <> text (show (ms_hs_date ms)),
 970                           text "ms_mod =" <+> ppr (ms_mod ms)
 971                                 <> text (hscSourceString (ms_hsc_src ms)) <> comma,
 972                           text "ms_imps =" <+> ppr (ms_imps ms),
 973                           text "ms_srcimps =" <+> ppr (ms_srcimps ms)]),
 974              char '}'
 975             ]
 976
 977 showModMsg :: Bool -> ModSummary -> String
 978 showModMsg use_object mod_summary
 979   = showSDoc (hsep [text (mod_str ++ replicate (max 0 (16 - length mod_str)) ' '),
 980                     char '(', text (msHsFilePath mod_summary) <> comma,
 981                     if use_object then text (msObjFilePath mod_summary)
 982                               else text "interpreted",
 983                     char ')'])
 984  where
 985     mod     = ms_mod mod_summary
 986     mod_str = moduleUserString mod ++ hscSourceString (ms_hsc_src mod_summary)
 987 \end{code}
 988
 989
 990 %************************************************************************
 991 %*                                                                      *
 992 \subsection{Linkable stuff}
 993 %*                                                                      *
 994 %************************************************************************
 995
 996 This stuff is in here, rather than (say) in Linker.lhs, because the Linker.lhs
 997 stuff is the *dynamic* linker, and isn't present in a stage-1 compiler
 998
 999 \begin{code}
1000 data Linkable = LM {
1001   linkableTime     :: ClockTime,        -- Time at which this linkable was built
1002                                         -- (i.e. when the bytecodes were produced,
1003                                         --       or the mod date on the files)
1004   linkableModule   :: Module,           -- Should be Module, but see below
1005   linkableUnlinked :: [Unlinked]
1006  }
1007
1008 isObjectLinkable :: Linkable -> Bool
1009 isObjectLinkable l = all isObject (linkableUnlinked l)
1010
1011 instance Outputable Linkable where
1012    ppr (LM when_made mod unlinkeds)
1013       = (text "LinkableM" <+> parens (text (show when_made)) <+> ppr mod)
1014         $$ nest 3 (ppr unlinkeds)
1015
1016 -------------------------------------------
1017 data Unlinked
1018    = DotO FilePath
1019    | DotA FilePath
1020    | DotDLL FilePath
1021    | BCOs CompiledByteCode
1022
1023 #ifndef GHCI
1024 data CompiledByteCode = NoByteCode
1025 #endif
1026
1027 instance Outputable Unlinked where
1028    ppr (DotO path)   = text "DotO" <+> text path
1029    ppr (DotA path)   = text "DotA" <+> text path
1030    ppr (DotDLL path) = text "DotDLL" <+> text path
1031 #ifdef GHCI
1032    ppr (BCOs bcos)   = text "BCOs" <+> ppr bcos
1033 #else
1034    ppr (BCOs bcos)   = text "No byte code"
1035 #endif
1036
1037 isObject (DotO _)   = True
1038 isObject (DotA _)   = True
1039 isObject (DotDLL _) = True
1040 isObject _          = False
1041
1042 isInterpretable = not . isObject
1043
1044 nameOfObject (DotO fn)   = fn
1045 nameOfObject (DotA fn)   = fn
1046 nameOfObject (DotDLL fn) = fn
1047
1048 byteCodeOfObject (BCOs bc) = bc
1049 \end{code}
1050
1051
1052