ghc/compiler/main/HscTypes.lhs

   1 %
   2 % (c) The University of Glasgow, 2000
   3 %
   4 \section[HscTypes]{Types for the per-module compiler}
   5
   6 \begin{code}
   7 module HscTypes (
   8         GhciMode(..),
   9
  10         ModuleLocation(..),
  11
  12         ModDetails(..), ModIface(..),
  13         HomeSymbolTable, emptySymbolTable,
  14         PackageTypeEnv,
  15         HomeIfaceTable, PackageIfaceTable, emptyIfaceTable,
  16         lookupIface, lookupIfaceByModName,
  17         emptyModIface,
  18
  19         InteractiveContext(..),
  20
  21         IfaceDecls, mkIfaceDecls, dcl_tycl, dcl_rules, dcl_insts,
  22
  23         VersionInfo(..), initialVersionInfo, lookupVersion,
  24
  25         TyThing(..), isTyClThing, implicitTyThingIds,
  26
  27         TypeEnv, lookupType, mkTypeEnv, emptyTypeEnv,
  28         extendTypeEnvList, extendTypeEnvWithIds,
  29         typeEnvElts, typeEnvClasses, typeEnvTyCons, typeEnvIds,
  30
  31         ImportedModuleInfo, WhetherHasOrphans, ImportVersion, WhatsImported(..),
  32         PersistentRenamerState(..), IsBootInterface, DeclsMap,
  33         IfaceInsts, IfaceRules, GatedDecl, GatedDecls, GateFn, IsExported,
  34         NameSupply(..), OrigNameCache, OrigIParamCache,
  35         Avails, AvailEnv, GenAvailInfo(..), AvailInfo, RdrAvailInfo,
  36         PersistentCompilerState(..),
  37
  38         Deprecations(..), lookupDeprec,
  39
  40         InstEnv, ClsInstEnv, DFunId,
  41         PackageInstEnv, PackageRuleBase,
  42
  43         GlobalRdrEnv, GlobalRdrElt(..), pprGlobalRdrEnv,
  44         LocalRdrEnv, extendLocalRdrEnv,
  45
  46
  47         -- Provenance
  48         Provenance(..), ImportReason(..),
  49         pprNameProvenance, hasBetterProv
  50
  51     ) where
  52
  53 #include "HsVersions.h"
  54
  55 import RdrName          ( RdrName, RdrNameEnv, addListToRdrEnv, emptyRdrEnv,
  56                           mkRdrUnqual, rdrEnvToList )
  57 import Name             ( Name, NamedThing, getName, nameOccName, nameModule, nameSrcLoc )
  58 import NameEnv
  59 import OccName          ( OccName )
  60 import Module           ( Module, ModuleName, ModuleEnv,
  61                           lookupModuleEnv, lookupModuleEnvByName, emptyModuleEnv
  62                         )
  63 import InstEnv          ( InstEnv, ClsInstEnv, DFunId )
  64 import Rules            ( RuleBase )
  65 import CoreSyn          ( CoreBind )
  66 import Id               ( Id )
  67 import Type             ( IPName )
  68 import Class            ( Class, classSelIds )
  69 import TyCon            ( TyCon, isNewTyCon, tyConGenIds, tyConSelIds, tyConDataConsIfAvailable )
  70 import DataCon          ( dataConId, dataConWrapId )
  71
  72 import BasicTypes       ( Version, initialVersion, Fixity )
  73
  74 import HsSyn            ( DeprecTxt, tyClDeclName, ifaceRuleDeclName )
  75 import RdrHsSyn         ( RdrNameInstDecl, RdrNameRuleDecl, RdrNameTyClDecl )
  76 import RnHsSyn          ( RenamedTyClDecl, RenamedRuleDecl, RenamedInstDecl )
  77
  78 import CoreSyn          ( IdCoreRule )
  79
  80 import FiniteMap        ( FiniteMap )
  81 import Bag              ( Bag )
  82 import Maybes           ( seqMaybe, orElse )
  83 import Outputable
  84 import SrcLoc           ( SrcLoc, isGoodSrcLoc )
  85 import Util             ( thenCmp, sortLt )
  86 import UniqSupply       ( UniqSupply )
  87 \end{code}
  88
  89 %************************************************************************
  90 %*                                                                      *
  91 \subsection{Which mode we're in
  92 %*                                                                      *
  93 %************************************************************************
  94
  95 \begin{code}
  96 data GhciMode = Batch | Interactive | OneShot
  97      deriving Eq
  98 \end{code}
  99
 100
 101 %************************************************************************
 102 %*                                                                      *
 103 \subsection{Module locations}
 104 %*                                                                      *
 105 %************************************************************************
 106
 107 \begin{code}
 108 data ModuleLocation
 109    = ModuleLocation {
 110         ml_hs_file   :: Maybe FilePath,
 111         ml_hspp_file :: Maybe FilePath,  -- path of preprocessed source
 112         ml_hi_file   :: FilePath,
 113         ml_obj_file  :: Maybe FilePath
 114      }
 115      deriving Show
 116
 117 instance Outputable ModuleLocation where
 118    ppr = text . show
 119 \end{code}
 120
 121 For a module in another package, the hs_file and obj_file
 122 components of ModuleLocation are undefined.
 123
 124 The locations specified by a ModuleLocation may or may not
 125 correspond to actual files yet: for example, even if the object
 126 file doesn't exist, the ModuleLocation still contains the path to
 127 where the object file will reside if/when it is created.
 128
 129
 130 %************************************************************************
 131 %*                                                                      *
 132 \subsection{Symbol tables and Module details}
 133 %*                                                                      *
 134 %************************************************************************
 135
 136 A @ModIface@ plus a @ModDetails@ summarises everything we know
 137 about a compiled module.  The @ModIface@ is the stuff *before* linking,
 138 and can be written out to an interface file.  The @ModDetails@ is after
 139 linking; it is the "linked" form of the mi_decls field.
 140
 141 \begin{code}
 142 data ModIface
 143    = ModIface {
 144         mi_module   :: !Module,             -- Complete with package info
 145         mi_version  :: !VersionInfo,        -- Module version number
 146         mi_orphan   :: WhetherHasOrphans,   -- Whether this module has orphans
 147         mi_boot     :: !IsBootInterface,    -- read from an hi-boot file?
 148
 149         mi_usages   :: ![ImportVersion Name],
 150                 -- Usages; kept sorted so that it's easy to decide
 151                 -- whether to write a new iface file (changing usages
 152                 -- doesn't affect the version of this module)
 153
 154         mi_exports  :: ![(ModuleName,Avails)],
 155                 -- What it exports Kept sorted by (mod,occ), to make
 156                 -- version comparisons easier
 157
 158         mi_globals  :: !GlobalRdrEnv,       -- Its top level environment
 159
 160         mi_fixities :: !(NameEnv Fixity),   -- Fixities
 161         mi_deprecs  :: !Deprecations,       -- Deprecations
 162
 163         mi_decls    :: IfaceDecls           -- The RnDecls form of ModDetails
 164      }
 165
 166 data IfaceDecls = IfaceDecls { dcl_tycl  :: [RenamedTyClDecl],  -- Sorted
 167                                dcl_rules :: [RenamedRuleDecl],  -- Sorted
 168                                dcl_insts :: [RenamedInstDecl] } -- Unsorted
 169
 170 mkIfaceDecls :: [RenamedTyClDecl] -> [RenamedRuleDecl] -> [RenamedInstDecl] -> IfaceDecls
 171 mkIfaceDecls tycls rules insts
 172   = IfaceDecls { dcl_tycl  = sortLt lt_tycl tycls,
 173                  dcl_rules = sortLt lt_rule rules,
 174                  dcl_insts = insts }
 175   where
 176     d1 `lt_tycl` d2 = tyClDeclName      d1 < tyClDeclName      d2
 177     r1 `lt_rule` r2 = ifaceRuleDeclName r1 < ifaceRuleDeclName r2
 178
 179
 180 -- typechecker should only look at this, not ModIface
 181 -- Should be able to construct ModDetails from mi_decls in ModIface
 182 data ModDetails
 183    = ModDetails {
 184         -- The next three fields are created by the typechecker
 185         md_types    :: !TypeEnv,
 186         md_insts    :: ![DFunId],       -- Dfun-ids for the instances in this module
 187         md_rules    :: ![IdCoreRule],   -- Domain may include Ids from other modules
 188         md_binds    :: ![CoreBind]
 189      }
 190
 191 -- The ModDetails takes on several slightly different forms:
 192 --
 193 -- After typecheck + desugar
 194 --      md_types        Contains TyCons, Classes, and implicit Ids
 195 --      md_insts        All instances from this module (incl derived ones)
 196 --      md_rules        All rules from this module
 197 --      md_binds        Desugared bindings
 198 --
 199 -- After simplification
 200 --      md_types        Same as after typecheck
 201 --      md_insts        Ditto
 202 --      md_rules        Orphan rules only (local ones now attached to binds)
 203 --      md_binds        With rules attached
 204 --
 205 -- After CoreTidy
 206 --      md_types        Now contains Ids as well, replete with final IdInfo
 207 --                         The Ids are only the ones that are visible from
 208 --                         importing modules.  Without -O that means only
 209 --                         exported Ids, but with -O importing modules may
 210 --                         see ids mentioned in unfoldings of exported Ids
 211 --
 212 --      md_insts        Same DFunIds as before, but with final IdInfo,
 213 --                         and the unique might have changed; remember that
 214 --                         CoreTidy links up the uniques of old and new versions
 215 --
 216 --      md_rules        All rules for exported things, substituted with final Ids
 217 --
 218 --      md_binds        Tidied
 219 --
 220 -- Passed back to compilation manager
 221 --      Just as after CoreTidy, but with md_binds nuked
 222
 223 \end{code}
 224
 225 \begin{code}
 226 emptyModIface :: Module -> ModIface
 227 emptyModIface mod
 228   = ModIface { mi_module   = mod,
 229                mi_version  = initialVersionInfo,
 230                mi_usages   = [],
 231                mi_orphan   = False,
 232                mi_boot     = False,
 233                mi_exports  = [],
 234                mi_fixities = emptyNameEnv,
 235                mi_globals  = emptyRdrEnv,
 236                mi_deprecs  = NoDeprecs,
 237                mi_decls    = panic "emptyModIface: decls"
 238     }
 239 \end{code}
 240
 241 Symbol tables map modules to ModDetails:
 242
 243 \begin{code}
 244 type SymbolTable        = ModuleEnv ModDetails
 245 type IfaceTable         = ModuleEnv ModIface
 246
 247 type HomeIfaceTable     = IfaceTable
 248 type PackageIfaceTable  = IfaceTable
 249
 250 type HomeSymbolTable    = SymbolTable   -- Domain = modules in the home package
 251
 252 emptySymbolTable :: SymbolTable
 253 emptySymbolTable = emptyModuleEnv
 254
 255 emptyIfaceTable :: IfaceTable
 256 emptyIfaceTable = emptyModuleEnv
 257 \end{code}
 258
 259 Simple lookups in the symbol table.
 260
 261 \begin{code}
 262 lookupIface :: HomeIfaceTable -> PackageIfaceTable -> Name -> Maybe ModIface
 263 -- We often have two IfaceTables, and want to do a lookup
 264 lookupIface hit pit name
 265   = lookupModuleEnv hit mod `seqMaybe` lookupModuleEnv pit mod
 266   where
 267     mod = nameModule name
 268
 269 lookupIfaceByModName :: HomeIfaceTable -> PackageIfaceTable -> ModuleName -> Maybe ModIface
 270 -- We often have two IfaceTables, and want to do a lookup
 271 lookupIfaceByModName hit pit mod
 272   = lookupModuleEnvByName hit mod `seqMaybe` lookupModuleEnvByName pit mod
 273 \end{code}
 274
 275
 276 %************************************************************************
 277 %*                                                                      *
 278 \subsection{The interactive context}
 279 %*                                                                      *
 280 %************************************************************************
 281
 282 \begin{code}
 283 data InteractiveContext
 284   = InteractiveContext {
 285         ic_module :: Module,            -- The current module in which
 286                                         -- the  user is sitting
 287
 288         ic_rn_env :: LocalRdrEnv,       -- Lexical context for variables bound
 289                                         -- during interaction
 290
 291         ic_type_env :: TypeEnv          -- Ditto for types
 292     }
 293 \end{code}
 294
 295
 296 %************************************************************************
 297 %*                                                                      *
 298 \subsection{Type environment stuff}
 299 %*                                                                      *
 300 %************************************************************************
 301
 302 \begin{code}
 303 data TyThing = AnId   Id
 304              | ATyCon TyCon
 305              | AClass Class
 306
 307 isTyClThing :: TyThing -> Bool
 308 isTyClThing (ATyCon _) = True
 309 isTyClThing (AClass _) = True
 310 isTyClThing (AnId   _) = False
 311
 312 instance NamedThing TyThing where
 313   getName (AnId id)   = getName id
 314   getName (ATyCon tc) = getName tc
 315   getName (AClass cl) = getName cl
 316
 317 instance Outputable TyThing where
 318   ppr (AnId   id) = ptext SLIT("AnId")   <+> ppr id
 319   ppr (ATyCon tc) = ptext SLIT("ATyCon") <+> ppr tc
 320   ppr (AClass cl) = ptext SLIT("AClass") <+> ppr cl
 321
 322
 323 typeEnvElts    :: TypeEnv -> [TyThing]
 324 typeEnvClasses :: TypeEnv -> [Class]
 325 typeEnvTyCons  :: TypeEnv -> [TyCon]
 326 typeEnvIds     :: TypeEnv -> [Id]
 327
 328 typeEnvElts    env = nameEnvElts env
 329 typeEnvClasses env = [cl | AClass cl <- typeEnvElts env]
 330 typeEnvTyCons  env = [tc | ATyCon tc <- typeEnvElts env]
 331 typeEnvIds     env = [id | AnId id   <- typeEnvElts env]
 332
 333 implicitTyThingIds :: [TyThing] -> [Id]
 334 -- Add the implicit data cons and selectors etc
 335 implicitTyThingIds things
 336   = concat (map go things)
 337   where
 338     go (AnId f)    = []
 339     go (AClass cl) = classSelIds cl
 340     go (ATyCon tc) = tyConGenIds tc ++
 341                      tyConSelIds tc ++
 342                      [ n | dc <- tyConDataConsIfAvailable tc,
 343                            n  <- implicitConIds tc dc]
 344                 -- Synonyms return empty list of constructors and selectors
 345
 346     implicitConIds tc dc        -- Newtypes have a constructor wrapper,
 347                                 -- but no worker
 348         | isNewTyCon tc = [dataConWrapId dc]
 349         | otherwise     = [dataConId dc, dataConWrapId dc]
 350 \end{code}
 351
 352
 353 \begin{code}
 354 type TypeEnv = NameEnv TyThing
 355
 356 emptyTypeEnv = emptyNameEnv
 357
 358 mkTypeEnv :: [TyThing] -> TypeEnv
 359 mkTypeEnv things = extendTypeEnvList emptyTypeEnv things
 360
 361 extendTypeEnvList :: TypeEnv -> [TyThing] -> TypeEnv
 362 extendTypeEnvList env things
 363   = extendNameEnvList env [(getName thing, thing) | thing <- things]
 364
 365 extendTypeEnvWithIds :: TypeEnv -> [Id] -> TypeEnv
 366 extendTypeEnvWithIds env ids
 367   = extendNameEnvList env [(getName id, AnId id) | id <- ids]
 368 \end{code}
 369
 370 \begin{code}
 371 lookupType :: HomeSymbolTable -> PackageTypeEnv -> Name -> Maybe TyThing
 372 lookupType hst pte name
 373   = case lookupModuleEnv hst (nameModule name) of
 374         Just details -> lookupNameEnv (md_types details) name
 375         Nothing      -> lookupNameEnv pte name
 376 \end{code}
 377
 378 %************************************************************************
 379 %*                                                                      *
 380 \subsection{Auxiliary types}
 381 %*                                                                      *
 382 %************************************************************************
 383
 384 These types are defined here because they are mentioned in ModDetails,
 385 but they are mostly elaborated elsewhere
 386
 387 \begin{code}
 388 data VersionInfo
 389   = VersionInfo {
 390         vers_module  :: Version,        -- Changes when anything changes
 391         vers_exports :: Version,        -- Changes when export list changes
 392         vers_rules   :: Version,        -- Changes when any rule changes
 393         vers_decls   :: NameEnv Version
 394                 -- Versions for "big" names only (not data constructors, class ops)
 395                 -- The version of an Id changes if its fixity changes
 396                 -- Ditto data constructors, class operations, except that the version of
 397                 -- the parent class/tycon changes
 398                 --
 399                 -- If a name isn't in the map, it means 'initialVersion'
 400     }
 401
 402 initialVersionInfo :: VersionInfo
 403 initialVersionInfo = VersionInfo { vers_module  = initialVersion,
 404                                    vers_exports = initialVersion,
 405                                    vers_rules   = initialVersion,
 406                                    vers_decls   = emptyNameEnv
 407                         }
 408
 409 lookupVersion :: NameEnv Version -> Name -> Version
 410 lookupVersion env name = lookupNameEnv env name `orElse` initialVersion
 411
 412 data Deprecations = NoDeprecs
 413                   | DeprecAll DeprecTxt                         -- Whole module deprecated
 414                   | DeprecSome (NameEnv (Name,DeprecTxt))       -- Some things deprecated
 415                                                                 -- Just "big" names
 416                 -- We keep the Name in the range, so we can print them out
 417
 418 lookupDeprec :: Deprecations -> Name -> Maybe DeprecTxt
 419 lookupDeprec NoDeprecs        name = Nothing
 420 lookupDeprec (DeprecAll  txt) name = Just txt
 421 lookupDeprec (DeprecSome env) name = case lookupNameEnv env name of
 422                                             Just (_, txt) -> Just txt
 423                                             Nothing       -> Nothing
 424
 425 instance Eq Deprecations where
 426   -- Used when checking whether we need write a new interface
 427   NoDeprecs       == NoDeprecs       = True
 428   (DeprecAll t1)  == (DeprecAll t2)  = t1 == t2
 429   (DeprecSome e1) == (DeprecSome e2) = nameEnvElts e1 == nameEnvElts e2
 430   d1              == d2              = False
 431 \end{code}
 432
 433
 434 \begin{code}
 435 type Avails       = [AvailInfo]
 436 type AvailInfo    = GenAvailInfo Name
 437 type RdrAvailInfo = GenAvailInfo OccName
 438
 439 data GenAvailInfo name  = Avail name     -- An ordinary identifier
 440                         | AvailTC name   -- The name of the type or class
 441                                   [name] -- The available pieces of type/class.
 442                                          -- NB: If the type or class is itself
 443                                          -- to be in scope, it must be in this list.
 444                                          -- Thus, typically: AvailTC Eq [Eq, ==, /=]
 445                         deriving( Eq )
 446                         -- Equality used when deciding if the interface has changed
 447
 448 type AvailEnv     = NameEnv AvailInfo   -- Maps a Name to the AvailInfo that contains it
 449
 450 instance Outputable n => Outputable (GenAvailInfo n) where
 451    ppr = pprAvail
 452
 453 pprAvail :: Outputable n => GenAvailInfo n -> SDoc
 454 pprAvail (AvailTC n ns) = ppr n <> case {- filter (/= n) -} ns of
 455                                         []  -> empty
 456                                         ns' -> braces (hsep (punctuate comma (map ppr ns')))
 457
 458 pprAvail (Avail n) = ppr n
 459 \end{code}
 460
 461
 462 %************************************************************************
 463 %*                                                                      *
 464 \subsection{ModIface}
 465 %*                                                                      *
 466 %************************************************************************
 467
 468 \begin{code}
 469 type WhetherHasOrphans   = Bool
 470         -- An "orphan" is
 471         --      * an instance decl in a module other than the defn module for
 472         --              one of the tycons or classes in the instance head
 473         --      * a transformation rule in a module other than the one defining
 474         --              the function in the head of the rule.
 475
 476 type IsBootInterface     = Bool
 477
 478 type ImportVersion name  = (ModuleName, WhetherHasOrphans, IsBootInterface, WhatsImported name)
 479
 480 data WhatsImported name  = NothingAtAll                         -- The module is below us in the
 481                                                                 -- hierarchy, but we import nothing
 482
 483                          | Everything Version           -- Used for modules from other packages;
 484                                                         -- we record only the module's version number
 485
 486                          | Specifically
 487                                 Version                 -- Module version
 488                                 (Maybe Version)         -- Export-list version, if we depend on it
 489                                 [(name,Version)]        -- List guaranteed non-empty
 490                                 Version                 -- Rules version
 491
 492                          deriving( Eq )
 493         -- 'Specifically' doesn't let you say "I imported f but none of the rules in
 494         -- the module". If you use anything in the module you get its rule version
 495         -- So if the rules change, you'll recompile, even if you don't use them.
 496         -- This is easy to implement, and it's safer: you might not have used the rules last
 497         -- time round, but if someone has added a new rule you might need it this time
 498
 499         -- The export list field is (Just v) if we depend on the export list:
 500         --      we imported the module without saying exactly what we imported
 501         -- We need to recompile if the module exports changes, because we might
 502         -- now have a name clash in the importing module.
 503
 504 type IsExported = Name -> Bool          -- True for names that are exported from this module
 505 \end{code}
 506
 507
 508 %************************************************************************
 509 %*                                                                      *
 510 \subsection{The persistent compiler state}
 511 %*                                                                      *
 512 %************************************************************************
 513
 514 \begin{code}
 515 data PersistentCompilerState
 516    = PCS {
 517         pcs_PIT :: !PackageIfaceTable,  -- Domain = non-home-package modules
 518                                         --   the mi_decls component is empty
 519
 520         pcs_PTE :: !PackageTypeEnv,     -- Domain = non-home-package modules
 521                                         --   except that the InstEnv components is empty
 522
 523         pcs_insts :: !PackageInstEnv,   -- The total InstEnv accumulated from all
 524                                         --   the non-home-package modules
 525
 526         pcs_rules :: !PackageRuleBase,  -- Ditto RuleEnv
 527
 528         pcs_PRS :: !PersistentRenamerState
 529      }
 530 \end{code}
 531
 532 The @PersistentRenamerState@ persists across successive calls to the
 533 compiler.
 534
 535 It contains:
 536   * A name supply, which deals with allocating unique names to
 537     (Module,OccName) original names,
 538
 539   * An accumulated TypeEnv from all the modules in imported packages
 540
 541   * An accumulated InstEnv from all the modules in imported packages
 542     The point is that we don't want to keep recreating it whenever
 543     we compile a new module.  The InstEnv component of pcPST is empty.
 544     (This means we might "see" instances that we shouldn't "really" see;
 545     but the Haskell Report is vague on what is meant to be visible,
 546     so we just take the easy road here.)
 547
 548   * Ditto for rules
 549
 550   * A "holding pen" for declarations that have been read out of
 551     interface files but not yet sucked in, renamed, and typechecked
 552
 553 \begin{code}
 554 type PackageTypeEnv  = TypeEnv
 555 type PackageRuleBase = RuleBase
 556 type PackageInstEnv  = InstEnv
 557
 558 data PersistentRenamerState
 559   = PRS { prsOrig    :: !NameSupply,
 560           prsImpMods :: !ImportedModuleInfo,
 561           prsDecls   :: !DeclsMap,
 562           prsInsts   :: !IfaceInsts,
 563           prsRules   :: !IfaceRules
 564     }
 565 \end{code}
 566
 567 The NameSupply makes sure that there is just one Unique assigned for
 568 each original name; i.e. (module-name, occ-name) pair.  The Name is
 569 always stored as a Global, and has the SrcLoc of its binding location.
 570 Actually that's not quite right.  When we first encounter the original
 571 name, we might not be at its binding site (e.g. we are reading an
 572 interface file); so we give it 'noSrcLoc' then.  Later, when we find
 573 its binding site, we fix it up.
 574
 575 Exactly the same is true of the Module stored in the Name.  When we first
 576 encounter the occurrence, we may not know the details of the module, so
 577 we just store junk.  Then when we find the binding site, we fix it up.
 578
 579 \begin{code}
 580 data NameSupply
 581  = NameSupply { nsUniqs :: UniqSupply,
 582                 -- Supply of uniques
 583                 nsNames :: OrigNameCache,
 584                 -- Ensures that one original name gets one unique
 585                 nsIPs   :: OrigIParamCache
 586                 -- Ensures that one implicit parameter name gets one unique
 587    }
 588
 589 type OrigNameCache   = FiniteMap (ModuleName,OccName) Name
 590 type OrigIParamCache = FiniteMap (IPName RdrName) (IPName Name)
 591 \end{code}
 592
 593 @ImportedModuleInfo@ contains info ONLY about modules that have not yet
 594 been loaded into the iPIT.  These modules are mentioned in interfaces we've
 595 already read, so we know a tiny bit about them, but we havn't yet looked
 596 at the interface file for the module itself.  It needs to persist across
 597 invocations of the renamer, at least from Rename.checkOldIface to Rename.renameSource.
 598 And there's no harm in it persisting across multiple compilations.
 599
 600 \begin{code}
 601 type ImportedModuleInfo = FiniteMap ModuleName (WhetherHasOrphans, IsBootInterface)
 602 \end{code}
 603
 604 A DeclsMap contains a binding for each Name in the declaration
 605 including the constructors of a type decl etc.  The Bool is True just
 606 for the 'main' Name.
 607
 608 \begin{code}
 609 type DeclsMap = (NameEnv (AvailInfo, Bool, (Module, RdrNameTyClDecl)), Int)
 610                                                 -- The Int says how many have been sucked in
 611
 612 type IfaceInsts = GatedDecls RdrNameInstDecl
 613 type IfaceRules = GatedDecls RdrNameRuleDecl
 614
 615 type GatedDecls d = (Bag (GatedDecl d), Int)    -- The Int says how many have been sucked in
 616 type GatedDecl  d = (GateFn, (Module, d))
 617 type GateFn       = (Name -> Bool) -> Bool      -- Returns True <=> gate is open
 618                                                 -- The (Name -> Bool) fn returns True for visible Names
 619         -- For example, suppose this is in an interface file
 620         --      instance C T where ...
 621         -- We want to slurp this decl if both C and T are "visible" in
 622         -- the importing module.  See "The gating story" in RnIfaces for details.
 623 \end{code}
 624
 625
 626 %************************************************************************
 627 %*                                                                      *
 628 \subsection{Provenance and export info}
 629 %*                                                                      *
 630 %************************************************************************
 631
 632 A LocalRdrEnv is used for local bindings (let, where, lambda, case)
 633
 634 \begin{code}
 635 type LocalRdrEnv = RdrNameEnv Name
 636
 637 extendLocalRdrEnv :: LocalRdrEnv -> [Name] -> LocalRdrEnv
 638 extendLocalRdrEnv env names
 639   = addListToRdrEnv env [(mkRdrUnqual (nameOccName n), n) | n <- names]
 640 \end{code}
 641
 642 The GlobalRdrEnv gives maps RdrNames to Names.  There is a separate
 643 one for each module, corresponding to that module's top-level scope.
 644
 645 \begin{code}
 646 type GlobalRdrEnv = RdrNameEnv [GlobalRdrElt]
 647         -- The list is because there may be name clashes
 648         -- These only get reported on lookup, not on construction
 649
 650 data GlobalRdrElt = GRE Name Provenance (Maybe DeprecTxt)
 651         -- The Maybe DeprecTxt tells whether this name is deprecated
 652
 653 pprGlobalRdrEnv env
 654   = vcat (map pp (rdrEnvToList env))
 655   where
 656     pp (rn, nps) = ppr rn <> colon <+>
 657                    vcat [ppr n <+> pprNameProvenance n p | (GRE n p _) <- nps]
 658 \end{code}
 659
 660 The "provenance" of something says how it came to be in scope.
 661
 662 \begin{code}
 663 data Provenance
 664   = LocalDef                    -- Defined locally
 665
 666   | NonLocalDef                 -- Defined non-locally
 667         ImportReason
 668
 669 -- Just used for grouping error messages (in RnEnv.warnUnusedBinds)
 670 instance Eq Provenance where
 671   p1 == p2 = case p1 `compare` p2 of EQ -> True; _ -> False
 672
 673 instance Eq ImportReason where
 674   p1 == p2 = case p1 `compare` p2 of EQ -> True; _ -> False
 675
 676 instance Ord Provenance where
 677    compare LocalDef LocalDef = EQ
 678    compare LocalDef (NonLocalDef _) = LT
 679    compare (NonLocalDef _) LocalDef = GT
 680
 681    compare (NonLocalDef reason1) (NonLocalDef reason2)
 682       = compare reason1 reason2
 683
 684 instance Ord ImportReason where
 685    compare ImplicitImport ImplicitImport = EQ
 686    compare ImplicitImport (UserImport _ _ _) = LT
 687    compare (UserImport _ _ _) ImplicitImport = GT
 688    compare (UserImport m1 loc1 _) (UserImport m2 loc2 _)
 689       = (m1 `compare` m2) `thenCmp` (loc1 `compare` loc2)
 690
 691
 692 data ImportReason
 693   = UserImport Module SrcLoc Bool       -- Imported from module M on line L
 694                                         -- Note the M may well not be the defining module
 695                                         -- for this thing!
 696         -- The Bool is true iff the thing was named *explicitly* in the import spec,
 697         -- rather than being imported as part of a group; e.g.
 698         --      import B
 699         --      import C( T(..) )
 700         -- Here, everything imported by B, and the constructors of T
 701         -- are not named explicitly; only T is named explicitly.
 702         -- This info is used when warning of unused names.
 703
 704   | ImplicitImport                      -- Imported implicitly for some other reason
 705 \end{code}
 706
 707 \begin{code}
 708 hasBetterProv :: Provenance -> Provenance -> Bool
 709 -- Choose
 710 --      a local thing                 over an   imported thing
 711 --      a user-imported thing         over a    non-user-imported thing
 712 --      an explicitly-imported thing  over an   implicitly imported thing
 713 hasBetterProv LocalDef                            _                            = True
 714 hasBetterProv (NonLocalDef (UserImport _ _ _   )) (NonLocalDef ImplicitImport) = True
 715 hasBetterProv _                                   _                            = False
 716
 717 pprNameProvenance :: Name -> Provenance -> SDoc
 718 pprNameProvenance name LocalDef          = ptext SLIT("defined at") <+> ppr (nameSrcLoc name)
 719 pprNameProvenance name (NonLocalDef why) = sep [ppr_reason why,
 720                                                 nest 2 (ppr_defn (nameSrcLoc name))]
 721
 722 ppr_reason ImplicitImport         = ptext SLIT("implicitly imported")
 723 ppr_reason (UserImport mod loc _) = ptext SLIT("imported from") <+> ppr mod <+> ptext SLIT("at") <+> ppr loc
 724
 725 ppr_defn loc | isGoodSrcLoc loc = parens (ptext SLIT("at") <+> ppr loc)
 726              | otherwise        = empty
 727 \end{code}