ghc/compiler/main/HscTypes.lhs

   1 %
   2 % (c) The University of Glasgow, 2000
   3 %
   4 \section[HscTypes]{Types for the per-module compiler}
   5
   6 \begin{code}
   7 module HscTypes (
   8         ModuleLocation(..),
   9
  10         ModDetails(..), ModIface(..),
  11         HomeSymbolTable, PackageTypeEnv,
  12         HomeIfaceTable, PackageIfaceTable, emptyIfaceTable,
  13         lookupIface, lookupIfaceByModName,
  14         emptyModIface,
  15
  16         IfaceDecls, mkIfaceDecls, dcl_tycl, dcl_rules, dcl_insts,
  17
  18         VersionInfo(..), initialVersionInfo,
  19
  20         TyThing(..), isTyClThing, implicitTyThingIds,
  21
  22         TypeEnv, lookupType, mkTypeEnv, extendTypeEnvList,
  23         typeEnvClasses, typeEnvTyCons,
  24
  25         ImportedModuleInfo, WhetherHasOrphans, ImportVersion, WhatsImported(..),
  26         PersistentRenamerState(..), IsBootInterface, Avails, DeclsMap,
  27         IfaceInsts, IfaceRules, GatedDecl, IsExported,
  28         NameSupply(..), OrigNameCache, OrigIParamCache,
  29         AvailEnv, AvailInfo, GenAvailInfo(..),
  30         PersistentCompilerState(..),
  31
  32         Deprecations(..), lookupDeprec,
  33
  34         InstEnv, ClsInstEnv, DFunId,
  35         PackageInstEnv, PackageRuleBase,
  36
  37         GlobalRdrEnv, GlobalRdrElt(..), RdrAvailInfo, pprGlobalRdrEnv,
  38
  39         -- Provenance
  40         Provenance(..), ImportReason(..),
  41         pprNameProvenance, hasBetterProv
  42
  43     ) where
  44
  45 #include "HsVersions.h"
  46
  47 import RdrName          ( RdrNameEnv, emptyRdrEnv, rdrEnvToList )
  48 import Name             ( Name, NamedThing, getName, nameModule, nameSrcLoc )
  49 import Name -- Env
  50 import OccName          ( OccName )
  51 import Module           ( Module, ModuleName, ModuleEnv,
  52                           lookupModuleEnv, lookupModuleEnvByName, emptyModuleEnv
  53                         )
  54 import InstEnv          ( InstEnv, ClsInstEnv, DFunId )
  55 import Rules            ( RuleBase )
  56 import Id               ( Id )
  57 import Class            ( Class, classSelIds )
  58 import TyCon            ( TyCon, tyConGenIds, tyConSelIds, tyConDataConsIfAvailable )
  59 import DataCon          ( dataConId, dataConWrapId )
  60
  61 import BasicTypes       ( Version, initialVersion, Fixity )
  62
  63 import HsSyn            ( DeprecTxt, tyClDeclName, ifaceRuleDeclName )
  64 import RdrHsSyn         ( RdrNameInstDecl, RdrNameRuleDecl, RdrNameTyClDecl )
  65 import RnHsSyn          ( RenamedTyClDecl, RenamedRuleDecl, RenamedInstDecl )
  66
  67 import CoreSyn          ( IdCoreRule )
  68
  69 import FiniteMap        ( FiniteMap )
  70 import Bag              ( Bag )
  71 import Maybes           ( seqMaybe )
  72 import Outputable
  73 import SrcLoc           ( SrcLoc, isGoodSrcLoc )
  74 import Util             ( thenCmp, sortLt )
  75 import UniqSupply       ( UniqSupply )
  76 \end{code}
  77
  78 %************************************************************************
  79 %*                                                                      *
  80 \subsection{Module locations}
  81 %*                                                                      *
  82 %************************************************************************
  83
  84 \begin{code}
  85 data ModuleLocation
  86    = ModuleLocation {
  87         ml_hs_file   :: Maybe FilePath,
  88         ml_hspp_file :: Maybe FilePath,  -- path of preprocessed source
  89         ml_hi_file   :: Maybe FilePath,
  90         ml_obj_file  :: Maybe FilePath
  91      }
  92      deriving Show
  93
  94 instance Outputable ModuleLocation where
  95    ppr = text . show
  96 \end{code}
  97
  98 For a module in another package, the hs_file and obj_file
  99 components of ModuleLocation are undefined.
 100
 101 The locations specified by a ModuleLocation may or may not
 102 correspond to actual files yet: for example, even if the object
 103 file doesn't exist, the ModuleLocation still contains the path to
 104 where the object file will reside if/when it is created.
 105
 106
 107 %************************************************************************
 108 %*                                                                      *
 109 \subsection{Symbol tables and Module details}
 110 %*                                                                      *
 111 %************************************************************************
 112
 113 A @ModIface@ plus a @ModDetails@ summarises everything we know
 114 about a compiled module.  The @ModIface@ is the stuff *before* linking,
 115 and can be written out to an interface file.  The @ModDetails@ is after
 116 linking; it is the "linked" form of the mi_decls field.
 117
 118 \begin{code}
 119 data ModIface
 120    = ModIface {
 121         mi_module   :: Module,                  -- Complete with package info
 122         mi_version  :: VersionInfo,             -- Module version number
 123         mi_orphan   :: WhetherHasOrphans,       -- Whether this module has orphans
 124         mi_boot     :: IsBootInterface,         -- Whether this interface was read from an hi-boot file
 125
 126         mi_usages   :: [ImportVersion Name],    -- Usages; kept sorted so that it's easy
 127                                                 -- to decide whether to write a new iface file
 128                                                 -- (changing usages doesn't affect the version of
 129                                                 --  this module)
 130
 131         mi_exports  :: [(ModuleName,Avails)],   -- What it exports
 132                                                 -- Kept sorted by (mod,occ),
 133                                                 -- to make version comparisons easier
 134
 135         mi_globals  :: GlobalRdrEnv,            -- Its top level environment
 136
 137         mi_fixities :: NameEnv Fixity,          -- Fixities
 138         mi_deprecs  :: Deprecations,            -- Deprecations
 139
 140         mi_decls    :: IfaceDecls               -- The RnDecls form of ModDetails
 141      }
 142
 143 data IfaceDecls = IfaceDecls { dcl_tycl  :: [RenamedTyClDecl],  -- Sorted
 144                                dcl_rules :: [RenamedRuleDecl],  -- Sorted
 145                                dcl_insts :: [RenamedInstDecl] } -- Unsorted
 146
 147 mkIfaceDecls :: [RenamedTyClDecl] -> [RenamedRuleDecl] -> [RenamedInstDecl] -> IfaceDecls
 148 mkIfaceDecls tycls rules insts
 149   = IfaceDecls { dcl_tycl  = sortLt lt_tycl tycls,
 150                  dcl_rules = sortLt lt_rule rules,
 151                  dcl_insts = insts }
 152   where
 153     d1 `lt_tycl` d2 = tyClDeclName      d1 < tyClDeclName      d2
 154     r1 `lt_rule` r2 = ifaceRuleDeclName r1 < ifaceRuleDeclName r2
 155
 156
 157 -- typechecker should only look at this, not ModIface
 158 -- Should be able to construct ModDetails from mi_decls in ModIface
 159 data ModDetails
 160    = ModDetails {
 161         -- The next three fields are created by the typechecker
 162         md_types    :: TypeEnv,
 163         md_insts    :: [DFunId],        -- Dfun-ids for the instances in this module
 164         md_rules    :: [IdCoreRule]     -- Domain may include Ids from other modules
 165      }
 166 \end{code}
 167
 168 \begin{code}
 169 emptyModDetails :: ModDetails
 170 emptyModDetails
 171   = ModDetails { md_types = emptyTypeEnv,
 172                  md_insts = [],
 173                  md_rules = []
 174     }
 175
 176 emptyModIface :: Module -> ModIface
 177 emptyModIface mod
 178   = ModIface { mi_module   = mod,
 179                mi_version  = initialVersionInfo,
 180                mi_usages   = [],
 181                mi_orphan   = False,
 182                mi_boot     = False,
 183                mi_exports  = [],
 184                mi_fixities = emptyNameEnv,
 185                mi_globals  = emptyRdrEnv,
 186                mi_deprecs  = NoDeprecs,
 187                mi_decls    = panic "emptyModIface: decls"
 188     }
 189 \end{code}
 190
 191 Symbol tables map modules to ModDetails:
 192
 193 \begin{code}
 194 type SymbolTable        = ModuleEnv ModDetails
 195 type IfaceTable         = ModuleEnv ModIface
 196
 197 type HomeIfaceTable     = IfaceTable
 198 type PackageIfaceTable  = IfaceTable
 199
 200 type HomeSymbolTable    = SymbolTable   -- Domain = modules in the home package
 201
 202 emptyIfaceTable :: IfaceTable
 203 emptyIfaceTable = emptyModuleEnv
 204 \end{code}
 205
 206 Simple lookups in the symbol table.
 207
 208 \begin{code}
 209 lookupIface :: HomeIfaceTable -> PackageIfaceTable -> Name -> Maybe ModIface
 210 -- We often have two IfaceTables, and want to do a lookup
 211 lookupIface hit pit name
 212   = lookupModuleEnv hit mod `seqMaybe` lookupModuleEnv pit mod
 213   where
 214     mod = nameModule name
 215
 216 lookupIfaceByModName :: HomeIfaceTable -> PackageIfaceTable -> ModuleName -> Maybe ModIface
 217 -- We often have two IfaceTables, and want to do a lookup
 218 lookupIfaceByModName hit pit mod
 219   = lookupModuleEnvByName hit mod `seqMaybe` lookupModuleEnvByName pit mod
 220 \end{code}
 221
 222
 223 %************************************************************************
 224 %*                                                                      *
 225 \subsection{Type environment stuff}
 226 %*                                                                      *
 227 %************************************************************************
 228
 229 \begin{code}
 230 data TyThing = AnId   Id
 231              | ATyCon TyCon
 232              | AClass Class
 233
 234 isTyClThing :: TyThing -> Bool
 235 isTyClThing (ATyCon _) = True
 236 isTyClThing (AClass _) = True
 237 isTyClThing (AnId   _) = False
 238
 239 instance NamedThing TyThing where
 240   getName (AnId id)   = getName id
 241   getName (ATyCon tc) = getName tc
 242   getName (AClass cl) = getName cl
 243
 244 instance Outputable TyThing where
 245   ppr (AnId   id) = ptext SLIT("AnId")   <+> ppr id
 246   ppr (ATyCon tc) = ptext SLIT("ATyCon") <+> ppr tc
 247   ppr (AClass cl) = ptext SLIT("AClass") <+> ppr cl
 248
 249 typeEnvClasses env = [cl | AClass cl <- nameEnvElts env]
 250 typeEnvTyCons  env = [tc | ATyCon tc <- nameEnvElts env]
 251
 252 implicitTyThingIds :: [TyThing] -> [Id]
 253 -- Add the implicit data cons and selectors etc
 254 implicitTyThingIds things
 255   = concat (map go things)
 256   where
 257     go (AnId f)    = []
 258     go (AClass cl) = classSelIds cl
 259     go (ATyCon tc) = tyConGenIds tc ++
 260                      tyConSelIds tc ++
 261                      [ n | dc <- tyConDataConsIfAvailable tc,
 262                            n  <- [dataConId dc, dataConWrapId dc] ]
 263                 -- Synonyms return empty list of constructors and selectors
 264 \end{code}
 265
 266
 267 \begin{code}
 268 type TypeEnv = NameEnv TyThing
 269
 270 emptyTypeEnv = emptyNameEnv
 271
 272 mkTypeEnv :: [TyThing] -> TypeEnv
 273 mkTypeEnv things = extendTypeEnvList emptyTypeEnv things
 274
 275 extendTypeEnvList :: TypeEnv -> [TyThing] -> TypeEnv
 276 extendTypeEnvList env things
 277   = foldl add_thing env things
 278   where
 279     add_thing :: TypeEnv -> TyThing -> TypeEnv
 280     add_thing env thing = extendNameEnv env (getName thing) thing
 281 \end{code}
 282
 283 \begin{code}
 284 lookupType :: HomeSymbolTable -> PackageTypeEnv -> Name -> Maybe TyThing
 285 lookupType hst pte name
 286   = case lookupModuleEnv hst (nameModule name) of
 287         Just details -> lookupNameEnv (md_types details) name
 288         Nothing      -> lookupNameEnv pte name
 289 \end{code}
 290
 291 %************************************************************************
 292 %*                                                                      *
 293 \subsection{Auxiliary types}
 294 %*                                                                      *
 295 %************************************************************************
 296
 297 These types are defined here because they are mentioned in ModDetails,
 298 but they are mostly elaborated elsewhere
 299
 300 \begin{code}
 301 data VersionInfo
 302   = VersionInfo {
 303         vers_module  :: Version,        -- Changes when anything changes
 304         vers_exports :: Version,        -- Changes when export list changes
 305         vers_rules   :: Version,        -- Changes when any rule changes
 306         vers_decls   :: NameEnv Version
 307                 -- Versions for "big" names only (not data constructors, class ops)
 308                 -- The version of an Id changes if its fixity changes
 309                 -- Ditto data constructors, class operations, except that the version of
 310                 -- the parent class/tycon changes
 311     }
 312
 313 initialVersionInfo :: VersionInfo
 314 initialVersionInfo = VersionInfo { vers_module  = initialVersion,
 315                                    vers_exports = initialVersion,
 316                                    vers_rules   = initialVersion,
 317                                    vers_decls   = emptyNameEnv }
 318
 319 data Deprecations = NoDeprecs
 320                   | DeprecAll DeprecTxt                         -- Whole module deprecated
 321                   | DeprecSome (NameEnv (Name,DeprecTxt))       -- Some things deprecated
 322                                                                 -- Just "big" names
 323                 -- We keep the Name in the range, so we can print them out
 324
 325 lookupDeprec :: Deprecations -> Name -> Maybe DeprecTxt
 326 lookupDeprec NoDeprecs        name = Nothing
 327 lookupDeprec (DeprecAll  txt) name = Just txt
 328 lookupDeprec (DeprecSome env) name = case lookupNameEnv env name of
 329                                             Just (_, txt) -> Just txt
 330                                             Nothing       -> Nothing
 331
 332 instance Eq Deprecations where
 333   -- Used when checking whether we need write a new interface
 334   NoDeprecs       == NoDeprecs       = True
 335   (DeprecAll t1)  == (DeprecAll t2)  = t1 == t2
 336   (DeprecSome e1) == (DeprecSome e2) = nameEnvElts e1 == nameEnvElts e2
 337   d1              == d2              = False
 338 \end{code}
 339
 340
 341 \begin{code}
 342 type Avails       = [AvailInfo]
 343 type AvailInfo    = GenAvailInfo Name
 344 type RdrAvailInfo = GenAvailInfo OccName
 345
 346 data GenAvailInfo name  = Avail name     -- An ordinary identifier
 347                         | AvailTC name   -- The name of the type or class
 348                                   [name] -- The available pieces of type/class.
 349                                          -- NB: If the type or class is itself
 350                                          -- to be in scope, it must be in this list.
 351                                          -- Thus, typically: AvailTC Eq [Eq, ==, /=]
 352                         deriving( Eq )
 353                         -- Equality used when deciding if the interface has changed
 354
 355 type AvailEnv     = NameEnv AvailInfo   -- Maps a Name to the AvailInfo that contains it
 356
 357 instance Outputable n => Outputable (GenAvailInfo n) where
 358    ppr = pprAvail
 359
 360 pprAvail :: Outputable n => GenAvailInfo n -> SDoc
 361 pprAvail (AvailTC n ns) = ppr n <> case {- filter (/= n) -} ns of
 362                                         []  -> empty
 363                                         ns' -> braces (hsep (punctuate comma (map ppr ns')))
 364
 365 pprAvail (Avail n) = ppr n
 366 \end{code}
 367
 368
 369 %************************************************************************
 370 %*                                                                      *
 371 \subsection{ModIface}
 372 %*                                                                      *
 373 %************************************************************************
 374
 375 \begin{code}
 376 type WhetherHasOrphans   = Bool
 377         -- An "orphan" is
 378         --      * an instance decl in a module other than the defn module for
 379         --              one of the tycons or classes in the instance head
 380         --      * a transformation rule in a module other than the one defining
 381         --              the function in the head of the rule.
 382
 383 type IsBootInterface     = Bool
 384
 385 type ImportVersion name  = (ModuleName, WhetherHasOrphans, IsBootInterface, WhatsImported name)
 386
 387 data WhatsImported name  = NothingAtAll                         -- The module is below us in the
 388                                                                 -- hierarchy, but we import nothing
 389
 390                          | Everything Version           -- Used for modules from other packages;
 391                                                         -- we record only the module's version number
 392
 393                          | Specifically
 394                                 Version                 -- Module version
 395                                 (Maybe Version)         -- Export-list version, if we depend on it
 396                                 [(name,Version)]        -- List guaranteed non-empty
 397                                 Version                 -- Rules version
 398
 399                          deriving( Eq )
 400         -- 'Specifically' doesn't let you say "I imported f but none of the rules in
 401         -- the module". If you use anything in the module you get its rule version
 402         -- So if the rules change, you'll recompile, even if you don't use them.
 403         -- This is easy to implement, and it's safer: you might not have used the rules last
 404         -- time round, but if someone has added a new rule you might need it this time
 405
 406         -- The export list field is (Just v) if we depend on the export list:
 407         --      we imported the module without saying exactly what we imported
 408         -- We need to recompile if the module exports changes, because we might
 409         -- now have a name clash in the importing module.
 410
 411 type IsExported = Name -> Bool          -- True for names that are exported from this module
 412 \end{code}
 413
 414
 415 %************************************************************************
 416 %*                                                                      *
 417 \subsection{The persistent compiler state}
 418 %*                                                                      *
 419 %************************************************************************
 420
 421 \begin{code}
 422 data PersistentCompilerState
 423    = PCS {
 424         pcs_PIT :: PackageIfaceTable,   -- Domain = non-home-package modules
 425                                         --   the mi_decls component is empty
 426
 427         pcs_PTE :: PackageTypeEnv,      -- Domain = non-home-package modules
 428                                         --   except that the InstEnv components is empty
 429
 430         pcs_insts :: PackageInstEnv,    -- The total InstEnv accumulated from all
 431                                         --   the non-home-package modules
 432
 433         pcs_rules :: PackageRuleBase,   -- Ditto RuleEnv
 434
 435         pcs_PRS :: PersistentRenamerState
 436      }
 437 \end{code}
 438
 439 The @PersistentRenamerState@ persists across successive calls to the
 440 compiler.
 441
 442 It contains:
 443   * A name supply, which deals with allocating unique names to
 444     (Module,OccName) original names,
 445
 446   * An accumulated TypeEnv from all the modules in imported packages
 447
 448   * An accumulated InstEnv from all the modules in imported packages
 449     The point is that we don't want to keep recreating it whenever
 450     we compile a new module.  The InstEnv component of pcPST is empty.
 451     (This means we might "see" instances that we shouldn't "really" see;
 452     but the Haskell Report is vague on what is meant to be visible,
 453     so we just take the easy road here.)
 454
 455   * Ditto for rules
 456
 457   * A "holding pen" for declarations that have been read out of
 458     interface files but not yet sucked in, renamed, and typechecked
 459
 460 \begin{code}
 461 type PackageTypeEnv  = TypeEnv
 462 type PackageRuleBase = RuleBase
 463 type PackageInstEnv  = InstEnv
 464
 465 data PersistentRenamerState
 466   = PRS { prsOrig    :: NameSupply,
 467           prsImpMods :: ImportedModuleInfo,
 468           prsDecls   :: DeclsMap,
 469           prsInsts   :: IfaceInsts,
 470           prsRules   :: IfaceRules
 471     }
 472 \end{code}
 473
 474 The NameSupply makes sure that there is just one Unique assigned for
 475 each original name; i.e. (module-name, occ-name) pair.  The Name is
 476 always stored as a Global, and has the SrcLoc of its binding location.
 477 Actually that's not quite right.  When we first encounter the original
 478 name, we might not be at its binding site (e.g. we are reading an
 479 interface file); so we give it 'noSrcLoc' then.  Later, when we find
 480 its binding site, we fix it up.
 481
 482 Exactly the same is true of the Module stored in the Name.  When we first
 483 encounter the occurrence, we may not know the details of the module, so
 484 we just store junk.  Then when we find the binding site, we fix it up.
 485
 486 \begin{code}
 487 data NameSupply
 488  = NameSupply { nsUniqs :: UniqSupply,
 489                 -- Supply of uniques
 490                 nsNames :: OrigNameCache,
 491                 -- Ensures that one original name gets one unique
 492                 nsIPs   :: OrigIParamCache
 493                 -- Ensures that one implicit parameter name gets one unique
 494    }
 495
 496 type OrigNameCache   = FiniteMap (ModuleName,OccName) Name
 497 type OrigIParamCache = FiniteMap OccName Name
 498 \end{code}
 499
 500 @ImportedModuleInfo@ contains info ONLY about modules that have not yet
 501 been loaded into the iPIT.  These modules are mentioned in interfaces we've
 502 already read, so we know a tiny bit about them, but we havn't yet looked
 503 at the interface file for the module itself.  It needs to persist across
 504 invocations of the renamer, at least from Rename.checkOldIface to Rename.renameSource.
 505 And there's no harm in it persisting across multiple compilations.
 506
 507 \begin{code}
 508 type ImportedModuleInfo = FiniteMap ModuleName (WhetherHasOrphans, IsBootInterface)
 509 \end{code}
 510
 511 A DeclsMap contains a binding for each Name in the declaration
 512 including the constructors of a type decl etc.  The Bool is True just
 513 for the 'main' Name.
 514
 515 \begin{code}
 516 type DeclsMap = (NameEnv (AvailInfo, Bool, (Module, RdrNameTyClDecl)), Int)
 517                                                 -- The Int says how many have been sucked in
 518
 519 type IfaceInsts = GatedDecls RdrNameInstDecl
 520 type IfaceRules = GatedDecls RdrNameRuleDecl
 521
 522 type GatedDecls d = (Bag (GatedDecl d), Int)    -- The Int says how many have been sucked in
 523 type GatedDecl  d = ([Name], (Module, d))
 524 \end{code}
 525
 526
 527 %************************************************************************
 528 %*                                                                      *
 529 \subsection{Provenance and export info}
 530 %*                                                                      *
 531 %************************************************************************
 532
 533 The GlobalRdrEnv gives maps RdrNames to Names.  There is a separate
 534 one for each module, corresponding to that module's top-level scope.
 535
 536 \begin{code}
 537 type GlobalRdrEnv = RdrNameEnv [GlobalRdrElt]
 538         -- The list is because there may be name clashes
 539         -- These only get reported on lookup, not on construction
 540
 541 data GlobalRdrElt = GRE Name Provenance (Maybe DeprecTxt)
 542         -- The Maybe DeprecTxt tells whether this name is deprecated
 543
 544 pprGlobalRdrEnv env
 545   = vcat (map pp (rdrEnvToList env))
 546   where
 547     pp (rn, nps) = ppr rn <> colon <+>
 548                    vcat [ppr n <+> pprNameProvenance n p | (GRE n p _) <- nps]
 549 \end{code}
 550
 551 The "provenance" of something says how it came to be in scope.
 552
 553 \begin{code}
 554 data Provenance
 555   = LocalDef                    -- Defined locally
 556
 557   | NonLocalDef                 -- Defined non-locally
 558         ImportReason
 559
 560 -- Just used for grouping error messages (in RnEnv.warnUnusedBinds)
 561 instance Eq Provenance where
 562   p1 == p2 = case p1 `compare` p2 of EQ -> True; _ -> False
 563
 564 instance Eq ImportReason where
 565   p1 == p2 = case p1 `compare` p2 of EQ -> True; _ -> False
 566
 567 instance Ord Provenance where
 568    compare LocalDef LocalDef = EQ
 569    compare LocalDef (NonLocalDef _) = LT
 570    compare (NonLocalDef _) LocalDef = GT
 571
 572    compare (NonLocalDef reason1) (NonLocalDef reason2)
 573       = compare reason1 reason2
 574
 575 instance Ord ImportReason where
 576    compare ImplicitImport ImplicitImport = EQ
 577    compare ImplicitImport (UserImport _ _ _) = LT
 578    compare (UserImport _ _ _) ImplicitImport = GT
 579    compare (UserImport m1 loc1 _) (UserImport m2 loc2 _)
 580       = (m1 `compare` m2) `thenCmp` (loc1 `compare` loc2)
 581
 582
 583 data ImportReason
 584   = UserImport Module SrcLoc Bool       -- Imported from module M on line L
 585                                         -- Note the M may well not be the defining module
 586                                         -- for this thing!
 587         -- The Bool is true iff the thing was named *explicitly* in the import spec,
 588         -- rather than being imported as part of a group; e.g.
 589         --      import B
 590         --      import C( T(..) )
 591         -- Here, everything imported by B, and the constructors of T
 592         -- are not named explicitly; only T is named explicitly.
 593         -- This info is used when warning of unused names.
 594
 595   | ImplicitImport                      -- Imported implicitly for some other reason
 596 \end{code}
 597
 598 \begin{code}
 599 hasBetterProv :: Provenance -> Provenance -> Bool
 600 -- Choose
 601 --      a local thing                 over an   imported thing
 602 --      a user-imported thing         over a    non-user-imported thing
 603 --      an explicitly-imported thing  over an   implicitly imported thing
 604 hasBetterProv LocalDef                            _                            = True
 605 hasBetterProv (NonLocalDef (UserImport _ _ _   )) (NonLocalDef ImplicitImport) = True
 606 hasBetterProv _                                   _                            = False
 607
 608 pprNameProvenance :: Name -> Provenance -> SDoc
 609 pprNameProvenance name LocalDef          = ptext SLIT("defined at") <+> ppr (nameSrcLoc name)
 610 pprNameProvenance name (NonLocalDef why) = sep [ppr_reason why,
 611                                                 nest 2 (parens (ppr_defn (nameSrcLoc name)))]
 612
 613 ppr_reason ImplicitImport         = ptext SLIT("implicitly imported")
 614 ppr_reason (UserImport mod loc _) = ptext SLIT("imported from") <+> ppr mod <+> ptext SLIT("at") <+> ppr loc
 615
 616 ppr_defn loc | isGoodSrcLoc loc = ptext SLIT("at") <+> ppr loc
 617              | otherwise        = empty
 618 \end{code}