ghc/compiler/main/ParsePkgConf.y

   1 {
   2 module ParsePkgConf( loadPackageConfig ) where
   3
   4 #include "HsVersions.h"
   5
   6 import Packages  ( PackageConfig(..), defaultPackageConfig )
   7 import Lex
   8 import FastString
   9 import StringBuffer
  10 import SrcLoc
  11 import Outputable
  12 import Panic     ( GhcException(..) )
  13 import EXCEPTION ( throwDyn )
  14
  15 }
  16
  17 %token
  18  '{'            { ITocurly }
  19  '}'            { ITccurly }
  20  '['            { ITobrack }
  21  ']'            { ITcbrack }
  22  ','            { ITcomma }
  23  '='            { ITequal }
  24  VARID          { ITvarid    $$ }
  25  CONID          { ITconid    $$ }
  26  STRING         { ITstring   $$ }
  27
  28 %monad { P } { thenP } { returnP }
  29 %lexer { lexer } { ITeof }
  30 %name parse
  31 %tokentype { Token }
  32 %%
  33
  34 pkgconf :: { [ PackageConfig ] }
  35         : '[' ']'                       { [] }
  36         | '[' pkgs ']'                  { reverse $2 }
  37
  38 pkgs    :: { [ PackageConfig ] }
  39         : pkg                           { [ $1 ] }
  40         | pkgs ',' pkg                  { $3 : $1 }
  41
  42 pkg     :: { PackageConfig }
  43         : CONID '{' fields '}'          { $3 defaultPackageConfig }
  44
  45 fields  :: { PackageConfig -> PackageConfig }
  46         : field                         { \p -> $1 p }
  47         | fields ',' field              { \p -> $1 ($3 p) }
  48
  49 field   :: { PackageConfig -> PackageConfig }
  50         : VARID '=' STRING
  51                  {% case unpackFS $1 of {
  52                    "name" -> returnP (\ p -> p{name = unpackFS $3});
  53                    _      -> happyError } }
  54
  55         | VARID '=' strlist
  56                 {\p -> case unpackFS $1 of
  57                         "import_dirs"     -> p{import_dirs     = $3}
  58                         "library_dirs"    -> p{library_dirs    = $3}
  59                         "hs_libraries"    -> p{hs_libraries    = $3}
  60                         "extra_libraries" -> p{extra_libraries = $3}
  61                         "include_dirs"    -> p{include_dirs    = $3}
  62                         "c_includes"      -> p{c_includes      = $3}
  63                         "package_deps"    -> p{package_deps    = $3}
  64                         "extra_ghc_opts"  -> p{extra_ghc_opts  = $3}
  65                         "extra_cc_opts"   -> p{extra_cc_opts   = $3}
  66                         "extra_ld_opts"   -> p{extra_ld_opts   = $3}
  67                         "framework_dirs"  -> p{framework_dirs  = $3}
  68                         "extra_frameworks"-> p{extra_frameworks= $3}
  69                         _other            -> p
  70                 }
  71
  72 strlist :: { [String] }
  73         : '[' ']'                       { [] }
  74         | '[' strs ']'                  { reverse $2 }
  75
  76 strs    :: { [String] }
  77         : STRING                        { [ unpackFS $1 ] }
  78         | strs ',' STRING               { unpackFS $3 : $1 }
  79
  80 {
  81 happyError :: P a
  82 happyError buf PState{ loc = loc } = PFailed (srcParseErr buf loc)
  83
  84 loadPackageConfig :: FilePath -> IO [PackageConfig]
  85 loadPackageConfig conf_filename = do
  86    buf <- hGetStringBuffer conf_filename
  87    let loc  = mkSrcLoc (mkFastString conf_filename) 1
  88        exts = ExtFlags {glasgowExtsEF = False,
  89                         ffiEF         = False,
  90                         withEF        = False,
  91                         parrEF        = False}
  92    case parse buf (mkPState loc exts) of
  93         PFailed err -> do
  94             freeStringBuffer buf
  95             throwDyn (InstallationError (showSDoc err))
  96
  97         POk _ pkg_details -> do
  98             freeStringBuffer buf
  99             return pkg_details
 100 }