ghc/compiler/main/HscTypes.lhs

   1 %
   2 % (c) The University of Glasgow, 2000
   3 %
   4 \section[HscTypes]{Types for the per-module compiler}
   5
   6 \begin{code}
   7 module HscTypes (
   8         Finder, ModuleLocation(..),
   9
  10         ModDetails(..), ModIface(..), GlobalSymbolTable,
  11         HomeSymbolTable, PackageSymbolTable,
  12         HomeIfaceTable, PackageIfaceTable,
  13         lookupTable, lookupTableByModName,
  14
  15         IfaceDecls(..),
  16
  17         VersionInfo(..), initialVersionInfo,
  18
  19         TyThing(..), groupTyThings,
  20
  21         TypeEnv, extendTypeEnv, lookupTypeEnv,
  22
  23         WhetherHasOrphans, ImportVersion, WhatsImported(..),
  24         PersistentRenamerState(..), IsBootInterface, Avails, DeclsMap,
  25         IfaceInsts, IfaceRules, GatedDecl,
  26         OrigNameEnv(..), OrigNameNameEnv, OrigNameIParamEnv,
  27         AvailEnv, AvailInfo, GenAvailInfo(..),
  28         PersistentCompilerState(..),
  29
  30         Deprecations(..), lookupDeprec,
  31
  32         InstEnv, ClsInstEnv, DFunId,
  33
  34         GlobalRdrEnv, RdrAvailInfo,
  35
  36         -- Provenance
  37         Provenance(..), ImportReason(..), PrintUnqualified,
  38         pprNameProvenance, hasBetterProv
  39
  40     ) where
  41
  42 #include "HsVersions.h"
  43
  44 import RdrName          ( RdrNameEnv, emptyRdrEnv )
  45 import Name             ( Name, NameEnv, NamedThing,
  46                           emptyNameEnv, unitNameEnv, extendNameEnv, plusNameEnv,
  47                           lookupNameEnv, emptyNameEnv, getName, nameModule,
  48                           nameSrcLoc )
  49 import NameSet          ( NameSet )
  50 import OccName          ( OccName )
  51 import Module           ( Module, ModuleName, ModuleEnv,
  52                           lookupModuleEnv, lookupModuleEnvByName
  53                         )
  54 import VarSet           ( TyVarSet )
  55 import VarEnv           ( emptyVarEnv )
  56 import Id               ( Id )
  57 import Class            ( Class )
  58 import TyCon            ( TyCon )
  59
  60 import BasicTypes       ( Version, initialVersion, Fixity )
  61
  62 import HsSyn            ( DeprecTxt )
  63 import RdrHsSyn         ( RdrNameHsDecl )
  64 import RnHsSyn          ( RenamedTyClDecl, RenamedIfaceSig, RenamedRuleDecl, RenamedInstDecl )
  65
  66 import CoreSyn          ( CoreRule )
  67 import Type             ( Type )
  68
  69 import FiniteMap        ( FiniteMap, emptyFM, addToFM, lookupFM, foldFM )
  70 import Bag              ( Bag )
  71 import Maybes           ( seqMaybe )
  72 import UniqFM           ( UniqFM )
  73 import Outputable
  74 import SrcLoc           ( SrcLoc, isGoodSrcLoc )
  75 import Util             ( thenCmp )
  76 import UniqSupply       ( UniqSupply )
  77 \end{code}
  78
  79 %************************************************************************
  80 %*                                                                      *
  81 \subsection{The Finder type}
  82 %*                                                                      *
  83 %************************************************************************
  84
  85 \begin{code}
  86 type Finder = ModuleName -> IO (Maybe (Module, ModuleLocation))
  87
  88 data ModuleLocation
  89    = ModuleLocation {
  90         hs_file  :: FilePath,
  91         hi_file  :: FilePath,
  92         obj_file :: FilePath
  93       }
  94 \end{code}
  95
  96 For a module in another package, the hs_file and obj_file
  97 components of ModuleLocation are undefined.
  98
  99 The locations specified by a ModuleLocation may or may not
 100 correspond to actual files yet: for example, even if the object
 101 file doesn't exist, the ModuleLocation still contains the path to
 102 where the object file will reside if/when it is created.
 103
 104
 105 %************************************************************************
 106 %*                                                                      *
 107 \subsection{Symbol tables and Module details}
 108 %*                                                                      *
 109 %************************************************************************
 110
 111 A @ModIface@ plus a @ModDetails@ summarises everything we know
 112 about a compiled module.  The @ModIface@ is the stuff *before* linking,
 113 and can be written out to an interface file.  The @ModDetails@ is after
 114 linking; it is the "linked" form of the mi_decls field.
 115
 116 \begin{code}
 117 data ModIface
 118    = ModIface {
 119         mi_module   :: Module,                  -- Complete with package info
 120         mi_version  :: VersionInfo,             -- Module version number
 121         mi_orphan   :: WhetherHasOrphans,       -- Whether this module has orphans
 122
 123         mi_usages   :: [ImportVersion Name],    -- Usages; kept sorted so that it's easy
 124                                                 -- to decide whether to write a new iface file
 125                                                 -- (changing usages doesn't affect the version of
 126                                                 --  this module)
 127
 128         mi_exports  :: Avails,                  -- What it exports
 129                                                 -- Kept sorted by (mod,occ),
 130                                                 -- to make version comparisons easier
 131
 132         mi_globals  :: GlobalRdrEnv,            -- Its top level environment
 133
 134         mi_fixities :: NameEnv Fixity,          -- Fixities
 135         mi_deprecs  :: Deprecations,            -- Deprecations
 136
 137         mi_decls    :: IfaceDecls               -- The RnDecls form of ModDetails
 138      }
 139
 140 data IfaceDecls = IfaceDecls { dcl_tycl  :: [RenamedTyClDecl],  -- Sorted
 141                                dcl_sigs  :: [RenamedIfaceSig],  -- Sorted
 142                                dcl_rules :: [RenamedRuleDecl],  -- Sorted
 143                                dcl_insts :: [RenamedInstDecl] } -- Unsorted
 144
 145 -- typechecker should only look at this, not ModIface
 146 -- Should be able to construct ModDetails from mi_decls in ModIface
 147 data ModDetails
 148    = ModDetails {
 149         -- The next three fields are created by the typechecker
 150         md_types    :: TypeEnv,
 151         md_insts    :: [DFunId],        -- Dfun-ids for the instances in this module
 152         md_rules    :: RuleEnv          -- Domain may include Ids from other modules
 153      }
 154 \end{code}
 155
 156 \begin{code}
 157 emptyModDetails :: ModDetails
 158 emptyModDetails
 159   = ModDetails { md_types = emptyTypeEnv,
 160                  md_insts = [],
 161                  md_rules = emptyRuleEnv
 162     }
 163
 164 emptyModIface :: Module -> ModIface
 165 emptyModIface mod
 166   = ModIface { mi_module   = mod,
 167                mi_exports  = [],
 168                mi_globals  = emptyRdrEnv,
 169                mi_deprecs  = NoDeprecs
 170     }
 171 \end{code}
 172
 173 Symbol tables map modules to ModDetails:
 174
 175 \begin{code}
 176 type SymbolTable        = ModuleEnv ModDetails
 177 type IfaceTable         = ModuleEnv ModIface
 178
 179 type HomeIfaceTable     = IfaceTable
 180 type PackageIfaceTable  = IfaceTable
 181
 182 type HomeSymbolTable    = SymbolTable   -- Domain = modules in the home package
 183 type PackageSymbolTable = SymbolTable   -- Domain = modules in the some other package
 184 type GlobalSymbolTable  = SymbolTable   -- Domain = all modules
 185 \end{code}
 186
 187 Simple lookups in the symbol table.
 188
 189 \begin{code}
 190 lookupTable :: ModuleEnv a -> ModuleEnv a -> Name -> Maybe a
 191 -- We often have two Symbol- or IfaceTables, and want to do a lookup
 192 lookupTable ht pt name
 193   = lookupModuleEnv ht mod `seqMaybe` lookupModuleEnv pt mod
 194   where
 195     mod = nameModule name
 196
 197 lookupTableByModName :: ModuleEnv a -> ModuleEnv a -> ModuleName -> Maybe a
 198 -- We often have two Symbol- or IfaceTables, and want to do a lookup
 199 lookupTableByModName ht pt mod
 200   = lookupModuleEnvByName ht mod `seqMaybe` lookupModuleEnvByName pt mod
 201 \end{code}
 202
 203
 204 %************************************************************************
 205 %*                                                                      *
 206 \subsection{Type environment stuff}
 207 %*                                                                      *
 208 %************************************************************************
 209
 210 \begin{code}
 211 type TypeEnv = NameEnv TyThing
 212 emptyTypeEnv = emptyNameEnv
 213
 214 data TyThing = AnId   Id
 215              | ATyCon TyCon
 216              | AClass Class
 217
 218 instance NamedThing TyThing where
 219   getName (AnId id)   = getName id
 220   getName (ATyCon tc) = getName tc
 221   getName (AClass cl) = getName cl
 222 \end{code}
 223
 224
 225 \begin{code}
 226 lookupTypeEnv :: SymbolTable -> Name -> Maybe TyThing
 227 lookupTypeEnv tbl name
 228   = case lookupModuleEnv tbl (nameModule name) of
 229         Just details -> lookupNameEnv (md_types details) name
 230         Nothing      -> Nothing
 231
 232
 233 groupTyThings :: [TyThing] -> FiniteMap Module TypeEnv
 234   -- Finite map because we want the range too
 235 groupTyThings things
 236   = foldl add emptyFM things
 237   where
 238     add :: FiniteMap Module TypeEnv -> TyThing -> FiniteMap Module TypeEnv
 239     add tbl thing = addToFM tbl mod new_env
 240                   where
 241                     name    = getName thing
 242                     mod     = nameModule name
 243                     new_env = case lookupFM tbl mod of
 244                                 Nothing  -> unitNameEnv name thing
 245                                 Just env -> extendNameEnv env name thing
 246
 247 extendTypeEnv :: SymbolTable -> FiniteMap Module TypeEnv -> SymbolTable
 248 extendTypeEnv tbl things
 249   = foldFM add tbl things
 250   where
 251     add mod type_env tbl
 252         = panic "extendTypeEnv" --extendModuleEnv mod new_details
 253         where
 254           new_details
 255              = case lookupModuleEnv tbl mod of
 256                   Nothing      -> emptyModDetails {md_types = type_env}
 257                   Just details -> details {md_types = md_types details
 258                                                      `plusNameEnv` type_env}
 259 \end{code}
 260
 261
 262 %************************************************************************
 263 %*                                                                      *
 264 \subsection{Auxiliary types}
 265 %*                                                                      *
 266 %************************************************************************
 267
 268 These types are defined here because they are mentioned in ModDetails,
 269 but they are mostly elaborated elsewhere
 270
 271 \begin{code}
 272 data VersionInfo
 273   = VersionInfo {
 274         vers_module  :: Version,        -- Changes when anything changes
 275         vers_exports :: Version,        -- Changes when export list changes
 276         vers_rules   :: Version,        -- Changes when any rule changes
 277         vers_decls   :: NameEnv Version
 278                 -- Versions for "big" names only (not data constructors, class ops)
 279                 -- The version of an Id changes if its fixity changes
 280                 -- Ditto data constructors, class operations, except that the version of
 281                 -- the parent class/tycon changes
 282     }
 283
 284 initialVersionInfo :: VersionInfo
 285 initialVersionInfo = VersionInfo { vers_module  = initialVersion,
 286                                    vers_exports = initialVersion,
 287                                    vers_rules   = initialVersion,
 288                                    vers_decls   = emptyNameEnv }
 289
 290 data Deprecations = NoDeprecs
 291                   | DeprecAll DeprecTxt                 -- Whole module deprecated
 292                   | DeprecSome (NameEnv DeprecTxt)      -- Some things deprecated
 293                                                         -- Just "big" names
 294
 295 lookupDeprec :: ModIface -> Name -> Maybe DeprecTxt
 296 lookupDeprec iface name
 297   = case mi_deprecs iface of
 298         NoDeprecs      -> Nothing
 299         DeprecAll txt  -> Just txt
 300         DeprecSome env -> lookupNameEnv env name
 301
 302 type InstEnv    = UniqFM ClsInstEnv             -- Maps Class to instances for that class
 303 type ClsInstEnv = [(TyVarSet, [Type], DFunId)]  -- The instances for a particular class
 304 type DFunId     = Id
 305
 306 type RuleEnv    = NameEnv [CoreRule]
 307
 308 emptyRuleEnv    = emptyVarEnv
 309 \end{code}
 310
 311
 312 \begin{code}
 313 type Avails       = [AvailInfo]
 314 type AvailInfo    = GenAvailInfo Name
 315 type RdrAvailInfo = GenAvailInfo OccName
 316
 317 data GenAvailInfo name  = Avail name     -- An ordinary identifier
 318                         | AvailTC name   -- The name of the type or class
 319                                   [name] -- The available pieces of type/class.
 320                                          -- NB: If the type or class is itself
 321                                          -- to be in scope, it must be in this list.
 322                                          -- Thus, typically: AvailTC Eq [Eq, ==, /=]
 323                         deriving( Eq )
 324                         -- Equality used when deciding if the interface has changed
 325
 326 type AvailEnv     = NameEnv AvailInfo   -- Maps a Name to the AvailInfo that contains it
 327 \end{code}
 328
 329
 330 %************************************************************************
 331 %*                                                                      *
 332 \subsection{ModIface}
 333 %*                                                                      *
 334 %************************************************************************
 335
 336 \begin{code}
 337 type WhetherHasOrphans   = Bool
 338         -- An "orphan" is
 339         --      * an instance decl in a module other than the defn module for
 340         --              one of the tycons or classes in the instance head
 341         --      * a transformation rule in a module other than the one defining
 342         --              the function in the head of the rule.
 343
 344 type IsBootInterface     = Bool
 345
 346 type ImportVersion name  = (ModuleName, WhetherHasOrphans, IsBootInterface, WhatsImported name)
 347
 348 data WhatsImported name  = NothingAtAll                         -- The module is below us in the
 349                                                                 -- hierarchy, but we import nothing
 350
 351                          | Everything Version           -- Used for modules from other packages;
 352                                                         -- we record only the module's version number
 353
 354                          | Specifically
 355                                 Version                 -- Module version
 356                                 (Maybe Version)         -- Export-list version, if we depend on it
 357                                 [(name,Version)]        -- List guaranteed non-empty
 358                                 Version                 -- Rules version
 359
 360                          deriving( Eq )
 361         -- 'Specifically' doesn't let you say "I imported f but none of the rules in
 362         -- the module". If you use anything in the module you get its rule version
 363         -- So if the rules change, you'll recompile, even if you don't use them.
 364         -- This is easy to implement, and it's safer: you might not have used the rules last
 365         -- time round, but if someone has added a new rule you might need it this time
 366
 367         -- The export list field is (Just v) if we depend on the export list:
 368         --      we imported the module without saying exactly what we imported
 369         -- We need to recompile if the module exports changes, because we might
 370         -- now have a name clash in the importing module.
 371 \end{code}
 372
 373
 374 %************************************************************************
 375 %*                                                                      *
 376 \subsection{The persistent compiler state}
 377 %*                                                                      *
 378 %************************************************************************
 379
 380 \begin{code}
 381 data PersistentCompilerState
 382    = PCS {
 383         pcs_PIT :: PackageIfaceTable,   -- Domain = non-home-package modules
 384                                         --   the mi_decls component is empty
 385         pcs_PST :: PackageSymbolTable,  -- Domain = non-home-package modules
 386                                         --   except that the InstEnv components is empty
 387         pcs_insts :: InstEnv,           -- The total InstEnv accumulated from all
 388                                         --   the non-home-package modules
 389         pcs_rules :: RuleEnv,           -- Ditto RuleEnv
 390
 391         pcs_PRS :: PersistentRenamerState
 392      }
 393 \end{code}
 394
 395 The @PersistentRenamerState@ persists across successive calls to the
 396 compiler.
 397
 398 It contains:
 399   * A name supply, which deals with allocating unique names to
 400     (Module,OccName) original names,
 401
 402   * An accumulated InstEnv from all the modules in pcs_PST
 403     The point is that we don't want to keep recreating it whenever
 404     we compile a new module.  The InstEnv component of pcPST is empty.
 405     (This means we might "see" instances that we shouldn't "really" see;
 406     but the Haskell Report is vague on what is meant to be visible,
 407     so we just take the easy road here.)
 408
 409   * Ditto for rules
 410
 411   * A "holding pen" for declarations that have been read out of
 412     interface files but not yet sucked in, renamed, and typechecked
 413
 414 \begin{code}
 415 data PersistentRenamerState
 416   = PRS { prsOrig  :: OrigNameEnv,
 417           prsDecls :: DeclsMap,
 418           prsInsts :: IfaceInsts,
 419           prsRules :: IfaceRules,
 420           prsNS    :: UniqSupply
 421     }
 422 \end{code}
 423
 424 The OrigNameEnv makes sure that there is just one Unique assigned for
 425 each original name; i.e. (module-name, occ-name) pair.  The Name is
 426 always stored as a Global, and has the SrcLoc of its binding location.
 427 Actually that's not quite right.  When we first encounter the original
 428 name, we might not be at its binding site (e.g. we are reading an
 429 interface file); so we give it 'noSrcLoc' then.  Later, when we find
 430 its binding site, we fix it up.
 431
 432 Exactly the same is true of the Module stored in the Name.  When we first
 433 encounter the occurrence, we may not know the details of the module, so
 434 we just store junk.  Then when we find the binding site, we fix it up.
 435
 436 \begin{code}
 437 data OrigNameEnv
 438  = Orig { origNames  :: OrigNameNameEnv,
 439                 -- Ensures that one original name gets one unique
 440           origIParam :: OrigNameIParamEnv
 441                 -- Ensures that one implicit parameter name gets one unique
 442    }
 443
 444 type OrigNameNameEnv   = FiniteMap (ModuleName,OccName) Name
 445 type OrigNameIParamEnv = FiniteMap OccName Name
 446 \end{code}
 447
 448
 449 A DeclsMap contains a binding for each Name in the declaration
 450 including the constructors of a type decl etc.  The Bool is True just
 451 for the 'main' Name.
 452
 453 \begin{code}
 454 type DeclsMap = NameEnv (AvailInfo, Bool, (Module, RdrNameHsDecl))
 455
 456 type IfaceInsts = Bag GatedDecl
 457 type IfaceRules = Bag GatedDecl
 458
 459 type GatedDecl = (NameSet, (Module, RdrNameHsDecl))
 460 \end{code}
 461
 462
 463 %************************************************************************
 464 %*                                                                      *
 465 \subsection{Provenance and export info}
 466 %*                                                                      *
 467 %************************************************************************
 468
 469 The GlobalRdrEnv gives maps RdrNames to Names.  There is a separate
 470 one for each module, corresponding to that module's top-level scope.
 471
 472 \begin{code}
 473 type GlobalRdrEnv = RdrNameEnv [(Name,Provenance)]      -- The list is because there may be name clashes
 474                                                         -- These only get reported on lookup,
 475                                                         -- not on construction
 476 \end{code}
 477
 478 The "provenance" of something says how it came to be in scope.
 479
 480 \begin{code}
 481 data Provenance
 482   = LocalDef                    -- Defined locally
 483
 484   | NonLocalDef                 -- Defined non-locally
 485         ImportReason
 486         PrintUnqualified
 487
 488 -- Just used for grouping error messages (in RnEnv.warnUnusedBinds)
 489 instance Eq Provenance where
 490   p1 == p2 = case p1 `compare` p2 of EQ -> True; _ -> False
 491
 492 instance Eq ImportReason where
 493   p1 == p2 = case p1 `compare` p2 of EQ -> True; _ -> False
 494
 495 instance Ord Provenance where
 496    compare LocalDef LocalDef = EQ
 497    compare LocalDef (NonLocalDef _ _) = LT
 498    compare (NonLocalDef _ _) LocalDef = GT
 499
 500    compare (NonLocalDef reason1 _) (NonLocalDef reason2 _)
 501       = compare reason1 reason2
 502
 503 instance Ord ImportReason where
 504    compare ImplicitImport ImplicitImport = EQ
 505    compare ImplicitImport (UserImport _ _ _) = LT
 506    compare (UserImport _ _ _) ImplicitImport = GT
 507    compare (UserImport m1 loc1 _) (UserImport m2 loc2 _)
 508       = (m1 `compare` m2) `thenCmp` (loc1 `compare` loc2)
 509
 510
 511 data ImportReason
 512   = UserImport Module SrcLoc Bool       -- Imported from module M on line L
 513                                         -- Note the M may well not be the defining module
 514                                         -- for this thing!
 515         -- The Bool is true iff the thing was named *explicitly* in the import spec,
 516         -- rather than being imported as part of a group; e.g.
 517         --      import B
 518         --      import C( T(..) )
 519         -- Here, everything imported by B, and the constructors of T
 520         -- are not named explicitly; only T is named explicitly.
 521         -- This info is used when warning of unused names.
 522
 523   | ImplicitImport                      -- Imported implicitly for some other reason
 524
 525
 526 type PrintUnqualified = Bool    -- True <=> the unqualified name of this thing is
 527                                 -- in scope in this module, so print it
 528                                 -- unqualified in error messages
 529 \end{code}
 530
 531 \begin{code}
 532 hasBetterProv :: Provenance -> Provenance -> Bool
 533 -- Choose
 534 --      a local thing                 over an   imported thing
 535 --      a user-imported thing         over a    non-user-imported thing
 536 --      an explicitly-imported thing  over an   implicitly imported thing
 537 hasBetterProv LocalDef                              _                              = True
 538 hasBetterProv (NonLocalDef (UserImport _ _ True) _) _                              = True
 539 hasBetterProv (NonLocalDef (UserImport _ _ _   ) _) (NonLocalDef ImplicitImport _) = True
 540 hasBetterProv _                                     _                              = False
 541
 542 pprNameProvenance :: Name -> Provenance -> SDoc
 543 pprNameProvenance name LocalDef            = ptext SLIT("defined at") <+> ppr (nameSrcLoc name)
 544 pprNameProvenance name (NonLocalDef why _) = sep [ppr_reason why,
 545                                               nest 2 (parens (ppr_defn (nameSrcLoc name)))]
 546
 547 ppr_reason ImplicitImport         = ptext SLIT("implicitly imported")
 548 ppr_reason (UserImport mod loc _) = ptext SLIT("imported from") <+> ppr mod <+> ptext SLIT("at") <+> ppr loc
 549
 550 ppr_defn loc | isGoodSrcLoc loc = ptext SLIT("at") <+> ppr loc
 551              | otherwise        = empty
 552 \end{code}