ghc/compiler/main/Packages.lhs

   1 %
   2 % (c) The University of Glasgow, 2000
   3 %
   4 \section{Package manipulation}
   5
   6 \begin{code}
   7 module Packages (
   8         module PackageConfig,
   9
  10         -- * The PackageConfigMap
  11         PackageConfigMap, emptyPackageConfigMap, lookupPackage,
  12         extendPackageConfigMap, dumpPackages,
  13
  14         -- * Reading the package config, and processing cmdline args
  15         PackageIdH(..), isHomePackage,
  16         PackageState(..),
  17         initPackages,
  18         moduleToPackageConfig,
  19         getPackageDetails,
  20         isHomeModule,
  21
  22         -- * Inspecting the set of packages in scope
  23         getPackageIncludePath,
  24         getPackageCIncludes,
  25         getPackageLibraryPath,
  26         getPackageLinkOpts,
  27         getPackageExtraCcOpts,
  28         getPackageFrameworkPath,
  29         getPackageFrameworks,
  30         getExplicitPackagesAnd,
  31
  32         -- * Utils
  33         isDllName
  34     )
  35 where
  36
  37 #include "HsVersions.h"
  38
  39 import PackageConfig
  40 import SysTools         ( getTopDir, getPackageConfigPath )
  41 import ParsePkgConf     ( loadPackageConfig )
  42 import DynFlags         ( dopt, DynFlag(..), DynFlags(..), PackageFlag(..) )
  43 import StaticFlags      ( opt_Static )
  44 import Config           ( cProjectVersion )
  45 import Name             ( Name, nameModule_maybe )
  46 import Module           ( Module, mkModule )
  47 import UniqFM
  48 import UniqSet
  49 import Util
  50 import Maybes           ( expectJust )
  51 import Panic
  52 import Outputable
  53
  54 #if __GLASGOW_HASKELL__ >= 603
  55 import System.Directory ( getAppUserDataDirectory )
  56 #else
  57 import Compat.Directory ( getAppUserDataDirectory )
  58 #endif
  59
  60 import Distribution.InstalledPackageInfo
  61 import Distribution.Package
  62 import Distribution.Version
  63 import System.IO        ( hPutStrLn, stderr )
  64 import Data.Maybe       ( isNothing )
  65 import System.Directory ( doesFileExist )
  66 import Control.Monad    ( when, foldM )
  67 import Data.List        ( nub, partition )
  68
  69 #ifdef mingw32_TARGET_OS
  70 import Data.List        ( isPrefixOf )
  71 #endif
  72
  73 import FastString
  74 import DATA_IOREF
  75 import EXCEPTION        ( throwDyn )
  76
  77 -- ---------------------------------------------------------------------------
  78 -- The Package state
  79
  80 -- Package state is all stored in DynFlags, including the details of
  81 -- all packages, which packages are exposed, and which modules they
  82 -- provide.
  83
  84 -- The package state is computed by initPackages, and kept in DynFlags.
  85 --
  86 --   * -package <pkg> causes <pkg> to become exposed, and all other packages
  87 --      with the same name to become hidden.
  88 --
  89 --   * -hide-package <pkg> causes <pkg> to become hidden.
  90 --
  91 --   * Let exposedPackages be the set of packages thus exposed.
  92 --     Let depExposedPackages be the transitive closure from exposedPackages of
  93 --     their dependencies.
  94 --
  95 --   * It is an error for any two packages in depExposedPackages to provide the
  96 --     same module.
  97 --
  98 --   * When searching for a module from an explicit import declaration,
  99 --     only the exposed modules in exposedPackages are valid.
 100 --
 101 --   * When searching for a module from an implicit import, all modules
 102 --     from depExposedPackages are valid.
 103 --
 104 --   * When linking in a comp manager mode, we link in packages the
 105 --     program depends on (the compiler knows this list by the
 106 --     time it gets to the link step).  Also, we link in all packages
 107 --     which were mentioned with explicit -package flags on the command-line,
 108 --     or are a transitive dependency of same, or are "base"/"rts".
 109 --     The reason for (b) is that we might need packages which don't
 110 --     contain any Haskell modules, and therefore won't be discovered
 111 --     by the normal mechanism of dependency tracking.
 112
 113
 114 -- One important thing that the package state provides is a way to
 115 -- tell, for a given module, whether it is part of the current package
 116 -- or not.  We need to know this for two reasons:
 117 --
 118 --  * generating cross-DLL calls is different from intra-DLL calls
 119 --    (see below).
 120 --  * we don't record version information in interface files for entities
 121 --    in a different package.
 122 --
 123 -- Notes on DLLs
 124 -- ~~~~~~~~~~~~~
 125 -- When compiling module A, which imports module B, we need to
 126 -- know whether B will be in the same DLL as A.
 127 --      If it's in the same DLL, we refer to B_f_closure
 128 --      If it isn't, we refer to _imp__B_f_closure
 129 -- When compiling A, we record in B's Module value whether it's
 130 -- in a different DLL, by setting the DLL flag.
 131
 132 data PackageState = PackageState {
 133
 134   explicitPackages      :: [PackageId],
 135         -- The packages we're going to link in eagerly.  This list
 136         -- should be in reverse dependency order; that is, a package
 137         -- is always mentioned before the packages it depends on.
 138
 139   pkgIdMap              :: PackageConfigMap, -- PackageId   -> PackageConfig
 140         -- mapping derived from the package databases and
 141         -- command-line package flags.
 142
 143   moduleToPkgConf       :: UniqFM (PackageConfig,Bool),
 144         -- Maps Module to (pkgconf,exposed), where pkgconf is the
 145         -- PackageConfig for the package containing the module, and
 146         -- exposed is True if the package exposes that module.
 147
 148   -- The PackageIds of some known packages
 149   basePackageId         :: PackageIdH,
 150   rtsPackageId          :: PackageIdH,
 151   haskell98PackageId    :: PackageIdH,
 152   thPackageId           :: PackageIdH
 153   }
 154
 155 data PackageIdH
 156    = HomePackage                -- The "home" package is the package curently
 157                                 -- being compiled
 158    | ExtPackage PackageId       -- An "external" package is any other package
 159
 160
 161 isHomePackage :: PackageIdH -> Bool
 162 isHomePackage HomePackage    = True
 163 isHomePackage (ExtPackage _) = False
 164
 165 -- A PackageConfigMap maps a PackageId to a PackageConfig
 166 type PackageConfigMap = UniqFM PackageConfig
 167
 168 emptyPackageConfigMap :: PackageConfigMap
 169 emptyPackageConfigMap = emptyUFM
 170
 171 lookupPackage :: PackageConfigMap -> PackageId -> Maybe PackageConfig
 172 lookupPackage = lookupUFM
 173
 174 extendPackageConfigMap
 175    :: PackageConfigMap -> [PackageConfig] -> PackageConfigMap
 176 extendPackageConfigMap pkg_map new_pkgs
 177   = foldl add pkg_map new_pkgs
 178   where add pkg_map p = addToUFM pkg_map (packageConfigId p) p
 179
 180 getPackageDetails :: PackageState -> PackageId -> PackageConfig
 181 getPackageDetails dflags ps = expectJust "getPackageDetails" (lookupPackage (pkgIdMap dflags) ps)
 182
 183 -- ----------------------------------------------------------------------------
 184 -- Loading the package config files and building up the package state
 185
 186 initPackages :: DynFlags -> IO DynFlags
 187 initPackages dflags = do
 188   pkg_map <- readPackageConfigs dflags;
 189   state <- mkPackageState dflags pkg_map
 190   return dflags{ pkgState = state }
 191
 192 -- -----------------------------------------------------------------------------
 193 -- Reading the package database(s)
 194
 195 readPackageConfigs :: DynFlags -> IO PackageConfigMap
 196 readPackageConfigs dflags = do
 197         -- System one always comes first
 198    system_pkgconf <- getPackageConfigPath
 199    pkg_map1 <- readPackageConfig dflags emptyPackageConfigMap system_pkgconf
 200
 201         -- Read user's package conf (eg. ~/.ghc/i386-linux-6.3/package.conf)
 202         -- unless the -no-user-package-conf flag was given.
 203         -- We only do this when getAppUserDataDirectory is available
 204         -- (GHC >= 6.3).
 205    (exists, pkgconf) <- catch (do
 206       appdir <- getAppUserDataDirectory "ghc"
 207       let
 208          pkgconf = appdir ++ '/':TARGET_ARCH ++ '-':TARGET_OS
 209                         ++ '-':cProjectVersion ++ "/package.conf"
 210       flg <- doesFileExist pkgconf
 211       return (flg, pkgconf))
 212        -- gobble them all up and turn into False.
 213       (\ _ -> return (False, ""))
 214    pkg_map2 <- if (dopt Opt_ReadUserPackageConf dflags && exists)
 215                   then readPackageConfig dflags pkg_map1 pkgconf
 216                   else return pkg_map1
 217
 218         -- Read all the ones mentioned in -package-conf flags
 219    pkg_map <- foldM (readPackageConfig dflags) pkg_map2
 220                  (extraPkgConfs dflags)
 221
 222    return pkg_map
 223
 224
 225 readPackageConfig
 226    :: DynFlags -> PackageConfigMap -> FilePath -> IO PackageConfigMap
 227 readPackageConfig dflags pkg_map conf_file = do
 228   when (verbosity dflags >= 2) $
 229         hPutStrLn stderr ("Using package config file: "
 230                          ++ conf_file)
 231   proto_pkg_configs <- loadPackageConfig conf_file
 232   top_dir           <- getTopDir
 233   let pkg_configs = mungePackagePaths top_dir proto_pkg_configs
 234   return (extendPackageConfigMap pkg_map pkg_configs)
 235
 236
 237 mungePackagePaths :: String -> [PackageConfig] -> [PackageConfig]
 238 -- Replace the string "$topdir" at the beginning of a path
 239 -- with the current topdir (obtained from the -B option).
 240 mungePackagePaths top_dir ps = map munge_pkg ps
 241  where
 242   munge_pkg p = p{ importDirs  = munge_paths (importDirs p),
 243                    includeDirs = munge_paths (includeDirs p),
 244                    libraryDirs = munge_paths (libraryDirs p),
 245                    frameworkDirs = munge_paths (frameworkDirs p) }
 246
 247   munge_paths = map munge_path
 248
 249   munge_path p
 250           | Just p' <- maybePrefixMatch "$topdir" p = top_dir ++ p'
 251           | otherwise                               = p
 252
 253
 254 -- -----------------------------------------------------------------------------
 255 -- When all the command-line options are in, we can process our package
 256 -- settings and populate the package state.
 257
 258 mkPackageState :: DynFlags -> PackageConfigMap -> IO PackageState
 259 mkPackageState dflags pkg_db = do
 260   --
 261   -- Modify the package database according to the command-line flags
 262   -- (-package, -hide-package, -ignore-package).
 263   --
 264   -- Also, here we build up a set of the packages mentioned in -package
 265   -- flags on the command line; these are called the "explicit" packages.
 266   -- we link these packages in eagerly.  The explicit set should contain
 267   -- at least rts & base, which is why we pretend that the command line
 268   -- contains -package rts & -package base.
 269   --
 270   let
 271         flags = reverse (packageFlags dflags)
 272
 273         procflags pkgs expl [] = return (pkgs,expl)
 274         procflags pkgs expl (ExposePackage str : flags) = do
 275            case partition (matches str) pkgs of
 276                 ([],_)   -> missingPackageErr str
 277                 ([p],ps) -> procflags (p':ps) (addOneToUniqSet expl pkgid) flags
 278                   where pkgid = packageConfigId p
 279                         p' = p {exposed=True}
 280                 (ps,_)   -> multiplePackagesErr str ps
 281         procflags pkgs expl (HidePackage str : flags) = do
 282            case partition (matches str) pkgs of
 283                 ([],_)   -> missingPackageErr str
 284                 ([p],ps) -> procflags (p':ps) expl flags
 285                   where p' = p {exposed=False}
 286                 (ps,_)   -> multiplePackagesErr str ps
 287         procflags pkgs expl (IgnorePackage str : flags) = do
 288            case partition (matches str) pkgs of
 289                 (ps,qs) -> procflags qs expl flags
 290                 -- missing package is not an error for -ignore-package,
 291                 -- because a common usage is to -ignore-package P as
 292                 -- a preventative measure just in case P exists.
 293
 294         -- A package named on the command line can either include the
 295         -- version, or just the name if it is unambiguous.
 296         matches str p
 297                 =  str == showPackageId (package p)
 298                 || str == pkgName (package p)
 299   --
 300   (pkgs1,explicit) <- procflags (eltsUFM pkg_db) emptyUniqSet flags
 301   --
 302   let
 303         elimDanglingDeps pkgs =
 304            case partition (hasDanglingDeps pkgs) pkgs of
 305               ([],ps) -> ps
 306               (ps,qs) -> elimDanglingDeps qs
 307
 308         hasDanglingDeps pkgs p = any dangling (depends p)
 309           where dangling pid = pid `notElem` all_pids
 310                 all_pids = map package pkgs
 311   --
 312   -- Eliminate any packages which have dangling dependencies (perhaps
 313   -- because the package was removed by -ignore-package).
 314   --
 315   let pkgs = elimDanglingDeps pkgs1
 316       pkg_db = extendPackageConfigMap emptyPackageConfigMap pkgs
 317   --
 318   -- Find the transitive closure of dependencies of exposed
 319   --
 320   let exposed_pkgids = [ packageConfigId p | p <- pkgs, exposed p ]
 321   dep_exposed <- closeDeps pkg_db exposed_pkgids
 322   --
 323   -- Look up some known PackageIds
 324   --
 325   let
 326         lookupPackageByName :: FastString -> PackageIdH
 327         lookupPackageByName nm =
 328           case [ conf | p <- dep_exposed,
 329                         Just conf <- [lookupPackage pkg_db p],
 330                         nm == mkFastString (pkgName (package conf)) ] of
 331                 []     -> HomePackage
 332                 (p:ps) -> ExtPackage (mkPackageId (package p))
 333
 334         -- Get the PackageIds for some known packages (we know the names,
 335         -- but we don't know the versions).  Some of these packages might
 336         -- not exist in the database, so they are Maybes.
 337         basePackageId           = lookupPackageByName basePackageName
 338         rtsPackageId            = lookupPackageByName rtsPackageName
 339         haskell98PackageId      = lookupPackageByName haskell98PackageName
 340         thPackageId             = lookupPackageByName thPackageName
 341
 342         -- add base & rts to the explicit packages
 343         basicLinkedPackages = [basePackageId,rtsPackageId]
 344         explicit' = addListToUniqSet explicit
 345                         [ p | ExtPackage p <- basicLinkedPackages ]
 346   --
 347   -- Close the explicit packages with their dependencies
 348   --
 349   dep_explicit <- closeDeps pkg_db (uniqSetToList explicit')
 350   --
 351   -- Build up a mapping from Module -> PackageConfig for all modules.
 352   -- Discover any conflicts at the same time, and factor in the new exposed
 353   -- status of each package.
 354   --
 355   let
 356         extend_modmap modmap pkgname = do
 357           let
 358                 pkg = expectJust "mkPackageState" (lookupPackage pkg_db pkgname)
 359                 exposed_mods = map mkModule (exposedModules pkg)
 360                 hidden_mods  = map mkModule (hiddenModules pkg)
 361                 all_mods = exposed_mods ++ hidden_mods
 362           --
 363           -- check for overlaps
 364           --
 365           let
 366                 overlaps = [ (m,pkg) | m <- all_mods,
 367                                        Just (pkg,_) <- [lookupUFM modmap m] ]
 368           --
 369           when (not (null overlaps)) $ overlappingError pkg overlaps
 370           --
 371           let
 372           return (addListToUFM modmap
 373                     [(m, (pkg, m `elem` exposed_mods))
 374                     | m <- all_mods])
 375   --
 376   mod_map <- foldM extend_modmap emptyUFM dep_exposed
 377
 378   return PackageState{ explicitPackages    = dep_explicit,
 379                        pkgIdMap            = pkg_db,
 380                        moduleToPkgConf     = mod_map,
 381                        basePackageId       = basePackageId,
 382                        rtsPackageId        = rtsPackageId,
 383                        haskell98PackageId  = haskell98PackageId,
 384                        thPackageId         = thPackageId
 385                      }
 386   -- done!
 387
 388 basePackageName      = FSLIT("base")
 389 rtsPackageName       = FSLIT("rts")
 390 haskell98PackageName = FSLIT("haskell98")
 391 thPackageName        = FSLIT("template-haskell")
 392                                 -- Template Haskell libraries in here
 393
 394 overlappingError pkg overlaps
 395   = throwDyn (CmdLineError (showSDoc (vcat (map msg overlaps))))
 396   where
 397         this_pkg = text (showPackageId (package pkg))
 398         msg (mod,other_pkg) =
 399            text "Error: module '" <> ppr mod
 400                  <> text "' is exposed by package "
 401                  <> this_pkg <> text " and package "
 402                  <> text (showPackageId (package other_pkg))
 403
 404 multiplePackagesErr str ps =
 405   throwDyn (CmdLineError (showSDoc (
 406                    text "Error; multiple packages match" <+>
 407                         text str <> colon <+>
 408                     sep (punctuate comma (map (text.showPackageId.package) ps))
 409                 )))
 410
 411 -- -----------------------------------------------------------------------------
 412 -- Extracting information from the packages in scope
 413
 414 -- Many of these functions take a list of packages: in those cases,
 415 -- the list is expected to contain the "dependent packages",
 416 -- i.e. those packages that were found to be depended on by the
 417 -- current module/program.  These can be auto or non-auto packages, it
 418 -- doesn't really matter.  The list is always combined with the list
 419 -- of explicit (command-line) packages to determine which packages to
 420 -- use.
 421
 422 getPackageIncludePath :: DynFlags -> [PackageId] -> IO [String]
 423 getPackageIncludePath dflags pkgs = do
 424   ps <- getExplicitPackagesAnd dflags pkgs
 425   return (nub (filter notNull (concatMap includeDirs ps)))
 426
 427         -- includes are in reverse dependency order (i.e. rts first)
 428 getPackageCIncludes :: [PackageConfig] -> IO [String]
 429 getPackageCIncludes pkg_configs = do
 430   return (reverse (nub (filter notNull (concatMap includes pkg_configs))))
 431
 432 getPackageLibraryPath :: DynFlags -> [PackageId] -> IO [String]
 433 getPackageLibraryPath dflags pkgs = do
 434   ps <- getExplicitPackagesAnd dflags pkgs
 435   return (nub (filter notNull (concatMap libraryDirs ps)))
 436
 437 getPackageLinkOpts :: DynFlags -> [PackageId] -> IO [String]
 438 getPackageLinkOpts dflags pkgs = do
 439   ps <- getExplicitPackagesAnd dflags pkgs
 440   let tag = buildTag dflags
 441       rts_tag = rtsBuildTag dflags
 442   let
 443         imp        = if opt_Static then "" else "_dyn"
 444         libs p     = map ((++imp) . addSuffix) (hACK (hsLibraries p)) ++ extraLibraries p
 445         all_opts p = map ("-l" ++) (libs p) ++ ldOptions p
 446
 447         suffix     = if null tag then "" else  '_':tag
 448         rts_suffix = if null rts_tag then "" else  '_':rts_tag
 449
 450         addSuffix rts@"HSrts"    = rts       ++ rts_suffix
 451         addSuffix other_lib      = other_lib ++ suffix
 452
 453   return (concat (map all_opts ps))
 454   where
 455
 456      -- This is a totally horrible (temporary) hack, for Win32.  Problem is
 457      -- that package.conf for Win32 says that the main prelude lib is
 458      -- split into HSbase1, HSbase2 and HSbase3, which is needed due to a bug
 459      -- in the GNU linker (PEi386 backend). However, we still only
 460      -- have HSbase.a for static linking, not HSbase{1,2,3}.a
 461      -- getPackageLibraries is called to find the .a's to add to the static
 462      -- link line.  On Win32, this hACK detects HSbase{1,2,3} and
 463      -- replaces them with HSbase, so static linking still works.
 464      -- Libraries needed for dynamic (GHCi) linking are discovered via
 465      -- different route (in InteractiveUI.linkPackage).
 466      -- See driver/PackageSrc.hs for the HSbase1/HSbase2 split definition.
 467      -- THIS IS A STRICTLY TEMPORARY HACK (famous last words ...)
 468      -- JRS 04 Sept 01: Same appalling hack for HSwin32[1,2]
 469      -- KAA 29 Mar  02: Same appalling hack for HSobjectio[1,2,3,4]
 470      --
 471      -- [sof 03/05: Renamed the (moribund) HSwin32 to HSwin_32 so as to
 472      --  avoid filename conflicts with the 'Win32' package on a case-insensitive filesystem]
 473      hACK libs
 474 #      if !defined(mingw32_TARGET_OS) && !defined(cygwin32_TARGET_OS)
 475        = libs
 476 #      else
 477        = if   "HSbase1" `elem` libs && "HSbase2" `elem` libs && "HSbase3" `elem` libs
 478          then "HSbase" : filter (not.(isPrefixOf "HSbase")) libs
 479          else
 480          if   "HSwin_321" `elem` libs && "HSwin_322" `elem` libs
 481          then "HSwin_32" : filter (not.(isPrefixOf "HSwin_32")) libs
 482          else
 483          if   "HSobjectio1" `elem` libs && "HSobjectio2" `elem` libs && "HSobjectio3" `elem` libs && "HSobjectio4" `elem` libs
 484          then "HSobjectio" : filter (not.(isPrefixOf "HSobjectio")) libs
 485          else
 486          libs
 487 #      endif
 488
 489 getPackageExtraCcOpts :: DynFlags -> [PackageId] -> IO [String]
 490 getPackageExtraCcOpts dflags pkgs = do
 491   ps <- getExplicitPackagesAnd dflags pkgs
 492   return (concatMap ccOptions ps)
 493
 494 getPackageFrameworkPath  :: DynFlags -> [PackageId] -> IO [String]
 495 getPackageFrameworkPath dflags pkgs = do
 496   ps <- getExplicitPackagesAnd dflags pkgs
 497   return (nub (filter notNull (concatMap frameworkDirs ps)))
 498
 499 getPackageFrameworks  :: DynFlags -> [PackageId] -> IO [String]
 500 getPackageFrameworks dflags pkgs = do
 501   ps <- getExplicitPackagesAnd dflags pkgs
 502   return (concatMap frameworks ps)
 503
 504 -- -----------------------------------------------------------------------------
 505 -- Package Utils
 506
 507 -- Takes a Module, and if the module is in a package returns
 508 -- (pkgconf,exposed) where pkgconf is the PackageConfig for that package,
 509 -- and exposed is True if the package exposes the module.
 510 moduleToPackageConfig :: DynFlags -> Module -> Maybe (PackageConfig,Bool)
 511 moduleToPackageConfig dflags m =
 512   lookupUFM (moduleToPkgConf (pkgState dflags)) m
 513
 514 isHomeModule :: DynFlags -> Module -> Bool
 515 isHomeModule dflags mod = isNothing (moduleToPackageConfig dflags mod)
 516
 517 getExplicitPackagesAnd :: DynFlags -> [PackageId] -> IO [PackageConfig]
 518 getExplicitPackagesAnd dflags pkgids =
 519   let
 520       state   = pkgState dflags
 521       pkg_map = pkgIdMap state
 522       expl    = explicitPackages state
 523   in do
 524   all_pkgs <- foldM (add_package pkg_map) expl pkgids
 525   return (map (getPackageDetails state) all_pkgs)
 526
 527 -- Takes a list of packages, and returns the list with dependencies included,
 528 -- in reverse dependency order (a package appears before those it depends on).
 529 closeDeps :: PackageConfigMap -> [PackageId] -> IO [PackageId]
 530 closeDeps pkg_map ps = foldM (add_package pkg_map) [] ps
 531
 532 -- internal helper
 533 add_package :: PackageConfigMap -> [PackageId] -> PackageId -> IO [PackageId]
 534 add_package pkg_db ps p
 535   | p `elem` ps = return ps     -- Check if we've already added this package
 536   | otherwise =
 537       case lookupPackage pkg_db p of
 538         Nothing -> missingPackageErr (packageIdString p)
 539         Just pkg -> do
 540            -- Add the package's dependents also
 541            let deps = map mkPackageId (depends pkg)
 542            ps' <- foldM (add_package pkg_db) ps deps
 543            return (p : ps')
 544
 545 missingPackageErr p =  throwDyn (CmdLineError ("unknown package: " ++ p))
 546
 547 -- -----------------------------------------------------------------------------
 548 -- Determining whether a Name refers to something in another package or not.
 549 -- Cross-package references need to be handled differently when dynamically-
 550 -- linked libraries are involved.
 551
 552 isDllName :: DynFlags -> Name -> Bool
 553 isDllName dflags name
 554   | opt_Static = False
 555   | otherwise =
 556     case nameModule_maybe name of
 557         Nothing -> False  -- no, it is not even an external name
 558         Just mod ->
 559             case lookupUFM (moduleToPkgConf (pkgState dflags)) mod of
 560                 Just _  -> True   -- yes, its a package module
 561                 Nothing -> False  -- no, must be a home module
 562
 563 -- -----------------------------------------------------------------------------
 564 -- Displaying packages
 565
 566 dumpPackages :: DynFlags -> IO ()
 567 -- Show package info on console, if verbosity is >= 3
 568 dumpPackages dflags
 569   = do  let pkg_map = pkgIdMap (pkgState dflags)
 570         hPutStrLn stderr $ showSDoc $
 571               vcat (map (text.showInstalledPackageInfo) (eltsUFM pkg_map))
 572 \end{code}